Merge branch 'master' into Lyberta/TeamplayOverhaul
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "mapobjects/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 .bool item_simple; // probably not really needed, but better safe than sorry
41 void Item_SetAlpha(entity this)
42 {
43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
44
45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
46         {
47                 this.alpha = 1;
48                 this.colormod = '1 1 1';
49                 this.glowmod = this.item_glowmod;
50         }
51         else
52         {
53                 this.alpha = autocvar_cl_ghost_items;
54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
55         }
56
57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
58         {
59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
60                 this.alpha = autocvar_cl_weapon_stay_alpha;
61         }
62
63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
64 }
65
66 void ItemDraw(entity this)
67 {
68     if(this.gravity)
69     {
70         Movetype_Physics_MatchServer(this, false);
71         if(IS_ONGROUND(this))
72         { // For some reason avelocity gets set to '0 0 0' here ...
73             this.oldorigin = this.origin;
74             this.gravity = 0;
75
76             if(autocvar_cl_animate_items)
77             { // ... so reset it if animations are requested.
78                 if(this.ItemStatus & ITS_ANIMATE1)
79                     this.avelocity = '0 180 0';
80
81                 if(this.ItemStatus & ITS_ANIMATE2)
82                     this.avelocity = '0 -90 0';
83             }
84
85             // delay is for blocking item's position for a while;
86             // it's a workaround for dropped weapons that receive the position
87             // another time right after they spawn overriding animation position
88             this.onground_time = time + 0.5;
89         }
90     }
91     else if (autocvar_cl_animate_items)
92     {
93         if(this.ItemStatus & ITS_ANIMATE1)
94         {
95                 if(!this.item_simple)
96                 this.angles += this.avelocity * frametime;
97             float fade_in = bound(0, time - this.onground_time, 1);
98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
99         }
100
101         if(this.ItemStatus & ITS_ANIMATE2)
102         {
103                 if(!this.item_simple)
104                 this.angles += this.avelocity * frametime;
105             float fade_in = bound(0, time - this.onground_time, 1);
106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
107         }
108     }
109
110     Item_SetAlpha(this);
111 }
112
113 void Item_PreDraw(entity this)
114 {
115         if(warpzone_warpzones_exist)
116         {
117                 setpredraw(this, func_null); // no need to keep running this
118                 return;
119         }
120         float alph;
121         vector org = getpropertyvec(VF_ORIGIN);
122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
124         if(this.fade_start)
125         {
126                 if(vdist(org - this.origin, >, this.fade_end))
127                         alph = 0; // save on some processing
128                 else if(vdist(org - this.origin, <, this.fade_start))
129                         alph = 1; // more processing saved
130                 else
131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
132         }
133         else
134                 alph = 1;
135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
137                 this.alpha = alph;
138         if(alph <= 0)
139                 this.drawmask = 0;
140         //else
141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
142 }
143
144 void ItemRemove(entity this)
145 {
146         strfree(this.mdl);
147 }
148
149 HashMap ENT_CLIENT_ITEM_simple;
150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
151 {
152         HM_NEW(ENT_CLIENT_ITEM_simple);
153 }
154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
155 {
156         HM_DELETE(ENT_CLIENT_ITEM_simple);
157 }
158
159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
160 {
161     int sf = ReadByte();
162
163     if(sf & ISF_LOCATION)
164     {
165         this.origin = ReadVector();
166         setorigin(this, this.origin);
167         this.oldorigin = this.origin;
168     }
169
170     if(sf & ISF_ANGLES)
171     {
172         this.angles_x = ReadAngle();
173         this.angles_y = ReadAngle();
174         this.angles_z = ReadAngle();
175     }
176
177     if(sf & ISF_SIZE)
178     {
179         float use_bigsize = ReadByte();
180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
181     }
182
183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
184     {
185         this.ItemStatus = ReadByte();
186
187         Item_SetAlpha(this);
188
189         if(autocvar_cl_fullbright_items)
190             if(this.ItemStatus & ITS_ALLOWFB)
191                 this.effects |= EF_FULLBRIGHT;
192
193         if(this.ItemStatus & ITS_GLOW)
194         {
195             if(this.ItemStatus & ITS_AVAILABLE)
196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
197             else
198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
199         }
200     }
201
202     if(sf & ISF_MODEL)
203     {
204         this.drawmask  = MASK_NORMAL;
205                 set_movetype(this, MOVETYPE_TOSS);
206                 if (isnew) IL_PUSH(g_drawables, this);
207         this.draw       = ItemDraw;
208         this.solid = SOLID_TRIGGER;
209         //this.flags |= FL_ITEM;
210
211         bool use_bigsize = ReadByte();
212
213         this.fade_end = ReadShort();
214         this.fade_start = ReadShort();
215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
216                 setpredraw(this, Item_PreDraw);
217
218                 strfree(this.mdl);
219
220         string _fn = ReadString();
221         this.item_simple = false; // reset it!
222
223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
224         {
225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
226             this.item_simple = true;
227
228                         #define extensions(x) \
229                                 x(md3) \
230                                 x(dpm) \
231                                 x(iqm) \
232                                 x(mdl) \
233                                 /**/
234                         #define tryext(ext) { \
235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
237                                 if (cached == "") { \
238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
239                                 } \
240                                 if (cached != "0") { \
241                                         strcpy(this.mdl, s); \
242                                         break; \
243                                 } \
244                         }
245                         do {
246                                 extensions(tryext);
247                                 this.item_simple = false;
248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
249                         } while (0);
250                         #undef tryext
251                         #undef extensions
252         }
253
254         if(!this.item_simple)
255             strcpy(this.mdl, _fn);
256
257         if(this.mdl == "")
258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
259
260         precache_model(this.mdl);
261         _setmodel(this, this.mdl);
262
263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
264     }
265
266     if(sf & ISF_COLORMAP)
267     {
268         this.colormap = ReadShort();
269         this.item_glowmod_x = ReadByte() / 255.0;
270         this.item_glowmod_y = ReadByte() / 255.0;
271         this.item_glowmod_z = ReadByte() / 255.0;
272     }
273
274     if(sf & ISF_DROP)
275     {
276         this.gravity = 1;
277         this.pushable = true;
278         //this.angles = '0 0 0';
279         set_movetype(this, MOVETYPE_TOSS);
280         this.velocity = ReadVector();
281         setorigin(this, this.oldorigin);
282
283         if(!this.move_time)
284         {
285             this.move_time = time;
286             this.spawntime = time;
287         }
288         else
289             this.move_time = max(this.move_time, time);
290     }
291
292     if(autocvar_cl_animate_items)
293     {
294         if(this.ItemStatus & ITS_ANIMATE1)
295             this.avelocity = '0 180 0';
296
297         if(this.ItemStatus & ITS_ANIMATE2)
298             this.avelocity = '0 -90 0';
299     }
300
301     this.entremove = ItemRemove;
302
303     return true;
304 }
305
306 #endif
307
308 #ifdef SVQC
309 bool ItemSend(entity this, entity to, int sf)
310 {
311         if(this.gravity)
312                 sf |= ISF_DROP;
313         else
314                 sf &= ~ISF_DROP;
315
316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
317         WriteByte(MSG_ENTITY, sf);
318
319         //WriteByte(MSG_ENTITY, this.cnt);
320         if(sf & ISF_LOCATION)
321         {
322                 WriteVector(MSG_ENTITY, this.origin);
323         }
324
325         if(sf & ISF_ANGLES)
326         {
327                 WriteAngle(MSG_ENTITY, this.angles_x);
328                 WriteAngle(MSG_ENTITY, this.angles_y);
329                 WriteAngle(MSG_ENTITY, this.angles_z);
330         }
331
332         if(sf & ISF_SIZE)
333         {
334                 Pickup p = this.itemdef;
335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
336         }
337
338         if(sf & ISF_STATUS)
339                 WriteByte(MSG_ENTITY, this.ItemStatus);
340
341         if(sf & ISF_MODEL)
342         {
343                 Pickup p = this.itemdef;
344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
345                 WriteShort(MSG_ENTITY, this.fade_end);
346                 WriteShort(MSG_ENTITY, this.fade_start);
347
348                 if(this.mdl == "")
349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
350
351                 WriteString(MSG_ENTITY, this.mdl);
352         }
353
354
355         if(sf & ISF_COLORMAP)
356         {
357                 WriteShort(MSG_ENTITY, this.colormap);
358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
361         }
362
363         if(sf & ISF_DROP)
364         {
365                 WriteVector(MSG_ENTITY, this.velocity);
366         }
367
368         return true;
369 }
370
371 void ItemUpdate(entity this)
372 {
373         this.oldorigin = this.origin;
374         this.SendFlags |= ISF_LOCATION;
375 }
376
377 void UpdateItemAfterTeleport(entity this)
378 {
379         if(getSendEntity(this) == ItemSend)
380                 ItemUpdate(this);
381 }
382
383 bool have_pickup_item(entity this)
384 {
385         if(this.itemdef.instanceOfPowerup)
386         {
387                 if(autocvar_g_powerups > 0)
388                         return true;
389                 if(autocvar_g_powerups == 0)
390                         return false;
391         }
392         else
393         {
394                 if(autocvar_g_pickup_items > 0)
395                         return true;
396                 if(autocvar_g_pickup_items == 0)
397                         return false;
398                 if(g_weaponarena)
399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
400                                 return false;
401         }
402         return true;
403 }
404
405 void Item_Show (entity e, float mode)
406 {
407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
408         e.ItemStatus &= ~ITS_STAYWEP;
409         entity def = e.itemdef;
410         if (mode > 0)
411         {
412                 // make the item look normal, and be touchable
413                 e.model = e.mdl;
414                 e.solid = SOLID_TRIGGER;
415                 e.spawnshieldtime = 1;
416                 e.ItemStatus |= ITS_AVAILABLE;
417         }
418         else if (mode < 0)
419         {
420                 // hide the item completely
421                 e.model = string_null;
422                 e.solid = SOLID_NOT;
423                 e.spawnshieldtime = 1;
424                 e.ItemStatus &= ~ITS_AVAILABLE;
425         }
426         else
427         {
428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
429                         || e.team // weapon stay isn't supported for teamed weapons
430                         ;
431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
432                 {
433                         // make the item translucent and not touchable
434                         e.model = e.mdl;
435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
436                         e.effects |= EF_STARDUST;
437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
439                 }
440                 else
441                 {
442                         //setmodel(e, "null");
443                         e.solid = SOLID_NOT;
444                         e.colormod = '0 0 0';
445                         //e.glowmod = e.colormod;
446                         e.spawnshieldtime = 1;
447                         e.ItemStatus &= ~ITS_AVAILABLE;
448                 }
449         }
450
451         if (def.m_glow)
452                 e.ItemStatus |= ITS_GLOW;
453
454         if (autocvar_g_nodepthtestitems)
455                 e.effects |= EF_NODEPTHTEST;
456
457
458         if (autocvar_g_fullbrightitems)
459                 e.ItemStatus |= ITS_ALLOWFB;
460
461         if (autocvar_sv_simple_items)
462                 e.ItemStatus |= ITS_ALLOWSI;
463
464         // relink entity (because solid may have changed)
465         setorigin(e, e.origin);
466         e.SendFlags |= ISF_STATUS;
467 }
468
469 void Item_Think(entity this)
470 {
471         this.nextthink = time;
472         if(this.origin != this.oldorigin)
473                 ItemUpdate(this);
474 }
475
476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
477 bool Item_ItemsTime_Allow(GameItem it);
478 float Item_ItemsTime_UpdateTime(entity e, float t);
479 void Item_ItemsTime_SetTime(entity e, float t);
480 void Item_ItemsTime_SetTimesForAllPlayers();
481
482 void Item_Respawn (entity this)
483 {
484         Item_Show(this, 1);
485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
486         setorigin(this, this.origin);
487
488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
489         {
490                 float t = Item_ItemsTime_UpdateTime(this, 0);
491                 Item_ItemsTime_SetTime(this, t);
492                 Item_ItemsTime_SetTimesForAllPlayers();
493         }
494
495         setthink(this, Item_Think);
496         this.nextthink = time;
497
498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
500 }
501
502 void Item_RespawnCountdown (entity this)
503 {
504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
505         {
506                 if(this.waypointsprite_attached)
507                         WaypointSprite_Kill(this.waypointsprite_attached);
508                 Item_Respawn(this);
509         }
510         else
511         {
512                 this.nextthink = time + 1;
513                 this.item_respawncounter += 1;
514                 if(this.item_respawncounter == 1)
515                 {
516                         do {
517                                 {
518                                         entity wi = Weapons_from(this.weapon);
519                                         if (wi != WEP_Null) {
520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
521                                                 wp.wp_extra = wi.m_id;
522                                                 break;
523                                         }
524                                 }
525                                 {
526                                         entity ii = this.itemdef;
527                                         if (ii != NULL) {
528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
529                                                 wp.wp_extra = ii.m_id;
530                                                 break;
531                                         }
532                                 }
533                         } while (0);
534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
535             if(this.waypointsprite_attached)
536             {
537                 GameItem def = this.itemdef;
538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
541             }
542                 }
543
544                 if(this.waypointsprite_attached)
545                 {
546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
548                                 {
549                                         msg_entity = it;
550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
551                                 }
552                         });
553
554                         WaypointSprite_Ping(this.waypointsprite_attached);
555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
556                 }
557         }
558 }
559
560 void Item_RespawnThink(entity this)
561 {
562         this.nextthink = time;
563         if(this.origin != this.oldorigin)
564                 ItemUpdate(this);
565
566         if(time >= this.wait)
567                 Item_Respawn(this);
568 }
569
570 void Item_ScheduleRespawnIn(entity e, float t)
571 {
572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
574         {
575                 setthink(e, Item_RespawnCountdown);
576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
578                 e.item_respawncounter = 0;
579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
580                 {
581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
582                         Item_ItemsTime_SetTime(e, t);
583                         Item_ItemsTime_SetTimesForAllPlayers();
584                 }
585         }
586         else
587         {
588                 setthink(e, Item_RespawnThink);
589                 e.nextthink = time;
590                 e.scheduledrespawntime = time + t;
591                 e.wait = time + t;
592
593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
594                 {
595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
596                         Item_ItemsTime_SetTime(e, t);
597                         Item_ItemsTime_SetTimesForAllPlayers();
598                 }
599         }
600 }
601
602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
605
606 /// Adjust respawn time according to the number of players.
607 float adjust_respawntime(float normal_respawntime) {
608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
609         float o = autocvar_g_pickup_respawntime_scaling_offset;
610         float l = autocvar_g_pickup_respawntime_scaling_linear;
611
612         if (r == 0 && l == 1) {
613                 return normal_respawntime;
614         }
615
616         entity balance = TeamBalance_CheckAllowedTeams(NULL);
617         TeamBalance_GetTeamCounts(balance, NULL);
618         int players = 0;
619         for (int i = 1; i <= NUM_TEAMS; ++i)
620         {
621                 if (TeamBalance_IsTeamAllowed(balance, i))
622                 {
623                         players += TeamBalance_GetNumberOfPlayers(balance, i);
624                 }
625         }
626         TeamBalance_Destroy(balance);
627         
628         if (players >= 2) {
629                 return normal_respawntime * (r / (players + o) + l);
630         } else {
631                 return normal_respawntime;
632         }
633 }
634
635 void Item_ScheduleRespawn(entity e)
636 {
637         if(e.respawntime > 0)
638         {
639                 Item_Show(e, 0);
640
641                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
642                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
643
644                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
645                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
646                 Item_ScheduleRespawnIn(e, respawn_in);
647         }
648         else // if respawntime is -1, this item does not respawn
649                 Item_Show(e, -1);
650 }
651
652 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
653         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
654
655 void Item_ScheduleInitialRespawn(entity e)
656 {
657         Item_Show(e, 0);
658
659         float spawn_in;
660         if (autocvar_g_pickup_respawntime_initial_random == 0)
661         {
662                 // range: respawntime .. respawntime + respawntimejitter
663                 spawn_in = e.respawntime + random() * e.respawntimejitter;
664         }
665         else
666         {
667                 float rnd;
668                 if (autocvar_g_pickup_respawntime_initial_random == 1)
669                 {
670                         static float shared_random = 0;
671                         // NOTE this code works only if items are scheduled at the same time (normal case)
672                         // NOTE2 random() can't return exactly 1 so this check always work as intended
673                         if (!shared_random || floor(time) > shared_random)
674                                 shared_random = floor(time) + random();
675                         rnd = shared_random - floor(time);
676                 }
677                 else
678                         rnd = random();
679
680                 // range:
681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
682                 // else: 0 .. ITEM_RESPAWN_TICKS
683                 // this is to prevent powerups spawning unexpectedly without waypoints
684                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
685         }
686
687         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
688 }
689
690 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
691         entity ammo_entity)
692 {
693         if (num_weapons == 0)
694         {
695                 return;
696         }
697         int num_potential_weapons = tokenize_console(weapon_names);
698         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
699         {
700                 RandomSelection_Init();
701                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
702                         ++weapon_index)
703                 {
704                         string weapon = argv(weapon_index);
705                         FOREACH(Weapons, it != WEP_Null,
706                         {
707                                 // Finding a weapon which player doesn't have.
708                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
709                                 {
710                                         RandomSelection_AddEnt(it, 1, 1);
711                                         break;
712                                 }
713                         });
714                 }
715                 if (RandomSelection_chosen_ent == NULL)
716                 {
717                         return;
718                 }
719                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
720                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
721                 {
722                         continue;
723                 }
724                 if (GetResourceAmount(receiver,
725                         RandomSelection_chosen_ent.ammo_type) != 0)
726                 {
727                         continue;
728                 }
729                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
730                         GetResourceAmount(ammo_entity,
731                         RandomSelection_chosen_ent.ammo_type));
732         }
733 }
734
735 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
736 {
737         float amount = GetResourceAmount(item, resource_type);
738         if (amount == 0)
739         {
740                 return false;
741         }
742         float player_amount = GetResourceAmount(player, resource_type);
743         if (item.spawnshieldtime)
744         {
745                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
746                 {
747                         return false;
748                 }
749                 GiveOrTakeResourceWithLimit(player, resource_type, amount, ammomax);
750                 return true;
751         }
752         if (g_weapon_stay != 2)
753         {
754                 return false;
755         }
756         GiveOrTakeResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
757         return true;
758 }
759
760 float Item_GiveTo(entity item, entity player)
761 {
762         float pickedup;
763
764         // if nothing happens to player, just return without taking the item
765         pickedup = false;
766         int _switchweapon = 0;
767         // in case the player has autoswitch enabled do the following:
768         // if the player is using their best weapon before items are given, they
769         // probably want to switch to an even better weapon after items are given
770
771         if(CS(player).autoswitch)
772         {
773                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
774                 {
775                         .entity weaponentity = weaponentities[slot];
776                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
777                         {
778                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
779                                         _switchweapon |= BIT(slot);
780
781                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
782                                         _switchweapon |= BIT(slot);
783                         }
784                 }
785         }
786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
788         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
789         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
790         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
791         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
792         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
793         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
794         if (item.itemdef.instanceOfWeaponPickup)
795         {
796                 WepSet w;
797                 w = STAT(WEAPONS, item);
798                 w &= ~STAT(WEAPONS, player);
799
800                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
801                 {
802                         pickedup = true;
803                         FOREACH(Weapons, it != WEP_Null, {
804                                 if(w & (it.m_wepset))
805                                 {
806                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
807                                         {
808                                                 .entity weaponentity = weaponentities[slot];
809                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
810                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
811                                         }
812                                         W_GiveWeapon(player, it.m_id);
813                                 }
814                         });
815                 }
816         }
817
818         if (item.itemdef.instanceOfPowerup)
819         {
820                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
821                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
822                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
823                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
824         }
825
826         int its;
827         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
828         {
829                 pickedup = true;
830                 player.items |= its;
831                 // TODO: we probably want to show a message in the console, but not this one!
832                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
833         }
834
835         if (item.strength_finished)
836         {
837                 pickedup = true;
838                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
839         }
840         if (item.invincible_finished)
841         {
842                 pickedup = true;
843                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
844         }
845         if (item.superweapons_finished)
846         {
847                 pickedup = true;
848                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
849         }
850
851         // always eat teamed entities
852         if(item.team)
853                 pickedup = true;
854
855         if (!pickedup)
856                 return 0;
857
858         // crude hack to enforce switching weapons
859         if(g_cts && item.itemdef.instanceOfWeaponPickup)
860         {
861                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
862                 {
863                         .entity weaponentity = weaponentities[slot];
864                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
865                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
866                 }
867                 return 1;
868         }
869
870         if(_switchweapon)
871         {
872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
873                 {
874                         .entity weaponentity = weaponentities[slot];
875                         if(_switchweapon & BIT(slot))
876                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
877                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
878                 }
879         }
880
881         return 1;
882 }
883
884 void Item_Touch(entity this, entity toucher)
885 {
886         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
887         if (Item_IsLoot(this))
888         {
889                 if (ITEM_TOUCH_NEEDKILL())
890                 {
891                         delete(this);
892                         return;
893                 }
894         }
895
896         if(!(toucher.flags & FL_PICKUPITEMS)
897         || STAT(FROZEN, toucher)
898         || IS_DEAD(toucher)
899         || (this.solid != SOLID_TRIGGER)
900         || (this.owner == toucher)
901         || (time < this.item_spawnshieldtime)
902         ) { return; }
903
904         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
905         {
906                 case MUT_ITEMTOUCH_RETURN: { return; }
907                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
908         }
909
910         toucher = M_ARGV(1, entity);
911
912         if (Item_IsExpiring(this))
913         {
914                 this.strength_finished = max(0, this.strength_finished - time);
915                 this.invincible_finished = max(0, this.invincible_finished - time);
916                 this.superweapons_finished = max(0, this.superweapons_finished - time);
917         }
918         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
919         if (!gave)
920         {
921                 if (Item_IsExpiring(this))
922                 {
923                         // undo what we did above
924                         this.strength_finished += time;
925                         this.invincible_finished += time;
926                         this.superweapons_finished += time;
927                 }
928                 return;
929         }
930
931 LABEL(pickup)
932
933         STAT(LAST_PICKUP, toucher) = time;
934
935         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
936         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
937
938         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
939         if (wasfreed(this))
940         {
941                 return;
942         }
943
944         if (Item_IsLoot(this))
945         {
946                 delete(this);
947                 return;
948         }
949         if (!this.spawnshieldtime)
950         {
951                 return;
952         }
953         entity e;
954         if (this.team)
955         {
956                 RandomSelection_Init();
957                 IL_EACH(g_items, it.team == this.team,
958                 {
959                         if (it.itemdef) // is a registered item
960                         {
961                                 Item_Show(it, -1);
962                                 it.scheduledrespawntime = 0;
963                                 RandomSelection_AddEnt(it, it.cnt, 0);
964                         }
965                 });
966                 e = RandomSelection_chosen_ent;
967                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
968         }
969         else
970                 e = this;
971         Item_ScheduleRespawn(e);
972 }
973
974 void Item_Reset(entity this)
975 {
976         Item_Show(this, !this.state);
977         setorigin(this, this.origin);
978
979         if (Item_IsLoot(this))
980         {
981                 return;
982         }
983         setthink(this, Item_Think);
984         this.nextthink = time;
985         if (this.waypointsprite_attached)
986         {
987                 WaypointSprite_Kill(this.waypointsprite_attached);
988         }
989         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
990         {
991                 Item_ScheduleInitialRespawn(this);
992         }
993 }
994
995 void Item_FindTeam(entity this)
996 {
997         entity e;
998
999         if(this.effects & EF_NODRAW)
1000         {
1001                 // marker for item team search
1002                 LOG_TRACE("Initializing item team ", ftos(this.team));
1003                 RandomSelection_Init();
1004                 IL_EACH(g_items, it.team == this.team,
1005                 {
1006                         if(it.itemdef) // is a registered item
1007                                 RandomSelection_AddEnt(it, it.cnt, 0);
1008                 });
1009
1010                 e = RandomSelection_chosen_ent;
1011                 e.state = 0;
1012                 Item_Show(e, 1);
1013
1014                 IL_EACH(g_items, it.team == this.team,
1015                 {
1016                         if(it.itemdef) // is a registered item
1017                         {
1018                                 if(it != e)
1019                                 {
1020                                         // make it non-spawned
1021                                         Item_Show(it, -1);
1022                                         it.state = 1; // state 1 = initially hidden item, apparently
1023                                 }
1024                                 it.effects &= ~EF_NODRAW;
1025                         }
1026                 });
1027
1028                 Item_Reset(this);
1029         }
1030 }
1031
1032 // Savage: used for item garbage-collection
1033 void RemoveItem(entity this)
1034 {
1035         if(wasfreed(this) || !this) { return; }
1036         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1037         delete(this);
1038 }
1039
1040 // pickup evaluation functions
1041 // these functions decide how desirable an item is to the bots
1042
1043 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1044
1045 float weapon_pickupevalfunc(entity player, entity item)
1046 {
1047         // See if I have it already
1048         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1049         {
1050                 // If I can pick it up
1051                 if(!item.spawnshieldtime)
1052                         return 0;
1053                 return ammo_pickupevalfunc(player, item);
1054         }
1055
1056         // reduce weapon value if bot already got a good arsenal
1057         float c = 1;
1058         int weapons_value = 0;
1059         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1060                 weapons_value += it.bot_pickupbasevalue;
1061         });
1062         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1063
1064         return item.bot_pickupbasevalue * c;
1065 }
1066
1067 float ammo_pickupevalfunc(entity player, entity item)
1068 {
1069         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1070         entity wpn = NULL;
1071         float c = 0;
1072         float rating = 0;
1073
1074         // Detect needed ammo
1075         if(item.itemdef.instanceOfWeaponPickup)
1076         {
1077                 entity ammo = NULL;
1078                 if(GetResourceAmount(item, RESOURCE_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1079                 else if(GetResourceAmount(item, RESOURCE_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1080                 else if(GetResourceAmount(item, RESOURCE_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1081                 else if(GetResourceAmount(item, RESOURCE_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1082                 else if(GetResourceAmount(item, RESOURCE_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1083                 else if(GetResourceAmount(item, RESOURCE_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1084
1085                 if(!ammo)
1086                         return 0;
1087                 wpn = item;
1088                 rating = ammo.m_botvalue;
1089         }
1090         else
1091         {
1092                 FOREACH(Weapons, it != WEP_Null, {
1093                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1094                                 continue;
1095
1096                         switch(it.ammo_type)
1097                         {
1098                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1099                                 case RESOURCE_BULLETS: need_nails   = true; break;
1100                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1101                                 case RESOURCE_CELLS:   need_cells   = true; break;
1102                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1103                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1104                         }
1105                 });
1106                 rating = item.bot_pickupbasevalue;
1107         }
1108
1109         float noammorating = 0.5;
1110
1111         if ((need_shells) && GetResourceAmount(item, RESOURCE_SHELLS) && (GetResourceAmount(player, RESOURCE_SHELLS) < g_pickup_shells_max))
1112                 c = GetResourceAmount(item, RESOURCE_SHELLS) / max(noammorating, GetResourceAmount(player, RESOURCE_SHELLS));
1113
1114         if ((need_nails) && GetResourceAmount(item, RESOURCE_BULLETS) && (GetResourceAmount(player, RESOURCE_BULLETS) < g_pickup_nails_max))
1115                 c = GetResourceAmount(item, RESOURCE_BULLETS) / max(noammorating, GetResourceAmount(player, RESOURCE_BULLETS));
1116
1117         if ((need_rockets) && GetResourceAmount(item, RESOURCE_ROCKETS) && (GetResourceAmount(player, RESOURCE_ROCKETS) < g_pickup_rockets_max))
1118                 c = GetResourceAmount(item, RESOURCE_ROCKETS) / max(noammorating, GetResourceAmount(player, RESOURCE_ROCKETS));
1119
1120         if ((need_cells) && GetResourceAmount(item, RESOURCE_CELLS) && (GetResourceAmount(player, RESOURCE_CELLS) < g_pickup_cells_max))
1121                 c = GetResourceAmount(item, RESOURCE_CELLS) / max(noammorating, GetResourceAmount(player, RESOURCE_CELLS));
1122
1123         if ((need_plasma) && GetResourceAmount(item, RESOURCE_PLASMA) && (GetResourceAmount(player, RESOURCE_PLASMA) < g_pickup_plasma_max))
1124                 c = GetResourceAmount(item, RESOURCE_PLASMA) / max(noammorating, GetResourceAmount(player, RESOURCE_PLASMA));
1125
1126         if ((need_fuel) && GetResourceAmount(item, RESOURCE_FUEL) && (GetResourceAmount(player, RESOURCE_FUEL) < g_pickup_fuel_max))
1127                 c = GetResourceAmount(item, RESOURCE_FUEL) / max(noammorating, GetResourceAmount(player, RESOURCE_FUEL));
1128
1129         rating *= min(c, 2);
1130         if(wpn)
1131                 rating += wpn.bot_pickupbasevalue * 0.1;
1132         return rating;
1133 }
1134
1135 float healtharmor_pickupevalfunc(entity player, entity item)
1136 {
1137         float c = 0;
1138         float rating = item.bot_pickupbasevalue;
1139
1140         float itemarmor = GetResourceAmount(item, RESOURCE_ARMOR);
1141         float itemhealth = GetResourceAmount(item, RESOURCE_HEALTH);
1142
1143         if(item.item_group)
1144         {
1145                 itemarmor *= min(4, item.item_group_count);
1146                 itemhealth *= min(4, item.item_group_count);
1147         }
1148
1149         if (itemarmor && (GetResourceAmount(player, RESOURCE_ARMOR) < item.max_armorvalue))
1150                 c = itemarmor / max(1, GetResourceAmount(player, RESOURCE_ARMOR) * 2/3 + GetResourceAmount(player, RESOURCE_HEALTH) * 1/3);
1151
1152         if (itemhealth && (GetResourceAmount(player, RESOURCE_HEALTH) < item.max_health))
1153                 c = itemhealth / max(1, GetResourceAmount(player, RESOURCE_HEALTH));
1154
1155         rating *= min(2, c);
1156         return rating;
1157 }
1158
1159 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1160 {
1161         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1162                 RemoveItem(this);
1163 }
1164
1165 void item_use(entity this, entity actor, entity trigger)
1166 {
1167         // use the touch function to handle collection
1168         gettouch(this)(this, actor);
1169 }
1170
1171 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1172 {
1173         string itemname = def.m_name;
1174         Model itemmodel = def.m_model;
1175     Sound pickupsound = def.m_sound;
1176         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1177         float pickupbasevalue = def.m_botvalue;
1178         int itemflags = def.m_itemflags;
1179
1180         startitem_failed = false;
1181
1182         this.item_model_ent = itemmodel;
1183     this.item_pickupsound_ent = pickupsound;
1184
1185     if(def.m_iteminit)
1186         def.m_iteminit(def, this);
1187
1188         if(!this.respawntime) // both need to be set
1189         {
1190                 this.respawntime = defaultrespawntime;
1191                 this.respawntimejitter = defaultrespawntimejitter;
1192         }
1193
1194         if(!this.pickup_anyway && def.m_pickupanyway)
1195                 this.pickup_anyway = def.m_pickupanyway();
1196
1197         int itemid = def.m_itemid;
1198         this.items = itemid;
1199         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1200         this.weapon = weaponid;
1201
1202         if(!this.fade_end)
1203         {
1204                 this.fade_start = autocvar_g_items_mindist;
1205                 this.fade_end = autocvar_g_items_maxdist;
1206         }
1207
1208         if(weaponid)
1209                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1210
1211         this.flags = FL_ITEM | itemflags;
1212         IL_PUSH(g_items, this);
1213
1214         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1215         {
1216                 startitem_failed = true;
1217                 delete(this);
1218                 return;
1219         }
1220
1221         if (Item_IsLoot(this))
1222         {
1223                 this.reset = SUB_Remove;
1224                 set_movetype(this, MOVETYPE_TOSS);
1225
1226                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1227                 setthink(this, RemoveItem);
1228                 this.nextthink = time + 20;
1229
1230                 this.takedamage = DAMAGE_YES;
1231                 this.event_damage = Item_Damage;
1232
1233                 if (Item_IsExpiring(this))
1234                 {
1235                         // if item is worthless after a timer, have it expire then
1236                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1237                 }
1238
1239                 // don't drop if in a NODROP zone (such as lava)
1240                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1241                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1242                 {
1243                         startitem_failed = true;
1244                         delete(this);
1245                         return;
1246                 }
1247         }
1248         else
1249         {
1250                 if(!have_pickup_item(this))
1251                 {
1252                         startitem_failed = true;
1253                         delete(this);
1254                         return;
1255                 }
1256
1257                 if(this.angles != '0 0 0')
1258                         this.SendFlags |= ISF_ANGLES;
1259
1260                 this.reset = Item_Reset;
1261                 // it's a level item
1262                 if(this.spawnflags & 1)
1263                         this.noalign = 1;
1264                 if (this.noalign > 0)
1265                         set_movetype(this, MOVETYPE_NONE);
1266                 else
1267                         set_movetype(this, MOVETYPE_TOSS);
1268                 // do item filtering according to game mode and other things
1269                 if (this.noalign <= 0)
1270                 {
1271                         // first nudge it off the floor a little bit to avoid math errors
1272                         setorigin(this, this.origin + '0 0 1');
1273                         // set item size before we spawn a spawnfunc_waypoint
1274                         setsize(this, def.m_mins, def.m_maxs);
1275                         this.SendFlags |= ISF_SIZE;
1276                         // note droptofloor returns false if stuck/or would fall too far
1277                         if (!this.noalign)
1278                                 droptofloor(this);
1279                         waypoint_spawnforitem(this);
1280                 }
1281
1282                 /*
1283                  * can't do it that way, as it would break maps
1284                  * TODO make a target_give like entity another way, that perhaps has
1285                  * the weapon name in a key
1286                 if(this.targetname)
1287                 {
1288                         // target_give not yet supported; maybe later
1289                         print("removed targeted ", this.classname, "\n");
1290                         startitem_failed = true;
1291                         delete(this);
1292                         return;
1293                 }
1294                 */
1295
1296                 if(this.targetname != "" && (this.spawnflags & 16))
1297                         this.use = item_use;
1298
1299                 if(autocvar_spawn_debug >= 2)
1300                 {
1301             // why not flags & fl_item?
1302                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1303                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1304                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1305                 error("Mapper sucks.");
1306             });
1307                         this.is_item = true;
1308                 }
1309
1310                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1311
1312                 precache_model(this.model);
1313                 precache_sound(this.item_pickupsound);
1314
1315                 if (   def.instanceOfPowerup
1316                         || def.instanceOfWeaponPickup
1317                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1318                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1319                         || (itemid & (IT_KEY1 | IT_KEY2))
1320                 ) this.target = "###item###"; // for finding the nearest item using find()
1321
1322                 Item_ItemsTime_SetTime(this, 0);
1323         }
1324
1325         this.bot_pickup = true;
1326         this.bot_pickupevalfunc = pickupevalfunc;
1327         this.bot_pickupbasevalue = pickupbasevalue;
1328         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1329         this.netname = itemname;
1330         settouch(this, Item_Touch);
1331         setmodel(this, MDL_Null); // precision set below
1332         //this.effects |= EF_LOWPRECISION;
1333
1334         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1335
1336         this.SendFlags |= ISF_SIZE;
1337
1338         if (!(this.spawnflags & 1024)) {
1339                 if(def.instanceOfPowerup)
1340                         this.ItemStatus |= ITS_ANIMATE1;
1341
1342                 if(GetResourceAmount(this, RESOURCE_ARMOR) || GetResourceAmount(this, RESOURCE_HEALTH))
1343                         this.ItemStatus |= ITS_ANIMATE2;
1344         }
1345
1346         if(def.instanceOfWeaponPickup)
1347         {
1348                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1349                         this.colormap = 1024; // color shirt=0 pants=0 grey
1350                 else
1351                         this.gravity = 1;
1352                 if (!(this.spawnflags & 1024))
1353                         this.ItemStatus |= ITS_ANIMATE1;
1354                 this.SendFlags |= ISF_COLORMAP;
1355         }
1356
1357         this.state = 0;
1358         if(this.team) // broken, no idea why.
1359         {
1360                 if(!this.cnt)
1361                         this.cnt = 1; // item probability weight
1362
1363                 this.effects |= EF_NODRAW; // marker for item team search
1364                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1365         }
1366         else
1367                 Item_Reset(this);
1368
1369         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1370
1371         // call this hook after everything else has been done
1372         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1373         {
1374                 startitem_failed = true;
1375                 delete(this);
1376                 return;
1377         }
1378
1379         setItemGroup(this);
1380 }
1381
1382 void StartItem(entity this, GameItem def)
1383 {
1384     def = def.m_spawnfunc_hookreplace(def, this);
1385     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1386     {
1387         delete(this);
1388         return;
1389     }
1390     this.classname = def.m_canonical_spawnfunc;
1391     _StartItem(
1392         this,
1393         this.itemdef = def,
1394         def.m_respawntime(), // defaultrespawntime
1395         def.m_respawntimejitter() // defaultrespawntimejitter
1396         );
1397 }
1398
1399 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1400 int group_count = 1;
1401
1402 void setItemGroup(entity this)
1403 {
1404         if(!IS_SMALL(this.itemdef))
1405                 return;
1406
1407         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1408         {
1409                 if(!this.item_group)
1410                 {
1411                         if(!it.item_group)
1412                         {
1413                                 it.item_group = group_count;
1414                                 group_count++;
1415                         }
1416                         this.item_group = it.item_group;
1417                 }
1418                 else // spawning item is already part of a item_group X
1419                 {
1420                         if(!it.item_group)
1421                                 it.item_group = this.item_group;
1422                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1423                         {
1424                                 int grY = it.item_group;
1425                                 // move all items of item_group Y to item_group X
1426                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1427                                 {
1428                                         if(it.item_group == grY)
1429                                                 it.item_group = this.item_group;
1430                                 });
1431                         }
1432                 }
1433         });
1434 }
1435
1436 void setItemGroupCount()
1437 {
1438         for (int k = 1; k <= group_count; k++)
1439         {
1440                 int count = 0;
1441                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1442                 if (count)
1443                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1444         }
1445 }
1446
1447 void target_items_use(entity this, entity actor, entity trigger)
1448 {
1449         if(Item_IsLoot(actor))
1450         {
1451                 EXACTTRIGGER_TOUCH(this, trigger);
1452                 delete(actor);
1453                 return;
1454         }
1455
1456         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1457                 return;
1458
1459         if(trigger.solid == SOLID_TRIGGER)
1460         {
1461                 EXACTTRIGGER_TOUCH(this, trigger);
1462         }
1463
1464         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1465         {
1466                 delete(it);
1467         });
1468
1469         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1470                 centerprint(actor, this.message);
1471 }
1472
1473 spawnfunc(target_items)
1474 {
1475         int n;
1476         string s;
1477
1478         this.use = target_items_use;
1479         if(!this.strength_finished)
1480                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1481         if(!this.invincible_finished)
1482                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1483         if(!this.superweapons_finished)
1484                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1485
1486         n = tokenize_console(this.netname);
1487         if(argv(0) == "give")
1488         {
1489                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1490         }
1491         else
1492         {
1493                 for(int j = 0; j < n; ++j)
1494                 {
1495                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1496                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1497                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1498                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1499                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1500                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1501                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1502                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1503                         else
1504                         {
1505                                 FOREACH(Buffs, it != BUFF_Null,
1506                                 {
1507                                         s = Buff_UndeprecateName(argv(j));
1508                                         if(s == it.m_name)
1509                                         {
1510                                                 STAT(BUFFS, this) |= (it.m_itemid);
1511                                                 break;
1512                                         }
1513                                 });
1514                                 FOREACH(Weapons, it != WEP_Null, {
1515                                         s = W_UndeprecateName(argv(j));
1516                                         if(s == it.netname)
1517                                         {
1518                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1519                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1520                                                         it.wr_init(it);
1521                                                 break;
1522                                         }
1523                                 });
1524                         }
1525                 }
1526
1527                 string itemprefix, valueprefix;
1528                 if(this.spawnflags == 0)
1529                 {
1530                         itemprefix = "";
1531                         valueprefix = "";
1532                 }
1533                 else if(this.spawnflags == 1)
1534                 {
1535                         itemprefix = "max ";
1536                         valueprefix = "max ";
1537                 }
1538                 else if(this.spawnflags == 2)
1539                 {
1540                         itemprefix = "min ";
1541                         valueprefix = "min ";
1542                 }
1543                 else if(this.spawnflags == 4)
1544                 {
1545                         itemprefix = "minus ";
1546                         valueprefix = "max ";
1547                 }
1548                 else
1549                 {
1550                         error("invalid spawnflags");
1551                         itemprefix = valueprefix = string_null;
1552                 }
1553
1554                 this.netname = "";
1555                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1557                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1558                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1559                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1562                 if(GetResourceAmount(this, RESOURCE_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_SHELLS)), "shells");
1563                 if(GetResourceAmount(this, RESOURCE_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_BULLETS)), "nails");
1564                 if(GetResourceAmount(this, RESOURCE_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_ROCKETS)), "rockets");
1565                 if(GetResourceAmount(this, RESOURCE_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_CELLS)), "cells");
1566                 if(GetResourceAmount(this, RESOURCE_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_PLASMA)), "plasma");
1567                 if(GetResourceAmount(this, RESOURCE_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_FUEL)), "fuel");
1568                 if(GetResourceAmount(this, RESOURCE_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_HEALTH)), "health");
1569                 if(GetResourceAmount(this, RESOURCE_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_ARMOR)), "armor");
1570                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1571                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1572         }
1573         this.netname = strzone(this.netname);
1574         //print(this.netname, "\n");
1575
1576         n = tokenize_console(this.netname);
1577         for(int j = 0; j < n; ++j)
1578         {
1579                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1580             it.wr_init(it);
1581             break;
1582                 });
1583         }
1584 }
1585
1586 float GiveWeapon(entity e, float wpn, float op, float val)
1587 {
1588         WepSet v0, v1;
1589         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1590         v0 = (STAT(WEAPONS, e) & s);
1591         switch(op)
1592         {
1593                 case OP_SET:
1594                         if(val > 0)
1595                                 STAT(WEAPONS, e) |= s;
1596                         else
1597                                 STAT(WEAPONS, e) &= ~s;
1598                         break;
1599                 case OP_MIN:
1600                 case OP_PLUS:
1601                         if(val > 0)
1602                                 STAT(WEAPONS, e) |= s;
1603                         break;
1604                 case OP_MAX:
1605                         if(val <= 0)
1606                                 STAT(WEAPONS, e) &= ~s;
1607                         break;
1608                 case OP_MINUS:
1609                         if(val > 0)
1610                                 STAT(WEAPONS, e) &= ~s;
1611                         break;
1612         }
1613         v1 = (STAT(WEAPONS, e) & s);
1614         return (v0 != v1);
1615 }
1616
1617 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1618 {
1619         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1620         switch(op)
1621         {
1622                 case OP_SET:
1623                         if(val > 0)
1624                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1625                         else
1626                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1627                         break;
1628                 case OP_MIN:
1629                 case OP_PLUS:
1630                         if(val > 0)
1631                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1632                         break;
1633                 case OP_MAX:
1634                         if(val <= 0)
1635                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1636                         break;
1637                 case OP_MINUS:
1638                         if(val > 0)
1639                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1640                         break;
1641         }
1642         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1643         return (had_buff != have_buff);
1644 }
1645
1646 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1647 {
1648         if(v1 == v0)
1649                 return;
1650         if(v1 <= v0 - t)
1651         {
1652                 if(snd_decr != NULL)
1653                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1654         }
1655         else if(v0 >= v0 + t)
1656         {
1657                 if(snd_incr != NULL)
1658                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1659         }
1660 }
1661
1662 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1663 {
1664         if(v0 < v1)
1665                 e.(rotfield) = max(e.(rotfield), time + rottime);
1666         else if(v0 > v1)
1667                 e.(regenfield) = max(e.(regenfield), time + regentime);
1668 }
1669 bool GiveResourceValue(entity e, int resource_type, int op, int val)
1670 {
1671         int v0 = GetResourceAmount(e, resource_type);
1672         switch (op)
1673         {
1674                 case OP_SET:
1675                         SetResourceAmount(e, resource_type, val);
1676                         break;
1677                 case OP_MIN:
1678                         SetResourceAmount(e, resource_type, max(v0, val)); // min 100 cells = at least 100 cells
1679                         break;
1680                 case OP_MAX:
1681                         SetResourceAmount(e, resource_type, min(v0, val));
1682                         break;
1683                 case OP_PLUS:
1684                         SetResourceAmount(e, resource_type, v0 + val);
1685                         break;
1686                 case OP_MINUS:
1687                         SetResourceAmount(e, resource_type, v0 - val);
1688                         break;
1689         }
1690         int v1 = GetResourceAmount(e, resource_type);
1691         return v0 != v1;
1692 }
1693
1694 float GiveItems(entity e, float beginarg, float endarg)
1695 {
1696         float got, i, val, op;
1697         string cmd;
1698
1699         val = 999;
1700         op = OP_SET;
1701
1702         got = 0;
1703
1704         int _switchweapon = 0;
1705
1706         if(CS(e).autoswitch)
1707         {
1708                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1709                 {
1710                         .entity weaponentity = weaponentities[slot];
1711                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1712                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1713                                 _switchweapon |= BIT(slot);
1714                 }
1715         }
1716
1717         e.strength_finished = max(0, e.strength_finished - time);
1718         e.invincible_finished = max(0, e.invincible_finished - time);
1719         e.superweapons_finished = max(0, e.superweapons_finished - time);
1720
1721         PREGIVE(e, items);
1722         PREGIVE_WEAPONS(e);
1723         PREGIVE(e, strength_finished);
1724         PREGIVE(e, invincible_finished);
1725         PREGIVE(e, superweapons_finished);
1726         PREGIVE_RESOURCE(e, RESOURCE_BULLETS);
1727         PREGIVE_RESOURCE(e, RESOURCE_CELLS);
1728         PREGIVE_RESOURCE(e, RESOURCE_PLASMA);
1729         PREGIVE_RESOURCE(e, RESOURCE_SHELLS);
1730         PREGIVE_RESOURCE(e, RESOURCE_ROCKETS);
1731         PREGIVE_RESOURCE(e, RESOURCE_FUEL);
1732         PREGIVE_RESOURCE(e, RESOURCE_ARMOR);
1733         PREGIVE_RESOURCE(e, RESOURCE_HEALTH);
1734
1735         for(i = beginarg; i < endarg; ++i)
1736         {
1737                 cmd = argv(i);
1738
1739                 if(cmd == "0" || stof(cmd))
1740                 {
1741                         val = stof(cmd);
1742                         continue;
1743                 }
1744                 switch(cmd)
1745                 {
1746                         case "no":
1747                                 op = OP_MAX;
1748                                 val = 0;
1749                                 continue;
1750                         case "max":
1751                                 op = OP_MAX;
1752                                 continue;
1753                         case "min":
1754                                 op = OP_MIN;
1755                                 continue;
1756                         case "plus":
1757                                 op = OP_PLUS;
1758                                 continue;
1759                         case "minus":
1760                                 op = OP_MINUS;
1761                                 continue;
1762                         case "ALL":
1763                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1764                                 got += GiveValue(e, strength_finished, op, val);
1765                                 got += GiveValue(e, invincible_finished, op, val);
1766                                 got += GiveValue(e, superweapons_finished, op, val);
1767                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1768                         case "all":
1769                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1770                                 got += GiveResourceValue(e, RESOURCE_HEALTH, op, val);
1771                                 got += GiveResourceValue(e, RESOURCE_ARMOR, op, val);
1772                         case "allweapons":
1773                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1774                         //case "allbuffs": // all buffs makes a player god, do not want!
1775                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1776                         case "allammo":
1777                                 got += GiveResourceValue(e, RESOURCE_CELLS, op, val);
1778                                 got += GiveResourceValue(e, RESOURCE_PLASMA, op, val);
1779                                 got += GiveResourceValue(e, RESOURCE_SHELLS, op, val);
1780                                 got += GiveResourceValue(e, RESOURCE_BULLETS, op, val);
1781                                 got += GiveResourceValue(e, RESOURCE_ROCKETS, op, val);
1782                                 got += GiveResourceValue(e, RESOURCE_FUEL, op, val);
1783                                 break;
1784                         case "unlimited_ammo":
1785                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1786                                 break;
1787                         case "unlimited_weapon_ammo":
1788                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1789                                 break;
1790                         case "unlimited_superweapons":
1791                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1792                                 break;
1793                         case "jetpack":
1794                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1795                                 break;
1796                         case "fuel_regen":
1797                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1798                                 break;
1799                         case "strength":
1800                                 got += GiveValue(e, strength_finished, op, val);
1801                                 break;
1802                         case "invincible":
1803                                 got += GiveValue(e, invincible_finished, op, val);
1804                                 break;
1805                         case "superweapons":
1806                                 got += GiveValue(e, superweapons_finished, op, val);
1807                                 break;
1808                         case "cells":
1809                                 got += GiveResourceValue(e, RESOURCE_CELLS, op, val);
1810                                 break;
1811                         case "plasma":
1812                                 got += GiveResourceValue(e, RESOURCE_PLASMA, op, val);
1813                                 break;
1814                         case "shells":
1815                                 got += GiveResourceValue(e, RESOURCE_SHELLS, op, val);
1816                                 break;
1817                         case "nails":
1818                         case "bullets":
1819                                 got += GiveResourceValue(e, RESOURCE_BULLETS, op, val);
1820                                 break;
1821                         case "rockets":
1822                                 got += GiveResourceValue(e, RESOURCE_ROCKETS, op, val);
1823                                 break;
1824                         case "health":
1825                                 got += GiveResourceValue(e, RESOURCE_HEALTH, op, val);
1826                                 break;
1827                         case "armor":
1828                                 got += GiveResourceValue(e, RESOURCE_ARMOR, op, val);
1829                                 break;
1830                         case "fuel":
1831                                 got += GiveResourceValue(e, RESOURCE_FUEL, op, val);
1832                                 break;
1833                         default:
1834                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1835                                 {
1836                                         got += GiveBuff(e, it, op, val);
1837                                         break;
1838                                 });
1839                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1840                     got += GiveWeapon(e, it.m_id, op, val);
1841                     break;
1842                                 });
1843                                 break;
1844                 }
1845                 val = 999;
1846                 op = OP_SET;
1847         }
1848
1849         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1850         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1851         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1852         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1853         FOREACH(Weapons, it != WEP_Null, {
1854                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1855                 if(!(save_weapons & (it.m_wepset)))
1856                         if(STAT(WEAPONS, e) & (it.m_wepset))
1857                                 it.wr_init(it);
1858         });
1859         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1860         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1861         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1862         POSTGIVE_RESOURCE(e, RESOURCE_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RESOURCE(e, RESOURCE_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1864         POSTGIVE_RESOURCE(e, RESOURCE_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1865         POSTGIVE_RESOURCE(e, RESOURCE_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1866         POSTGIVE_RESOURCE(e, RESOURCE_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1867         POSTGIVE_RESOURCE_ROT(e, RESOURCE_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1868         POSTGIVE_RESOURCE_ROT(e, RESOURCE_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1869         POSTGIVE_RESOURCE_ROT(e, RESOURCE_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1870
1871         if(e.superweapons_finished <= 0)
1872                 if(STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1873                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1874
1875         if(e.strength_finished <= 0)
1876                 e.strength_finished = 0;
1877         else
1878                 e.strength_finished += time;
1879         if(e.invincible_finished <= 0)
1880                 e.invincible_finished = 0;
1881         else
1882                 e.invincible_finished += time;
1883         if(e.superweapons_finished <= 0)
1884                 e.superweapons_finished = 0;
1885         else
1886                 e.superweapons_finished += time;
1887
1888         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1889         {
1890                 .entity weaponentity = weaponentities[slot];
1891                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1892                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1893                         _switchweapon |= BIT(slot);
1894         }
1895
1896         if(_switchweapon)
1897         {
1898                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1899                 {
1900                         .entity weaponentity = weaponentities[slot];
1901                         if(_switchweapon & BIT(slot))
1902                         {
1903                                 Weapon wep = w_getbestweapon(e, weaponentity);
1904                                 if(wep != e.(weaponentity).m_switchweapon)
1905                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1906                         }
1907                 }
1908         }
1909
1910         return got;
1911 }
1912 #endif