qcsrc/common/physics/movetypes/movetypes.qc

   1 #include "../player.qh"
   2
   3 #if defined(CSQC)
   4         #include "../../../client/defs.qh"
   5         #include "../../stats.qh"
   6         #include "../../util.qh"
   7         #include "movetypes.qh"
   8         #include "../../../lib/csqcmodel/common.qh"
   9         #include "../../../server/t_items.qh"
  10 #elif defined(MENUQC)
  11 #elif defined(SVQC)
  12         #include "../../../server/autocvars.qh"
  13 #endif
  14
  15 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
  16 {
  17         /*float d, i;
  18         vector into, side;
  19         makevectors(this.v_angle);
  20         d = (stepnormal * v_forward) + 0.5;
  21
  22         if(d < 0)
  23         {
  24             i = (stepnormal * this.move_velocity);
  25             into = i * stepnormal;
  26             side = this.move_velocity - into;
  27             this.move_velocity_x = side.x * (1 * d);
  28             this.move_velocity_y = side.y * (1 * d);
  29         }*/
  30 }
  31
  32 vector planes[MAX_CLIP_PLANES];
  33 int _Movetype_FlyMove(entity this, float dt, bool applygravity, vector stepnormal, float stepheight) // SV_FlyMove
  34 {
  35         int blocked = 0, bumpcount;
  36         int i, j, numplanes = 0;
  37         float time_left = dt, grav = 0;
  38         vector push;
  39         vector primal_velocity, original_velocity, restore_velocity;
  40
  41         for(i = 0; i < MAX_CLIP_PLANES; ++i)
  42                 planes[i] = '0 0 0';
  43
  44         if(applygravity)
  45         {
  46                 this.move_didgravity = 1;
  47                 grav = dt * (PHYS_ENTGRAVITY(this) ? PHYS_ENTGRAVITY(this) : 1) * PHYS_GRAVITY(this);
  48
  49                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
  50                 {
  51                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
  52                                 this.move_velocity_z -= grav * 0.5;
  53                         else
  54                                 this.move_velocity_z -= grav;
  55                 }
  56         }
  57
  58         original_velocity = primal_velocity = restore_velocity = this.move_velocity;
  59
  60         for(bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
  61         {
  62                 if(this.move_velocity == '0 0 0')
  63                         break;
  64
  65                 push = this.move_velocity * time_left;
  66                 _Movetype_PushEntity(this, push, true);
  67                 if(trace_startsolid)
  68                 {
  69                         // we got teleported by a touch function
  70                         // let's abort the move
  71                         blocked |= 8;
  72                         break;
  73                 }
  74
  75                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
  76                 // abort move if we're stuck in the world (and didn't make it out)
  77                 if(trace_startsolid && trace_allsolid)
  78                 {
  79                         this.move_velocity = restore_velocity;
  80                         return 3;
  81                 }
  82
  83                 if(trace_fraction == 1)
  84                         break;
  85
  86                 float my_trace_fraction = trace_fraction;
  87                 vector my_trace_plane_normal = trace_plane_normal;
  88
  89                 if(trace_plane_normal.z)
  90                 {
  91                         if(trace_plane_normal.z > 0.7)
  92                         {
  93                                 // floor
  94                                 blocked |= 1;
  95
  96                                 if(!trace_ent)
  97                                 {
  98                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
  99                                         trace_ent = world;
 100                                 }
 101
 102                                 this.move_flags |= FL_ONGROUND;
 103                                 this.move_groundentity = trace_ent;
 104                         }
 105                 }
 106                 else if(stepheight)
 107                 {
 108                         // step - handle it immediately
 109                         vector org = this.move_origin;
 110                         vector steppush = '0 0 1' * stepheight;
 111
 112                         _Movetype_PushEntity(this, steppush, true);
 113                         if(trace_startsolid)
 114                         {
 115                                 blocked |= 8;
 116                                 break;
 117                         }
 118                         _Movetype_PushEntity(this, push, true);
 119                         if(trace_startsolid)
 120                         {
 121                                 blocked |= 8;
 122                                 break;
 123                         }
 124                         float trace2_fraction = trace_fraction;
 125                         steppush = '0 0 1' * (org_z - this.move_origin_z);
 126                         _Movetype_PushEntity(this, steppush, true);
 127                         if(trace_startsolid)
 128                         {
 129                                 blocked |= 8;
 130                                 break;
 131                         }
 132
 133                         // accept the new position if it made some progress...
 134                         if(fabs(this.move_origin_x - org_x) >= 0.03125 || fabs(this.move_origin_y - org_y) >= 0.03125)
 135                         {
 136                                 trace_endpos = this.move_origin;
 137                                 time_left *= 1 - trace2_fraction;
 138                                 numplanes = 0;
 139                                 continue;
 140                         }
 141                         else
 142                                 this.move_origin = org;
 143                 }
 144                 else
 145                 {
 146                         // step - return it to caller
 147                         blocked |= 2;
 148                         // save the trace for player extrafriction
 149                         if(stepnormal)
 150                                 stepnormal = trace_plane_normal;
 151                 }
 152
 153                 if(my_trace_fraction >= 0.001)
 154                 {
 155                         // actually covered some distance
 156                         original_velocity = this.move_velocity;
 157                         numplanes = 0;
 158                 }
 159
 160                 time_left *= 1 - my_trace_fraction;
 161
 162                 // clipped to another plane
 163                 if(numplanes >= MAX_CLIP_PLANES)
 164                 {
 165                         // this shouldn't really happen
 166                         this.move_velocity = '0 0 0';
 167                         blocked = 3;
 168                         break;
 169                 }
 170
 171                 planes[numplanes] = my_trace_plane_normal;
 172                 numplanes++;
 173
 174                 // modify original_velocity so it parallels all of the clip planes
 175                 vector new_velocity = '0 0 0';
 176                 for (i = 0;i < numplanes;i++)
 177                 {
 178                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
 179                         for (j = 0;j < numplanes;j++)
 180                         {
 181                                 if(j != i)
 182                                 {
 183                                         // not ok
 184                                         if((new_velocity * planes[j]) < 0)
 185                                                 break;
 186                                 }
 187                         }
 188                         if(j == numplanes)
 189                                 break;
 190                 }
 191
 192                 if(i != numplanes)
 193                 {
 194                         // go along this plane
 195                         this.move_velocity = new_velocity;
 196                 }
 197                 else
 198                 {
 199                         // go along the crease
 200                         if(numplanes != 2)
 201                         {
 202                                 this.move_velocity = '0 0 0';
 203                                 blocked = 7;
 204                                 break;
 205                         }
 206                         vector dir = cross(planes[0], planes[1]);
 207                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
 208                         float ilength = sqrt((dir * dir));
 209                         if(ilength)
 210                                 ilength = 1.0 / ilength;
 211                         dir.x *= ilength;
 212                         dir.y *= ilength;
 213                         dir.z *= ilength;
 214                         float d = (dir * this.move_velocity);
 215                         this.move_velocity = dir * d;
 216                 }
 217
 218                 // if current velocity is against the original velocity,
 219                 // stop dead to avoid tiny occilations in sloping corners
 220                 if((this.move_velocity * primal_velocity) <= 0)
 221                 {
 222                         this.move_velocity = '0 0 0';
 223                         break;
 224                 }
 225         }
 226
 227         // LordHavoc: this came from QW and allows you to get out of water more easily
 228         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.move_flags & FL_WATERJUMP) && !(blocked & 8))
 229                 this.move_velocity = primal_velocity;
 230
 231         if(applygravity)
 232         {
 233                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
 234                 {
 235                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 236                                 this.move_velocity_z -= grav * 0.5f;
 237                 }
 238         }
 239
 240         return blocked;
 241 }
 242
 243 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
 244 {
 245         // if(vlen(this.move_velocity) < 0.0001)
 246         // this.move_velocity = '0 0 0';
 247 }
 248
 249 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
 250 {
 251         vector point = this.move_origin;
 252         point.z += this.mins.z + 1;
 253
 254         int nativecontents = pointcontents(point);
 255         if(this.move_watertype && this.move_watertype != nativecontents)
 256         {
 257                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.move_watertype, nativecontents);
 258                 if(this.contentstransition)
 259                         this.contentstransition(this.move_watertype, nativecontents);
 260         }
 261
 262         this.move_waterlevel = WATERLEVEL_NONE;
 263         this.move_watertype = CONTENT_EMPTY;
 264
 265         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
 266         if(supercontents & DPCONTENTS_LIQUIDSMASK)
 267         {
 268                 this.move_watertype = nativecontents;
 269                 this.move_waterlevel = WATERLEVEL_WETFEET;
 270                 point.z = this.move_origin.z + (this.mins.z + this.maxs.z) * 0.5;
 271                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 272                 {
 273                         this.move_waterlevel = WATERLEVEL_SWIMMING;
 274                         point.z = this.move_origin.z + this.view_ofs.z;
 275                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 276                                 this.move_waterlevel = WATERLEVEL_SUBMERGED;
 277                 }
 278         }
 279
 280         return this.move_waterlevel > 1;
 281 }
 282
 283 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
 284 {
 285         int contents = pointcontents(ent.move_origin);
 286
 287         if(!ent.move_watertype)
 288         {
 289                 // just spawned here
 290                 if(!autocvar_cl_gameplayfix_fixedcheckwatertransition)
 291                 {
 292                         ent.move_watertype = contents;
 293                         ent.move_waterlevel = 1;
 294                         return;
 295                 }
 296         }
 297         else if(ent.move_watertype != contents)
 298         {
 299                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.move_origin), pointcontents(ent.move_origin), ent.move_watertype, contents);
 300                 if(ent.contentstransition)
 301                         ent.contentstransition(ent.move_watertype, contents);
 302         }
 303
 304         if(contents <= CONTENT_WATER)
 305         {
 306                 ent.move_watertype = contents;
 307                 ent.move_waterlevel = 1;
 308         }
 309         else
 310         {
 311                 ent.move_watertype = CONTENT_EMPTY;
 312                 ent.move_waterlevel = (autocvar_cl_gameplayfix_fixedcheckwatertransition ? 0 : contents);
 313         }
 314 }
 315
 316 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
 317 {
 318         entity oldother = other;
 319
 320         if(this.move_touch)
 321         {
 322                 other = oth;
 323
 324                 WITH(entity, self, this, this.move_touch());
 325
 326                 other = oldother;
 327         }
 328
 329         if(oth.move_touch)
 330         {
 331                 other = this;
 332
 333                 WITH(entity, self, oth, oth.move_touch());
 334
 335                 other = oldother;
 336         }
 337 }
 338
 339 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
 340 {
 341         entity oldother = other;
 342
 343         for (entity e = findradius(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin)); e; e = e.chain)
 344         {
 345                 if(e.move_nomonsters != MOVE_NOMONSTERS && e.move_nomonsters != MOVE_WORLDONLY)
 346                 if(e.move_touch && boxesoverlap(e.absmin, e.absmax, this.absmin, this.absmax))
 347                 {
 348                         other = this;
 349
 350                         trace_allsolid = false;
 351                         trace_startsolid = false;
 352                         trace_fraction = 1;
 353                         trace_inwater = false;
 354                         trace_inopen = true;
 355                         trace_endpos = e.move_origin;
 356                         trace_plane_normal = '0 0 1';
 357                         trace_plane_dist = 0;
 358                         trace_ent = this;
 359
 360                         WITH(entity, self, e, e.move_touch());
 361                 }
 362         }
 363
 364         other = oldother;
 365 }
 366
 367 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
 368 {
 369         vector mi, ma;
 370         if(this.solid == SOLID_BSP)
 371         {
 372                 // TODO set the absolute bbox
 373                 mi = this.mins;
 374                 ma = this.maxs;
 375         }
 376         else
 377         {
 378                 mi = this.mins;
 379                 ma = this.maxs;
 380         }
 381         mi += this.move_origin;
 382         ma += this.move_origin;
 383
 384         if(this.move_flags & FL_ITEM)
 385         {
 386                 mi.x -= 15;
 387                 mi.y -= 15;
 388                 mi.z -= 1;
 389                 ma.x += 15;
 390                 ma.y += 15;
 391                 ma.z += 1;
 392         }
 393         else
 394         {
 395                 mi.x -= 1;
 396                 mi.y -= 1;
 397                 mi.z -= 1;
 398                 ma.x += 1;
 399                 ma.y += 1;
 400                 ma.z += 1;
 401         }
 402
 403         this.absmin = mi;
 404         this.absmax = ma;
 405
 406         if(touch_triggers)
 407                 _Movetype_LinkEdict_TouchAreaGrid(this);
 408 }
 409
 410 bool _Movetype_TestEntityPosition(entity this, vector ofs)  // SV_TestEntityPosition
 411 {
 412 //      vector org = this.move_origin + ofs;
 413
 414         int cont = this.dphitcontentsmask;
 415         this.dphitcontentsmask = DPCONTENTS_SOLID;
 416         tracebox(this.move_origin, this.mins, this.maxs, this.move_origin, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
 417         this.dphitcontentsmask = cont;
 418
 419         if(trace_startsolid)
 420                 return true;
 421
 422         if(vlen(trace_endpos - this.move_origin) > 0.0001)
 423                 this.move_origin = trace_endpos;
 424         return false;
 425 }
 426
 427 bool _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
 428 {
 429         if(!_Movetype_TestEntityPosition(this, '0 0 0')) return true;
 430         if(!_Movetype_TestEntityPosition(this, '-1 0 0')) goto success;
 431         if(!_Movetype_TestEntityPosition(this, '1 0 0')) goto success;
 432         if(!_Movetype_TestEntityPosition(this, '0 -1 0')) goto success;
 433         if(!_Movetype_TestEntityPosition(this, '0 1 0')) goto success;
 434         if(!_Movetype_TestEntityPosition(this, '-1 -1 0')) goto success;
 435         if(!_Movetype_TestEntityPosition(this, '1 -1 0')) goto success;
 436         if(!_Movetype_TestEntityPosition(this, '-1 1 0')) goto success;
 437         if(!_Movetype_TestEntityPosition(this, '1 1 0')) goto success;
 438         for (int i = 1; i <= 17; ++i)
 439         {
 440                 if(!_Movetype_TestEntityPosition(this, '0 0 -1' * i)) goto success;
 441                 if(!_Movetype_TestEntityPosition(this, '0 0 1' * i)) goto success;
 442         }
 443         LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)\n",
 444                 etof(this), this.classname, vtos(this.move_origin));
 445         return false;
 446         : success;
 447         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)\n",
 448                 etof(this), this.classname, vtos(this.move_origin));
 449         _Movetype_LinkEdict(this, true);
 450         return true;
 451 }
 452
 453 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // SV_ClipVelocity
 454 {
 455         vel -= ((vel * norm) * norm) * f;
 456
 457         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
 458         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
 459         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
 460
 461         return vel;
 462 }
 463
 464 void _Movetype_PushEntityTrace(entity this, vector push)
 465 {
 466         vector end = this.move_origin + push;
 467         int type;
 468         if(this.move_nomonsters)
 469                 type = max(0, this.move_nomonsters);
 470         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
 471                 type = MOVE_MISSILE;
 472         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
 473                 type = MOVE_WORLDONLY;
 474         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
 475                 type = MOVE_NOMONSTERS;
 476         else
 477                 type = MOVE_NORMAL;
 478
 479         tracebox(this.move_origin, this.mins, this.maxs, end, type, this);
 480 }
 481
 482 float _Movetype_PushEntity(entity this, vector push, bool failonstartsolid)  // SV_PushEntity
 483 {
 484         _Movetype_PushEntityTrace(this, push);
 485
 486         if(trace_startsolid && failonstartsolid)
 487                 return trace_fraction;
 488
 489         this.move_origin = trace_endpos;
 490
 491         if(trace_fraction < 1)
 492                 if(this.solid >= SOLID_TRIGGER && (!(this.move_flags & FL_ONGROUND) || (this.move_groundentity != trace_ent)))
 493                         _Movetype_Impact(this, trace_ent);
 494
 495         return trace_fraction;
 496 }
 497
 498
 499 .float ltime;
 500 .void() blocked;
 501 // matrix version of makevectors, sets v_forward, v_right and v_up
 502 void makevectors_matrix(vector myangles)  // AngleVectorsFLU
 503 {
 504         v_forward = v_right = v_up = '0 0 0';
 505
 506         float y = myangles.y * (M_PI * 2 / 360);
 507         float sy = sin(y);
 508         float cy = cos(y);
 509         float p = myangles.x * (M_PI * 2 / 360);
 510         float sp = sin(p);
 511         float cp = cos(p);
 512         if(v_forward)
 513         {
 514                 v_forward.x = cp * cy;
 515                 v_forward.y = cp * sy;
 516                 v_forward.z = -sp;
 517         }
 518         if(v_right || v_up)
 519         {
 520                 if(myangles.z)
 521                 {
 522                         float r = myangles.z * (M_PI * 2 / 360);
 523                         float sr = sin(r);
 524                         float cr = cos(r);
 525                         if(v_right)
 526                         {
 527                                 v_right.x = sr * sp * cy + cr * -sy;
 528                                 v_right.y = sr * sp * sy + cr * cy;
 529                                 v_right.z = sr * cp;
 530                         }
 531                         if(v_up)
 532                         {
 533                                 v_up.x = cr * sp * cy + -sr * -sy;
 534                                 v_up.y = cr * sp * sy + -sr * cy;
 535                                 v_up.z = cr * cp;
 536                         }
 537                 }
 538                 else
 539                 {
 540                         if(v_right)
 541                         {
 542                                 v_right.x = -sy;
 543                                 v_right.y = cy;
 544                                 v_right.z = 0;
 545                         }
 546                         if(v_up)
 547                         {
 548                                 v_up.x = sp * cy;
 549                                 v_up.y = sp * sy;
 550                                 v_up.z = cp;
 551                         }
 552                 }
 553         }
 554 }
 555
 556 void _Movetype_Physics_Frame(entity this, float movedt)
 557 {
 558         this.move_didgravity = -1;
 559         switch (this.move_movetype)
 560         {
 561                 case MOVETYPE_PUSH:
 562                 case MOVETYPE_FAKEPUSH:
 563                         _Movetype_Physics_Pusher(this, movedt);
 564                         break;
 565                 case MOVETYPE_NONE:
 566                         break;
 567                 case MOVETYPE_FOLLOW:
 568                         _Movetype_Physics_Follow(this);
 569                         break;
 570                 case MOVETYPE_NOCLIP:
 571                         _Movetype_CheckWater(this);
 572                         this.move_origin = this.move_origin + TICRATE * this.move_velocity;
 573                         this.move_angles = this.move_angles + TICRATE * this.move_avelocity;
 574                         _Movetype_LinkEdict(this, false);
 575                         break;
 576                 case MOVETYPE_STEP:
 577                         _Movetype_Physics_Step(this, movedt);
 578                         break;
 579                 case MOVETYPE_WALK:
 580                         _Movetype_Physics_Walk(this, movedt);
 581                         break;
 582                 case MOVETYPE_TOSS:
 583                 case MOVETYPE_BOUNCE:
 584                 case MOVETYPE_BOUNCEMISSILE:
 585                 case MOVETYPE_FLYMISSILE:
 586                 case MOVETYPE_FLY:
 587                 case MOVETYPE_FLY_WORLDONLY:
 588                         _Movetype_Physics_Toss(this, movedt);
 589                         _Movetype_LinkEdict(this, true);
 590                         break;
 591                 case MOVETYPE_PHYSICS:
 592                         break;
 593         }
 594 }
 595
 596 void _Movetype_Physics_ClientFrame(entity this, float movedt)
 597 {
 598         this.move_didgravity = -1;
 599         switch (this.move_movetype)
 600         {
 601                 case MOVETYPE_PUSH:
 602                 case MOVETYPE_FAKEPUSH:
 603                         _Movetype_Physics_Pusher(this, movedt);
 604                         break;
 605                 case MOVETYPE_NONE:
 606                         break;
 607                 case MOVETYPE_FOLLOW:
 608                         _Movetype_Physics_Follow(this);
 609                         break;
 610                 case MOVETYPE_NOCLIP:
 611                         _Movetype_CheckWater(this);
 612                         this.move_origin = this.move_origin + TICRATE * this.move_velocity;
 613                         this.move_angles = this.move_angles + TICRATE * this.move_avelocity;
 614                         _Movetype_LinkEdict(this, false);
 615                         break;
 616                 case MOVETYPE_STEP:
 617                         _Movetype_Physics_Step(this, movedt);
 618                         break;
 619                 case MOVETYPE_WALK:
 620                 case MOVETYPE_FLY:
 621                 case MOVETYPE_FLY_WORLDONLY:
 622                         _Movetype_Physics_Walk(this, movedt);
 623                         break;
 624                 case MOVETYPE_TOSS:
 625                 case MOVETYPE_BOUNCE:
 626                 case MOVETYPE_BOUNCEMISSILE:
 627                 case MOVETYPE_FLYMISSILE:
 628                         _Movetype_Physics_Toss(this, movedt);
 629                         break;
 630                 case MOVETYPE_PHYSICS:
 631                         break;
 632         }
 633 }
 634
 635 void Movetype_Physics_NoMatchServer(entity this)  // optimized
 636 {
 637         float movedt = time - this.move_time;
 638         this.move_time = time;
 639
 640         _Movetype_Physics_Frame(this, movedt);
 641         if(wasfreed(this))
 642                 return;
 643
 644         this.avelocity = this.move_avelocity;
 645         this.velocity = this.move_velocity;
 646         this.angles = this.move_angles;
 647         setorigin(this, this.move_origin);
 648 }
 649
 650 void Movetype_Physics_MatchServer(entity this, bool sloppy)
 651 {
 652         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
 653 }
 654
 655 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
 656 {
 657         if(tr <= 0)
 658         {
 659                 Movetype_Physics_NoMatchServer(this);
 660                 return;
 661         }
 662
 663         float dt = time - this.move_time;
 664
 665         int n = max(0, floor(dt / tr));
 666         dt -= n * tr;
 667         this.move_time += n * tr;
 668
 669         if(!this.move_didgravity)
 670                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.move_flags & FL_ONGROUND));
 671
 672         for (int i = 0; i < n; ++i)
 673         {
 674                 _Movetype_Physics_Frame(this, tr);
 675                 if(wasfreed(this))
 676                         return;
 677         }
 678
 679         this.avelocity = this.move_avelocity;
 680
 681         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.move_flags & FL_ONGROUND))
 682         {
 683                 // now continue the move from move_time to time
 684                 this.velocity = this.move_velocity;
 685
 686                 if(this.move_didgravity > 0)
 687                 {
 688                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
 689                             * dt
 690                             * (this.gravity ? this.gravity : 1)
 691                             * PHYS_GRAVITY(this);
 692                 }
 693
 694                 this.angles = this.move_angles + dt * this.avelocity;
 695
 696                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
 697                 {
 698                         setorigin(this, this.move_origin + dt * this.velocity);
 699                 }
 700                 else
 701                 {
 702                         _Movetype_PushEntityTrace(this, dt * this.velocity);
 703                         if(!trace_startsolid)
 704                                 setorigin(this, trace_endpos);
 705                 }
 706
 707                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 708                         this.velocity_z -= 0.5 * dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
 709         }
 710         else
 711         {
 712                 this.velocity = this.move_velocity;
 713                 this.angles = this.move_angles;
 714                 setorigin(this, this.move_origin);
 715         }
 716 }