qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, TIMEIN)
  69         CASE(CPID, VEHICLES)
  70         CASE(CPID, VEHICLES_OTHER)
  71         /** always last */
  72         CASE(CPID, LAST)
  73 ENUMCLASS_END(CPID)
  74
  75 USING(Notification, entity);
  76
  77 // used for notification system multi-team identifiers
  78 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  79 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  80
  81 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  82         VARITEM(1, 0, s1) \
  83         VARITEM(2, 0, XPD(s1, s2)) \
  84         VARITEM(3, 0, XPD(s1, s2, s3)) \
  85         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  86         VARITEM(0, 1, f1) \
  87         VARITEM(1, 1, XPD(s1, f1)) \
  88         VARITEM(2, 1, XPD(s1, s2, f1)) \
  89         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  90         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  91         VARITEM(0, 2, XPD(f1, f2)) \
  92         VARITEM(1, 2, XPD(s1, f1, f2)) \
  93         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  94         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  95         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  96         VARITEM(0, 3, XPD(f1, f2, f3)) \
  97         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  98         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  99         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 100         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 101         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 102         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 103         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 104         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 105         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 106
 107 void Destroy_All_Notifications();
 108 void Create_Notification_Entity(entity notif,
 109         float var_default,
 110         float var_cvar,
 111         MSG typeId,
 112         string namestring,
 113         int teamnum);
 114 void Create_Notification_Entity_Annce(entity notif,
 115                                                                                 float var_cvar,
 116                                                                                 string namestring,
 117                                                                                 /* MSG_ANNCE */
 118                                                                                 float channel,
 119                                                                                 string snd,
 120                                                                                 float vol,
 121                                                                                 float position);
 122
 123 void Create_Notification_Entity_InfoCenter(entity notif,
 124                                                                                         float var_cvar,
 125                                                                                         string namestring,
 126                                                                                         int strnum,
 127                                                                                         int flnum,
 128                                                                                         /* MSG_INFO & MSG_CENTER */
 129                                                                                         string args,
 130                                                                                         string hudargs,
 131                                                                                         string icon,
 132                                                                                         CPID cpid,
 133                                                                                         string durcnt,
 134                                                                                         string normal,
 135                                                                                         string gentle);
 136
 137 void Create_Notification_Entity_Multi(entity notif,
 138                                                                                 float var_cvar,
 139                                                                                 string namestring,
 140                                                                                 /* MSG_MULTI */
 141                                                                                 Notification anncename,
 142                                                                                 Notification infoname,
 143                                                                                 Notification centername);
 144
 145 void Create_Notification_Entity_Choice(entity notif,
 146                                                                                 float var_cvar,
 147                                                                                 string namestring,
 148                                                                                 /* MSG_CHOICE */
 149                                                                                 float challow_def,
 150                                                                                 float challow_var,
 151                                                                                 MSG chtype,
 152                                                                                 Notification optiona,
 153                                                                                 Notification optionb);
 154
 155 void Dump_Notifications(int fh, bool alsoprint);
 156
 157 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 158 {
 159         switch (request)
 160         {
 161                 case CMD_REQUEST_COMMAND:
 162                 {
 163                         #ifdef GAMEQC
 164                         string filename = argv(1);
 165                         bool alsoprint = false;
 166                         if (filename == "")
 167                         {
 168                                 filename = "notifications_dump.cfg";
 169                                 alsoprint = false;
 170                         }
 171                         else if (filename == "-")
 172                         {
 173                                 filename = "notifications_dump.cfg";
 174                                 alsoprint = true;
 175                         }
 176                         int fh = fopen(filename, FILE_WRITE);
 177                         if (fh >= 0)
 178                         {
 179                                 Dump_Notifications(fh, alsoprint);
 180                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 181                                 fclose(fh);
 182                         }
 183                         else
 184                         {
 185                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 186                         }
 187                         #else
 188                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 189                         #endif
 190                         return;
 191                 }
 192                 default:
 193                 case CMD_REQUEST_USAGE:
 194                 {
 195                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 196                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 197                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 198                         LOG_INFO("  if left blank, it will only write to default.\n");
 199                         return;
 200                 }
 201         }
 202 }
 203
 204 #ifdef NOTIFICATIONS_DEBUG
 205 bool autocvar_notification_debug = false;
 206 void Debug_Notification(string input)
 207 {
 208         switch (autocvar_notification_debug)
 209         {
 210                 case 1: { LOG_TRACE(input); break; }
 211                 case 2: { LOG_INFO(input); break; }
 212         }
 213 }
 214 #endif
 215
 216 void Local_Notification(MSG net_type, Notification net_name, ...count);
 217 /** glue for networking, forwards to `Local_Notification` */
 218 void Local_Notification_WOVA(
 219         MSG net_type, Notification net_name,
 220         float stringcount, float floatcount,
 221         string s1, string s2, string s3, string s4,
 222         float f1, float f2, float f3, float f4);
 223
 224 #ifdef CSQC
 225 string prev_soundfile;
 226 float prev_soundtime;
 227 #endif
 228
 229 #ifdef SVQC
 230 IntrusiveList g_notifications;
 231 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 232 #endif
 233
 234 #ifdef SVQC
 235 ENUMCLASS(NOTIF)
 236         /** send to one client and their spectators */
 237         CASE(NOTIF, ONE)
 238         /** send ONLY to one client */
 239         CASE(NOTIF, ONE_ONLY)
 240         /** send only to X team and their spectators */
 241         CASE(NOTIF, TEAM)
 242         /** send only to X team and their spectators, except for Y person and their spectators */
 243         CASE(NOTIF, TEAM_EXCEPT)
 244         /** send to everyone */
 245         CASE(NOTIF, ALL)
 246         /** send to everyone except X person and their spectators */
 247         CASE(NOTIF, ALL_EXCEPT)
 248 ENUMCLASS_END(NOTIF)
 249
 250 string Get_Notif_BroadcastName(NOTIF broadcast)
 251 {
 252         switch (broadcast)
 253         {
 254                 case NOTIF_ONE: return "NOTIF_ONE";
 255                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 256                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 257                 case NOTIF_ALL: return "NOTIF_ALL";
 258                 case NOTIF_TEAM: return "NOTIF_TEAM";
 259                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 260         }
 261         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 262         return "";
 263 }
 264
 265 void Kill_Notification(
 266         NOTIF broadcast, entity client,
 267         MSG net_type, CPID net_name);
 268 void Send_Notification(
 269         NOTIF broadcast, entity client,
 270         MSG net_type, Notification net_name,
 271         ...count);
 272 void Send_Notification_WOVA(
 273         NOTIF broadcast, entity client,
 274         MSG net_type, Notification net_name,
 275         float stringcount, float floatcount,
 276         string s1, string s2, string s3, string s4,
 277         float f1, float f2, float f3, float f4);
 278 void Send_Notification_WOCOVA(
 279         NOTIF broadcast, entity client,
 280         MSG net_type, Notification net_name,
 281         string s1, string s2, string s3, string s4,
 282         float f1, float f2, float f3, float f4);
 283 #endif
 284
 285 // ===========================
 286 //  Special CVAR Declarations
 287 // ===========================
 288
 289 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 290 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 291
 292 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 293
 294 float autocvar_notification_show_location = false;
 295 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 296 float autocvar_notification_show_sprees = true;
 297 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 298 float autocvar_notification_show_sprees_info_newline = true;
 299 float autocvar_notification_show_sprees_info_specialonly = true;
 300 float autocvar_notification_errors_are_fatal = true;
 301 #ifdef SVQC
 302 float autocvar_notification_lifetime_runtime = 0.5;
 303 float autocvar_notification_lifetime_mapload = 10;
 304 #endif
 305
 306 #ifdef SVQC
 307 .float FRAG_VERBOSE;
 308 void Notification_GetCvars(entity this);
 309 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 310 #else
 311 float autocvar_notification_item_centerprinttime = 1.5;
 312
 313 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 314 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 315 float autocvar_notification_allow_chatboxprint = 0;
 316
 317 float autocvar_notification_show_sprees_center = true;
 318 float autocvar_notification_show_sprees_center_specialonly = true;
 319 #endif
 320
 321
 322 // ============================
 323 //  Notification Argument List
 324 // ============================
 325 /*
 326  These arguments get replaced with the Local_Notification_sprintf
 327  and other such functions found in all.qc to supply data
 328  from networked notifications to their usage in sprintf... It
 329  allows for more dynamic data to be inferred by the local
 330  notification parser, so that the server does not have to network
 331  anything too crazy on a per-client/per-situation basis.
 332
 333  Pay attention to the CSQC/SVQC relations, some of these are redefined
 334  in slightly different ways for different programs, this is because the
 335  server does a more conservative approach to the notifs than the client.
 336
 337  All arguments are swapped into strings, so be sure that your
 338  sprintf usage matches with proper %s placement.
 339
 340  Argument descriptions:
 341         s1-s4: string arguments to be literally swapped into sprintf
 342         s2loc: s2 string of locations of deaths or other events
 343         s3loc: s3 string of locations of deaths or other events
 344         f1-f4: float arguments expanded into strings to be swapped into sprintf
 345         f1p2dec: f1 float to string with 2 decimal places
 346         f2p2dec: f2 float to string with 2 decimal places
 347         f2primsec: f2 float primary or secondary selection for weapons
 348         f3primsec: f3 float primary or secondary selection for weapons
 349         f1secs: count_seconds of f1
 350         f1points: point or points depending on f1
 351         f1ord: count_ordinal of f1
 352         f1time: process_time of f1
 353         f1race_time: mmssss of f1
 354         f2race_time: mmssss of f2
 355         race_col: color of race time/position (i.e. good or bad)
 356         race_diff: show time difference between f2 and f3
 357         missing_teams: show which teams still need players
 358         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 359         nade_key: find the keybind for nade throwing
 360         frag_ping: show the ping of a player
 361         frag_stats: show health/armor/ping of a player
 362         frag_pos: show score status and position in the match of a player
 363         spree_cen: centerprint notif for kill spree/how many kills they have
 364         spree_inf: info notif for kill spree/how many kills they have
 365         spree_end: placed at the end of murder messages to show ending of sprees
 366         spree_lost: placed at the end of suicide messages to show losing of sprees
 367         item_wepname: return full name of a weapon from weaponid
 368         item_wepammo: ammo display for weapon from string
 369         item_centime: amount of time to display weapon message in centerprint
 370         item_buffname: return full name of a buff from buffid
 371         death_team: show the full name of the team a player is switching from
 372         minigame1_name: return human readable name of a minigame from its id(s1)
 373         minigame1_d: return descriptor name of a minigame from its id(s1)
 374 */
 375
 376 const float NOTIF_MAX_ARGS = 7;
 377 const float NOTIF_MAX_HUDARGS = 2;
 378 const float NOTIF_MAX_DURCNT = 2;
 379
 380 string arg_slot[NOTIF_MAX_ARGS];
 381
 382 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 383 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 384 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 385 const float ARG_CS = 4; // unique result to CSQC
 386 const float ARG_SV = 5; // unique result to SVQC
 387 const float ARG_DC = 6; // unique result to durcnt/centerprint
 388
 389 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 390 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 391
 392 string BUFF_NAME(int i);
 393
 394 #define NOTIF_ARGUMENT_LIST \
 395         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 396         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 397         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 398         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 399         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 400         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 401         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 402         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 403         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 404         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 405         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 406         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 407         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 408         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 409         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 410         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 411         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 412         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 413         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 414         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 415         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 416         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 417         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 418         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 419         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 420         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 421         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 422         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 423         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 424         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 425         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 426         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 427         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 428         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 429         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 430         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 431         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 432         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 433         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 434         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 435         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 436         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 437
 438 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 439         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 440 } MACRO_END
 441 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 442
 443 #define KILL_SPREE_LIST \
 444         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 445         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 446         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 447         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 448         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 449         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 450         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 451
 452 #ifdef CSQC
 453 string notif_arg_frag_ping(bool newline, float fping)
 454 {
 455         string s = newline ? "\n" : " ";
 456         if (fping < 0)
 457                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 458         else
 459                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 460 }
 461
 462 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 463 {
 464         string s = notif_arg_frag_ping(false, fping);
 465         if (fhealth > 1)
 466                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 467         else
 468                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 469 }
 470
 471 string notif_arg_missing_teams(float f1)
 472 {
 473         return strcat(
 474                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 475                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 476                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 477                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 478         );
 479 }
 480
 481 string notif_arg_spree_cen(float spree)
 482 {
 483         // 0 = off, 1 = target (but only for first victim) and attacker
 484         if(autocvar_notification_show_sprees_center)
 485         {
 486                 if(spree > 1)
 487                 {
 488                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 489                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 490
 491                         switch(spree)
 492                         {
 493                                 KILL_SPREE_LIST
 494                                 default:
 495                                 {
 496                                         if (!autocvar_notification_show_sprees_center_specialonly)
 497                                         {
 498                                                 return
 499                                                         sprintf(
 500                                                                 normal_or_gentle(
 501                                                                         _("%d frag spree! "),
 502                                                                         _("%d score spree! ")
 503                                                                 ),
 504                                                                 spree);
 505                                         }
 506                                         else { return ""; } // don't show spree information if it isn't an achievement
 507                                 }
 508                         }
 509
 510                         #undef SPREE_ITEM
 511                 }
 512                 else if(spree == -1) // first blood
 513                 {
 514                         return normal_or_gentle(_("First blood! "), _("First score! "));
 515                 }
 516                 else if(spree == -2) // first victim
 517                 {
 518                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 519                 }
 520         }
 521         return "";
 522 }
 523 #endif
 524
 525 string notif_arg_spree_inf(float type, string input, string player, float spree)
 526 {
 527         switch(type)
 528         {
 529                 case 1: // attacker kill spree
 530                 {
 531                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 532                         // this conditional (& 2) is true for 2 and 3
 533                         if(autocvar_notification_show_sprees_info & 2)
 534                         {
 535                                 #ifdef CSQC
 536                                 string spree_newline =
 537                                         ( autocvar_notification_show_sprees_info_newline ?
 538                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 539                                 #else
 540                                 string spree_newline =
 541                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 542                                 #endif
 543
 544                                 if(spree > 1)
 545                                 {
 546                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 547                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 548
 549                                         switch(spree)
 550                                         {
 551                                                 KILL_SPREE_LIST
 552                                                 default:
 553                                                 {
 554                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 555                                                         {
 556                                                                 return
 557                                                                         sprintf(
 558                                                                                 CCR(normal_or_gentle(
 559                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 560                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 561                                                                                 )),
 562                                                                                 player,
 563                                                                                 spree,
 564                                                                                 spree_newline
 565                                                                         );
 566                                                         }
 567                                                         else { return ""; } // don't show spree information if it isn't an achievement
 568                                                 }
 569                                         }
 570
 571                                         #undef SPREE_ITEM
 572                                 }
 573                                 else if(spree == -1) // firstblood
 574                                 {
 575                                         return
 576                                                 sprintf(
 577                                                         CCR(normal_or_gentle(
 578                                                                 _("%s^K1 drew first blood! %s^BG"),
 579                                                                 _("%s^K1 got the first score! %s^BG")
 580                                                         )),
 581                                                         player,
 582                                                         spree_newline
 583                                                 );
 584                                 }
 585                         }
 586                         break;
 587                 }
 588
 589                 case -1: // kill spree ended
 590                 {
 591                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 592                         {
 593                                 return
 594                                         sprintf(normal_or_gentle(
 595                                                 _(", ending their %d frag spree"),
 596                                                 _(", ending their %d score spree")
 597                                                 ),
 598                                                 spree
 599                                         );
 600                         }
 601                         break;
 602                 }
 603
 604                 case -2: // kill spree lost
 605                 {
 606                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 607                         {
 608                                 return
 609                                         sprintf(normal_or_gentle(
 610                                                 _(", losing their %d frag spree"),
 611                                                 _(", losing their %d score spree")
 612                                                 ),
 613                                                 spree
 614                                         );
 615                         }
 616                         break;
 617                 }
 618         }
 619         return "";
 620 }
 621
 622
 623 // ====================================
 624 //  Initialization/Create Declarations
 625 // ====================================
 626
 627 // common notification entity values
 628 .int nent_default;
 629 .bool nent_enabled;
 630 .MSG nent_type;
 631 .string nent_name;
 632 .int nent_stringcount;
 633 .int nent_floatcount;
 634 .int nent_teamnum;
 635
 636 // MSG_ANNCE entity values
 637 .int nent_channel;
 638 .string nent_snd;
 639 .float nent_vol;
 640 .float nent_position;
 641
 642 // MSG_INFO and MSG_CENTER entity values
 643 .string nent_args; // used by both
 644 .string nent_hudargs; // used by info
 645 .string nent_icon; // used by info
 646 .CPID nent_cpid; // used by center
 647 .string nent_durcnt; // used by center
 648 .string nent_string; // used by both
 649
 650 // MSG_MULTI entity values
 651 .entity nent_msgannce;
 652 .entity nent_msginfo;
 653 .entity nent_msgcenter;
 654
 655 // MSG_CHOICE entity values
 656 .float nent_challow_def;
 657 .float nent_challow_var;
 658 .entity nent_optiona;
 659 .entity nent_optionb;
 660
 661 // networked notification entity values
 662 #ifdef SVQC
 663 .NOTIF nent_broadcast;
 664 #endif
 665 .entity nent_client;
 666 .MSG nent_net_type;
 667 .float nent_net_name;
 668 .string nent_strings[4];
 669 .float nent_floats[4];
 670
 671 #define ACVNN(name) autocvar_notification_##name
 672
 673 REGISTRY(Notifications, BITS(11))
 674 REGISTER_REGISTRY(Notifications)
 675 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 676 REGISTRY_CHECK(Notifications)
 677
 678 const int NOTIF_CHOICE_MAX = 50;
 679 int nent_choice_count = 0;
 680 .int nent_choice_idx;
 681 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 682 // initialization error detection
 683 bool notif_error;
 684 bool notif_global_error;
 685
 686 STATIC_INIT_LATE(Notif_Choices) {
 687         int c = 0;
 688         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 689         if (c > NOTIF_CHOICE_MAX) {
 690                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 691         }
 692 }
 693
 694 string Get_Notif_CvarName(Notification notif)
 695 {
 696         if(!notif.nent_teamnum)
 697                 return notif.nent_name;
 698         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 699 }
 700
 701 Notification Get_Notif_Ent(MSG net_type, int net_name)
 702 {
 703         Notification it = _Notifications_from(net_name, NULL);
 704         if (it.nent_type != net_type) {
 705                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 706                         Get_Notif_TypeName(net_type), net_type,
 707                         it.registered_id, net_name,
 708                         Get_Notif_TypeName(it.nent_type)
 709                 );
 710                 return NULL;
 711         }
 712         return it;
 713 }
 714
 715 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, default, sound, channel, volume, position) \
 716         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, default, sound, channel, volume, position)
 717
 718 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 719         NOTIF_ADD_AUTOCVAR(ANNCE_##name, default) \
 720         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, default, sound, channel, volume, position)
 721
 722 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, default, sound, channel, volume, position) \
 723         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 724                 Create_Notification_Entity      (this, default, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 725                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 726                         channel,   /* channel  */ \
 727                         sound,     /* snd      */ \
 728                         volume,    /* vol      */ \
 729                         position); /* position */ \
 730         }
 731
 732 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 733         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 734
 735 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 736         NOTIF_ADD_AUTOCVAR(INFO_##name, default) \
 737         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 738
 739 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 740         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 741                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 742                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 743                         args,     /* args    */ \
 744                         hudargs,  /* hudargs */ \
 745                         icon,     /* icon    */ \
 746                         CPID_Null,/* cpid    */ \
 747                         "",       /* durcnt  */ \
 748                         normal,   /* normal  */ \
 749                         gentle);  /* gentle  */ \
 750         }
 751
 752 .string nent_iconargs;
 753 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 754         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 755 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 756         NOTIF_ADD_AUTOCVAR(name, default) \
 757         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 758                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 759                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 760                         args,     /* args    */ \
 761                         hudargs,  /* hudargs */ \
 762                         icon,     /* icon    */ \
 763                         CPID_Null,/* cpid    */ \
 764                         "",       /* durcnt  */ \
 765                         normal,   /* normal  */ \
 766                         gentle);  /* gentle  */ \
 767                 this.nent_iconargs = iconargs; \
 768         }
 769
 770 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 771         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 772
 773 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 774         NOTIF_ADD_AUTOCVAR(CENTER_##name, default) \
 775         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 776
 777 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 778         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 779                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 780                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 781                         args,    /* args    */ \
 782                         "",      /* hudargs */ \
 783                         "",      /* icon    */ \
 784                         cpid,    /* cpid    */ \
 785                         durcnt,  /* durcnt  */ \
 786                         normal,  /* normal  */ \
 787                         gentle); /* gentle  */ \
 788         }
 789
 790 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 791         NOTIF_ADD_AUTOCVAR(name, default) \
 792         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 793                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 794                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 795                         anncename,   /* anncename  */ \
 796                         infoname,    /* infoname   */ \
 797                         centername); /* centername */ \
 798         }
 799
 800 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 801         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, default, challow, chtype, optiona, optionb)
 802
 803 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 804         NOTIF_ADD_AUTOCVAR(CHOICE_##name, default) \
 805         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 806         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, default, challow, chtype, optiona, optionb)
 807
 808 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 809         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 810                 this.nent_choice_idx = nent_choice_count++; \
 811                 Create_Notification_Entity       (this, default, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 812                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 813                         challow,                                 /* challow_def */ \
 814                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 815                         chtype,                                  /* chtype      */ \
 816                         optiona,                                 /* optiona     */ \
 817                         optionb);                                /* optionb     */ \
 818         }
 819
 820 REGISTRY_BEGIN(Notifications)
 821 {
 822         notif_global_error = false;
 823 }
 824
 825 REGISTRY_END(Notifications)
 826 {
 827         if (!notif_global_error) return;
 828         // shit happened... stop the loading of the program now if this is unacceptable
 829         if (autocvar_notification_errors_are_fatal)
 830                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 831         else
 832                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 833 }
 834
 835 #include "all.inc"