qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include "../lib/warpzone/util_server.qh"
  26 #elif defined(CSQC)
  27         #include "physics/movetypes/movetypes.qh"
  28         #include <common/weapons/_all.qh>
  29         #include "../lib/csqcmodel/cl_model.qh"
  30         #include "../lib/csqcmodel/common.qh"
  31 #endif
  32
  33 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  34
  35 #ifdef CSQC
  36 bool autocvar_cl_ghost_items_vehicle = true;
  37 .vector item_glowmod;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = '1 1 1';
  46                 this.glowmod = this.item_glowmod;
  47         }
  48         else
  49         {
  50                 if (autocvar_cl_ghost_items_color)
  51                 {
  52                         this.alpha = autocvar_cl_ghost_items;
  53                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  54                 }
  55                 else
  56                         this.alpha = -1;
  57         }
  58
  59         if(!veh_hud)
  60         if(this.ItemStatus & ITS_STAYWEP)
  61         {
  62                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  63                 this.alpha = autocvar_cl_weapon_stay_alpha;
  64         }
  65 }
  66
  67 void ItemDraw(entity this)
  68 {
  69     if(this.gravity)
  70     {
  71         Movetype_Physics_MatchServer(this, false);
  72         if(IS_ONGROUND(this))
  73         { // For some reason avelocity gets set to '0 0 0' here ...
  74             this.oldorigin = this.origin;
  75             this.gravity = 0;
  76
  77             if(autocvar_cl_animate_items)
  78             { // ... so reset it if animations are requested.
  79                 if(this.ItemStatus & ITS_ANIMATE1)
  80                     this.avelocity = '0 180 0';
  81
  82                 if(this.ItemStatus & ITS_ANIMATE2)
  83                     this.avelocity = '0 -90 0';
  84             }
  85
  86             // delay is for blocking item's position for a while;
  87             // it's a workaround for dropped weapons that receive the position
  88             // another time right after they spawn overriding animation position
  89             this.onground_time = time + 0.5;
  90         }
  91     }
  92     else if (autocvar_cl_animate_items)
  93     {
  94         if(this.ItemStatus & ITS_ANIMATE1)
  95         {
  96             this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103             this.angles += this.avelocity * frametime;
 104             float fade_in = bound(0, time - this.onground_time, 1);
 105             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 106         }
 107     }
 108
 109     Item_SetAlpha(this);
 110 }
 111
 112 void ItemDrawSimple(entity this)
 113 {
 114     if(this.gravity)
 115     {
 116         Movetype_Physics_MatchServer(this, false);
 117
 118         if(IS_ONGROUND(this))
 119             this.gravity = 0;
 120     }
 121
 122     Item_SetAlpha(this);
 123 }
 124
 125 void Item_PreDraw(entity this)
 126 {
 127         if(warpzone_warpzones_exist)
 128         {
 129                 // just incase warpzones were initialized last, reset these
 130                 //this.alpha = 1; // alpha is already set by the draw function
 131                 this.drawmask = MASK_NORMAL;
 132                 return;
 133         }
 134         float alph;
 135         vector org = getpropertyvec(VF_ORIGIN);
 136         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 137                 alph = 0;
 138         else if(this.fade_start)
 139                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 140         else
 141                 alph = 1;
 142         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 143         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 144                 this.alpha = alph;
 145         if(alph <= 0)
 146                 this.drawmask = 0;
 147         else
 148                 this.drawmask = MASK_NORMAL;
 149 }
 150
 151 void ItemRemove(entity this)
 152 {
 153         if(this.mdl)
 154                 strunzone(this.mdl);
 155 }
 156
 157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 158 {
 159     int sf = ReadByte();
 160
 161     if(sf & ISF_LOCATION)
 162     {
 163         this.origin_x = ReadCoord();
 164         this.origin_y = ReadCoord();
 165         this.origin_z = ReadCoord();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218         if(this.mdl)
 219             strunzone(this.mdl);
 220
 221         this.mdl = "";
 222         string _fn = ReadString();
 223
 224         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 225         {
 226             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 227             this.draw = ItemDrawSimple;
 228
 229             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 230                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 231             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 237             else
 238             {
 239                 this.draw = ItemDraw;
 240                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 241             }
 242         }
 243
 244         if(this.draw != ItemDrawSimple)
 245             this.mdl = strzone(_fn);
 246
 247
 248         if(this.mdl == "")
 249             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 250
 251         precache_model(this.mdl);
 252         _setmodel(this, this.mdl);
 253
 254         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 255     }
 256
 257     if(sf & ISF_COLORMAP)
 258     {
 259         this.colormap = ReadShort();
 260         this.item_glowmod_x = ReadByte() / 255.0;
 261         this.item_glowmod_y = ReadByte() / 255.0;
 262         this.item_glowmod_z = ReadByte() / 255.0;
 263     }
 264
 265     if(sf & ISF_DROP)
 266     {
 267         this.gravity = 1;
 268         this.pushable = true;
 269         //this.angles = '0 0 0';
 270         set_movetype(this, MOVETYPE_TOSS);
 271         this.velocity_x = ReadCoord();
 272         this.velocity_y = ReadCoord();
 273         this.velocity_z = ReadCoord();
 274         setorigin(this, this.oldorigin);
 275
 276         if(!this.move_time)
 277         {
 278             this.move_time = time;
 279             this.spawntime = time;
 280         }
 281         else
 282             this.move_time = max(this.move_time, time);
 283     }
 284
 285     if(autocvar_cl_animate_items)
 286     {
 287         if(this.ItemStatus & ITS_ANIMATE1)
 288             this.avelocity = '0 180 0';
 289
 290         if(this.ItemStatus & ITS_ANIMATE2)
 291             this.avelocity = '0 -90 0';
 292     }
 293
 294     this.entremove = ItemRemove;
 295
 296     return true;
 297 }
 298
 299 #endif
 300
 301 #ifdef SVQC
 302 bool ItemSend(entity this, entity to, int sf)
 303 {
 304         if(this.gravity)
 305                 sf |= ISF_DROP;
 306         else
 307                 sf &= ~ISF_DROP;
 308
 309         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 310         WriteByte(MSG_ENTITY, sf);
 311
 312         //WriteByte(MSG_ENTITY, this.cnt);
 313         if(sf & ISF_LOCATION)
 314         {
 315                 WriteCoord(MSG_ENTITY, this.origin.x);
 316                 WriteCoord(MSG_ENTITY, this.origin.y);
 317                 WriteCoord(MSG_ENTITY, this.origin.z);
 318         }
 319
 320         if(sf & ISF_ANGLES)
 321         {
 322                 WriteAngle(MSG_ENTITY, this.angles_x);
 323                 WriteAngle(MSG_ENTITY, this.angles_y);
 324                 WriteAngle(MSG_ENTITY, this.angles_z);
 325         }
 326
 327         if(sf & ISF_SIZE)
 328         {
 329                 Pickup p = this.itemdef;
 330                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 331         }
 332
 333         if(sf & ISF_STATUS)
 334                 WriteByte(MSG_ENTITY, this.ItemStatus);
 335
 336         if(sf & ISF_MODEL)
 337         {
 338                 Pickup p = this.itemdef;
 339                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 340                 WriteShort(MSG_ENTITY, this.fade_end);
 341                 WriteShort(MSG_ENTITY, this.fade_start);
 342
 343                 if(this.mdl == "")
 344                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 345
 346                 WriteString(MSG_ENTITY, this.mdl);
 347         }
 348
 349
 350         if(sf & ISF_COLORMAP)
 351         {
 352                 WriteShort(MSG_ENTITY, this.colormap);
 353                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 354         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 356         }
 357
 358         if(sf & ISF_DROP)
 359         {
 360                 WriteCoord(MSG_ENTITY, this.velocity.x);
 361                 WriteCoord(MSG_ENTITY, this.velocity.y);
 362                 WriteCoord(MSG_ENTITY, this.velocity.z);
 363         }
 364
 365         return true;
 366 }
 367
 368 void ItemUpdate(entity this)
 369 {
 370         this.oldorigin = this.origin;
 371         this.SendFlags |= ISF_LOCATION;
 372 }
 373
 374 void UpdateItemAfterTeleport(entity this)
 375 {
 376         if(getSendEntity(this) == ItemSend)
 377                 ItemUpdate(this);
 378 }
 379
 380 bool have_pickup_item(entity this)
 381 {
 382         if(this.itemdef.instanceOfPowerup)
 383         {
 384                 if(autocvar_g_powerups > 0)
 385                         return true;
 386                 if(autocvar_g_powerups == 0)
 387                         return false;
 388         }
 389         else
 390         {
 391                 if(autocvar_g_pickup_items > 0)
 392                         return true;
 393                 if(autocvar_g_pickup_items == 0)
 394                         return false;
 395                 if(g_weaponarena)
 396                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 397                                 return false;
 398         }
 399         return true;
 400 }
 401
 402 /*
 403 float Item_Customize()
 404 {
 405         if(this.spawnshieldtime)
 406                 return true;
 407         if(this.weapons & ~other.weapons)
 408         {
 409                 this.colormod = '0 0 0';
 410                 this.glowmod = this.colormod;
 411                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 412                 return true;
 413         }
 414         else
 415         {
 416                 if(g_ghost_items)
 417                 {
 418                         this.colormod = stov(autocvar_g_ghost_items_color);
 419                         this.glowmod = this.colormod;
 420                         this.alpha = g_ghost_items;
 421                         return true;
 422                 }
 423                 else
 424                         return false;
 425         }
 426 }
 427 */
 428
 429 void Item_Show (entity e, float mode)
 430 {
 431         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 432         e.ItemStatus &= ~ITS_STAYWEP;
 433         entity def = e.itemdef;
 434         if (mode > 0)
 435         {
 436                 // make the item look normal, and be touchable
 437                 e.model = e.mdl;
 438                 e.solid = SOLID_TRIGGER;
 439                 e.spawnshieldtime = 1;
 440                 e.ItemStatus |= ITS_AVAILABLE;
 441         }
 442         else if (mode < 0)
 443         {
 444                 // hide the item completely
 445                 e.model = string_null;
 446                 e.solid = SOLID_NOT;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus &= ~ITS_AVAILABLE;
 449         }
 450         else {
 451         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 452                 || e.team // weapon stay isn't supported for teamed weapons
 453                 ;
 454         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 455         {
 456                 // make the item translucent and not touchable
 457                 e.model = e.mdl;
 458                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 459                 e.effects |= EF_STARDUST;
 460                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 461                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 462         }
 463         else
 464         {
 465                 //setmodel(e, "null");
 466                 e.solid = SOLID_NOT;
 467                 e.colormod = '0 0 0';
 468                 //e.glowmod = e.colormod;
 469                 e.spawnshieldtime = 1;
 470                 e.ItemStatus &= ~ITS_AVAILABLE;
 471         }}
 472
 473         if (def.m_glow)
 474                 e.ItemStatus |= ITS_GLOW;
 475
 476         if (autocvar_g_nodepthtestitems)
 477                 e.effects |= EF_NODEPTHTEST;
 478
 479
 480         if (autocvar_g_fullbrightitems)
 481                 e.ItemStatus |= ITS_ALLOWFB;
 482
 483         if (autocvar_sv_simple_items)
 484                 e.ItemStatus |= ITS_ALLOWSI;
 485
 486         // relink entity (because solid may have changed)
 487         setorigin(e, e.origin);
 488         e.SendFlags |= ISF_STATUS;
 489 }
 490
 491 void Item_Think(entity this)
 492 {
 493         this.nextthink = time;
 494         if(this.origin != this.oldorigin)
 495                 ItemUpdate(this);
 496 }
 497
 498 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 499 bool Item_ItemsTime_Allow(GameItem it);
 500 float Item_ItemsTime_UpdateTime(entity e, float t);
 501 void Item_ItemsTime_SetTime(entity e, float t);
 502 void Item_ItemsTime_SetTimesForAllPlayers();
 503
 504 void Item_Respawn (entity this)
 505 {
 506         Item_Show(this, 1);
 507         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 508         setorigin(this, this.origin);
 509
 510     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 511         {
 512                 float t = Item_ItemsTime_UpdateTime(this, 0);
 513                 Item_ItemsTime_SetTime(this, t);
 514                 Item_ItemsTime_SetTimesForAllPlayers();
 515         }
 516
 517         setthink(this, Item_Think);
 518         this.nextthink = time;
 519
 520         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 521         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 522 }
 523
 524 void Item_RespawnCountdown (entity this)
 525 {
 526         if(this.count >= ITEM_RESPAWN_TICKS)
 527         {
 528                 if(this.waypointsprite_attached)
 529                         WaypointSprite_Kill(this.waypointsprite_attached);
 530                 Item_Respawn(this);
 531         }
 532         else
 533         {
 534                 this.nextthink = time + 1;
 535                 this.count += 1;
 536                 if(this.count == 1)
 537                 {
 538                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 539                         do {
 540                                 {
 541                                         entity wi = Weapons_from(this.weapon);
 542                                         if (wi != WEP_Null) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 544                                                 wp.wp_extra = wi.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                                 {
 549                                         entity ii = this.itemdef;
 550                                         if (ii != NULL) {
 551                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 552                                                 wp.wp_extra = ii.m_id;
 553                                                 break;
 554                                         }
 555                                 }
 556                         } while (0);
 557             if(this.waypointsprite_attached)
 558             {
 559                 GameItem def = this.itemdef;
 560                 if (Item_ItemsTime_SpectatorOnly(def))
 561                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 562                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 563             }
 564                 }
 565
 566                 if(this.waypointsprite_attached)
 567                 {
 568                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 569                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 570                                 {
 571                                         msg_entity = it;
 572                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 573                                 }
 574                         });
 575
 576                         WaypointSprite_Ping(this.waypointsprite_attached);
 577                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 578                 }
 579         }
 580 }
 581
 582 void Item_RespawnThink(entity this)
 583 {
 584         this.nextthink = time;
 585         if(this.origin != this.oldorigin)
 586                 ItemUpdate(this);
 587
 588         if(time >= this.wait)
 589                 Item_Respawn(this);
 590 }
 591
 592 void Item_ScheduleRespawnIn(entity e, float t)
 593 {
 594         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 595         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 596         {
 597                 setthink(e, Item_RespawnCountdown);
 598                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 599                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 600                 e.count = 0;
 601                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 602                 Item_ItemsTime_SetTime(e, t);
 603                 Item_ItemsTime_SetTimesForAllPlayers();
 604         }
 605         else
 606         {
 607                 setthink(e, Item_RespawnThink);
 608                 e.nextthink = time;
 609                 e.scheduledrespawntime = time + t;
 610                 e.wait = time + t;
 611         }
 612 }
 613
 614 void Item_ScheduleRespawn(entity e)
 615 {
 616         if(e.respawntime > 0)
 617         {
 618                 Item_Show(e, 0);
 619                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 620         }
 621         else // if respawntime is -1, this item does not respawn
 622                 Item_Show(e, -1);
 623 }
 624
 625 void Item_ScheduleInitialRespawn(entity e)
 626 {
 627         Item_Show(e, 0);
 628         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 629 }
 630
 631 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 632 {
 633         if (!item.(ammotype))
 634                 return false;
 635
 636         if (item.spawnshieldtime)
 637         {
 638                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 639                 {
 640                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 641                         goto YEAH;
 642                 }
 643         }
 644         else if(g_weapon_stay == 2)
 645         {
 646                 float mi = min(item.(ammotype), ammomax);
 647                 if (player.(ammotype) < mi)
 648                 {
 649                         player.(ammotype) = mi;
 650                         goto YEAH;
 651                 }
 652         }
 653
 654         return false;
 655
 656 LABEL(YEAH)
 657         switch(mode)
 658         {
 659                 case ITEM_MODE_FUEL:
 660                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 661                         break;
 662                 case ITEM_MODE_HEALTH:
 663                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 664                         break;
 665                 case ITEM_MODE_ARMOR:
 666                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 667                         break;
 668                 default:
 669                         break;
 670         }
 671         return true;
 672 }
 673
 674 float Item_GiveTo(entity item, entity player)
 675 {
 676         float pickedup;
 677
 678         // if nothing happens to player, just return without taking the item
 679         pickedup = false;
 680         int _switchweapon = 0;
 681         // in case the player has autoswitch enabled do the following:
 682         // if the player is using their best weapon before items are given, they
 683         // probably want to switch to an even better weapon after items are given
 684
 685         if(player.autoswitch)
 686         {
 687                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 688                 {
 689                         .entity weaponentity = weaponentities[slot];
 690                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 691                         {
 692                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 693                                         _switchweapon |= BIT(slot);
 694
 695                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 696                                         _switchweapon |= BIT(slot);
 697                         }
 698                 }
 699         }
 700
 701         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 702         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 703         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 704         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 705         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 706         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 707         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 708         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 709
 710         if (item.itemdef.instanceOfWeaponPickup)
 711         {
 712                 WepSet w;
 713                 w = item.weapons;
 714                 w &= ~player.weapons;
 715
 716                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 717                 {
 718                         pickedup = true;
 719                         FOREACH(Weapons, it != WEP_Null, {
 720                                 if(w & (it.m_wepset))
 721                                 {
 722                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723                                         {
 724                                                 .entity weaponentity = weaponentities[slot];
 725                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 726                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 727                                         }
 728                                         W_GiveWeapon(player, it.m_id);
 729                                 }
 730                         });
 731                 }
 732         }
 733
 734         if (item.itemdef.instanceOfPowerup)
 735         {
 736                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 737                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 738                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 739                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 740         }
 741
 742         int its;
 743         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 744         {
 745                 pickedup = true;
 746                 player.items |= its;
 747                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 748         }
 749
 750         if (item.strength_finished)
 751         {
 752                 pickedup = true;
 753                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 754         }
 755         if (item.invincible_finished)
 756         {
 757                 pickedup = true;
 758                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 759         }
 760         if (item.superweapons_finished)
 761         {
 762                 pickedup = true;
 763                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 764         }
 765
 766 LABEL(skip)
 767
 768         // always eat teamed entities
 769         if(item.team)
 770                 pickedup = true;
 771
 772         if (!pickedup)
 773                 return 0;
 774
 775         // crude hack to enforce switching weapons
 776         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 777         {
 778                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779                 {
 780                         .entity weaponentity = weaponentities[slot];
 781                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 782                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 783                 }
 784                 return 1;
 785         }
 786
 787         if(_switchweapon)
 788         {
 789                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 790                 {
 791                         .entity weaponentity = weaponentities[slot];
 792                         if(_switchweapon & BIT(slot))
 793                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 794                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 795                 }
 796         }
 797
 798         return 1;
 799 }
 800
 801 void Item_Touch(entity this, entity toucher)
 802 {
 803
 804         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 805         if (this.classname == "droppedweapon")
 806         {
 807                 if (ITEM_TOUCH_NEEDKILL())
 808                 {
 809                         delete(this);
 810                         return;
 811                 }
 812         }
 813
 814         if(!(toucher.flags & FL_PICKUPITEMS)
 815         || STAT(FROZEN, toucher)
 816         || IS_DEAD(toucher)
 817         || (this.solid != SOLID_TRIGGER)
 818         || (this.owner == toucher)
 819         || (time < this.item_spawnshieldtime)
 820         ) { return; }
 821
 822         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 823         {
 824                 case MUT_ITEMTOUCH_RETURN: { return; }
 825                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 826         }
 827
 828         toucher = M_ARGV(1, entity);
 829
 830         if (this.classname == "droppedweapon")
 831         {
 832                 this.strength_finished = max(0, this.strength_finished - time);
 833                 this.invincible_finished = max(0, this.invincible_finished - time);
 834                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 835         }
 836         entity it = this.itemdef;
 837         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 838         if (!gave)
 839         {
 840                 if (this.classname == "droppedweapon")
 841                 {
 842                         // undo what we did above
 843                         this.strength_finished += time;
 844                         this.invincible_finished += time;
 845                         this.superweapons_finished += time;
 846                 }
 847                 return;
 848         }
 849
 850 LABEL(pickup)
 851
 852         toucher.last_pickup = time;
 853
 854         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 855         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 856
 857         if (this.classname == "droppedweapon")
 858                 delete (this);
 859         else if (this.spawnshieldtime)
 860         {
 861                 entity e;
 862                 if(this.team)
 863                 {
 864                         RandomSelection_Init();
 865                         IL_EACH(g_items, it.team == this.team,
 866                         {
 867                                 if(it.itemdef) // is a registered item
 868                                 {
 869                                         Item_Show(it, -1);
 870                                         RandomSelection_AddEnt(it, it.cnt, 0);
 871                                 }
 872                         });
 873                         e = RandomSelection_chosen_ent;
 874
 875                 }
 876                 else
 877                         e = this;
 878                 Item_ScheduleRespawn(e);
 879         }
 880 }
 881
 882 void Item_Reset(entity this)
 883 {
 884         Item_Show(this, !this.state);
 885         setorigin(this, this.origin);
 886
 887         if (this.classname != "droppedweapon")
 888         {
 889                 setthink(this, Item_Think);
 890                 this.nextthink = time;
 891
 892                 if (this.waypointsprite_attached)
 893                         WaypointSprite_Kill(this.waypointsprite_attached);
 894
 895                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 896                         Item_ScheduleInitialRespawn(this);
 897         }
 898 }
 899
 900 void Item_FindTeam(entity this)
 901 {
 902         entity e;
 903
 904         if(this.effects & EF_NODRAW)
 905         {
 906                 // marker for item team search
 907                 LOG_TRACE("Initializing item team ", ftos(this.team));
 908                 RandomSelection_Init();
 909                 IL_EACH(g_items, it.team == this.team,
 910                 {
 911                         if(it.itemdef) // is a registered item
 912                                 RandomSelection_AddEnt(it, it.cnt, 0);
 913                 });
 914
 915                 e = RandomSelection_chosen_ent;
 916                 e.state = 0;
 917                 Item_Show(e, 1);
 918
 919                 IL_EACH(g_items, it.team == this.team,
 920                 {
 921                         if(it.itemdef) // is a registered item
 922                         {
 923                                 if(it != e)
 924                                 {
 925                                         // make it non-spawned
 926                                         Item_Show(it, -1);
 927                                         it.state = 1; // state 1 = initially hidden item, apparently
 928                                 }
 929                                 it.effects &= ~EF_NODRAW;
 930                         }
 931                 });
 932
 933                 Item_Reset(this);
 934         }
 935 }
 936
 937 // Savage: used for item garbage-collection
 938 void RemoveItem(entity this)
 939 {
 940         if(wasfreed(this) || !this) { return; }
 941         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 942         delete(this);
 943 }
 944
 945 // pickup evaluation functions
 946 // these functions decide how desirable an item is to the bots
 947
 948 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 949
 950 float weapon_pickupevalfunc(entity player, entity item)
 951 {
 952         float c;
 953         int rating = item.bot_pickupbasevalue;
 954
 955         // See if I have it already
 956         if(player.weapons & item.weapons)
 957         {
 958                 // If I can pick it up
 959                 if(!item.spawnshieldtime)
 960                         c = 0;
 961                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 962                 {
 963                         if (rating > 0)
 964                                 rating = BOT_PICKUP_RATING_LOW * 0.5 * (1 + rating / BOT_PICKUP_RATING_HIGH);
 965                         // Skilled bots will grab more
 966                         c = 1 + bound(0, skill / 10, 1) * 0.5;
 967                 }
 968                 else
 969                         c = 0;
 970         }
 971         else
 972                 c = 1;
 973
 974         if (c <= 0)
 975                 return 0;
 976
 977         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 978         if(bot_custom_weapon)
 979         {
 980                 int best_ratio = 0;
 981                 int missing = 0;
 982
 983                 // evaluate weapon usefulness in all ranges
 984                 for(int list = 0; list < 3; list++)
 985                 {
 986                         int position = -1;
 987                         int wep_count = 0;
 988                         int wpn = item.weapon;
 989                         for (int j = 0; j < WEP_LAST; ++j)
 990                         {
 991                                 int list_wpn = 0;
 992                                 if (list == 0) list_wpn = bot_weapons_far[j];
 993                                 else if (list == 1) list_wpn = bot_weapons_mid[j];
 994                                 else list_wpn = bot_weapons_close[j];
 995
 996                                 if (weaponsInMap & Weapons_from(list_wpn).m_wepset) // only if available
 997                                 {
 998                                         if (list_wpn > 0)
 999                                                 wep_count++;
1000                                         if (position == -1 && list_wpn == wpn)
1001                                                 position = wep_count;
1002                                 }
1003                         }
1004                         if (position == -1)
1005                         {
1006                                 missing++;
1007                                 position = wep_count; // if missing assume last
1008                         }
1009                         if (wep_count)
1010                         {
1011                                 if (!best_ratio || position / wep_count < best_ratio)
1012                                         best_ratio = position / wep_count;
1013                         }
1014                 }
1015
1016                 if (missing < 3 && best_ratio)
1017                         c = c - best_ratio * 0.3;
1018         }
1019
1020         return rating * c;
1021 }
1022
1023 float commodity_pickupevalfunc(entity player, entity item)
1024 {
1025         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1026         float c = 0;
1027
1028         // Detect needed ammo
1029         FOREACH(Weapons, it != WEP_Null, {
1030                 if(!(player.weapons & (it.m_wepset)))
1031                         continue;
1032
1033                 switch(it.ammo_field)
1034                 {
1035                         case ammo_shells:  need_shells  = true; break;
1036                         case ammo_nails:   need_nails   = true; break;
1037                         case ammo_rockets: need_rockets = true; break;
1038                         case ammo_cells:   need_cells   = true; break;
1039                         case ammo_plasma:  need_plasma  = true; break;
1040                         case ammo_fuel:    need_fuel    = true; break;
1041                 }
1042         });
1043
1044         // TODO: figure out if the player even has the weapon this ammo is for?
1045         // may not affect strategy much though...
1046         // find out how much more ammo/armor/health the player can hold
1047         if (need_shells)
1048         if (item.ammo_shells)
1049         if (player.ammo_shells < g_pickup_shells_max)
1050                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1051         if (need_nails)
1052         if (item.ammo_nails)
1053         if (player.ammo_nails < g_pickup_nails_max)
1054                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1055         if (need_rockets)
1056         if (item.ammo_rockets)
1057         if (player.ammo_rockets < g_pickup_rockets_max)
1058                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1059         if (need_cells)
1060         if (item.ammo_cells)
1061         if (player.ammo_cells < g_pickup_cells_max)
1062                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1063         if (need_plasma)
1064         if (item.ammo_plasma)
1065         if (player.ammo_plasma < g_pickup_plasma_max)
1066                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1067         if (need_fuel)
1068         if (item.ammo_fuel)
1069         if (player.ammo_fuel < g_pickup_fuel_max)
1070                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1071         if (item.armorvalue)
1072         if (player.armorvalue < item.max_armorvalue)
1073                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1074         if (item.health)
1075         if (player.health < item.max_health)
1076                 c = c + max(0, 1 - player.health / item.max_health);
1077
1078         return item.bot_pickupbasevalue * c;
1079 }
1080
1081 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1082 {
1083         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1084                 RemoveItem(this);
1085 }
1086
1087 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1088 {
1089         string itemname = def.m_name;
1090         Model itemmodel = def.m_model;
1091     Sound pickupsound = def.m_sound;
1092         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1093         float pickupbasevalue = def.m_botvalue;
1094         int itemflags = def.m_itemflags;
1095
1096         startitem_failed = false;
1097
1098         this.item_model_ent = itemmodel;
1099     this.item_pickupsound_ent = pickupsound;
1100
1101         if(!this.respawntime) // both need to be set
1102         {
1103                 this.respawntime = defaultrespawntime;
1104                 this.respawntimejitter = defaultrespawntimejitter;
1105         }
1106
1107         int itemid = def.m_itemid;
1108         this.items = itemid;
1109         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1110         this.weapon = weaponid;
1111
1112         if(!this.fade_end)
1113         {
1114                 this.fade_start = autocvar_g_items_mindist;
1115                 this.fade_end = autocvar_g_items_maxdist;
1116         }
1117
1118         if(weaponid)
1119                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1120
1121         this.flags = FL_ITEM | itemflags;
1122         IL_PUSH(g_items, this);
1123
1124         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1125         {
1126                 startitem_failed = true;
1127                 delete(this);
1128                 return;
1129         }
1130
1131         // is it a dropped weapon?
1132         if (this.classname == "droppedweapon")
1133         {
1134                 this.reset = SUB_Remove;
1135                 // it's a dropped weapon
1136                 set_movetype(this, MOVETYPE_TOSS);
1137
1138                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1139                 setthink(this, RemoveItem);
1140                 this.nextthink = time + 20;
1141
1142                 this.takedamage = DAMAGE_YES;
1143                 this.event_damage = Item_Damage;
1144
1145                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1146                 {
1147                         // if item is worthless after a timer, have it expire then
1148                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1149                 }
1150
1151                 // don't drop if in a NODROP zone (such as lava)
1152                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1153                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1154                 {
1155                         startitem_failed = true;
1156                         delete(this);
1157                         return;
1158                 }
1159         }
1160         else
1161         {
1162                 if(!have_pickup_item(this))
1163                 {
1164                         startitem_failed = true;
1165                         delete (this);
1166                         return;
1167                 }
1168
1169                 if(this.angles != '0 0 0')
1170                         this.SendFlags |= ISF_ANGLES;
1171
1172                 this.reset = Item_Reset;
1173                 // it's a level item
1174                 if(this.spawnflags & 1)
1175                         this.noalign = 1;
1176                 if (this.noalign > 0)
1177                         set_movetype(this, MOVETYPE_NONE);
1178                 else
1179                         set_movetype(this, MOVETYPE_TOSS);
1180                 // do item filtering according to game mode and other things
1181                 if (this.noalign <= 0)
1182                 {
1183                         // first nudge it off the floor a little bit to avoid math errors
1184                         setorigin(this, this.origin + '0 0 1');
1185                         // set item size before we spawn a spawnfunc_waypoint
1186                         setsize(this, def.m_mins, def.m_maxs);
1187                         this.SendFlags |= ISF_SIZE;
1188                         // note droptofloor returns false if stuck/or would fall too far
1189                         if (!this.noalign)
1190                                 droptofloor(this);
1191                         waypoint_spawnforitem(this);
1192                 }
1193
1194                 /*
1195                  * can't do it that way, as it would break maps
1196                  * TODO make a target_give like entity another way, that perhaps has
1197                  * the weapon name in a key
1198                 if(this.targetname)
1199                 {
1200                         // target_give not yet supported; maybe later
1201                         print("removed targeted ", this.classname, "\n");
1202                         startitem_failed = true;
1203                         remove (this);
1204                         return;
1205                 }
1206                 */
1207
1208                 if(autocvar_spawn_debug >= 2)
1209                 {
1210             // why not flags & fl_item?
1211                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1212                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1213                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1214                 error("Mapper sucks.");
1215             });
1216                         this.is_item = true;
1217                 }
1218
1219                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1220
1221                 precache_model(this.model);
1222                 precache_sound(this.item_pickupsound);
1223
1224                 if (   def.instanceOfPowerup
1225                         || def.instanceOfWeaponPickup
1226                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1227                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1228                         || (itemid & (IT_KEY1 | IT_KEY2))
1229                 ) this.target = "###item###"; // for finding the nearest item using find()
1230
1231                 Item_ItemsTime_SetTime(this, 0);
1232         }
1233
1234         this.bot_pickup = true;
1235         this.bot_pickupevalfunc = pickupevalfunc;
1236         this.bot_pickupbasevalue = pickupbasevalue;
1237         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1238         this.netname = itemname;
1239         settouch(this, Item_Touch);
1240         setmodel(this, MDL_Null); // precision set below
1241         //this.effects |= EF_LOWPRECISION;
1242
1243         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1244
1245         this.SendFlags |= ISF_SIZE;
1246
1247         if (!(this.spawnflags & 1024)) {
1248                 if(def.instanceOfPowerup)
1249                         this.ItemStatus |= ITS_ANIMATE1;
1250
1251                 if(this.armorvalue || this.health)
1252                         this.ItemStatus |= ITS_ANIMATE2;
1253         }
1254
1255         if(def.instanceOfWeaponPickup)
1256         {
1257                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1258                         this.colormap = 1024; // color shirt=0 pants=0 grey
1259                 else
1260                         this.gravity = 1;
1261                 if (!(this.spawnflags & 1024))
1262                         this.ItemStatus |= ITS_ANIMATE1;
1263                 this.SendFlags |= ISF_COLORMAP;
1264         }
1265
1266         this.state = 0;
1267         if(this.team) // broken, no idea why.
1268         {
1269                 if(!this.cnt)
1270                         this.cnt = 1; // item probability weight
1271
1272                 this.effects |= EF_NODRAW; // marker for item team search
1273                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1274         }
1275         else
1276                 Item_Reset(this);
1277
1278         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1279
1280         // call this hook after everything else has been done
1281         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1282         {
1283                 startitem_failed = true;
1284                 delete(this);
1285                 return;
1286         }
1287 }
1288
1289 void StartItem(entity this, GameItem def)
1290 {
1291     _StartItem(
1292         this,
1293         this.itemdef = def,
1294         def.m_respawntime(), // defaultrespawntime
1295         def.m_respawntimejitter() // defaultrespawntimejitter
1296         );
1297 }
1298
1299 spawnfunc(item_rockets)
1300 {
1301         if(!this.ammo_rockets)
1302                 this.ammo_rockets = g_pickup_rockets;
1303         if(!this.pickup_anyway)
1304                 this.pickup_anyway = g_pickup_ammo_anyway;
1305     StartItem(this, ITEM_Rockets);
1306 }
1307
1308 spawnfunc(item_bullets)
1309 {
1310         if(!weaponswapping)
1311         if(autocvar_sv_q3acompat_machineshotgunswap)
1312         if(this.classname != "droppedweapon")
1313         {
1314                 weaponswapping = true;
1315                 spawnfunc_item_shells(this);
1316                 weaponswapping = false;
1317                 return;
1318         }
1319
1320         if(!this.ammo_nails)
1321                 this.ammo_nails = g_pickup_nails;
1322         if(!this.pickup_anyway)
1323                 this.pickup_anyway = g_pickup_ammo_anyway;
1324     StartItem(this, ITEM_Bullets);
1325 }
1326
1327 spawnfunc(item_cells)
1328 {
1329         if(!this.ammo_cells)
1330                 this.ammo_cells = g_pickup_cells;
1331         if(!this.pickup_anyway)
1332                 this.pickup_anyway = g_pickup_ammo_anyway;
1333         StartItem(this, ITEM_Cells);
1334 }
1335
1336 spawnfunc(item_plasma)
1337 {
1338         if(!this.ammo_plasma)
1339                 this.ammo_plasma = g_pickup_plasma;
1340         if(!this.pickup_anyway)
1341                 this.pickup_anyway = g_pickup_ammo_anyway;
1342         StartItem(this, ITEM_Plasma);
1343 }
1344
1345 spawnfunc(item_shells)
1346 {
1347         if(!weaponswapping)
1348         if(autocvar_sv_q3acompat_machineshotgunswap)
1349         if(this.classname != "droppedweapon")
1350         {
1351                 weaponswapping = true;
1352                 spawnfunc_item_bullets(this);
1353                 weaponswapping = false;
1354                 return;
1355         }
1356
1357         if(!this.ammo_shells)
1358                 this.ammo_shells = g_pickup_shells;
1359         if(!this.pickup_anyway)
1360                 this.pickup_anyway = g_pickup_ammo_anyway;
1361         StartItem(this, ITEM_Shells);
1362 }
1363
1364 spawnfunc(item_armor_small)
1365 {
1366         if(!this.armorvalue)
1367                 this.armorvalue = g_pickup_armorsmall;
1368         if(!this.max_armorvalue)
1369                 this.max_armorvalue = g_pickup_armorsmall_max;
1370         if(!this.pickup_anyway)
1371                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1372         StartItem(this, ITEM_ArmorSmall);
1373 }
1374
1375 spawnfunc(item_armor_medium)
1376 {
1377         if(!this.armorvalue)
1378                 this.armorvalue = g_pickup_armormedium;
1379         if(!this.max_armorvalue)
1380                 this.max_armorvalue = g_pickup_armormedium_max;
1381         if(!this.pickup_anyway)
1382                 this.pickup_anyway = g_pickup_armormedium_anyway;
1383         StartItem(this, ITEM_ArmorMedium);
1384 }
1385
1386 spawnfunc(item_armor_big)
1387 {
1388         if(!this.armorvalue)
1389                 this.armorvalue = g_pickup_armorbig;
1390         if(!this.max_armorvalue)
1391                 this.max_armorvalue = g_pickup_armorbig_max;
1392         if(!this.pickup_anyway)
1393                 this.pickup_anyway = g_pickup_armorbig_anyway;
1394         StartItem(this, ITEM_ArmorBig);
1395 }
1396
1397 spawnfunc(item_armor_mega)
1398 {
1399         if(!this.armorvalue)
1400                 this.armorvalue = g_pickup_armormega;
1401         if(!this.max_armorvalue)
1402                 this.max_armorvalue = g_pickup_armormega_max;
1403         if(!this.pickup_anyway)
1404                 this.pickup_anyway = g_pickup_armormega_anyway;
1405         StartItem(this, ITEM_ArmorMega);
1406 }
1407
1408 spawnfunc(item_health_small)
1409 {
1410         if(!this.max_health)
1411                 this.max_health = g_pickup_healthsmall_max;
1412         if(!this.health)
1413                 this.health = g_pickup_healthsmall;
1414         if(!this.pickup_anyway)
1415                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1416         StartItem(this, ITEM_HealthSmall);
1417 }
1418
1419 spawnfunc(item_health_medium)
1420 {
1421         if(!this.max_health)
1422                 this.max_health = g_pickup_healthmedium_max;
1423         if(!this.health)
1424                 this.health = g_pickup_healthmedium;
1425         if(!this.pickup_anyway)
1426                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1427     StartItem(this, ITEM_HealthMedium);
1428 }
1429
1430 spawnfunc(item_health_big)
1431 {
1432         if(!this.max_health)
1433                 this.max_health = g_pickup_healthbig_max;
1434         if(!this.health)
1435                 this.health = g_pickup_healthbig;
1436         if(!this.pickup_anyway)
1437                 this.pickup_anyway = g_pickup_healthbig_anyway;
1438         StartItem(this, ITEM_HealthBig);
1439 }
1440
1441 spawnfunc(item_health_mega)
1442 {
1443     if(!this.max_health)
1444         this.max_health = g_pickup_healthmega_max;
1445     if(!this.health)
1446         this.health = g_pickup_healthmega;
1447     if(!this.pickup_anyway)
1448         this.pickup_anyway = g_pickup_healthmega_anyway;
1449     StartItem(this, ITEM_HealthMega);
1450 }
1451
1452 // support old misnamed entities
1453 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1454 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1455 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1456 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1457 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1458 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1459 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1460
1461 spawnfunc(item_strength)
1462 {
1463                 if(!this.strength_finished)
1464                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1465                 StartItem(this, ITEM_Strength);
1466 }
1467
1468 spawnfunc(item_invincible)
1469 {
1470                 if(!this.invincible_finished)
1471                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1472                 StartItem(this, ITEM_Shield);
1473 }
1474
1475 // compatibility:
1476 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1477
1478 void target_items_use(entity this, entity actor, entity trigger)
1479 {
1480         if(actor.classname == "droppedweapon")
1481         {
1482                 EXACTTRIGGER_TOUCH(this, trigger);
1483                 delete(actor);
1484                 return;
1485         }
1486
1487         if (!IS_PLAYER(actor))
1488                 return;
1489         if(IS_DEAD(actor))
1490                 return;
1491         if(trigger.solid == SOLID_TRIGGER)
1492         {
1493                 EXACTTRIGGER_TOUCH(this, trigger);
1494         }
1495
1496         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1497         {
1498                 delete(it);
1499         });
1500
1501         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1502                 centerprint(actor, this.message);
1503 }
1504
1505 spawnfunc(target_items)
1506 {
1507         int n, j;
1508         string s;
1509
1510         this.use = target_items_use;
1511         if(!this.strength_finished)
1512                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1513         if(!this.invincible_finished)
1514                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1515         if(!this.superweapons_finished)
1516                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1517
1518         n = tokenize_console(this.netname);
1519         if(argv(0) == "give")
1520         {
1521                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1522         }
1523         else
1524         {
1525                 for(j = 0; j < n; ++j)
1526                 {
1527                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1528                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1529                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1530                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1531                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1532                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1533                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1534                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1535                         else
1536                         {
1537                                 FOREACH(Weapons, it != WEP_Null, {
1538                                         s = W_UndeprecateName(argv(j));
1539                                         if(s == it.netname)
1540                                         {
1541                                                 this.weapons |= (it.m_wepset);
1542                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1543                                                         it.wr_init(it);
1544                                                 break;
1545                                         }
1546                                 });
1547                         }
1548                 }
1549
1550                 string itemprefix, valueprefix;
1551                 if(this.spawnflags == 0)
1552                 {
1553                         itemprefix = "";
1554                         valueprefix = "";
1555                 }
1556                 else if(this.spawnflags == 1)
1557                 {
1558                         itemprefix = "max ";
1559                         valueprefix = "max ";
1560                 }
1561                 else if(this.spawnflags == 2)
1562                 {
1563                         itemprefix = "min ";
1564                         valueprefix = "min ";
1565                 }
1566                 else if(this.spawnflags == 4)
1567                 {
1568                         itemprefix = "minus ";
1569                         valueprefix = "max ";
1570                 }
1571                 else
1572                 {
1573                         error("invalid spawnflags");
1574                         itemprefix = valueprefix = string_null;
1575                 }
1576
1577                 this.netname = "";
1578                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1579                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1580                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1581                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1582                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1583                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1584                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1585                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1586                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1587                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1588                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1589                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1590                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1591                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1592                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1593                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1594         }
1595         this.netname = strzone(this.netname);
1596         //print(this.netname, "\n");
1597
1598         n = tokenize_console(this.netname);
1599         for(j = 0; j < n; ++j)
1600         {
1601                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1602             it.wr_init(it);
1603             break;
1604                 });
1605         }
1606 }
1607
1608 spawnfunc(item_fuel)
1609 {
1610         if(!this.ammo_fuel)
1611                 this.ammo_fuel = g_pickup_fuel;
1612         if(!this.pickup_anyway)
1613                 this.pickup_anyway = g_pickup_ammo_anyway;
1614         StartItem(this, ITEM_JetpackFuel);
1615 }
1616
1617 spawnfunc(item_fuel_regen)
1618 {
1619         if(start_items & ITEM_JetpackRegen.m_itemid)
1620         {
1621                 spawnfunc_item_fuel(this);
1622                 return;
1623         }
1624         StartItem(this, ITEM_JetpackRegen);
1625 }
1626
1627 spawnfunc(item_jetpack)
1628 {
1629         if(!this.ammo_fuel)
1630                 this.ammo_fuel = g_pickup_fuel_jetpack;
1631         if(start_items & ITEM_Jetpack.m_itemid)
1632         {
1633                 spawnfunc_item_fuel(this);
1634                 return;
1635         }
1636         StartItem(this, ITEM_Jetpack);
1637 }
1638
1639 float GiveWeapon(entity e, float wpn, float op, float val)
1640 {
1641         WepSet v0, v1;
1642         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1643         v0 = (e.weapons & s);
1644         switch(op)
1645         {
1646                 case OP_SET:
1647                         if(val > 0)
1648                                 e.weapons |= s;
1649                         else
1650                                 e.weapons &= ~s;
1651                         break;
1652                 case OP_MIN:
1653                 case OP_PLUS:
1654                         if(val > 0)
1655                                 e.weapons |= s;
1656                         break;
1657                 case OP_MAX:
1658                         if(val <= 0)
1659                                 e.weapons &= ~s;
1660                         break;
1661                 case OP_MINUS:
1662                         if(val > 0)
1663                                 e.weapons &= ~s;
1664                         break;
1665         }
1666         v1 = (e.weapons & s);
1667         return (v0 != v1);
1668 }
1669
1670 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1671 {
1672         if(v1 == v0)
1673                 return;
1674         if(v1 <= v0 - t)
1675         {
1676                 if(snd_decr != NULL)
1677                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1678         }
1679         else if(v0 >= v0 + t)
1680         {
1681                 if(snd_incr != NULL)
1682                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1683         }
1684 }
1685
1686 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1687 {
1688         if(v0 < v1)
1689                 e.(rotfield) = max(e.(rotfield), time + rottime);
1690         else if(v0 > v1)
1691                 e.(regenfield) = max(e.(regenfield), time + regentime);
1692 }
1693 float GiveItems(entity e, float beginarg, float endarg)
1694 {
1695         float got, i, val, op;
1696         string cmd;
1697
1698         val = 999;
1699         op = OP_SET;
1700
1701         got = 0;
1702
1703         int _switchweapon = 0;
1704
1705         if(e.autoswitch)
1706         {
1707                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1708                 {
1709                         .entity weaponentity = weaponentities[slot];
1710                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1711                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1712                                 _switchweapon |= BIT(slot);
1713                 }
1714         }
1715
1716         e.strength_finished = max(0, e.strength_finished - time);
1717         e.invincible_finished = max(0, e.invincible_finished - time);
1718         e.superweapons_finished = max(0, e.superweapons_finished - time);
1719
1720         PREGIVE(e, items);
1721         PREGIVE_WEAPONS(e);
1722         PREGIVE(e, strength_finished);
1723         PREGIVE(e, invincible_finished);
1724         PREGIVE(e, superweapons_finished);
1725         PREGIVE(e, ammo_nails);
1726         PREGIVE(e, ammo_cells);
1727         PREGIVE(e, ammo_plasma);
1728         PREGIVE(e, ammo_shells);
1729         PREGIVE(e, ammo_rockets);
1730         PREGIVE(e, ammo_fuel);
1731         PREGIVE(e, armorvalue);
1732         PREGIVE(e, health);
1733
1734         for(i = beginarg; i < endarg; ++i)
1735         {
1736                 cmd = argv(i);
1737
1738                 if(cmd == "0" || stof(cmd))
1739                 {
1740                         val = stof(cmd);
1741                         continue;
1742                 }
1743                 switch(cmd)
1744                 {
1745                         case "no":
1746                                 op = OP_MAX;
1747                                 val = 0;
1748                                 continue;
1749                         case "max":
1750                                 op = OP_MAX;
1751                                 continue;
1752                         case "min":
1753                                 op = OP_MIN;
1754                                 continue;
1755                         case "plus":
1756                                 op = OP_PLUS;
1757                                 continue;
1758                         case "minus":
1759                                 op = OP_MINUS;
1760                                 continue;
1761                         case "ALL":
1762                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1763                                 got += GiveValue(e, strength_finished, op, val);
1764                                 got += GiveValue(e, invincible_finished, op, val);
1765                                 got += GiveValue(e, superweapons_finished, op, val);
1766                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1767                         case "all":
1768                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1769                                 got += GiveValue(e, health, op, val);
1770                                 got += GiveValue(e, armorvalue, op, val);
1771                         case "allweapons":
1772                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1773                         case "allammo":
1774                                 got += GiveValue(e, ammo_cells, op, val);
1775                                 got += GiveValue(e, ammo_plasma, op, val);
1776                                 got += GiveValue(e, ammo_shells, op, val);
1777                                 got += GiveValue(e, ammo_nails, op, val);
1778                                 got += GiveValue(e, ammo_rockets, op, val);
1779                                 got += GiveValue(e, ammo_fuel, op, val);
1780                                 break;
1781                         case "unlimited_ammo":
1782                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1783                                 break;
1784                         case "unlimited_weapon_ammo":
1785                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1786                                 break;
1787                         case "unlimited_superweapons":
1788                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1789                                 break;
1790                         case "jetpack":
1791                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1792                                 break;
1793                         case "fuel_regen":
1794                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1795                                 break;
1796                         case "strength":
1797                                 got += GiveValue(e, strength_finished, op, val);
1798                                 break;
1799                         case "invincible":
1800                                 got += GiveValue(e, invincible_finished, op, val);
1801                                 break;
1802                         case "superweapons":
1803                                 got += GiveValue(e, superweapons_finished, op, val);
1804                                 break;
1805                         case "cells":
1806                                 got += GiveValue(e, ammo_cells, op, val);
1807                                 break;
1808                         case "plasma":
1809                                 got += GiveValue(e, ammo_plasma, op, val);
1810                                 break;
1811                         case "shells":
1812                                 got += GiveValue(e, ammo_shells, op, val);
1813                                 break;
1814                         case "nails":
1815                         case "bullets":
1816                                 got += GiveValue(e, ammo_nails, op, val);
1817                                 break;
1818                         case "rockets":
1819                                 got += GiveValue(e, ammo_rockets, op, val);
1820                                 break;
1821                         case "health":
1822                                 got += GiveValue(e, health, op, val);
1823                                 break;
1824                         case "armor":
1825                                 got += GiveValue(e, armorvalue, op, val);
1826                                 break;
1827                         case "fuel":
1828                                 got += GiveValue(e, ammo_fuel, op, val);
1829                                 break;
1830                         default:
1831                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1832                     got += GiveWeapon(e, it.m_id, op, val);
1833                     break;
1834                                 });
1835                                 break;
1836                 }
1837                 val = 999;
1838                 op = OP_SET;
1839         }
1840
1841         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1842         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1843         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1844         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1845         FOREACH(Weapons, it != WEP_Null, {
1846                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1847                 if(!(save_weapons & (it.m_wepset)))
1848                         if(e.weapons & (it.m_wepset))
1849                                 it.wr_init(it);
1850         });
1851         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1852         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1853         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1854         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1855         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1856         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1857         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1858         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1861         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1862
1863         if(e.superweapons_finished <= 0)
1864                 if(e.weapons & WEPSET_SUPERWEAPONS)
1865                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1866
1867         if(e.strength_finished <= 0)
1868                 e.strength_finished = 0;
1869         else
1870                 e.strength_finished += time;
1871         if(e.invincible_finished <= 0)
1872                 e.invincible_finished = 0;
1873         else
1874                 e.invincible_finished += time;
1875         if(e.superweapons_finished <= 0)
1876                 e.superweapons_finished = 0;
1877         else
1878                 e.superweapons_finished += time;
1879
1880         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1881         {
1882                 .entity weaponentity = weaponentities[slot];
1883                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1884                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1885                         _switchweapon |= BIT(slot);
1886         }
1887
1888         if(_switchweapon)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(_switchweapon & BIT(slot))
1894                                 W_SwitchWeapon_Force(e, w_getbestweapon(e, weaponentity), weaponentity);
1895                 }
1896         }
1897
1898         return got;
1899 }
1900 #endif