Merge branch 'divVerent/simpler-clipped-rectangle' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / notifications / all.qh
1 #pragma once
2
3 #include <common/command/_mod.qh>
4
5 #include <common/constants.qh>
6 #include <common/teams.qh>
7 #include <common/util.qh>
8 #include <common/sounds/sound.qh>
9 #include <common/weapons/all.qh>
10
11 #ifdef CSQC
12 #include <client/autocvars.qh>
13 #endif
14
15 // Operator for bold notifications
16 #define BOLD_OPERATOR "^BOLD"
17
18 /** main types/groups of notifications */
19 ENUMCLASS(MSG)
20         /** "Global" AND "personal" announcer messages */
21         CASE(MSG, ANNCE)
22         /** "Global" information messages */
23         CASE(MSG, INFO)
24         /** "Personal" centerprint messages */
25         CASE(MSG, CENTER)
26         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
27         CASE(MSG, MULTI)
28         /** Choose which subcall wrapper to activate */
29         CASE(MSG, CHOICE)
30         /** Kill centerprint message @deprecated */
31         CASE(MSG, CENTER_KILL)
32 ENUMCLASS_END(MSG)
33
34 string Get_Notif_TypeName(MSG net_type)
35 {
36         switch (net_type)
37         {
38                 case MSG_ANNCE: return "MSG_ANNCE";
39                 case MSG_INFO: return "MSG_INFO";
40                 case MSG_CENTER: return "MSG_CENTER";
41                 case MSG_MULTI: return "MSG_MULTI";
42                 case MSG_CHOICE: return "MSG_CHOICE";
43         }
44         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
45         return "";
46 }
47
48 ENUMCLASS(CPID)
49         CASE(CPID, ASSAULT_ROLE)
50         CASE(CPID, ROUND)
51         CASE(CPID, CAMPCHECK)
52         CASE(CPID, CTF_CAPSHIELD)
53         CASE(CPID, CTF_LOWPRIO)
54         CASE(CPID, CTF_PASS)
55         CASE(CPID, STALEMATE)
56         CASE(CPID, NADES)
57         CASE(CPID, IDLING)
58         CASE(CPID, ITEM)
59         CASE(CPID, PREVENT_JOIN)
60         CASE(CPID, KEEPAWAY)
61         CASE(CPID, KEEPAWAY_WARN)
62         CASE(CPID, KEYHUNT)
63         CASE(CPID, KEYHUNT_OTHER)
64         CASE(CPID, LMS)
65         CASE(CPID, MISSING_TEAMS)
66         CASE(CPID, MISSING_PLAYERS)
67         CASE(CPID, INSTAGIB_FINDAMMO)
68         CASE(CPID, CAMPAIGN_MESSAGE)
69         CASE(CPID, MOTD)
70         CASE(CPID, NIX)
71         CASE(CPID, ONSLAUGHT)
72         CASE(CPID, ONS_CAPSHIELD)
73         CASE(CPID, OVERTIME)
74         CASE(CPID, POWERUP)
75         CASE(CPID, RACE_FINISHLAP)
76         CASE(CPID, TEAMCHANGE)
77         CASE(CPID, TIMEOUT)
78         CASE(CPID, TIMEIN)
79         CASE(CPID, VEHICLES)
80         CASE(CPID, VEHICLES_OTHER)
81         /** always last */
82         CASE(CPID, LAST)
83 ENUMCLASS_END(CPID)
84
85 USING(Notification, entity);
86
87 // used for notification system multi-team identifiers
88 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
89 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
90
91 #define EIGHT_VARS_TO_VARARGS_VARLIST \
92         VARITEM(1, 0, s1) \
93         VARITEM(2, 0, XPD(s1, s2)) \
94         VARITEM(3, 0, XPD(s1, s2, s3)) \
95         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
96         VARITEM(0, 1, f1) \
97         VARITEM(1, 1, XPD(s1, f1)) \
98         VARITEM(2, 1, XPD(s1, s2, f1)) \
99         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
100         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
101         VARITEM(0, 2, XPD(f1, f2)) \
102         VARITEM(1, 2, XPD(s1, f1, f2)) \
103         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
104         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
105         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
106         VARITEM(0, 3, XPD(f1, f2, f3)) \
107         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
108         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
109         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
110         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
111         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
112         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
113         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
114         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
115         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
116
117 void Destroy_All_Notifications();
118 void Create_Notification_Entity(entity notif,
119         float var_default,
120         float var_cvar,
121         MSG typeId,
122         string namestring,
123         int teamnum);
124 void Create_Notification_Entity_Annce(entity notif,
125                                                                                 float var_cvar,
126                                                                                 string namestring,
127                                                                                 /* MSG_ANNCE */
128                                                                                 float channel,
129                                                                                 string snd,
130                                                                                 float vol,
131                                                                                 float position);
132
133 void Create_Notification_Entity_InfoCenter(entity notif,
134                                                                                         float var_cvar,
135                                                                                         string namestring,
136                                                                                         int strnum,
137                                                                                         int flnum,
138                                                                                         /* MSG_INFO & MSG_CENTER */
139                                                                                         string args,
140                                                                                         string hudargs,
141                                                                                         string icon,
142                                                                                         CPID cpid,
143                                                                                         string durcnt,
144                                                                                         string normal,
145                                                                                         string gentle);
146
147 void Create_Notification_Entity_Multi(entity notif,
148                                                                                 float var_cvar,
149                                                                                 string namestring,
150                                                                                 /* MSG_MULTI */
151                                                                                 Notification anncename,
152                                                                                 Notification infoname,
153                                                                                 Notification centername);
154
155 void Create_Notification_Entity_Choice(entity notif,
156                                                                                 float var_cvar,
157                                                                                 string namestring,
158                                                                                 /* MSG_CHOICE */
159                                                                                 float challow_def,
160                                                                                 float challow_var,
161                                                                                 MSG chtype,
162                                                                                 Notification optiona,
163                                                                                 Notification optionb);
164
165 void Dump_Notifications(int fh, bool alsoprint);
166
167 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt", false)
168 {
169         switch (request)
170         {
171                 case CMD_REQUEST_COMMAND:
172                 {
173                         #ifdef GAMEQC
174                         string filename = argv(1);
175                         bool alsoprint = false;
176                         if (filename == "")
177                         {
178                                 filename = "notifications_dump.cfg";
179                                 alsoprint = false;
180                         }
181                         else if (filename == "-")
182                         {
183                                 filename = "notifications_dump.cfg";
184                                 alsoprint = true;
185                         }
186                         int fh = fopen(filename, FILE_WRITE);
187                         if (fh >= 0)
188                         {
189                                 Dump_Notifications(fh, alsoprint);
190                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
191                                 fclose(fh);
192                         }
193                         else
194                         {
195                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
196                         }
197                         #else
198                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd."));
199                         #endif
200                         return;
201                 }
202                 default:
203                 case CMD_REQUEST_USAGE:
204                 {
205                         LOG_INFO("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]");
206                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),");
207                         LOG_INFO("  if supplied with '-' output to console as well as default,");
208                         LOG_INFO("  if left blank, it will only write to default.");
209                         return;
210                 }
211         }
212 }
213
214 #ifdef NOTIFICATIONS_DEBUG
215 bool autocvar_notification_debug = false;
216 void Debug_Notification(string input)
217 {
218         switch (autocvar_notification_debug)
219         {
220                 case 1: { LOG_TRACE(input); break; }
221                 case 2: { LOG_INFO(input); break; }
222         }
223 }
224 #endif
225
226 void Local_Notification(MSG net_type, Notification net_name, ...count);
227 /** glue for networking, forwards to `Local_Notification` */
228 void Local_Notification_WOVA(
229         MSG net_type, Notification net_name,
230         float stringcount, float floatcount,
231         string s1, string s2, string s3, string s4,
232         float f1, float f2, float f3, float f4);
233
234 #ifdef CSQC
235 string prev_soundfile;
236 float prev_soundtime;
237 #endif
238
239 #ifdef SVQC
240 IntrusiveList g_notifications;
241 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
242 #endif
243
244 #ifdef SVQC
245 ENUMCLASS(NOTIF)
246         /** send to one client and their spectators */
247         CASE(NOTIF, ONE)
248         /** send ONLY to one client */
249         CASE(NOTIF, ONE_ONLY)
250         /** send only to X team and their spectators */
251         CASE(NOTIF, TEAM)
252         /** send only to X team and their spectators, except for Y person and their spectators */
253         CASE(NOTIF, TEAM_EXCEPT)
254         /** send to everyone */
255         CASE(NOTIF, ALL)
256         /** send to everyone except X person and their spectators */
257         CASE(NOTIF, ALL_EXCEPT)
258 ENUMCLASS_END(NOTIF)
259
260 string Get_Notif_BroadcastName(NOTIF broadcast)
261 {
262         switch (broadcast)
263         {
264                 case NOTIF_ONE: return "NOTIF_ONE";
265                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
266                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
267                 case NOTIF_ALL: return "NOTIF_ALL";
268                 case NOTIF_TEAM: return "NOTIF_TEAM";
269                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
270         }
271         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
272         return "";
273 }
274
275 void Kill_Notification(
276         NOTIF broadcast, entity client,
277         MSG net_type, CPID net_name);
278 void Send_Notification(
279         NOTIF broadcast, entity client,
280         MSG net_type, Notification net_name,
281         ...count);
282 void Send_Notification_WOVA(
283         NOTIF broadcast, entity client,
284         MSG net_type, Notification net_name,
285         float stringcount, float floatcount,
286         string s1, string s2, string s3, string s4,
287         float f1, float f2, float f3, float f4);
288 void Send_Notification_WOCOVA(
289         NOTIF broadcast, entity client,
290         MSG net_type, Notification net_name,
291         string s1, string s2, string s3, string s4,
292         float f1, float f2, float f3, float f4);
293 #endif
294
295 // ===========================
296 //  Special CVAR Declarations
297 // ===========================
298
299 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
300 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
301
302 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
303
304 float autocvar_notification_show_location = false;
305 string autocvar_notification_show_location_string = ""; //_(" at the %s");
306 float autocvar_notification_show_sprees = true;
307 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
308 float autocvar_notification_show_sprees_info_newline = true;
309 float autocvar_notification_show_sprees_info_specialonly = true;
310 float autocvar_notification_errors_are_fatal = true;
311 #ifdef SVQC
312 float autocvar_notification_lifetime_runtime = 0.5;
313 float autocvar_notification_lifetime_mapload = 10;
314 #endif
315
316 #ifdef SVQC
317 void Notification_GetCvars(entity this);
318 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
319 #else
320 float autocvar_notification_item_centerprinttime = 1.5;
321
322 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
323 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
324 float autocvar_notification_allow_chatboxprint = 0;
325
326 float autocvar_notification_show_sprees_center = true;
327 float autocvar_notification_show_sprees_center_specialonly = true;
328 #endif
329
330
331 // ============================
332 //  Notification Argument List
333 // ============================
334 /*
335  These arguments get replaced with the Local_Notification_sprintf
336  and other such functions found in all.qc to supply data
337  from networked notifications to their usage in sprintf... It
338  allows for more dynamic data to be inferred by the local
339  notification parser, so that the server does not have to network
340  anything too crazy on a per-client/per-situation basis.
341
342  Pay attention to the CSQC/SVQC relations, some of these are redefined
343  in slightly different ways for different programs, this is because the
344  server does a more conservative approach to the notifs than the client.
345
346  All arguments are swapped into strings, so be sure that your
347  sprintf usage matches with proper %s placement.
348
349  Argument descriptions:
350         s1-s4: string arguments to be literally swapped into sprintf
351         s2loc: s2 string of locations of deaths or other events
352         s3loc: s3 string of locations of deaths or other events
353         f1-f4: float arguments expanded into strings to be swapped into sprintf
354         f1p2dec: f1 float to string with 2 decimal places
355         f2p2dec: f2 float to string with 2 decimal places
356         f2primsec: f2 float primary or secondary selection for weapons
357         f3primsec: f3 float primary or secondary selection for weapons
358         f1secs: count_seconds of f1
359         f1points: point or points depending on f1
360         f1ord: count_ordinal of f1
361         f1time: process_time of f1
362         f1race_time: mmssss of f1
363         f2race_time: mmssss of f2
364         race_col: color of race time/position (i.e. good or bad)
365         race_diff: show time difference between f2 and f3
366         missing_teams: show which teams still need players
367         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
368         nade_key: find the keybind for nade throwing
369         frag_ping: show the ping of a player
370         frag_stats: show health/armor/ping of a player
371         frag_pos: show score status and position in the match of a player
372         spree_cen: centerprint notif for kill spree/how many kills they have
373         spree_inf: info notif for kill spree/how many kills they have
374         spree_end: placed at the end of murder messages to show ending of sprees
375         spree_lost: placed at the end of suicide messages to show losing of sprees
376         item_wepname: return full name of a weapon from weaponid
377         item_wepammo: ammo display for weapon from f1 and f2
378         item_centime: amount of time to display weapon message in centerprint
379         item_buffname: return full name of a buff from buffid
380         death_team: show the full name of the team a player is switching from
381         minigame1_name: return human readable name of a minigame from its id(s1)
382         minigame1_d: return descriptor name of a minigame from its id(s1)
383 */
384
385 const float NOTIF_MAX_ARGS = 7;
386 const float NOTIF_MAX_HUDARGS = 2;
387 const float NOTIF_MAX_DURCNT = 2;
388
389 string arg_slot[NOTIF_MAX_ARGS];
390
391 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
392 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
393 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
394 const float ARG_CS = 4; // unique result to CSQC
395 const float ARG_SV = 5; // unique result to SVQC
396 const float ARG_DC = 6; // unique result to durcnt/centerprint
397
398 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
399 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
400
401 string BUFF_NAME(int i);
402
403 #define NOTIF_ARGUMENT_LIST \
404         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
405         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
406         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
407         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
408         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
409         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
410         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
411         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
412         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
413         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
414         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
415         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
416         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
417         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
418         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
419         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
420         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
421         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
422         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
423         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
424         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
425         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
426         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
427         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
428         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
429         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
430         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
431         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
432         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
433         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
434         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
435         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
436         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
437         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
438         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
439         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
440         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
441         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
442         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
443         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
444         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
445         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
446         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
447
448 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
449         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
450 MACRO_END
451
452 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
453
454 #define KILL_SPREE_LIST \
455         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
456         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
457         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
458         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
459         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
460         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
461         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
462
463 #ifdef CSQC
464 string notif_arg_frag_ping(bool newline, float fping)
465 {
466         string s = newline ? "\n" : " ";
467         if (fping < 0)
468                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
469         else
470                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
471 }
472
473 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
474 {
475         string s = notif_arg_frag_ping(false, fping);
476         if (fhealth > 1)
477                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
478         else
479                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
480 }
481
482 string notif_arg_missing_teams(float f1)
483 {
484         return strcat(
485                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
486                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
487                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
488                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
489         );
490 }
491
492 string notif_arg_spree_cen(float spree)
493 {
494         // 0 = off, 1 = target (but only for first victim) and attacker
495         if(autocvar_notification_show_sprees_center)
496         {
497                 if(spree > 1)
498                 {
499                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
500                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
501
502                         switch(spree)
503                         {
504                                 KILL_SPREE_LIST
505                                 default:
506                                 {
507                                         if (!autocvar_notification_show_sprees_center_specialonly)
508                                         {
509                                                 return
510                                                         sprintf(
511                                                                 normal_or_gentle(
512                                                                         _("%d frag spree! "),
513                                                                         _("%d score spree! ")
514                                                                 ),
515                                                                 spree);
516                                         }
517                                         else { return ""; } // don't show spree information if it isn't an achievement
518                                 }
519                         }
520
521                         #undef SPREE_ITEM
522                 }
523                 else if(spree == -1) // first blood
524                 {
525                         return normal_or_gentle(_("First blood! "), _("First score! "));
526                 }
527                 else if(spree == -2) // first victim
528                 {
529                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
530                 }
531         }
532         return "";
533 }
534 #endif
535
536 string notif_arg_spree_inf(float type, string input, string player, float spree)
537 {
538         switch(type)
539         {
540                 case 1: // attacker kill spree
541                 {
542                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
543                         // this conditional (& 2) is true for 2 and 3
544                         if(autocvar_notification_show_sprees_info & 2)
545                         {
546                                 #ifdef CSQC
547                                 string spree_newline =
548                                         ( autocvar_notification_show_sprees_info_newline ?
549                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
550                                 #else
551                                 string spree_newline =
552                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
553                                 #endif
554
555                                 if(spree > 1)
556                                 {
557                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
558                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
559
560                                         switch(spree)
561                                         {
562                                                 KILL_SPREE_LIST
563                                                 default:
564                                                 {
565                                                         if (!autocvar_notification_show_sprees_info_specialonly)
566                                                         {
567                                                                 return
568                                                                         sprintf(
569                                                                                 CCR(normal_or_gentle(
570                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
571                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
572                                                                                 )),
573                                                                                 player,
574                                                                                 spree,
575                                                                                 spree_newline
576                                                                         );
577                                                         }
578                                                         else { return ""; } // don't show spree information if it isn't an achievement
579                                                 }
580                                         }
581
582                                         #undef SPREE_ITEM
583                                 }
584                                 else if(spree == -1) // firstblood
585                                 {
586                                         return
587                                                 sprintf(
588                                                         CCR(normal_or_gentle(
589                                                                 _("%s^K1 drew first blood! %s^BG"),
590                                                                 _("%s^K1 got the first score! %s^BG")
591                                                         )),
592                                                         player,
593                                                         spree_newline
594                                                 );
595                                 }
596                         }
597                         break;
598                 }
599
600                 case -1: // kill spree ended
601                 {
602                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
603                         {
604                                 return
605                                         sprintf(normal_or_gentle(
606                                                 _(", ending their %d frag spree"),
607                                                 _(", ending their %d score spree")
608                                                 ),
609                                                 spree
610                                         );
611                         }
612                         break;
613                 }
614
615                 case -2: // kill spree lost
616                 {
617                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
618                         {
619                                 return
620                                         sprintf(normal_or_gentle(
621                                                 _(", losing their %d frag spree"),
622                                                 _(", losing their %d score spree")
623                                                 ),
624                                                 spree
625                                         );
626                         }
627                         break;
628                 }
629         }
630         return "";
631 }
632
633 string notif_arg_item_wepammo(float f1, float f2)
634 {
635         string ammoitems = "";
636         Weapon wep = Weapons_from(f1);
637         switch (wep.ammo_type)
638         {
639                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
640                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
641                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
642                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
643                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
644                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
645                 default: return ""; // doesn't use ammo
646         }
647         return sprintf(_(" with %d %s"), f2, ammoitems);
648 }
649
650
651 // ====================================
652 //  Initialization/Create Declarations
653 // ====================================
654
655 // common notification entity values
656 .int nent_default;
657 .bool nent_enabled;
658 .MSG nent_type;
659 .string nent_name;
660 .int nent_stringcount;
661 .int nent_floatcount;
662 .int nent_teamnum;
663
664 // MSG_ANNCE entity values
665 .int nent_channel;
666 .string nent_snd;
667 .float nent_vol;
668 .float nent_position;
669
670 // MSG_INFO and MSG_CENTER entity values
671 .string nent_args; // used by both
672 .string nent_hudargs; // used by info
673 .string nent_icon; // used by info
674 .CPID nent_cpid; // used by center
675 .string nent_durcnt; // used by center
676 .string nent_string; // used by both
677
678 // MSG_MULTI entity values
679 .entity nent_msgannce;
680 .entity nent_msginfo;
681 .entity nent_msgcenter;
682
683 // MSG_CHOICE entity values
684 .float nent_challow_def;
685 .float nent_challow_var;
686 .entity nent_optiona;
687 .entity nent_optionb;
688
689 // networked notification entity values
690 #ifdef SVQC
691 .NOTIF nent_broadcast;
692 #endif
693 .entity nent_client;
694 .MSG nent_net_type;
695 .float nent_net_name;
696 .string nent_strings[4];
697 .float nent_floats[4];
698
699 #define ACVNN(name) autocvar_notification_##name
700
701 REGISTRY(Notifications, BITS(11))
702 REGISTER_REGISTRY(Notifications)
703 REGISTRY_SORT(Notifications);
704 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
705 REGISTRY_CHECK(Notifications)
706
707 const int NOTIF_CHOICE_MAX = 20;
708 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
709 // thus they are counted as 1 in nent_choice_count
710 int nent_choice_count = 0;
711 .int nent_choice_idx;
712 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
713 // initialization error detection
714 bool notif_error;
715 bool notif_global_error;
716
717 STATIC_INIT_LATE(Notif_Choices)
718 {
719         if (nent_choice_count > NOTIF_CHOICE_MAX)
720                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
721                         nent_choice_count, NOTIF_CHOICE_MAX);
722 }
723
724 string Get_Notif_CvarName(Notification notif)
725 {
726         if(!notif.nent_teamnum)
727                 return notif.nent_name;
728         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
729 }
730
731 Notification Get_Notif_Ent(MSG net_type, int net_name)
732 {
733         Notification it = _Notifications_from(net_name, NULL);
734         if (it.nent_type != net_type) {
735                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
736                         Get_Notif_TypeName(net_type), net_type,
737                         it.registered_id, net_name,
738                         Get_Notif_TypeName(it.nent_type)
739                 );
740                 return NULL;
741         }
742         return it;
743 }
744
745 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
746         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position)
747
748 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position) \
749         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
750         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position)
751
752 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
753         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
754                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
755                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
756                         channel,   /* channel  */ \
757                         sound,     /* snd      */ \
758                         volume,    /* vol      */ \
759                         position); /* position */ \
760         }
761
762 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
763         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
764
765 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
766         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
767         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
768
769 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
770         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
771                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
772                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
773                         args,     /* args    */ \
774                         hudargs,  /* hudargs */ \
775                         icon,     /* icon    */ \
776                         CPID_Null,/* cpid    */ \
777                         "",       /* durcnt  */ \
778                         normal,   /* normal  */ \
779                         gentle);  /* gentle  */ \
780         }
781
782 .string nent_iconargs;
783 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
784         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
785 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
786         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
787         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
788                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
789                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
790                         args,     /* args    */ \
791                         hudargs,  /* hudargs */ \
792                         icon,     /* icon    */ \
793                         CPID_Null,/* cpid    */ \
794                         "",       /* durcnt  */ \
795                         normal,   /* normal  */ \
796                         gentle);  /* gentle  */ \
797                 this.nent_iconargs = iconargs; \
798         }
799
800 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
801         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
802
803 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
804         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
805         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
806
807 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
808         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
809                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
810                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
811                         args,    /* args    */ \
812                         "",      /* hudargs */ \
813                         "",      /* icon    */ \
814                         cpid,    /* cpid    */ \
815                         durcnt,  /* durcnt  */ \
816                         normal,  /* normal  */ \
817                         gentle); /* gentle  */ \
818         }
819
820 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
821         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
822         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
823                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
824                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
825                         anncename,   /* anncename  */ \
826                         infoname,    /* infoname   */ \
827                         centername); /* centername */ \
828         }
829
830 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
831         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
832
833 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
834         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
835         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
836         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
837
838 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
839         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
840                 this.nent_choice_idx = nent_choice_count; \
841                 if (!teamnum || teamnum == NUM_TEAM_4) \
842                         nent_choice_count++; \
843                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
844                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
845                         challow,                                 /* challow_def */ \
846                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
847                         chtype,                                  /* chtype      */ \
848                         optiona,                                 /* optiona     */ \
849                         optionb);                                /* optionb     */ \
850         }
851
852 REGISTRY_BEGIN(Notifications)
853 {
854         notif_global_error = false;
855 }
856
857 REGISTRY_END(Notifications)
858 {
859         if (!notif_global_error) return;
860         // shit happened... stop the loading of the program now if this is unacceptable
861         if (autocvar_notification_errors_are_fatal)
862                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
863         else
864                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
865 }
866
867 #ifdef CSQC
868 .int cvar_value;
869 void ReplicateVars(bool would_destroy)
870 {
871         if (!would_destroy)
872                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
873                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
874                         // NOTE: REPLICATE_SIMPLE can return;
875                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
876                 });
877 }
878 #endif
879
880 #include "all.inc"