qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         strfree(this.mdl);
 152 }
 153
 154 HashMap ENT_CLIENT_ITEM_simple;
 155 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 156 {
 157         HM_NEW(ENT_CLIENT_ITEM_simple);
 158 }
 159 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 160 {
 161         HM_DELETE(ENT_CLIENT_ITEM_simple);
 162 }
 163
 164 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 165 {
 166     int sf = ReadByte();
 167
 168     if(sf & ISF_LOCATION)
 169     {
 170         this.origin = ReadVector();
 171         setorigin(this, this.origin);
 172         this.oldorigin = this.origin;
 173     }
 174
 175     if(sf & ISF_ANGLES)
 176     {
 177         this.angles_x = ReadAngle();
 178         this.angles_y = ReadAngle();
 179         this.angles_z = ReadAngle();
 180     }
 181
 182     if(sf & ISF_SIZE)
 183     {
 184         float use_bigsize = ReadByte();
 185         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 186     }
 187
 188     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 189     {
 190         this.ItemStatus = ReadByte();
 191
 192         Item_SetAlpha(this);
 193
 194         if(autocvar_cl_fullbright_items)
 195             if(this.ItemStatus & ITS_ALLOWFB)
 196                 this.effects |= EF_FULLBRIGHT;
 197
 198         if(this.ItemStatus & ITS_GLOW)
 199         {
 200             if(this.ItemStatus & ITS_AVAILABLE)
 201                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 202             else
 203                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 204         }
 205     }
 206
 207     if(sf & ISF_MODEL)
 208     {
 209         this.drawmask  = MASK_NORMAL;
 210                 set_movetype(this, MOVETYPE_TOSS);
 211                 if (isnew) IL_PUSH(g_drawables, this);
 212         this.draw       = ItemDraw;
 213         this.solid = SOLID_TRIGGER;
 214         //this.flags |= FL_ITEM;
 215
 216         bool use_bigsize = ReadByte();
 217
 218         this.fade_end = ReadShort();
 219         this.fade_start = ReadShort();
 220         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 221                 setpredraw(this, Item_PreDraw);
 222
 223                 strfree(this.mdl);
 224
 225         string _fn = ReadString();
 226         this.item_simple = false; // reset it!
 227
 228         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 229         {
 230             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 231             this.item_simple = true;
 232
 233                         #define extensions(x) \
 234                                 x(md3) \
 235                                 x(dpm) \
 236                                 x(iqm) \
 237                                 x(mdl) \
 238                                 /**/
 239                         #define tryext(ext) { \
 240                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 241                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 242                                 if (cached == "") { \
 243                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 244                                 } \
 245                                 if (cached != "0") { \
 246                                         strcpy(this.mdl, s); \
 247                                         break; \
 248                                 } \
 249                         }
 250                         do {
 251                                 extensions(tryext);
 252                                 this.item_simple = false;
 253                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 254                         } while (0);
 255                         #undef tryext
 256                         #undef extensions
 257         }
 258
 259         if(!this.item_simple)
 260             strcpy(this.mdl, _fn);
 261
 262         if(this.mdl == "")
 263             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 264
 265         precache_model(this.mdl);
 266         _setmodel(this, this.mdl);
 267
 268         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 269     }
 270
 271     if(sf & ISF_COLORMAP)
 272     {
 273         this.colormap = ReadShort();
 274         this.item_glowmod_x = ReadByte() / 255.0;
 275         this.item_glowmod_y = ReadByte() / 255.0;
 276         this.item_glowmod_z = ReadByte() / 255.0;
 277     }
 278
 279     if(sf & ISF_DROP)
 280     {
 281         this.gravity = 1;
 282         this.pushable = true;
 283         //this.angles = '0 0 0';
 284         set_movetype(this, MOVETYPE_TOSS);
 285         this.velocity = ReadVector();
 286         setorigin(this, this.oldorigin);
 287
 288         if(!this.move_time)
 289         {
 290             this.move_time = time;
 291             this.spawntime = time;
 292         }
 293         else
 294             this.move_time = max(this.move_time, time);
 295     }
 296
 297     if(autocvar_cl_animate_items)
 298     {
 299         if(this.ItemStatus & ITS_ANIMATE1)
 300             this.avelocity = '0 180 0';
 301
 302         if(this.ItemStatus & ITS_ANIMATE2)
 303             this.avelocity = '0 -90 0';
 304     }
 305
 306     this.entremove = ItemRemove;
 307
 308     return true;
 309 }
 310
 311 #endif
 312
 313 #ifdef SVQC
 314 bool ItemSend(entity this, entity to, int sf)
 315 {
 316         if(this.gravity)
 317                 sf |= ISF_DROP;
 318         else
 319                 sf &= ~ISF_DROP;
 320
 321         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 322         WriteByte(MSG_ENTITY, sf);
 323
 324         //WriteByte(MSG_ENTITY, this.cnt);
 325         if(sf & ISF_LOCATION)
 326         {
 327                 WriteVector(MSG_ENTITY, this.origin);
 328         }
 329
 330         if(sf & ISF_ANGLES)
 331         {
 332                 WriteAngle(MSG_ENTITY, this.angles_x);
 333                 WriteAngle(MSG_ENTITY, this.angles_y);
 334                 WriteAngle(MSG_ENTITY, this.angles_z);
 335         }
 336
 337         if(sf & ISF_SIZE)
 338         {
 339                 Pickup p = this.itemdef;
 340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 341         }
 342
 343         if(sf & ISF_STATUS)
 344                 WriteByte(MSG_ENTITY, this.ItemStatus);
 345
 346         if(sf & ISF_MODEL)
 347         {
 348                 Pickup p = this.itemdef;
 349                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 350                 WriteShort(MSG_ENTITY, this.fade_end);
 351                 WriteShort(MSG_ENTITY, this.fade_start);
 352
 353                 if(this.mdl == "")
 354                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 355
 356                 WriteString(MSG_ENTITY, this.mdl);
 357         }
 358
 359
 360         if(sf & ISF_COLORMAP)
 361         {
 362                 WriteShort(MSG_ENTITY, this.colormap);
 363                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 364         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 365         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 366         }
 367
 368         if(sf & ISF_DROP)
 369         {
 370                 WriteVector(MSG_ENTITY, this.velocity);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.item_respawncounter += 1;
 546                 if(this.item_respawncounter == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.item_respawncounter = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 /// Adjust respawn time according to the number of players.
 639 float adjust_respawntime(float normal_respawntime) {
 640         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 641         float o = autocvar_g_pickup_respawntime_scaling_offset;
 642         float l = autocvar_g_pickup_respawntime_scaling_linear;
 643
 644         if (r == 0 && l == 1) {
 645                 return normal_respawntime;
 646         }
 647
 648         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 649         TeamBalance_GetTeamCounts(balance, NULL);
 650         int players = 0;
 651         for (int i = 1; i <= NUM_TEAMS; ++i)
 652         {
 653                 if (TeamBalance_IsTeamAllowed(balance, i))
 654                 {
 655                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 656                 }
 657         }
 658         TeamBalance_Destroy(balance);
 659
 660         if (players >= 2) {
 661                 return normal_respawntime * (r / (players + o) + l);
 662         } else {
 663                 return normal_respawntime;
 664         }
 665 }
 666
 667 void Item_ScheduleRespawn(entity e)
 668 {
 669         if(e.respawntime > 0)
 670         {
 671                 Item_Show(e, 0);
 672
 673                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 674                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 675
 676                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 677                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 678                 Item_ScheduleRespawnIn(e, respawn_in);
 679         }
 680         else // if respawntime is -1, this item does not respawn
 681                 Item_Show(e, -1);
 682 }
 683
 684 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 685         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 686
 687 void Item_ScheduleInitialRespawn(entity e)
 688 {
 689         Item_Show(e, 0);
 690
 691         float spawn_in;
 692         if (autocvar_g_pickup_respawntime_initial_random == 0)
 693         {
 694                 // range: respawntime .. respawntime + respawntimejitter
 695                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 696         }
 697         else
 698         {
 699                 float rnd;
 700                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 701                 {
 702                         static float shared_random = 0;
 703                         // NOTE this code works only if items are scheduled at the same time (normal case)
 704                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 705                         if (!shared_random || floor(time) > shared_random)
 706                                 shared_random = floor(time) + random();
 707                         rnd = shared_random - floor(time);
 708                 }
 709                 else
 710                         rnd = random();
 711
 712                 // range:
 713                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 714                 // else: 0 .. ITEM_RESPAWN_TICKS
 715                 // this is to prevent powerups spawning unexpectedly without waypoints
 716                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 717         }
 718
 719         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 720 }
 721
 722 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 723         entity ammo_entity)
 724 {
 725         if (num_weapons == 0)
 726         {
 727                 return;
 728         }
 729         int num_potential_weapons = tokenize_console(weapon_names);
 730         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 731         {
 732                 RandomSelection_Init();
 733                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 734                         ++weapon_index)
 735                 {
 736                         string weapon = argv(weapon_index);
 737                         FOREACH(Weapons, it != WEP_Null,
 738                         {
 739                                 // Finding a weapon which player doesn't have.
 740                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 741                                 {
 742                                         RandomSelection_AddEnt(it, 1, 1);
 743                                         break;
 744                                 }
 745                         });
 746                 }
 747                 if (RandomSelection_chosen_ent == NULL)
 748                 {
 749                         return;
 750                 }
 751                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 752                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 753                 {
 754                         continue;
 755                 }
 756                 if (GetResourceAmount(receiver,
 757                         RandomSelection_chosen_ent.ammo_type) != 0)
 758                 {
 759                         continue;
 760                 }
 761                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 762                         GetResourceAmount(ammo_entity,
 763                         RandomSelection_chosen_ent.ammo_type));
 764         }
 765 }
 766
 767 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 768 {
 769         float amount = GetResourceAmount(item, resource_type);
 770         if (amount == 0)
 771         {
 772                 return false;
 773         }
 774         float player_amount = GetResourceAmount(player, resource_type);
 775         if (item.spawnshieldtime)
 776         {
 777                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 778                 {
 779                         return false;
 780                 }
 781                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 782                 return true;
 783         }
 784         if (g_weapon_stay != 2)
 785         {
 786                 return false;
 787         }
 788         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 789         return true;
 790 }
 791
 792 float Item_GiveTo(entity item, entity player)
 793 {
 794         float pickedup;
 795
 796         // if nothing happens to player, just return without taking the item
 797         pickedup = false;
 798         int _switchweapon = 0;
 799         // in case the player has autoswitch enabled do the following:
 800         // if the player is using their best weapon before items are given, they
 801         // probably want to switch to an even better weapon after items are given
 802
 803         if(CS(player).autoswitch)
 804         {
 805                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 806                 {
 807                         .entity weaponentity = weaponentities[slot];
 808                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 809                         {
 810                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 811                                         _switchweapon |= BIT(slot);
 812
 813                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 814                                         _switchweapon |= BIT(slot);
 815                         }
 816                 }
 817         }
 818         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 819         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 820         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 821         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 822         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 823         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 824         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 825         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 826         if (item.itemdef.instanceOfWeaponPickup)
 827         {
 828                 WepSet w;
 829                 w = item.weapons;
 830                 w &= ~player.weapons;
 831
 832                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 833                 {
 834                         pickedup = true;
 835                         FOREACH(Weapons, it != WEP_Null, {
 836                                 if(w & (it.m_wepset))
 837                                 {
 838                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 839                                         {
 840                                                 .entity weaponentity = weaponentities[slot];
 841                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 842                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 843                                         }
 844                                         W_GiveWeapon(player, it.m_id);
 845                                 }
 846                         });
 847                 }
 848         }
 849
 850         if (item.itemdef.instanceOfPowerup)
 851         {
 852                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 853                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 854                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 855                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 856         }
 857
 858         int its;
 859         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 860         {
 861                 pickedup = true;
 862                 player.items |= its;
 863                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 864         }
 865
 866         if (item.strength_finished)
 867         {
 868                 pickedup = true;
 869                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 870         }
 871         if (item.invincible_finished)
 872         {
 873                 pickedup = true;
 874                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 875         }
 876         if (item.superweapons_finished)
 877         {
 878                 pickedup = true;
 879                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 880         }
 881
 882         // always eat teamed entities
 883         if(item.team)
 884                 pickedup = true;
 885
 886         if (!pickedup)
 887                 return 0;
 888
 889         // crude hack to enforce switching weapons
 890         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 891         {
 892                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 893                 {
 894                         .entity weaponentity = weaponentities[slot];
 895                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 896                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 897                 }
 898                 return 1;
 899         }
 900
 901         if(_switchweapon)
 902         {
 903                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 904                 {
 905                         .entity weaponentity = weaponentities[slot];
 906                         if(_switchweapon & BIT(slot))
 907                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 908                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 909                 }
 910         }
 911
 912         return 1;
 913 }
 914
 915 void Item_Touch(entity this, entity toucher)
 916 {
 917         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 918         if (Item_IsLoot(this))
 919         {
 920                 if (ITEM_TOUCH_NEEDKILL())
 921                 {
 922                         delete(this);
 923                         return;
 924                 }
 925         }
 926
 927         if(!(toucher.flags & FL_PICKUPITEMS)
 928         || STAT(FROZEN, toucher)
 929         || IS_DEAD(toucher)
 930         || (this.solid != SOLID_TRIGGER)
 931         || (this.owner == toucher)
 932         || (time < this.item_spawnshieldtime)
 933         ) { return; }
 934
 935         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 936         {
 937                 case MUT_ITEMTOUCH_RETURN: { return; }
 938                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 939         }
 940
 941         toucher = M_ARGV(1, entity);
 942
 943         if (Item_IsExpiring(this))
 944         {
 945                 this.strength_finished = max(0, this.strength_finished - time);
 946                 this.invincible_finished = max(0, this.invincible_finished - time);
 947                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 948         }
 949         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 950         if (!gave)
 951         {
 952                 if (Item_IsExpiring(this))
 953                 {
 954                         // undo what we did above
 955                         this.strength_finished += time;
 956                         this.invincible_finished += time;
 957                         this.superweapons_finished += time;
 958                 }
 959                 return;
 960         }
 961
 962 LABEL(pickup)
 963
 964         STAT(LAST_PICKUP, toucher) = time;
 965
 966         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 967         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 968
 969         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 970         if (wasfreed(this))
 971         {
 972                 return;
 973         }
 974
 975         if (Item_IsLoot(this))
 976         {
 977                 delete(this);
 978                 return;
 979         }
 980         if (!this.spawnshieldtime)
 981         {
 982                 return;
 983         }
 984         entity e;
 985         if (this.team)
 986         {
 987                 RandomSelection_Init();
 988                 IL_EACH(g_items, it.team == this.team,
 989                 {
 990                         if (it.itemdef) // is a registered item
 991                         {
 992                                 Item_Show(it, -1);
 993                                 it.scheduledrespawntime = 0;
 994                                 RandomSelection_AddEnt(it, it.cnt, 0);
 995                         }
 996                 });
 997                 e = RandomSelection_chosen_ent;
 998                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 999         }
1000         else
1001                 e = this;
1002         Item_ScheduleRespawn(e);
1003 }
1004
1005 void Item_Reset(entity this)
1006 {
1007         Item_Show(this, !this.state);
1008         setorigin(this, this.origin);
1009
1010         if (Item_IsLoot(this))
1011         {
1012                 return;
1013         }
1014         setthink(this, Item_Think);
1015         this.nextthink = time;
1016         if (this.waypointsprite_attached)
1017         {
1018                 WaypointSprite_Kill(this.waypointsprite_attached);
1019         }
1020         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1021         {
1022                 Item_ScheduleInitialRespawn(this);
1023         }
1024 }
1025
1026 void Item_FindTeam(entity this)
1027 {
1028         entity e;
1029
1030         if(this.effects & EF_NODRAW)
1031         {
1032                 // marker for item team search
1033                 LOG_TRACE("Initializing item team ", ftos(this.team));
1034                 RandomSelection_Init();
1035                 IL_EACH(g_items, it.team == this.team,
1036                 {
1037                         if(it.itemdef) // is a registered item
1038                                 RandomSelection_AddEnt(it, it.cnt, 0);
1039                 });
1040
1041                 e = RandomSelection_chosen_ent;
1042                 e.state = 0;
1043                 Item_Show(e, 1);
1044
1045                 IL_EACH(g_items, it.team == this.team,
1046                 {
1047                         if(it.itemdef) // is a registered item
1048                         {
1049                                 if(it != e)
1050                                 {
1051                                         // make it non-spawned
1052                                         Item_Show(it, -1);
1053                                         it.state = 1; // state 1 = initially hidden item, apparently
1054                                 }
1055                                 it.effects &= ~EF_NODRAW;
1056                         }
1057                 });
1058
1059                 Item_Reset(this);
1060         }
1061 }
1062
1063 // Savage: used for item garbage-collection
1064 void RemoveItem(entity this)
1065 {
1066         if(wasfreed(this) || !this) { return; }
1067         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1068         delete(this);
1069 }
1070
1071 // pickup evaluation functions
1072 // these functions decide how desirable an item is to the bots
1073
1074 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1075
1076 float weapon_pickupevalfunc(entity player, entity item)
1077 {
1078         // See if I have it already
1079         if(player.weapons & item.weapons)
1080         {
1081                 // If I can pick it up
1082                 if(!item.spawnshieldtime)
1083                         return 0;
1084                 return ammo_pickupevalfunc(player, item);
1085         }
1086
1087         // reduce weapon value if bot already got a good arsenal
1088         float c = 1;
1089         int weapons_value = 0;
1090         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1091                 weapons_value += it.bot_pickupbasevalue;
1092         });
1093         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1094
1095         return item.bot_pickupbasevalue * c;
1096 }
1097
1098 float ammo_pickupevalfunc(entity player, entity item)
1099 {
1100         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1101         entity wpn = NULL;
1102         float c = 0;
1103         float rating = 0;
1104
1105         // Detect needed ammo
1106         if(item.itemdef.instanceOfWeaponPickup)
1107         {
1108                 entity ammo = NULL;
1109                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1110                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1111                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1112                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1113                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1114                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1115
1116                 if(!ammo)
1117                         return 0;
1118                 wpn = item;
1119                 rating = ammo.m_botvalue;
1120         }
1121         else
1122         {
1123                 FOREACH(Weapons, it != WEP_Null, {
1124                         if(!(player.weapons & (it.m_wepset)))
1125                                 continue;
1126
1127                         switch(it.ammo_type)
1128                         {
1129                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1130                                 case RESOURCE_BULLETS: need_nails   = true; break;
1131                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1132                                 case RESOURCE_CELLS:   need_cells   = true; break;
1133                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1134                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1135                         }
1136                 });
1137                 rating = item.bot_pickupbasevalue;
1138         }
1139
1140         float noammorating = 0.5;
1141
1142         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1143                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1144
1145         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1146                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1147
1148         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1149                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1150
1151         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1152                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1153
1154         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1155                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1156
1157         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1158                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1159
1160         rating *= min(c, 2);
1161         if(wpn)
1162                 rating += wpn.bot_pickupbasevalue * 0.1;
1163         return rating;
1164 }
1165
1166 float healtharmor_pickupevalfunc(entity player, entity item)
1167 {
1168         float c = 0;
1169         float rating = item.bot_pickupbasevalue;
1170
1171         float itemarmor = item.armorvalue;
1172         float itemhealth = item.health;
1173
1174         if(item.item_group)
1175         {
1176                 itemarmor *= min(4, item.item_group_count);
1177                 itemhealth *= min(4, item.item_group_count);
1178         }
1179
1180         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1181                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1182
1183         if (itemhealth && (player.health < item.max_health))
1184                 c = itemhealth / max(1, player.health);
1185
1186         rating *= min(2, c);
1187         return rating;
1188 }
1189
1190 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1191 {
1192         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1193                 RemoveItem(this);
1194 }
1195
1196 void item_use(entity this, entity actor, entity trigger)
1197 {
1198         // use the touch function to handle collection
1199         gettouch(this)(this, actor);
1200 }
1201
1202 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1203 {
1204         string itemname = def.m_name;
1205         Model itemmodel = def.m_model;
1206     Sound pickupsound = def.m_sound;
1207         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1208         float pickupbasevalue = def.m_botvalue;
1209         int itemflags = def.m_itemflags;
1210
1211         startitem_failed = false;
1212
1213         this.item_model_ent = itemmodel;
1214     this.item_pickupsound_ent = pickupsound;
1215
1216     if(def.m_iteminit)
1217         def.m_iteminit(this);
1218
1219         if(!this.respawntime) // both need to be set
1220         {
1221                 this.respawntime = defaultrespawntime;
1222                 this.respawntimejitter = defaultrespawntimejitter;
1223         }
1224
1225         if(!this.pickup_anyway && def.m_pickupanyway)
1226                 this.pickup_anyway = def.m_pickupanyway();
1227
1228         int itemid = def.m_itemid;
1229         this.items = itemid;
1230         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1231         this.weapon = weaponid;
1232
1233         if(!this.fade_end)
1234         {
1235                 this.fade_start = autocvar_g_items_mindist;
1236                 this.fade_end = autocvar_g_items_maxdist;
1237         }
1238
1239         if(weaponid)
1240                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1241
1242         this.flags = FL_ITEM | itemflags;
1243         IL_PUSH(g_items, this);
1244
1245         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1246         {
1247                 startitem_failed = true;
1248                 delete(this);
1249                 return;
1250         }
1251
1252         if (Item_IsLoot(this))
1253         {
1254                 this.reset = SUB_Remove;
1255                 set_movetype(this, MOVETYPE_TOSS);
1256
1257                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1258                 setthink(this, RemoveItem);
1259                 this.nextthink = time + 20;
1260
1261                 this.takedamage = DAMAGE_YES;
1262                 this.event_damage = Item_Damage;
1263
1264                 if (Item_IsExpiring(this))
1265                 {
1266                         // if item is worthless after a timer, have it expire then
1267                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1268                 }
1269
1270                 // don't drop if in a NODROP zone (such as lava)
1271                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1272                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1273                 {
1274                         startitem_failed = true;
1275                         delete(this);
1276                         return;
1277                 }
1278         }
1279         else
1280         {
1281                 if(!have_pickup_item(this))
1282                 {
1283                         startitem_failed = true;
1284                         delete(this);
1285                         return;
1286                 }
1287
1288                 if(this.angles != '0 0 0')
1289                         this.SendFlags |= ISF_ANGLES;
1290
1291                 this.reset = Item_Reset;
1292                 // it's a level item
1293                 if(this.spawnflags & 1)
1294                         this.noalign = 1;
1295                 if (this.noalign > 0)
1296                         set_movetype(this, MOVETYPE_NONE);
1297                 else
1298                         set_movetype(this, MOVETYPE_TOSS);
1299                 // do item filtering according to game mode and other things
1300                 if (this.noalign <= 0)
1301                 {
1302                         // first nudge it off the floor a little bit to avoid math errors
1303                         setorigin(this, this.origin + '0 0 1');
1304                         // set item size before we spawn a spawnfunc_waypoint
1305                         setsize(this, def.m_mins, def.m_maxs);
1306                         this.SendFlags |= ISF_SIZE;
1307                         // note droptofloor returns false if stuck/or would fall too far
1308                         if (!this.noalign)
1309                                 droptofloor(this);
1310                         waypoint_spawnforitem(this);
1311                 }
1312
1313                 /*
1314                  * can't do it that way, as it would break maps
1315                  * TODO make a target_give like entity another way, that perhaps has
1316                  * the weapon name in a key
1317                 if(this.targetname)
1318                 {
1319                         // target_give not yet supported; maybe later
1320                         print("removed targeted ", this.classname, "\n");
1321                         startitem_failed = true;
1322                         delete(this);
1323                         return;
1324                 }
1325                 */
1326
1327                 if(this.targetname != "" && (this.spawnflags & 16))
1328                         this.use = item_use;
1329
1330                 if(autocvar_spawn_debug >= 2)
1331                 {
1332             // why not flags & fl_item?
1333                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1334                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1335                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1336                 error("Mapper sucks.");
1337             });
1338                         this.is_item = true;
1339                 }
1340
1341                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1342
1343                 precache_model(this.model);
1344                 precache_sound(this.item_pickupsound);
1345
1346                 if (   def.instanceOfPowerup
1347                         || def.instanceOfWeaponPickup
1348                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1349                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1350                         || (itemid & (IT_KEY1 | IT_KEY2))
1351                 ) this.target = "###item###"; // for finding the nearest item using find()
1352
1353                 Item_ItemsTime_SetTime(this, 0);
1354         }
1355
1356         this.bot_pickup = true;
1357         this.bot_pickupevalfunc = pickupevalfunc;
1358         this.bot_pickupbasevalue = pickupbasevalue;
1359         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1360         this.netname = itemname;
1361         settouch(this, Item_Touch);
1362         setmodel(this, MDL_Null); // precision set below
1363         //this.effects |= EF_LOWPRECISION;
1364
1365         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1366
1367         this.SendFlags |= ISF_SIZE;
1368
1369         if (!(this.spawnflags & 1024)) {
1370                 if(def.instanceOfPowerup)
1371                         this.ItemStatus |= ITS_ANIMATE1;
1372
1373                 if(this.armorvalue || this.health)
1374                         this.ItemStatus |= ITS_ANIMATE2;
1375         }
1376
1377         if(def.instanceOfWeaponPickup)
1378         {
1379                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1380                         this.colormap = 1024; // color shirt=0 pants=0 grey
1381                 else
1382                         this.gravity = 1;
1383                 if (!(this.spawnflags & 1024))
1384                         this.ItemStatus |= ITS_ANIMATE1;
1385                 this.SendFlags |= ISF_COLORMAP;
1386         }
1387
1388         this.state = 0;
1389         if(this.team) // broken, no idea why.
1390         {
1391                 if(!this.cnt)
1392                         this.cnt = 1; // item probability weight
1393
1394                 this.effects |= EF_NODRAW; // marker for item team search
1395                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1396         }
1397         else
1398                 Item_Reset(this);
1399
1400         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1401
1402         // call this hook after everything else has been done
1403         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1404         {
1405                 startitem_failed = true;
1406                 delete(this);
1407                 return;
1408         }
1409
1410         setItemGroup(this);
1411 }
1412
1413 void StartItem(entity this, GameItem def)
1414 {
1415     def = def.m_spawnfunc_hookreplace(def, this);
1416     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1417     {
1418         delete(this);
1419         return;
1420     }
1421     this.classname = def.m_canonical_spawnfunc;
1422     _StartItem(
1423         this,
1424         this.itemdef = def,
1425         def.m_respawntime(), // defaultrespawntime
1426         def.m_respawntimejitter() // defaultrespawntimejitter
1427         );
1428 }
1429
1430 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1431 int group_count = 1;
1432
1433 void setItemGroup(entity this)
1434 {
1435         if(!IS_SMALL(this.itemdef))
1436                 return;
1437
1438         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1439         {
1440                 if(!this.item_group)
1441                 {
1442                         if(!it.item_group)
1443                         {
1444                                 it.item_group = group_count;
1445                                 group_count++;
1446                         }
1447                         this.item_group = it.item_group;
1448                 }
1449                 else // spawning item is already part of a item_group X
1450                 {
1451                         if(!it.item_group)
1452                                 it.item_group = this.item_group;
1453                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1454                         {
1455                                 int grY = it.item_group;
1456                                 // move all items of item_group Y to item_group X
1457                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1458                                 {
1459                                         if(it.item_group == grY)
1460                                                 it.item_group = this.item_group;
1461                                 });
1462                         }
1463                 }
1464         });
1465 }
1466
1467 void setItemGroupCount()
1468 {
1469         for (int k = 1; k <= group_count; k++)
1470         {
1471                 int count = 0;
1472                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1473                 if (count)
1474                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1475         }
1476 }
1477
1478 void target_items_use(entity this, entity actor, entity trigger)
1479 {
1480         if(Item_IsLoot(actor))
1481         {
1482                 EXACTTRIGGER_TOUCH(this, trigger);
1483                 delete(actor);
1484                 return;
1485         }
1486
1487         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1488                 return;
1489
1490         if(trigger.solid == SOLID_TRIGGER)
1491         {
1492                 EXACTTRIGGER_TOUCH(this, trigger);
1493         }
1494
1495         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1496         {
1497                 delete(it);
1498         });
1499
1500         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1501                 centerprint(actor, this.message);
1502 }
1503
1504 spawnfunc(target_items)
1505 {
1506         int n;
1507         string s;
1508
1509         this.use = target_items_use;
1510         if(!this.strength_finished)
1511                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1512         if(!this.invincible_finished)
1513                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1514         if(!this.superweapons_finished)
1515                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1516
1517         n = tokenize_console(this.netname);
1518         if(argv(0) == "give")
1519         {
1520                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1521         }
1522         else
1523         {
1524                 for(int j = 0; j < n; ++j)
1525                 {
1526                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1527                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1528                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1529                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1530                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1531                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1532                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1533                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1534                         else
1535                         {
1536                                 FOREACH(Buffs, it != BUFF_Null,
1537                                 {
1538                                         s = Buff_UndeprecateName(argv(j));
1539                                         if(s == it.m_name)
1540                                         {
1541                                                 STAT(BUFFS, this) |= (it.m_itemid);
1542                                                 break;
1543                                         }
1544                                 });
1545                                 FOREACH(Weapons, it != WEP_Null, {
1546                                         s = W_UndeprecateName(argv(j));
1547                                         if(s == it.netname)
1548                                         {
1549                                                 this.weapons |= (it.m_wepset);
1550                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1551                                                         it.wr_init(it);
1552                                                 break;
1553                                         }
1554                                 });
1555                         }
1556                 }
1557
1558                 string itemprefix, valueprefix;
1559                 if(this.spawnflags == 0)
1560                 {
1561                         itemprefix = "";
1562                         valueprefix = "";
1563                 }
1564                 else if(this.spawnflags == 1)
1565                 {
1566                         itemprefix = "max ";
1567                         valueprefix = "max ";
1568                 }
1569                 else if(this.spawnflags == 2)
1570                 {
1571                         itemprefix = "min ";
1572                         valueprefix = "min ";
1573                 }
1574                 else if(this.spawnflags == 4)
1575                 {
1576                         itemprefix = "minus ";
1577                         valueprefix = "max ";
1578                 }
1579                 else
1580                 {
1581                         error("invalid spawnflags");
1582                         itemprefix = valueprefix = string_null;
1583                 }
1584
1585                 this.netname = "";
1586                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1587                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1588                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1589                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1590                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1591                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1592                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1593                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1594                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1595                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1596                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1597                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1598                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1599                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1600                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1601                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1602                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1603         }
1604         this.netname = strzone(this.netname);
1605         //print(this.netname, "\n");
1606
1607         n = tokenize_console(this.netname);
1608         for(int j = 0; j < n; ++j)
1609         {
1610                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1611             it.wr_init(it);
1612             break;
1613                 });
1614         }
1615 }
1616
1617 float GiveWeapon(entity e, float wpn, float op, float val)
1618 {
1619         WepSet v0, v1;
1620         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1621         v0 = (e.weapons & s);
1622         switch(op)
1623         {
1624                 case OP_SET:
1625                         if(val > 0)
1626                                 e.weapons |= s;
1627                         else
1628                                 e.weapons &= ~s;
1629                         break;
1630                 case OP_MIN:
1631                 case OP_PLUS:
1632                         if(val > 0)
1633                                 e.weapons |= s;
1634                         break;
1635                 case OP_MAX:
1636                         if(val <= 0)
1637                                 e.weapons &= ~s;
1638                         break;
1639                 case OP_MINUS:
1640                         if(val > 0)
1641                                 e.weapons &= ~s;
1642                         break;
1643         }
1644         v1 = (e.weapons & s);
1645         return (v0 != v1);
1646 }
1647
1648 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1649 {
1650         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1651         switch(op)
1652         {
1653                 case OP_SET:
1654                         if(val > 0)
1655                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1656                         else
1657                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1658                         break;
1659                 case OP_MIN:
1660                 case OP_PLUS:
1661                         if(val > 0)
1662                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1663                         break;
1664                 case OP_MAX:
1665                         if(val <= 0)
1666                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1667                         break;
1668                 case OP_MINUS:
1669                         if(val > 0)
1670                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1671                         break;
1672         }
1673         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1674         return (had_buff != have_buff);
1675 }
1676
1677 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1678 {
1679         if(v1 == v0)
1680                 return;
1681         if(v1 <= v0 - t)
1682         {
1683                 if(snd_decr != NULL)
1684                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1685         }
1686         else if(v0 >= v0 + t)
1687         {
1688                 if(snd_incr != NULL)
1689                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1690         }
1691 }
1692
1693 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1694 {
1695         if(v0 < v1)
1696                 e.(rotfield) = max(e.(rotfield), time + rottime);
1697         else if(v0 > v1)
1698                 e.(regenfield) = max(e.(regenfield), time + regentime);
1699 }
1700 float GiveItems(entity e, float beginarg, float endarg)
1701 {
1702         float got, i, val, op;
1703         string cmd;
1704
1705         val = 999;
1706         op = OP_SET;
1707
1708         got = 0;
1709
1710         int _switchweapon = 0;
1711
1712         if(CS(e).autoswitch)
1713         {
1714                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1715                 {
1716                         .entity weaponentity = weaponentities[slot];
1717                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1718                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1719                                 _switchweapon |= BIT(slot);
1720                 }
1721         }
1722
1723         e.strength_finished = max(0, e.strength_finished - time);
1724         e.invincible_finished = max(0, e.invincible_finished - time);
1725         e.superweapons_finished = max(0, e.superweapons_finished - time);
1726
1727         PREGIVE(e, items);
1728         PREGIVE_WEAPONS(e);
1729         PREGIVE(e, strength_finished);
1730         PREGIVE(e, invincible_finished);
1731         PREGIVE(e, superweapons_finished);
1732         PREGIVE(e, ammo_nails);
1733         PREGIVE(e, ammo_cells);
1734         PREGIVE(e, ammo_plasma);
1735         PREGIVE(e, ammo_shells);
1736         PREGIVE(e, ammo_rockets);
1737         PREGIVE(e, ammo_fuel);
1738         PREGIVE(e, armorvalue);
1739         PREGIVE(e, health);
1740
1741         for(i = beginarg; i < endarg; ++i)
1742         {
1743                 cmd = argv(i);
1744
1745                 if(cmd == "0" || stof(cmd))
1746                 {
1747                         val = stof(cmd);
1748                         continue;
1749                 }
1750                 switch(cmd)
1751                 {
1752                         case "no":
1753                                 op = OP_MAX;
1754                                 val = 0;
1755                                 continue;
1756                         case "max":
1757                                 op = OP_MAX;
1758                                 continue;
1759                         case "min":
1760                                 op = OP_MIN;
1761                                 continue;
1762                         case "plus":
1763                                 op = OP_PLUS;
1764                                 continue;
1765                         case "minus":
1766                                 op = OP_MINUS;
1767                                 continue;
1768                         case "ALL":
1769                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1770                                 got += GiveValue(e, strength_finished, op, val);
1771                                 got += GiveValue(e, invincible_finished, op, val);
1772                                 got += GiveValue(e, superweapons_finished, op, val);
1773                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1774                         case "all":
1775                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1776                                 got += GiveValue(e, health, op, val);
1777                                 got += GiveValue(e, armorvalue, op, val);
1778                         case "allweapons":
1779                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1780                         //case "allbuffs": // all buffs makes a player god, do not want!
1781                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1782                         case "allammo":
1783                                 got += GiveValue(e, ammo_cells, op, val);
1784                                 got += GiveValue(e, ammo_plasma, op, val);
1785                                 got += GiveValue(e, ammo_shells, op, val);
1786                                 got += GiveValue(e, ammo_nails, op, val);
1787                                 got += GiveValue(e, ammo_rockets, op, val);
1788                                 got += GiveValue(e, ammo_fuel, op, val);
1789                                 break;
1790                         case "unlimited_ammo":
1791                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1792                                 break;
1793                         case "unlimited_weapon_ammo":
1794                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1795                                 break;
1796                         case "unlimited_superweapons":
1797                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1798                                 break;
1799                         case "jetpack":
1800                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1801                                 break;
1802                         case "fuel_regen":
1803                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1804                                 break;
1805                         case "strength":
1806                                 got += GiveValue(e, strength_finished, op, val);
1807                                 break;
1808                         case "invincible":
1809                                 got += GiveValue(e, invincible_finished, op, val);
1810                                 break;
1811                         case "superweapons":
1812                                 got += GiveValue(e, superweapons_finished, op, val);
1813                                 break;
1814                         case "cells":
1815                                 got += GiveValue(e, ammo_cells, op, val);
1816                                 break;
1817                         case "plasma":
1818                                 got += GiveValue(e, ammo_plasma, op, val);
1819                                 break;
1820                         case "shells":
1821                                 got += GiveValue(e, ammo_shells, op, val);
1822                                 break;
1823                         case "nails":
1824                         case "bullets":
1825                                 got += GiveValue(e, ammo_nails, op, val);
1826                                 break;
1827                         case "rockets":
1828                                 got += GiveValue(e, ammo_rockets, op, val);
1829                                 break;
1830                         case "health":
1831                                 got += GiveValue(e, health, op, val);
1832                                 break;
1833                         case "armor":
1834                                 got += GiveValue(e, armorvalue, op, val);
1835                                 break;
1836                         case "fuel":
1837                                 got += GiveValue(e, ammo_fuel, op, val);
1838                                 break;
1839                         default:
1840                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1841                                 {
1842                                         got += GiveBuff(e, it, op, val);
1843                                         break;
1844                                 });
1845                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1846                     got += GiveWeapon(e, it.m_id, op, val);
1847                     break;
1848                                 });
1849                                 break;
1850                 }
1851                 val = 999;
1852                 op = OP_SET;
1853         }
1854
1855         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1856         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1857         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1858         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1859         FOREACH(Weapons, it != WEP_Null, {
1860                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1861                 if(!(save_weapons & (it.m_wepset)))
1862                         if(e.weapons & (it.m_wepset))
1863                                 it.wr_init(it);
1864         });
1865         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1866         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1867         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1868         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1869         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1870         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1871         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1872         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1873         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1874         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1875         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1876
1877         if(e.superweapons_finished <= 0)
1878                 if(e.weapons & WEPSET_SUPERWEAPONS)
1879                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1880
1881         if(e.strength_finished <= 0)
1882                 e.strength_finished = 0;
1883         else
1884                 e.strength_finished += time;
1885         if(e.invincible_finished <= 0)
1886                 e.invincible_finished = 0;
1887         else
1888                 e.invincible_finished += time;
1889         if(e.superweapons_finished <= 0)
1890                 e.superweapons_finished = 0;
1891         else
1892                 e.superweapons_finished += time;
1893
1894         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1895         {
1896                 .entity weaponentity = weaponentities[slot];
1897                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1898                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1899                         _switchweapon |= BIT(slot);
1900         }
1901
1902         if(_switchweapon)
1903         {
1904                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1905                 {
1906                         .entity weaponentity = weaponentities[slot];
1907                         if(_switchweapon & BIT(slot))
1908                         {
1909                                 Weapon wep = w_getbestweapon(e, weaponentity);
1910                                 if(wep != e.(weaponentity).m_switchweapon)
1911                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1912                         }
1913                 }
1914         }
1915
1916         return got;
1917 }
1918 #endif