qcsrc/common/physics/movetypes/movetypes.qc

   1 #include "../player.qh"
   2
   3 #if defined(CSQC)
   4         #include <client/defs.qh>
   5         #include <common/stats.qh>
   6         #include <common/util.qh>
   7         #include "movetypes.qh"
   8         #include <lib/csqcmodel/common.qh>
   9         #include <common/t_items.qh>
  10 #elif defined(MENUQC)
  11 #elif defined(SVQC)
  12         #include <server/autocvars.qh>
  13 #endif
  14
  15 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
  16 {
  17         /*float d, i;
  18         vector into, side;
  19         makevectors(this.v_angle);
  20         d = (stepnormal * v_forward) + 0.5;
  21
  22         if(d < 0)
  23         {
  24             i = (stepnormal * this.move_velocity);
  25             into = i * stepnormal;
  26             side = this.move_velocity - into;
  27             this.move_velocity_x = side.x * (1 * d);
  28             this.move_velocity_y = side.y * (1 * d);
  29         }*/
  30 }
  31
  32 vector planes[MAX_CLIP_PLANES];
  33 int _Movetype_FlyMove(entity this, float dt, bool applygravity, vector stepnormal, float stepheight) // SV_FlyMove
  34 {
  35         int blocked = 0, bumpcount;
  36         int i, j, numplanes = 0;
  37         float time_left = dt, grav = 0;
  38         vector push;
  39         vector primal_velocity, original_velocity, restore_velocity;
  40
  41         for(i = 0; i < MAX_CLIP_PLANES; ++i)
  42                 planes[i] = '0 0 0';
  43
  44         if(applygravity)
  45         {
  46                 this.move_didgravity = 1;
  47                 grav = dt * (PHYS_ENTGRAVITY(this) ? PHYS_ENTGRAVITY(this) : 1) * PHYS_GRAVITY(this);
  48
  49                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
  50                 {
  51                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
  52                                 this.move_velocity_z -= grav * 0.5;
  53                         else
  54                                 this.move_velocity_z -= grav;
  55                 }
  56         }
  57
  58         original_velocity = primal_velocity = restore_velocity = this.move_velocity;
  59
  60         for(bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
  61         {
  62                 if(this.move_velocity == '0 0 0')
  63                         break;
  64
  65                 push = this.move_velocity * time_left;
  66                 _Movetype_PushEntity(this, push, true);
  67                 if(trace_startsolid)
  68                 {
  69                         // we got teleported by a touch function
  70                         // let's abort the move
  71                         blocked |= 8;
  72                         break;
  73                 }
  74
  75                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
  76                 // abort move if we're stuck in the world (and didn't make it out)
  77                 if(trace_startsolid && trace_allsolid)
  78                 {
  79                         this.move_velocity = restore_velocity;
  80                         return 3;
  81                 }
  82
  83                 if(trace_fraction == 1)
  84                         break;
  85
  86                 float my_trace_fraction = trace_fraction;
  87                 vector my_trace_plane_normal = trace_plane_normal;
  88
  89                 if(trace_plane_normal.z)
  90                 {
  91                         if(trace_plane_normal.z > 0.7)
  92                         {
  93                                 // floor
  94                                 blocked |= 1;
  95
  96                                 if(!trace_ent)
  97                                 {
  98                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
  99                                         trace_ent = NULL;
 100                                 }
 101
 102                                 this.move_flags |= FL_ONGROUND;
 103                                 this.move_groundentity = trace_ent;
 104                         }
 105                 }
 106                 else if(stepheight)
 107                 {
 108                         // step - handle it immediately
 109                         vector org = this.move_origin;
 110                         vector steppush = '0 0 1' * stepheight;
 111
 112                         _Movetype_PushEntity(this, steppush, true);
 113                         if(trace_startsolid)
 114                         {
 115                                 blocked |= 8;
 116                                 break;
 117                         }
 118                         _Movetype_PushEntity(this, push, true);
 119                         if(trace_startsolid)
 120                         {
 121                                 blocked |= 8;
 122                                 break;
 123                         }
 124                         float trace2_fraction = trace_fraction;
 125                         steppush = '0 0 1' * (org_z - this.move_origin_z);
 126                         _Movetype_PushEntity(this, steppush, true);
 127                         if(trace_startsolid)
 128                         {
 129                                 blocked |= 8;
 130                                 break;
 131                         }
 132
 133                         // accept the new position if it made some progress...
 134                         if(fabs(this.move_origin_x - org_x) >= 0.03125 || fabs(this.move_origin_y - org_y) >= 0.03125)
 135                         {
 136                                 trace_endpos = this.move_origin;
 137                                 time_left *= 1 - trace2_fraction;
 138                                 numplanes = 0;
 139                                 continue;
 140                         }
 141                         else
 142                                 this.move_origin = org;
 143                 }
 144                 else
 145                 {
 146                         // step - return it to caller
 147                         blocked |= 2;
 148                         // save the trace for player extrafriction
 149                         if(stepnormal)
 150                                 stepnormal = trace_plane_normal;
 151                 }
 152
 153                 if(my_trace_fraction >= 0.001)
 154                 {
 155                         // actually covered some distance
 156                         original_velocity = this.move_velocity;
 157                         numplanes = 0;
 158                 }
 159
 160                 time_left *= 1 - my_trace_fraction;
 161
 162                 // clipped to another plane
 163                 if(numplanes >= MAX_CLIP_PLANES)
 164                 {
 165                         // this shouldn't really happen
 166                         this.move_velocity = '0 0 0';
 167                         blocked = 3;
 168                         break;
 169                 }
 170
 171                 planes[numplanes] = my_trace_plane_normal;
 172                 numplanes++;
 173
 174                 // modify original_velocity so it parallels all of the clip planes
 175                 vector new_velocity = '0 0 0';
 176                 for (i = 0;i < numplanes;i++)
 177                 {
 178                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
 179                         for (j = 0;j < numplanes;j++)
 180                         {
 181                                 if(j != i)
 182                                 {
 183                                         // not ok
 184                                         if((new_velocity * planes[j]) < 0)
 185                                                 break;
 186                                 }
 187                         }
 188                         if(j == numplanes)
 189                                 break;
 190                 }
 191
 192                 if(i != numplanes)
 193                 {
 194                         // go along this plane
 195                         this.move_velocity = new_velocity;
 196                 }
 197                 else
 198                 {
 199                         // go along the crease
 200                         if(numplanes != 2)
 201                         {
 202                                 this.move_velocity = '0 0 0';
 203                                 blocked = 7;
 204                                 break;
 205                         }
 206                         vector dir = cross(planes[0], planes[1]);
 207                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
 208                         float ilength = sqrt((dir * dir));
 209                         if(ilength)
 210                                 ilength = 1.0 / ilength;
 211                         dir.x *= ilength;
 212                         dir.y *= ilength;
 213                         dir.z *= ilength;
 214                         float d = (dir * this.move_velocity);
 215                         this.move_velocity = dir * d;
 216                 }
 217
 218                 // if current velocity is against the original velocity,
 219                 // stop dead to avoid tiny occilations in sloping corners
 220                 if((this.move_velocity * primal_velocity) <= 0)
 221                 {
 222                         this.move_velocity = '0 0 0';
 223                         break;
 224                 }
 225         }
 226
 227         // LordHavoc: this came from QW and allows you to get out of water more easily
 228         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.move_flags & FL_WATERJUMP) && !(blocked & 8))
 229                 this.move_velocity = primal_velocity;
 230
 231         if(applygravity)
 232         {
 233                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
 234                 {
 235                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 236                                 this.move_velocity_z -= grav * 0.5f;
 237                 }
 238         }
 239
 240         return blocked;
 241 }
 242
 243 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
 244 {
 245         // if(vlen(this.move_velocity) < 0.0001)
 246         // this.move_velocity = '0 0 0';
 247 }
 248
 249 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
 250 {
 251         vector point = this.move_origin;
 252         point.z += this.mins.z + 1;
 253
 254         int nativecontents = pointcontents(point);
 255         if(this.move_watertype && this.move_watertype != nativecontents)
 256         {
 257                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.move_watertype, nativecontents);
 258                 if(this.contentstransition)
 259                         this.contentstransition(this.move_watertype, nativecontents);
 260         }
 261
 262         this.move_waterlevel = WATERLEVEL_NONE;
 263         this.move_watertype = CONTENT_EMPTY;
 264
 265         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
 266         if(supercontents & DPCONTENTS_LIQUIDSMASK)
 267         {
 268                 this.move_watertype = nativecontents;
 269                 this.move_waterlevel = WATERLEVEL_WETFEET;
 270                 point.z = this.move_origin.z + (this.mins.z + this.maxs.z) * 0.5;
 271                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 272                 {
 273                         this.move_waterlevel = WATERLEVEL_SWIMMING;
 274                         point.z = this.move_origin.z + this.view_ofs.z;
 275                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 276                                 this.move_waterlevel = WATERLEVEL_SUBMERGED;
 277                 }
 278         }
 279
 280         return this.move_waterlevel > 1;
 281 }
 282
 283 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
 284 {
 285         int contents = pointcontents(ent.move_origin);
 286
 287         if(!ent.move_watertype)
 288         {
 289                 // just spawned here
 290                 if(!autocvar_cl_gameplayfix_fixedcheckwatertransition)
 291                 {
 292                         ent.move_watertype = contents;
 293                         ent.move_waterlevel = 1;
 294                         return;
 295                 }
 296         }
 297         else if(ent.move_watertype != contents)
 298         {
 299                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.move_origin), pointcontents(ent.move_origin), ent.move_watertype, contents);
 300                 if(ent.contentstransition)
 301                         ent.contentstransition(ent.move_watertype, contents);
 302         }
 303
 304         if(contents <= CONTENT_WATER)
 305         {
 306                 ent.move_watertype = contents;
 307                 ent.move_waterlevel = 1;
 308         }
 309         else
 310         {
 311                 ent.move_watertype = CONTENT_EMPTY;
 312                 ent.move_waterlevel = (autocvar_cl_gameplayfix_fixedcheckwatertransition ? 0 : contents);
 313         }
 314 }
 315
 316 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
 317 {
 318         if(gettouch(this))
 319                 gettouch(this)(this, oth);
 320
 321         if(gettouch(oth))
 322                 gettouch(oth)(oth, this);
 323 }
 324
 325 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
 326 {
 327         if(this.solid == SOLID_NOT)
 328                 return;
 329
 330     FOREACH_ENTITY_RADIUS(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 331                 if (it.solid == SOLID_TRIGGER && it != this)
 332                 if (it.move_nomonsters != MOVE_NOMONSTERS && it.move_nomonsters != MOVE_WORLDONLY)
 333                 if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax))
 334                 {
 335                         trace_allsolid = false;
 336                         trace_startsolid = false;
 337                         trace_fraction = 1;
 338                         trace_inwater = false;
 339                         trace_inopen = true;
 340                         trace_endpos = it.move_origin;
 341                         trace_plane_normal = '0 0 1';
 342                         trace_plane_dist = 0;
 343                         trace_ent = this;
 344
 345                         gettouch(it)(it, this);
 346                 }
 347     });
 348 }
 349
 350 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
 351 {
 352         vector mi, ma;
 353         if(this.solid == SOLID_BSP)
 354         {
 355                 // TODO set the absolute bbox
 356                 mi = this.mins;
 357                 ma = this.maxs;
 358         }
 359         else
 360         {
 361                 mi = this.mins;
 362                 ma = this.maxs;
 363         }
 364         mi += this.move_origin;
 365         ma += this.move_origin;
 366
 367         if(this.move_flags & FL_ITEM)
 368         {
 369                 mi.x -= 15;
 370                 mi.y -= 15;
 371                 mi.z -= 1;
 372                 ma.x += 15;
 373                 ma.y += 15;
 374                 ma.z += 1;
 375         }
 376         else
 377         {
 378                 mi.x -= 1;
 379                 mi.y -= 1;
 380                 mi.z -= 1;
 381                 ma.x += 1;
 382                 ma.y += 1;
 383                 ma.z += 1;
 384         }
 385
 386         this.absmin = mi;
 387         this.absmax = ma;
 388
 389         if(touch_triggers)
 390                 _Movetype_LinkEdict_TouchAreaGrid(this);
 391 }
 392
 393 entity _Movetype_TestEntityPosition_ent;
 394 bool _Movetype_TestEntityPosition(vector ofs)  // SV_TestEntityPosition
 395 {
 396     entity this = _Movetype_TestEntityPosition_ent;
 397 //      vector org = this.move_origin + ofs;
 398
 399         int cont = this.dphitcontentsmask;
 400         this.dphitcontentsmask = DPCONTENTS_SOLID;
 401         tracebox(this.move_origin, this.mins, this.maxs, this.move_origin, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
 402         this.dphitcontentsmask = cont;
 403
 404         if(trace_startsolid)
 405                 return true;
 406
 407         if(vdist(trace_endpos - this.move_origin, >, 0.0001))
 408                 this.move_origin = trace_endpos;
 409         return false;
 410 }
 411
 412 bool _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
 413 {
 414     _Movetype_TestEntityPosition_ent = this;
 415         if (!_Movetype_TestEntityPosition(' 0  0  0')) {
 416             return true;
 417         }
 418         #define X(v) if (_Movetype_TestEntityPosition(v))
 419         X('-1  0  0') X(' 1  0  0')
 420         X(' 0 -1  0') X(' 0  1  0')
 421         X('-1 -1  0') X(' 1 -1  0')
 422         X('-1  1  0') X(' 1  1  0')
 423         #undef X
 424         {
 425         #define X(i) \
 426             if (_Movetype_TestEntityPosition('0 0 -1' * i)) \
 427             if (_Movetype_TestEntityPosition('0 0 1' * i))
 428         X(01) X(02) X(03) X(04) X(05) X(06) X(07) X(08)
 429         X(09) X(10) X(11) X(12) X(13) X(14) X(15) X(16)
 430         X(17)
 431         #undef X
 432         {
 433             LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)\n",
 434                 etof(this), this.classname, vtos(this.move_origin));
 435             return false;
 436         }
 437         }
 438         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)\n",
 439                 etof(this), this.classname, vtos(this.move_origin));
 440         _Movetype_LinkEdict(this, true);
 441         return true;
 442 }
 443
 444 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // SV_ClipVelocity
 445 {
 446         vel -= ((vel * norm) * norm) * f;
 447
 448         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
 449         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
 450         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
 451
 452         return vel;
 453 }
 454
 455 void _Movetype_PushEntityTrace(entity this, vector push)
 456 {
 457         vector end = this.move_origin + push;
 458         int type;
 459         if(this.move_nomonsters)
 460                 type = max(0, this.move_nomonsters);
 461         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
 462                 type = MOVE_MISSILE;
 463         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
 464                 type = MOVE_WORLDONLY;
 465         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
 466                 type = MOVE_NOMONSTERS;
 467         else
 468                 type = MOVE_NORMAL;
 469
 470         tracebox(this.move_origin, this.mins, this.maxs, end, type, this);
 471 }
 472
 473 float _Movetype_PushEntity(entity this, vector push, bool failonstartsolid)  // SV_PushEntity
 474 {
 475         _Movetype_PushEntityTrace(this, push);
 476
 477         if(trace_startsolid && failonstartsolid)
 478                 return trace_fraction;
 479
 480         this.move_origin = trace_endpos;
 481
 482         if(trace_fraction < 1)
 483                 if(this.solid >= SOLID_TRIGGER && (!(this.move_flags & FL_ONGROUND) || (this.move_groundentity != trace_ent)))
 484                         _Movetype_Impact(this, trace_ent);
 485
 486         return trace_fraction;
 487 }
 488
 489
 490 .float ltime;
 491 .void() blocked;
 492 // matrix version of makevectors, sets v_forward, v_right and v_up
 493 void makevectors_matrix(vector myangles)  // AngleVectorsFLU
 494 {
 495         v_forward = v_right = v_up = '0 0 0';
 496
 497         float y = myangles.y * (M_PI * 2 / 360);
 498         float sy = sin(y);
 499         float cy = cos(y);
 500         float p = myangles.x * (M_PI * 2 / 360);
 501         float sp = sin(p);
 502         float cp = cos(p);
 503         if(v_forward)
 504         {
 505                 v_forward.x = cp * cy;
 506                 v_forward.y = cp * sy;
 507                 v_forward.z = -sp;
 508         }
 509         if(v_right || v_up)
 510         {
 511                 if(myangles.z)
 512                 {
 513                         float r = myangles.z * (M_PI * 2 / 360);
 514                         float sr = sin(r);
 515                         float cr = cos(r);
 516                         if(v_right)
 517                         {
 518                                 v_right.x = sr * sp * cy + cr * -sy;
 519                                 v_right.y = sr * sp * sy + cr * cy;
 520                                 v_right.z = sr * cp;
 521                         }
 522                         if(v_up)
 523                         {
 524                                 v_up.x = cr * sp * cy + -sr * -sy;
 525                                 v_up.y = cr * sp * sy + -sr * cy;
 526                                 v_up.z = cr * cp;
 527                         }
 528                 }
 529                 else
 530                 {
 531                         if(v_right)
 532                         {
 533                                 v_right.x = -sy;
 534                                 v_right.y = cy;
 535                                 v_right.z = 0;
 536                         }
 537                         if(v_up)
 538                         {
 539                                 v_up.x = sp * cy;
 540                                 v_up.y = sp * sy;
 541                                 v_up.z = cp;
 542                         }
 543                 }
 544         }
 545 }
 546
 547 void _Movetype_Physics_Frame(entity this, float movedt)
 548 {
 549         this.move_didgravity = -1;
 550         switch (this.move_movetype)
 551         {
 552                 case MOVETYPE_PUSH:
 553                 case MOVETYPE_FAKEPUSH:
 554                         _Movetype_Physics_Pusher(this, movedt);
 555                         break;
 556                 case MOVETYPE_NONE:
 557                         break;
 558                 case MOVETYPE_FOLLOW:
 559                         _Movetype_Physics_Follow(this);
 560                         break;
 561                 case MOVETYPE_NOCLIP:
 562                         _Movetype_CheckWater(this);
 563                         this.move_origin = this.move_origin + TICRATE * this.move_velocity;
 564                         this.move_angles = this.move_angles + TICRATE * this.move_avelocity;
 565                         _Movetype_LinkEdict(this, false);
 566                         break;
 567                 case MOVETYPE_STEP:
 568                         _Movetype_Physics_Step(this, movedt);
 569                         break;
 570                 case MOVETYPE_WALK:
 571                         _Movetype_Physics_Walk(this, movedt);
 572                         break;
 573                 case MOVETYPE_TOSS:
 574                 case MOVETYPE_BOUNCE:
 575                 case MOVETYPE_BOUNCEMISSILE:
 576                 case MOVETYPE_FLYMISSILE:
 577                 case MOVETYPE_FLY:
 578                 case MOVETYPE_FLY_WORLDONLY:
 579                         _Movetype_Physics_Toss(this, movedt);
 580                         _Movetype_LinkEdict(this, true);
 581                         break;
 582                 case MOVETYPE_PHYSICS:
 583                         break;
 584         }
 585 }
 586
 587 void _Movetype_Physics_ClientFrame(entity this, float movedt)
 588 {
 589         this.move_didgravity = -1;
 590         switch (this.move_movetype)
 591         {
 592                 case MOVETYPE_PUSH:
 593                 case MOVETYPE_FAKEPUSH:
 594                         _Movetype_Physics_Pusher(this, movedt);
 595                         break;
 596                 case MOVETYPE_NONE:
 597                         break;
 598                 case MOVETYPE_FOLLOW:
 599                         _Movetype_Physics_Follow(this);
 600                         break;
 601                 case MOVETYPE_NOCLIP:
 602                         _Movetype_CheckWater(this);
 603                         this.move_origin = this.move_origin + movedt * this.move_velocity;
 604                         this.move_angles = this.move_angles + movedt * this.move_avelocity;
 605                         _Movetype_LinkEdict(this, false);
 606                         break;
 607                 case MOVETYPE_STEP:
 608                         _Movetype_Physics_Step(this, movedt);
 609                         break;
 610                 case MOVETYPE_WALK:
 611                 case MOVETYPE_FLY:
 612                 case MOVETYPE_FLY_WORLDONLY:
 613                         _Movetype_Physics_Walk(this, movedt);
 614                         break;
 615                 case MOVETYPE_TOSS:
 616                 case MOVETYPE_BOUNCE:
 617                 case MOVETYPE_BOUNCEMISSILE:
 618                 case MOVETYPE_FLYMISSILE:
 619                         _Movetype_Physics_Toss(this, movedt);
 620                         break;
 621                 case MOVETYPE_PHYSICS:
 622                         break;
 623         }
 624 }
 625
 626 void Movetype_Physics_NoMatchServer(entity this)  // optimized
 627 {
 628         float movedt = time - this.move_time;
 629         this.move_time = time;
 630
 631         _Movetype_Physics_Frame(this, movedt);
 632         if(wasfreed(this))
 633                 return;
 634
 635         this.avelocity = this.move_avelocity;
 636         this.velocity = this.move_velocity;
 637         this.angles = this.move_angles;
 638         setorigin(this, this.move_origin);
 639 }
 640
 641 void Movetype_Physics_MatchServer(entity this, bool sloppy)
 642 {
 643         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
 644 }
 645
 646 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
 647 {
 648         if(tr <= 0)
 649         {
 650                 Movetype_Physics_NoMatchServer(this);
 651                 return;
 652         }
 653
 654         float dt = time - this.move_time;
 655
 656         int n = max(0, floor(dt / tr));
 657         dt -= n * tr;
 658         this.move_time += n * tr;
 659
 660         if(!this.move_didgravity)
 661                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.move_flags & FL_ONGROUND));
 662
 663         for (int i = 0; i < n; ++i)
 664         {
 665                 _Movetype_Physics_Frame(this, tr);
 666                 if(wasfreed(this))
 667                         return;
 668         }
 669
 670         this.avelocity = this.move_avelocity;
 671
 672         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.move_flags & FL_ONGROUND))
 673         {
 674                 // now continue the move from move_time to time
 675                 this.velocity = this.move_velocity;
 676
 677                 if(this.move_didgravity > 0)
 678                 {
 679                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
 680                             * dt
 681                             * (this.gravity ? this.gravity : 1)
 682                             * PHYS_GRAVITY(this);
 683                 }
 684
 685                 this.angles = this.move_angles + dt * this.avelocity;
 686
 687                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
 688                 {
 689                         setorigin(this, this.move_origin + dt * this.velocity);
 690                 }
 691                 else
 692                 {
 693                         _Movetype_PushEntityTrace(this, dt * this.velocity);
 694                         if(!trace_startsolid)
 695                                 setorigin(this, trace_endpos);
 696                 }
 697
 698                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 699                         this.velocity_z -= 0.5 * dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
 700         }
 701         else
 702         {
 703                 this.velocity = this.move_velocity;
 704                 this.angles = this.move_angles;
 705                 setorigin(this, this.move_origin);
 706         }
 707 }