fcd4d9a459983fc06a2e35fdb1cd5e8db753e8b9
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / sounds / all.qc
1 #include "all.qh"
2 #ifdef SVQC
3
4 #include <server/utils.qh>
5
6 bool autocvar_bot_sound_monopoly;
7
8 .entity realowner;
9 bool sound_allowed(int to, entity e)
10 {
11         if(!e) return true; // save on a few checks
12         for ( ; ; )
13         {
14                 if (e.classname == "body") e = e.enemy;
15                 else if (e.realowner && e.realowner != e) e = e.realowner;
16                 else if (e.owner && e.owner != e) e = e.owner;
17                 else break;
18         }
19         // sounds to self may always pass
20         if (to == MSG_ONE && e == msg_entity) return true;
21         // sounds by players can be removed
22         if (autocvar_bot_sound_monopoly && IS_REAL_CLIENT(e)) return false;
23         // anything else may pass
24         return true;
25 }
26
27 /** hack: string precache_sound(string s) = #19; */
28 int precache_sound_index(string s) = #19;
29
30 const int SVC_SOUND = 6;
31 const int SVC_STOPSOUND = 16;
32
33 const int SND_VOLUME = BIT(0);
34 const int SND_ATTENUATION = BIT(1);
35 const int SND_LARGEENTITY = BIT(3);
36 const int SND_LARGESOUND = BIT(4);
37
38 void soundtoat(int to, entity e, vector o, int chan, string samp, float vol, float attenu)
39 {
40         if (!sound_allowed(to, e)) return;
41         int entno = etof(e);
42         int idx = precache_sound_index(samp);
43         attenu = floor(attenu * 64);
44         vol = floor(vol * 255);
45         int sflags = 0;
46         if (vol != 255) sflags |= SND_VOLUME;
47         if (attenu != 64) sflags |= SND_ATTENUATION;
48         if (entno >= 8192 || chan < 0 || chan > 7) sflags |= SND_LARGEENTITY;
49         if (idx >= 256) sflags |= SND_LARGESOUND;
50         WriteByte(to, SVC_SOUND);
51         WriteByte(to, sflags);
52         if (sflags & SND_VOLUME) WriteByte(to, vol);
53         if (sflags & SND_ATTENUATION) WriteByte(to, attenu);
54         if (sflags & SND_LARGEENTITY)
55         {
56                 WriteShort(to, entno);
57                 WriteByte(to, chan);
58         }
59         else
60         {
61                 WriteShort(to, (entno << 3) | chan);
62         }
63         if (sflags & SND_LARGESOUND) WriteShort(to, idx);
64         else WriteByte(to, idx);
65         WriteCoord(to, o.x);
66         WriteCoord(to, o.y);
67         WriteCoord(to, o.z);
68 }
69
70 void soundto(int _dest, entity e, int chan, string samp, float vol, float _atten)
71 {
72         if (!sound_allowed(_dest, e)) return;
73         vector o = e.origin + 0.5 * (e.mins + e.maxs);
74         soundtoat(_dest, e, o, chan, samp, vol, _atten);
75 }
76 void soundat(entity e, vector o, int chan, string samp, float vol, float _atten)
77 {
78         soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
79 }
80 void stopsoundto(int _dest, entity e, int chan)
81 {
82         if (!sound_allowed(_dest, e)) return;
83         int entno = etof(e);
84         if (entno >= 8192 || chan < 0 || chan > 7)
85         {
86                 int idx = precache_sound_index(SND(Null));
87                 int sflags = SND_LARGEENTITY;
88                 if (idx >= 256) sflags |= SND_LARGESOUND;
89                 WriteByte(_dest, SVC_SOUND);
90                 WriteByte(_dest, sflags);
91                 WriteShort(_dest, entno);
92                 WriteByte(_dest, chan);
93                 if (sflags & SND_LARGESOUND) WriteShort(_dest, idx);
94                 else WriteByte(_dest, idx);
95                 WriteCoord(_dest, e.origin.x);
96                 WriteCoord(_dest, e.origin.y);
97                 WriteCoord(_dest, e.origin.z);
98         }
99         else
100         {
101                 WriteByte(_dest, SVC_STOPSOUND);
102                 WriteShort(_dest, entno * 8 + chan);
103         }
104 }
105 void stopsound(entity e, int chan)
106 {
107         if (!sound_allowed(MSG_BROADCAST, e)) return;
108         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
109         stopsoundto(MSG_ALL, e, chan);       // in case of packet loss
110 }
111
112 void play2(entity e, string filename)
113 {
114         msg_entity = e;
115         soundtoat(MSG_ONE, NULL, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
116 }
117
118 .float spamtime;
119 /** use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame) */
120 float spamsound(entity e, int chan, Sound samp, float vol, float _atten)
121 {
122         if (!sound_allowed(MSG_BROADCAST, e)) return false;
123         if (time > e.spamtime)
124         {
125                 e.spamtime = time;
126                 sound(e, chan, samp, vol, _atten);
127                 return true;
128         }
129         return false;
130 }
131
132 void play2team(float t, string filename)
133 {
134         if (autocvar_bot_sound_monopoly) return;
135         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.team == t, play2(it, filename));
136 }
137
138 void play2all(string samp)
139 {
140         if (autocvar_bot_sound_monopoly) return;
141         _sound(NULL, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
142 }
143
144 #endif