qcsrc/common/playerstats.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4     #include "constants.qh"
   5     #include "util.qh"
   6     #include "weapons/all.qh"
   7     #include "../server/weapons/accuracy.qh"
   8     #include "../server/defs.qh"
   9     #include "playerstats.qh"
  10     #include "../server/scores.qh"
  11 #endif
  12
  13 #ifdef SVQC
  14 void PlayerStats_Prematch(void)
  15 {
  16         //foobar
  17 }
  18
  19 void PlayerStats_GameReport_AddPlayer(entity e)
  20 {
  21         if((PS_GR_OUT_DB < 0) || (e.playerstats_id)) { return; }
  22
  23         // set up player identification
  24         string s = string_null;
  25
  26         if((e.crypto_idfp != "") && (e.cvar_cl_allow_uidtracking == 1))
  27                 { s = e.crypto_idfp; }
  28         else if(IS_BOT_CLIENT(e))
  29                 { s = sprintf("bot#%g#%s", skill, e.cleanname); }
  30
  31         if((s == "") || find(world, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
  32         {
  33                 if(IS_BOT_CLIENT(e))
  34                         { s = sprintf("bot#%d", e.playerid); }
  35                 else
  36                         { s = sprintf("player#%d", e.playerid); }
  37         }
  38
  39         e.playerstats_id = strzone(s);
  40
  41         // now add the player to the database
  42         string key = sprintf("%s:*", e.playerstats_id);
  43         string p = db_get(PS_GR_OUT_DB, key);
  44
  45         if(p == "")
  46         {
  47                 if(PS_GR_OUT_PL)
  48                 {
  49                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_PL);
  50                         strunzone(PS_GR_OUT_PL);
  51                 }
  52                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  53                 PS_GR_OUT_PL = strzone(e.playerstats_id);
  54         }
  55 }
  56
  57 void PlayerStats_GameReport_AddTeam(float t)
  58 {
  59         if(PS_GR_OUT_DB < 0) { return; }
  60
  61         string key = sprintf("%d", t);
  62         string p = db_get(PS_GR_OUT_DB, key);
  63
  64         if(p == "")
  65         {
  66                 if(PS_GR_OUT_TL)
  67                 {
  68                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_TL);
  69                         strunzone(PS_GR_OUT_TL);
  70                 }
  71                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  72                 PS_GR_OUT_TL = strzone(key);
  73         }
  74 }
  75
  76 void PlayerStats_GameReport_AddEvent(string event_id)
  77 {
  78         if(PS_GR_OUT_DB < 0) { return; }
  79
  80         string key = sprintf("*:%s", event_id);
  81         string p = db_get(PS_GR_OUT_DB, key);
  82
  83         if(p == "")
  84         {
  85                 if(PS_GR_OUT_EVL)
  86                 {
  87                         db_put(PS_GR_OUT_DB, key, PS_GR_OUT_EVL);
  88                         strunzone(PS_GR_OUT_EVL);
  89                 }
  90                 else { db_put(PS_GR_OUT_DB, key, "#"); }
  91                 PS_GR_OUT_EVL = strzone(event_id);
  92         }
  93 }
  94
  95 // referred to by PS_GR_P_ADDVAL and PS_GR_T_ADDVAL
  96 float PlayerStats_GameReport_Event(string prefix, string event_id, float value)
  97 {
  98         if((prefix == "") || PS_GR_OUT_DB < 0) { return 0; }
  99
 100         string key = sprintf("%s:%s", prefix, event_id);
 101         float val = stof(db_get(PS_GR_OUT_DB, key));
 102         val += value;
 103         db_put(PS_GR_OUT_DB, key, ftos(val));
 104         return val;
 105 }
 106
 107 void PlayerStats_GameReport_Accuracy(entity p)
 108 {
 109         int i;
 110
 111         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 112         {
 113                 entity w = get_weaponinfo(i);
 114
 115                 #define ACCMAC(suffix,field) \
 116                         PS_GR_P_ADDVAL(p, sprintf("acc-%s-%s", w.netname, suffix), p.accuracy.(field[i-1]));
 117
 118                 ACCMAC("hit", accuracy_hit)
 119                 ACCMAC("fired", accuracy_fired)
 120                 ACCMAC("cnt-hit", accuracy_cnt_hit)
 121                 ACCMAC("cnt-fired", accuracy_cnt_fired)
 122                 ACCMAC("frags", accuracy_frags)
 123
 124                 #undef ACCMAC
 125         }
 126 }
 127
 128 void PlayerStats_GameReport_FinalizePlayer(entity p)
 129 {
 130         if((p.playerstats_id == "") || PS_GR_OUT_DB < 0) { return; }
 131
 132         // add global info!
 133         if(p.alivetime)
 134         {
 135                 PS_GR_P_ADDVAL(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 136                 p.alivetime = 0;
 137         }
 138
 139         db_put(PS_GR_OUT_DB, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 140
 141         if(p.cvar_cl_allow_uid2name == 1 || IS_BOT_CLIENT(p))
 142                 db_put(PS_GR_OUT_DB, sprintf("%s:_netname", p.playerstats_id), p.netname);
 143
 144         if(teamplay)
 145                 db_put(PS_GR_OUT_DB, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 146
 147         if(stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 148                 PS_GR_P_ADDVAL(p, PLAYERSTATS_JOINS, 1);
 149
 150         PlayerStats_GameReport_Accuracy(p);
 151
 152         if(IS_REAL_CLIENT(p))
 153         {
 154                 if(p.latency_cnt)
 155                 {
 156                         float latency = (p.latency_sum / p.latency_cnt);
 157                         if(latency) { PS_GR_P_ADDVAL(p, PLAYERSTATS_AVGLATENCY, latency); }
 158                 }
 159         }
 160
 161         strunzone(p.playerstats_id);
 162         p.playerstats_id = string_null;
 163 }
 164
 165 void PlayerStats_GameReport(float finished)
 166 {
 167         if(PS_GR_OUT_DB < 0) { return; }
 168
 169         PlayerScore_Sort(score_dummyfield, 0, 0, 0);
 170         PlayerScore_Sort(scoreboard_pos, 1, 1, 1);
 171         if(teamplay) { PlayerScore_TeamStats(); }
 172
 173         entity p;
 174         FOR_EACH_CLIENT(p)
 175         {
 176                 // add personal score rank
 177                 PS_GR_P_ADDVAL(p, PLAYERSTATS_RANK, p.score_dummyfield);
 178
 179                 // scoreboard data
 180                 if(p.scoreboard_pos)
 181                 {
 182                         // scoreboard is valid!
 183                         PS_GR_P_ADDVAL(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
 184
 185                         // add scoreboard position
 186                         PS_GR_P_ADDVAL(p, PLAYERSTATS_SCOREBOARD_POS, p.scoreboard_pos);
 187
 188                         // add scoreboard data
 189                         PlayerScore_PlayerStats(p);
 190
 191                         // if the match ended normally, add winning info
 192                         if(finished)
 193                         {
 194                                 PS_GR_P_ADDVAL(p, PLAYERSTATS_WINS, p.winning);
 195                                 PS_GR_P_ADDVAL(p, PLAYERSTATS_MATCHES, 1);
 196                         }
 197                 }
 198
 199                 // collect final player information
 200                 PlayerStats_GameReport_FinalizePlayer(p);
 201         }
 202
 203         if(autocvar_g_playerstats_gamereport_uri != "")
 204         {
 205                 PlayerStats_GameReport_DelayMapVote = true;
 206                 url_multi_fopen(
 207                         autocvar_g_playerstats_gamereport_uri,
 208                         FILE_APPEND,
 209                         PlayerStats_GameReport_Handler,
 210                         world
 211                 );
 212         }
 213         else
 214         {
 215                 PlayerStats_GameReport_DelayMapVote = false;
 216                 db_close(PS_GR_OUT_DB);
 217                 PS_GR_OUT_DB = -1;
 218         }
 219 }
 220
 221 void PlayerStats_GameReport_Init() // initiated before InitGameplayMode so that scores are added properly
 222 {
 223         if(autocvar_g_playerstats_gamereport_uri == "") { return; }
 224
 225         PS_GR_OUT_DB = db_create();
 226
 227         if(PS_GR_OUT_DB >= 0)
 228         {
 229                 PlayerStats_GameReport_DelayMapVote = true;
 230
 231                 serverflags |= SERVERFLAG_PLAYERSTATS;
 232
 233                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ALIVETIME);
 234                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_AVGLATENCY);
 235                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_WINS);
 236                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_MATCHES);
 237                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_JOINS);
 238                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
 239                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
 240                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_RANK);
 241
 242                 // accuracy stats
 243                 entity w;
 244                 float i;
 245                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 246                 {
 247                         w = get_weaponinfo(i);
 248                         PlayerStats_GameReport_AddEvent(strcat("acc-", w.netname, "-hit"));
 249                         PlayerStats_GameReport_AddEvent(strcat("acc-", w.netname, "-fired"));
 250                         PlayerStats_GameReport_AddEvent(strcat("acc-", w.netname, "-cnt-hit"));
 251                         PlayerStats_GameReport_AddEvent(strcat("acc-", w.netname, "-cnt-fired"));
 252                         PlayerStats_GameReport_AddEvent(strcat("acc-", w.netname, "-frags"));
 253                 }
 254
 255                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
 256                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
 257                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
 258                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
 259                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
 260                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
 261                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
 262                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
 263                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
 264                 PlayerStats_GameReport_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
 265         }
 266         else { PlayerStats_GameReport_DelayMapVote = false; }
 267 }
 268
 269 void PlayerStats_GameReport_Handler(entity fh, entity pass, float status)
 270 {
 271         string t, tn;
 272         string p, pn;
 273         string e, en;
 274         string nn, tt;
 275         string s;
 276
 277         switch(status)
 278         {
 279                 // ======================================
 280                 // -- OUTGOING GAME REPORT INFORMATION --
 281                 // ======================================
 282                 /* SPECIFICATIONS:
 283                  * V: format version (always a fixed number) - this MUST be the first line!
 284                  * #: comment (MUST be ignored by any parser)
 285                  * R: release information on the server
 286                  * G: game type
 287                  * O: mod name (icon request) as in server browser
 288                  * M: map name
 289                  * I: match ID (see "matchid" in g_world.qc)
 290                  * S: "hostname" of the server
 291                  * C: number of "unpure" cvar changes
 292                  * U: UDP port number of the server
 293                  * D: duration of the match
 294                  * L: "ladder" in which the server is participating in
 295                  * P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 296                  * Q: team number of an existing team (format: team#NN); this also sets the owner for all following "e" lines (lower case!)
 297                  * i: player index
 298                  * n: nickname of the player (optional)
 299                  * t: team ID
 300                  * e: followed by an event name, a space, and the event count/score
 301                  *  event names can be:
 302                  *   alivetime: total playing time of the player
 303                  *   avglatency: average network latency compounded throughout the match
 304                  *   wins: number of games won (can only be set if matches is set)
 305                  *   matches: number of matches played to the end (not aborted by map switch)
 306                  *   joins: number of matches joined (always 1 unless player never played during the match)
 307                  *   scoreboardvalid: set to 1 if the player was there at the end of the match
 308                  *   total-<scoreboardname>: total score of that scoreboard item
 309                  *   scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 310                  *   achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
 311                  *   kills-<index>: number of kills against the indexed player
 312                  *   rank <number>: rank of player
 313                  *   acc-<weapon netname>-hit: total damage dealt
 314                  *   acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 315                  *   acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 316                  *   acc-<weapon netname>-cnt-fired: amount of fired shots
 317                  *   acc-<weapon netname>-frags: amount of frags dealt by weapon
 318                  */
 319                 case URL_READY_CANWRITE:
 320                 {
 321                         url_fputs(fh, "V 9\n");
 322                         #ifdef WATERMARK
 323                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 324                         #endif
 325                         url_fputs(fh, sprintf("G %s\n", GetGametype()));
 326                         url_fputs(fh, sprintf("O %s\n", modname));
 327                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 328                         url_fputs(fh, sprintf("I %s\n", matchid));
 329                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 330                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 331                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
 332                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
 333                         url_fputs(fh, sprintf("L %s\n", autocvar_g_playerstats_gamereport_ladder));
 334
 335                         // TEAMS
 336                         if(teamplay)
 337                         {
 338                                 for(t = PS_GR_OUT_TL; (tn = db_get(PS_GR_OUT_DB, sprintf("%d", stof(t)))) != ""; t = tn)
 339                                 {
 340                                         // start team section
 341                                         url_fputs(fh, sprintf("Q team#%s\n", t));
 342
 343                                         // output team events // todo: does this do unnecessary loops? perhaps we should do a separate "team_events_last" tracker..."
 344                                         for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 345                                         {
 346                                                 float v = stof(db_get(PS_GR_OUT_DB, sprintf("team#%d:%s", stof(t), e)));
 347                                                 if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 348                                         }
 349                                 }
 350                         }
 351
 352                         // PLAYERS
 353                         for(p = PS_GR_OUT_PL; (pn = db_get(PS_GR_OUT_DB, sprintf("%s:*", p))) != ""; p = pn)
 354                         {
 355                                 // start player section
 356                                 url_fputs(fh, sprintf("P %s\n", p));
 357
 358                                 // playerid/index (entity number for this server)
 359                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_playerid", p));
 360                                 if(nn != "") { url_fputs(fh, sprintf("i %s\n", nn)); }
 361
 362                                 // player name
 363                                 nn = db_get(PS_GR_OUT_DB, sprintf("%s:_netname", p));
 364                                 if(nn != "") { url_fputs(fh, sprintf("n %s\n", nn)); }
 365
 366                                 // team identification number
 367                                 if(teamplay)
 368                                 {
 369                                         tt = db_get(PS_GR_OUT_DB, sprintf("%s:_team", p));
 370                                         url_fputs(fh, sprintf("t %s\n", tt));
 371                                 }
 372
 373                                 // output player events
 374                                 for(e = PS_GR_OUT_EVL; (en = db_get(PS_GR_OUT_DB, sprintf("*:%s", e))) != ""; e = en)
 375                                 {
 376                                         float v = stof(db_get(PS_GR_OUT_DB, sprintf("%s:%s", p, e)));
 377                                         if(v != 0) { url_fputs(fh, sprintf("e %s %g\n", e, v)); }
 378                                 }
 379                         }
 380                         url_fputs(fh, "\n");
 381                         url_fclose(fh);
 382                         break;
 383                 }
 384
 385                 // ======================================
 386                 // -- INCOMING GAME REPORT INFORMATION --
 387                 // ======================================
 388                 /* SPECIFICATIONS:
 389                  * stuff
 390                  */
 391                 case URL_READY_CANREAD:
 392                 {
 393                         // url_fclose is processing, we got a response for writing the data
 394                         // this must come from HTTP
 395                         LOG_TRACE("Got response from player stats server:\n");
 396                         while((s = url_fgets(fh))) { LOG_TRACE("  ", s, "\n"); }
 397                         LOG_TRACE("End of response.\n");
 398                         url_fclose(fh);
 399                         break;
 400                 }
 401
 402                 case URL_READY_CLOSED:
 403                 {
 404                         // url_fclose has finished
 405                         LOG_TRACE("Player stats written\n");
 406                         PlayerStats_GameReport_DelayMapVote = false;
 407                         if(PS_GR_OUT_DB >= 0)
 408                         {
 409                                 db_close(PS_GR_OUT_DB);
 410                                 PS_GR_OUT_DB = -1;
 411                         }
 412                         break;
 413                 }
 414
 415                 case URL_READY_ERROR:
 416                 default:
 417                 {
 418                         LOG_INFO("Player stats writing failed: ", ftos(status), "\n");
 419                         PlayerStats_GameReport_DelayMapVote = false;
 420                         if(PS_GR_OUT_DB >= 0)
 421                         {
 422                                 db_close(PS_GR_OUT_DB);
 423                                 PS_GR_OUT_DB = -1;
 424                         }
 425                         break;
 426                 }
 427         }
 428 }
 429
 430 void PlayerStats_PlayerBasic(entity joiningplayer, float newrequest)
 431 {
 432         // http://stats.xonotic.org/player/GgXRw6piDtFIbMArMuiAi8JG4tiin8VLjZgsKB60Uds=/elo.txt
 433         if(autocvar_g_playerstats_playerbasic_uri != "")
 434         {
 435                 string uri = autocvar_g_playerstats_playerbasic_uri;
 436                 if(joiningplayer.crypto_idfp != "")
 437                 {
 438                         // create the database if it doesn't already exist
 439                         if(PS_B_IN_DB < 0)
 440                                 PS_B_IN_DB = db_create();
 441
 442                         // now request the information
 443                         uri = strcat(uri, "/player/", uri_escape(uri_escape(joiningplayer.crypto_idfp)), "/elo.txt");
 444                         LOG_TRACE("Retrieving playerstats from URL: ", uri, "\n");
 445                         url_single_fopen(
 446                                 uri,
 447                                 FILE_APPEND,
 448                                 PlayerStats_PlayerBasic_Handler,
 449                                 joiningplayer
 450                         );
 451
 452                         // set status appropriately // todo: check whether the player info exists in the database previously
 453                         if(newrequest)
 454                         {
 455                                 // database still contains useful information, so don't clear it of a useful status
 456                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_WAITING;
 457                         }
 458                         else
 459                         {
 460                                 // database was previously empty or never hit received status for some reason
 461                                 joiningplayer.playerstats_basicstatus = PS_B_STATUS_UPDATING;
 462                         }
 463                 }
 464         }
 465         else
 466         {
 467                 // server has this disabled, kill the DB and set status to idle
 468                 if(PS_B_IN_DB >= 0)
 469                 {
 470                         entity player;
 471
 472                         db_close(PS_B_IN_DB);
 473                         PS_B_IN_DB = -1;
 474
 475                         FOR_EACH_REALCLIENT(player) { player.playerstats_basicstatus = PS_B_STATUS_IDLE; }
 476                 }
 477         }
 478 }
 479
 480 void PlayerStats_PlayerBasic_CheckUpdate(entity joiningplayer)
 481 {
 482         // determine whether we should retrieve playerbasic information again
 483
 484         #if 0
 485         LOG_INFOF("PlayerStats_PlayerBasic_CheckUpdate('%s'): %f\n",
 486                 joiningplayer.netname,
 487                 time
 488         );
 489         #endif
 490
 491         // TODO: check to see if this playerid is inside the database already somehow...
 492         // for now we'll just check the field, but this won't work for players who disconnect and reconnect properly
 493         // although maybe we should just submit another request ANYWAY?
 494         if(!joiningplayer.playerstats_basicstatus)
 495         {
 496                 PlayerStats_PlayerBasic(
 497                         joiningplayer,
 498                         (joiningplayer.playerstats_basicstatus == PS_B_STATUS_RECEIVED)
 499                 );
 500         }
 501 }
 502
 503 void PlayerStats_PlayerBasic_Handler(entity fh, entity p, float status)
 504 {
 505         switch(status)
 506         {
 507                 case URL_READY_CANWRITE:
 508                 {
 509                         LOG_TRACE("-- Sending data to player stats server\n");
 510                         /*url_fputs(fh, "V 1\n");
 511                         #ifdef WATERMARK
 512                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 513                         #endif
 514                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 515                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
 516                         url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 517                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 518                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 519                         */url_fputs(fh, "\n");
 520                         url_fclose(fh);
 521                         break;
 522                 }
 523
 524                 case URL_READY_CANREAD:
 525                 {
 526                         string s = "";
 527                         LOG_TRACE("-- Got response from player stats server:\n");
 528                         //string gametype = string_null;
 529                         while((s = url_fgets(fh)))
 530                         {
 531                                 LOG_TRACE("  ", s, "\n");
 532                                 /*
 533                                 string key = "", value = "", data = "";
 534
 535                                 n = tokenizebyseparator(s, " "); // key (value) data
 536                                 if (n == 1)
 537                                         continue;
 538                                 else if (n == 2)
 539                                 {
 540                                 key = argv(0);
 541                                 data = argv(1);
 542                                 }
 543                                 else if (n >= 3)
 544                                 {
 545                                                                 key = argv(0);
 546                                                                 value = argv(1);
 547                                                                 data = argv(2);
 548                                 }
 549
 550                                 if (data == "")
 551                                 continue;
 552
 553                                 if (key == "#")
 554                                 continue;
 555                                 else if (key == "V")
 556                                 PlayerInfo_AddItem(p, "_version", data);
 557                                 else if (key == "R")
 558                                 PlayerInfo_AddItem(p, "_release", data);
 559                                 else if (key == "T")
 560                                 PlayerInfo_AddItem(p, "_time", data);
 561                                 else if (key == "S")
 562                                 PlayerInfo_AddItem(p, "_statsurl", data);
 563                                 else if (key == "P")
 564                                 PlayerInfo_AddItem(p, "_hashkey", data);
 565                                 else if (key == "n")
 566                                 PlayerInfo_AddItem(p, "_playernick", data);
 567                                 else if (key == "i")
 568                                 PlayerInfo_AddItem(p, "_playerid", data);
 569                                 else if (key == "G")
 570                                 gametype = data;
 571                                 else if (key == "e" && value != "")
 572                                 {
 573                                 if (gametype == "")
 574                                 PlayerInfo_AddItem(p, value, data);
 575                                 else
 576                                 PlayerInfo_AddItem(p, sprintf("%s/%s", gametype, value), data);
 577                                 }
 578                                 else
 579                                 continue;
 580                                 */
 581                         }
 582                         LOG_TRACE("-- End of response.\n");
 583                         url_fclose(fh);
 584                         break;
 585                 }
 586                 case URL_READY_CLOSED:
 587                 {
 588                         // url_fclose has finished
 589                         LOG_INFO("Player stats synchronized with server\n");
 590                         break;
 591                 }
 592
 593                 case URL_READY_ERROR:
 594                 default:
 595                 {
 596                         LOG_INFO("Receiving player stats failed: ", ftos(status), "\n");
 597                         break;
 598                 }
 599         }
 600 }
 601 #endif // SVQC
 602
 603 #ifdef MENUQC
 604
 605
 606 #if 0 // reading the entire DB at once
 607         string e = "", en = "";
 608         float i = 0;
 609         for(e = PS_D_IN_EVL; (en = db_get(PS_D_IN_DB, e)) != ""; e = en)
 610         {
 611                 LOG_INFO(sprintf("%d:%s:%s\n", i, e, db_get(PS_D_IN_DB, sprintf("#%s", e))));
 612                 ++i;
 613         }
 614 #endif
 615
 616 void PlayerStats_PlayerDetail_AddItem(string event, string data)
 617 {
 618         if(PS_D_IN_DB < 0) { return; }
 619
 620         // create a marker for the event so that we can access it later
 621         string marker = sprintf("%s", event);
 622         if(db_get(PS_D_IN_DB, marker) == "")
 623         {
 624                 if(PS_D_IN_EVL)
 625                 {
 626                         db_put(PS_D_IN_DB, marker, PS_D_IN_EVL);
 627                         strunzone(PS_D_IN_EVL);
 628                 }
 629                 else { db_put(PS_D_IN_DB, marker, "#"); }
 630                 PS_D_IN_EVL = strzone(marker);
 631         }
 632
 633         // now actually set the event data
 634         db_put(PS_D_IN_DB, sprintf("#%s", event), data);
 635         LOG_TRACE("Added item ", sprintf("#%s", event), "=", data, " to PS_D_IN_DB\n");
 636 }
 637
 638 void PlayerStats_PlayerDetail(void)
 639 {
 640         // http://stats.xonotic.org/player/me
 641         if((autocvar_g_playerstats_playerdetail_uri != "") && (crypto_getmyidstatus(0) > 0))
 642         {
 643                 // create the database if it doesn't already exist
 644                 if(PS_D_IN_DB < 0)
 645                         PS_D_IN_DB = db_create();
 646
 647                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
 648                 LOG_TRACE("Retrieving playerstats from URL: ", autocvar_g_playerstats_playerdetail_uri, "\n");
 649                 url_single_fopen(
 650                         autocvar_g_playerstats_playerdetail_uri,
 651                         FILE_APPEND,
 652                         PlayerStats_PlayerDetail_Handler,
 653                         world
 654                 );
 655
 656                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_WAITING;
 657         }
 658         else
 659         {
 660                 // player has this disabled, kill the DB and set status to idle
 661                 if(PS_D_IN_DB >= 0)
 662                 {
 663                         db_close(PS_D_IN_DB);
 664                         PS_D_IN_DB = -1;
 665                 }
 666
 667                 PlayerStats_PlayerDetail_Status = PS_D_STATUS_IDLE;
 668         }
 669 }
 670
 671 void PlayerStats_PlayerDetail_CheckUpdate(void)
 672 {
 673         // determine whether we should retrieve playerdetail information again
 674         float gamecount = cvar("cl_matchcount");
 675
 676         #if 0
 677         LOG_INFOF("PlayerStats_PlayerDetail_CheckUpdate(): %f >= %f, %d > %d\n",
 678                 time,
 679                 PS_D_NEXTUPDATETIME,
 680                 PS_D_LASTGAMECOUNT,
 681                 gamecount
 682         );
 683         #endif
 684
 685         if(
 686                 (time >= PS_D_NEXTUPDATETIME)
 687                 ||
 688                 (gamecount > PS_D_LASTGAMECOUNT)
 689         )
 690         {
 691                 PlayerStats_PlayerDetail();
 692                 PS_D_NEXTUPDATETIME = (time + autocvar_g_playerstats_playerdetail_autoupdatetime);
 693                 PS_D_LASTGAMECOUNT = gamecount;
 694         }
 695 }
 696
 697 void PlayerStats_PlayerDetail_Handler(entity fh, entity unused, float status)
 698 {
 699         switch(status)
 700         {
 701                 case URL_READY_CANWRITE:
 702                 {
 703                         LOG_TRACE("PlayerStats_PlayerDetail_Handler(): Sending data to player stats server...\n");
 704                         url_fputs(fh, "V 1\n");
 705                         #ifdef WATERMARK
 706                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 707                         #endif
 708                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 709                         //url_fputs(fh, sprintf("c %s\n", cvar_string("_cl_country"))); // country
 710                         //url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 711                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 712                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 713                         url_fputs(fh, "\n");
 714                         url_fclose(fh);
 715                         break;
 716                 }
 717
 718                 case URL_READY_CANREAD:
 719                 {
 720                         //print("PlayerStats_PlayerDetail_Handler(): Got response from player stats server:\n");
 721                         string input = "";
 722                         string gametype = "overall";
 723                         while((input = url_fgets(fh)))
 724                         {
 725                                 float count = tokenizebyseparator(input, " ");
 726                                 string key = "", event = "", data = "";
 727
 728                                 if(argv(0) == "#") { continue; }
 729
 730                                 if(count == 2)
 731                                 {
 732                                         key = argv(0);
 733                                         data = substring(input, argv_start_index(1), strlen(input) - argv_start_index(1));
 734                                 }
 735                                 else if(count >= 3)
 736                                 {
 737                                         key = argv(0);
 738                                         event = argv(1);
 739                                         data = substring(input, argv_start_index(2), strlen(input) - argv_start_index(2));
 740                                 }
 741                                 else { continue; }
 742
 743                                 switch(key)
 744                                 {
 745                                         // general info
 746                                         case "V": PlayerStats_PlayerDetail_AddItem("version", data); break;
 747                                         case "R": PlayerStats_PlayerDetail_AddItem("release", data); break;
 748                                         case "T": PlayerStats_PlayerDetail_AddItem("time", data); break;
 749
 750                                         // player info
 751                                         case "S": PlayerStats_PlayerDetail_AddItem("statsurl", data); break;
 752                                         case "P": PlayerStats_PlayerDetail_AddItem("hashkey", data); break;
 753                                         case "n": PlayerStats_PlayerDetail_AddItem("playernick", data); break;
 754                                         case "i": PlayerStats_PlayerDetail_AddItem("playerid", data); break;
 755
 756                                         // other/event info
 757                                         case "G": gametype = data; break;
 758                                         case "e":
 759                                         {
 760                                                 if(event != "" && data != "")
 761                                                 {
 762                                                         PlayerStats_PlayerDetail_AddItem(
 763                                                                 sprintf(
 764                                                                         "%s/%s",
 765                                                                         gametype,
 766                                                                         event
 767                                                                 ),
 768                                                                 data
 769                                                         );
 770                                                 }
 771                                                 break;
 772                                         }
 773
 774                                         default:
 775                                         {
 776                                                 LOG_INFOF(
 777                                                         "PlayerStats_PlayerDetail_Handler(): ERROR: "
 778                                                         "Key went unhandled? Is our version outdated?\n"
 779                                                         "PlayerStats_PlayerDetail_Handler(): "
 780                                                         "Key '%s', Event '%s', Data '%s'\n",
 781                                                         key,
 782                                                         event,
 783                                                         data
 784                                                 );
 785                                                 break;
 786                                         }
 787                                 }
 788
 789                                 #if 0
 790                                 LOG_INFO(sprintf(
 791                                         "PlayerStats_PlayerDetail_Handler(): "
 792                                         "Key '%s', Event '%s', Data '%s'\n",
 793                                         key,
 794                                         event,
 795                                         data
 796                                 ));
 797                                 #endif
 798                         }
 799                         //print("PlayerStats_PlayerDetail_Handler(): End of response.\n");
 800                         url_fclose(fh);
 801                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_RECEIVED;
 802                         statslist.getStats(statslist);
 803                         break;
 804                 }
 805
 806                 case URL_READY_CLOSED:
 807                 {
 808                         // url_fclose has finished
 809                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Player stats synchronized with server.\n");
 810                         break;
 811                 }
 812
 813                 case URL_READY_ERROR:
 814                 default:
 815                 {
 816                         LOG_INFO("PlayerStats_PlayerDetail_Handler(): Receiving player stats failed: ", ftos(status), "\n");
 817                         PlayerStats_PlayerDetail_Status = PS_D_STATUS_ERROR;
 818                         if(PS_D_IN_DB >= 0)
 819                         {
 820                                 db_close(PS_D_IN_DB);
 821                                 PS_D_IN_DB = -1;
 822                         }
 823                         break;
 824                 }
 825         }
 826 }
 827 #endif
 828
 829 /*
 830 void PlayerInfo_AddPlayer(entity e)
 831 {
 832         if(playerinfo_db < 0)
 833                 return;
 834
 835         string key;
 836         key = sprintf("#%d:*", e.playerid); // TODO: use hashkey instead?
 837
 838         string p;
 839         p = db_get(playerinfo_db, key);
 840         if(p == "")
 841         {
 842                 if(playerinfo_last)
 843                 {
 844                         db_put(playerinfo_db, key, playerinfo_last);
 845                         strunzone(playerinfo_last);
 846                 }
 847                 else
 848                         db_put(playerinfo_db, key, "#");
 849                 playerinfo_last = strzone(ftos(e.playerid));
 850                 print("  Added player ", ftos(e.playerid), " to playerinfo_db\n");//DEBUG//
 851         }
 852 }
 853
 854 void PlayerInfo_AddItem(entity e, string item_id, string val)
 855 {
 856         if(playerinfo_db < 0)
 857                 return;
 858
 859         string key;
 860         key = sprintf("*:%s", item_id);
 861
 862         string p;
 863         p = db_get(playerinfo_db, key);
 864         if(p == "")
 865         {
 866                 if(playerinfo_events_last)
 867                 {
 868                         db_put(playerinfo_db, key, playerinfo_events_last);
 869                         strunzone(playerinfo_events_last);
 870                 }
 871                 else
 872                         db_put(playerinfo_db, key, "#");
 873                 playerinfo_events_last = strzone(item_id);
 874         }
 875
 876         key = sprintf("#%d:%s", e.playerid, item_id);
 877         db_put(playerinfo_db, key, val);
 878         print("  Added item ", key, "=", val, " to playerinfo_db\n");//DEBUG//
 879 }
 880
 881 string PlayerInfo_GetItem(entity e, string item_id)
 882 {
 883         if(playerinfo_db < 0)
 884                 return "";
 885
 886         string key;
 887         key = sprintf("#%d:%s",  e.playerid, item_id);
 888         return db_get(playerinfo_db, key);
 889 }
 890
 891 string PlayerInfo_GetItemLocal(string item_id)
 892 {
 893         entity p = spawn();
 894         p.playerid = 0;
 895         return PlayerInfo_GetItem(p, item_id);
 896 }
 897
 898 void PlayerInfo_ready(entity fh, entity p, float status)
 899 {
 900         float n;
 901         string s;
 902
 903         PlayerInfo_AddPlayer(p);
 904
 905         switch(status)
 906         {
 907                 case URL_READY_CANWRITE:
 908                         print("-- Sending data to player stats server\n");
 909                         url_fputs(fh, "V 1\n");
 910 #ifdef WATERMARK
 911                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 912 #endif
 913 #ifdef MENUQC
 914                         url_fputs(fh, sprintf("l %s\n", cvar_string("_menu_prvm_language"))); // language
 915                         url_fputs(fh, sprintf("c %s\n", cvar_string("_menu_prvm_country"))); // country
 916                         url_fputs(fh, sprintf("g %s\n", cvar_string("_cl_gender"))); // gender
 917                         url_fputs(fh, sprintf("n %s\n", cvar_string("_cl_name"))); // name
 918                         url_fputs(fh, sprintf("m %s %s\n", cvar_string("_cl_playermodel"), cvar_string("_cl_playerskin"))); // model/skin
 919 #endif
 920                         url_fputs(fh, "\n");
 921                         url_fclose(fh);
 922                         break;
 923                 case URL_READY_CANREAD:
 924                         print("-- Got response from player stats server:\n");
 925                         string gametype = string_null;
 926                         while((s = url_fgets(fh)))
 927                         {
 928                                 print("  ", s, "\n");
 929
 930                                 string key = "", value = "", data = "";
 931
 932                                 n = tokenizebyseparator(s, " "); // key (value) data
 933                                 if (n == 1)
 934                                         continue;
 935                                 else if (n == 2)
 936                                 {
 937                                         key = argv(0);
 938                                         data = argv(1);
 939                                 }
 940                                 else if (n >= 3)
 941                                 {
 942                                         key = argv(0);
 943                                         value = argv(1);
 944                                         data = argv(2);
 945                                 }
 946
 947                                 if (data == "")
 948                                         continue;
 949
 950                                 if (key == "#")
 951                                         continue;
 952                                 else if (key == "V")
 953                                         PlayerInfo_AddItem(p, "_version", data);
 954                                 else if (key == "R")
 955                                         PlayerInfo_AddItem(p, "_release", data);
 956                                 else if (key == "T")
 957                                         PlayerInfo_AddItem(p, "_time", data);
 958                                 else if (key == "S")
 959                                         PlayerInfo_AddItem(p, "_statsurl", data);
 960                                 else if (key == "P")
 961                                         PlayerInfo_AddItem(p, "_hashkey", data);
 962                                 else if (key == "n")
 963                                         PlayerInfo_AddItem(p, "_playernick", data);
 964                                 else if (key == "i")
 965                                         PlayerInfo_AddItem(p, "_playerid", data);
 966                                 else if (key == "G")
 967                                         gametype = data;
 968                                 else if (key == "e" && value != "")
 969                                 {
 970                                         if (gametype == "")
 971                                                 PlayerInfo_AddItem(p, value, data);
 972                                         else
 973                                                 PlayerInfo_AddItem(p, sprintf("%s/%s", gametype, value), data);
 974                                 }
 975                                 else
 976                                         continue;
 977                         }
 978                         print("-- End of response.\n");
 979                         url_fclose(fh);
 980                         break;
 981                 case URL_READY_CLOSED:
 982                         // url_fclose has finished
 983                         print("Player stats synchronized with server\n");
 984                         break;
 985                 case URL_READY_ERROR:
 986                 default:
 987                         print("Receiving player stats failed: ", ftos(status), "\n");
 988                         break;
 989         }
 990 }
 991
 992 void PlayerInfo_Init()
 993 {
 994         playerinfo_db = db_create();
 995 }
 996
 997 #ifdef SVQC
 998 void PlayerInfo_Basic(entity p)
 999 {
1000         print("-- Getting basic PlayerInfo for player ",ftos(p.playerid)," (SVQC)\n");
1001
1002         if(playerinfo_db < 0)
1003                 return;
1004
1005         string uri;
1006         uri = autocvar_g_playerinfo_uri;
1007         if(uri != "" && p.crypto_idfp != "")
1008         {
1009                 uri = strcat(uri, "/elo/", uri_escape(p.crypto_idfp));
1010                 print("Retrieving playerstats from URL: ", uri, "\n");
1011                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1012         }
1013 }
1014 #endif
1015
1016 #ifdef MENUQC
1017 void PlayerInfo_Details()
1018 {
1019         print("-- Getting detailed PlayerInfo for local player (MENUQC)\n");
1020
1021         if(playerinfo_db < 0)
1022                 return;
1023
1024         string uri;
1025         uri = autocvar_g_playerinfo_uri; // FIXME
1026         if(uri != "" && crypto_getmyidstatus(0) > 0)
1027         {
1028                 //uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1029                 uri = strcat(uri, "/player/me");
1030                 print("Retrieving playerstats from URL: ", uri, "\n");
1031                 url_single_fopen(uri, FILE_APPEND, PlayerInfo_ready, world);
1032         }
1033 }
1034 #endif
1035
1036 #ifdef CSQC
1037 // FIXME - crypto_* builtin functions missing in CSQC (csprogsdefs.qh:885)
1038 void PlayerInfo_Details()
1039 {
1040         print("-- Getting detailed PlayerInfo for local player (CSQC)\n");
1041
1042         if(playerinfo_db < 0)
1043                 return;
1044
1045         string uri;
1046         uri = autocvar_g_playerinfo_uri; // FIXME
1047         if(uri != "" && crypto_getmyidstatus(0) > 0)
1048         {
1049                 uri = strcat(uri, "/player/", uri_escape(crypto_getmyidfp(0)));
1050                 print("Retrieving playerstats from URL: ", uri, "\n");
1051                 url_single_fopen(uri, FILE_READ, PlayerInfo_ready, p);
1052         }
1053 }
1054
1055 #endif
1056 */