qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, TIMEIN)
  69         CASE(CPID, VEHICLES)
  70         CASE(CPID, VEHICLES_OTHER)
  71         /** always last */
  72         CASE(CPID, LAST)
  73 ENUMCLASS_END(CPID)
  74
  75 USING(Notification, entity);
  76
  77 // used for notification system multi-team identifiers
  78 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  79 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  80
  81 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  82         VARITEM(1, 0, s1) \
  83         VARITEM(2, 0, XPD(s1, s2)) \
  84         VARITEM(3, 0, XPD(s1, s2, s3)) \
  85         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  86         VARITEM(0, 1, f1) \
  87         VARITEM(1, 1, XPD(s1, f1)) \
  88         VARITEM(2, 1, XPD(s1, s2, f1)) \
  89         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  90         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  91         VARITEM(0, 2, XPD(f1, f2)) \
  92         VARITEM(1, 2, XPD(s1, f1, f2)) \
  93         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  94         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  95         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  96         VARITEM(0, 3, XPD(f1, f2, f3)) \
  97         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  98         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  99         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 100         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 101         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 102         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 103         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 104         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 105         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 106
 107 void Destroy_All_Notifications();
 108 void Create_Notification_Entity(entity notif,
 109         float var_default,
 110         float var_cvar,
 111         MSG typeId,
 112         string namestring);
 113 void Create_Notification_Entity_Annce(entity notif,
 114                                                                                 float var_cvar,
 115                                                                                 string namestring,
 116                                                                                 /* MSG_ANNCE */
 117                                                                                 float channel,
 118                                                                                 string snd,
 119                                                                                 float vol,
 120                                                                                 float position);
 121
 122 void Create_Notification_Entity_InfoCenter(entity notif,
 123                                                                                         float var_cvar,
 124                                                                                         string namestring,
 125                                                                                         int strnum,
 126                                                                                         int flnum,
 127                                                                                         /* MSG_INFO & MSG_CENTER */
 128                                                                                         string args,
 129                                                                                         string hudargs,
 130                                                                                         string icon,
 131                                                                                         CPID cpid,
 132                                                                                         string durcnt,
 133                                                                                         string normal,
 134                                                                                         string gentle);
 135
 136 void Create_Notification_Entity_Multi(entity notif,
 137                                                                                 float var_cvar,
 138                                                                                 string namestring,
 139                                                                                 /* MSG_MULTI */
 140                                                                                 Notification anncename,
 141                                                                                 Notification infoname,
 142                                                                                 Notification centername);
 143
 144 void Create_Notification_Entity_Choice(entity notif,
 145                                                                                 float var_cvar,
 146                                                                                 string namestring,
 147                                                                                 /* MSG_CHOICE */
 148                                                                                 float challow_def,
 149                                                                                 float challow_var,
 150                                                                                 MSG chtype,
 151                                                                                 Notification optiona,
 152                                                                                 Notification optionb);
 153
 154 void Dump_Notifications(int fh, bool alsoprint);
 155
 156 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 157 {
 158         switch (request)
 159         {
 160                 case CMD_REQUEST_COMMAND:
 161                 {
 162                         #ifdef GAMEQC
 163                         string filename = argv(1);
 164                         bool alsoprint = false;
 165                         if (filename == "")
 166                         {
 167                                 filename = "notifications_dump.cfg";
 168                                 alsoprint = false;
 169                         }
 170                         else if (filename == "-")
 171                         {
 172                                 filename = "notifications_dump.cfg";
 173                                 alsoprint = true;
 174                         }
 175                         int fh = fopen(filename, FILE_WRITE);
 176                         if (fh >= 0)
 177                         {
 178                                 Dump_Notifications(fh, alsoprint);
 179                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 180                                 fclose(fh);
 181                         }
 182                         else
 183                         {
 184                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 185                         }
 186                         #else
 187                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 188                         #endif
 189                         return;
 190                 }
 191                 default:
 192                 case CMD_REQUEST_USAGE:
 193                 {
 194                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 195                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 196                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 197                         LOG_INFO("  if left blank, it will only write to default.\n");
 198                         return;
 199                 }
 200         }
 201 }
 202
 203 #ifdef NOTIFICATIONS_DEBUG
 204 bool autocvar_notification_debug = false;
 205 void Debug_Notification(string input)
 206 {
 207         switch (autocvar_notification_debug)
 208         {
 209                 case 1: { LOG_TRACE(input); break; }
 210                 case 2: { LOG_INFO(input); break; }
 211         }
 212 }
 213 #endif
 214
 215 void Local_Notification(MSG net_type, Notification net_name, ...count);
 216 /** glue for networking, forwards to `Local_Notification` */
 217 void Local_Notification_WOVA(
 218         MSG net_type, Notification net_name,
 219         float stringcount, float floatcount,
 220         string s1, string s2, string s3, string s4,
 221         float f1, float f2, float f3, float f4);
 222
 223 #ifdef CSQC
 224 string prev_soundfile;
 225 float prev_soundtime;
 226 #endif
 227
 228 #ifdef SVQC
 229 IntrusiveList g_notifications;
 230 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 231 #endif
 232
 233 #ifdef SVQC
 234 ENUMCLASS(NOTIF)
 235         /** send to one client and their spectators */
 236         CASE(NOTIF, ONE)
 237         /** send ONLY to one client */
 238         CASE(NOTIF, ONE_ONLY)
 239         /** send only to X team and their spectators */
 240         CASE(NOTIF, TEAM)
 241         /** send only to X team and their spectators, except for Y person and their spectators */
 242         CASE(NOTIF, TEAM_EXCEPT)
 243         /** send to everyone */
 244         CASE(NOTIF, ALL)
 245         /** send to everyone except X person and their spectators */
 246         CASE(NOTIF, ALL_EXCEPT)
 247 ENUMCLASS_END(NOTIF)
 248
 249 string Get_Notif_BroadcastName(NOTIF broadcast)
 250 {
 251         switch (broadcast)
 252         {
 253                 case NOTIF_ONE: return "NOTIF_ONE";
 254                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 255                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 256                 case NOTIF_ALL: return "NOTIF_ALL";
 257                 case NOTIF_TEAM: return "NOTIF_TEAM";
 258                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 259         }
 260         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 261         return "";
 262 }
 263
 264 void Kill_Notification(
 265         NOTIF broadcast, entity client,
 266         MSG net_type, CPID net_name);
 267 void Send_Notification(
 268         NOTIF broadcast, entity client,
 269         MSG net_type, Notification net_name,
 270         ...count);
 271 void Send_Notification_WOVA(
 272         NOTIF broadcast, entity client,
 273         MSG net_type, Notification net_name,
 274         float stringcount, float floatcount,
 275         string s1, string s2, string s3, string s4,
 276         float f1, float f2, float f3, float f4);
 277 void Send_Notification_WOCOVA(
 278         NOTIF broadcast, entity client,
 279         MSG net_type, Notification net_name,
 280         string s1, string s2, string s3, string s4,
 281         float f1, float f2, float f3, float f4);
 282 #endif
 283
 284 // ===========================
 285 //  Special CVAR Declarations
 286 // ===========================
 287
 288 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 289 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 290
 291 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 292
 293 float autocvar_notification_show_location = false;
 294 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 295 float autocvar_notification_show_sprees = true;
 296 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 297 float autocvar_notification_show_sprees_info_newline = true;
 298 float autocvar_notification_show_sprees_info_specialonly = true;
 299 float autocvar_notification_errors_are_fatal = true;
 300 #ifdef SVQC
 301 float autocvar_notification_lifetime_runtime = 0.5;
 302 float autocvar_notification_lifetime_mapload = 10;
 303 #endif
 304
 305 #ifdef SVQC
 306 .float FRAG_VERBOSE;
 307 void Notification_GetCvars(entity this);
 308 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 309 #else
 310 float autocvar_notification_item_centerprinttime = 1.5;
 311
 312 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 313 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 314 float autocvar_notification_allow_chatboxprint = 0;
 315
 316 float autocvar_notification_show_sprees_center = true;
 317 float autocvar_notification_show_sprees_center_specialonly = true;
 318 #endif
 319
 320
 321 // ============================
 322 //  Notification Argument List
 323 // ============================
 324 /*
 325  These arguments get replaced with the Local_Notification_sprintf
 326  and other such functions found in all.qc to supply data
 327  from networked notifications to their usage in sprintf... It
 328  allows for more dynamic data to be inferred by the local
 329  notification parser, so that the server does not have to network
 330  anything too crazy on a per-client/per-situation basis.
 331
 332  Pay attention to the CSQC/SVQC relations, some of these are redefined
 333  in slightly different ways for different programs, this is because the
 334  server does a more conservative approach to the notifs than the client.
 335
 336  All arguments are swapped into strings, so be sure that your
 337  sprintf usage matches with proper %s placement.
 338
 339  Argument descriptions:
 340         s1-s4: string arguments to be literally swapped into sprintf
 341         s2loc: s2 string of locations of deaths or other events
 342         s3loc: s3 string of locations of deaths or other events
 343         f1-f4: float arguments expanded into strings to be swapped into sprintf
 344         f1p2dec: f1 float to string with 2 decimal places
 345         f2p2dec: f2 float to string with 2 decimal places
 346         f2primsec: f2 float primary or secondary selection for weapons
 347         f3primsec: f3 float primary or secondary selection for weapons
 348         f1secs: count_seconds of f1
 349         f1points: point or points depending on f1
 350         f1ord: count_ordinal of f1
 351         f1time: process_time of f1
 352         f1race_time: mmssss of f1
 353         f2race_time: mmssss of f2
 354         race_col: color of race time/position (i.e. good or bad)
 355         race_diff: show time difference between f2 and f3
 356         missing_teams: show which teams still need players
 357         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 358         nade_key: find the keybind for nade throwing
 359         frag_ping: show the ping of a player
 360         frag_stats: show health/armor/ping of a player
 361         frag_pos: show score status and position in the match of a player
 362         spree_cen: centerprint notif for kill spree/how many kills they have
 363         spree_inf: info notif for kill spree/how many kills they have
 364         spree_end: placed at the end of murder messages to show ending of sprees
 365         spree_lost: placed at the end of suicide messages to show losing of sprees
 366         item_wepname: return full name of a weapon from weaponid
 367         item_wepammo: ammo display for weapon from string
 368         item_centime: amount of time to display weapon message in centerprint
 369         item_buffname: return full name of a buff from buffid
 370         death_team: show the full name of the team a player is switching from
 371         minigame1_name: return human readable name of a minigame from its id(s1)
 372         minigame1_d: return descriptor name of a minigame from its id(s1)
 373 */
 374
 375 const float NOTIF_MAX_ARGS = 7;
 376 const float NOTIF_MAX_HUDARGS = 2;
 377 const float NOTIF_MAX_DURCNT = 2;
 378
 379 string arg_slot[NOTIF_MAX_ARGS];
 380
 381 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 382 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 383 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 384 const float ARG_CS = 4; // unique result to CSQC
 385 const float ARG_SV = 5; // unique result to SVQC
 386 const float ARG_DC = 6; // unique result to durcnt/centerprint
 387
 388 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 389 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 390
 391 string BUFF_NAME(int i);
 392
 393 #define NOTIF_ARGUMENT_LIST \
 394         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 395         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 396         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 397         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 398         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 399         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 400         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 401         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 402         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 403         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 404         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 405         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 406         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 407         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 408         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 409         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 410         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 411         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 412         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 413         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 414         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 415         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 416         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 417         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 418         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 419         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 420         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 421         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 422         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 423         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 424         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 425         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 426         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 427         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 428         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 429         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 430         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 431         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 432         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 433         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 434         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 435         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 436
 437 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 438         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 439 } MACRO_END
 440 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 441
 442 #define KILL_SPREE_LIST \
 443         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 444         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 445         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 446         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 447         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 448         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 449         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 450
 451 #ifdef CSQC
 452 string notif_arg_frag_ping(bool newline, float fping)
 453 {
 454         string s = newline ? "\n" : " ";
 455         if (fping < 0)
 456                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 457         else
 458                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 459 }
 460
 461 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 462 {
 463         string s = notif_arg_frag_ping(false, fping);
 464         if (fhealth > 1)
 465                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 466         else
 467                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 468 }
 469
 470 string notif_arg_missing_teams(float f1)
 471 {
 472         return sprintf("%s%s%s%s",
 473                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 474                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 475                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 476                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 477         );
 478 }
 479
 480 string notif_arg_spree_cen(float spree)
 481 {
 482         // 0 = off, 1 = target (but only for first victim) and attacker
 483         if(autocvar_notification_show_sprees_center)
 484         {
 485                 if(spree > 1)
 486                 {
 487                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 488                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 489
 490                         switch(spree)
 491                         {
 492                                 KILL_SPREE_LIST
 493                                 default:
 494                                 {
 495                                         if (!autocvar_notification_show_sprees_center_specialonly)
 496                                         {
 497                                                 return
 498                                                         sprintf(
 499                                                                 normal_or_gentle(
 500                                                                         _("%d frag spree! "),
 501                                                                         _("%d score spree! ")
 502                                                                 ),
 503                                                                 spree);
 504                                         }
 505                                         else { return ""; } // don't show spree information if it isn't an achievement
 506                                 }
 507                         }
 508
 509                         #undef SPREE_ITEM
 510                 }
 511                 else if(spree == -1) // first blood
 512                 {
 513                         return normal_or_gentle(_("First blood! "), _("First score! "));
 514                 }
 515                 else if(spree == -2) // first victim
 516                 {
 517                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 518                 }
 519         }
 520         return "";
 521 }
 522 #endif
 523
 524 string notif_arg_spree_inf(float type, string input, string player, float spree)
 525 {
 526         switch(type)
 527         {
 528                 case 1: // attacker kill spree
 529                 {
 530                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 531                         // this conditional (& 2) is true for 2 and 3
 532                         if(autocvar_notification_show_sprees_info & 2)
 533                         {
 534                                 #ifdef CSQC
 535                                 string spree_newline =
 536                                         ( autocvar_notification_show_sprees_info_newline ?
 537                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 538                                 #else
 539                                 string spree_newline =
 540                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 541                                 #endif
 542
 543                                 if(spree > 1)
 544                                 {
 545                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 546                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 547
 548                                         switch(spree)
 549                                         {
 550                                                 KILL_SPREE_LIST
 551                                                 default:
 552                                                 {
 553                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 554                                                         {
 555                                                                 return
 556                                                                         sprintf(
 557                                                                                 CCR(normal_or_gentle(
 558                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 559                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 560                                                                                 )),
 561                                                                                 player,
 562                                                                                 spree,
 563                                                                                 spree_newline
 564                                                                         );
 565                                                         }
 566                                                         else { return ""; } // don't show spree information if it isn't an achievement
 567                                                 }
 568                                         }
 569
 570                                         #undef SPREE_ITEM
 571                                 }
 572                                 else if(spree == -1) // firstblood
 573                                 {
 574                                         return
 575                                                 sprintf(
 576                                                         CCR(normal_or_gentle(
 577                                                                 _("%s^K1 drew first blood! %s^BG"),
 578                                                                 _("%s^K1 got the first score! %s^BG")
 579                                                         )),
 580                                                         player,
 581                                                         spree_newline
 582                                                 );
 583                                 }
 584                         }
 585                         break;
 586                 }
 587
 588                 case -1: // kill spree ended
 589                 {
 590                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 591                         {
 592                                 return
 593                                         sprintf(normal_or_gentle(
 594                                                 _(", ending their %d frag spree"),
 595                                                 _(", ending their %d score spree")
 596                                                 ),
 597                                                 spree
 598                                         );
 599                         }
 600                         break;
 601                 }
 602
 603                 case -2: // kill spree lost
 604                 {
 605                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 606                         {
 607                                 return
 608                                         sprintf(normal_or_gentle(
 609                                                 _(", losing their %d frag spree"),
 610                                                 _(", losing their %d score spree")
 611                                                 ),
 612                                                 spree
 613                                         );
 614                         }
 615                         break;
 616                 }
 617         }
 618         return "";
 619 }
 620
 621
 622 // ====================================
 623 //  Initialization/Create Declarations
 624 // ====================================
 625
 626 // common notification entity values
 627 .int nent_default;
 628 .bool nent_enabled;
 629 .MSG nent_type;
 630 .string nent_name;
 631 .int nent_stringcount;
 632 .int nent_floatcount;
 633
 634 // MSG_ANNCE entity values
 635 .int nent_channel;
 636 .string nent_snd;
 637 .float nent_vol;
 638 .float nent_position;
 639
 640 // MSG_INFO and MSG_CENTER entity values
 641 .string nent_args; // used by both
 642 .string nent_hudargs; // used by info
 643 .string nent_icon; // used by info
 644 .CPID nent_cpid; // used by center
 645 .string nent_durcnt; // used by center
 646 .string nent_string; // used by both
 647
 648 // MSG_MULTI entity values
 649 .entity nent_msgannce;
 650 .entity nent_msginfo;
 651 .entity nent_msgcenter;
 652
 653 // MSG_CHOICE entity values
 654 .float nent_challow_def;
 655 .float nent_challow_var;
 656 .entity nent_optiona;
 657 .entity nent_optionb;
 658
 659 // networked notification entity values
 660 #ifdef SVQC
 661 .NOTIF nent_broadcast;
 662 #endif
 663 .entity nent_client;
 664 .MSG nent_net_type;
 665 .float nent_net_name;
 666 .string nent_strings[4];
 667 .float nent_floats[4];
 668
 669 #define ACVNN(name) autocvar_notification_##name
 670
 671 REGISTRY(Notifications, BITS(11))
 672 REGISTER_REGISTRY(Notifications)
 673 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 674 REGISTRY_CHECK(Notifications)
 675
 676 const int NOTIF_CHOICE_MAX = 50;
 677 int nent_choice_count = 0;
 678 .int nent_choice_idx;
 679 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 680 // initialization error detection
 681 bool notif_error;
 682 bool notif_global_error;
 683
 684 STATIC_INIT_LATE(Notif_Choices) {
 685         int c = 0;
 686         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 687         if (c > NOTIF_CHOICE_MAX) {
 688                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 689         }
 690 }
 691
 692 Notification Get_Notif_Ent(MSG net_type, int net_name)
 693 {
 694         Notification it = _Notifications_from(net_name, NULL);
 695         if (it.nent_type != net_type) {
 696                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 697                         Get_Notif_TypeName(net_type), net_type,
 698                         it.registered_id, net_name,
 699                         Get_Notif_TypeName(it.nent_type)
 700                 );
 701                 return NULL;
 702         }
 703         return it;
 704 }
 705
 706 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 707         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 708 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 709         NOTIF_ADD_AUTOCVAR(name, default) \
 710         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 711                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, strtoupper(#name)); \
 712                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 713                         channel,   /* channel  */ \
 714                         sound,     /* snd      */ \
 715                         volume,    /* vol      */ \
 716                         position); /* position */ \
 717         }
 718
 719 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 720         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 721 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 722         NOTIF_ADD_AUTOCVAR(name, default) \
 723         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 724                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 725                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 726                         args,     /* args    */ \
 727                         hudargs,  /* hudargs */ \
 728                         icon,     /* icon    */ \
 729                         CPID_Null,/* cpid    */ \
 730                         "",       /* durcnt  */ \
 731                         normal,   /* normal  */ \
 732                         gentle);  /* gentle  */ \
 733         }
 734
 735 .string nent_iconargs;
 736 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 737         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 738 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 739         NOTIF_ADD_AUTOCVAR(name, default) \
 740         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 741                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 742                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 743                         args,     /* args    */ \
 744                         hudargs,  /* hudargs */ \
 745                         icon,     /* icon    */ \
 746                         CPID_Null,/* cpid    */ \
 747                         "",       /* durcnt  */ \
 748                         normal,   /* normal  */ \
 749                         gentle);  /* gentle  */ \
 750                 this.nent_iconargs = iconargs; \
 751         }
 752
 753 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 754         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 755 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 756         NOTIF_ADD_AUTOCVAR(name, default) \
 757         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 758                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, strtoupper(#name)); \
 759                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 760                         args,    /* args    */ \
 761                         "",      /* hudargs */ \
 762                         "",      /* icon    */ \
 763                         cpid,    /* cpid    */ \
 764                         durcnt,  /* durcnt  */ \
 765                         normal,  /* normal  */ \
 766                         gentle); /* gentle  */ \
 767         }
 768
 769 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 770         NOTIF_ADD_AUTOCVAR(name, default) \
 771         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 772                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name)); \
 773                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 774                         anncename,   /* anncename  */ \
 775                         infoname,    /* infoname   */ \
 776                         centername); /* centername */ \
 777         }
 778
 779 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 780         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 781 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 782         NOTIF_ADD_AUTOCVAR(name, default) \
 783         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 784         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 785                 this.nent_choice_idx = nent_choice_count++; \
 786                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, strtoupper(#name)); \
 787                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 788                         challow,                                 /* challow_def */ \
 789                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 790                         chtype,                                  /* chtype      */ \
 791                         optiona,                                 /* optiona     */ \
 792                         optionb);                                /* optionb     */ \
 793         }
 794
 795 REGISTRY_BEGIN(Notifications)
 796 {
 797         notif_global_error = false;
 798 }
 799
 800 REGISTRY_END(Notifications)
 801 {
 802         if (!notif_global_error) return;
 803         // shit happened... stop the loading of the program now if this is unacceptable
 804         if (autocvar_notification_errors_are_fatal)
 805                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 806         else
 807                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 808 }
 809
 810 #include "all.inc"