qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 void Item_ScheduleRespawn(entity e)
 635 {
 636         if(e.respawntime > 0)
 637         {
 638                 Item_Show(e, 0);
 639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 640         }
 641         else // if respawntime is -1, this item does not respawn
 642                 Item_Show(e, -1);
 643 }
 644
 645 void Item_ScheduleInitialRespawn(entity e)
 646 {
 647         Item_Show(e, 0);
 648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 649 }
 650
 651 void GivePlayerHealth(entity player, float amount)
 652 {
 653         if (amount == 0)
 654         {
 655                 return;
 656         }
 657         player.health = bound(player.health, player.health + amount,
 658                  g_pickup_healthmega_max);
 659         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
 660                 autocvar_g_balance_pause_health_rot);
 661 }
 662
 663 void GivePlayerArmor(entity player, float amount)
 664 {
 665         if (amount == 0)
 666         {
 667                 return;
 668         }
 669         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 670                  g_pickup_armormega_max);
 671         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
 672                 autocvar_g_balance_pause_armor_rot);
 673 }
 674
 675 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 676 {
 677         float maxvalue = 999;
 678         switch (ammotype)
 679         {
 680                 case ammo_shells:
 681                 {
 682                         maxvalue = g_pickup_shells_max;
 683                         break;
 684                 }
 685                 case ammo_cells:
 686                 {
 687                         maxvalue = g_pickup_cells_max;
 688                         break;
 689                 }
 690                 case ammo_rockets:
 691                 {
 692                         maxvalue = g_pickup_rockets_max;
 693                         break;
 694                 }
 695                 case ammo_plasma:
 696                 {
 697                         maxvalue = g_pickup_plasma_max;
 698                         break;
 699                 }
 700                 case ammo_nails:
 701                 {
 702                         maxvalue = g_pickup_nails_max;
 703                         break;
 704                 }
 705                 case ammo_fuel:
 706                 {
 707                         maxvalue = g_pickup_fuel_max;
 708                         break;
 709                 }
 710         }
 711         player.(ammotype) = min(player.(ammotype) + amount, maxvalue);
 712 }
 713
 714 void GivePlayerRandomWeapons(entity player, int num_weapons,
 715         string weapon_names, float shells, float bullets, float rockets,
 716         float cells, float plasma)
 717 {
 718         if (num_weapons == 0)
 719         {
 720                 return;
 721         }
 722         int num_potential_weapons = tokenize_console(weapon_names);
 723         for (int i = 0; i < num_weapons; ++i)
 724         {
 725                 RandomSelection_Init();
 726                 for (int j = 0; j < num_potential_weapons; ++j)
 727                 {
 728                         string weapon = argv(j);
 729                         FOREACH(Weapons, it != WEP_Null,
 730                         {
 731                                 // Finding a weapon which player doesn't have.
 732                                 if (!(player.weapons & it.m_wepset) && (it.netname == weapon))
 733                                 {
 734                                         RandomSelection_AddEnt(it, 1, 1);
 735                                         break;
 736                                 }
 737                         });
 738                 }
 739                 if (RandomSelection_chosen_ent == NULL)
 740                 {
 741                         return;
 742                 }
 743                 player.weapons |= RandomSelection_chosen_ent.m_wepset;
 744                 switch (RandomSelection_chosen_ent.ammo_field)
 745                 {
 746                         case (ammo_shells):
 747                         {
 748                                 if (player.ammo_shells != 0)
 749                                 {
 750                                         break;
 751                                 }
 752                                 GivePlayerAmmo(player, ammo_shells, shells);
 753                                 break;
 754                         }
 755                         case (ammo_nails):
 756                         {
 757                                 if (player.ammo_nails != 0)
 758                                 {
 759                                         break;
 760                                 }
 761                                 GivePlayerAmmo(player, ammo_nails, bullets);
 762                                 break;
 763                         }
 764                         case (ammo_rockets):
 765                         {
 766                                 if (player.ammo_rockets != 0)
 767                                 {
 768                                         break;
 769                                 }
 770                                 GivePlayerAmmo(player, ammo_rockets, rockets);
 771                                 break;
 772                         }
 773                         case (ammo_cells):
 774                         {
 775                                 if (player.ammo_cells != 0)
 776                                 {
 777                                         break;
 778                                 }
 779                                 GivePlayerAmmo(player, ammo_cells, cells);
 780                                 break;
 781                         }
 782                         case (ammo_plasma):
 783                         {
 784                                 if (player.ammo_plasma != 0)
 785                                 {
 786                                         break;
 787                                 }
 788                                 GivePlayerAmmo(player, ammo_plasma, plasma);
 789                                 break;
 790                         }
 791                 }
 792         }
 793 }
 794
 795 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 796 {
 797         if (!item.(ammotype))
 798                 return false;
 799
 800         if (item.spawnshieldtime)
 801         {
 802                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 803                 {
 804                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 805                         goto YEAH;
 806                 }
 807         }
 808         else if(g_weapon_stay == 2)
 809         {
 810                 float mi = min(item.(ammotype), ammomax);
 811                 if (player.(ammotype) < mi)
 812                 {
 813                         player.(ammotype) = mi;
 814                         goto YEAH;
 815                 }
 816         }
 817
 818         return false;
 819
 820 LABEL(YEAH)
 821         switch(mode)
 822         {
 823                 case ITEM_MODE_FUEL:
 824                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 825                         break;
 826                 case ITEM_MODE_HEALTH:
 827                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 828                         break;
 829                 case ITEM_MODE_ARMOR:
 830                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 831                         break;
 832                 default:
 833                         break;
 834         }
 835         return true;
 836 }
 837
 838 float Item_GiveTo(entity item, entity player)
 839 {
 840         float pickedup;
 841
 842         // if nothing happens to player, just return without taking the item
 843         pickedup = false;
 844         int _switchweapon = 0;
 845         // in case the player has autoswitch enabled do the following:
 846         // if the player is using their best weapon before items are given, they
 847         // probably want to switch to an even better weapon after items are given
 848
 849         if(CS(player).autoswitch)
 850         {
 851                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 852                 {
 853                         .entity weaponentity = weaponentities[slot];
 854                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 855                         {
 856                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 857                                         _switchweapon |= BIT(slot);
 858
 859                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 860                                         _switchweapon |= BIT(slot);
 861                         }
 862                 }
 863         }
 864
 865         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 866         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 867         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 868         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 869         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 870         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 871         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 872         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 873
 874         if (item.itemdef.instanceOfWeaponPickup)
 875         {
 876                 WepSet w;
 877                 w = item.weapons;
 878                 w &= ~player.weapons;
 879
 880                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 881                 {
 882                         pickedup = true;
 883                         FOREACH(Weapons, it != WEP_Null, {
 884                                 if(w & (it.m_wepset))
 885                                 {
 886                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 887                                         {
 888                                                 .entity weaponentity = weaponentities[slot];
 889                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 890                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 891                                         }
 892                                         W_GiveWeapon(player, it.m_id);
 893                                 }
 894                         });
 895                 }
 896         }
 897
 898         if (item.itemdef.instanceOfPowerup)
 899         {
 900                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 901                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 902                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 903                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 904         }
 905
 906         int its;
 907         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 908         {
 909                 pickedup = true;
 910                 player.items |= its;
 911                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 912         }
 913
 914         if (item.strength_finished)
 915         {
 916                 pickedup = true;
 917                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 918         }
 919         if (item.invincible_finished)
 920         {
 921                 pickedup = true;
 922                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 923         }
 924         if (item.superweapons_finished)
 925         {
 926                 pickedup = true;
 927                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 928         }
 929
 930 LABEL(skip)
 931
 932         // always eat teamed entities
 933         if(item.team)
 934                 pickedup = true;
 935
 936         if (!pickedup)
 937                 return 0;
 938
 939         // crude hack to enforce switching weapons
 940         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 941         {
 942                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 943                 {
 944                         .entity weaponentity = weaponentities[slot];
 945                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 946                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 947                 }
 948                 return 1;
 949         }
 950
 951         if(_switchweapon)
 952         {
 953                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 954                 {
 955                         .entity weaponentity = weaponentities[slot];
 956                         if(_switchweapon & BIT(slot))
 957                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 958                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 959                 }
 960         }
 961
 962         return 1;
 963 }
 964
 965 void Item_Touch(entity this, entity toucher)
 966 {
 967
 968         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 969         if (this.classname == "droppedweapon")
 970         {
 971                 if (ITEM_TOUCH_NEEDKILL())
 972                 {
 973                         delete(this);
 974                         return;
 975                 }
 976         }
 977
 978         if(!(toucher.flags & FL_PICKUPITEMS)
 979         || STAT(FROZEN, toucher)
 980         || IS_DEAD(toucher)
 981         || (this.solid != SOLID_TRIGGER)
 982         || (this.owner == toucher)
 983         || (time < this.item_spawnshieldtime)
 984         ) { return; }
 985
 986         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 987         {
 988                 case MUT_ITEMTOUCH_RETURN: { return; }
 989                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 990         }
 991
 992         toucher = M_ARGV(1, entity);
 993
 994         if (this.classname == "droppedweapon")
 995         {
 996                 this.strength_finished = max(0, this.strength_finished - time);
 997                 this.invincible_finished = max(0, this.invincible_finished - time);
 998                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 999         }
1000         entity it = this.itemdef;
1001         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
1002         if (!gave)
1003         {
1004                 if (this.classname == "droppedweapon")
1005                 {
1006                         // undo what we did above
1007                         this.strength_finished += time;
1008                         this.invincible_finished += time;
1009                         this.superweapons_finished += time;
1010                 }
1011                 return;
1012         }
1013
1014 LABEL(pickup)
1015
1016         toucher.last_pickup = time;
1017
1018         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1019         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
1020
1021         if (this.classname == "droppedweapon")
1022                 delete(this);
1023         else if (this.spawnshieldtime)
1024         {
1025                 entity e;
1026                 if(this.team)
1027                 {
1028                         RandomSelection_Init();
1029                         IL_EACH(g_items, it.team == this.team,
1030                         {
1031                                 if(it.itemdef) // is a registered item
1032                                 {
1033                                         Item_Show(it, -1);
1034                                         RandomSelection_AddEnt(it, it.cnt, 0);
1035                                 }
1036                         });
1037                         e = RandomSelection_chosen_ent;
1038                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
1039                 }
1040                 else
1041                         e = this;
1042                 Item_ScheduleRespawn(e);
1043         }
1044 }
1045
1046 void Item_Reset(entity this)
1047 {
1048         Item_Show(this, !this.state);
1049         setorigin(this, this.origin);
1050
1051         if (this.classname != "droppedweapon")
1052         {
1053                 setthink(this, Item_Think);
1054                 this.nextthink = time;
1055
1056                 if (this.waypointsprite_attached)
1057                         WaypointSprite_Kill(this.waypointsprite_attached);
1058
1059                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1060                         Item_ScheduleInitialRespawn(this);
1061         }
1062 }
1063
1064 void Item_FindTeam(entity this)
1065 {
1066         entity e;
1067
1068         if(this.effects & EF_NODRAW)
1069         {
1070                 // marker for item team search
1071                 LOG_TRACE("Initializing item team ", ftos(this.team));
1072                 RandomSelection_Init();
1073                 IL_EACH(g_items, it.team == this.team,
1074                 {
1075                         if(it.itemdef) // is a registered item
1076                                 RandomSelection_AddEnt(it, it.cnt, 0);
1077                 });
1078
1079                 e = RandomSelection_chosen_ent;
1080                 e.state = 0;
1081                 Item_Show(e, 1);
1082
1083                 IL_EACH(g_items, it.team == this.team,
1084                 {
1085                         if(it.itemdef) // is a registered item
1086                         {
1087                                 if(it != e)
1088                                 {
1089                                         // make it non-spawned
1090                                         Item_Show(it, -1);
1091                                         it.state = 1; // state 1 = initially hidden item, apparently
1092                                 }
1093                                 it.effects &= ~EF_NODRAW;
1094                         }
1095                 });
1096
1097                 Item_Reset(this);
1098         }
1099 }
1100
1101 // Savage: used for item garbage-collection
1102 void RemoveItem(entity this)
1103 {
1104         if(wasfreed(this) || !this) { return; }
1105         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1106         delete(this);
1107 }
1108
1109 // pickup evaluation functions
1110 // these functions decide how desirable an item is to the bots
1111
1112 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1113
1114 float weapon_pickupevalfunc(entity player, entity item)
1115 {
1116         // See if I have it already
1117         if(player.weapons & item.weapons)
1118         {
1119                 // If I can pick it up
1120                 if(!item.spawnshieldtime)
1121                         return 0;
1122                 return ammo_pickupevalfunc(player, item);
1123         }
1124
1125         // reduce weapon value if bot already got a good arsenal
1126         float c = 1;
1127         int weapons_value = 0;
1128         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1129                 weapons_value += it.bot_pickupbasevalue;
1130         });
1131         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1132
1133         return item.bot_pickupbasevalue * c;
1134 }
1135
1136 float ammo_pickupevalfunc(entity player, entity item)
1137 {
1138         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1139         entity wpn = NULL;
1140         float c = 0;
1141         float rating = 0;
1142
1143         // Detect needed ammo
1144         if(item.itemdef.instanceOfWeaponPickup)
1145         {
1146                 entity ammo = NULL;
1147                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1148                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1149                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1150                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1151                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1152                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1153
1154                 if(!ammo)
1155                         return 0;
1156                 wpn = item;
1157                 rating = ammo.m_botvalue;
1158         }
1159         else
1160         {
1161                 FOREACH(Weapons, it != WEP_Null, {
1162                         if(!(player.weapons & (it.m_wepset)))
1163                                 continue;
1164
1165                         switch(it.ammo_field)
1166                         {
1167                                 case ammo_shells:  need_shells  = true; break;
1168                                 case ammo_nails:   need_nails   = true; break;
1169                                 case ammo_rockets: need_rockets = true; break;
1170                                 case ammo_cells:   need_cells   = true; break;
1171                                 case ammo_plasma:  need_plasma  = true; break;
1172                                 case ammo_fuel:    need_fuel    = true; break;
1173                         }
1174                 });
1175                 rating = item.bot_pickupbasevalue;
1176         }
1177
1178         float noammorating = 0.5;
1179
1180         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1181                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1182
1183         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1184                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1185
1186         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1187                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1188
1189         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1190                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1191
1192         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1193                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1194
1195         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1196                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1197
1198         rating *= min(c, 2);
1199         if(wpn)
1200                 rating += wpn.bot_pickupbasevalue * 0.1;
1201         return rating;
1202 }
1203
1204 .int item_group;
1205 .int item_group_count;
1206 float healtharmor_pickupevalfunc(entity player, entity item)
1207 {
1208         float c = 0;
1209         float rating = item.bot_pickupbasevalue;
1210
1211         float itemarmor = item.armorvalue;
1212         float itemhealth = item.health;
1213
1214         if(item.item_group)
1215         {
1216                 itemarmor *= min(4, item.item_group_count);
1217                 itemhealth *= min(4, item.item_group_count);
1218         }
1219
1220         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1221                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1222
1223         if (itemhealth && (player.health < item.max_health))
1224                 c = itemhealth / max(1, player.health);
1225
1226         rating *= min(2, c);
1227         return rating;
1228 }
1229
1230 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1231 {
1232         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1233                 RemoveItem(this);
1234 }
1235
1236 void item_use(entity this, entity actor, entity trigger)
1237 {
1238         // use the touch function to handle collection
1239         gettouch(this)(this, actor);
1240 }
1241
1242 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1243 {
1244         string itemname = def.m_name;
1245         Model itemmodel = def.m_model;
1246     Sound pickupsound = def.m_sound;
1247         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1248         float pickupbasevalue = def.m_botvalue;
1249         int itemflags = def.m_itemflags;
1250
1251         startitem_failed = false;
1252
1253         this.item_model_ent = itemmodel;
1254     this.item_pickupsound_ent = pickupsound;
1255
1256     if(def.m_iteminit)
1257         def.m_iteminit(this);
1258
1259         if(!this.respawntime) // both need to be set
1260         {
1261                 this.respawntime = defaultrespawntime;
1262                 this.respawntimejitter = defaultrespawntimejitter;
1263         }
1264
1265         if(!this.pickup_anyway && def.m_pickupanyway)
1266                 this.pickup_anyway = def.m_pickupanyway();
1267
1268         int itemid = def.m_itemid;
1269         this.items = itemid;
1270         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1271         this.weapon = weaponid;
1272
1273         if(!this.fade_end)
1274         {
1275                 this.fade_start = autocvar_g_items_mindist;
1276                 this.fade_end = autocvar_g_items_maxdist;
1277         }
1278
1279         if(weaponid)
1280                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1281
1282         this.flags = FL_ITEM | itemflags;
1283         IL_PUSH(g_items, this);
1284
1285         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1286         {
1287                 startitem_failed = true;
1288                 delete(this);
1289                 return;
1290         }
1291
1292         // is it a dropped weapon?
1293         if (this.classname == "droppedweapon")
1294         {
1295                 this.reset = SUB_Remove;
1296                 // it's a dropped weapon
1297                 set_movetype(this, MOVETYPE_TOSS);
1298
1299                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1300                 setthink(this, RemoveItem);
1301                 this.nextthink = time + 20;
1302
1303                 this.takedamage = DAMAGE_YES;
1304                 this.event_damage = Item_Damage;
1305
1306                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1307                 {
1308                         // if item is worthless after a timer, have it expire then
1309                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1310                 }
1311
1312                 // don't drop if in a NODROP zone (such as lava)
1313                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1314                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1315                 {
1316                         startitem_failed = true;
1317                         delete(this);
1318                         return;
1319                 }
1320         }
1321         else
1322         {
1323                 if(!have_pickup_item(this))
1324                 {
1325                         startitem_failed = true;
1326                         delete(this);
1327                         return;
1328                 }
1329
1330                 if(this.angles != '0 0 0')
1331                         this.SendFlags |= ISF_ANGLES;
1332
1333                 this.reset = Item_Reset;
1334                 // it's a level item
1335                 if(this.spawnflags & 1)
1336                         this.noalign = 1;
1337                 if (this.noalign > 0)
1338                         set_movetype(this, MOVETYPE_NONE);
1339                 else
1340                         set_movetype(this, MOVETYPE_TOSS);
1341                 // do item filtering according to game mode and other things
1342                 if (this.noalign <= 0)
1343                 {
1344                         // first nudge it off the floor a little bit to avoid math errors
1345                         setorigin(this, this.origin + '0 0 1');
1346                         // set item size before we spawn a spawnfunc_waypoint
1347                         setsize(this, def.m_mins, def.m_maxs);
1348                         this.SendFlags |= ISF_SIZE;
1349                         // note droptofloor returns false if stuck/or would fall too far
1350                         if (!this.noalign)
1351                                 droptofloor(this);
1352                         waypoint_spawnforitem(this);
1353                 }
1354
1355                 /*
1356                  * can't do it that way, as it would break maps
1357                  * TODO make a target_give like entity another way, that perhaps has
1358                  * the weapon name in a key
1359                 if(this.targetname)
1360                 {
1361                         // target_give not yet supported; maybe later
1362                         print("removed targeted ", this.classname, "\n");
1363                         startitem_failed = true;
1364                         delete(this);
1365                         return;
1366                 }
1367                 */
1368
1369                 if(this.targetname != "" && (this.spawnflags & 16))
1370                         this.use = item_use;
1371
1372                 if(autocvar_spawn_debug >= 2)
1373                 {
1374             // why not flags & fl_item?
1375                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1376                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1377                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1378                 error("Mapper sucks.");
1379             });
1380                         this.is_item = true;
1381                 }
1382
1383                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1384
1385                 precache_model(this.model);
1386                 precache_sound(this.item_pickupsound);
1387
1388                 if (   def.instanceOfPowerup
1389                         || def.instanceOfWeaponPickup
1390                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1391                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1392                         || (itemid & (IT_KEY1 | IT_KEY2))
1393                 ) this.target = "###item###"; // for finding the nearest item using find()
1394
1395                 Item_ItemsTime_SetTime(this, 0);
1396         }
1397
1398         this.bot_pickup = true;
1399         this.bot_pickupevalfunc = pickupevalfunc;
1400         this.bot_pickupbasevalue = pickupbasevalue;
1401         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1402         this.netname = itemname;
1403         settouch(this, Item_Touch);
1404         setmodel(this, MDL_Null); // precision set below
1405         //this.effects |= EF_LOWPRECISION;
1406
1407         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1408
1409         this.SendFlags |= ISF_SIZE;
1410
1411         if (!(this.spawnflags & 1024)) {
1412                 if(def.instanceOfPowerup)
1413                         this.ItemStatus |= ITS_ANIMATE1;
1414
1415                 if(this.armorvalue || this.health)
1416                         this.ItemStatus |= ITS_ANIMATE2;
1417         }
1418
1419         if(def.instanceOfWeaponPickup)
1420         {
1421                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1422                         this.colormap = 1024; // color shirt=0 pants=0 grey
1423                 else
1424                         this.gravity = 1;
1425                 if (!(this.spawnflags & 1024))
1426                         this.ItemStatus |= ITS_ANIMATE1;
1427                 this.SendFlags |= ISF_COLORMAP;
1428         }
1429
1430         this.state = 0;
1431         if(this.team) // broken, no idea why.
1432         {
1433                 if(!this.cnt)
1434                         this.cnt = 1; // item probability weight
1435
1436                 this.effects |= EF_NODRAW; // marker for item team search
1437                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1438         }
1439         else
1440                 Item_Reset(this);
1441
1442         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1443
1444         // call this hook after everything else has been done
1445         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1446         {
1447                 startitem_failed = true;
1448                 delete(this);
1449                 return;
1450         }
1451
1452         setItemGroup(this);
1453 }
1454
1455 void StartItem(entity this, GameItem def)
1456 {
1457     _StartItem(
1458         this,
1459         this.itemdef = def,
1460         def.m_respawntime(), // defaultrespawntime
1461         def.m_respawntimejitter() // defaultrespawntimejitter
1462         );
1463 }
1464
1465 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1466 int group_count = 1;
1467
1468 void setItemGroup(entity this)
1469 {
1470         if(!IS_SMALL(this.itemdef))
1471                 return;
1472
1473         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1474         {
1475                 if(!this.item_group)
1476                 {
1477                         if(!it.item_group)
1478                         {
1479                                 it.item_group = group_count;
1480                                 group_count++;
1481                         }
1482                         this.item_group = it.item_group;
1483                 }
1484                 else // spawning item is already part of a item_group X
1485                 {
1486                         if(!it.item_group)
1487                                 it.item_group = this.item_group;
1488                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1489                         {
1490                                 int grY = it.item_group;
1491                                 // move all items of item_group Y to item_group X
1492                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1493                                 {
1494                                         if(it.item_group == grY)
1495                                                 it.item_group = this.item_group;
1496                                 });
1497                         }
1498                 }
1499         });
1500 }
1501
1502 void setItemGroupCount()
1503 {
1504         for (int k = 1; k <= group_count; k++)
1505         {
1506                 int count = 0;
1507                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1508                 if (count)
1509                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1510         }
1511 }
1512
1513 spawnfunc(item_rockets)
1514 {
1515     StartItem(this, ITEM_Rockets);
1516 }
1517
1518 spawnfunc(item_bullets)
1519 {
1520         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1521            (this.classname != "droppedweapon"))
1522         {
1523                 weaponswapping = true;
1524                 spawnfunc_item_shells(this);
1525                 weaponswapping = false;
1526                 return;
1527         }
1528
1529     StartItem(this, ITEM_Bullets);
1530 }
1531
1532 spawnfunc(item_cells)
1533 {
1534         StartItem(this, ITEM_Cells);
1535 }
1536
1537 spawnfunc(item_plasma)
1538 {
1539         StartItem(this, ITEM_Plasma);
1540 }
1541
1542 spawnfunc(item_shells)
1543 {
1544         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1545            (this.classname != "droppedweapon"))
1546         {
1547                 weaponswapping = true;
1548                 spawnfunc_item_bullets(this);
1549                 weaponswapping = false;
1550                 return;
1551         }
1552
1553         StartItem(this, ITEM_Shells);
1554 }
1555
1556 spawnfunc(item_armor_small)
1557 {
1558         StartItem(this, ITEM_ArmorSmall);
1559 }
1560
1561 spawnfunc(item_armor_medium)
1562 {
1563         StartItem(this, ITEM_ArmorMedium);
1564 }
1565
1566 spawnfunc(item_armor_big)
1567 {
1568         StartItem(this, ITEM_ArmorBig);
1569 }
1570
1571 spawnfunc(item_armor_mega)
1572 {
1573         StartItem(this, ITEM_ArmorMega);
1574 }
1575
1576 spawnfunc(item_health_small)
1577 {
1578         StartItem(this, ITEM_HealthSmall);
1579 }
1580
1581 spawnfunc(item_health_medium)
1582 {
1583     StartItem(this, ITEM_HealthMedium);
1584 }
1585
1586 spawnfunc(item_health_big)
1587 {
1588         StartItem(this, ITEM_HealthBig);
1589 }
1590
1591 spawnfunc(item_health_mega)
1592 {
1593     StartItem(this, ITEM_HealthMega);
1594 }
1595
1596 // support old misnamed entities
1597 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1598 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1599 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1600 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1601 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1602 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1603 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1604
1605 spawnfunc(item_strength)
1606 {
1607         StartItem(this, ITEM_Strength);
1608 }
1609
1610 spawnfunc(item_invincible)
1611 {
1612         StartItem(this, ITEM_Shield);
1613 }
1614
1615 // compatibility:
1616 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1617
1618 void target_items_use(entity this, entity actor, entity trigger)
1619 {
1620         if(actor.classname == "droppedweapon")
1621         {
1622                 EXACTTRIGGER_TOUCH(this, trigger);
1623                 delete(actor);
1624                 return;
1625         }
1626
1627         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1628                 return;
1629
1630         if(trigger.solid == SOLID_TRIGGER)
1631         {
1632                 EXACTTRIGGER_TOUCH(this, trigger);
1633         }
1634
1635         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1636         {
1637                 delete(it);
1638         });
1639
1640         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1641                 centerprint(actor, this.message);
1642 }
1643
1644 spawnfunc(target_items)
1645 {
1646         int n;
1647         string s;
1648
1649         this.use = target_items_use;
1650         if(!this.strength_finished)
1651                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1652         if(!this.invincible_finished)
1653                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1654         if(!this.superweapons_finished)
1655                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1656
1657         n = tokenize_console(this.netname);
1658         if(argv(0) == "give")
1659         {
1660                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1661         }
1662         else
1663         {
1664                 for(int j = 0; j < n; ++j)
1665                 {
1666                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1667                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1668                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1669                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1670                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1671                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1672                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1673                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1674                         else
1675                         {
1676                                 FOREACH(Buffs, it != BUFF_Null,
1677                                 {
1678                                         s = Buff_UndeprecateName(argv(j));
1679                                         if(s == it.m_name)
1680                                         {
1681                                                 this.buffs |= (it.m_itemid);
1682                                                 break;
1683                                         }
1684                                 });
1685                                 FOREACH(Weapons, it != WEP_Null, {
1686                                         s = W_UndeprecateName(argv(j));
1687                                         if(s == it.netname)
1688                                         {
1689                                                 this.weapons |= (it.m_wepset);
1690                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1691                                                         it.wr_init(it);
1692                                                 break;
1693                                         }
1694                                 });
1695                         }
1696                 }
1697
1698                 string itemprefix, valueprefix;
1699                 if(this.spawnflags == 0)
1700                 {
1701                         itemprefix = "";
1702                         valueprefix = "";
1703                 }
1704                 else if(this.spawnflags == 1)
1705                 {
1706                         itemprefix = "max ";
1707                         valueprefix = "max ";
1708                 }
1709                 else if(this.spawnflags == 2)
1710                 {
1711                         itemprefix = "min ";
1712                         valueprefix = "min ";
1713                 }
1714                 else if(this.spawnflags == 4)
1715                 {
1716                         itemprefix = "minus ";
1717                         valueprefix = "max ";
1718                 }
1719                 else
1720                 {
1721                         error("invalid spawnflags");
1722                         itemprefix = valueprefix = string_null;
1723                 }
1724
1725                 this.netname = "";
1726                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1727                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1728                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1729                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1730                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1731                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1732                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1733                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1734                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1735                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1736                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1737                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1738                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1739                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1740                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1741                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1742                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1743         }
1744         this.netname = strzone(this.netname);
1745         //print(this.netname, "\n");
1746
1747         n = tokenize_console(this.netname);
1748         for(int j = 0; j < n; ++j)
1749         {
1750                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1751             it.wr_init(it);
1752             break;
1753                 });
1754         }
1755 }
1756
1757 spawnfunc(item_fuel)
1758 {
1759         StartItem(this, ITEM_JetpackFuel);
1760 }
1761
1762 spawnfunc(item_fuel_regen)
1763 {
1764         if(start_items & ITEM_JetpackRegen.m_itemid)
1765         {
1766                 spawnfunc_item_fuel(this);
1767                 return;
1768         }
1769         StartItem(this, ITEM_JetpackRegen);
1770 }
1771
1772 spawnfunc(item_jetpack)
1773 {
1774         if(start_items & ITEM_Jetpack.m_itemid)
1775         {
1776                 spawnfunc_item_fuel(this);
1777                 return;
1778         }
1779         StartItem(this, ITEM_Jetpack);
1780 }
1781
1782 float GiveWeapon(entity e, float wpn, float op, float val)
1783 {
1784         WepSet v0, v1;
1785         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1786         v0 = (e.weapons & s);
1787         switch(op)
1788         {
1789                 case OP_SET:
1790                         if(val > 0)
1791                                 e.weapons |= s;
1792                         else
1793                                 e.weapons &= ~s;
1794                         break;
1795                 case OP_MIN:
1796                 case OP_PLUS:
1797                         if(val > 0)
1798                                 e.weapons |= s;
1799                         break;
1800                 case OP_MAX:
1801                         if(val <= 0)
1802                                 e.weapons &= ~s;
1803                         break;
1804                 case OP_MINUS:
1805                         if(val > 0)
1806                                 e.weapons &= ~s;
1807                         break;
1808         }
1809         v1 = (e.weapons & s);
1810         return (v0 != v1);
1811 }
1812
1813 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1814 {
1815         bool had_buff = (e.buffs & thebuff.m_itemid);
1816         switch(op)
1817         {
1818                 case OP_SET:
1819                         if(val > 0)
1820                                 e.buffs |= thebuff.m_itemid;
1821                         else
1822                                 e.buffs &= ~thebuff.m_itemid;
1823                         break;
1824                 case OP_MIN:
1825                 case OP_PLUS:
1826                         if(val > 0)
1827                                 e.buffs |= thebuff.m_itemid;
1828                         break;
1829                 case OP_MAX:
1830                         if(val <= 0)
1831                                 e.buffs &= ~thebuff.m_itemid;
1832                         break;
1833                 case OP_MINUS:
1834                         if(val > 0)
1835                                 e.buffs &= ~thebuff.m_itemid;
1836                         break;
1837         }
1838         bool have_buff = (e.buffs & thebuff.m_itemid);
1839         return (had_buff != have_buff);
1840 }
1841
1842 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1843 {
1844         if(v1 == v0)
1845                 return;
1846         if(v1 <= v0 - t)
1847         {
1848                 if(snd_decr != NULL)
1849                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1850         }
1851         else if(v0 >= v0 + t)
1852         {
1853                 if(snd_incr != NULL)
1854                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1855         }
1856 }
1857
1858 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1859 {
1860         if(v0 < v1)
1861                 e.(rotfield) = max(e.(rotfield), time + rottime);
1862         else if(v0 > v1)
1863                 e.(regenfield) = max(e.(regenfield), time + regentime);
1864 }
1865 float GiveItems(entity e, float beginarg, float endarg)
1866 {
1867         float got, i, val, op;
1868         string cmd;
1869
1870         val = 999;
1871         op = OP_SET;
1872
1873         got = 0;
1874
1875         int _switchweapon = 0;
1876
1877         if(CS(e).autoswitch)
1878         {
1879                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1880                 {
1881                         .entity weaponentity = weaponentities[slot];
1882                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1883                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1884                                 _switchweapon |= BIT(slot);
1885                 }
1886         }
1887
1888         e.strength_finished = max(0, e.strength_finished - time);
1889         e.invincible_finished = max(0, e.invincible_finished - time);
1890         e.superweapons_finished = max(0, e.superweapons_finished - time);
1891
1892         PREGIVE(e, items);
1893         PREGIVE_WEAPONS(e);
1894         PREGIVE(e, strength_finished);
1895         PREGIVE(e, invincible_finished);
1896         PREGIVE(e, superweapons_finished);
1897         PREGIVE(e, ammo_nails);
1898         PREGIVE(e, ammo_cells);
1899         PREGIVE(e, ammo_plasma);
1900         PREGIVE(e, ammo_shells);
1901         PREGIVE(e, ammo_rockets);
1902         PREGIVE(e, ammo_fuel);
1903         PREGIVE(e, armorvalue);
1904         PREGIVE(e, health);
1905
1906         for(i = beginarg; i < endarg; ++i)
1907         {
1908                 cmd = argv(i);
1909
1910                 if(cmd == "0" || stof(cmd))
1911                 {
1912                         val = stof(cmd);
1913                         continue;
1914                 }
1915                 switch(cmd)
1916                 {
1917                         case "no":
1918                                 op = OP_MAX;
1919                                 val = 0;
1920                                 continue;
1921                         case "max":
1922                                 op = OP_MAX;
1923                                 continue;
1924                         case "min":
1925                                 op = OP_MIN;
1926                                 continue;
1927                         case "plus":
1928                                 op = OP_PLUS;
1929                                 continue;
1930                         case "minus":
1931                                 op = OP_MINUS;
1932                                 continue;
1933                         case "ALL":
1934                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1935                                 got += GiveValue(e, strength_finished, op, val);
1936                                 got += GiveValue(e, invincible_finished, op, val);
1937                                 got += GiveValue(e, superweapons_finished, op, val);
1938                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1939                         case "all":
1940                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1941                                 got += GiveValue(e, health, op, val);
1942                                 got += GiveValue(e, armorvalue, op, val);
1943                         case "allweapons":
1944                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1945                         //case "allbuffs": // all buffs makes a player god, do not want!
1946                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1947                         case "allammo":
1948                                 got += GiveValue(e, ammo_cells, op, val);
1949                                 got += GiveValue(e, ammo_plasma, op, val);
1950                                 got += GiveValue(e, ammo_shells, op, val);
1951                                 got += GiveValue(e, ammo_nails, op, val);
1952                                 got += GiveValue(e, ammo_rockets, op, val);
1953                                 got += GiveValue(e, ammo_fuel, op, val);
1954                                 break;
1955                         case "unlimited_ammo":
1956                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1957                                 break;
1958                         case "unlimited_weapon_ammo":
1959                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1960                                 break;
1961                         case "unlimited_superweapons":
1962                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1963                                 break;
1964                         case "jetpack":
1965                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1966                                 break;
1967                         case "fuel_regen":
1968                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1969                                 break;
1970                         case "strength":
1971                                 got += GiveValue(e, strength_finished, op, val);
1972                                 break;
1973                         case "invincible":
1974                                 got += GiveValue(e, invincible_finished, op, val);
1975                                 break;
1976                         case "superweapons":
1977                                 got += GiveValue(e, superweapons_finished, op, val);
1978                                 break;
1979                         case "cells":
1980                                 got += GiveValue(e, ammo_cells, op, val);
1981                                 break;
1982                         case "plasma":
1983                                 got += GiveValue(e, ammo_plasma, op, val);
1984                                 break;
1985                         case "shells":
1986                                 got += GiveValue(e, ammo_shells, op, val);
1987                                 break;
1988                         case "nails":
1989                         case "bullets":
1990                                 got += GiveValue(e, ammo_nails, op, val);
1991                                 break;
1992                         case "rockets":
1993                                 got += GiveValue(e, ammo_rockets, op, val);
1994                                 break;
1995                         case "health":
1996                                 got += GiveValue(e, health, op, val);
1997                                 break;
1998                         case "armor":
1999                                 got += GiveValue(e, armorvalue, op, val);
2000                                 break;
2001                         case "fuel":
2002                                 got += GiveValue(e, ammo_fuel, op, val);
2003                                 break;
2004                         default:
2005                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
2006                                 {
2007                                         got += GiveBuff(e, it, op, val);
2008                                         break;
2009                                 });
2010                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
2011                     got += GiveWeapon(e, it.m_id, op, val);
2012                     break;
2013                                 });
2014                                 break;
2015                 }
2016                 val = 999;
2017                 op = OP_SET;
2018         }
2019
2020         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
2021         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
2022         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
2023         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
2024         FOREACH(Weapons, it != WEP_Null, {
2025                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
2026                 if(!(save_weapons & (it.m_wepset)))
2027                         if(e.weapons & (it.m_wepset))
2028                                 it.wr_init(it);
2029         });
2030         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
2031         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
2032         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
2033         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
2034         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
2035         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
2036         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
2037         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
2038         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
2039         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
2040         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
2041
2042         if(e.superweapons_finished <= 0)
2043                 if(e.weapons & WEPSET_SUPERWEAPONS)
2044                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2045
2046         if(e.strength_finished <= 0)
2047                 e.strength_finished = 0;
2048         else
2049                 e.strength_finished += time;
2050         if(e.invincible_finished <= 0)
2051                 e.invincible_finished = 0;
2052         else
2053                 e.invincible_finished += time;
2054         if(e.superweapons_finished <= 0)
2055                 e.superweapons_finished = 0;
2056         else
2057                 e.superweapons_finished += time;
2058
2059         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2060         {
2061                 .entity weaponentity = weaponentities[slot];
2062                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2063                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2064                         _switchweapon |= BIT(slot);
2065         }
2066
2067         if(_switchweapon)
2068         {
2069                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2070                 {
2071                         .entity weaponentity = weaponentities[slot];
2072                         if(_switchweapon & BIT(slot))
2073                         {
2074                                 Weapon wep = w_getbestweapon(e, weaponentity);
2075                                 if(wep != e.(weaponentity).m_switchweapon)
2076                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2077                         }
2078                 }
2079         }
2080
2081         return got;
2082 }
2083 #endif