qcsrc/common/physics/movetypes/movetypes.qc

   1 #include "movetypes.qh"
   2 #include "../player.qh"
   3
   4 #if defined(CSQC)
   5         #include <client/defs.qh>
   6         #include <common/stats.qh>
   7         #include <common/util.qh>
   8         #include <lib/csqcmodel/common.qh>
   9         #include <common/t_items.qh>
  10 #elif defined(MENUQC)
  11 #elif defined(SVQC)
  12         #include <server/autocvars.qh>
  13 #endif
  14
  15 #ifdef SVQC
  16 void set_movetype(entity this, int mt)
  17 {
  18         this.move_movetype = mt;
  19         if (mt == MOVETYPE_PHYSICS || mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH) {
  20                 this.move_qcphysics = false;
  21         }
  22         this.movetype = (this.move_qcphysics) ? MOVETYPE_NONE : mt;
  23 }
  24 #elif defined(CSQC)
  25 void set_movetype(entity this, int mt)
  26 {
  27         this.move_movetype = mt;
  28 }
  29 #endif
  30
  31 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
  32 {
  33         /*float d, i;
  34         vector into, side;
  35         makevectors(this.v_angle);
  36         d = (stepnormal * v_forward) + 0.5;
  37
  38         if(d < 0)
  39         {
  40             i = (stepnormal * this.velocity);
  41             into = i * stepnormal;
  42             side = this.velocity - into;
  43             this.velocity_x = side.x * (1 * d);
  44             this.velocity_y = side.y * (1 * d);
  45         }*/
  46 }
  47
  48 vector planes[MAX_CLIP_PLANES];
  49 int _Movetype_FlyMove(entity this, float dt, bool applygravity, vector stepnormal, float stepheight) // SV_FlyMove
  50 {
  51         int blocked = 0, bumpcount;
  52         int i, j, numplanes = 0;
  53         float time_left = dt, grav = 0;
  54         vector push;
  55         vector primal_velocity, original_velocity, restore_velocity;
  56
  57         for(i = 0; i < MAX_CLIP_PLANES; ++i)
  58                 planes[i] = '0 0 0';
  59
  60         if(applygravity)
  61         {
  62                 this.move_didgravity = 1;
  63                 grav = dt * (PHYS_ENTGRAVITY(this) ? PHYS_ENTGRAVITY(this) : 1) * PHYS_GRAVITY(this);
  64
  65                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
  66                 {
  67                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
  68                                 this.velocity_z -= grav * 0.5;
  69                         else
  70                                 this.velocity_z -= grav;
  71                 }
  72         }
  73
  74         original_velocity = primal_velocity = restore_velocity = this.velocity;
  75
  76         for(bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
  77         {
  78                 if(this.velocity == '0 0 0')
  79                         break;
  80
  81                 push = this.velocity * time_left;
  82                 _Movetype_PushEntity(this, push, true);
  83                 if(trace_startsolid)
  84                 {
  85                         // we got teleported by a touch function
  86                         // let's abort the move
  87                         blocked |= 8;
  88                         break;
  89                 }
  90
  91                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
  92                 // abort move if we're stuck in the world (and didn't make it out)
  93                 if(trace_startsolid && trace_allsolid)
  94                 {
  95                         this.velocity = restore_velocity;
  96                         return 3;
  97                 }
  98
  99                 if(trace_fraction == 1)
 100                         break;
 101
 102                 float my_trace_fraction = trace_fraction;
 103                 vector my_trace_plane_normal = trace_plane_normal;
 104
 105                 if(trace_plane_normal.z)
 106                 {
 107                         if(trace_plane_normal.z > 0.7)
 108                         {
 109                                 // floor
 110                                 blocked |= 1;
 111
 112                                 if(!trace_ent)
 113                                 {
 114                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
 115                                         trace_ent = NULL;
 116                                 }
 117
 118                                 SET_ONGROUND(this);
 119                                 this.groundentity = trace_ent;
 120                         }
 121                 }
 122                 else if(stepheight)
 123                 {
 124                         // step - handle it immediately
 125                         vector org = this.origin;
 126                         vector steppush = '0 0 1' * stepheight;
 127
 128                         _Movetype_PushEntity(this, steppush, true);
 129                         if(trace_startsolid)
 130                         {
 131                                 blocked |= 8;
 132                                 break;
 133                         }
 134                         _Movetype_PushEntity(this, push, true);
 135                         if(trace_startsolid)
 136                         {
 137                                 blocked |= 8;
 138                                 break;
 139                         }
 140                         float trace2_fraction = trace_fraction;
 141                         steppush = '0 0 1' * (org_z - this.origin_z);
 142                         _Movetype_PushEntity(this, steppush, true);
 143                         if(trace_startsolid)
 144                         {
 145                                 blocked |= 8;
 146                                 break;
 147                         }
 148
 149                         // accept the new position if it made some progress...
 150                         if(fabs(this.origin_x - org_x) >= 0.03125 || fabs(this.origin_y - org_y) >= 0.03125)
 151                         {
 152                                 trace_endpos = this.origin;
 153                                 time_left *= 1 - trace2_fraction;
 154                                 numplanes = 0;
 155                                 continue;
 156                         }
 157                         else
 158                                 this.origin = org;
 159                 }
 160                 else
 161                 {
 162                         // step - return it to caller
 163                         blocked |= 2;
 164                         // save the trace for player extrafriction
 165                         if(stepnormal)
 166                                 stepnormal = trace_plane_normal;
 167                 }
 168
 169                 if(my_trace_fraction >= 0.001)
 170                 {
 171                         // actually covered some distance
 172                         original_velocity = this.velocity;
 173                         numplanes = 0;
 174                 }
 175
 176                 time_left *= 1 - my_trace_fraction;
 177
 178                 // clipped to another plane
 179                 if(numplanes >= MAX_CLIP_PLANES)
 180                 {
 181                         // this shouldn't really happen
 182                         this.velocity = '0 0 0';
 183                         blocked = 3;
 184                         break;
 185                 }
 186
 187                 planes[numplanes] = my_trace_plane_normal;
 188                 numplanes++;
 189
 190                 // modify original_velocity so it parallels all of the clip planes
 191                 vector new_velocity = '0 0 0';
 192                 for (i = 0;i < numplanes;i++)
 193                 {
 194                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
 195                         for (j = 0;j < numplanes;j++)
 196                         {
 197                                 if(j != i)
 198                                 {
 199                                         // not ok
 200                                         if((new_velocity * planes[j]) < 0)
 201                                                 break;
 202                                 }
 203                         }
 204                         if(j == numplanes)
 205                                 break;
 206                 }
 207
 208                 if(i != numplanes)
 209                 {
 210                         // go along this plane
 211                         this.velocity = new_velocity;
 212                 }
 213                 else
 214                 {
 215                         // go along the crease
 216                         if(numplanes != 2)
 217                         {
 218                                 this.velocity = '0 0 0';
 219                                 blocked = 7;
 220                                 break;
 221                         }
 222                         vector dir = cross(planes[0], planes[1]);
 223                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
 224                         float ilength = sqrt((dir * dir));
 225                         if(ilength)
 226                                 ilength = 1.0 / ilength;
 227                         dir.x *= ilength;
 228                         dir.y *= ilength;
 229                         dir.z *= ilength;
 230                         float d = (dir * this.velocity);
 231                         this.velocity = dir * d;
 232                 }
 233
 234                 // if current velocity is against the original velocity,
 235                 // stop dead to avoid tiny occilations in sloping corners
 236                 if((this.velocity * primal_velocity) <= 0)
 237                 {
 238                         this.velocity = '0 0 0';
 239                         break;
 240                 }
 241         }
 242
 243         // LordHavoc: this came from QW and allows you to get out of water more easily
 244         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.flags & FL_WATERJUMP) && !(blocked & 8))
 245                 this.velocity = primal_velocity;
 246
 247         if(applygravity)
 248         {
 249                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
 250                 {
 251                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 252                                 this.velocity_z -= grav * 0.5f;
 253                 }
 254         }
 255
 256         return blocked;
 257 }
 258
 259 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
 260 {
 261         // if(vlen(this.velocity) < 0.0001)
 262         // this.velocity = '0 0 0';
 263 }
 264
 265 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
 266 {
 267         vector point = this.origin;
 268         point.z += this.mins.z + 1;
 269
 270         int nativecontents = pointcontents(point);
 271         if(this.watertype && this.watertype != nativecontents)
 272         {
 273                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.watertype, nativecontents);
 274                 if(this.contentstransition)
 275                         this.contentstransition(this.watertype, nativecontents);
 276         }
 277
 278         this.waterlevel = WATERLEVEL_NONE;
 279         this.watertype = CONTENT_EMPTY;
 280
 281         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
 282         if(supercontents & DPCONTENTS_LIQUIDSMASK)
 283         {
 284                 this.watertype = nativecontents;
 285                 this.waterlevel = WATERLEVEL_WETFEET;
 286                 point.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 287                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 288                 {
 289                         this.waterlevel = WATERLEVEL_SWIMMING;
 290                         point.z = this.origin.z + this.view_ofs.z;
 291                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 292                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 293                 }
 294         }
 295
 296         return this.waterlevel > 1;
 297 }
 298
 299 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
 300 {
 301         int contents = pointcontents(ent.origin);
 302
 303         if(!ent.watertype)
 304         {
 305                 // just spawned here
 306                 if(!GAMEPLAYFIX_WATERTRANSITION(ent))
 307                 {
 308                         ent.watertype = contents;
 309                         ent.waterlevel = 1;
 310                         return;
 311                 }
 312         }
 313         else if(ent.watertype != contents)
 314         {
 315                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.origin), pointcontents(ent.origin), ent.watertype, contents);
 316                 if(ent.contentstransition)
 317                         ent.contentstransition(ent.watertype, contents);
 318         }
 319
 320         if(contents <= CONTENT_WATER)
 321         {
 322                 ent.watertype = contents;
 323                 ent.waterlevel = 1;
 324         }
 325         else
 326         {
 327                 ent.watertype = CONTENT_EMPTY;
 328                 ent.waterlevel = (GAMEPLAYFIX_WATERTRANSITION(ent) ? 0 : contents);
 329         }
 330 }
 331
 332 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
 333 {
 334         if(gettouch(this))
 335                 gettouch(this)(this, oth);
 336
 337         if(gettouch(oth))
 338                 gettouch(oth)(oth, this);
 339 }
 340
 341 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
 342 {
 343         if(this.solid == SOLID_NOT)
 344                 return;
 345
 346     FOREACH_ENTITY_RADIUS(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 347                 if (it.solid == SOLID_TRIGGER && it != this)
 348                 if (it.move_nomonsters != MOVE_NOMONSTERS && it.move_nomonsters != MOVE_WORLDONLY)
 349                 if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax))
 350                 {
 351                         trace_allsolid = false;
 352                         trace_startsolid = false;
 353                         trace_fraction = 1;
 354                         trace_inwater = false;
 355                         trace_inopen = true;
 356                         trace_endpos = it.origin;
 357                         trace_plane_normal = '0 0 1';
 358                         trace_plane_dist = 0;
 359                         trace_ent = this;
 360
 361                         gettouch(it)(it, this);
 362                 }
 363     });
 364 }
 365
 366 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
 367 {
 368         vector mi, ma;
 369         if(this.solid == SOLID_BSP)
 370         {
 371                 // TODO set the absolute bbox
 372                 mi = this.mins;
 373                 ma = this.maxs;
 374         }
 375         else
 376         {
 377                 mi = this.mins;
 378                 ma = this.maxs;
 379         }
 380         mi += this.origin;
 381         ma += this.origin;
 382
 383         if(this.flags & FL_ITEM)
 384         {
 385                 mi.x -= 15;
 386                 mi.y -= 15;
 387                 mi.z -= 1;
 388                 ma.x += 15;
 389                 ma.y += 15;
 390                 ma.z += 1;
 391         }
 392         else
 393         {
 394                 mi.x -= 1;
 395                 mi.y -= 1;
 396                 mi.z -= 1;
 397                 ma.x += 1;
 398                 ma.y += 1;
 399                 ma.z += 1;
 400         }
 401
 402         this.absmin = mi;
 403         this.absmax = ma;
 404
 405         if(touch_triggers)
 406                 _Movetype_LinkEdict_TouchAreaGrid(this);
 407 }
 408
 409 entity _Movetype_TestEntityPosition_ent;
 410 bool _Movetype_TestEntityPosition(vector ofs)  // SV_TestEntityPosition
 411 {
 412     entity this = _Movetype_TestEntityPosition_ent;
 413 //      vector org = this.origin + ofs;
 414
 415         int cont = this.dphitcontentsmask;
 416         this.dphitcontentsmask = DPCONTENTS_SOLID;
 417         tracebox(this.origin, this.mins, this.maxs, this.origin, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
 418         this.dphitcontentsmask = cont;
 419
 420         if(trace_startsolid)
 421                 return true;
 422
 423         if(vdist(trace_endpos - this.origin, >, 0.0001))
 424                 this.origin = trace_endpos;
 425         return false;
 426 }
 427
 428 bool _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
 429 {
 430     _Movetype_TestEntityPosition_ent = this;
 431         if (!_Movetype_TestEntityPosition(' 0  0  0')) {
 432             return true;
 433         }
 434         #define X(v) if (_Movetype_TestEntityPosition(v))
 435         X('-1  0  0') X(' 1  0  0')
 436         X(' 0 -1  0') X(' 0  1  0')
 437         X('-1 -1  0') X(' 1 -1  0')
 438         X('-1  1  0') X(' 1  1  0')
 439         #undef X
 440         {
 441         #define X(i) \
 442             if (_Movetype_TestEntityPosition('0 0 -1' * i)) \
 443             if (_Movetype_TestEntityPosition('0 0 1' * i))
 444         X(01) X(02) X(03) X(04) X(05) X(06) X(07) X(08)
 445         X(09) X(10) X(11) X(12) X(13) X(14) X(15) X(16)
 446         X(17)
 447         #undef X
 448         {
 449             LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)",
 450                 etof(this), this.classname, vtos(this.origin));
 451             return false;
 452         }
 453         }
 454         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)",
 455                 etof(this), this.classname, vtos(this.origin));
 456         _Movetype_LinkEdict(this, true);
 457         return true;
 458 }
 459
 460 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // SV_ClipVelocity
 461 {
 462         vel -= ((vel * norm) * norm) * f;
 463
 464         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
 465         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
 466         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
 467
 468         return vel;
 469 }
 470
 471 void _Movetype_PushEntityTrace(entity this, vector push)
 472 {
 473         vector end = this.origin + push;
 474         int type;
 475         if(this.move_nomonsters)
 476                 type = max(0, this.move_nomonsters);
 477         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
 478                 type = MOVE_MISSILE;
 479         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
 480                 type = MOVE_WORLDONLY;
 481         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
 482                 type = MOVE_NOMONSTERS;
 483         else
 484                 type = MOVE_NORMAL;
 485
 486         tracebox(this.origin, this.mins, this.maxs, end, type, this);
 487 }
 488
 489 float _Movetype_PushEntity(entity this, vector push, bool failonstartsolid)  // SV_PushEntity
 490 {
 491         _Movetype_PushEntityTrace(this, push);
 492
 493         if(trace_startsolid && failonstartsolid)
 494                 return trace_fraction;
 495
 496         this.origin = trace_endpos;
 497
 498         if(trace_fraction < 1)
 499                 if(this.solid >= SOLID_TRIGGER && (!IS_ONGROUND(this) || (this.groundentity != trace_ent)))
 500                         _Movetype_Impact(this, trace_ent);
 501
 502         return trace_fraction;
 503 }
 504
 505
 506 .float ltime;
 507 .void() blocked;
 508
 509 void _Movetype_Physics_Frame(entity this, float movedt)
 510 {
 511         this.move_didgravity = -1;
 512         switch (this.move_movetype)
 513         {
 514                 case MOVETYPE_PUSH:
 515                 case MOVETYPE_FAKEPUSH:
 516                         LOG_DEBUGF("Physics: Lacking QuakeC support for Push movetype, FIX ME by using engine physics!");
 517                         break;
 518                 case MOVETYPE_NONE:
 519                         break;
 520                 case MOVETYPE_FOLLOW:
 521                         _Movetype_Physics_Follow(this);
 522                         break;
 523                 case MOVETYPE_NOCLIP:
 524                         _Movetype_CheckWater(this);
 525                         this.origin = this.origin + movedt * this.velocity;
 526                         this.angles = this.angles + movedt * this.avelocity;
 527                         _Movetype_LinkEdict(this, false);
 528                         break;
 529                 case MOVETYPE_STEP:
 530                         _Movetype_Physics_Step(this, movedt);
 531                         break;
 532                 case MOVETYPE_WALK:
 533                         _Movetype_Physics_Walk(this, movedt);
 534                         break;
 535                 case MOVETYPE_TOSS:
 536                 case MOVETYPE_BOUNCE:
 537                 case MOVETYPE_BOUNCEMISSILE:
 538                 case MOVETYPE_FLYMISSILE:
 539                 case MOVETYPE_FLY:
 540                 case MOVETYPE_FLY_WORLDONLY:
 541                         _Movetype_Physics_Toss(this, movedt);
 542                         _Movetype_LinkEdict(this, true);
 543                         break;
 544                 case MOVETYPE_PHYSICS:
 545                         break;
 546         }
 547 }
 548
 549 void _Movetype_Physics_ClientFrame(entity this, float movedt)
 550 {
 551         this.move_didgravity = -1;
 552         switch (this.move_movetype)
 553         {
 554                 case MOVETYPE_PUSH:
 555                 case MOVETYPE_FAKEPUSH:
 556                         LOG_DEBUGF("Physics: Lacking QuakeC support for Push movetype, FIX ME by using engine physics!");
 557                         break;
 558                 case MOVETYPE_NONE:
 559                         break;
 560                 case MOVETYPE_FOLLOW:
 561                         _Movetype_Physics_Follow(this);
 562                         break;
 563                 case MOVETYPE_NOCLIP:
 564                         _Movetype_CheckWater(this);
 565                         this.origin = this.origin + movedt * this.velocity;
 566                         this.angles = this.angles + movedt * this.avelocity;
 567                         _Movetype_LinkEdict(this, false);
 568                         break;
 569                 case MOVETYPE_STEP:
 570                         _Movetype_Physics_Step(this, movedt);
 571                         break;
 572                 case MOVETYPE_WALK:
 573                 case MOVETYPE_FLY:
 574                 case MOVETYPE_FLY_WORLDONLY:
 575                         _Movetype_Physics_Walk(this, movedt);
 576                         break;
 577                 case MOVETYPE_TOSS:
 578                 case MOVETYPE_BOUNCE:
 579                 case MOVETYPE_BOUNCEMISSILE:
 580                 case MOVETYPE_FLYMISSILE:
 581                         _Movetype_Physics_Toss(this, movedt);
 582                         break;
 583                 case MOVETYPE_PHYSICS:
 584                         break;
 585         }
 586 }
 587
 588 void Movetype_Physics_NoMatchTicrate(entity this, float movedt, bool isclient)  // to be run every move frame
 589 {
 590         this.move_time = time;
 591
 592         if(isclient)
 593                 _Movetype_Physics_ClientFrame(this, movedt);
 594         else
 595                 _Movetype_Physics_Frame(this, movedt);
 596         if(wasfreed(this))
 597                 return;
 598
 599         setorigin(this, this.origin);
 600 }
 601
 602 void Movetype_Physics_NoMatchServer(entity this)  // optimized
 603 {
 604         float movedt = time - this.move_time;
 605         this.move_time = time;
 606
 607         _Movetype_Physics_Frame(this, movedt);
 608         if(wasfreed(this))
 609                 return;
 610
 611         setorigin(this, this.origin);
 612 }
 613
 614 void Movetype_Physics_MatchServer(entity this, bool sloppy)
 615 {
 616         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
 617 }
 618
 619 .vector tic_origin;
 620 .vector tic_velocity;
 621 .int tic_flags;
 622 .vector tic_avelocity;
 623 .vector tic_angles;
 624
 625 .vector tic_saved_origin;
 626 .vector tic_saved_velocity;
 627 .int tic_saved_flags;
 628 .vector tic_saved_avelocity;
 629 .vector tic_saved_angles;
 630 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
 631 {
 632 #define X(s) \
 633         if(this.(s) != this.tic_saved_##s) \
 634                 this.tic_##s = this.(s)
 635
 636         X(origin);
 637         X(velocity);
 638         X(flags);
 639         X(avelocity);
 640         X(angles);
 641 #undef X
 642
 643         if(tr <= 0)
 644         {
 645                 this.flags = this.tic_flags;
 646                 this.velocity = this.tic_velocity;
 647                 this.origin = this.tic_origin;
 648                 this.avelocity = this.tic_avelocity;
 649                 this.angles = this.tic_angles;
 650                 Movetype_Physics_NoMatchServer(this);
 651                 this.tic_origin = this.origin;
 652                 this.tic_velocity = this.velocity;
 653                 this.tic_avelocity = this.avelocity;
 654                 this.tic_angles = this.angles;
 655                 this.tic_flags = this.flags;
 656
 657                 this.tic_saved_flags = this.flags;
 658                 this.tic_saved_velocity = this.velocity;
 659                 this.tic_saved_origin = this.origin;
 660                 this.tic_saved_avelocity = this.avelocity;
 661                 this.tic_saved_angles = this.angles;
 662                 return;
 663         }
 664
 665         float dt = time - this.move_time;
 666
 667         int n = max(0, floor(dt / tr));
 668         dt -= n * tr;
 669         this.move_time += n * tr;
 670
 671         if(!this.move_didgravity)
 672                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.tic_flags & FL_ONGROUND));
 673
 674         for (int i = 0; i < n; ++i)
 675         {
 676                 this.flags = this.tic_flags;
 677                 this.velocity = this.tic_velocity;
 678                 setorigin(this, this.tic_origin);
 679                 this.avelocity = this.tic_avelocity;
 680                 this.angles = this.tic_angles;
 681                 _Movetype_Physics_Frame(this, tr);
 682                 this.tic_origin = this.origin;
 683                 this.tic_velocity = this.velocity;
 684                 this.tic_avelocity = this.avelocity;
 685                 this.tic_angles = this.angles;
 686                 this.tic_flags = this.flags;
 687                 if(wasfreed(this))
 688                         return;
 689         }
 690
 691         this.avelocity = this.tic_avelocity;
 692
 693         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.tic_flags & FL_ONGROUND))
 694         {
 695                 // now continue the move from move_time to time
 696                 this.velocity = this.tic_velocity;
 697
 698                 if(this.move_didgravity > 0)
 699                 {
 700                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
 701                             * dt
 702                             * (this.gravity ? this.gravity : 1)
 703                             * PHYS_GRAVITY(this);
 704                 }
 705
 706                 this.angles = this.tic_angles + dt * this.avelocity;
 707
 708                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
 709                 {
 710                         setorigin(this, this.tic_origin + dt * this.velocity);
 711                 }
 712                 else
 713                 {
 714                         vector oldorg = this.origin;
 715                         this.origin = this.tic_origin;
 716                         _Movetype_PushEntityTrace(this, dt * this.velocity);
 717                         this.origin = oldorg;
 718                         if(!trace_startsolid)
 719                                 setorigin(this, trace_endpos);
 720                 }
 721
 722                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 723                         this.velocity_z -= 0.5 * dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
 724         }
 725         else
 726         {
 727                 this.velocity = this.tic_velocity;
 728                 this.angles = this.tic_angles;
 729                 setorigin(this, this.tic_origin);
 730         }
 731
 732         this.tic_saved_flags = this.flags;
 733         this.tic_saved_velocity = this.velocity;
 734         this.tic_saved_origin = this.origin;
 735         this.tic_saved_avelocity = this.avelocity;
 736         this.tic_saved_angles = this.angles;
 737 }