qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, TIMEIN)
  69         CASE(CPID, VEHICLES)
  70         CASE(CPID, VEHICLES_OTHER)
  71         /** always last */
  72         CASE(CPID, LAST)
  73 ENUMCLASS_END(CPID)
  74
  75 USING(Notification, entity);
  76
  77 // used for notification system multi-team identifiers
  78 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  79 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  80
  81 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  82         VARITEM(1, 0, s1) \
  83         VARITEM(2, 0, XPD(s1, s2)) \
  84         VARITEM(3, 0, XPD(s1, s2, s3)) \
  85         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  86         VARITEM(0, 1, f1) \
  87         VARITEM(1, 1, XPD(s1, f1)) \
  88         VARITEM(2, 1, XPD(s1, s2, f1)) \
  89         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  90         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  91         VARITEM(0, 2, XPD(f1, f2)) \
  92         VARITEM(1, 2, XPD(s1, f1, f2)) \
  93         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  94         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  95         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  96         VARITEM(0, 3, XPD(f1, f2, f3)) \
  97         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  98         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  99         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 100         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 101         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 102         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 103         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 104         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 105         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 106
 107 void Destroy_All_Notifications();
 108 void Create_Notification_Entity(entity notif,
 109         float var_default,
 110         float var_cvar,
 111         MSG typeId,
 112         string namestring,
 113         string cvarnamestring,
 114         int teamnum);
 115 void Create_Notification_Entity_Annce(entity notif,
 116                                                                                 float var_cvar,
 117                                                                                 string namestring,
 118                                                                                 /* MSG_ANNCE */
 119                                                                                 float channel,
 120                                                                                 string snd,
 121                                                                                 float vol,
 122                                                                                 float position);
 123
 124 void Create_Notification_Entity_InfoCenter(entity notif,
 125                                                                                         float var_cvar,
 126                                                                                         string namestring,
 127                                                                                         int strnum,
 128                                                                                         int flnum,
 129                                                                                         /* MSG_INFO & MSG_CENTER */
 130                                                                                         string args,
 131                                                                                         string hudargs,
 132                                                                                         string icon,
 133                                                                                         CPID cpid,
 134                                                                                         string durcnt,
 135                                                                                         string normal,
 136                                                                                         string gentle);
 137
 138 void Create_Notification_Entity_Multi(entity notif,
 139                                                                                 float var_cvar,
 140                                                                                 string namestring,
 141                                                                                 /* MSG_MULTI */
 142                                                                                 Notification anncename,
 143                                                                                 Notification infoname,
 144                                                                                 Notification centername);
 145
 146 void Create_Notification_Entity_Choice(entity notif,
 147                                                                                 float var_cvar,
 148                                                                                 string namestring,
 149                                                                                 /* MSG_CHOICE */
 150                                                                                 float challow_def,
 151                                                                                 float challow_var,
 152                                                                                 MSG chtype,
 153                                                                                 Notification optiona,
 154                                                                                 Notification optionb);
 155
 156 void Dump_Notifications(int fh, bool alsoprint);
 157
 158 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 159 {
 160         switch (request)
 161         {
 162                 case CMD_REQUEST_COMMAND:
 163                 {
 164                         #ifdef GAMEQC
 165                         string filename = argv(1);
 166                         bool alsoprint = false;
 167                         if (filename == "")
 168                         {
 169                                 filename = "notifications_dump.cfg";
 170                                 alsoprint = false;
 171                         }
 172                         else if (filename == "-")
 173                         {
 174                                 filename = "notifications_dump.cfg";
 175                                 alsoprint = true;
 176                         }
 177                         int fh = fopen(filename, FILE_WRITE);
 178                         if (fh >= 0)
 179                         {
 180                                 Dump_Notifications(fh, alsoprint);
 181                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 182                                 fclose(fh);
 183                         }
 184                         else
 185                         {
 186                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 187                         }
 188                         #else
 189                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 190                         #endif
 191                         return;
 192                 }
 193                 default:
 194                 case CMD_REQUEST_USAGE:
 195                 {
 196                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 197                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 198                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 199                         LOG_INFO("  if left blank, it will only write to default.\n");
 200                         return;
 201                 }
 202         }
 203 }
 204
 205 #ifdef NOTIFICATIONS_DEBUG
 206 bool autocvar_notification_debug = false;
 207 void Debug_Notification(string input)
 208 {
 209         switch (autocvar_notification_debug)
 210         {
 211                 case 1: { LOG_TRACE(input); break; }
 212                 case 2: { LOG_INFO(input); break; }
 213         }
 214 }
 215 #endif
 216
 217 void Local_Notification(MSG net_type, Notification net_name, ...count);
 218 /** glue for networking, forwards to `Local_Notification` */
 219 void Local_Notification_WOVA(
 220         MSG net_type, Notification net_name,
 221         float stringcount, float floatcount,
 222         string s1, string s2, string s3, string s4,
 223         float f1, float f2, float f3, float f4);
 224
 225 #ifdef CSQC
 226 string prev_soundfile;
 227 float prev_soundtime;
 228 #endif
 229
 230 #ifdef SVQC
 231 IntrusiveList g_notifications;
 232 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 233 #endif
 234
 235 #ifdef SVQC
 236 ENUMCLASS(NOTIF)
 237         /** send to one client and their spectators */
 238         CASE(NOTIF, ONE)
 239         /** send ONLY to one client */
 240         CASE(NOTIF, ONE_ONLY)
 241         /** send only to X team and their spectators */
 242         CASE(NOTIF, TEAM)
 243         /** send only to X team and their spectators, except for Y person and their spectators */
 244         CASE(NOTIF, TEAM_EXCEPT)
 245         /** send to everyone */
 246         CASE(NOTIF, ALL)
 247         /** send to everyone except X person and their spectators */
 248         CASE(NOTIF, ALL_EXCEPT)
 249 ENUMCLASS_END(NOTIF)
 250
 251 string Get_Notif_BroadcastName(NOTIF broadcast)
 252 {
 253         switch (broadcast)
 254         {
 255                 case NOTIF_ONE: return "NOTIF_ONE";
 256                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 257                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 258                 case NOTIF_ALL: return "NOTIF_ALL";
 259                 case NOTIF_TEAM: return "NOTIF_TEAM";
 260                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 261         }
 262         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 263         return "";
 264 }
 265
 266 void Kill_Notification(
 267         NOTIF broadcast, entity client,
 268         MSG net_type, CPID net_name);
 269 void Send_Notification(
 270         NOTIF broadcast, entity client,
 271         MSG net_type, Notification net_name,
 272         ...count);
 273 void Send_Notification_WOVA(
 274         NOTIF broadcast, entity client,
 275         MSG net_type, Notification net_name,
 276         float stringcount, float floatcount,
 277         string s1, string s2, string s3, string s4,
 278         float f1, float f2, float f3, float f4);
 279 void Send_Notification_WOCOVA(
 280         NOTIF broadcast, entity client,
 281         MSG net_type, Notification net_name,
 282         string s1, string s2, string s3, string s4,
 283         float f1, float f2, float f3, float f4);
 284 #endif
 285
 286 // ===========================
 287 //  Special CVAR Declarations
 288 // ===========================
 289
 290 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 291 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 292
 293 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 294
 295 float autocvar_notification_show_location = false;
 296 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 297 float autocvar_notification_show_sprees = true;
 298 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 299 float autocvar_notification_show_sprees_info_newline = true;
 300 float autocvar_notification_show_sprees_info_specialonly = true;
 301 float autocvar_notification_errors_are_fatal = true;
 302 #ifdef SVQC
 303 float autocvar_notification_lifetime_runtime = 0.5;
 304 float autocvar_notification_lifetime_mapload = 10;
 305 #endif
 306
 307 #ifdef SVQC
 308 .float FRAG_VERBOSE;
 309 void Notification_GetCvars(entity this);
 310 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 311 #else
 312 float autocvar_notification_item_centerprinttime = 1.5;
 313
 314 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 315 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 316 float autocvar_notification_allow_chatboxprint = 0;
 317
 318 float autocvar_notification_show_sprees_center = true;
 319 float autocvar_notification_show_sprees_center_specialonly = true;
 320 #endif
 321
 322
 323 // ============================
 324 //  Notification Argument List
 325 // ============================
 326 /*
 327  These arguments get replaced with the Local_Notification_sprintf
 328  and other such functions found in all.qc to supply data
 329  from networked notifications to their usage in sprintf... It
 330  allows for more dynamic data to be inferred by the local
 331  notification parser, so that the server does not have to network
 332  anything too crazy on a per-client/per-situation basis.
 333
 334  Pay attention to the CSQC/SVQC relations, some of these are redefined
 335  in slightly different ways for different programs, this is because the
 336  server does a more conservative approach to the notifs than the client.
 337
 338  All arguments are swapped into strings, so be sure that your
 339  sprintf usage matches with proper %s placement.
 340
 341  Argument descriptions:
 342         s1-s4: string arguments to be literally swapped into sprintf
 343         s2loc: s2 string of locations of deaths or other events
 344         s3loc: s3 string of locations of deaths or other events
 345         f1-f4: float arguments expanded into strings to be swapped into sprintf
 346         f1p2dec: f1 float to string with 2 decimal places
 347         f2p2dec: f2 float to string with 2 decimal places
 348         f2primsec: f2 float primary or secondary selection for weapons
 349         f3primsec: f3 float primary or secondary selection for weapons
 350         f1secs: count_seconds of f1
 351         f1points: point or points depending on f1
 352         f1ord: count_ordinal of f1
 353         f1time: process_time of f1
 354         f1race_time: mmssss of f1
 355         f2race_time: mmssss of f2
 356         race_col: color of race time/position (i.e. good or bad)
 357         race_diff: show time difference between f2 and f3
 358         missing_teams: show which teams still need players
 359         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 360         nade_key: find the keybind for nade throwing
 361         frag_ping: show the ping of a player
 362         frag_stats: show health/armor/ping of a player
 363         frag_pos: show score status and position in the match of a player
 364         spree_cen: centerprint notif for kill spree/how many kills they have
 365         spree_inf: info notif for kill spree/how many kills they have
 366         spree_end: placed at the end of murder messages to show ending of sprees
 367         spree_lost: placed at the end of suicide messages to show losing of sprees
 368         item_wepname: return full name of a weapon from weaponid
 369         item_wepammo: ammo display for weapon from string
 370         item_centime: amount of time to display weapon message in centerprint
 371         item_buffname: return full name of a buff from buffid
 372         death_team: show the full name of the team a player is switching from
 373         minigame1_name: return human readable name of a minigame from its id(s1)
 374         minigame1_d: return descriptor name of a minigame from its id(s1)
 375 */
 376
 377 const float NOTIF_MAX_ARGS = 7;
 378 const float NOTIF_MAX_HUDARGS = 2;
 379 const float NOTIF_MAX_DURCNT = 2;
 380
 381 string arg_slot[NOTIF_MAX_ARGS];
 382
 383 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 384 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 385 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 386 const float ARG_CS = 4; // unique result to CSQC
 387 const float ARG_SV = 5; // unique result to SVQC
 388 const float ARG_DC = 6; // unique result to durcnt/centerprint
 389
 390 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 391 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 392
 393 string BUFF_NAME(int i);
 394
 395 #define NOTIF_ARGUMENT_LIST \
 396         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 397         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 398         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 399         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 400         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 401         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 402         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 403         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 404         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 405         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 406         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 407         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 408         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 409         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 410         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 411         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 412         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 413         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 414         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 415         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 416         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 417         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 418         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 419         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 420         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 421         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 422         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 423         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 424         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 425         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 426         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 427         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 428         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 429         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 430         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 431         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 432         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 433         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 434         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 435         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 436         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 437         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 438
 439 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 440         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 441 } MACRO_END
 442 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 443
 444 #define KILL_SPREE_LIST \
 445         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 446         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 447         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 448         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 449         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 450         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 451         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 452
 453 #ifdef CSQC
 454 string notif_arg_frag_ping(bool newline, float fping)
 455 {
 456         string s = newline ? "\n" : " ";
 457         if (fping < 0)
 458                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 459         else
 460                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 461 }
 462
 463 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 464 {
 465         string s = notif_arg_frag_ping(false, fping);
 466         if (fhealth > 1)
 467                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 468         else
 469                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 470 }
 471
 472 string notif_arg_missing_teams(float f1)
 473 {
 474         return sprintf("%s%s%s%s",
 475                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 476                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 477                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 478                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 479         );
 480 }
 481
 482 string notif_arg_spree_cen(float spree)
 483 {
 484         // 0 = off, 1 = target (but only for first victim) and attacker
 485         if(autocvar_notification_show_sprees_center)
 486         {
 487                 if(spree > 1)
 488                 {
 489                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 490                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 491
 492                         switch(spree)
 493                         {
 494                                 KILL_SPREE_LIST
 495                                 default:
 496                                 {
 497                                         if (!autocvar_notification_show_sprees_center_specialonly)
 498                                         {
 499                                                 return
 500                                                         sprintf(
 501                                                                 normal_or_gentle(
 502                                                                         _("%d frag spree! "),
 503                                                                         _("%d score spree! ")
 504                                                                 ),
 505                                                                 spree);
 506                                         }
 507                                         else { return ""; } // don't show spree information if it isn't an achievement
 508                                 }
 509                         }
 510
 511                         #undef SPREE_ITEM
 512                 }
 513                 else if(spree == -1) // first blood
 514                 {
 515                         return normal_or_gentle(_("First blood! "), _("First score! "));
 516                 }
 517                 else if(spree == -2) // first victim
 518                 {
 519                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 520                 }
 521         }
 522         return "";
 523 }
 524 #endif
 525
 526 string notif_arg_spree_inf(float type, string input, string player, float spree)
 527 {
 528         switch(type)
 529         {
 530                 case 1: // attacker kill spree
 531                 {
 532                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 533                         // this conditional (& 2) is true for 2 and 3
 534                         if(autocvar_notification_show_sprees_info & 2)
 535                         {
 536                                 #ifdef CSQC
 537                                 string spree_newline =
 538                                         ( autocvar_notification_show_sprees_info_newline ?
 539                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 540                                 #else
 541                                 string spree_newline =
 542                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 543                                 #endif
 544
 545                                 if(spree > 1)
 546                                 {
 547                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 548                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 549
 550                                         switch(spree)
 551                                         {
 552                                                 KILL_SPREE_LIST
 553                                                 default:
 554                                                 {
 555                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 556                                                         {
 557                                                                 return
 558                                                                         sprintf(
 559                                                                                 CCR(normal_or_gentle(
 560                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 561                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 562                                                                                 )),
 563                                                                                 player,
 564                                                                                 spree,
 565                                                                                 spree_newline
 566                                                                         );
 567                                                         }
 568                                                         else { return ""; } // don't show spree information if it isn't an achievement
 569                                                 }
 570                                         }
 571
 572                                         #undef SPREE_ITEM
 573                                 }
 574                                 else if(spree == -1) // firstblood
 575                                 {
 576                                         return
 577                                                 sprintf(
 578                                                         CCR(normal_or_gentle(
 579                                                                 _("%s^K1 drew first blood! %s^BG"),
 580                                                                 _("%s^K1 got the first score! %s^BG")
 581                                                         )),
 582                                                         player,
 583                                                         spree_newline
 584                                                 );
 585                                 }
 586                         }
 587                         break;
 588                 }
 589
 590                 case -1: // kill spree ended
 591                 {
 592                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 593                         {
 594                                 return
 595                                         sprintf(normal_or_gentle(
 596                                                 _(", ending their %d frag spree"),
 597                                                 _(", ending their %d score spree")
 598                                                 ),
 599                                                 spree
 600                                         );
 601                         }
 602                         break;
 603                 }
 604
 605                 case -2: // kill spree lost
 606                 {
 607                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 608                         {
 609                                 return
 610                                         sprintf(normal_or_gentle(
 611                                                 _(", losing their %d frag spree"),
 612                                                 _(", losing their %d score spree")
 613                                                 ),
 614                                                 spree
 615                                         );
 616                         }
 617                         break;
 618                 }
 619         }
 620         return "";
 621 }
 622
 623
 624 // ====================================
 625 //  Initialization/Create Declarations
 626 // ====================================
 627
 628 // common notification entity values
 629 .int nent_default;
 630 .bool nent_enabled;
 631 .MSG nent_type;
 632 .string nent_name;
 633 .string nent_cvarname;
 634 .int nent_stringcount;
 635 .int nent_floatcount;
 636 .bool nent_teamnum;
 637
 638 // MSG_ANNCE entity values
 639 .int nent_channel;
 640 .string nent_snd;
 641 .float nent_vol;
 642 .float nent_position;
 643
 644 // MSG_INFO and MSG_CENTER entity values
 645 .string nent_args; // used by both
 646 .string nent_hudargs; // used by info
 647 .string nent_icon; // used by info
 648 .CPID nent_cpid; // used by center
 649 .string nent_durcnt; // used by center
 650 .string nent_string; // used by both
 651
 652 // MSG_MULTI entity values
 653 .entity nent_msgannce;
 654 .entity nent_msginfo;
 655 .entity nent_msgcenter;
 656
 657 // MSG_CHOICE entity values
 658 .float nent_challow_def;
 659 .float nent_challow_var;
 660 .entity nent_optiona;
 661 .entity nent_optionb;
 662
 663 // networked notification entity values
 664 #ifdef SVQC
 665 .NOTIF nent_broadcast;
 666 #endif
 667 .entity nent_client;
 668 .MSG nent_net_type;
 669 .float nent_net_name;
 670 .string nent_strings[4];
 671 .float nent_floats[4];
 672
 673 #define ACVNN(name) autocvar_notification_##name
 674
 675 REGISTRY(Notifications, BITS(11))
 676 REGISTER_REGISTRY(Notifications)
 677 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 678 REGISTRY_CHECK(Notifications)
 679
 680 const int NOTIF_CHOICE_MAX = 50;
 681 int nent_choice_count = 0;
 682 .int nent_choice_idx;
 683 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 684 // initialization error detection
 685 bool notif_error;
 686 bool notif_global_error;
 687
 688 STATIC_INIT_LATE(Notif_Choices) {
 689         int c = 0;
 690         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 691         if (c > NOTIF_CHOICE_MAX) {
 692                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 693         }
 694 }
 695
 696 Notification Get_Notif_Ent(MSG net_type, int net_name)
 697 {
 698         Notification it = _Notifications_from(net_name, NULL);
 699         if (it.nent_type != net_type) {
 700                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 701                         Get_Notif_TypeName(net_type), net_type,
 702                         it.registered_id, net_name,
 703                         Get_Notif_TypeName(it.nent_type)
 704                 );
 705                 return NULL;
 706         }
 707         return it;
 708 }
 709
 710 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, default, sound, channel, volume, position) \
 711         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, default, sound, channel, volume, position)
 712
 713 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 714         NOTIF_ADD_AUTOCVAR(ANNCE_##name, default) \
 715         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, default, sound, channel, volume, position)
 716
 717 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, default, sound, channel, volume, position) \
 718         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 719                 Create_Notification_Entity      (this, default, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), #cvarname, teamnum); \
 720                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 721                         channel,   /* channel  */ \
 722                         sound,     /* snd      */ \
 723                         volume,    /* vol      */ \
 724                         position); /* position */ \
 725         }
 726
 727 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 728         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 729
 730 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 731         NOTIF_ADD_AUTOCVAR(INFO_##name, default) \
 732         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 733
 734 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 735         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 736                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_INFO, strtoupper(#name), #cvarname, teamnum); \
 737                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 738                         args,     /* args    */ \
 739                         hudargs,  /* hudargs */ \
 740                         icon,     /* icon    */ \
 741                         CPID_Null,/* cpid    */ \
 742                         "",       /* durcnt  */ \
 743                         normal,   /* normal  */ \
 744                         gentle);  /* gentle  */ \
 745         }
 746
 747 .string nent_iconargs;
 748 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 749         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 750 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 751         NOTIF_ADD_AUTOCVAR(name, default) \
 752         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 753                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name), #name, 0); \
 754                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 755                         args,     /* args    */ \
 756                         hudargs,  /* hudargs */ \
 757                         icon,     /* icon    */ \
 758                         CPID_Null,/* cpid    */ \
 759                         "",       /* durcnt  */ \
 760                         normal,   /* normal  */ \
 761                         gentle);  /* gentle  */ \
 762                 this.nent_iconargs = iconargs; \
 763         }
 764
 765 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 766         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 767
 768 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 769         NOTIF_ADD_AUTOCVAR(CENTER_##name, default) \
 770         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 771
 772 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 773         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 774                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), #cvarname, teamnum); \
 775                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 776                         args,    /* args    */ \
 777                         "",      /* hudargs */ \
 778                         "",      /* icon    */ \
 779                         cpid,    /* cpid    */ \
 780                         durcnt,  /* durcnt  */ \
 781                         normal,  /* normal  */ \
 782                         gentle); /* gentle  */ \
 783         }
 784
 785 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 786         NOTIF_ADD_AUTOCVAR(name, default) \
 787         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 788                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name), #name, 0); \
 789                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 790                         anncename,   /* anncename  */ \
 791                         infoname,    /* infoname   */ \
 792                         centername); /* centername */ \
 793         }
 794
 795 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 796         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, default, challow, chtype, optiona, optionb)
 797
 798 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 799         NOTIF_ADD_AUTOCVAR(CHOICE_##name, default) \
 800         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 801         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, default, challow, chtype, optiona, optionb)
 802
 803 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 804         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 805                 this.nent_choice_idx = nent_choice_count++; \
 806                 Create_Notification_Entity       (this, default, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), #cvarname, teamnum); \
 807                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 808                         challow,                                 /* challow_def */ \
 809                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 810                         chtype,                                  /* chtype      */ \
 811                         optiona,                                 /* optiona     */ \
 812                         optionb);                                /* optionb     */ \
 813         }
 814
 815 REGISTRY_BEGIN(Notifications)
 816 {
 817         notif_global_error = false;
 818 }
 819
 820 REGISTRY_END(Notifications)
 821 {
 822         if (!notif_global_error) return;
 823         // shit happened... stop the loading of the program now if this is unacceptable
 824         if (autocvar_notification_errors_are_fatal)
 825                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 826         else
 827                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 828 }
 829
 830 #include "all.inc"