qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 #ifdef CSQC
  10 #include <client/autocvars.qh>
  11 #endif
  12
  13 /** main types/groups of notifications */
  14 ENUMCLASS(MSG)
  15         /** "Global" AND "personal" announcer messages */
  16         CASE(MSG, ANNCE)
  17         /** "Global" information messages */
  18         CASE(MSG, INFO)
  19         /** "Personal" centerprint messages */
  20         CASE(MSG, CENTER)
  21         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  22         CASE(MSG, MULTI)
  23         /** Choose which subcall wrapper to activate */
  24         CASE(MSG, CHOICE)
  25         /** Kill centerprint message @deprecated */
  26         CASE(MSG, CENTER_KILL)
  27 ENUMCLASS_END(MSG)
  28
  29 string Get_Notif_TypeName(MSG net_type)
  30 {
  31         switch (net_type)
  32         {
  33                 case MSG_ANNCE: return "MSG_ANNCE";
  34                 case MSG_INFO: return "MSG_INFO";
  35                 case MSG_CENTER: return "MSG_CENTER";
  36                 case MSG_MULTI: return "MSG_MULTI";
  37                 case MSG_CHOICE: return "MSG_CHOICE";
  38         }
  39         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  40         return "";
  41 }
  42
  43 ENUMCLASS(CPID)
  44         CASE(CPID, ASSAULT_ROLE)
  45         CASE(CPID, ROUND)
  46         CASE(CPID, CAMPCHECK)
  47         CASE(CPID, CTF_CAPSHIELD)
  48         CASE(CPID, CTF_LOWPRIO)
  49         CASE(CPID, CTF_PASS)
  50         CASE(CPID, STALEMATE)
  51         CASE(CPID, NADES)
  52         CASE(CPID, IDLING)
  53         CASE(CPID, ITEM)
  54         CASE(CPID, PREVENT_JOIN)
  55         CASE(CPID, KEEPAWAY)
  56         CASE(CPID, KEEPAWAY_WARN)
  57         CASE(CPID, KEYHUNT)
  58         CASE(CPID, KEYHUNT_OTHER)
  59         CASE(CPID, LMS)
  60         CASE(CPID, MISSING_TEAMS)
  61         CASE(CPID, MISSING_PLAYERS)
  62         CASE(CPID, INSTAGIB_FINDAMMO)
  63         CASE(CPID, MOTD)
  64         CASE(CPID, NIX)
  65         CASE(CPID, ONSLAUGHT)
  66         CASE(CPID, ONS_CAPSHIELD)
  67         CASE(CPID, OVERTIME)
  68         CASE(CPID, POWERUP)
  69         CASE(CPID, RACE_FINISHLAP)
  70         CASE(CPID, TEAMCHANGE)
  71         CASE(CPID, TIMEOUT)
  72         CASE(CPID, TIMEIN)
  73         CASE(CPID, VEHICLES)
  74         CASE(CPID, VEHICLES_OTHER)
  75         /** always last */
  76         CASE(CPID, LAST)
  77 ENUMCLASS_END(CPID)
  78
  79 USING(Notification, entity);
  80
  81 // used for notification system multi-team identifiers
  82 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  83 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  84
  85 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  86         VARITEM(1, 0, s1) \
  87         VARITEM(2, 0, XPD(s1, s2)) \
  88         VARITEM(3, 0, XPD(s1, s2, s3)) \
  89         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  90         VARITEM(0, 1, f1) \
  91         VARITEM(1, 1, XPD(s1, f1)) \
  92         VARITEM(2, 1, XPD(s1, s2, f1)) \
  93         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  94         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  95         VARITEM(0, 2, XPD(f1, f2)) \
  96         VARITEM(1, 2, XPD(s1, f1, f2)) \
  97         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  98         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  99         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 100         VARITEM(0, 3, XPD(f1, f2, f3)) \
 101         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 102         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 103         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 104         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 105         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 106         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 107         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 108         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 109         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 110
 111 void Destroy_All_Notifications();
 112 void Create_Notification_Entity(entity notif,
 113         float var_default,
 114         float var_cvar,
 115         MSG typeId,
 116         string namestring,
 117         int teamnum);
 118 void Create_Notification_Entity_Annce(entity notif,
 119                                                                                 float var_cvar,
 120                                                                                 string namestring,
 121                                                                                 /* MSG_ANNCE */
 122                                                                                 float channel,
 123                                                                                 string snd,
 124                                                                                 float vol,
 125                                                                                 float position);
 126
 127 void Create_Notification_Entity_InfoCenter(entity notif,
 128                                                                                         float var_cvar,
 129                                                                                         string namestring,
 130                                                                                         int strnum,
 131                                                                                         int flnum,
 132                                                                                         /* MSG_INFO & MSG_CENTER */
 133                                                                                         string args,
 134                                                                                         string hudargs,
 135                                                                                         string icon,
 136                                                                                         CPID cpid,
 137                                                                                         string durcnt,
 138                                                                                         string normal,
 139                                                                                         string gentle);
 140
 141 void Create_Notification_Entity_Multi(entity notif,
 142                                                                                 float var_cvar,
 143                                                                                 string namestring,
 144                                                                                 /* MSG_MULTI */
 145                                                                                 Notification anncename,
 146                                                                                 Notification infoname,
 147                                                                                 Notification centername);
 148
 149 void Create_Notification_Entity_Choice(entity notif,
 150                                                                                 float var_cvar,
 151                                                                                 string namestring,
 152                                                                                 /* MSG_CHOICE */
 153                                                                                 float challow_def,
 154                                                                                 float challow_var,
 155                                                                                 MSG chtype,
 156                                                                                 Notification optiona,
 157                                                                                 Notification optionb);
 158
 159 void Dump_Notifications(int fh, bool alsoprint);
 160
 161 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 162 {
 163         switch (request)
 164         {
 165                 case CMD_REQUEST_COMMAND:
 166                 {
 167                         #ifdef GAMEQC
 168                         string filename = argv(1);
 169                         bool alsoprint = false;
 170                         if (filename == "")
 171                         {
 172                                 filename = "notifications_dump.cfg";
 173                                 alsoprint = false;
 174                         }
 175                         else if (filename == "-")
 176                         {
 177                                 filename = "notifications_dump.cfg";
 178                                 alsoprint = true;
 179                         }
 180                         int fh = fopen(filename, FILE_WRITE);
 181                         if (fh >= 0)
 182                         {
 183                                 Dump_Notifications(fh, alsoprint);
 184                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 185                                 fclose(fh);
 186                         }
 187                         else
 188                         {
 189                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 190                         }
 191                         #else
 192                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd."));
 193                         #endif
 194                         return;
 195                 }
 196                 default:
 197                 case CMD_REQUEST_USAGE:
 198                 {
 199                         LOG_INFO("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]");
 200                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),");
 201                         LOG_INFO("  if supplied with '-' output to console as well as default,");
 202                         LOG_INFO("  if left blank, it will only write to default.");
 203                         return;
 204                 }
 205         }
 206 }
 207
 208 #ifdef NOTIFICATIONS_DEBUG
 209 bool autocvar_notification_debug = false;
 210 void Debug_Notification(string input)
 211 {
 212         switch (autocvar_notification_debug)
 213         {
 214                 case 1: { LOG_TRACE(input); break; }
 215                 case 2: { LOG_INFO(input); break; }
 216         }
 217 }
 218 #endif
 219
 220 void Local_Notification(MSG net_type, Notification net_name, ...count);
 221 /** glue for networking, forwards to `Local_Notification` */
 222 void Local_Notification_WOVA(
 223         MSG net_type, Notification net_name,
 224         float stringcount, float floatcount,
 225         string s1, string s2, string s3, string s4,
 226         float f1, float f2, float f3, float f4);
 227
 228 #ifdef CSQC
 229 string prev_soundfile;
 230 float prev_soundtime;
 231 #endif
 232
 233 #ifdef SVQC
 234 IntrusiveList g_notifications;
 235 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 236 #endif
 237
 238 #ifdef SVQC
 239 ENUMCLASS(NOTIF)
 240         /** send to one client and their spectators */
 241         CASE(NOTIF, ONE)
 242         /** send ONLY to one client */
 243         CASE(NOTIF, ONE_ONLY)
 244         /** send only to X team and their spectators */
 245         CASE(NOTIF, TEAM)
 246         /** send only to X team and their spectators, except for Y person and their spectators */
 247         CASE(NOTIF, TEAM_EXCEPT)
 248         /** send to everyone */
 249         CASE(NOTIF, ALL)
 250         /** send to everyone except X person and their spectators */
 251         CASE(NOTIF, ALL_EXCEPT)
 252 ENUMCLASS_END(NOTIF)
 253
 254 string Get_Notif_BroadcastName(NOTIF broadcast)
 255 {
 256         switch (broadcast)
 257         {
 258                 case NOTIF_ONE: return "NOTIF_ONE";
 259                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 260                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 261                 case NOTIF_ALL: return "NOTIF_ALL";
 262                 case NOTIF_TEAM: return "NOTIF_TEAM";
 263                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 264         }
 265         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 266         return "";
 267 }
 268
 269 void Kill_Notification(
 270         NOTIF broadcast, entity client,
 271         MSG net_type, CPID net_name);
 272 void Send_Notification(
 273         NOTIF broadcast, entity client,
 274         MSG net_type, Notification net_name,
 275         ...count);
 276 void Send_Notification_WOVA(
 277         NOTIF broadcast, entity client,
 278         MSG net_type, Notification net_name,
 279         float stringcount, float floatcount,
 280         string s1, string s2, string s3, string s4,
 281         float f1, float f2, float f3, float f4);
 282 void Send_Notification_WOCOVA(
 283         NOTIF broadcast, entity client,
 284         MSG net_type, Notification net_name,
 285         string s1, string s2, string s3, string s4,
 286         float f1, float f2, float f3, float f4);
 287 #endif
 288
 289 // ===========================
 290 //  Special CVAR Declarations
 291 // ===========================
 292
 293 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 294 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 295
 296 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 297
 298 float autocvar_notification_show_location = false;
 299 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 300 float autocvar_notification_show_sprees = true;
 301 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 302 float autocvar_notification_show_sprees_info_newline = true;
 303 float autocvar_notification_show_sprees_info_specialonly = true;
 304 float autocvar_notification_errors_are_fatal = true;
 305 #ifdef SVQC
 306 float autocvar_notification_lifetime_runtime = 0.5;
 307 float autocvar_notification_lifetime_mapload = 10;
 308 #endif
 309
 310 #ifdef SVQC
 311 .float FRAG_VERBOSE;
 312 void Notification_GetCvars(entity this);
 313 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 314 #else
 315 float autocvar_notification_item_centerprinttime = 1.5;
 316
 317 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 318 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 319 float autocvar_notification_allow_chatboxprint = 0;
 320
 321 float autocvar_notification_show_sprees_center = true;
 322 float autocvar_notification_show_sprees_center_specialonly = true;
 323 #endif
 324
 325
 326 // ============================
 327 //  Notification Argument List
 328 // ============================
 329 /*
 330  These arguments get replaced with the Local_Notification_sprintf
 331  and other such functions found in all.qc to supply data
 332  from networked notifications to their usage in sprintf... It
 333  allows for more dynamic data to be inferred by the local
 334  notification parser, so that the server does not have to network
 335  anything too crazy on a per-client/per-situation basis.
 336
 337  Pay attention to the CSQC/SVQC relations, some of these are redefined
 338  in slightly different ways for different programs, this is because the
 339  server does a more conservative approach to the notifs than the client.
 340
 341  All arguments are swapped into strings, so be sure that your
 342  sprintf usage matches with proper %s placement.
 343
 344  Argument descriptions:
 345         s1-s4: string arguments to be literally swapped into sprintf
 346         s2loc: s2 string of locations of deaths or other events
 347         s3loc: s3 string of locations of deaths or other events
 348         f1-f4: float arguments expanded into strings to be swapped into sprintf
 349         f1p2dec: f1 float to string with 2 decimal places
 350         f2p2dec: f2 float to string with 2 decimal places
 351         f2primsec: f2 float primary or secondary selection for weapons
 352         f3primsec: f3 float primary or secondary selection for weapons
 353         f1secs: count_seconds of f1
 354         f1points: point or points depending on f1
 355         f1ord: count_ordinal of f1
 356         f1time: process_time of f1
 357         f1race_time: mmssss of f1
 358         f2race_time: mmssss of f2
 359         race_col: color of race time/position (i.e. good or bad)
 360         race_diff: show time difference between f2 and f3
 361         missing_teams: show which teams still need players
 362         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 363         nade_key: find the keybind for nade throwing
 364         frag_ping: show the ping of a player
 365         frag_stats: show health/armor/ping of a player
 366         frag_pos: show score status and position in the match of a player
 367         spree_cen: centerprint notif for kill spree/how many kills they have
 368         spree_inf: info notif for kill spree/how many kills they have
 369         spree_end: placed at the end of murder messages to show ending of sprees
 370         spree_lost: placed at the end of suicide messages to show losing of sprees
 371         item_wepname: return full name of a weapon from weaponid
 372         item_wepammo: ammo display for weapon from string
 373         item_centime: amount of time to display weapon message in centerprint
 374         item_buffname: return full name of a buff from buffid
 375         death_team: show the full name of the team a player is switching from
 376         minigame1_name: return human readable name of a minigame from its id(s1)
 377         minigame1_d: return descriptor name of a minigame from its id(s1)
 378 */
 379
 380 const float NOTIF_MAX_ARGS = 7;
 381 const float NOTIF_MAX_HUDARGS = 2;
 382 const float NOTIF_MAX_DURCNT = 2;
 383
 384 string arg_slot[NOTIF_MAX_ARGS];
 385
 386 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 387 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 388 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 389 const float ARG_CS = 4; // unique result to CSQC
 390 const float ARG_SV = 5; // unique result to SVQC
 391 const float ARG_DC = 6; // unique result to durcnt/centerprint
 392
 393 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 394 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 395
 396 string BUFF_NAME(int i);
 397
 398 #define NOTIF_ARGUMENT_LIST \
 399         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 400         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 401         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 402         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 403         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 404         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 405         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 406         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 407         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 408         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 409         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 410         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 411         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 412         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 413         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 414         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 415         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 416         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 417         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 418         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 419         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 420         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 421         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 422         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 423         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 424         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 425         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 426         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 427         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 428         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 429         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 430         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 431         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 432         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 433         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 434         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 435         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 436         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 437         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 438         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 439         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 440         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 441
 442 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 443         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 444 } MACRO_END
 445 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 446
 447 #define KILL_SPREE_LIST \
 448         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 449         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 450         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 451         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 452         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 453         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 454         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 455
 456 #ifdef CSQC
 457 string notif_arg_frag_ping(bool newline, float fping)
 458 {
 459         string s = newline ? "\n" : " ";
 460         if (fping < 0)
 461                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 462         else
 463                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 464 }
 465
 466 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 467 {
 468         string s = notif_arg_frag_ping(false, fping);
 469         if (fhealth > 1)
 470                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 471         else
 472                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 473 }
 474
 475 string notif_arg_missing_teams(float f1)
 476 {
 477         return strcat(
 478                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 479                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 480                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 481                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 482         );
 483 }
 484
 485 string notif_arg_spree_cen(float spree)
 486 {
 487         // 0 = off, 1 = target (but only for first victim) and attacker
 488         if(autocvar_notification_show_sprees_center)
 489         {
 490                 if(spree > 1)
 491                 {
 492                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 493                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 494
 495                         switch(spree)
 496                         {
 497                                 KILL_SPREE_LIST
 498                                 default:
 499                                 {
 500                                         if (!autocvar_notification_show_sprees_center_specialonly)
 501                                         {
 502                                                 return
 503                                                         sprintf(
 504                                                                 normal_or_gentle(
 505                                                                         _("%d frag spree! "),
 506                                                                         _("%d score spree! ")
 507                                                                 ),
 508                                                                 spree);
 509                                         }
 510                                         else { return ""; } // don't show spree information if it isn't an achievement
 511                                 }
 512                         }
 513
 514                         #undef SPREE_ITEM
 515                 }
 516                 else if(spree == -1) // first blood
 517                 {
 518                         return normal_or_gentle(_("First blood! "), _("First score! "));
 519                 }
 520                 else if(spree == -2) // first victim
 521                 {
 522                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 523                 }
 524         }
 525         return "";
 526 }
 527 #endif
 528
 529 string notif_arg_spree_inf(float type, string input, string player, float spree)
 530 {
 531         switch(type)
 532         {
 533                 case 1: // attacker kill spree
 534                 {
 535                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 536                         // this conditional (& 2) is true for 2 and 3
 537                         if(autocvar_notification_show_sprees_info & 2)
 538                         {
 539                                 #ifdef CSQC
 540                                 string spree_newline =
 541                                         ( autocvar_notification_show_sprees_info_newline ?
 542                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 543                                 #else
 544                                 string spree_newline =
 545                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 546                                 #endif
 547
 548                                 if(spree > 1)
 549                                 {
 550                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 551                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 552
 553                                         switch(spree)
 554                                         {
 555                                                 KILL_SPREE_LIST
 556                                                 default:
 557                                                 {
 558                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 559                                                         {
 560                                                                 return
 561                                                                         sprintf(
 562                                                                                 CCR(normal_or_gentle(
 563                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 564                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 565                                                                                 )),
 566                                                                                 player,
 567                                                                                 spree,
 568                                                                                 spree_newline
 569                                                                         );
 570                                                         }
 571                                                         else { return ""; } // don't show spree information if it isn't an achievement
 572                                                 }
 573                                         }
 574
 575                                         #undef SPREE_ITEM
 576                                 }
 577                                 else if(spree == -1) // firstblood
 578                                 {
 579                                         return
 580                                                 sprintf(
 581                                                         CCR(normal_or_gentle(
 582                                                                 _("%s^K1 drew first blood! %s^BG"),
 583                                                                 _("%s^K1 got the first score! %s^BG")
 584                                                         )),
 585                                                         player,
 586                                                         spree_newline
 587                                                 );
 588                                 }
 589                         }
 590                         break;
 591                 }
 592
 593                 case -1: // kill spree ended
 594                 {
 595                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 596                         {
 597                                 return
 598                                         sprintf(normal_or_gentle(
 599                                                 _(", ending their %d frag spree"),
 600                                                 _(", ending their %d score spree")
 601                                                 ),
 602                                                 spree
 603                                         );
 604                         }
 605                         break;
 606                 }
 607
 608                 case -2: // kill spree lost
 609                 {
 610                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 611                         {
 612                                 return
 613                                         sprintf(normal_or_gentle(
 614                                                 _(", losing their %d frag spree"),
 615                                                 _(", losing their %d score spree")
 616                                                 ),
 617                                                 spree
 618                                         );
 619                         }
 620                         break;
 621                 }
 622         }
 623         return "";
 624 }
 625
 626
 627 // ====================================
 628 //  Initialization/Create Declarations
 629 // ====================================
 630
 631 // common notification entity values
 632 .int nent_default;
 633 .bool nent_enabled;
 634 .MSG nent_type;
 635 .string nent_name;
 636 .int nent_stringcount;
 637 .int nent_floatcount;
 638 .int nent_teamnum;
 639
 640 // MSG_ANNCE entity values
 641 .int nent_channel;
 642 .string nent_snd;
 643 .float nent_vol;
 644 .float nent_position;
 645
 646 // MSG_INFO and MSG_CENTER entity values
 647 .string nent_args; // used by both
 648 .string nent_hudargs; // used by info
 649 .string nent_icon; // used by info
 650 .CPID nent_cpid; // used by center
 651 .string nent_durcnt; // used by center
 652 .string nent_string; // used by both
 653
 654 // MSG_MULTI entity values
 655 .entity nent_msgannce;
 656 .entity nent_msginfo;
 657 .entity nent_msgcenter;
 658
 659 // MSG_CHOICE entity values
 660 .float nent_challow_def;
 661 .float nent_challow_var;
 662 .entity nent_optiona;
 663 .entity nent_optionb;
 664
 665 // networked notification entity values
 666 #ifdef SVQC
 667 .NOTIF nent_broadcast;
 668 #endif
 669 .entity nent_client;
 670 .MSG nent_net_type;
 671 .float nent_net_name;
 672 .string nent_strings[4];
 673 .float nent_floats[4];
 674
 675 #define ACVNN(name) autocvar_notification_##name
 676
 677 REGISTRY(Notifications, BITS(11))
 678 REGISTER_REGISTRY(Notifications)
 679 REGISTRY_SORT(Notifications);
 680 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 681 REGISTRY_CHECK(Notifications)
 682
 683 const int NOTIF_CHOICE_MAX = 50;
 684 int nent_choice_count = 0;
 685 .int nent_choice_idx;
 686 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 687 // initialization error detection
 688 bool notif_error;
 689 bool notif_global_error;
 690
 691 STATIC_INIT_LATE(Notif_Choices) {
 692         int c = 0;
 693         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 694         if (c > NOTIF_CHOICE_MAX) {
 695                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 696         }
 697 }
 698
 699 string Get_Notif_CvarName(Notification notif)
 700 {
 701         if(!notif.nent_teamnum)
 702                 return notif.nent_name;
 703         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 704 }
 705
 706 Notification Get_Notif_Ent(MSG net_type, int net_name)
 707 {
 708         Notification it = _Notifications_from(net_name, NULL);
 709         if (it.nent_type != net_type) {
 710                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 711                         Get_Notif_TypeName(net_type), net_type,
 712                         it.registered_id, net_name,
 713                         Get_Notif_TypeName(it.nent_type)
 714                 );
 715                 return NULL;
 716         }
 717         return it;
 718 }
 719
 720 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, default, sound, channel, volume, position) \
 721         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, default, sound, channel, volume, position)
 722
 723 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 724         NOTIF_ADD_AUTOCVAR(ANNCE_##name, default) \
 725         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, default, sound, channel, volume, position)
 726
 727 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, default, sound, channel, volume, position) \
 728         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 729                 Create_Notification_Entity      (this, default, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 730                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 731                         channel,   /* channel  */ \
 732                         sound,     /* snd      */ \
 733                         volume,    /* vol      */ \
 734                         position); /* position */ \
 735         }
 736
 737 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 738         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 739
 740 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 741         NOTIF_ADD_AUTOCVAR(INFO_##name, default) \
 742         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 743
 744 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 745         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 746                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 747                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 748                         args,     /* args    */ \
 749                         hudargs,  /* hudargs */ \
 750                         icon,     /* icon    */ \
 751                         CPID_Null,/* cpid    */ \
 752                         "",       /* durcnt  */ \
 753                         normal,   /* normal  */ \
 754                         gentle);  /* gentle  */ \
 755         }
 756
 757 .string nent_iconargs;
 758 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 759         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 760 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 761         NOTIF_ADD_AUTOCVAR(name, default) \
 762         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 763                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 764                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 765                         args,     /* args    */ \
 766                         hudargs,  /* hudargs */ \
 767                         icon,     /* icon    */ \
 768                         CPID_Null,/* cpid    */ \
 769                         "",       /* durcnt  */ \
 770                         normal,   /* normal  */ \
 771                         gentle);  /* gentle  */ \
 772                 this.nent_iconargs = iconargs; \
 773         }
 774
 775 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 776         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 777
 778 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 779         NOTIF_ADD_AUTOCVAR(CENTER_##name, default) \
 780         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 781
 782 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 783         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 784                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 785                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 786                         args,    /* args    */ \
 787                         "",      /* hudargs */ \
 788                         "",      /* icon    */ \
 789                         cpid,    /* cpid    */ \
 790                         durcnt,  /* durcnt  */ \
 791                         normal,  /* normal  */ \
 792                         gentle); /* gentle  */ \
 793         }
 794
 795 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 796         NOTIF_ADD_AUTOCVAR(name, default) \
 797         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 798                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 799                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 800                         anncename,   /* anncename  */ \
 801                         infoname,    /* infoname   */ \
 802                         centername); /* centername */ \
 803         }
 804
 805 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 806         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, default, challow, chtype, optiona, optionb)
 807
 808 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 809         NOTIF_ADD_AUTOCVAR(CHOICE_##name, default) \
 810         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 811         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, default, challow, chtype, optiona, optionb)
 812
 813 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 814         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 815                 this.nent_choice_idx = nent_choice_count++; \
 816                 Create_Notification_Entity       (this, default, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 817                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 818                         challow,                                 /* challow_def */ \
 819                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 820                         chtype,                                  /* chtype      */ \
 821                         optiona,                                 /* optiona     */ \
 822                         optionb);                                /* optionb     */ \
 823         }
 824
 825 REGISTRY_BEGIN(Notifications)
 826 {
 827         notif_global_error = false;
 828 }
 829
 830 REGISTRY_END(Notifications)
 831 {
 832         if (!notif_global_error) return;
 833         // shit happened... stop the loading of the program now if this is unacceptable
 834         if (autocvar_notification_errors_are_fatal)
 835                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 836         else
 837                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 838 }
 839
 840 #include "all.inc"