qcsrc/common/physics/movetypes/movetypes.qc

   1 #include "movetypes.qh"
   2
   3 #ifdef SVQC
   4 void set_movetype(entity this, int mt)
   5 {
   6         this.move_movetype = mt;
   7         if (mt == MOVETYPE_PHYSICS || mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH) {
   8                 this.move_qcphysics = false;
   9         }
  10         this.movetype = (this.move_qcphysics) ? MOVETYPE_NONE : mt;
  11 }
  12 #elif defined(CSQC)
  13 void set_movetype(entity this, int mt)
  14 {
  15         this.move_movetype = mt;
  16 }
  17 #endif
  18
  19 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
  20 {
  21         /*float d, i;
  22         vector into, side;
  23         makevectors(this.v_angle);
  24         d = (stepnormal * v_forward) + 0.5;
  25
  26         if(d < 0)
  27         {
  28             i = (stepnormal * this.velocity);
  29             into = i * stepnormal;
  30             side = this.velocity - into;
  31             this.velocity_x = side.x * (1 * d);
  32             this.velocity_y = side.y * (1 * d);
  33         }*/
  34 }
  35
  36 vector planes[MAX_CLIP_PLANES];
  37 int _Movetype_FlyMove(entity this, float dt, bool applygravity, vector stepnormal, float stepheight) // SV_FlyMove
  38 {
  39         if(dt <= 0)
  40                 return 0;
  41
  42         int blocked = 0;
  43         int i, j, numplanes = 0;
  44         float time_left = dt, grav = 0;
  45         vector push;
  46         vector primal_velocity, original_velocity;
  47         vector restore_velocity = this.velocity;
  48
  49         for(i = 0; i < MAX_CLIP_PLANES; ++i)
  50                 planes[i] = '0 0 0';
  51
  52         if(applygravity)
  53         {
  54                 this.move_didgravity = 1;
  55                 grav = dt * (PHYS_ENTGRAVITY(this) ? PHYS_ENTGRAVITY(this) : 1) * PHYS_GRAVITY(this);
  56
  57                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
  58                 {
  59                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
  60                                 this.velocity_z -= grav * 0.5;
  61                         else
  62                                 this.velocity_z -= grav;
  63                 }
  64         }
  65
  66         original_velocity = primal_velocity = this.velocity;
  67
  68         for(int bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
  69         {
  70                 if(this.velocity == '0 0 0')
  71                         break;
  72
  73                 push = this.velocity * time_left;
  74                 if(!_Movetype_PushEntity(this, push, true, false))
  75                 {
  76                         // we got teleported by a touch function
  77                         // let's abort the move
  78                         blocked |= 8;
  79                         break;
  80                 }
  81
  82                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
  83                 // abort move if we're stuck in the world (and didn't make it out)
  84                 if(trace_startsolid && trace_allsolid)
  85                 {
  86                         this.velocity = restore_velocity;
  87                         return 3;
  88                 }
  89
  90                 if(trace_fraction == 1)
  91                         break;
  92
  93                 float my_trace_fraction = trace_fraction;
  94                 vector my_trace_plane_normal = trace_plane_normal;
  95
  96                 if(trace_plane_normal.z)
  97                 {
  98                         if(trace_plane_normal.z > 0.7)
  99                         {
 100                                 // floor
 101                                 blocked |= 1;
 102
 103                                 if(!trace_ent)
 104                                 {
 105                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
 106                                         trace_ent = NULL;
 107                                 }
 108
 109                                 SET_ONGROUND(this);
 110                                 this.groundentity = trace_ent;
 111                         }
 112                 }
 113                 else if(stepheight)
 114                 {
 115                         // step - handle it immediately
 116                         vector org = this.origin;
 117                         vector steppush = '0 0 1' * stepheight;
 118
 119                         if(!_Movetype_PushEntity(this, steppush, true, false))
 120                         {
 121                                 blocked |= 8;
 122                                 break;
 123                         }
 124                         if(!_Movetype_PushEntity(this, push, true, false))
 125                         {
 126                                 blocked |= 8;
 127                                 break;
 128                         }
 129                         float trace2_fraction = trace_fraction;
 130                         steppush = vec3(0, 0, org.z - this.origin_z);
 131                         if(!_Movetype_PushEntity(this, steppush, true, false))
 132                         {
 133                                 blocked |= 8;
 134                                 break;
 135                         }
 136
 137                         // accept the new position if it made some progress...
 138                         if(fabs(this.origin_x - org.x) >= 0.03125 || fabs(this.origin_y - org.y) >= 0.03125)
 139                         {
 140                                 trace_endpos = this.origin;
 141                                 time_left *= 1 - trace2_fraction;
 142                                 numplanes = 0;
 143                                 continue;
 144                         }
 145                         else
 146                                 this.origin = org;
 147                 }
 148                 else
 149                 {
 150                         // step - return it to caller
 151                         blocked |= 2;
 152                         // save the trace for player extrafriction
 153                         if(stepnormal)
 154                                 stepnormal = trace_plane_normal;
 155                 }
 156
 157                 if(my_trace_fraction >= 0.001)
 158                 {
 159                         // actually covered some distance
 160                         original_velocity = this.velocity;
 161                         numplanes = 0;
 162                 }
 163
 164                 time_left *= 1 - my_trace_fraction;
 165
 166                 // clipped to another plane
 167                 if(numplanes >= MAX_CLIP_PLANES)
 168                 {
 169                         // this shouldn't really happen
 170                         this.velocity = '0 0 0';
 171                         blocked = 3;
 172                         break;
 173                 }
 174
 175                 planes[numplanes] = my_trace_plane_normal;
 176                 numplanes++;
 177
 178                 // modify original_velocity so it parallels all of the clip planes
 179                 vector new_velocity = '0 0 0';
 180                 for (i = 0;i < numplanes;i++)
 181                 {
 182                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
 183                         for (j = 0;j < numplanes;j++)
 184                         {
 185                                 if(j != i)
 186                                 {
 187                                         // not ok
 188                                         if((new_velocity * planes[j]) < 0)
 189                                                 break;
 190                                 }
 191                         }
 192                         if(j == numplanes)
 193                                 break;
 194                 }
 195
 196                 if(i != numplanes)
 197                 {
 198                         // go along this plane
 199                         this.velocity = new_velocity;
 200                 }
 201                 else
 202                 {
 203                         // go along the crease
 204                         if(numplanes != 2)
 205                         {
 206                                 this.velocity = '0 0 0';
 207                                 blocked = 7;
 208                                 break;
 209                         }
 210                         vector dir = cross(planes[0], planes[1]);
 211                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
 212                         float ilength = sqrt((dir * dir));
 213                         if(ilength)
 214                                 ilength = 1.0 / ilength;
 215                         dir.x *= ilength;
 216                         dir.y *= ilength;
 217                         dir.z *= ilength;
 218                         float d = (dir * this.velocity);
 219                         this.velocity = dir * d;
 220                 }
 221
 222                 // if current velocity is against the original velocity,
 223                 // stop dead to avoid tiny occilations in sloping corners
 224                 if((this.velocity * primal_velocity) <= 0)
 225                 {
 226                         this.velocity = '0 0 0';
 227                         break;
 228                 }
 229         }
 230
 231         // LordHavoc: this came from QW and allows you to get out of water more easily
 232         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.flags & FL_WATERJUMP) && !(blocked & 8))
 233                 this.velocity = primal_velocity;
 234
 235         if(PHYS_WALLCLIP(this) && this.pm_time && !(this.flags & FL_WATERJUMP) && !(blocked & 8))
 236                 this.velocity = primal_velocity;
 237
 238         if(applygravity)
 239         {
 240                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
 241                 {
 242                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 243                                 this.velocity_z -= grav * 0.5f;
 244                 }
 245         }
 246
 247         return blocked;
 248 }
 249
 250 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
 251 {
 252         // if(vlen(this.velocity) < 0.0001)
 253         // this.velocity = '0 0 0';
 254 }
 255
 256 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
 257 {
 258         vector point = this.origin;
 259         point.z += this.mins.z + 1;
 260
 261         int nativecontents = pointcontents(point);
 262         if(this.watertype && this.watertype != nativecontents)
 263         {
 264                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.watertype, nativecontents);
 265                 if(this.contentstransition)
 266                         this.contentstransition(this.watertype, nativecontents);
 267         }
 268
 269         this.waterlevel = WATERLEVEL_NONE;
 270         this.watertype = CONTENT_EMPTY;
 271
 272         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
 273         if(supercontents & DPCONTENTS_LIQUIDSMASK)
 274         {
 275                 this.watertype = nativecontents;
 276                 this.waterlevel = WATERLEVEL_WETFEET;
 277                 point.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 278                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 279                 {
 280                         this.waterlevel = WATERLEVEL_SWIMMING;
 281                         point.z = this.origin.z + this.view_ofs.z;
 282                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 283                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 284                 }
 285         }
 286
 287         return this.waterlevel > 1;
 288 }
 289
 290 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
 291 {
 292         int contents = pointcontents(ent.origin);
 293
 294         if(!ent.watertype)
 295         {
 296                 // just spawned here
 297                 if(!GAMEPLAYFIX_WATERTRANSITION(ent))
 298                 {
 299                         ent.watertype = contents;
 300                         ent.waterlevel = 1;
 301                         return;
 302                 }
 303         }
 304         else if(ent.watertype != contents)
 305         {
 306                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.origin), pointcontents(ent.origin), ent.watertype, contents);
 307                 if(ent.contentstransition)
 308                         ent.contentstransition(ent.watertype, contents);
 309         }
 310
 311         if(contents <= CONTENT_WATER)
 312         {
 313                 ent.watertype = contents;
 314                 ent.waterlevel = 1;
 315         }
 316         else
 317         {
 318                 ent.watertype = CONTENT_EMPTY;
 319                 ent.waterlevel = (GAMEPLAYFIX_WATERTRANSITION(ent) ? 0 : contents);
 320         }
 321 }
 322
 323 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
 324 {
 325         if(gettouch(this))
 326                 gettouch(this)(this, oth);
 327
 328         if(gettouch(oth))
 329                 gettouch(oth)(oth, this);
 330 }
 331
 332 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
 333 {
 334         if(this.solid == SOLID_NOT)
 335                 return;
 336
 337     FOREACH_ENTITY_RADIUS(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 338                 if (it.solid == SOLID_TRIGGER && it != this)
 339                 if (it.move_nomonsters != MOVE_NOMONSTERS && it.move_nomonsters != MOVE_WORLDONLY)
 340                 if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax))
 341                 {
 342                         trace_allsolid = false;
 343                         trace_startsolid = false;
 344                         trace_fraction = 1;
 345                         trace_inwater = false;
 346                         trace_inopen = true;
 347                         trace_endpos = it.origin;
 348                         trace_plane_normal = '0 0 1';
 349                         trace_plane_dist = 0;
 350                         trace_ent = this;
 351                         trace_dpstartcontents = 0;
 352                         trace_dphitcontents = 0;
 353                         trace_dphitq3surfaceflags = 0;
 354                         trace_dphittexturename = string_null;
 355
 356                         gettouch(it)(it, this);
 357                 }
 358     });
 359 }
 360
 361 bool autocvar__movetype_debug = false;
 362 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
 363 {
 364         if(autocvar__movetype_debug)
 365         {
 366                 vector mi, ma;
 367                 if(this.solid == SOLID_BSP)
 368                 {
 369                         // TODO set the absolute bbox
 370                         mi = this.mins;
 371                         ma = this.maxs;
 372                 }
 373                 else
 374                 {
 375                         mi = this.mins;
 376                         ma = this.maxs;
 377                 }
 378                 mi += this.origin;
 379                 ma += this.origin;
 380
 381                 if(this.flags & FL_ITEM)
 382                 {
 383                         mi -= '15 15 1';
 384                         ma += '15 15 1';
 385                 }
 386                 else
 387                 {
 388                         mi -= '1 1 1';
 389                         ma += '1 1 1';
 390                 }
 391
 392                 this.absmin = mi;
 393                 this.absmax = ma;
 394         }
 395         else
 396         {
 397                 setorigin(this, this.origin); // calls SV_LinkEdict
 398         #ifdef CSQC
 399                 // NOTE: CSQC's version of setorigin doesn't expand
 400                 this.absmin -= '1 1 1';
 401                 this.absmax += '1 1 1';
 402         #endif
 403         }
 404
 405         if(touch_triggers)
 406                 _Movetype_LinkEdict_TouchAreaGrid(this);
 407 }
 408
 409 entity _Movetype_TestEntityPosition_ent;
 410 bool _Movetype_TestEntityPosition(vector ofs)  // SV_TestEntityPosition
 411 {
 412     entity this = _Movetype_TestEntityPosition_ent;
 413         vector org = this.origin + ofs;
 414
 415         int cont = this.dphitcontentsmask;
 416         this.dphitcontentsmask = DPCONTENTS_SOLID;
 417         tracebox(org, this.mins, this.maxs, org, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
 418         this.dphitcontentsmask = cont;
 419
 420         if(trace_startsolid)
 421                 return true;
 422
 423         if(vdist(trace_endpos - this.origin, >, 0.0001))
 424                 this.origin = trace_endpos;
 425         return false;
 426 }
 427
 428 int _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
 429 {
 430     _Movetype_TestEntityPosition_ent = this;
 431         if (!_Movetype_TestEntityPosition(' 0  0  0')) {
 432             return UNSTICK_FINE;
 433         }
 434         #define X(v) if (_Movetype_TestEntityPosition(v))
 435         X('-1  0  0') X(' 1  0  0')
 436         X(' 0 -1  0') X(' 0  1  0')
 437         X('-1 -1  0') X(' 1 -1  0')
 438         X('-1  1  0') X(' 1  1  0')
 439         #undef X
 440         {
 441         #define X(i) \
 442             if (_Movetype_TestEntityPosition('0 0 -1' * i)) \
 443             if (_Movetype_TestEntityPosition('0 0 1' * i))
 444         X(1) X(2) X(3) X(4) X(5) X(6) X(7) X(8)
 445         X(9) X(10) X(11) X(12) X(13) X(14) X(15) X(16)
 446         X(17)
 447         #undef X
 448         {
 449             LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)",
 450                 etof(this), this.classname, vtos(this.origin));
 451             return UNSTICK_STUCK;
 452         }
 453         }
 454         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)",
 455                 etof(this), this.classname, vtos(this.origin));
 456         _Movetype_LinkEdict(this, true);
 457         return UNSTICK_FIXED;
 458 }
 459
 460 void _Movetype_CheckStuck(entity this)  // SV_CheckStuck
 461 {
 462         int unstick = _Movetype_UnstickEntity(this); // sets test position entity
 463         switch(unstick)
 464         {
 465                 case UNSTICK_FINE:
 466                         this.oldorigin = this.origin;
 467                         break;
 468                 case UNSTICK_FIXED:
 469                         break; // already sorted
 470                 case UNSTICK_STUCK:
 471                         vector offset = this.oldorigin - this.origin;
 472                         if(!_Movetype_TestEntityPosition(offset))
 473                                 _Movetype_LinkEdict(this, false);
 474                         // couldn't unstick, should we warn about this?
 475                         break;
 476         }
 477 }
 478
 479 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // SV_ClipVelocity
 480 {
 481         vel -= ((vel * norm) * norm) * f;
 482
 483         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
 484         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
 485         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
 486
 487         return vel;
 488 }
 489
 490 void _Movetype_PushEntityTrace(entity this, vector push)
 491 {
 492         vector end = this.origin + push;
 493         int type;
 494         if(this.move_nomonsters)
 495                 type = max(0, this.move_nomonsters);
 496         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
 497                 type = MOVE_MISSILE;
 498         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
 499                 type = MOVE_WORLDONLY;
 500         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
 501                 type = MOVE_NOMONSTERS;
 502         else
 503                 type = MOVE_NORMAL;
 504
 505         tracebox(this.origin, this.mins, this.maxs, end, type, this);
 506 }
 507
 508 bool _Movetype_PushEntity(entity this, vector push, bool failonstartsolid, bool dolink)  // SV_PushEntity
 509 {
 510         _Movetype_PushEntityTrace(this, push);
 511
 512         // NOTE: this is a workaround for the QC's lack of a worldstartsolid trace parameter
 513         if(trace_startsolid && failonstartsolid)
 514         {
 515                 int oldtype = this.move_nomonsters;
 516                 this.move_nomonsters = MOVE_WORLDONLY;
 517                 _Movetype_PushEntityTrace(this, push);
 518                 this.move_nomonsters = oldtype;
 519                 if(trace_startsolid)
 520                         return true;
 521         }
 522
 523         this.origin = trace_endpos;
 524
 525         vector last_origin = this.origin;
 526
 527         if(dolink)
 528                 _Movetype_LinkEdict(this, true);
 529
 530         if(trace_fraction < 1)
 531                 if(this.solid >= SOLID_TRIGGER && trace_ent && (!IS_ONGROUND(this) || (this.groundentity != trace_ent)))
 532                         _Movetype_Impact(this, trace_ent);
 533
 534         return (this.origin == last_origin); // false if teleported by touch
 535 }
 536
 537
 538 .float ltime;
 539 .void() blocked;
 540
 541 void _Movetype_Physics_Frame(entity this, float movedt)
 542 {
 543         this.move_didgravity = -1;
 544         switch (this.move_movetype)
 545         {
 546                 case MOVETYPE_PUSH:
 547                 case MOVETYPE_FAKEPUSH:
 548                         LOG_DEBUG("Physics: Lacking QuakeC support for Push movetype, FIX ME by using engine physics!");
 549                         break;
 550                 case MOVETYPE_NONE:
 551                         break;
 552                 case MOVETYPE_FOLLOW:
 553                         _Movetype_Physics_Follow(this);
 554                         break;
 555                 case MOVETYPE_NOCLIP:
 556                         _Movetype_CheckWater(this);
 557                         this.origin = this.origin + movedt * this.velocity;
 558                         this.angles = this.angles + movedt * this.avelocity;
 559                         _Movetype_LinkEdict(this, false);
 560                         break;
 561                 case MOVETYPE_STEP:
 562                         _Movetype_Physics_Step(this, movedt);
 563                         break;
 564                 case MOVETYPE_WALK:
 565                         _Movetype_Physics_Walk(this, movedt);
 566                         break;
 567                 case MOVETYPE_TOSS:
 568                 case MOVETYPE_BOUNCE:
 569                 case MOVETYPE_BOUNCEMISSILE:
 570                 case MOVETYPE_FLYMISSILE:
 571                 case MOVETYPE_FLY:
 572                 case MOVETYPE_FLY_WORLDONLY:
 573                         _Movetype_Physics_Toss(this, movedt);
 574                         if(wasfreed(this))
 575                                 return;
 576                         _Movetype_LinkEdict(this, true);
 577                         break;
 578                 case MOVETYPE_PHYSICS:
 579                         break;
 580         }
 581 }
 582
 583 void _Movetype_Physics_ClientFrame(entity this, float movedt)
 584 {
 585         this.move_didgravity = -1;
 586         switch (this.move_movetype)
 587         {
 588                 case MOVETYPE_PUSH:
 589                 case MOVETYPE_FAKEPUSH:
 590                         LOG_DEBUG("Physics: Lacking QuakeC support for Push movetype, FIX ME by using engine physics!");
 591                         break;
 592                 case MOVETYPE_NONE:
 593                         break;
 594                 case MOVETYPE_FOLLOW:
 595                         _Movetype_Physics_Follow(this);
 596                         break;
 597                 case MOVETYPE_NOCLIP:
 598                         _Movetype_CheckWater(this);
 599                         this.origin = this.origin + movedt * this.velocity;
 600                         this.angles = this.angles + movedt * this.avelocity;
 601                         break;
 602                 case MOVETYPE_STEP:
 603                         _Movetype_Physics_Step(this, movedt);
 604                         break;
 605                 case MOVETYPE_WALK:
 606                 case MOVETYPE_FLY:
 607                 case MOVETYPE_FLY_WORLDONLY:
 608                         _Movetype_Physics_Walk(this, movedt);
 609                         break;
 610                 case MOVETYPE_TOSS:
 611                 case MOVETYPE_BOUNCE:
 612                 case MOVETYPE_BOUNCEMISSILE:
 613                 case MOVETYPE_FLYMISSILE:
 614                         _Movetype_Physics_Toss(this, movedt);
 615                         break;
 616                 case MOVETYPE_PHYSICS:
 617                         break;
 618         }
 619
 620         //_Movetype_CheckVelocity(this);
 621
 622         _Movetype_LinkEdict(this, true);
 623
 624         //_Movetype_CheckVelocity(this);
 625 }
 626
 627 void Movetype_Physics_NoMatchTicrate(entity this, float movedt, bool isclient)  // to be run every move frame
 628 {
 629         this.move_time = time;
 630
 631         if(isclient)
 632                 _Movetype_Physics_ClientFrame(this, movedt);
 633         else
 634                 _Movetype_Physics_Frame(this, movedt);
 635         if(wasfreed(this))
 636                 return;
 637
 638         setorigin(this, this.origin);
 639 }
 640
 641 void Movetype_Physics_NoMatchServer(entity this)  // optimized
 642 {
 643         float movedt = time - this.move_time;
 644         this.move_time = time;
 645
 646         _Movetype_Physics_Frame(this, movedt);
 647         if(wasfreed(this))
 648                 return;
 649
 650         setorigin(this, this.origin);
 651 }
 652
 653 void Movetype_Physics_MatchServer(entity this, bool sloppy)
 654 {
 655         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
 656 }
 657
 658 .vector tic_origin;
 659 .vector tic_velocity;
 660 .int tic_flags;
 661 .vector tic_avelocity;
 662 .vector tic_angles;
 663
 664 .vector tic_saved_origin;
 665 .vector tic_saved_velocity;
 666 .int tic_saved_flags;
 667 .vector tic_saved_avelocity;
 668 .vector tic_saved_angles;
 669 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
 670 {
 671 #define X(s) \
 672         if(this.(s) != this.tic_saved_##s) \
 673                 this.tic_##s = this.(s)
 674
 675         X(origin);
 676         X(velocity);
 677         X(flags);
 678         X(avelocity);
 679         X(angles);
 680 #undef X
 681
 682         if(tr <= 0)
 683         {
 684                 this.flags = this.tic_flags;
 685                 this.velocity = this.tic_velocity;
 686                 this.origin = this.tic_origin;
 687                 this.avelocity = this.tic_avelocity;
 688                 this.angles = this.tic_angles;
 689                 Movetype_Physics_NoMatchServer(this);
 690                 this.tic_origin = this.origin;
 691                 this.tic_velocity = this.velocity;
 692                 this.tic_avelocity = this.avelocity;
 693                 this.tic_angles = this.angles;
 694                 this.tic_flags = this.flags;
 695
 696                 this.tic_saved_flags = this.flags;
 697                 this.tic_saved_velocity = this.velocity;
 698                 this.tic_saved_origin = this.origin;
 699                 this.tic_saved_avelocity = this.avelocity;
 700                 this.tic_saved_angles = this.angles;
 701                 return;
 702         }
 703
 704         float dt = time - this.move_time;
 705
 706         int n = max(0, floor(dt / tr));
 707         dt -= n * tr;
 708         this.move_time += n * tr;
 709
 710         if(!this.move_didgravity)
 711                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.tic_flags & FL_ONGROUND));
 712
 713         for (int i = 0; i < n; ++i)
 714         {
 715                 this.flags = this.tic_flags;
 716                 this.velocity = this.tic_velocity;
 717                 setorigin(this, this.tic_origin);
 718                 this.avelocity = this.tic_avelocity;
 719                 this.angles = this.tic_angles;
 720                 _Movetype_Physics_Frame(this, tr);
 721                 this.tic_origin = this.origin;
 722                 this.tic_velocity = this.velocity;
 723                 this.tic_avelocity = this.avelocity;
 724                 this.tic_angles = this.angles;
 725                 this.tic_flags = this.flags;
 726                 if(wasfreed(this))
 727                         return;
 728         }
 729
 730         this.avelocity = this.tic_avelocity;
 731
 732         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.tic_flags & FL_ONGROUND))
 733         {
 734                 // now continue the move from move_time to time
 735                 this.velocity = this.tic_velocity;
 736
 737                 if(this.move_didgravity > 0)
 738                 {
 739                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
 740                             * dt
 741                             * (this.gravity ? this.gravity : 1)
 742                             * PHYS_GRAVITY(this);
 743                 }
 744
 745                 this.angles = this.tic_angles + dt * this.avelocity;
 746
 747                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
 748                 {
 749                         setorigin(this, this.tic_origin + dt * this.velocity);
 750                 }
 751                 else
 752                 {
 753                         vector oldorg = this.origin;
 754                         this.origin = this.tic_origin;
 755                         _Movetype_PushEntityTrace(this, dt * this.velocity);
 756                         this.origin = oldorg;
 757                         if(!trace_startsolid)
 758                                 setorigin(this, trace_endpos);
 759                 }
 760
 761                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 762                         this.velocity_z -= 0.5 * dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
 763         }
 764         else
 765         {
 766                 this.velocity = this.tic_velocity;
 767                 this.angles = this.tic_angles;
 768                 setorigin(this, this.tic_origin);
 769         }
 770
 771         this.tic_saved_flags = this.flags;
 772         this.tic_saved_velocity = this.velocity;
 773         this.tic_saved_origin = this.origin;
 774         this.tic_saved_avelocity = this.avelocity;
 775         this.tic_saved_angles = this.angles;
 776 }