qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 if(!this.item_simple)
  96                 this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103                 if(!this.item_simple)
 104                 this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void Item_PreDraw(entity this)
 114 {
 115         if(warpzone_warpzones_exist)
 116         {
 117                 setpredraw(this, func_null); // no need to keep running this
 118                 return;
 119         }
 120         float alph;
 121         vector org = getpropertyvec(VF_ORIGIN);
 122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 124         if(this.fade_start)
 125         {
 126                 if(vdist(org - this.origin, >, this.fade_end))
 127                         alph = 0; // save on some processing
 128                 else if(vdist(org - this.origin, <, this.fade_start))
 129                         alph = 1; // more processing saved
 130                 else
 131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         }
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         //else
 141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         strfree(this.mdl);
 147 }
 148
 149 HashMap ENT_CLIENT_ITEM_simple;
 150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 151 {
 152         HM_NEW(ENT_CLIENT_ITEM_simple);
 153 }
 154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 155 {
 156         HM_DELETE(ENT_CLIENT_ITEM_simple);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin = ReadVector();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218                 strfree(this.mdl);
 219
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228                         #define extensions(x) \
 229                                 x(md3) \
 230                                 x(dpm) \
 231                                 x(iqm) \
 232                                 x(mdl) \
 233                                 /**/
 234                         #define tryext(ext) { \
 235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 237                                 if (cached == "") { \
 238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 239                                 } \
 240                                 if (cached != "0") { \
 241                                         strcpy(this.mdl, s); \
 242                                         break; \
 243                                 } \
 244                         }
 245                         do {
 246                                 extensions(tryext);
 247                                 this.item_simple = false;
 248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 249                         } while (0);
 250                         #undef tryext
 251                         #undef extensions
 252         }
 253
 254         if(!this.item_simple)
 255             strcpy(this.mdl, _fn);
 256
 257         if(this.mdl == "")
 258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 259
 260         precache_model(this.mdl);
 261         _setmodel(this, this.mdl);
 262
 263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 264     }
 265
 266     if(sf & ISF_COLORMAP)
 267     {
 268         this.colormap = ReadShort();
 269         this.item_glowmod_x = ReadByte() / 255.0;
 270         this.item_glowmod_y = ReadByte() / 255.0;
 271         this.item_glowmod_z = ReadByte() / 255.0;
 272     }
 273
 274     if(sf & ISF_DROP)
 275     {
 276         this.gravity = 1;
 277         this.pushable = true;
 278         //this.angles = '0 0 0';
 279         set_movetype(this, MOVETYPE_TOSS);
 280         this.velocity = ReadVector();
 281         setorigin(this, this.oldorigin);
 282
 283         if(!this.move_time)
 284         {
 285             this.move_time = time;
 286             this.spawntime = time;
 287         }
 288         else
 289             this.move_time = max(this.move_time, time);
 290     }
 291
 292     if(autocvar_cl_animate_items)
 293     {
 294         if(this.ItemStatus & ITS_ANIMATE1)
 295             this.avelocity = '0 180 0';
 296
 297         if(this.ItemStatus & ITS_ANIMATE2)
 298             this.avelocity = '0 -90 0';
 299     }
 300
 301     this.entremove = ItemRemove;
 302
 303     return true;
 304 }
 305
 306 #endif
 307
 308 #ifdef SVQC
 309 bool ItemSend(entity this, entity to, int sf)
 310 {
 311         if(this.gravity)
 312                 sf |= ISF_DROP;
 313         else
 314                 sf &= ~ISF_DROP;
 315
 316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 317         WriteByte(MSG_ENTITY, sf);
 318
 319         //WriteByte(MSG_ENTITY, this.cnt);
 320         if(sf & ISF_LOCATION)
 321         {
 322                 WriteVector(MSG_ENTITY, this.origin);
 323         }
 324
 325         if(sf & ISF_ANGLES)
 326         {
 327                 WriteAngle(MSG_ENTITY, this.angles_x);
 328                 WriteAngle(MSG_ENTITY, this.angles_y);
 329                 WriteAngle(MSG_ENTITY, this.angles_z);
 330         }
 331
 332         if(sf & ISF_SIZE)
 333         {
 334                 Pickup p = this.itemdef;
 335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 336         }
 337
 338         if(sf & ISF_STATUS)
 339                 WriteByte(MSG_ENTITY, this.ItemStatus);
 340
 341         if(sf & ISF_MODEL)
 342         {
 343                 Pickup p = this.itemdef;
 344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 345                 WriteShort(MSG_ENTITY, this.fade_end);
 346                 WriteShort(MSG_ENTITY, this.fade_start);
 347
 348                 if(this.mdl == "")
 349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 350
 351                 WriteString(MSG_ENTITY, this.mdl);
 352         }
 353
 354
 355         if(sf & ISF_COLORMAP)
 356         {
 357                 WriteShort(MSG_ENTITY, this.colormap);
 358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 361         }
 362
 363         if(sf & ISF_DROP)
 364         {
 365                 WriteVector(MSG_ENTITY, this.velocity);
 366         }
 367
 368         return true;
 369 }
 370
 371 void ItemUpdate(entity this)
 372 {
 373         this.oldorigin = this.origin;
 374         this.SendFlags |= ISF_LOCATION;
 375 }
 376
 377 void UpdateItemAfterTeleport(entity this)
 378 {
 379         if(getSendEntity(this) == ItemSend)
 380                 ItemUpdate(this);
 381 }
 382
 383 bool have_pickup_item(entity this)
 384 {
 385         if(this.itemdef.instanceOfPowerup)
 386         {
 387                 if(autocvar_g_powerups > 0)
 388                         return true;
 389                 if(autocvar_g_powerups == 0)
 390                         return false;
 391         }
 392         else
 393         {
 394                 if(autocvar_g_pickup_items > 0)
 395                         return true;
 396                 if(autocvar_g_pickup_items == 0)
 397                         return false;
 398                 if(g_weaponarena)
 399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 400                                 return false;
 401         }
 402         return true;
 403 }
 404
 405 void Item_Show (entity e, float mode)
 406 {
 407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 408         e.ItemStatus &= ~ITS_STAYWEP;
 409         entity def = e.itemdef;
 410         if (mode > 0)
 411         {
 412                 // make the item look normal, and be touchable
 413                 e.model = e.mdl;
 414                 e.solid = SOLID_TRIGGER;
 415                 e.spawnshieldtime = 1;
 416                 e.ItemStatus |= ITS_AVAILABLE;
 417         }
 418         else if (mode < 0)
 419         {
 420                 // hide the item completely
 421                 e.model = string_null;
 422                 e.solid = SOLID_NOT;
 423                 e.spawnshieldtime = 1;
 424                 e.ItemStatus &= ~ITS_AVAILABLE;
 425         }
 426         else
 427         {
 428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 429                         || e.team // weapon stay isn't supported for teamed weapons
 430                         ;
 431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 432                 {
 433                         // make the item translucent and not touchable
 434                         e.model = e.mdl;
 435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 436                         e.effects |= EF_STARDUST;
 437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 439                 }
 440                 else
 441                 {
 442                         //setmodel(e, "null");
 443                         e.solid = SOLID_NOT;
 444                         e.colormod = '0 0 0';
 445                         //e.glowmod = e.colormod;
 446                         e.spawnshieldtime = 1;
 447                         e.ItemStatus &= ~ITS_AVAILABLE;
 448                 }
 449         }
 450
 451         if (def.m_glow)
 452                 e.ItemStatus |= ITS_GLOW;
 453
 454         if (autocvar_g_nodepthtestitems)
 455                 e.effects |= EF_NODEPTHTEST;
 456
 457
 458         if (autocvar_g_fullbrightitems)
 459                 e.ItemStatus |= ITS_ALLOWFB;
 460
 461         if (autocvar_sv_simple_items)
 462                 e.ItemStatus |= ITS_ALLOWSI;
 463
 464         // relink entity (because solid may have changed)
 465         setorigin(e, e.origin);
 466         e.SendFlags |= ISF_STATUS;
 467 }
 468
 469 void Item_Think(entity this)
 470 {
 471         this.nextthink = time;
 472         if(this.origin != this.oldorigin)
 473                 ItemUpdate(this);
 474 }
 475
 476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 477 bool Item_ItemsTime_Allow(GameItem it);
 478 float Item_ItemsTime_UpdateTime(entity e, float t);
 479 void Item_ItemsTime_SetTime(entity e, float t);
 480 void Item_ItemsTime_SetTimesForAllPlayers();
 481
 482 void Item_Respawn (entity this)
 483 {
 484         Item_Show(this, 1);
 485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 486         setorigin(this, this.origin);
 487
 488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 489         {
 490                 float t = Item_ItemsTime_UpdateTime(this, 0);
 491                 Item_ItemsTime_SetTime(this, t);
 492                 Item_ItemsTime_SetTimesForAllPlayers();
 493         }
 494
 495         setthink(this, Item_Think);
 496         this.nextthink = time;
 497
 498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 500 }
 501
 502 void Item_RespawnCountdown (entity this)
 503 {
 504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 505         {
 506                 if(this.waypointsprite_attached)
 507                         WaypointSprite_Kill(this.waypointsprite_attached);
 508                 Item_Respawn(this);
 509         }
 510         else
 511         {
 512                 this.nextthink = time + 1;
 513                 this.item_respawncounter += 1;
 514                 if(this.item_respawncounter == 1)
 515                 {
 516                         do {
 517                                 {
 518                                         entity wi = Weapons_from(this.weapon);
 519                                         if (wi != WEP_Null) {
 520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 521                                                 wp.wp_extra = wi.m_id;
 522                                                 break;
 523                                         }
 524                                 }
 525                                 {
 526                                         entity ii = this.itemdef;
 527                                         if (ii != NULL) {
 528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 529                                                 wp.wp_extra = ii.m_id;
 530                                                 break;
 531                                         }
 532                                 }
 533                         } while (0);
 534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 535             if(this.waypointsprite_attached)
 536             {
 537                 GameItem def = this.itemdef;
 538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 541             }
 542                 }
 543
 544                 if(this.waypointsprite_attached)
 545                 {
 546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 548                                 {
 549                                         msg_entity = it;
 550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 551                                 }
 552                         });
 553
 554                         WaypointSprite_Ping(this.waypointsprite_attached);
 555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 556                 }
 557         }
 558 }
 559
 560 void Item_RespawnThink(entity this)
 561 {
 562         this.nextthink = time;
 563         if(this.origin != this.oldorigin)
 564                 ItemUpdate(this);
 565
 566         if(time >= this.wait)
 567                 Item_Respawn(this);
 568 }
 569
 570 void Item_ScheduleRespawnIn(entity e, float t)
 571 {
 572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 574         {
 575                 setthink(e, Item_RespawnCountdown);
 576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 578                 e.item_respawncounter = 0;
 579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 580                 {
 581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 582                         Item_ItemsTime_SetTime(e, t);
 583                         Item_ItemsTime_SetTimesForAllPlayers();
 584                 }
 585         }
 586         else
 587         {
 588                 setthink(e, Item_RespawnThink);
 589                 e.nextthink = time;
 590                 e.scheduledrespawntime = time + t;
 591                 e.wait = time + t;
 592
 593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 594                 {
 595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 596                         Item_ItemsTime_SetTime(e, t);
 597                         Item_ItemsTime_SetTimesForAllPlayers();
 598                 }
 599         }
 600 }
 601
 602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 605
 606 /// Adjust respawn time according to the number of players.
 607 float adjust_respawntime(float normal_respawntime) {
 608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 609         float o = autocvar_g_pickup_respawntime_scaling_offset;
 610         float l = autocvar_g_pickup_respawntime_scaling_linear;
 611
 612         if (r == 0 && l == 1) {
 613                 return normal_respawntime;
 614         }
 615
 616         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 617         TeamBalance_GetTeamCounts(balance, NULL);
 618         int players = 0;
 619         for (int i = 1; i <= NUM_TEAMS; ++i)
 620         {
 621                 if (TeamBalance_IsTeamAllowed(balance, i))
 622                 {
 623                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 624                 }
 625         }
 626         TeamBalance_Destroy(balance);
 627
 628         if (players >= 2) {
 629                 return normal_respawntime * (r / (players + o) + l);
 630         } else {
 631                 return normal_respawntime;
 632         }
 633 }
 634
 635 void Item_ScheduleRespawn(entity e)
 636 {
 637         if(e.respawntime > 0)
 638         {
 639                 Item_Show(e, 0);
 640
 641                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 642                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 643
 644                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 645                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 646                 Item_ScheduleRespawnIn(e, respawn_in);
 647         }
 648         else // if respawntime is -1, this item does not respawn
 649                 Item_Show(e, -1);
 650 }
 651
 652 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 653         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 654
 655 void Item_ScheduleInitialRespawn(entity e)
 656 {
 657         Item_Show(e, 0);
 658
 659         float spawn_in;
 660         if (autocvar_g_pickup_respawntime_initial_random == 0)
 661         {
 662                 // range: respawntime .. respawntime + respawntimejitter
 663                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 664         }
 665         else
 666         {
 667                 float rnd;
 668                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 669                 {
 670                         static float shared_random = 0;
 671                         // NOTE this code works only if items are scheduled at the same time (normal case)
 672                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 673                         if (!shared_random || floor(time) > shared_random)
 674                                 shared_random = floor(time) + random();
 675                         rnd = shared_random - floor(time);
 676                 }
 677                 else
 678                         rnd = random();
 679
 680                 // range:
 681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 682                 // else: 0 .. ITEM_RESPAWN_TICKS
 683                 // this is to prevent powerups spawning unexpectedly without waypoints
 684                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 685         }
 686
 687         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 688 }
 689
 690 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 691         entity ammo_entity)
 692 {
 693         if (num_weapons == 0)
 694         {
 695                 return;
 696         }
 697         int num_potential_weapons = tokenize_console(weapon_names);
 698         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 699         {
 700                 RandomSelection_Init();
 701                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 702                         ++weapon_index)
 703                 {
 704                         string weapon = argv(weapon_index);
 705                         FOREACH(Weapons, it != WEP_Null,
 706                         {
 707                                 // Finding a weapon which player doesn't have.
 708                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 709                                 {
 710                                         RandomSelection_AddEnt(it, 1, 1);
 711                                         break;
 712                                 }
 713                         });
 714                 }
 715                 if (RandomSelection_chosen_ent == NULL)
 716                 {
 717                         return;
 718                 }
 719                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 720                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 721                 {
 722                         continue;
 723                 }
 724                 if (GetResourceAmount(receiver,
 725                         RandomSelection_chosen_ent.ammo_type) != 0)
 726                 {
 727                         continue;
 728                 }
 729                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 730                         GetResourceAmount(ammo_entity,
 731                         RandomSelection_chosen_ent.ammo_type));
 732         }
 733 }
 734
 735 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 736 {
 737         float amount = GetResourceAmount(item, resource_type);
 738         if (amount == 0)
 739         {
 740                 return false;
 741         }
 742         float player_amount = GetResourceAmount(player, resource_type);
 743         if (item.spawnshieldtime)
 744         {
 745                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 746                 {
 747                         return false;
 748                 }
 749                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 750                 return true;
 751         }
 752         if (g_weapon_stay != 2)
 753         {
 754                 return false;
 755         }
 756         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 757         return true;
 758 }
 759
 760 float Item_GiveTo(entity item, entity player)
 761 {
 762         float pickedup;
 763
 764         // if nothing happens to player, just return without taking the item
 765         pickedup = false;
 766         int _switchweapon = 0;
 767         // in case the player has autoswitch enabled do the following:
 768         // if the player is using their best weapon before items are given, they
 769         // probably want to switch to an even better weapon after items are given
 770
 771         if(CS(player).autoswitch)
 772         {
 773                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 774                 {
 775                         .entity weaponentity = weaponentities[slot];
 776                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 777                         {
 778                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 779                                         _switchweapon |= BIT(slot);
 780
 781                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 782                                         _switchweapon |= BIT(slot);
 783                         }
 784                 }
 785         }
 786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 788         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 789         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 790         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 791         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 792         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 793         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 794         if (item.itemdef.instanceOfWeaponPickup)
 795         {
 796                 WepSet w;
 797                 w = STAT(WEAPONS, item);
 798                 w &= ~STAT(WEAPONS, player);
 799
 800                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 801                 {
 802                         pickedup = true;
 803                         FOREACH(Weapons, it != WEP_Null, {
 804                                 if(w & (it.m_wepset))
 805                                 {
 806                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 807                                         {
 808                                                 .entity weaponentity = weaponentities[slot];
 809                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 810                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 811                                         }
 812                                         W_GiveWeapon(player, it.m_id);
 813                                 }
 814                         });
 815                 }
 816         }
 817
 818         if (item.itemdef.instanceOfPowerup)
 819         {
 820                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 821                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 822                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 823                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 824         }
 825
 826         int its;
 827         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 828         {
 829                 pickedup = true;
 830                 player.items |= its;
 831                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 832         }
 833
 834         if (item.strength_finished)
 835         {
 836                 pickedup = true;
 837                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 838         }
 839         if (item.invincible_finished)
 840         {
 841                 pickedup = true;
 842                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 843         }
 844         if (item.superweapons_finished)
 845         {
 846                 pickedup = true;
 847                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 848         }
 849
 850         // always eat teamed entities
 851         if(item.team)
 852                 pickedup = true;
 853
 854         if (!pickedup)
 855                 return 0;
 856
 857         // crude hack to enforce switching weapons
 858         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 859         {
 860                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 861                 {
 862                         .entity weaponentity = weaponentities[slot];
 863                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 864                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 865                 }
 866                 return 1;
 867         }
 868
 869         if(_switchweapon)
 870         {
 871                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 872                 {
 873                         .entity weaponentity = weaponentities[slot];
 874                         if(_switchweapon & BIT(slot))
 875                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 876                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 877                 }
 878         }
 879
 880         return 1;
 881 }
 882
 883 void Item_Touch(entity this, entity toucher)
 884 {
 885         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 886         if (Item_IsLoot(this))
 887         {
 888                 if (ITEM_TOUCH_NEEDKILL())
 889                 {
 890                         delete(this);
 891                         return;
 892                 }
 893         }
 894
 895         if(!(toucher.flags & FL_PICKUPITEMS)
 896         || STAT(FROZEN, toucher)
 897         || IS_DEAD(toucher)
 898         || (this.solid != SOLID_TRIGGER)
 899         || (this.owner == toucher)
 900         || (time < this.item_spawnshieldtime)
 901         ) { return; }
 902
 903         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 904         {
 905                 case MUT_ITEMTOUCH_RETURN: { return; }
 906                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 907         }
 908
 909         toucher = M_ARGV(1, entity);
 910
 911         if (Item_IsExpiring(this))
 912         {
 913                 this.strength_finished = max(0, this.strength_finished - time);
 914                 this.invincible_finished = max(0, this.invincible_finished - time);
 915                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 916         }
 917         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 918         if (!gave)
 919         {
 920                 if (Item_IsExpiring(this))
 921                 {
 922                         // undo what we did above
 923                         this.strength_finished += time;
 924                         this.invincible_finished += time;
 925                         this.superweapons_finished += time;
 926                 }
 927                 return;
 928         }
 929
 930 LABEL(pickup)
 931
 932         STAT(LAST_PICKUP, toucher) = time;
 933
 934         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 935         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 936
 937         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 938         if (wasfreed(this))
 939         {
 940                 return;
 941         }
 942
 943         if (Item_IsLoot(this))
 944         {
 945                 delete(this);
 946                 return;
 947         }
 948         if (!this.spawnshieldtime)
 949         {
 950                 return;
 951         }
 952         entity e;
 953         if (this.team)
 954         {
 955                 RandomSelection_Init();
 956                 IL_EACH(g_items, it.team == this.team,
 957                 {
 958                         if (it.itemdef) // is a registered item
 959                         {
 960                                 Item_Show(it, -1);
 961                                 it.scheduledrespawntime = 0;
 962                                 RandomSelection_AddEnt(it, it.cnt, 0);
 963                         }
 964                 });
 965                 e = RandomSelection_chosen_ent;
 966                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 967         }
 968         else
 969                 e = this;
 970         Item_ScheduleRespawn(e);
 971 }
 972
 973 void Item_Reset(entity this)
 974 {
 975         Item_Show(this, !this.state);
 976         setorigin(this, this.origin);
 977
 978         if (Item_IsLoot(this))
 979         {
 980                 return;
 981         }
 982         setthink(this, Item_Think);
 983         this.nextthink = time;
 984         if (this.waypointsprite_attached)
 985         {
 986                 WaypointSprite_Kill(this.waypointsprite_attached);
 987         }
 988         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 989         {
 990                 Item_ScheduleInitialRespawn(this);
 991         }
 992 }
 993
 994 void Item_FindTeam(entity this)
 995 {
 996         entity e;
 997
 998         if(this.effects & EF_NODRAW)
 999         {
1000                 // marker for item team search
1001                 LOG_TRACE("Initializing item team ", ftos(this.team));
1002                 RandomSelection_Init();
1003                 IL_EACH(g_items, it.team == this.team,
1004                 {
1005                         if(it.itemdef) // is a registered item
1006                                 RandomSelection_AddEnt(it, it.cnt, 0);
1007                 });
1008
1009                 e = RandomSelection_chosen_ent;
1010                 e.state = 0;
1011                 Item_Show(e, 1);
1012
1013                 IL_EACH(g_items, it.team == this.team,
1014                 {
1015                         if(it.itemdef) // is a registered item
1016                         {
1017                                 if(it != e)
1018                                 {
1019                                         // make it non-spawned
1020                                         Item_Show(it, -1);
1021                                         it.state = 1; // state 1 = initially hidden item, apparently
1022                                 }
1023                                 it.effects &= ~EF_NODRAW;
1024                         }
1025                 });
1026
1027                 Item_Reset(this);
1028         }
1029 }
1030
1031 // Savage: used for item garbage-collection
1032 void RemoveItem(entity this)
1033 {
1034         if(wasfreed(this) || !this) { return; }
1035         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1036         delete(this);
1037 }
1038
1039 // pickup evaluation functions
1040 // these functions decide how desirable an item is to the bots
1041
1042 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1043
1044 float weapon_pickupevalfunc(entity player, entity item)
1045 {
1046         // See if I have it already
1047         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1048         {
1049                 // If I can pick it up
1050                 if(!item.spawnshieldtime)
1051                         return 0;
1052                 return ammo_pickupevalfunc(player, item);
1053         }
1054
1055         // reduce weapon value if bot already got a good arsenal
1056         float c = 1;
1057         int weapons_value = 0;
1058         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1059                 weapons_value += it.bot_pickupbasevalue;
1060         });
1061         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1062
1063         return item.bot_pickupbasevalue * c;
1064 }
1065
1066 float ammo_pickupevalfunc(entity player, entity item)
1067 {
1068         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1069         entity wpn = NULL;
1070         float c = 0;
1071         float rating = 0;
1072
1073         // Detect needed ammo
1074         if(item.itemdef.instanceOfWeaponPickup)
1075         {
1076                 entity ammo = NULL;
1077                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1078                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1079                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1080                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1081                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1082                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1083
1084                 if(!ammo)
1085                         return 0;
1086                 wpn = item;
1087                 rating = ammo.m_botvalue;
1088         }
1089         else
1090         {
1091                 FOREACH(Weapons, it != WEP_Null, {
1092                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1093                                 continue;
1094
1095                         switch(it.ammo_type)
1096                         {
1097                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1098                                 case RESOURCE_BULLETS: need_nails   = true; break;
1099                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1100                                 case RESOURCE_CELLS:   need_cells   = true; break;
1101                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1102                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1103                         }
1104                 });
1105                 rating = item.bot_pickupbasevalue;
1106         }
1107
1108         float noammorating = 0.5;
1109
1110         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1111                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1112
1113         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1114                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1115
1116         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1117                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1118
1119         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1120                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1121
1122         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1123                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1124
1125         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1126                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1127
1128         rating *= min(c, 2);
1129         if(wpn)
1130                 rating += wpn.bot_pickupbasevalue * 0.1;
1131         return rating;
1132 }
1133
1134 float healtharmor_pickupevalfunc(entity player, entity item)
1135 {
1136         float c = 0;
1137         float rating = item.bot_pickupbasevalue;
1138
1139         float itemarmor = item.armorvalue;
1140         float itemhealth = item.health;
1141
1142         if(item.item_group)
1143         {
1144                 itemarmor *= min(4, item.item_group_count);
1145                 itemhealth *= min(4, item.item_group_count);
1146         }
1147
1148         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1149                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1150
1151         if (itemhealth && (player.health < item.max_health))
1152                 c = itemhealth / max(1, player.health);
1153
1154         rating *= min(2, c);
1155         return rating;
1156 }
1157
1158 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1159 {
1160         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1161                 RemoveItem(this);
1162 }
1163
1164 void item_use(entity this, entity actor, entity trigger)
1165 {
1166         // use the touch function to handle collection
1167         gettouch(this)(this, actor);
1168 }
1169
1170 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1171 {
1172         string itemname = def.m_name;
1173         Model itemmodel = def.m_model;
1174     Sound pickupsound = def.m_sound;
1175         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1176         float pickupbasevalue = def.m_botvalue;
1177         int itemflags = def.m_itemflags;
1178
1179         startitem_failed = false;
1180
1181         this.item_model_ent = itemmodel;
1182     this.item_pickupsound_ent = pickupsound;
1183
1184     if(def.m_iteminit)
1185         def.m_iteminit(this);
1186
1187         if(!this.respawntime) // both need to be set
1188         {
1189                 this.respawntime = defaultrespawntime;
1190                 this.respawntimejitter = defaultrespawntimejitter;
1191         }
1192
1193         if(!this.pickup_anyway && def.m_pickupanyway)
1194                 this.pickup_anyway = def.m_pickupanyway();
1195
1196         int itemid = def.m_itemid;
1197         this.items = itemid;
1198         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1199         this.weapon = weaponid;
1200
1201         if(!this.fade_end)
1202         {
1203                 this.fade_start = autocvar_g_items_mindist;
1204                 this.fade_end = autocvar_g_items_maxdist;
1205         }
1206
1207         if(weaponid)
1208                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1209
1210         this.flags = FL_ITEM | itemflags;
1211         IL_PUSH(g_items, this);
1212
1213         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1214         {
1215                 startitem_failed = true;
1216                 delete(this);
1217                 return;
1218         }
1219
1220         if (Item_IsLoot(this))
1221         {
1222                 this.reset = SUB_Remove;
1223                 set_movetype(this, MOVETYPE_TOSS);
1224
1225                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1226                 setthink(this, RemoveItem);
1227                 this.nextthink = time + 20;
1228
1229                 this.takedamage = DAMAGE_YES;
1230                 this.event_damage = Item_Damage;
1231
1232                 if (Item_IsExpiring(this))
1233                 {
1234                         // if item is worthless after a timer, have it expire then
1235                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1236                 }
1237
1238                 // don't drop if in a NODROP zone (such as lava)
1239                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1240                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1241                 {
1242                         startitem_failed = true;
1243                         delete(this);
1244                         return;
1245                 }
1246         }
1247         else
1248         {
1249                 if(!have_pickup_item(this))
1250                 {
1251                         startitem_failed = true;
1252                         delete(this);
1253                         return;
1254                 }
1255
1256                 if(this.angles != '0 0 0')
1257                         this.SendFlags |= ISF_ANGLES;
1258
1259                 this.reset = Item_Reset;
1260                 // it's a level item
1261                 if(this.spawnflags & 1)
1262                         this.noalign = 1;
1263                 if (this.noalign > 0)
1264                         set_movetype(this, MOVETYPE_NONE);
1265                 else
1266                         set_movetype(this, MOVETYPE_TOSS);
1267                 // do item filtering according to game mode and other things
1268                 if (this.noalign <= 0)
1269                 {
1270                         // first nudge it off the floor a little bit to avoid math errors
1271                         setorigin(this, this.origin + '0 0 1');
1272                         // set item size before we spawn a spawnfunc_waypoint
1273                         setsize(this, def.m_mins, def.m_maxs);
1274                         this.SendFlags |= ISF_SIZE;
1275                         // note droptofloor returns false if stuck/or would fall too far
1276                         if (!this.noalign)
1277                                 droptofloor(this);
1278                         waypoint_spawnforitem(this);
1279                 }
1280
1281                 /*
1282                  * can't do it that way, as it would break maps
1283                  * TODO make a target_give like entity another way, that perhaps has
1284                  * the weapon name in a key
1285                 if(this.targetname)
1286                 {
1287                         // target_give not yet supported; maybe later
1288                         print("removed targeted ", this.classname, "\n");
1289                         startitem_failed = true;
1290                         delete(this);
1291                         return;
1292                 }
1293                 */
1294
1295                 if(this.targetname != "" && (this.spawnflags & 16))
1296                         this.use = item_use;
1297
1298                 if(autocvar_spawn_debug >= 2)
1299                 {
1300             // why not flags & fl_item?
1301                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1302                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1303                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1304                 error("Mapper sucks.");
1305             });
1306                         this.is_item = true;
1307                 }
1308
1309                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1310
1311                 precache_model(this.model);
1312                 precache_sound(this.item_pickupsound);
1313
1314                 if (   def.instanceOfPowerup
1315                         || def.instanceOfWeaponPickup
1316                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1317                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1318                         || (itemid & (IT_KEY1 | IT_KEY2))
1319                 ) this.target = "###item###"; // for finding the nearest item using find()
1320
1321                 Item_ItemsTime_SetTime(this, 0);
1322         }
1323
1324         this.bot_pickup = true;
1325         this.bot_pickupevalfunc = pickupevalfunc;
1326         this.bot_pickupbasevalue = pickupbasevalue;
1327         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1328         this.netname = itemname;
1329         settouch(this, Item_Touch);
1330         setmodel(this, MDL_Null); // precision set below
1331         //this.effects |= EF_LOWPRECISION;
1332
1333         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1334
1335         this.SendFlags |= ISF_SIZE;
1336
1337         if (!(this.spawnflags & 1024)) {
1338                 if(def.instanceOfPowerup)
1339                         this.ItemStatus |= ITS_ANIMATE1;
1340
1341                 if(this.armorvalue || this.health)
1342                         this.ItemStatus |= ITS_ANIMATE2;
1343         }
1344
1345         if(def.instanceOfWeaponPickup)
1346         {
1347                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1348                         this.colormap = 1024; // color shirt=0 pants=0 grey
1349                 else
1350                         this.gravity = 1;
1351                 if (!(this.spawnflags & 1024))
1352                         this.ItemStatus |= ITS_ANIMATE1;
1353                 this.SendFlags |= ISF_COLORMAP;
1354         }
1355
1356         this.state = 0;
1357         if(this.team) // broken, no idea why.
1358         {
1359                 if(!this.cnt)
1360                         this.cnt = 1; // item probability weight
1361
1362                 this.effects |= EF_NODRAW; // marker for item team search
1363                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1364         }
1365         else
1366                 Item_Reset(this);
1367
1368         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1369
1370         // call this hook after everything else has been done
1371         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1372         {
1373                 startitem_failed = true;
1374                 delete(this);
1375                 return;
1376         }
1377
1378         setItemGroup(this);
1379 }
1380
1381 void StartItem(entity this, GameItem def)
1382 {
1383     def = def.m_spawnfunc_hookreplace(def, this);
1384     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1385     {
1386         delete(this);
1387         return;
1388     }
1389     this.classname = def.m_canonical_spawnfunc;
1390     _StartItem(
1391         this,
1392         this.itemdef = def,
1393         def.m_respawntime(), // defaultrespawntime
1394         def.m_respawntimejitter() // defaultrespawntimejitter
1395         );
1396 }
1397
1398 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1399 int group_count = 1;
1400
1401 void setItemGroup(entity this)
1402 {
1403         if(!IS_SMALL(this.itemdef))
1404                 return;
1405
1406         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1407         {
1408                 if(!this.item_group)
1409                 {
1410                         if(!it.item_group)
1411                         {
1412                                 it.item_group = group_count;
1413                                 group_count++;
1414                         }
1415                         this.item_group = it.item_group;
1416                 }
1417                 else // spawning item is already part of a item_group X
1418                 {
1419                         if(!it.item_group)
1420                                 it.item_group = this.item_group;
1421                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1422                         {
1423                                 int grY = it.item_group;
1424                                 // move all items of item_group Y to item_group X
1425                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1426                                 {
1427                                         if(it.item_group == grY)
1428                                                 it.item_group = this.item_group;
1429                                 });
1430                         }
1431                 }
1432         });
1433 }
1434
1435 void setItemGroupCount()
1436 {
1437         for (int k = 1; k <= group_count; k++)
1438         {
1439                 int count = 0;
1440                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1441                 if (count)
1442                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1443         }
1444 }
1445
1446 void target_items_use(entity this, entity actor, entity trigger)
1447 {
1448         if(Item_IsLoot(actor))
1449         {
1450                 EXACTTRIGGER_TOUCH(this, trigger);
1451                 delete(actor);
1452                 return;
1453         }
1454
1455         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1456                 return;
1457
1458         if(trigger.solid == SOLID_TRIGGER)
1459         {
1460                 EXACTTRIGGER_TOUCH(this, trigger);
1461         }
1462
1463         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1464         {
1465                 delete(it);
1466         });
1467
1468         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1469                 centerprint(actor, this.message);
1470 }
1471
1472 spawnfunc(target_items)
1473 {
1474         int n;
1475         string s;
1476
1477         this.use = target_items_use;
1478         if(!this.strength_finished)
1479                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1480         if(!this.invincible_finished)
1481                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1482         if(!this.superweapons_finished)
1483                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1484
1485         n = tokenize_console(this.netname);
1486         if(argv(0) == "give")
1487         {
1488                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1489         }
1490         else
1491         {
1492                 for(int j = 0; j < n; ++j)
1493                 {
1494                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1495                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1496                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1497                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1498                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1499                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1500                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1501                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1502                         else
1503                         {
1504                                 FOREACH(Buffs, it != BUFF_Null,
1505                                 {
1506                                         s = Buff_UndeprecateName(argv(j));
1507                                         if(s == it.m_name)
1508                                         {
1509                                                 STAT(BUFFS, this) |= (it.m_itemid);
1510                                                 break;
1511                                         }
1512                                 });
1513                                 FOREACH(Weapons, it != WEP_Null, {
1514                                         s = W_UndeprecateName(argv(j));
1515                                         if(s == it.netname)
1516                                         {
1517                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1518                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1519                                                         it.wr_init(it);
1520                                                 break;
1521                                         }
1522                                 });
1523                         }
1524                 }
1525
1526                 string itemprefix, valueprefix;
1527                 if(this.spawnflags == 0)
1528                 {
1529                         itemprefix = "";
1530                         valueprefix = "";
1531                 }
1532                 else if(this.spawnflags == 1)
1533                 {
1534                         itemprefix = "max ";
1535                         valueprefix = "max ";
1536                 }
1537                 else if(this.spawnflags == 2)
1538                 {
1539                         itemprefix = "min ";
1540                         valueprefix = "min ";
1541                 }
1542                 else if(this.spawnflags == 4)
1543                 {
1544                         itemprefix = "minus ";
1545                         valueprefix = "max ";
1546                 }
1547                 else
1548                 {
1549                         error("invalid spawnflags");
1550                         itemprefix = valueprefix = string_null;
1551                 }
1552
1553                 this.netname = "";
1554                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1555                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1557                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1558                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1561                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1562                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1563                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1564                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1565                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1566                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1567                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1568                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1569                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1570                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1571         }
1572         this.netname = strzone(this.netname);
1573         //print(this.netname, "\n");
1574
1575         n = tokenize_console(this.netname);
1576         for(int j = 0; j < n; ++j)
1577         {
1578                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1579             it.wr_init(it);
1580             break;
1581                 });
1582         }
1583 }
1584
1585 float GiveWeapon(entity e, float wpn, float op, float val)
1586 {
1587         WepSet v0, v1;
1588         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1589         v0 = (STAT(WEAPONS, e) & s);
1590         switch(op)
1591         {
1592                 case OP_SET:
1593                         if(val > 0)
1594                                 STAT(WEAPONS, e) |= s;
1595                         else
1596                                 STAT(WEAPONS, e) &= ~s;
1597                         break;
1598                 case OP_MIN:
1599                 case OP_PLUS:
1600                         if(val > 0)
1601                                 STAT(WEAPONS, e) |= s;
1602                         break;
1603                 case OP_MAX:
1604                         if(val <= 0)
1605                                 STAT(WEAPONS, e) &= ~s;
1606                         break;
1607                 case OP_MINUS:
1608                         if(val > 0)
1609                                 STAT(WEAPONS, e) &= ~s;
1610                         break;
1611         }
1612         v1 = (STAT(WEAPONS, e) & s);
1613         return (v0 != v1);
1614 }
1615
1616 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1617 {
1618         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1619         switch(op)
1620         {
1621                 case OP_SET:
1622                         if(val > 0)
1623                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1624                         else
1625                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1626                         break;
1627                 case OP_MIN:
1628                 case OP_PLUS:
1629                         if(val > 0)
1630                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1631                         break;
1632                 case OP_MAX:
1633                         if(val <= 0)
1634                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1635                         break;
1636                 case OP_MINUS:
1637                         if(val > 0)
1638                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1639                         break;
1640         }
1641         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1642         return (had_buff != have_buff);
1643 }
1644
1645 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1646 {
1647         if(v1 == v0)
1648                 return;
1649         if(v1 <= v0 - t)
1650         {
1651                 if(snd_decr != NULL)
1652                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1653         }
1654         else if(v0 >= v0 + t)
1655         {
1656                 if(snd_incr != NULL)
1657                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1658         }
1659 }
1660
1661 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1662 {
1663         if(v0 < v1)
1664                 e.(rotfield) = max(e.(rotfield), time + rottime);
1665         else if(v0 > v1)
1666                 e.(regenfield) = max(e.(regenfield), time + regentime);
1667 }
1668 float GiveItems(entity e, float beginarg, float endarg)
1669 {
1670         float got, i, val, op;
1671         string cmd;
1672
1673         val = 999;
1674         op = OP_SET;
1675
1676         got = 0;
1677
1678         int _switchweapon = 0;
1679
1680         if(CS(e).autoswitch)
1681         {
1682                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1683                 {
1684                         .entity weaponentity = weaponentities[slot];
1685                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1686                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1687                                 _switchweapon |= BIT(slot);
1688                 }
1689         }
1690
1691         e.strength_finished = max(0, e.strength_finished - time);
1692         e.invincible_finished = max(0, e.invincible_finished - time);
1693         e.superweapons_finished = max(0, e.superweapons_finished - time);
1694
1695         PREGIVE(e, items);
1696         PREGIVE_WEAPONS(e);
1697         PREGIVE(e, strength_finished);
1698         PREGIVE(e, invincible_finished);
1699         PREGIVE(e, superweapons_finished);
1700         PREGIVE(e, ammo_nails);
1701         PREGIVE(e, ammo_cells);
1702         PREGIVE(e, ammo_plasma);
1703         PREGIVE(e, ammo_shells);
1704         PREGIVE(e, ammo_rockets);
1705         PREGIVE(e, ammo_fuel);
1706         PREGIVE(e, armorvalue);
1707         PREGIVE(e, health);
1708
1709         for(i = beginarg; i < endarg; ++i)
1710         {
1711                 cmd = argv(i);
1712
1713                 if(cmd == "0" || stof(cmd))
1714                 {
1715                         val = stof(cmd);
1716                         continue;
1717                 }
1718                 switch(cmd)
1719                 {
1720                         case "no":
1721                                 op = OP_MAX;
1722                                 val = 0;
1723                                 continue;
1724                         case "max":
1725                                 op = OP_MAX;
1726                                 continue;
1727                         case "min":
1728                                 op = OP_MIN;
1729                                 continue;
1730                         case "plus":
1731                                 op = OP_PLUS;
1732                                 continue;
1733                         case "minus":
1734                                 op = OP_MINUS;
1735                                 continue;
1736                         case "ALL":
1737                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1738                                 got += GiveValue(e, strength_finished, op, val);
1739                                 got += GiveValue(e, invincible_finished, op, val);
1740                                 got += GiveValue(e, superweapons_finished, op, val);
1741                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1742                         case "all":
1743                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1744                                 got += GiveValue(e, health, op, val);
1745                                 got += GiveValue(e, armorvalue, op, val);
1746                         case "allweapons":
1747                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1748                         //case "allbuffs": // all buffs makes a player god, do not want!
1749                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1750                         case "allammo":
1751                                 got += GiveValue(e, ammo_cells, op, val);
1752                                 got += GiveValue(e, ammo_plasma, op, val);
1753                                 got += GiveValue(e, ammo_shells, op, val);
1754                                 got += GiveValue(e, ammo_nails, op, val);
1755                                 got += GiveValue(e, ammo_rockets, op, val);
1756                                 got += GiveValue(e, ammo_fuel, op, val);
1757                                 break;
1758                         case "unlimited_ammo":
1759                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1760                                 break;
1761                         case "unlimited_weapon_ammo":
1762                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1763                                 break;
1764                         case "unlimited_superweapons":
1765                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1766                                 break;
1767                         case "jetpack":
1768                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1769                                 break;
1770                         case "fuel_regen":
1771                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1772                                 break;
1773                         case "strength":
1774                                 got += GiveValue(e, strength_finished, op, val);
1775                                 break;
1776                         case "invincible":
1777                                 got += GiveValue(e, invincible_finished, op, val);
1778                                 break;
1779                         case "superweapons":
1780                                 got += GiveValue(e, superweapons_finished, op, val);
1781                                 break;
1782                         case "cells":
1783                                 got += GiveValue(e, ammo_cells, op, val);
1784                                 break;
1785                         case "plasma":
1786                                 got += GiveValue(e, ammo_plasma, op, val);
1787                                 break;
1788                         case "shells":
1789                                 got += GiveValue(e, ammo_shells, op, val);
1790                                 break;
1791                         case "nails":
1792                         case "bullets":
1793                                 got += GiveValue(e, ammo_nails, op, val);
1794                                 break;
1795                         case "rockets":
1796                                 got += GiveValue(e, ammo_rockets, op, val);
1797                                 break;
1798                         case "health":
1799                                 got += GiveValue(e, health, op, val);
1800                                 break;
1801                         case "armor":
1802                                 got += GiveValue(e, armorvalue, op, val);
1803                                 break;
1804                         case "fuel":
1805                                 got += GiveValue(e, ammo_fuel, op, val);
1806                                 break;
1807                         default:
1808                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1809                                 {
1810                                         got += GiveBuff(e, it, op, val);
1811                                         break;
1812                                 });
1813                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1814                     got += GiveWeapon(e, it.m_id, op, val);
1815                     break;
1816                                 });
1817                                 break;
1818                 }
1819                 val = 999;
1820                 op = OP_SET;
1821         }
1822
1823         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1824         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1825         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1826         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1827         FOREACH(Weapons, it != WEP_Null, {
1828                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1829                 if(!(save_weapons & (it.m_wepset)))
1830                         if(STAT(WEAPONS, e) & (it.m_wepset))
1831                                 it.wr_init(it);
1832         });
1833         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1834         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1835         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1836         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1837         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1838         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1839         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1840         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1841         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1842         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1843         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1844
1845         if(e.superweapons_finished <= 0)
1846                 if(STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1847                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1848
1849         if(e.strength_finished <= 0)
1850                 e.strength_finished = 0;
1851         else
1852                 e.strength_finished += time;
1853         if(e.invincible_finished <= 0)
1854                 e.invincible_finished = 0;
1855         else
1856                 e.invincible_finished += time;
1857         if(e.superweapons_finished <= 0)
1858                 e.superweapons_finished = 0;
1859         else
1860                 e.superweapons_finished += time;
1861
1862         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863         {
1864                 .entity weaponentity = weaponentities[slot];
1865                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1866                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1867                         _switchweapon |= BIT(slot);
1868         }
1869
1870         if(_switchweapon)
1871         {
1872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1873                 {
1874                         .entity weaponentity = weaponentities[slot];
1875                         if(_switchweapon & BIT(slot))
1876                         {
1877                                 Weapon wep = w_getbestweapon(e, weaponentity);
1878                                 if(wep != e.(weaponentity).m_switchweapon)
1879                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1880                         }
1881                 }
1882         }
1883
1884         return got;
1885 }
1886 #endif