Simplify clipped circle pictures (e.g. crosshair ring).
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "mapobjects/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 .bool item_simple; // probably not really needed, but better safe than sorry
41 void Item_SetAlpha(entity this)
42 {
43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
44
45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
46         {
47                 this.alpha = 1;
48                 this.colormod = '1 1 1';
49                 this.glowmod = this.item_glowmod;
50         }
51         else
52         {
53                 this.alpha = autocvar_cl_ghost_items;
54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
55         }
56
57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
58         {
59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
60                 this.alpha = autocvar_cl_weapon_stay_alpha;
61         }
62
63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
64 }
65
66 void ItemDraw(entity this)
67 {
68     if(this.gravity)
69     {
70         Movetype_Physics_MatchServer(this, false);
71         if(IS_ONGROUND(this))
72         { // For some reason avelocity gets set to '0 0 0' here ...
73             this.oldorigin = this.origin;
74             this.gravity = 0;
75
76             if(autocvar_cl_animate_items)
77             { // ... so reset it if animations are requested.
78                 if(this.ItemStatus & ITS_ANIMATE1)
79                     this.avelocity = '0 180 0';
80
81                 if(this.ItemStatus & ITS_ANIMATE2)
82                     this.avelocity = '0 -90 0';
83             }
84
85             // delay is for blocking item's position for a while;
86             // it's a workaround for dropped weapons that receive the position
87             // another time right after they spawn overriding animation position
88             this.onground_time = time + 0.5;
89         }
90     }
91     else if (autocvar_cl_animate_items && !this.item_simple) // no bobbing applied to simple items, for consistency's sake (no visual difference between ammo and weapons)
92     {
93         if(this.ItemStatus & ITS_ANIMATE1)
94         {
95                 this.angles += this.avelocity * frametime;
96             float fade_in = bound(0, time - this.onground_time, 1);
97             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
98         }
99
100         if(this.ItemStatus & ITS_ANIMATE2)
101         {
102                 this.angles += this.avelocity * frametime;
103             float fade_in = bound(0, time - this.onground_time, 1);
104             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
105         }
106     }
107
108     Item_SetAlpha(this);
109 }
110
111 void Item_PreDraw(entity this)
112 {
113         if(warpzone_warpzones_exist)
114         {
115                 setpredraw(this, func_null); // no need to keep running this
116                 return;
117         }
118         float alph;
119         vector org = getpropertyvec(VF_ORIGIN);
120         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
121                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
122         if(this.fade_start)
123         {
124                 if(vdist(org - this.origin, >, this.fade_end))
125                         alph = 0; // save on some processing
126                 else if(vdist(org - this.origin, <, this.fade_start))
127                         alph = 1; // more processing saved
128                 else
129                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
130         }
131         else
132                 alph = 1;
133         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
134         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
135                 this.alpha = alph;
136         if(alph <= 0)
137                 this.drawmask = 0;
138         //else
139                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
140 }
141
142 void ItemRemove(entity this)
143 {
144         strfree(this.mdl);
145 }
146
147 HashMap ENT_CLIENT_ITEM_simple;
148 STATIC_INIT(ENT_CLIENT_ITEM_simple)
149 {
150         HM_NEW(ENT_CLIENT_ITEM_simple);
151 }
152 SHUTDOWN(ENT_CLIENT_ITEM_simple)
153 {
154         HM_DELETE(ENT_CLIENT_ITEM_simple);
155 }
156
157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
158 {
159     int sf = ReadByte();
160
161     if(sf & ISF_LOCATION)
162     {
163         this.origin = ReadVector();
164         setorigin(this, this.origin);
165         this.oldorigin = this.origin;
166     }
167
168     if(sf & ISF_ANGLES)
169     {
170         this.angles_x = ReadAngle();
171         this.angles_y = ReadAngle();
172         this.angles_z = ReadAngle();
173     }
174
175     if(sf & ISF_SIZE)
176     {
177         float use_bigsize = ReadByte();
178         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
179     }
180
181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
182     {
183         this.ItemStatus = ReadByte();
184
185         Item_SetAlpha(this);
186
187         if(this.ItemStatus & ITS_ALLOWFB)
188            this.effects |= EF_FULLBRIGHT;
189
190         if(this.ItemStatus & ITS_GLOW)
191         {
192             if(this.ItemStatus & ITS_AVAILABLE)
193                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
194             else
195                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
196         }
197     }
198
199     if(sf & ISF_MODEL)
200     {
201         this.drawmask  = MASK_NORMAL;
202                 set_movetype(this, MOVETYPE_TOSS);
203                 if (isnew) IL_PUSH(g_drawables, this);
204         this.draw       = ItemDraw;
205         this.solid = SOLID_TRIGGER;
206         //this.flags |= FL_ITEM;
207
208         bool use_bigsize = ReadByte();
209
210         this.fade_end = ReadShort();
211         this.fade_start = ReadShort();
212         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
213                 setpredraw(this, Item_PreDraw);
214
215                 strfree(this.mdl);
216
217         string _fn = ReadString();
218         this.item_simple = false; // reset it!
219
220         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
221         {
222             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
223             this.item_simple = true;
224
225                         #define extensions(x) \
226                                 x(md3) \
227                                 x(dpm) \
228                                 x(iqm) \
229                                 x(mdl) \
230                                 /**/
231                         #define tryext(ext) { \
232                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
233                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
234                                 if (cached == "") { \
235                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
236                                 } \
237                                 if (cached != "0") { \
238                                         strcpy(this.mdl, s); \
239                                         break; \
240                                 } \
241                         }
242                         do {
243                                 extensions(tryext);
244                                 this.item_simple = false;
245                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
246                         } while (0);
247                         #undef tryext
248                         #undef extensions
249         }
250
251         if(!this.item_simple)
252             strcpy(this.mdl, _fn);
253
254         if(this.mdl == "")
255             LOG_WARNF("this.mdl is unset for item %s", this.classname);
256
257         precache_model(this.mdl);
258         _setmodel(this, this.mdl);
259
260         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
261     }
262
263     if(sf & ISF_COLORMAP)
264     {
265         this.colormap = ReadShort();
266         this.item_glowmod_x = ReadByte() / 255.0;
267         this.item_glowmod_y = ReadByte() / 255.0;
268         this.item_glowmod_z = ReadByte() / 255.0;
269     }
270
271     if(sf & ISF_DROP)
272     {
273         this.gravity = 1;
274         this.pushable = true;
275         //this.angles = '0 0 0';
276         set_movetype(this, MOVETYPE_TOSS);
277         this.velocity = ReadVector();
278         setorigin(this, this.oldorigin);
279
280         if(!this.move_time)
281         {
282             this.move_time = time;
283             this.spawntime = time;
284         }
285         else
286             this.move_time = max(this.move_time, time);
287     }
288
289     if(autocvar_cl_animate_items)
290     {
291         if(this.ItemStatus & ITS_ANIMATE1)
292             this.avelocity = '0 180 0';
293
294         if(this.ItemStatus & ITS_ANIMATE2)
295             this.avelocity = '0 -90 0';
296     }
297
298     this.entremove = ItemRemove;
299
300     return true;
301 }
302
303 #endif
304
305 #ifdef SVQC
306 bool ItemSend(entity this, entity to, int sf)
307 {
308         if(this.gravity)
309                 sf |= ISF_DROP;
310         else
311                 sf &= ~ISF_DROP;
312
313         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
314         WriteByte(MSG_ENTITY, sf);
315
316         //WriteByte(MSG_ENTITY, this.cnt);
317         if(sf & ISF_LOCATION)
318         {
319                 WriteVector(MSG_ENTITY, this.origin);
320         }
321
322         if(sf & ISF_ANGLES)
323         {
324                 WriteAngle(MSG_ENTITY, this.angles_x);
325                 WriteAngle(MSG_ENTITY, this.angles_y);
326                 WriteAngle(MSG_ENTITY, this.angles_z);
327         }
328
329         if(sf & ISF_SIZE)
330         {
331                 Pickup p = this.itemdef;
332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
333         }
334
335         if(sf & ISF_STATUS)
336                 WriteByte(MSG_ENTITY, this.ItemStatus);
337
338         if(sf & ISF_MODEL)
339         {
340                 Pickup p = this.itemdef;
341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
342                 WriteShort(MSG_ENTITY, this.fade_end);
343                 WriteShort(MSG_ENTITY, this.fade_start);
344
345                 if(this.mdl == "")
346                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
347
348                 WriteString(MSG_ENTITY, this.mdl);
349         }
350
351
352         if(sf & ISF_COLORMAP)
353         {
354                 WriteShort(MSG_ENTITY, this.colormap);
355                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
356                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
357                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
358         }
359
360         if(sf & ISF_DROP)
361         {
362                 WriteVector(MSG_ENTITY, this.velocity);
363         }
364
365         return true;
366 }
367
368 void ItemUpdate(entity this)
369 {
370         this.oldorigin = this.origin;
371         this.SendFlags |= ISF_LOCATION;
372 }
373
374 void UpdateItemAfterTeleport(entity this)
375 {
376         if(getSendEntity(this) == ItemSend)
377                 ItemUpdate(this);
378 }
379
380 bool have_pickup_item(entity this)
381 {
382         if(this.itemdef.instanceOfPowerup)
383         {
384                 if(autocvar_g_powerups > 0)
385                         return true;
386                 if(autocvar_g_powerups == 0)
387                         return false;
388         }
389         else
390         {
391                 if(autocvar_g_pickup_items > 0)
392                         return true;
393                 if(autocvar_g_pickup_items == 0)
394                         return false;
395                 if(g_weaponarena)
396                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
397                                 return false;
398         }
399         return true;
400 }
401
402 void Item_Show(entity e, int mode)
403 {
404         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
405         e.ItemStatus &= ~ITS_STAYWEP;
406         entity def = e.itemdef;
407         if (mode > 0)
408         {
409                 // make the item look normal, and be touchable
410                 e.model = e.mdl;
411                 e.solid = SOLID_TRIGGER;
412                 e.spawnshieldtime = 1;
413                 e.ItemStatus |= ITS_AVAILABLE;
414         }
415         else if (mode < 0)
416         {
417                 // hide the item completely
418                 e.model = string_null;
419                 e.solid = SOLID_NOT;
420                 e.spawnshieldtime = 1;
421                 e.ItemStatus &= ~ITS_AVAILABLE;
422         }
423         else
424         {
425                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
426                         || e.team // weapon stay isn't supported for teamed weapons
427                         ;
428                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
429                 {
430                         // make the item translucent and not touchable
431                         e.model = e.mdl;
432                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
433                         e.effects |= EF_STARDUST;
434                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
435                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
436                 }
437                 else
438                 {
439                         //setmodel(e, "null");
440                         e.solid = SOLID_NOT;
441                         e.colormod = '0 0 0';
442                         //e.glowmod = e.colormod;
443                         e.spawnshieldtime = 1;
444                         e.ItemStatus &= ~ITS_AVAILABLE;
445                 }
446         }
447
448         if (def.m_glow)
449                 e.ItemStatus |= ITS_GLOW;
450
451         if (autocvar_g_nodepthtestitems)
452                 e.effects |= EF_NODEPTHTEST;
453
454
455         if (autocvar_g_fullbrightitems)
456                 e.ItemStatus |= ITS_ALLOWFB;
457
458         if (autocvar_sv_simple_items)
459                 e.ItemStatus |= ITS_ALLOWSI;
460
461         // relink entity (because solid may have changed)
462         setorigin(e, e.origin);
463         e.SendFlags |= ISF_STATUS;
464 }
465
466 void Item_Think(entity this)
467 {
468         this.nextthink = time;
469         if(this.origin != this.oldorigin)
470                 ItemUpdate(this);
471 }
472
473 bool Item_ItemsTime_SpectatorOnly(GameItem it);
474 bool Item_ItemsTime_Allow(GameItem it);
475 float Item_ItemsTime_UpdateTime(entity e, float t);
476 void Item_ItemsTime_SetTime(entity e, float t);
477 void Item_ItemsTime_SetTimesForAllPlayers();
478
479 void Item_Respawn(entity this)
480 {
481         Item_Show(this, 1);
482         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
483         setorigin(this, this.origin);
484
485         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
486         {
487                 float t = Item_ItemsTime_UpdateTime(this, 0);
488                 Item_ItemsTime_SetTime(this, t);
489                 Item_ItemsTime_SetTimesForAllPlayers();
490         }
491
492         setthink(this, Item_Think);
493         this.nextthink = time;
494
495         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
496         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
497 }
498
499 void Item_RespawnCountdown(entity this)
500 {
501         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
502         {
503                 if(this.waypointsprite_attached)
504                         WaypointSprite_Kill(this.waypointsprite_attached);
505                 Item_Respawn(this);
506         }
507         else
508         {
509                 this.nextthink = time + 1;
510                 this.item_respawncounter += 1;
511                 if(this.item_respawncounter == 1)
512                 {
513                         do {
514                                 {
515                                         entity wi = Weapons_from(this.weapon);
516                                         if (wi != WEP_Null) {
517                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
518                                                 wp.wp_extra = wi.m_id;
519                                                 break;
520                                         }
521                                 }
522                                 {
523                                         entity ii = this.itemdef;
524                                         if (ii != NULL) {
525                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
526                                                 wp.wp_extra = ii.m_id;
527                                                 break;
528                                         }
529                                 }
530                         } while (0);
531                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
532             if(this.waypointsprite_attached)
533             {
534                 GameItem def = this.itemdef;
535                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
536                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
537                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
538             }
539                 }
540
541                 if(this.waypointsprite_attached)
542                 {
543                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
544                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
545                                 {
546                                         msg_entity = it;
547                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
548                                 }
549                         });
550
551                         WaypointSprite_Ping(this.waypointsprite_attached);
552                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
553                 }
554         }
555 }
556
557 void Item_RespawnThink(entity this)
558 {
559         this.nextthink = time;
560         if(this.origin != this.oldorigin)
561                 ItemUpdate(this);
562
563         if(time >= this.wait)
564                 Item_Respawn(this);
565 }
566
567 void Item_ScheduleRespawnIn(entity e, float t)
568 {
569         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
570         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
571         {
572                 setthink(e, Item_RespawnCountdown);
573                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
574                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
575                 e.item_respawncounter = 0;
576                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
577                 {
578                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
579                         Item_ItemsTime_SetTime(e, t);
580                         Item_ItemsTime_SetTimesForAllPlayers();
581                 }
582         }
583         else
584         {
585                 setthink(e, Item_RespawnThink);
586                 e.nextthink = time;
587                 e.scheduledrespawntime = time + t;
588                 e.wait = time + t;
589
590                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
591                 {
592                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
593                         Item_ItemsTime_SetTime(e, t);
594                         Item_ItemsTime_SetTimesForAllPlayers();
595                 }
596         }
597 }
598
599 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
600 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
601 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
602
603 /// Adjust respawn time according to the number of players.
604 float adjust_respawntime(float normal_respawntime) {
605         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
606         float o = autocvar_g_pickup_respawntime_scaling_offset;
607         float l = autocvar_g_pickup_respawntime_scaling_linear;
608
609         if (r == 0 && l == 1) {
610                 return normal_respawntime;
611         }
612
613         entity balance = TeamBalance_CheckAllowedTeams(NULL);
614         TeamBalance_GetTeamCounts(balance, NULL);
615         int players = 0;
616         for (int i = 1; i <= NUM_TEAMS; ++i)
617         {
618                 if (TeamBalance_IsTeamAllowed(balance, i))
619                 {
620                         players += TeamBalance_GetNumberOfPlayers(balance, i);
621                 }
622         }
623         TeamBalance_Destroy(balance);
624
625         if (players >= 2) {
626                 return normal_respawntime * (r / (players + o) + l);
627         } else {
628                 return normal_respawntime;
629         }
630 }
631
632 void Item_ScheduleRespawn(entity e)
633 {
634         if(e.respawntime > 0)
635         {
636                 Item_Show(e, 0);
637
638                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
639                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
640
641                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
642                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
643                 Item_ScheduleRespawnIn(e, respawn_in);
644         }
645         else // if respawntime is -1, this item does not respawn
646                 Item_Show(e, -1);
647 }
648
649 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
650         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
651
652 void Item_ScheduleInitialRespawn(entity e)
653 {
654         Item_Show(e, 0);
655
656         float spawn_in;
657         if (autocvar_g_pickup_respawntime_initial_random == 0)
658         {
659                 // range: respawntime .. respawntime + respawntimejitter
660                 spawn_in = e.respawntime + random() * e.respawntimejitter;
661         }
662         else
663         {
664                 float rnd;
665                 if (autocvar_g_pickup_respawntime_initial_random == 1)
666                 {
667                         static float shared_random = 0;
668                         // NOTE this code works only if items are scheduled at the same time (normal case)
669                         // NOTE2 random() can't return exactly 1 so this check always work as intended
670                         if (!shared_random || floor(time) > shared_random)
671                                 shared_random = floor(time) + random();
672                         rnd = shared_random - floor(time);
673                 }
674                 else
675                         rnd = random();
676
677                 // range:
678                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
679                 // else: 0 .. ITEM_RESPAWN_TICKS
680                 // this is to prevent powerups spawning unexpectedly without waypoints
681                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
682         }
683
684         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
685 }
686
687 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
688         entity ammo_entity)
689 {
690         if (num_weapons == 0)
691         {
692                 return;
693         }
694         int num_potential_weapons = tokenize_console(weapon_names);
695         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
696         {
697                 RandomSelection_Init();
698                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
699                         ++weapon_index)
700                 {
701                         string weapon = argv(weapon_index);
702                         FOREACH(Weapons, it != WEP_Null,
703                         {
704                                 // Finding a weapon which player doesn't have.
705                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
706                                 {
707                                         RandomSelection_AddEnt(it, 1, 1);
708                                         break;
709                                 }
710                         });
711                 }
712                 if (RandomSelection_chosen_ent == NULL)
713                 {
714                         return;
715                 }
716                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
717                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
718                 {
719                         continue;
720                 }
721                 if (GetResource(receiver,
722                         RandomSelection_chosen_ent.ammo_type) != 0)
723                 {
724                         continue;
725                 }
726                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
727                         GetResource(ammo_entity,
728                         RandomSelection_chosen_ent.ammo_type));
729         }
730 }
731
732 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
733 {
734         float amount = GetResource(item, res_type);
735         if (amount == 0)
736         {
737                 return false;
738         }
739         float player_amount = GetResource(player, res_type);
740         if (item.spawnshieldtime)
741         {
742                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
743                         return false;
744         }
745         else if (g_weapon_stay == 2)
746                 ammomax = min(amount, ammomax);
747         else
748                 return false;
749         if (amount < 0)
750                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
751         else
752                 GiveResourceWithLimit(player, res_type, amount, ammomax);
753         return true;
754 }
755
756 bool Item_GiveTo(entity item, entity player)
757 {
758         // if nothing happens to player, just return without taking the item
759         int _switchweapon = 0;
760         // in case the player has autoswitch enabled do the following:
761         // if the player is using their best weapon before items are given, they
762         // probably want to switch to an even better weapon after items are given
763
764         if(CS(player).autoswitch)
765         {
766                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
767                 {
768                         .entity weaponentity = weaponentities[slot];
769                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
770                         {
771                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
772                                         _switchweapon |= BIT(slot);
773
774                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
775                                         _switchweapon |= BIT(slot);
776                         }
777                 }
778         }
779         bool pickedup = false;
780         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
781         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
782         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
783         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
784         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
785         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
786         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
787         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
788         if (item.itemdef.instanceOfWeaponPickup)
789         {
790                 WepSet w;
791                 w = STAT(WEAPONS, item);
792                 w &= ~STAT(WEAPONS, player);
793
794                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
795                 {
796                         pickedup = true;
797                         FOREACH(Weapons, it != WEP_Null, {
798                                 if(w & (it.m_wepset))
799                                 {
800                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
801                                         {
802                                                 .entity weaponentity = weaponentities[slot];
803                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
804                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
805                                         }
806                                         W_GiveWeapon(player, it.m_id);
807                                 }
808                         });
809                 }
810         }
811
812         if (item.itemdef.instanceOfPowerup)
813         {
814                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
815                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
816                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
817                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
818         }
819
820         int its;
821         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
822         {
823                 pickedup = true;
824                 player.items |= its;
825                 // TODO: we probably want to show a message in the console, but not this one!
826                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
827         }
828
829         if (item.strength_finished)
830         {
831                 pickedup = true;
832                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
833         }
834         if (item.invincible_finished)
835         {
836                 pickedup = true;
837                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
838         }
839         if (item.superweapons_finished)
840         {
841                 pickedup = true;
842                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
843         }
844
845         // always eat teamed entities
846         if(item.team)
847                 pickedup = true;
848
849         if (!pickedup)
850                 return false;
851
852         // crude hack to enforce switching weapons
853         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
854         {
855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
856                 {
857                         .entity weaponentity = weaponentities[slot];
858                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
859                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
860                 }
861                 return true;
862         }
863
864         if(_switchweapon)
865         {
866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
867                 {
868                         .entity weaponentity = weaponentities[slot];
869                         if(_switchweapon & BIT(slot))
870                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
871                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
872                 }
873         }
874
875         return true;
876 }
877
878 void Item_Touch(entity this, entity toucher)
879 {
880         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
881         if (Item_IsLoot(this))
882         {
883                 if (ITEM_TOUCH_NEEDKILL())
884                 {
885                         delete(this);
886                         return;
887                 }
888         }
889
890         if(!(toucher.flags & FL_PICKUPITEMS)
891         || STAT(FROZEN, toucher)
892         || IS_DEAD(toucher)
893         || (this.solid != SOLID_TRIGGER)
894         || (this.owner == toucher)
895         || (time < this.item_spawnshieldtime)
896         ) { return; }
897
898         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
899         {
900                 case MUT_ITEMTOUCH_RETURN: { return; }
901                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
902         }
903
904         toucher = M_ARGV(1, entity);
905
906         if (Item_IsExpiring(this))
907         {
908                 this.strength_finished = max(0, this.strength_finished - time);
909                 this.invincible_finished = max(0, this.invincible_finished - time);
910                 this.superweapons_finished = max(0, this.superweapons_finished - time);
911         }
912         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
913         if (!gave)
914         {
915                 if (Item_IsExpiring(this))
916                 {
917                         // undo what we did above
918                         this.strength_finished += time;
919                         this.invincible_finished += time;
920                         this.superweapons_finished += time;
921                 }
922                 return;
923         }
924
925 LABEL(pickup)
926
927         if(this.target && this.target != "" && this.target != "###item###") // defrag support
928                 SUB_UseTargets(this, toucher, NULL);
929
930         STAT(LAST_PICKUP, toucher) = time;
931
932         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
933         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
934
935         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
936         if (wasfreed(this))
937         {
938                 return;
939         }
940
941         if (Item_IsLoot(this))
942         {
943                 delete(this);
944                 return;
945         }
946         if (!this.spawnshieldtime)
947         {
948                 return;
949         }
950         entity e;
951         if (this.team)
952         {
953                 RandomSelection_Init();
954                 IL_EACH(g_items, it.team == this.team,
955                 {
956                         if (it.itemdef) // is a registered item
957                         {
958                                 Item_Show(it, -1);
959                                 it.scheduledrespawntime = 0;
960                                 RandomSelection_AddEnt(it, it.cnt, 0);
961                         }
962                 });
963                 e = RandomSelection_chosen_ent;
964                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
965         }
966         else
967                 e = this;
968         Item_ScheduleRespawn(e);
969 }
970
971 void Item_Reset(entity this)
972 {
973         Item_Show(this, !this.state);
974         setorigin(this, this.origin);
975
976         if (Item_IsLoot(this))
977         {
978                 return;
979         }
980         setthink(this, Item_Think);
981         this.nextthink = time;
982         if (this.waypointsprite_attached)
983         {
984                 WaypointSprite_Kill(this.waypointsprite_attached);
985         }
986         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
987         {
988                 Item_ScheduleInitialRespawn(this);
989         }
990 }
991
992 void Item_FindTeam(entity this)
993 {
994         entity e;
995
996         if(this.effects & EF_NODRAW)
997         {
998                 // marker for item team search
999                 LOG_TRACE("Initializing item team ", ftos(this.team));
1000                 RandomSelection_Init();
1001                 IL_EACH(g_items, it.team == this.team,
1002                 {
1003                         if(it.itemdef) // is a registered item
1004                                 RandomSelection_AddEnt(it, it.cnt, 0);
1005                 });
1006
1007                 e = RandomSelection_chosen_ent;
1008                 if (!e)
1009                         return;
1010
1011                 IL_EACH(g_items, it.team == this.team,
1012                 {
1013                         if(it.itemdef) // is a registered item
1014                         {
1015                                 if(it != e)
1016                                 {
1017                                         // make it non-spawned
1018                                         Item_Show(it, -1);
1019                                         it.state = 1; // state 1 = initially hidden item, apparently
1020                                 }
1021                                 else
1022                                         Item_Reset(it);
1023                                 it.effects &= ~EF_NODRAW;
1024                         }
1025                 });
1026         }
1027 }
1028
1029 // Savage: used for item garbage-collection
1030 void RemoveItem(entity this)
1031 {
1032         if(wasfreed(this) || !this) { return; }
1033         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1034         delete(this);
1035 }
1036
1037 // pickup evaluation functions
1038 // these functions decide how desirable an item is to the bots
1039
1040 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1041
1042 float weapon_pickupevalfunc(entity player, entity item)
1043 {
1044         // See if I have it already
1045         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1046         {
1047                 // If I can pick it up
1048                 if(!item.spawnshieldtime)
1049                         return 0;
1050                 return ammo_pickupevalfunc(player, item);
1051         }
1052
1053         // reduce weapon value if bot already got a good arsenal
1054         float c = 1;
1055         int weapons_value = 0;
1056         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1057                 weapons_value += it.bot_pickupbasevalue;
1058         });
1059         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1060
1061         return item.bot_pickupbasevalue * c;
1062 }
1063
1064 float ammo_pickupevalfunc(entity player, entity item)
1065 {
1066         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1067         entity wpn = NULL;
1068         float c = 0;
1069         float rating = 0;
1070
1071         // Detect needed ammo
1072         if(item.itemdef.instanceOfWeaponPickup)
1073         {
1074                 entity ammo = NULL;
1075                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1076                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1077                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1078                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1079                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1080                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1081
1082                 if(!ammo)
1083                         return 0;
1084                 wpn = item;
1085                 rating = ammo.m_botvalue;
1086         }
1087         else
1088         {
1089                 FOREACH(Weapons, it != WEP_Null, {
1090                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1091                                 continue;
1092
1093                         switch(it.ammo_type)
1094                         {
1095                                 case RES_SHELLS:  need_shells  = true; break;
1096                                 case RES_BULLETS: need_nails   = true; break;
1097                                 case RES_ROCKETS: need_rockets = true; break;
1098                                 case RES_CELLS:   need_cells   = true; break;
1099                                 case RES_PLASMA:  need_plasma  = true; break;
1100                                 case RES_FUEL:    need_fuel    = true; break;
1101                         }
1102                 });
1103                 rating = item.bot_pickupbasevalue;
1104         }
1105
1106         float noammorating = 0.5;
1107
1108         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1109                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1110
1111         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1112                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1113
1114         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1115                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1116
1117         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1118                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1119
1120         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1121                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1122
1123         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1124                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1125
1126         rating *= min(c, 2);
1127         if(wpn)
1128                 rating += wpn.bot_pickupbasevalue * 0.1;
1129         return rating;
1130 }
1131
1132 float healtharmor_pickupevalfunc(entity player, entity item)
1133 {
1134         float c = 0;
1135         float rating = item.bot_pickupbasevalue;
1136
1137         float itemarmor = GetResource(item, RES_ARMOR);
1138         float itemhealth = GetResource(item, RES_HEALTH);
1139
1140         if(item.item_group)
1141         {
1142                 itemarmor *= min(4, item.item_group_count);
1143                 itemhealth *= min(4, item.item_group_count);
1144         }
1145
1146         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1147                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1148
1149         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1150                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1151
1152         rating *= min(2, c);
1153         return rating;
1154 }
1155
1156 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1157 {
1158         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1159                 RemoveItem(this);
1160 }
1161
1162 void item_use(entity this, entity actor, entity trigger)
1163 {
1164         // use the touch function to handle collection
1165         gettouch(this)(this, actor);
1166 }
1167
1168 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1169 {
1170         string itemname = def.m_name;
1171         Model itemmodel = def.m_model;
1172         Sound pickupsound = def.m_sound;
1173         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1174         float pickupbasevalue = def.m_botvalue;
1175         int itemflags = def.m_itemflags;
1176
1177         startitem_failed = false;
1178
1179         this.item_model_ent = itemmodel;
1180         this.item_pickupsound_ent = pickupsound;
1181
1182         if(def.m_iteminit)
1183                 def.m_iteminit(def, this);
1184
1185         if(!this.respawntime) // both need to be set
1186         {
1187                 this.respawntime = defaultrespawntime;
1188                 this.respawntimejitter = defaultrespawntimejitter;
1189         }
1190
1191         if(!this.pickup_anyway && def.m_pickupanyway)
1192                 this.pickup_anyway = def.m_pickupanyway();
1193
1194         int itemid = def.m_itemid;
1195         this.items = itemid;
1196         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1197         this.weapon = weaponid;
1198
1199         if(!this.fade_end)
1200         {
1201                 this.fade_start = autocvar_g_items_mindist;
1202                 this.fade_end = autocvar_g_items_maxdist;
1203         }
1204
1205         if(weaponid)
1206                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1207
1208         this.flags = FL_ITEM | itemflags;
1209         IL_PUSH(g_items, this);
1210
1211         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1212         {
1213                 startitem_failed = true;
1214                 delete(this);
1215                 return;
1216         }
1217
1218         precache_model(this.model);
1219         precache_sound(this.item_pickupsound);
1220
1221         if (Item_IsLoot(this))
1222         {
1223                 this.reset = SUB_Remove;
1224                 set_movetype(this, MOVETYPE_TOSS);
1225
1226                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1227                 setthink(this, RemoveItem);
1228                 this.nextthink = time + 20;
1229
1230                 this.takedamage = DAMAGE_YES;
1231                 this.event_damage = Item_Damage;
1232
1233                 if (Item_IsExpiring(this))
1234                 {
1235                         // if item is worthless after a timer, have it expire then
1236                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1237                 }
1238
1239                 // don't drop if in a NODROP zone (such as lava)
1240                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1241                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1242                 {
1243                         startitem_failed = true;
1244                         delete(this);
1245                         return;
1246                 }
1247         }
1248         else
1249         {
1250                 if(!have_pickup_item(this))
1251                 {
1252                         startitem_failed = true;
1253                         delete(this);
1254                         return;
1255                 }
1256
1257                 if(this.angles != '0 0 0')
1258                         this.SendFlags |= ISF_ANGLES;
1259
1260                 this.reset = Item_Reset;
1261                 // it's a level item
1262                 if(this.spawnflags & 1)
1263                         this.noalign = 1;
1264                 if (this.noalign > 0)
1265                         set_movetype(this, MOVETYPE_NONE);
1266                 else
1267                         set_movetype(this, MOVETYPE_TOSS);
1268                 // do item filtering according to game mode and other things
1269                 if (this.noalign <= 0)
1270                 {
1271                         // first nudge it off the floor a little bit to avoid math errors
1272                         setorigin(this, this.origin + '0 0 1');
1273                         // set item size before we spawn a spawnfunc_waypoint
1274                         setsize(this, def.m_mins, def.m_maxs);
1275                         this.SendFlags |= ISF_SIZE;
1276                         // note droptofloor returns false if stuck/or would fall too far
1277                         if (!this.noalign)
1278                                 droptofloor(this);
1279                         waypoint_spawnforitem(this);
1280                 }
1281
1282                 /*
1283                  * can't do it that way, as it would break maps
1284                  * TODO make a target_give like entity another way, that perhaps has
1285                  * the weapon name in a key
1286                 if(this.targetname)
1287                 {
1288                         // target_give not yet supported; maybe later
1289                         print("removed targeted ", this.classname, "\n");
1290                         startitem_failed = true;
1291                         delete(this);
1292                         return;
1293                 }
1294                 */
1295
1296                 if(this.targetname != "" && (this.spawnflags & 16))
1297                         this.use = item_use;
1298
1299                 if(autocvar_spawn_debug >= 2)
1300                 {
1301             // why not flags & fl_item?
1302                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1303                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1304                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1305                 error("Mapper sucks.");
1306             });
1307                         this.is_item = true;
1308                 }
1309
1310                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1311
1312                 if (   def.instanceOfPowerup
1313                         || def.instanceOfWeaponPickup
1314                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1315                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1316                         || (itemid & (IT_KEY1 | IT_KEY2))
1317                 )
1318                 {
1319                         if(!this.target || this.target == "")
1320                                 this.target = "###item###"; // for finding the nearest item using findnearest
1321                 }
1322
1323                 Item_ItemsTime_SetTime(this, 0);
1324         }
1325
1326         this.bot_pickup = true;
1327         this.bot_pickupevalfunc = pickupevalfunc;
1328         this.bot_pickupbasevalue = pickupbasevalue;
1329         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1330         this.netname = itemname;
1331         settouch(this, Item_Touch);
1332         setmodel(this, MDL_Null); // precision set below
1333         //this.effects |= EF_LOWPRECISION;
1334
1335         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1336
1337         this.SendFlags |= ISF_SIZE;
1338
1339         if (!(this.spawnflags & 1024)) {
1340                 if(def.instanceOfPowerup)
1341                         this.ItemStatus |= ITS_ANIMATE1;
1342
1343                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1344                         this.ItemStatus |= ITS_ANIMATE2;
1345         }
1346
1347         if(Item_IsLoot(this))
1348                 this.gravity = 1;
1349
1350         if(def.instanceOfWeaponPickup)
1351         {
1352                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1353                         this.colormap = 1024; // color shirt=0 pants=0 grey
1354                 if (!(this.spawnflags & 1024))
1355                         this.ItemStatus |= ITS_ANIMATE1;
1356                 this.SendFlags |= ISF_COLORMAP;
1357         }
1358
1359         this.state = 0;
1360         if(this.team)
1361         {
1362                 if(!this.cnt)
1363                         this.cnt = 1; // item probability weight
1364
1365                 this.effects |= EF_NODRAW; // marker for item team search
1366                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1367         }
1368         else
1369                 Item_Reset(this);
1370
1371         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1372
1373         // call this hook after everything else has been done
1374         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1375         {
1376                 startitem_failed = true;
1377                 delete(this);
1378                 return;
1379         }
1380
1381         setItemGroup(this);
1382 }
1383
1384 void StartItem(entity this, GameItem def)
1385 {
1386     def = def.m_spawnfunc_hookreplace(def, this);
1387     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1388     {
1389         delete(this);
1390         return;
1391     }
1392     this.classname = def.m_canonical_spawnfunc;
1393     _StartItem(
1394         this,
1395         this.itemdef = def,
1396         def.m_respawntime(), // defaultrespawntime
1397         def.m_respawntimejitter() // defaultrespawntimejitter
1398         );
1399 }
1400
1401 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1402 int group_count = 1;
1403
1404 void setItemGroup(entity this)
1405 {
1406         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1407                 return;
1408
1409         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1410         {
1411                 if(!this.item_group)
1412                 {
1413                         if(!it.item_group)
1414                         {
1415                                 it.item_group = group_count;
1416                                 group_count++;
1417                         }
1418                         this.item_group = it.item_group;
1419                 }
1420                 else // spawning item is already part of a item_group X
1421                 {
1422                         if(!it.item_group)
1423                                 it.item_group = this.item_group;
1424                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1425                         {
1426                                 int grY = it.item_group;
1427                                 // move all items of item_group Y to item_group X
1428                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1429                                 {
1430                                         if(it.item_group == grY)
1431                                                 it.item_group = this.item_group;
1432                                 });
1433                         }
1434                 }
1435         });
1436 }
1437
1438 void setItemGroupCount()
1439 {
1440         for (int k = 1; k <= group_count; k++)
1441         {
1442                 int count = 0;
1443                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1444                 if (count)
1445                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1446         }
1447 }
1448
1449 void target_items_use(entity this, entity actor, entity trigger)
1450 {
1451         if(Item_IsLoot(actor))
1452         {
1453                 EXACTTRIGGER_TOUCH(this, trigger);
1454                 delete(actor);
1455                 return;
1456         }
1457
1458         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1459                 return;
1460
1461         if(trigger.solid == SOLID_TRIGGER)
1462         {
1463                 EXACTTRIGGER_TOUCH(this, trigger);
1464         }
1465
1466         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1467         {
1468                 delete(it);
1469         });
1470
1471         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1472                 centerprint(actor, this.message);
1473 }
1474
1475 spawnfunc(target_items)
1476 {
1477         this.use = target_items_use;
1478         if(!this.strength_finished)
1479                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1480         if(!this.invincible_finished)
1481                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1482         if(!this.superweapons_finished)
1483                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1484
1485         int n = tokenize_console(this.netname);
1486         if(argv(0) == "give")
1487         {
1488                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1489         }
1490         else
1491         {
1492                 for(int j = 0; j < n; ++j)
1493                 {
1494                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1495                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1496                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1497                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1498                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1499                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1500                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1501                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1502                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1503                         else
1504                         {
1505                                 FOREACH(Buffs, it != BUFF_Null,
1506                                 {
1507                                         string s = Buff_UndeprecateName(argv(j));
1508                                         if(s == it.netname)
1509                                         {
1510                                                 STAT(BUFFS, this) |= (it.m_itemid);
1511                                                 if(!STAT(BUFF_TIME, this))
1512                                                         STAT(BUFF_TIME, this) = it.m_time(it);
1513                                                 break;
1514                                         }
1515                                 });
1516                                 FOREACH(Weapons, it != WEP_Null, {
1517                                         string s = W_UndeprecateName(argv(j));
1518                                         if(s == it.netname)
1519                                         {
1520                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1521                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1522                                                         it.wr_init(it);
1523                                                 break;
1524                                         }
1525                                 });
1526                         }
1527                 }
1528
1529                 string itemprefix, valueprefix;
1530                 if(this.spawnflags == 0)
1531                 {
1532                         itemprefix = "";
1533                         valueprefix = "";
1534                 }
1535                 else if(this.spawnflags == 1)
1536                 {
1537                         itemprefix = "max ";
1538                         valueprefix = "max ";
1539                 }
1540                 else if(this.spawnflags == 2)
1541                 {
1542                         itemprefix = "min ";
1543                         valueprefix = "min ";
1544                 }
1545                 else if(this.spawnflags == 4)
1546                 {
1547                         itemprefix = "minus ";
1548                         valueprefix = "max ";
1549                 }
1550                 else
1551                 {
1552                         error("invalid spawnflags");
1553                         itemprefix = valueprefix = string_null;
1554                 }
1555
1556                 this.netname = "";
1557                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1558                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1559                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1564                 if(GetResource(this, RES_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_SHELLS)), "shells");
1565                 if(GetResource(this, RES_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_BULLETS)), "nails");
1566                 if(GetResource(this, RES_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ROCKETS)), "rockets");
1567                 if(GetResource(this, RES_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_CELLS)), "cells");
1568                 if(GetResource(this, RES_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_PLASMA)), "plasma");
1569                 if(GetResource(this, RES_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_FUEL)), "fuel");
1570                 if(GetResource(this, RES_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_HEALTH)), "health");
1571                 if(GetResource(this, RES_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ARMOR)), "armor");
1572                 FOREACH(Buffs, it != BUFF_Null && (STAT(BUFFS, this) & it.m_itemid), this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1573                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1574         }
1575         this.netname = strzone(this.netname);
1576         //print(this.netname, "\n");
1577
1578         n = tokenize_console(this.netname);
1579         for(int j = 0; j < n; ++j)
1580         {
1581                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1582                         it.wr_init(it);
1583                         break;
1584                 });
1585         }
1586 }
1587
1588 float GiveWeapon(entity e, float wpn, float op, float val)
1589 {
1590         WepSet v0, v1;
1591         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1592         v0 = (STAT(WEAPONS, e) & s);
1593         switch(op)
1594         {
1595                 case OP_SET:
1596                         if(val > 0)
1597                                 STAT(WEAPONS, e) |= s;
1598                         else
1599                                 STAT(WEAPONS, e) &= ~s;
1600                         break;
1601                 case OP_MIN:
1602                 case OP_PLUS:
1603                         if(val > 0)
1604                                 STAT(WEAPONS, e) |= s;
1605                         break;
1606                 case OP_MAX:
1607                         if(val <= 0)
1608                                 STAT(WEAPONS, e) &= ~s;
1609                         break;
1610                 case OP_MINUS:
1611                         if(val > 0)
1612                                 STAT(WEAPONS, e) &= ~s;
1613                         break;
1614         }
1615         v1 = (STAT(WEAPONS, e) & s);
1616         return (v0 != v1);
1617 }
1618
1619 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1620 {
1621         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1622         switch (op)
1623         {
1624                 case OP_SET:
1625                         STAT(BUFF_TIME, e) = val;
1626                         break;
1627                 case OP_MIN:
1628                         STAT(BUFF_TIME, e) = max(STAT(BUFF_TIME, e), val);
1629                         break;
1630                 case OP_MAX:
1631                         STAT(BUFF_TIME, e) = min(STAT(BUFF_TIME, e), val);
1632                         break;
1633                 case OP_PLUS:
1634                         STAT(BUFF_TIME, e) += val;
1635                         break;
1636                 case OP_MINUS:
1637                         STAT(BUFF_TIME, e) -= val;
1638                         break;
1639         }
1640         if(STAT(BUFF_TIME, e) <= 0)
1641                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1642         else
1643                 STAT(BUFFS, e) = thebuff.m_itemid; // NOTE: replaces any existing buffs on the player!
1644         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1645         return (had_buff != have_buff);
1646 }
1647
1648 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1649 {
1650         if(v1 == v0)
1651                 return;
1652         if(v1 <= v0 - t)
1653         {
1654                 if(snd_decr != NULL)
1655                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1656         }
1657         else if(v0 >= v0 + t)
1658         {
1659                 if(snd_incr != NULL)
1660                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1661         }
1662 }
1663
1664 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1665 {
1666         if(v0 < v1)
1667                 e.(rotfield) = max(e.(rotfield), time + rottime);
1668         else if(v0 > v1)
1669                 e.(regenfield) = max(e.(regenfield), time + regentime);
1670 }
1671 bool GiveResourceValue(entity e, int res_type, int op, int val)
1672 {
1673         int v0 = GetResource(e, res_type);
1674         switch (op)
1675         {
1676                 // min 100 cells = at least 100 cells
1677                 case OP_SET: SetResource(e, res_type, val); break;
1678                 case OP_MIN: SetResource(e, res_type, max(v0, val)); break;
1679                 case OP_MAX: SetResource(e, res_type, min(v0, val)); break;
1680                 case OP_PLUS: SetResource(e, res_type, v0 + val); break;
1681                 case OP_MINUS: SetResource(e, res_type, v0 - val); break;
1682         }
1683         int v1 = GetResource(e, res_type);
1684         return v0 != v1;
1685 }
1686
1687 float GiveItems(entity e, float beginarg, float endarg)
1688 {
1689         float got, i, val, op;
1690         string cmd;
1691
1692         val = 999;
1693         op = OP_SET;
1694
1695         got = 0;
1696
1697         int _switchweapon = 0;
1698
1699         if(CS(e).autoswitch)
1700         {
1701                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1702                 {
1703                         .entity weaponentity = weaponentities[slot];
1704                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1705                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1706                                 _switchweapon |= BIT(slot);
1707                 }
1708         }
1709
1710         e.strength_finished = max(0, e.strength_finished - time);
1711         e.invincible_finished = max(0, e.invincible_finished - time);
1712         e.superweapons_finished = max(0, e.superweapons_finished - time);
1713         STAT(BUFF_TIME, e) = max(0, STAT(BUFF_TIME, e) - time);
1714
1715         PREGIVE(e, items);
1716         PREGIVE_WEAPONS(e);
1717         PREGIVE(e, strength_finished);
1718         PREGIVE(e, invincible_finished);
1719         PREGIVE(e, superweapons_finished);
1720         PREGIVE_RESOURCE(e, RES_BULLETS);
1721         PREGIVE_RESOURCE(e, RES_CELLS);
1722         PREGIVE_RESOURCE(e, RES_PLASMA);
1723         PREGIVE_RESOURCE(e, RES_SHELLS);
1724         PREGIVE_RESOURCE(e, RES_ROCKETS);
1725         PREGIVE_RESOURCE(e, RES_FUEL);
1726         PREGIVE_RESOURCE(e, RES_ARMOR);
1727         PREGIVE_RESOURCE(e, RES_HEALTH);
1728
1729         for(i = beginarg; i < endarg; ++i)
1730         {
1731                 cmd = argv(i);
1732
1733                 if(cmd == "0" || stof(cmd))
1734                 {
1735                         val = stof(cmd);
1736                         continue;
1737                 }
1738                 switch(cmd)
1739                 {
1740                         case "no":
1741                                 op = OP_MAX;
1742                                 val = 0;
1743                                 continue;
1744                         case "max":
1745                                 op = OP_MAX;
1746                                 continue;
1747                         case "min":
1748                                 op = OP_MIN;
1749                                 continue;
1750                         case "plus":
1751                                 op = OP_PLUS;
1752                                 continue;
1753                         case "minus":
1754                                 op = OP_MINUS;
1755                                 continue;
1756                         case "ALL":
1757                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1758                                 got += GiveValue(e, strength_finished, op, val);
1759                                 got += GiveValue(e, invincible_finished, op, val);
1760                                 got += GiveValue(e, superweapons_finished, op, val);
1761                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1762                         case "all":
1763                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1764                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1765                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1766                         case "allweapons":
1767                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1768                         //case "allbuffs": // all buffs makes a player god, do not want!
1769                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1770                         case "allammo":
1771                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1772                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1773                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1774                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1775                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1776                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1777                                 break;
1778                         case "unlimited_ammo":
1779                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1780                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1781                                 break;
1782                         case "unlimited_weapon_ammo":
1783                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1784                                 break;
1785                         case "unlimited_superweapons":
1786                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1787                                 break;
1788                         case "jetpack":
1789                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1790                                 break;
1791                         case "fuel_regen":
1792                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1793                                 break;
1794                         case "strength":
1795                                 got += GiveValue(e, strength_finished, op, val);
1796                                 break;
1797                         case "invincible":
1798                                 got += GiveValue(e, invincible_finished, op, val);
1799                                 break;
1800                         case "superweapons":
1801                                 got += GiveValue(e, superweapons_finished, op, val);
1802                                 break;
1803                         case "cells":
1804                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1805                                 break;
1806                         case "plasma":
1807                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1808                                 break;
1809                         case "shells":
1810                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1811                                 break;
1812                         case "nails":
1813                         case "bullets":
1814                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1815                                 break;
1816                         case "rockets":
1817                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1818                                 break;
1819                         case "health":
1820                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1821                                 break;
1822                         case "armor":
1823                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1824                                 break;
1825                         case "fuel":
1826                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1827                                 break;
1828                         default:
1829                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.netname,
1830                                 {
1831                                         got += GiveBuff(e, it, op, val);
1832                                         break;
1833                                 });
1834                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1835                     got += GiveWeapon(e, it.m_id, op, val);
1836                     break;
1837                                 });
1838                                 break;
1839                 }
1840                 val = 999;
1841                 op = OP_SET;
1842         }
1843
1844         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1845         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1846         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1847         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1848         FOREACH(Weapons, it != WEP_Null, {
1849                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1850                 if(!(save_weapons & (it.m_wepset)))
1851                         if(STAT(WEAPONS, e) & (it.m_wepset))
1852                                 it.wr_init(it);
1853         });
1854         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1855         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1856         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1857         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1858         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1864         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1865
1866         if(e.superweapons_finished <= 0)
1867                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1868                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1869
1870         if(e.strength_finished <= 0)
1871                 e.strength_finished = 0;
1872         else
1873                 e.strength_finished += time;
1874         if(e.invincible_finished <= 0)
1875                 e.invincible_finished = 0;
1876         else
1877                 e.invincible_finished += time;
1878         if(e.superweapons_finished <= 0)
1879                 e.superweapons_finished = 0;
1880         else
1881                 e.superweapons_finished += time;
1882         if(STAT(BUFF_TIME, e) <= 0)
1883                 STAT(BUFF_TIME, e) = 0;
1884         else
1885                 STAT(BUFF_TIME, e) += time;
1886
1887         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888         {
1889                 .entity weaponentity = weaponentities[slot];
1890                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1891                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1892                         _switchweapon |= BIT(slot);
1893         }
1894
1895         if(_switchweapon)
1896         {
1897                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1898                 {
1899                         .entity weaponentity = weaponentities[slot];
1900                         if(_switchweapon & BIT(slot))
1901                         {
1902                                 Weapon wep = w_getbestweapon(e, weaponentity);
1903                                 if(wep != e.(weaponentity).m_switchweapon)
1904                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1905                         }
1906                 }
1907         }
1908
1909         return got;
1910 }
1911 #endif