Fix g_fullbrightitems that requires a game restart to apply changes when it's toggle off
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "mapobjects/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26         #include <common/mutators/mutator/buffs/sv_buffs.qh>
27
28     #include "../lib/warpzone/util_server.qh"
29 #elif defined(CSQC)
30         #include "physics/movetypes/movetypes.qh"
31         #include <common/weapons/_all.qh>
32         #include "../lib/csqcmodel/cl_model.qh"
33         #include "../lib/csqcmodel/common.qh"
34 #endif
35
36 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
37
38 #ifdef CSQC
39 bool autocvar_cl_ghost_items_vehicle = true;
40 .vector item_glowmod;
41 .bool item_simple; // probably not really needed, but better safe than sorry
42 void Item_SetAlpha(entity this)
43 {
44         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
45
46         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
47         {
48                 this.alpha = 1;
49                 this.colormod = '1 1 1';
50                 this.glowmod = this.item_glowmod;
51         }
52         else
53         {
54                 this.alpha = autocvar_cl_ghost_items;
55                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56         }
57
58         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
59         {
60                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
61                 this.alpha = autocvar_cl_weapon_stay_alpha;
62         }
63
64         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
65 }
66
67 void ItemDraw(entity this)
68 {
69     if(this.gravity)
70     {
71         Movetype_Physics_MatchServer(this, false);
72         if(IS_ONGROUND(this))
73         { // For some reason avelocity gets set to '0 0 0' here ...
74             this.oldorigin = this.origin;
75             this.gravity = 0;
76
77             if(autocvar_cl_animate_items)
78             { // ... so reset it if animations are requested.
79                 if(this.ItemStatus & ITS_ANIMATE1)
80                     this.avelocity = '0 180 0';
81
82                 if(this.ItemStatus & ITS_ANIMATE2)
83                     this.avelocity = '0 -90 0';
84             }
85
86             // delay is for blocking item's position for a while;
87             // it's a workaround for dropped weapons that receive the position
88             // another time right after they spawn overriding animation position
89             this.onground_time = time + 0.5;
90         }
91     }
92     else if (autocvar_cl_animate_items && !this.item_simple) // no bobbing applied to simple items, for consistency's sake (no visual difference between ammo and weapons)
93     {
94         if(this.ItemStatus & ITS_ANIMATE1)
95         {
96                 this.angles += this.avelocity * frametime;
97             float fade_in = bound(0, time - this.onground_time, 1);
98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
99         }
100
101         if(this.ItemStatus & ITS_ANIMATE2)
102         {
103                 this.angles += this.avelocity * frametime;
104             float fade_in = bound(0, time - this.onground_time, 1);
105             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
106         }
107     }
108
109     Item_SetAlpha(this);
110 }
111
112 void Item_PreDraw(entity this)
113 {
114         if(warpzone_warpzones_exist)
115         {
116                 setpredraw(this, func_null); // no need to keep running this
117                 return;
118         }
119         float alph;
120         vector org = getpropertyvec(VF_ORIGIN);
121         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
122                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
123         if(this.fade_start)
124         {
125                 if(vdist(org - this.origin, >, this.fade_end))
126                         alph = 0; // save on some processing
127                 else if(vdist(org - this.origin, <, this.fade_start))
128                         alph = 1; // more processing saved
129                 else
130                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
131         }
132         else
133                 alph = 1;
134         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
135         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
136                 this.alpha = alph;
137         if(alph <= 0)
138                 this.drawmask = 0;
139         //else
140                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
141 }
142
143 void ItemRemove(entity this)
144 {
145         strfree(this.mdl);
146 }
147
148 HashMap ENT_CLIENT_ITEM_simple;
149 STATIC_INIT(ENT_CLIENT_ITEM_simple)
150 {
151         HM_NEW(ENT_CLIENT_ITEM_simple);
152 }
153 SHUTDOWN(ENT_CLIENT_ITEM_simple)
154 {
155         HM_DELETE(ENT_CLIENT_ITEM_simple);
156 }
157
158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
159 {
160     int sf = ReadByte();
161
162     if(sf & ISF_LOCATION)
163     {
164         this.origin = ReadVector();
165         setorigin(this, this.origin);
166         this.oldorigin = this.origin;
167     }
168
169     if(sf & ISF_ANGLES)
170     {
171         this.angles_x = ReadAngle();
172         this.angles_y = ReadAngle();
173         this.angles_z = ReadAngle();
174     }
175
176     if(sf & ISF_SIZE)
177     {
178         setsize(this, '-16 -16 0', '16 16 48');
179     }
180
181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
182     {
183         this.ItemStatus = ReadByte();
184
185         Item_SetAlpha(this);
186
187         if(this.ItemStatus & ITS_ALLOWFB)
188             this.effects |= EF_FULLBRIGHT;
189         else
190             this.effects &= ~EF_FULLBRIGHT;
191
192         if(this.ItemStatus & ITS_GLOW)
193         {
194             if(this.ItemStatus & ITS_AVAILABLE)
195                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
196             else
197                 this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
198         }
199     }
200
201     if(sf & ISF_MODEL)
202     {
203         this.drawmask  = MASK_NORMAL;
204                 set_movetype(this, MOVETYPE_TOSS);
205                 if (isnew) IL_PUSH(g_drawables, this);
206         this.draw       = ItemDraw;
207         this.solid = SOLID_TRIGGER;
208         //this.flags |= FL_ITEM;
209
210         this.fade_end = ReadShort();
211         this.fade_start = ReadShort();
212         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
213                 setpredraw(this, Item_PreDraw);
214
215                 strfree(this.mdl);
216
217         string _fn = ReadString();
218         this.item_simple = false; // reset it!
219
220         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
221         {
222             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
223             this.item_simple = true;
224
225                         #define extensions(x) \
226                                 x(md3) \
227                                 x(dpm) \
228                                 x(iqm) \
229                                 x(mdl) \
230                                 /**/
231                         #define tryext(ext) { \
232                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
233                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
234                                 if (cached == "") { \
235                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
236                                 } \
237                                 if (cached != "0") { \
238                                         strcpy(this.mdl, s); \
239                                         break; \
240                                 } \
241                         }
242                         do {
243                                 extensions(tryext);
244                                 this.item_simple = false;
245                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
246                         } while (0);
247                         #undef tryext
248                         #undef extensions
249         }
250
251         if(!this.item_simple)
252             strcpy(this.mdl, _fn);
253
254         if(this.mdl == "")
255             LOG_WARNF("this.mdl is unset for item %s", this.classname);
256
257         precache_model(this.mdl);
258         _setmodel(this, this.mdl);
259
260         setsize(this, '-16 -16 0', '16 16 48');
261     }
262
263     if(sf & ISF_COLORMAP)
264     {
265         this.colormap = ReadShort();
266         this.item_glowmod_x = ReadByte() / 255.0;
267         this.item_glowmod_y = ReadByte() / 255.0;
268         this.item_glowmod_z = ReadByte() / 255.0;
269     }
270
271     if(sf & ISF_DROP)
272     {
273         this.gravity = 1;
274         this.pushable = true;
275         //this.angles = '0 0 0';
276         set_movetype(this, MOVETYPE_TOSS);
277         this.velocity = ReadVector();
278         setorigin(this, this.oldorigin);
279
280         if(!this.move_time)
281         {
282             this.move_time = time;
283             this.spawntime = time;
284         }
285         else
286             this.move_time = max(this.move_time, time);
287     }
288
289     if(autocvar_cl_animate_items)
290     {
291         if(this.ItemStatus & ITS_ANIMATE1)
292             this.avelocity = '0 180 0';
293
294         if(this.ItemStatus & ITS_ANIMATE2)
295             this.avelocity = '0 -90 0';
296     }
297
298     this.entremove = ItemRemove;
299
300     return true;
301 }
302
303 #endif
304
305 #ifdef SVQC
306 bool ItemSend(entity this, entity to, int sf)
307 {
308         if(this.gravity)
309                 sf |= ISF_DROP;
310         else
311                 sf &= ~ISF_DROP;
312
313         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
314         WriteByte(MSG_ENTITY, sf);
315
316         //WriteByte(MSG_ENTITY, this.cnt);
317         if(sf & ISF_LOCATION)
318         {
319                 WriteVector(MSG_ENTITY, this.origin);
320         }
321
322         if(sf & ISF_ANGLES)
323         {
324                 WriteAngle(MSG_ENTITY, this.angles_x);
325                 WriteAngle(MSG_ENTITY, this.angles_y);
326                 WriteAngle(MSG_ENTITY, this.angles_z);
327         }
328
329         // sets size on the client, unused on server
330         //if(sf & ISF_SIZE)
331
332         if(sf & ISF_STATUS)
333                 WriteByte(MSG_ENTITY, this.ItemStatus);
334
335         if(sf & ISF_MODEL)
336         {
337                 WriteShort(MSG_ENTITY, this.fade_end);
338                 WriteShort(MSG_ENTITY, this.fade_start);
339
340                 if(this.mdl == "")
341                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
342
343                 WriteString(MSG_ENTITY, this.mdl);
344         }
345
346
347         if(sf & ISF_COLORMAP)
348         {
349                 WriteShort(MSG_ENTITY, this.colormap);
350                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
351                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
352                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
353         }
354
355         if(sf & ISF_DROP)
356         {
357                 WriteVector(MSG_ENTITY, this.velocity);
358         }
359
360         return true;
361 }
362
363 void ItemUpdate(entity this)
364 {
365         this.oldorigin = this.origin;
366         this.SendFlags |= ISF_LOCATION;
367 }
368
369 void UpdateItemAfterTeleport(entity this)
370 {
371         if(getSendEntity(this) == ItemSend)
372                 ItemUpdate(this);
373 }
374
375 bool have_pickup_item(entity this)
376 {
377         if(this.itemdef.instanceOfPowerup)
378         {
379                 if(autocvar_g_powerups > 0)
380                         return true;
381                 if(autocvar_g_powerups == 0)
382                         return false;
383         }
384         else
385         {
386                 if(autocvar_g_pickup_items > 0)
387                         return true;
388                 if(autocvar_g_pickup_items == 0)
389                         return false;
390                 if(g_weaponarena)
391                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
392                                 return false;
393         }
394         return true;
395 }
396
397 void Item_Show(entity e, int mode)
398 {
399         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
400         e.ItemStatus &= ~ITS_STAYWEP;
401         entity def = e.itemdef;
402         if (mode > 0)
403         {
404                 // make the item look normal, and be touchable
405                 e.model = e.mdl;
406                 e.solid = SOLID_TRIGGER;
407                 e.spawnshieldtime = 1;
408                 e.ItemStatus |= ITS_AVAILABLE;
409         }
410         else if (mode < 0)
411         {
412                 // hide the item completely
413                 e.model = string_null;
414                 e.solid = SOLID_NOT;
415                 e.spawnshieldtime = 1;
416                 e.ItemStatus &= ~ITS_AVAILABLE;
417         }
418         else
419         {
420                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
421                         || e.team // weapon stay isn't supported for teamed weapons
422                         ;
423                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
424                 {
425                         // make the item translucent and not touchable
426                         e.model = e.mdl;
427                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
428                         e.effects |= EF_STARDUST;
429                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
430                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
431                 }
432                 else
433                 {
434                         //setmodel(e, "null");
435                         e.solid = SOLID_NOT;
436                         e.colormod = '0 0 0';
437                         //e.glowmod = e.colormod;
438                         e.spawnshieldtime = 1;
439                         e.ItemStatus &= ~ITS_AVAILABLE;
440                 }
441         }
442
443         if (def.m_glow)
444                 e.ItemStatus |= ITS_GLOW;
445
446         if (autocvar_g_nodepthtestitems)
447                 e.effects |= EF_NODEPTHTEST;
448
449         if (autocvar_g_fullbrightitems)
450                 e.ItemStatus |= ITS_ALLOWFB;
451         else
452                 e.ItemStatus &= ~ITS_ALLOWFB;
453
454         if (autocvar_sv_simple_items)
455                 e.ItemStatus |= ITS_ALLOWSI;
456
457         // relink entity (because solid may have changed)
458         setorigin(e, e.origin);
459         e.SendFlags |= ISF_STATUS;
460 }
461
462 void Item_Think(entity this)
463 {
464         this.nextthink = time;
465         if(this.origin != this.oldorigin)
466                 ItemUpdate(this);
467 }
468
469 bool Item_ItemsTime_SpectatorOnly(GameItem it);
470 bool Item_ItemsTime_Allow(GameItem it);
471 float Item_ItemsTime_UpdateTime(entity e, float t);
472 void Item_ItemsTime_SetTime(entity e, float t);
473 void Item_ItemsTime_SetTimesForAllPlayers();
474
475 void Item_Respawn(entity this)
476 {
477         Item_Show(this, 1);
478         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
479         setorigin(this, this.origin);
480
481         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
482         {
483                 float t = Item_ItemsTime_UpdateTime(this, 0);
484                 Item_ItemsTime_SetTime(this, t);
485                 Item_ItemsTime_SetTimesForAllPlayers();
486         }
487
488         setthink(this, Item_Think);
489         this.nextthink = time;
490
491         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
492         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
493 }
494
495 void Item_RespawnCountdown(entity this)
496 {
497         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
498         {
499                 if(this.waypointsprite_attached)
500                         WaypointSprite_Kill(this.waypointsprite_attached);
501                 Item_Respawn(this);
502         }
503         else
504         {
505                 this.nextthink = time + 1;
506                 this.item_respawncounter += 1;
507                 if(this.item_respawncounter == 1)
508                 {
509                         do {
510                                 {
511                                         entity wi = Weapons_from(this.weapon);
512                                         if (wi != WEP_Null) {
513                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
514                                                 wp.wp_extra = wi.m_id;
515                                                 break;
516                                         }
517                                 }
518                                 {
519                                         entity ii = this.itemdef;
520                                         if (ii != NULL) {
521                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
522                                                 wp.wp_extra = ii.m_id;
523                                                 break;
524                                         }
525                                 }
526                         } while (0);
527                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
528             if(this.waypointsprite_attached)
529             {
530                 GameItem def = this.itemdef;
531                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
532                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
533                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
534             }
535                 }
536
537                 if(this.waypointsprite_attached)
538                 {
539                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
540                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
541                                 {
542                                         msg_entity = it;
543                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
544                                 }
545                         });
546
547                         WaypointSprite_Ping(this.waypointsprite_attached);
548                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
549                 }
550         }
551 }
552
553 void Item_RespawnThink(entity this)
554 {
555         this.nextthink = time;
556         if(this.origin != this.oldorigin)
557                 ItemUpdate(this);
558
559         if(time >= this.wait)
560                 Item_Respawn(this);
561 }
562
563 void Item_ScheduleRespawnIn(entity e, float t)
564 {
565         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
566         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
567         {
568                 setthink(e, Item_RespawnCountdown);
569                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
570                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
571                 e.item_respawncounter = 0;
572                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
573                 {
574                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
575                         Item_ItemsTime_SetTime(e, t);
576                         Item_ItemsTime_SetTimesForAllPlayers();
577                 }
578         }
579         else
580         {
581                 setthink(e, Item_RespawnThink);
582                 e.nextthink = time;
583                 e.scheduledrespawntime = time + t;
584                 e.wait = time + t;
585
586                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
587                 {
588                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
589                         Item_ItemsTime_SetTime(e, t);
590                         Item_ItemsTime_SetTimesForAllPlayers();
591                 }
592         }
593 }
594
595 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
596 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
597 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
598
599 /// Adjust respawn time according to the number of players.
600 float adjust_respawntime(float normal_respawntime) {
601         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
602         float o = autocvar_g_pickup_respawntime_scaling_offset;
603         float l = autocvar_g_pickup_respawntime_scaling_linear;
604
605         if (r == 0 && l == 1) {
606                 return normal_respawntime;
607         }
608
609         entity balance = TeamBalance_CheckAllowedTeams(NULL);
610         TeamBalance_GetTeamCounts(balance, NULL);
611         int players = 0;
612         for (int i = 1; i <= NUM_TEAMS; ++i)
613         {
614                 if (TeamBalance_IsTeamAllowed(balance, i))
615                 {
616                         players += TeamBalance_GetNumberOfPlayers(balance, i);
617                 }
618         }
619         TeamBalance_Destroy(balance);
620
621         if (players >= 2) {
622                 return normal_respawntime * (r / (players + o) + l);
623         } else {
624                 return normal_respawntime;
625         }
626 }
627
628 void Item_ScheduleRespawn(entity e)
629 {
630         if(e.respawntime > 0)
631         {
632                 Item_Show(e, 0);
633
634                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
635                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
636
637                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
638                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
639                 Item_ScheduleRespawnIn(e, respawn_in);
640         }
641         else // if respawntime is -1, this item does not respawn
642                 Item_Show(e, -1);
643 }
644
645 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
646         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
647
648 void Item_ScheduleInitialRespawn(entity e)
649 {
650         Item_Show(e, 0);
651
652         float spawn_in;
653         if (autocvar_g_pickup_respawntime_initial_random == 0)
654         {
655                 // range: respawntime .. respawntime + respawntimejitter
656                 spawn_in = e.respawntime + random() * e.respawntimejitter;
657         }
658         else
659         {
660                 float rnd;
661                 if (autocvar_g_pickup_respawntime_initial_random == 1)
662                 {
663                         static float shared_random = 0;
664                         // NOTE this code works only if items are scheduled at the same time (normal case)
665                         // NOTE2 random() can't return exactly 1 so this check always work as intended
666                         if (!shared_random || floor(time) > shared_random)
667                                 shared_random = floor(time) + random();
668                         rnd = shared_random - floor(time);
669                 }
670                 else
671                         rnd = random();
672
673                 // range:
674                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
675                 // else: 0 .. ITEM_RESPAWN_TICKS
676                 // this is to prevent powerups spawning unexpectedly without waypoints
677                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
678         }
679
680         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
681 }
682
683 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
684         entity ammo_entity)
685 {
686         if (num_weapons == 0)
687         {
688                 return;
689         }
690         int num_potential_weapons = tokenize_console(weapon_names);
691         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
692         {
693                 RandomSelection_Init();
694                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
695                         ++weapon_index)
696                 {
697                         string weapon = argv(weapon_index);
698                         FOREACH(Weapons, it != WEP_Null,
699                         {
700                                 // Finding a weapon which player doesn't have.
701                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
702                                 {
703                                         RandomSelection_AddEnt(it, 1, 1);
704                                         break;
705                                 }
706                         });
707                 }
708                 if (RandomSelection_chosen_ent == NULL)
709                 {
710                         return;
711                 }
712                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
713                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
714                 {
715                         continue;
716                 }
717                 if (GetResource(receiver,
718                         RandomSelection_chosen_ent.ammo_type) != 0)
719                 {
720                         continue;
721                 }
722                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
723                         GetResource(ammo_entity,
724                         RandomSelection_chosen_ent.ammo_type));
725         }
726 }
727
728 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
729 {
730         float amount = GetResource(item, res_type);
731         if (amount == 0)
732         {
733                 return false;
734         }
735         float player_amount = GetResource(player, res_type);
736         if (item.spawnshieldtime)
737         {
738                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
739                         return false;
740         }
741         else if (g_weapon_stay == 2)
742         {
743                 ammomax = min(amount, ammomax);
744                 if(player_amount >= ammomax)
745                         return false;
746         }
747         else
748                 return false;
749         if (amount < 0)
750                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
751         else
752                 GiveResourceWithLimit(player, res_type, amount, ammomax);
753         return true;
754 }
755
756 bool Item_GiveTo(entity item, entity player)
757 {
758         // if nothing happens to player, just return without taking the item
759         int _switchweapon = 0;
760         // in case the player has autoswitch enabled do the following:
761         // if the player is using their best weapon before items are given, they
762         // probably want to switch to an even better weapon after items are given
763
764         if(CS(player).autoswitch)
765         {
766                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
767                 {
768                         .entity weaponentity = weaponentities[slot];
769                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
770                         {
771                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
772                                         _switchweapon |= BIT(slot);
773
774                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
775                                         _switchweapon |= BIT(slot);
776                         }
777                 }
778         }
779         bool pickedup = false;
780         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
781         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
782         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
783         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
784         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
785         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
786         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
787         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
788         if (item.itemdef.instanceOfWeaponPickup)
789         {
790                 WepSet w;
791                 w = STAT(WEAPONS, item);
792                 w &= ~STAT(WEAPONS, player);
793
794                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
795                 {
796                         pickedup = true;
797                         FOREACH(Weapons, it != WEP_Null, {
798                                 if(w & (it.m_wepset))
799                                 {
800                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
801                                         {
802                                                 .entity weaponentity = weaponentities[slot];
803                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
804                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
805                                         }
806                                         W_GiveWeapon(player, it.m_id);
807                                 }
808                         });
809                 }
810         }
811
812         if (item.itemdef.instanceOfPowerup)
813         {
814                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
815                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
816                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
817                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
818         }
819
820         int its;
821         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
822         {
823                 pickedup = true;
824                 player.items |= its;
825                 // TODO: we probably want to show a message in the console, but not this one!
826                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
827         }
828
829         if (item.strength_finished)
830         {
831                 pickedup = true;
832                 STAT(STRENGTH_FINISHED, player) = max(STAT(STRENGTH_FINISHED, player), time) + item.strength_finished;
833         }
834         if (item.invincible_finished)
835         {
836                 pickedup = true;
837                 STAT(INVINCIBLE_FINISHED, player) = max(STAT(INVINCIBLE_FINISHED, player), time) + item.invincible_finished;
838         }
839         if (item.superweapons_finished)
840         {
841                 pickedup = true;
842                 STAT(SUPERWEAPONS_FINISHED, player) = max(STAT(SUPERWEAPONS_FINISHED, player), time) + item.superweapons_finished;
843         }
844
845         // always eat teamed entities
846         if(item.team)
847                 pickedup = true;
848
849         if (!pickedup)
850                 return false;
851
852         // crude hack to enforce switching weapons
853         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
854         {
855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
856                 {
857                         .entity weaponentity = weaponentities[slot];
858                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
859                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
860                 }
861                 return true;
862         }
863
864         if(_switchweapon)
865         {
866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
867                 {
868                         .entity weaponentity = weaponentities[slot];
869                         if(_switchweapon & BIT(slot))
870                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
871                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
872                 }
873         }
874
875         return true;
876 }
877
878 void Item_Touch(entity this, entity toucher)
879 {
880         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
881         if (Item_IsLoot(this))
882         {
883                 if (ITEM_TOUCH_NEEDKILL())
884                 {
885                         delete(this);
886                         return;
887                 }
888         }
889
890         if(!(toucher.flags & FL_PICKUPITEMS)
891         || STAT(FROZEN, toucher)
892         || IS_DEAD(toucher)
893         || (this.solid != SOLID_TRIGGER)
894         || (this.owner == toucher)
895         || (time < this.item_spawnshieldtime)
896         ) { return; }
897
898         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
899         {
900                 case MUT_ITEMTOUCH_RETURN: { return; }
901                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
902         }
903
904         toucher = M_ARGV(1, entity);
905
906         if (Item_IsExpiring(this))
907         {
908                 this.strength_finished = max(0, this.strength_finished - time);
909                 this.invincible_finished = max(0, this.invincible_finished - time);
910                 this.superweapons_finished = max(0, this.superweapons_finished - time);
911         }
912         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
913         if (!gave)
914         {
915                 if (Item_IsExpiring(this))
916                 {
917                         // undo what we did above
918                         this.strength_finished += time;
919                         this.invincible_finished += time;
920                         this.superweapons_finished += time;
921                 }
922                 return;
923         }
924
925 LABEL(pickup)
926
927         if(this.target && this.target != "" && this.target != "###item###") // defrag support
928                 SUB_UseTargets(this, toucher, NULL);
929
930         STAT(LAST_PICKUP, toucher) = time;
931
932         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
933         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
934
935         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
936         if (wasfreed(this))
937         {
938                 return;
939         }
940
941         if (Item_IsLoot(this))
942         {
943                 delete(this);
944                 return;
945         }
946         if (!this.spawnshieldtime)
947         {
948                 return;
949         }
950         entity e;
951         if (this.team)
952         {
953                 RandomSelection_Init();
954                 IL_EACH(g_items, it.team == this.team,
955                 {
956                         if (it.itemdef) // is a registered item
957                         {
958                                 Item_Show(it, -1);
959                                 it.scheduledrespawntime = 0;
960                                 RandomSelection_AddEnt(it, it.cnt, 0);
961                         }
962                 });
963                 e = RandomSelection_chosen_ent;
964                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
965         }
966         else
967                 e = this;
968         Item_ScheduleRespawn(e);
969 }
970
971 void Item_Reset(entity this)
972 {
973         Item_Show(this, !this.state);
974         setorigin(this, this.origin);
975
976         if (Item_IsLoot(this))
977         {
978                 return;
979         }
980         setthink(this, Item_Think);
981         this.nextthink = time;
982         if (this.waypointsprite_attached)
983         {
984                 WaypointSprite_Kill(this.waypointsprite_attached);
985         }
986         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
987         {
988                 Item_ScheduleInitialRespawn(this);
989         }
990 }
991
992 void Item_FindTeam(entity this)
993 {
994         entity e;
995
996         if(this.effects & EF_NODRAW)
997         {
998                 // marker for item team search
999                 LOG_TRACE("Initializing item team ", ftos(this.team));
1000                 RandomSelection_Init();
1001                 IL_EACH(g_items, it.team == this.team,
1002                 {
1003                         if(it.itemdef) // is a registered item
1004                                 RandomSelection_AddEnt(it, it.cnt, 0);
1005                 });
1006
1007                 e = RandomSelection_chosen_ent;
1008                 if (!e)
1009                         return;
1010
1011                 IL_EACH(g_items, it.team == this.team,
1012                 {
1013                         if(it.itemdef) // is a registered item
1014                         {
1015                                 if(it != e)
1016                                 {
1017                                         // make it non-spawned
1018                                         Item_Show(it, -1);
1019                                         it.state = 1; // state 1 = initially hidden item, apparently
1020                                 }
1021                                 else
1022                                         Item_Reset(it);
1023                                 it.effects &= ~EF_NODRAW;
1024                         }
1025                 });
1026         }
1027 }
1028
1029 // Savage: used for item garbage-collection
1030 void RemoveItem(entity this)
1031 {
1032         if(wasfreed(this) || !this) { return; }
1033         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1034         delete(this);
1035 }
1036
1037 // pickup evaluation functions
1038 // these functions decide how desirable an item is to the bots
1039
1040 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1041
1042 float weapon_pickupevalfunc(entity player, entity item)
1043 {
1044         // See if I have it already
1045         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1046         {
1047                 // If I can pick it up
1048                 if(!item.spawnshieldtime)
1049                         return 0;
1050                 return ammo_pickupevalfunc(player, item);
1051         }
1052
1053         // reduce weapon value if bot already got a good arsenal
1054         float c = 1;
1055         int weapons_value = 0;
1056         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1057                 weapons_value += it.bot_pickupbasevalue;
1058         });
1059         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1060
1061         return item.bot_pickupbasevalue * c;
1062 }
1063
1064 float ammo_pickupevalfunc(entity player, entity item)
1065 {
1066         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1067         entity wpn = NULL;
1068         float c = 0;
1069         float rating = 0;
1070
1071         // Detect needed ammo
1072         if(item.itemdef.instanceOfWeaponPickup)
1073         {
1074                 entity ammo = NULL;
1075                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1076                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1077                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1078                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1079                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1080                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1081
1082                 if(!ammo)
1083                         return 0;
1084                 wpn = item;
1085                 rating = ammo.m_botvalue;
1086         }
1087         else
1088         {
1089                 FOREACH(Weapons, it != WEP_Null, {
1090                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1091                                 continue;
1092
1093                         switch(it.ammo_type)
1094                         {
1095                                 case RES_SHELLS:  need_shells  = true; break;
1096                                 case RES_BULLETS: need_nails   = true; break;
1097                                 case RES_ROCKETS: need_rockets = true; break;
1098                                 case RES_CELLS:   need_cells   = true; break;
1099                                 case RES_PLASMA:  need_plasma  = true; break;
1100                                 case RES_FUEL:    need_fuel    = true; break;
1101                         }
1102                 });
1103                 rating = item.bot_pickupbasevalue;
1104         }
1105
1106         float noammorating = 0.5;
1107
1108         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1109                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1110
1111         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1112                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1113
1114         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1115                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1116
1117         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1118                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1119
1120         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1121                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1122
1123         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1124                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1125
1126         rating *= min(c, 2);
1127         if(wpn)
1128                 rating += wpn.bot_pickupbasevalue * 0.1;
1129         return rating;
1130 }
1131
1132 float healtharmor_pickupevalfunc(entity player, entity item)
1133 {
1134         float c = 0;
1135         float rating = item.bot_pickupbasevalue;
1136
1137         float itemarmor = GetResource(item, RES_ARMOR);
1138         float itemhealth = GetResource(item, RES_HEALTH);
1139
1140         if(item.item_group)
1141         {
1142                 itemarmor *= min(4, item.item_group_count);
1143                 itemhealth *= min(4, item.item_group_count);
1144         }
1145
1146         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1147                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1148
1149         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1150                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1151
1152         rating *= min(2, c);
1153         return rating;
1154 }
1155
1156 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1157 {
1158         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1159                 RemoveItem(this);
1160 }
1161
1162 void item_use(entity this, entity actor, entity trigger)
1163 {
1164         // use the touch function to handle collection
1165         gettouch(this)(this, actor);
1166 }
1167
1168 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1169 {
1170         string itemname = def.m_name;
1171         Model itemmodel = def.m_model;
1172         Sound pickupsound = def.m_sound;
1173         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1174         float pickupbasevalue = def.m_botvalue;
1175         int itemflags = def.m_itemflags;
1176
1177         startitem_failed = false;
1178
1179         this.item_model_ent = itemmodel;
1180         this.item_pickupsound_ent = pickupsound;
1181
1182         if(def.m_iteminit)
1183                 def.m_iteminit(def, this);
1184
1185         if(!this.respawntime) // both need to be set
1186         {
1187                 this.respawntime = defaultrespawntime;
1188                 this.respawntimejitter = defaultrespawntimejitter;
1189         }
1190
1191         if(!this.pickup_anyway && def.m_pickupanyway)
1192                 this.pickup_anyway = def.m_pickupanyway();
1193
1194         int itemid = def.m_itemid;
1195         this.items = itemid;
1196         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1197         this.weapon = weaponid;
1198
1199         if(!this.fade_end)
1200         {
1201                 this.fade_start = autocvar_g_items_mindist;
1202                 this.fade_end = autocvar_g_items_maxdist;
1203         }
1204
1205         if(weaponid)
1206                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1207
1208         this.flags = FL_ITEM | itemflags;
1209         IL_PUSH(g_items, this);
1210
1211         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1212         {
1213                 startitem_failed = true;
1214                 delete(this);
1215                 return;
1216         }
1217
1218         precache_model(this.model);
1219         precache_sound(this.item_pickupsound);
1220
1221         if (Item_IsLoot(this))
1222         {
1223                 this.reset = SUB_Remove;
1224                 set_movetype(this, MOVETYPE_TOSS);
1225
1226                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1227                 setthink(this, RemoveItem);
1228                 this.nextthink = time + 20;
1229
1230                 this.takedamage = DAMAGE_YES;
1231                 this.event_damage = Item_Damage;
1232
1233                 if (Item_IsExpiring(this))
1234                 {
1235                         // if item is worthless after a timer, have it expire then
1236                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1237                 }
1238
1239                 // don't drop if in a NODROP zone (such as lava)
1240                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1241                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1242                 {
1243                         startitem_failed = true;
1244                         delete(this);
1245                         return;
1246                 }
1247         }
1248         else
1249         {
1250                 if(!have_pickup_item(this))
1251                 {
1252                         startitem_failed = true;
1253                         delete(this);
1254                         return;
1255                 }
1256
1257                 if(this.angles != '0 0 0')
1258                         this.SendFlags |= ISF_ANGLES;
1259
1260                 this.reset = Item_Reset;
1261                 // it's a level item
1262                 if(this.spawnflags & 1)
1263                         this.noalign = 1;
1264                 if (this.noalign > 0)
1265                         set_movetype(this, MOVETYPE_NONE);
1266                 else
1267                         set_movetype(this, MOVETYPE_TOSS);
1268                 // do item filtering according to game mode and other things
1269                 if (this.noalign <= 0)
1270                 {
1271                         // first nudge it off the floor a little bit to avoid math errors
1272                         setorigin(this, this.origin + '0 0 1');
1273                         // set item size before we spawn a spawnfunc_waypoint
1274                         setsize(this, def.m_mins, def.m_maxs);
1275                         this.SendFlags |= ISF_SIZE;
1276                         // note droptofloor returns false if stuck/or would fall too far
1277                         if (!this.noalign)
1278                                 droptofloor(this);
1279                         waypoint_spawnforitem(this);
1280                 }
1281
1282                 /*
1283                  * can't do it that way, as it would break maps
1284                  * TODO make a target_give like entity another way, that perhaps has
1285                  * the weapon name in a key
1286                 if(this.targetname)
1287                 {
1288                         // target_give not yet supported; maybe later
1289                         print("removed targeted ", this.classname, "\n");
1290                         startitem_failed = true;
1291                         delete(this);
1292                         return;
1293                 }
1294                 */
1295
1296                 if(this.targetname != "" && (this.spawnflags & 16))
1297                         this.use = item_use;
1298
1299                 if(autocvar_spawn_debug >= 2)
1300                 {
1301             // why not flags & fl_item?
1302                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1303                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1304                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1305                 error("Mapper sucks.");
1306             });
1307                         this.is_item = true;
1308                 }
1309
1310                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1311
1312                 if (   def.instanceOfPowerup
1313                         || def.instanceOfWeaponPickup
1314                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1315                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1316                         || (itemid & (IT_KEY1 | IT_KEY2))
1317                 )
1318                 {
1319                         if(!this.target || this.target == "")
1320                                 this.target = "###item###"; // for finding the nearest item using findnearest
1321                 }
1322
1323                 Item_ItemsTime_SetTime(this, 0);
1324         }
1325
1326         this.bot_pickup = true;
1327         this.bot_pickupevalfunc = pickupevalfunc;
1328         this.bot_pickupbasevalue = pickupbasevalue;
1329         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1330         this.netname = itemname;
1331         settouch(this, Item_Touch);
1332         setmodel(this, MDL_Null); // precision set below
1333         //this.effects |= EF_LOWPRECISION;
1334
1335         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1336
1337         this.SendFlags |= ISF_SIZE;
1338
1339         if (!(this.spawnflags & 1024)) {
1340                 if(def.instanceOfPowerup)
1341                         this.ItemStatus |= ITS_ANIMATE1;
1342
1343                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1344                         this.ItemStatus |= ITS_ANIMATE2;
1345         }
1346
1347         if(Item_IsLoot(this))
1348                 this.gravity = 1;
1349
1350         if(def.instanceOfWeaponPickup)
1351         {
1352                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1353                         this.colormap = 1024; // color shirt=0 pants=0 grey
1354                 if (!(this.spawnflags & 1024))
1355                         this.ItemStatus |= ITS_ANIMATE1;
1356                 this.SendFlags |= ISF_COLORMAP;
1357         }
1358
1359         this.state = 0;
1360         if(this.team)
1361         {
1362                 if(!this.cnt)
1363                         this.cnt = 1; // item probability weight
1364
1365                 this.effects |= EF_NODRAW; // marker for item team search
1366                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1367         }
1368         else
1369                 Item_Reset(this);
1370
1371         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1372
1373         // call this hook after everything else has been done
1374         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1375         {
1376                 startitem_failed = true;
1377                 delete(this);
1378                 return;
1379         }
1380
1381         setItemGroup(this);
1382 }
1383
1384 void StartItem(entity this, GameItem def)
1385 {
1386     def = def.m_spawnfunc_hookreplace(def, this);
1387     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1388     {
1389         delete(this);
1390         return;
1391     }
1392     this.classname = def.m_canonical_spawnfunc;
1393     _StartItem(
1394         this,
1395         this.itemdef = def,
1396         def.m_respawntime(), // defaultrespawntime
1397         def.m_respawntimejitter() // defaultrespawntimejitter
1398         );
1399 }
1400
1401 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1402 int group_count = 1;
1403
1404 void setItemGroup(entity this)
1405 {
1406         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1407                 return;
1408
1409         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1410         {
1411                 if(!this.item_group)
1412                 {
1413                         if(!it.item_group)
1414                         {
1415                                 it.item_group = group_count;
1416                                 group_count++;
1417                         }
1418                         this.item_group = it.item_group;
1419                 }
1420                 else // spawning item is already part of a item_group X
1421                 {
1422                         if(!it.item_group)
1423                                 it.item_group = this.item_group;
1424                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1425                         {
1426                                 int grY = it.item_group;
1427                                 // move all items of item_group Y to item_group X
1428                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1429                                 {
1430                                         if(it.item_group == grY)
1431                                                 it.item_group = this.item_group;
1432                                 });
1433                         }
1434                 }
1435         });
1436 }
1437
1438 void setItemGroupCount()
1439 {
1440         for (int k = 1; k <= group_count; k++)
1441         {
1442                 int count = 0;
1443                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1444                 if (count)
1445                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1446         }
1447 }
1448
1449 void target_items_use(entity this, entity actor, entity trigger)
1450 {
1451         if(Item_IsLoot(actor))
1452         {
1453                 EXACTTRIGGER_TOUCH(this, trigger);
1454                 delete(actor);
1455                 return;
1456         }
1457
1458         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1459                 return;
1460
1461         if(trigger.solid == SOLID_TRIGGER)
1462         {
1463                 EXACTTRIGGER_TOUCH(this, trigger);
1464         }
1465
1466         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1467         {
1468                 delete(it);
1469         });
1470
1471         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1472                 centerprint(actor, this.message);
1473 }
1474
1475 spawnfunc(target_items)
1476 {
1477         this.use = target_items_use;
1478         if(!this.strength_finished)
1479                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1480         if(!this.invincible_finished)
1481                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1482         if(!this.superweapons_finished)
1483                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1484
1485         string str;
1486         int n = tokenize_console(this.netname);
1487         if(argv(0) == "give")
1488         {
1489                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1490         }
1491         else
1492         {
1493                 for(int j = 0; j < n; ++j)
1494                 {
1495                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1496                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1497                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1498                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1499                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1500                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1501                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1502                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1503                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1504                         else
1505                         {
1506                                 FOREACH(Buffs, it != BUFF_Null,
1507                                 {
1508                                         string s = Buff_UndeprecateName(argv(j));
1509                                         if(s == it.netname)
1510                                         {
1511                                                 STAT(BUFFS, this) |= (it.m_itemid);
1512                                                 if(!STAT(BUFF_TIME, this))
1513                                                         STAT(BUFF_TIME, this) = it.m_time(it);
1514                                                 break;
1515                                         }
1516                                 });
1517                                 FOREACH(Weapons, it != WEP_Null, {
1518                                         string s = W_UndeprecateName(argv(j));
1519                                         if(s == it.netname)
1520                                         {
1521                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1522                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1523                                                         it.wr_init(it);
1524                                                 break;
1525                                         }
1526                                 });
1527                         }
1528                 }
1529
1530                 string itemprefix, valueprefix;
1531                 if(this.spawnflags == 0)
1532                 {
1533                         itemprefix = "";
1534                         valueprefix = "";
1535                 }
1536                 else if(this.spawnflags == 1)
1537                 {
1538                         itemprefix = "max ";
1539                         valueprefix = "max ";
1540                 }
1541                 else if(this.spawnflags == 2)
1542                 {
1543                         itemprefix = "min ";
1544                         valueprefix = "min ";
1545                 }
1546                 else if(this.spawnflags == 4)
1547                 {
1548                         itemprefix = "minus ";
1549                         valueprefix = "max ";
1550                 }
1551                 else
1552                 {
1553                         error("invalid spawnflags");
1554                         itemprefix = valueprefix = string_null;
1555                 }
1556
1557                 str = "";
1558                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1559                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1560                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1561                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1562                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1563                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1564                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1565                 float res;
1566                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1567                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1568                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1569                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1570                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1571                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1572                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1573                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1574                 // HACK: buffs share a single timer, so we need to include enabled buffs AFTER disabled ones to avoid loss
1575                 FOREACH(Buffs, it != BUFF_Null && !(STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1576                 FOREACH(Buffs, it != BUFF_Null && (STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1577                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1578         }
1579         this.netname = strzone(str);
1580
1581         n = tokenize_console(this.netname);
1582         for(int j = 0; j < n; ++j)
1583         {
1584                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1585                         it.wr_init(it);
1586                         break;
1587                 });
1588         }
1589 }
1590
1591 float GiveWeapon(entity e, float wpn, float op, float val)
1592 {
1593         WepSet v0, v1;
1594         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1595         v0 = (STAT(WEAPONS, e) & s);
1596         switch(op)
1597         {
1598                 case OP_SET:
1599                         if(val > 0)
1600                                 STAT(WEAPONS, e) |= s;
1601                         else
1602                                 STAT(WEAPONS, e) &= ~s;
1603                         break;
1604                 case OP_MIN:
1605                 case OP_PLUS:
1606                         if(val > 0)
1607                                 STAT(WEAPONS, e) |= s;
1608                         break;
1609                 case OP_MAX:
1610                         if(val <= 0)
1611                                 STAT(WEAPONS, e) &= ~s;
1612                         break;
1613                 case OP_MINUS:
1614                         if(val > 0)
1615                                 STAT(WEAPONS, e) &= ~s;
1616                         break;
1617         }
1618         v1 = (STAT(WEAPONS, e) & s);
1619         return (v0 != v1);
1620 }
1621
1622 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1623 {
1624         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1625         float new_buff_time = ((had_buff) ? STAT(BUFF_TIME, e) : 0);
1626         switch (op)
1627         {
1628                 case OP_SET:
1629                         new_buff_time = val;
1630                         break;
1631                 case OP_MIN:
1632                         new_buff_time = max(new_buff_time, val);
1633                         break;
1634                 case OP_MAX:
1635                         new_buff_time = min(new_buff_time, val);
1636                         break;
1637                 case OP_PLUS:
1638                         new_buff_time += val;
1639                         break;
1640                 case OP_MINUS:
1641                         new_buff_time -= val;
1642                         break;
1643         }
1644         if(new_buff_time <= 0)
1645         {
1646                 if(had_buff)
1647                         STAT(BUFF_TIME, e) = new_buff_time;
1648                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1649         }
1650         else
1651         {
1652                 STAT(BUFF_TIME, e) = new_buff_time;
1653                 STAT(BUFFS, e) = thebuff.m_itemid; // NOTE: replaces any existing buffs on the player!
1654         }
1655         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1656         return (had_buff != have_buff);
1657 }
1658
1659 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1660 {
1661         if(v1 == v0)
1662                 return;
1663         if(v1 <= v0 - t)
1664         {
1665                 if(snd_decr != NULL)
1666                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1667         }
1668         else if(v0 >= v0 + t)
1669         {
1670                 if(snd_incr != NULL)
1671                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1672         }
1673 }
1674
1675 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1676 {
1677         if(v0 < v1)
1678                 e.(rotfield) = max(e.(rotfield), time + rottime);
1679         else if(v0 > v1)
1680                 e.(regenfield) = max(e.(regenfield), time + regentime);
1681 }
1682 bool GiveResourceValue(entity e, int res_type, int op, int val)
1683 {
1684         int v0 = GetResource(e, res_type);
1685         float new_val = 0;
1686         switch (op)
1687         {
1688                 // min 100 cells = at least 100 cells
1689                 case OP_SET: new_val = val; break;
1690                 case OP_MIN: new_val = max(v0, val); break;
1691                 case OP_MAX: new_val = min(v0, val); break;
1692                 case OP_PLUS: new_val = v0 + val; break;
1693                 case OP_MINUS: new_val = v0 - val; break;
1694                 default: return false;
1695         }
1696
1697         return SetResourceExplicit(e, res_type, new_val);
1698 }
1699
1700 float GiveItems(entity e, float beginarg, float endarg)
1701 {
1702         float got, i, val, op;
1703         string cmd;
1704
1705         val = 999;
1706         op = OP_SET;
1707
1708         got = 0;
1709
1710         int _switchweapon = 0;
1711
1712         if(CS(e).autoswitch)
1713         {
1714                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1715                 {
1716                         .entity weaponentity = weaponentities[slot];
1717                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1718                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1719                                 _switchweapon |= BIT(slot);
1720                 }
1721         }
1722
1723         STAT(STRENGTH_FINISHED, e) = max(0, STAT(STRENGTH_FINISHED, e) - time);
1724         STAT(INVINCIBLE_FINISHED, e) = max(0, STAT(INVINCIBLE_FINISHED, e) - time);
1725         STAT(SUPERWEAPONS_FINISHED, e) = max(0, STAT(SUPERWEAPONS_FINISHED, e) - time);
1726         STAT(BUFF_TIME, e) = max(0, STAT(BUFF_TIME, e) - time);
1727
1728         PREGIVE(e, items);
1729         PREGIVE_WEAPONS(e);
1730         PREGIVE(e, stat_STRENGTH_FINISHED);
1731         PREGIVE(e, stat_INVINCIBLE_FINISHED);
1732         PREGIVE(e, stat_SUPERWEAPONS_FINISHED);
1733         PREGIVE_RESOURCE(e, RES_BULLETS);
1734         PREGIVE_RESOURCE(e, RES_CELLS);
1735         PREGIVE_RESOURCE(e, RES_PLASMA);
1736         PREGIVE_RESOURCE(e, RES_SHELLS);
1737         PREGIVE_RESOURCE(e, RES_ROCKETS);
1738         PREGIVE_RESOURCE(e, RES_FUEL);
1739         PREGIVE_RESOURCE(e, RES_ARMOR);
1740         PREGIVE_RESOURCE(e, RES_HEALTH);
1741
1742         for(i = beginarg; i < endarg; ++i)
1743         {
1744                 cmd = argv(i);
1745
1746                 if(cmd == "0" || stof(cmd))
1747                 {
1748                         val = stof(cmd);
1749                         continue;
1750                 }
1751                 switch(cmd)
1752                 {
1753                         case "no":
1754                                 op = OP_MAX;
1755                                 val = 0;
1756                                 continue;
1757                         case "max":
1758                                 op = OP_MAX;
1759                                 continue;
1760                         case "min":
1761                                 op = OP_MIN;
1762                                 continue;
1763                         case "plus":
1764                                 op = OP_PLUS;
1765                                 continue;
1766                         case "minus":
1767                                 op = OP_MINUS;
1768                                 continue;
1769                         case "ALL":
1770                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1771                                 got += GiveValue(e, stat_STRENGTH_FINISHED, op, val);
1772                                 got += GiveValue(e, stat_INVINCIBLE_FINISHED, op, val);
1773                                 got += GiveValue(e, stat_SUPERWEAPONS_FINISHED, op, val);
1774                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1775                         case "all":
1776                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1777                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1778                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1779                         case "allweapons":
1780                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1781                         //case "allbuffs": // all buffs makes a player god, do not want!
1782                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1783                         case "allammo":
1784                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1785                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1786                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1787                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1788                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1789                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1790                                 break;
1791                         case "unlimited_ammo":
1792                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1793                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1794                                 break;
1795                         case "unlimited_weapon_ammo":
1796                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1797                                 break;
1798                         case "unlimited_superweapons":
1799                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1800                                 break;
1801                         case "jetpack":
1802                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1803                                 break;
1804                         case "fuel_regen":
1805                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1806                                 break;
1807                         case "strength":
1808                                 got += GiveValue(e, stat_STRENGTH_FINISHED, op, val);
1809                                 break;
1810                         case "invincible":
1811                                 got += GiveValue(e, stat_INVINCIBLE_FINISHED, op, val);
1812                                 break;
1813                         case "superweapons":
1814                                 got += GiveValue(e, stat_SUPERWEAPONS_FINISHED, op, val);
1815                                 break;
1816                         case "cells":
1817                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1818                                 break;
1819                         case "plasma":
1820                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1821                                 break;
1822                         case "shells":
1823                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1824                                 break;
1825                         case "nails":
1826                         case "bullets":
1827                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1828                                 break;
1829                         case "rockets":
1830                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1831                                 break;
1832                         case "health":
1833                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1834                                 break;
1835                         case "armor":
1836                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1837                                 break;
1838                         case "fuel":
1839                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1840                                 break;
1841                         default:
1842                                 FOREACH(Buffs, it != BUFF_Null && buff_Available(it) && Buff_UndeprecateName(cmd) == it.netname,
1843                                 {
1844                                         got += GiveBuff(e, it, op, val);
1845                                         break;
1846                                 });
1847                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1848                     got += GiveWeapon(e, it.m_id, op, val);
1849                     break;
1850                                 });
1851                                 break;
1852                 }
1853                 val = 999;
1854                 op = OP_SET;
1855         }
1856
1857         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1858         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1859         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1860         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1861         FOREACH(Weapons, it != WEP_Null, {
1862                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1863                 if(!(save_weapons & (it.m_wepset)))
1864                         if(STAT(WEAPONS, e) & (it.m_wepset))
1865                                 it.wr_init(it);
1866         });
1867         POSTGIVE_VALUE(e, stat_STRENGTH_FINISHED, 1, SND_POWERUP, SND_POWEROFF);
1868         POSTGIVE_VALUE(e, stat_INVINCIBLE_FINISHED, 1, SND_Shield, SND_POWEROFF);
1869         //POSTGIVE_VALUE(e, stat_SUPERWEAPONS_FINISHED, 1, SND_Null, SND_Null);
1870         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1871         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1872         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1873         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1874         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1875         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1876         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1877         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1878
1879         if(STAT(SUPERWEAPONS_FINISHED, e) <= 0)
1880                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1881                         STAT(SUPERWEAPONS_FINISHED, e) = autocvar_g_balance_superweapons_time;
1882
1883         if(STAT(STRENGTH_FINISHED, e) <= 0)
1884                 STAT(STRENGTH_FINISHED, e) = 0;
1885         else
1886                 STAT(STRENGTH_FINISHED, e) += time;
1887         if(STAT(INVINCIBLE_FINISHED, e) <= 0)
1888                 STAT(INVINCIBLE_FINISHED, e) = 0;
1889         else
1890                 STAT(INVINCIBLE_FINISHED, e) += time;
1891         if(STAT(SUPERWEAPONS_FINISHED, e) <= 0)
1892                 STAT(SUPERWEAPONS_FINISHED, e) = 0;
1893         else
1894                 STAT(SUPERWEAPONS_FINISHED, e) += time;
1895         if(STAT(BUFF_TIME, e) <= 0)
1896                 STAT(BUFF_TIME, e) = 0;
1897         else
1898                 STAT(BUFF_TIME, e) += time;
1899
1900         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1901         {
1902                 .entity weaponentity = weaponentities[slot];
1903                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1904                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1905                         _switchweapon |= BIT(slot);
1906         }
1907
1908         if(_switchweapon)
1909         {
1910                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1911                 {
1912                         .entity weaponentity = weaponentities[slot];
1913                         if(_switchweapon & BIT(slot))
1914                         {
1915                                 Weapon wep = w_getbestweapon(e, weaponentity);
1916                                 if(wep != e.(weaponentity).m_switchweapon)
1917                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1918                         }
1919                 }
1920         }
1921
1922         return got;
1923 }
1924 #endif