qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637 void Item_ScheduleRespawn(entity e)
 638 {
 639         if(e.respawntime > 0)
 640         {
 641                 Item_Show(e, 0);
 642
 643                 CheckAllowedTeams(NULL);
 644                 GetTeamCounts(NULL);
 645                 int players = 0;
 646                 if (c1 != -1) players += c1;
 647                 if (c2 != -1) players += c2;
 648                 if (c3 != -1) players += c3;
 649                 if (c4 != -1) players += c4;
 650                 float adjusted_respawntime;
 651                 if (players >= 2) {
 652                         float a = autocvar_g_pickup_respawntime_scaling_reciprocal;
 653                         float b = autocvar_g_pickup_respawntime_scaling_offset;
 654                         float c = autocvar_g_pickup_respawntime_scaling_linear;
 655                         adjusted_respawntime = e.respawntime * (a / (players + b) + c);
 656                 } else {
 657                         adjusted_respawntime = e.respawntime;
 658                 }
 659                 //LOG_INFOF("item %s will respawn in %f\n", e.classname, adjusted_respawntime);
 660                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 661                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 662                 Item_ScheduleRespawnIn(e, actual_time);
 663         }
 664         else // if respawntime is -1, this item does not respawn
 665                 Item_Show(e, -1);
 666 }
 667
 668 void Item_ScheduleInitialRespawn(entity e)
 669 {
 670         Item_Show(e, 0);
 671         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 672 }
 673
 674 void GivePlayerResource(entity player, .float resource_type, float amount)
 675 {
 676         if (amount == 0)
 677         {
 678                 return;
 679         }
 680         switch (resource_type)
 681         {
 682                 case health:
 683                 {
 684                         // Ugly hack. We do not check if health goes beyond hard limit since
 685                         // currently it is done in player_regen. We need to bring back this
 686                         // check when other code is ported to this function.
 687                         player.health = bound(player.health, player.health + amount,
 688                                 autocvar_g_balance_health_limit);
 689                         // Correct code:
 690                         //player.health = bound(player.health, player.health + amount,
 691                         //      min(autocvar_g_balance_health_limit,
 692                         //      RESOURCE_AMOUNT_HARD_LIMIT));
 693                         player.pauserothealth_finished = max(player.pauserothealth_finished,
 694                                 time + autocvar_g_balance_pause_health_rot);
 695                         return;
 696                 }
 697                 case armorvalue:
 698                 {
 699                         // Ugly hack. We do not check if armor goes beyond hard limit since
 700                         // currently it is done in player_regen. We need to bring back this
 701                         // check when other code is ported to this function.
 702                         player.armorvalue = bound(player.armorvalue, player.armorvalue +
 703                                 amount, autocvar_g_balance_armor_limit);
 704                         // Correct code:
 705                         //player.armorvalue = bound(player.armorvalue, player.armorvalue +
 706                         //      amount, min(autocvar_g_balance_armor_limit,
 707                         //      RESOURCE_AMOUNT_HARD_LIMIT));
 708                         player.pauserotarmor_finished = max(player.pauserotarmor_finished,
 709                                 time + autocvar_g_balance_pause_armor_rot);
 710                         return;
 711                 }
 712                 case ammo_shells:
 713                 case ammo_nails:
 714                 case ammo_rockets:
 715                 case ammo_cells:
 716                 case ammo_plasma:
 717                 {
 718                         GivePlayerAmmo(player, resource_type, amount);
 719                         return;
 720                 }
 721                 case ammo_fuel:
 722                 {
 723                         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel +
 724                                 amount, min(g_pickup_fuel_max, RESOURCE_AMOUNT_HARD_LIMIT));
 725                         player.pauserotfuel_finished = max(player.pauserotfuel_finished,
 726                                 time + autocvar_g_balance_pause_fuel_rot);
 727                         return;
 728                 }
 729         }
 730 }
 731
 732 void GivePlayerHealth(entity player, float amount)
 733 {
 734         GivePlayerResource(player, health, amount);
 735 }
 736
 737 void GivePlayerArmor(entity player, float amount)
 738 {
 739         GivePlayerResource(player, armorvalue, amount);
 740 }
 741
 742 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 743 {
 744         if (amount == 0)
 745         {
 746                 return;
 747         }
 748         float maxvalue = RESOURCE_AMOUNT_HARD_LIMIT;
 749         switch (ammotype)
 750         {
 751                 case ammo_shells:
 752                 {
 753                         maxvalue = g_pickup_shells_max;
 754                         break;
 755                 }
 756                 case ammo_cells:
 757                 {
 758                         maxvalue = g_pickup_cells_max;
 759                         break;
 760                 }
 761                 case ammo_rockets:
 762                 {
 763                         maxvalue = g_pickup_rockets_max;
 764                         break;
 765                 }
 766                 case ammo_plasma:
 767                 {
 768                         maxvalue = g_pickup_plasma_max;
 769                         break;
 770                 }
 771                 case ammo_nails:
 772                 {
 773                         maxvalue = g_pickup_nails_max;
 774                         break;
 775                 }
 776         }
 777         player.(ammotype) = min(player.(ammotype) + amount,
 778                 min(maxvalue, RESOURCE_AMOUNT_HARD_LIMIT));
 779 }
 780
 781 void GivePlayerFuel(entity player, float amount)
 782 {
 783         GivePlayerResource(player, ammo_fuel, amount);
 784 }
 785
 786 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
 787 {
 788         if (!item.(ammotype))
 789                 return false;
 790
 791         if (item.spawnshieldtime)
 792         {
 793                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 794                 {
 795                         float amount = item.(ammotype);
 796                         if ((player.(ammotype) + amount) > ammomax)
 797                         {
 798                                 amount = ammomax - player.(ammotype);
 799                         }
 800                         GivePlayerResource(player, ammotype, amount);
 801                         return true;
 802                 }
 803         }
 804         else if(g_weapon_stay == 2)
 805         {
 806                 float mi = min(item.(ammotype), ammomax);
 807                 if (player.(ammotype) < mi)
 808                 {
 809                         GivePlayerResource(player, ammotype, mi - player.(ammotype));
 810                 }
 811                 return true;
 812         }
 813         return false;
 814 }
 815
 816 float Item_GiveTo(entity item, entity player)
 817 {
 818         float pickedup;
 819
 820         // if nothing happens to player, just return without taking the item
 821         pickedup = false;
 822         int _switchweapon = 0;
 823         // in case the player has autoswitch enabled do the following:
 824         // if the player is using their best weapon before items are given, they
 825         // probably want to switch to an even better weapon after items are given
 826
 827         if(CS(player).autoswitch)
 828         {
 829                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830                 {
 831                         .entity weaponentity = weaponentities[slot];
 832                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 833                         {
 834                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 835                                         _switchweapon |= BIT(slot);
 836
 837                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 838                                         _switchweapon |= BIT(slot);
 839                         }
 840                 }
 841         }
 842         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
 843         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
 844         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
 845         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
 846         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
 847         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
 848         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
 849         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 850         if (item.itemdef.instanceOfWeaponPickup)
 851         {
 852                 WepSet w;
 853                 w = item.weapons;
 854                 w &= ~player.weapons;
 855
 856                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 857                 {
 858                         pickedup = true;
 859                         FOREACH(Weapons, it != WEP_Null, {
 860                                 if(w & (it.m_wepset))
 861                                 {
 862                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 863                                         {
 864                                                 .entity weaponentity = weaponentities[slot];
 865                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 866                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 867                                         }
 868                                         W_GiveWeapon(player, it.m_id);
 869                                 }
 870                         });
 871                 }
 872         }
 873
 874         if (item.itemdef.instanceOfPowerup)
 875         {
 876                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 877                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 878                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 879                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 880         }
 881
 882         int its;
 883         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 884         {
 885                 pickedup = true;
 886                 player.items |= its;
 887                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 888         }
 889
 890         if (item.strength_finished)
 891         {
 892                 pickedup = true;
 893                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 894         }
 895         if (item.invincible_finished)
 896         {
 897                 pickedup = true;
 898                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 899         }
 900         if (item.superweapons_finished)
 901         {
 902                 pickedup = true;
 903                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 904         }
 905
 906 LABEL(skip)
 907
 908         // always eat teamed entities
 909         if(item.team)
 910                 pickedup = true;
 911
 912         if (!pickedup)
 913                 return 0;
 914
 915         // crude hack to enforce switching weapons
 916         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 917         {
 918                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 919                 {
 920                         .entity weaponentity = weaponentities[slot];
 921                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 922                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 923                 }
 924                 return 1;
 925         }
 926
 927         if(_switchweapon)
 928         {
 929                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 930                 {
 931                         .entity weaponentity = weaponentities[slot];
 932                         if(_switchweapon & BIT(slot))
 933                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 934                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 935                 }
 936         }
 937
 938         return 1;
 939 }
 940
 941 void Item_Touch(entity this, entity toucher)
 942 {
 943
 944         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 945         if (this.classname == "droppedweapon")
 946         {
 947                 if (ITEM_TOUCH_NEEDKILL())
 948                 {
 949                         delete(this);
 950                         return;
 951                 }
 952         }
 953
 954         if(!(toucher.flags & FL_PICKUPITEMS)
 955         || STAT(FROZEN, toucher)
 956         || IS_DEAD(toucher)
 957         || (this.solid != SOLID_TRIGGER)
 958         || (this.owner == toucher)
 959         || (time < this.item_spawnshieldtime)
 960         ) { return; }
 961
 962         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 963         {
 964                 case MUT_ITEMTOUCH_RETURN: { return; }
 965                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 966         }
 967
 968         toucher = M_ARGV(1, entity);
 969
 970         if (this.classname == "droppedweapon")
 971         {
 972                 this.strength_finished = max(0, this.strength_finished - time);
 973                 this.invincible_finished = max(0, this.invincible_finished - time);
 974                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 975         }
 976         entity it = this.itemdef;
 977         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 978         if (!gave)
 979         {
 980                 if (this.classname == "droppedweapon")
 981                 {
 982                         // undo what we did above
 983                         this.strength_finished += time;
 984                         this.invincible_finished += time;
 985                         this.superweapons_finished += time;
 986                 }
 987                 return;
 988         }
 989
 990 LABEL(pickup)
 991
 992         toucher.last_pickup = time;
 993
 994         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 995         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 996
 997         if (this.classname == "droppedweapon")
 998                 delete(this);
 999         else if (this.spawnshieldtime)
1000         {
1001                 entity e;
1002                 if(this.team)
1003                 {
1004                         RandomSelection_Init();
1005                         IL_EACH(g_items, it.team == this.team,
1006                         {
1007                                 if(it.itemdef) // is a registered item
1008                                 {
1009                                         Item_Show(it, -1);
1010                                         RandomSelection_AddEnt(it, it.cnt, 0);
1011                                 }
1012                         });
1013                         e = RandomSelection_chosen_ent;
1014                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
1015                 }
1016                 else
1017                         e = this;
1018                 Item_ScheduleRespawn(e);
1019         }
1020 }
1021
1022 void Item_Reset(entity this)
1023 {
1024         Item_Show(this, !this.state);
1025         setorigin(this, this.origin);
1026
1027         if (this.classname != "droppedweapon")
1028         {
1029                 setthink(this, Item_Think);
1030                 this.nextthink = time;
1031
1032                 if (this.waypointsprite_attached)
1033                         WaypointSprite_Kill(this.waypointsprite_attached);
1034
1035                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1036                         Item_ScheduleInitialRespawn(this);
1037         }
1038 }
1039
1040 void Item_FindTeam(entity this)
1041 {
1042         entity e;
1043
1044         if(this.effects & EF_NODRAW)
1045         {
1046                 // marker for item team search
1047                 LOG_TRACE("Initializing item team ", ftos(this.team));
1048                 RandomSelection_Init();
1049                 IL_EACH(g_items, it.team == this.team,
1050                 {
1051                         if(it.itemdef) // is a registered item
1052                                 RandomSelection_AddEnt(it, it.cnt, 0);
1053                 });
1054
1055                 e = RandomSelection_chosen_ent;
1056                 e.state = 0;
1057                 Item_Show(e, 1);
1058
1059                 IL_EACH(g_items, it.team == this.team,
1060                 {
1061                         if(it.itemdef) // is a registered item
1062                         {
1063                                 if(it != e)
1064                                 {
1065                                         // make it non-spawned
1066                                         Item_Show(it, -1);
1067                                         it.state = 1; // state 1 = initially hidden item, apparently
1068                                 }
1069                                 it.effects &= ~EF_NODRAW;
1070                         }
1071                 });
1072
1073                 Item_Reset(this);
1074         }
1075 }
1076
1077 // Savage: used for item garbage-collection
1078 void RemoveItem(entity this)
1079 {
1080         if(wasfreed(this) || !this) { return; }
1081         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1082         delete(this);
1083 }
1084
1085 // pickup evaluation functions
1086 // these functions decide how desirable an item is to the bots
1087
1088 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1089
1090 float weapon_pickupevalfunc(entity player, entity item)
1091 {
1092         // See if I have it already
1093         if(player.weapons & item.weapons)
1094         {
1095                 // If I can pick it up
1096                 if(!item.spawnshieldtime)
1097                         return 0;
1098                 return ammo_pickupevalfunc(player, item);
1099         }
1100
1101         // reduce weapon value if bot already got a good arsenal
1102         float c = 1;
1103         int weapons_value = 0;
1104         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1105                 weapons_value += it.bot_pickupbasevalue;
1106         });
1107         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1108
1109         return item.bot_pickupbasevalue * c;
1110 }
1111
1112 float ammo_pickupevalfunc(entity player, entity item)
1113 {
1114         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1115         entity wpn = NULL;
1116         float c = 0;
1117         float rating = 0;
1118
1119         // Detect needed ammo
1120         if(item.itemdef.instanceOfWeaponPickup)
1121         {
1122                 entity ammo = NULL;
1123                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1124                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1125                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1126                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1127                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1128                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1129
1130                 if(!ammo)
1131                         return 0;
1132                 wpn = item;
1133                 rating = ammo.m_botvalue;
1134         }
1135         else
1136         {
1137                 FOREACH(Weapons, it != WEP_Null, {
1138                         if(!(player.weapons & (it.m_wepset)))
1139                                 continue;
1140
1141                         switch(it.ammo_field)
1142                         {
1143                                 case ammo_shells:  need_shells  = true; break;
1144                                 case ammo_nails:   need_nails   = true; break;
1145                                 case ammo_rockets: need_rockets = true; break;
1146                                 case ammo_cells:   need_cells   = true; break;
1147                                 case ammo_plasma:  need_plasma  = true; break;
1148                                 case ammo_fuel:    need_fuel    = true; break;
1149                         }
1150                 });
1151                 rating = item.bot_pickupbasevalue;
1152         }
1153
1154         float noammorating = 0.5;
1155
1156         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1157                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1158
1159         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1160                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1161
1162         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1163                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1164
1165         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1166                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1167
1168         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1169                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1170
1171         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1172                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1173
1174         rating *= min(c, 2);
1175         if(wpn)
1176                 rating += wpn.bot_pickupbasevalue * 0.1;
1177         return rating;
1178 }
1179
1180 .int item_group;
1181 .int item_group_count;
1182 float healtharmor_pickupevalfunc(entity player, entity item)
1183 {
1184         float c = 0;
1185         float rating = item.bot_pickupbasevalue;
1186
1187         float itemarmor = item.armorvalue;
1188         float itemhealth = item.health;
1189
1190         if(item.item_group)
1191         {
1192                 itemarmor *= min(4, item.item_group_count);
1193                 itemhealth *= min(4, item.item_group_count);
1194         }
1195
1196         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1197                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1198
1199         if (itemhealth && (player.health < item.max_health))
1200                 c = itemhealth / max(1, player.health);
1201
1202         rating *= min(2, c);
1203         return rating;
1204 }
1205
1206 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1207 {
1208         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1209                 RemoveItem(this);
1210 }
1211
1212 void item_use(entity this, entity actor, entity trigger)
1213 {
1214         // use the touch function to handle collection
1215         gettouch(this)(this, actor);
1216 }
1217
1218 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1219 {
1220         string itemname = def.m_name;
1221         Model itemmodel = def.m_model;
1222     Sound pickupsound = def.m_sound;
1223         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1224         float pickupbasevalue = def.m_botvalue;
1225         int itemflags = def.m_itemflags;
1226
1227         startitem_failed = false;
1228
1229         this.item_model_ent = itemmodel;
1230     this.item_pickupsound_ent = pickupsound;
1231
1232     if(def.m_iteminit)
1233         def.m_iteminit(this);
1234
1235         if(!this.respawntime) // both need to be set
1236         {
1237                 this.respawntime = defaultrespawntime;
1238                 this.respawntimejitter = defaultrespawntimejitter;
1239         }
1240
1241         if(!this.pickup_anyway && def.m_pickupanyway)
1242                 this.pickup_anyway = def.m_pickupanyway();
1243
1244         int itemid = def.m_itemid;
1245         this.items = itemid;
1246         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1247         this.weapon = weaponid;
1248
1249         if(!this.fade_end)
1250         {
1251                 this.fade_start = autocvar_g_items_mindist;
1252                 this.fade_end = autocvar_g_items_maxdist;
1253         }
1254
1255         if(weaponid)
1256                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1257
1258         this.flags = FL_ITEM | itemflags;
1259         IL_PUSH(g_items, this);
1260
1261         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1262         {
1263                 startitem_failed = true;
1264                 delete(this);
1265                 return;
1266         }
1267
1268         // is it a dropped weapon?
1269         if (this.classname == "droppedweapon")
1270         {
1271                 this.reset = SUB_Remove;
1272                 // it's a dropped weapon
1273                 set_movetype(this, MOVETYPE_TOSS);
1274
1275                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1276                 setthink(this, RemoveItem);
1277                 this.nextthink = time + 20;
1278
1279                 this.takedamage = DAMAGE_YES;
1280                 this.event_damage = Item_Damage;
1281
1282                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1283                 {
1284                         // if item is worthless after a timer, have it expire then
1285                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1286                 }
1287
1288                 // don't drop if in a NODROP zone (such as lava)
1289                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1290                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1291                 {
1292                         startitem_failed = true;
1293                         delete(this);
1294                         return;
1295                 }
1296         }
1297         else
1298         {
1299                 if(!have_pickup_item(this))
1300                 {
1301                         startitem_failed = true;
1302                         delete(this);
1303                         return;
1304                 }
1305
1306                 if(this.angles != '0 0 0')
1307                         this.SendFlags |= ISF_ANGLES;
1308
1309                 this.reset = Item_Reset;
1310                 // it's a level item
1311                 if(this.spawnflags & 1)
1312                         this.noalign = 1;
1313                 if (this.noalign > 0)
1314                         set_movetype(this, MOVETYPE_NONE);
1315                 else
1316                         set_movetype(this, MOVETYPE_TOSS);
1317                 // do item filtering according to game mode and other things
1318                 if (this.noalign <= 0)
1319                 {
1320                         // first nudge it off the floor a little bit to avoid math errors
1321                         setorigin(this, this.origin + '0 0 1');
1322                         // set item size before we spawn a spawnfunc_waypoint
1323                         setsize(this, def.m_mins, def.m_maxs);
1324                         this.SendFlags |= ISF_SIZE;
1325                         // note droptofloor returns false if stuck/or would fall too far
1326                         if (!this.noalign)
1327                                 droptofloor(this);
1328                         waypoint_spawnforitem(this);
1329                 }
1330
1331                 /*
1332                  * can't do it that way, as it would break maps
1333                  * TODO make a target_give like entity another way, that perhaps has
1334                  * the weapon name in a key
1335                 if(this.targetname)
1336                 {
1337                         // target_give not yet supported; maybe later
1338                         print("removed targeted ", this.classname, "\n");
1339                         startitem_failed = true;
1340                         delete(this);
1341                         return;
1342                 }
1343                 */
1344
1345                 if(this.targetname != "" && (this.spawnflags & 16))
1346                         this.use = item_use;
1347
1348                 if(autocvar_spawn_debug >= 2)
1349                 {
1350             // why not flags & fl_item?
1351                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1352                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1353                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1354                 error("Mapper sucks.");
1355             });
1356                         this.is_item = true;
1357                 }
1358
1359                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1360
1361                 precache_model(this.model);
1362                 precache_sound(this.item_pickupsound);
1363
1364                 if (   def.instanceOfPowerup
1365                         || def.instanceOfWeaponPickup
1366                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1367                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1368                         || (itemid & (IT_KEY1 | IT_KEY2))
1369                 ) this.target = "###item###"; // for finding the nearest item using find()
1370
1371                 Item_ItemsTime_SetTime(this, 0);
1372         }
1373
1374         this.bot_pickup = true;
1375         this.bot_pickupevalfunc = pickupevalfunc;
1376         this.bot_pickupbasevalue = pickupbasevalue;
1377         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1378         this.netname = itemname;
1379         settouch(this, Item_Touch);
1380         setmodel(this, MDL_Null); // precision set below
1381         //this.effects |= EF_LOWPRECISION;
1382
1383         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1384
1385         this.SendFlags |= ISF_SIZE;
1386
1387         if (!(this.spawnflags & 1024)) {
1388                 if(def.instanceOfPowerup)
1389                         this.ItemStatus |= ITS_ANIMATE1;
1390
1391                 if(this.armorvalue || this.health)
1392                         this.ItemStatus |= ITS_ANIMATE2;
1393         }
1394
1395         if(def.instanceOfWeaponPickup)
1396         {
1397                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1398                         this.colormap = 1024; // color shirt=0 pants=0 grey
1399                 else
1400                         this.gravity = 1;
1401                 if (!(this.spawnflags & 1024))
1402                         this.ItemStatus |= ITS_ANIMATE1;
1403                 this.SendFlags |= ISF_COLORMAP;
1404         }
1405
1406         this.state = 0;
1407         if(this.team) // broken, no idea why.
1408         {
1409                 if(!this.cnt)
1410                         this.cnt = 1; // item probability weight
1411
1412                 this.effects |= EF_NODRAW; // marker for item team search
1413                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1414         }
1415         else
1416                 Item_Reset(this);
1417
1418         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1419
1420         // call this hook after everything else has been done
1421         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1422         {
1423                 startitem_failed = true;
1424                 delete(this);
1425                 return;
1426         }
1427
1428         setItemGroup(this);
1429 }
1430
1431 void StartItem(entity this, GameItem def)
1432 {
1433     _StartItem(
1434         this,
1435         this.itemdef = def,
1436         def.m_respawntime(), // defaultrespawntime
1437         def.m_respawntimejitter() // defaultrespawntimejitter
1438         );
1439 }
1440
1441 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1442 int group_count = 1;
1443
1444 void setItemGroup(entity this)
1445 {
1446         if(!IS_SMALL(this.itemdef))
1447                 return;
1448
1449         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1450         {
1451                 if(!this.item_group)
1452                 {
1453                         if(!it.item_group)
1454                         {
1455                                 it.item_group = group_count;
1456                                 group_count++;
1457                         }
1458                         this.item_group = it.item_group;
1459                 }
1460                 else // spawning item is already part of a item_group X
1461                 {
1462                         if(!it.item_group)
1463                                 it.item_group = this.item_group;
1464                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1465                         {
1466                                 int grY = it.item_group;
1467                                 // move all items of item_group Y to item_group X
1468                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1469                                 {
1470                                         if(it.item_group == grY)
1471                                                 it.item_group = this.item_group;
1472                                 });
1473                         }
1474                 }
1475         });
1476 }
1477
1478 void setItemGroupCount()
1479 {
1480         for (int k = 1; k <= group_count; k++)
1481         {
1482                 int count = 0;
1483                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1484                 if (count)
1485                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1486         }
1487 }
1488
1489 spawnfunc(item_rockets)
1490 {
1491     StartItem(this, ITEM_Rockets);
1492 }
1493
1494 spawnfunc(item_bullets)
1495 {
1496         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1497            (this.classname != "droppedweapon"))
1498         {
1499                 weaponswapping = true;
1500                 spawnfunc_item_shells(this);
1501                 weaponswapping = false;
1502                 return;
1503         }
1504
1505     StartItem(this, ITEM_Bullets);
1506 }
1507
1508 spawnfunc(item_cells)
1509 {
1510         StartItem(this, ITEM_Cells);
1511 }
1512
1513 spawnfunc(item_plasma)
1514 {
1515         StartItem(this, ITEM_Plasma);
1516 }
1517
1518 spawnfunc(item_shells)
1519 {
1520         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1521            (this.classname != "droppedweapon"))
1522         {
1523                 weaponswapping = true;
1524                 spawnfunc_item_bullets(this);
1525                 weaponswapping = false;
1526                 return;
1527         }
1528
1529         StartItem(this, ITEM_Shells);
1530 }
1531
1532 spawnfunc(item_armor_small)
1533 {
1534         StartItem(this, ITEM_ArmorSmall);
1535 }
1536
1537 spawnfunc(item_armor_medium)
1538 {
1539         StartItem(this, ITEM_ArmorMedium);
1540 }
1541
1542 spawnfunc(item_armor_big)
1543 {
1544         StartItem(this, ITEM_ArmorBig);
1545 }
1546
1547 spawnfunc(item_armor_mega)
1548 {
1549         StartItem(this, ITEM_ArmorMega);
1550 }
1551
1552 spawnfunc(item_health_small)
1553 {
1554         StartItem(this, ITEM_HealthSmall);
1555 }
1556
1557 spawnfunc(item_health_medium)
1558 {
1559     StartItem(this, ITEM_HealthMedium);
1560 }
1561
1562 spawnfunc(item_health_big)
1563 {
1564         StartItem(this, ITEM_HealthBig);
1565 }
1566
1567 spawnfunc(item_health_mega)
1568 {
1569     StartItem(this, ITEM_HealthMega);
1570 }
1571
1572 // support old misnamed entities
1573 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1574 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1575 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1576 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1577 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1578 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1579 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1580
1581 spawnfunc(item_strength)
1582 {
1583         StartItem(this, ITEM_Strength);
1584 }
1585
1586 spawnfunc(item_invincible)
1587 {
1588         StartItem(this, ITEM_Shield);
1589 }
1590
1591 // compatibility:
1592 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1593
1594 void target_items_use(entity this, entity actor, entity trigger)
1595 {
1596         if(actor.classname == "droppedweapon")
1597         {
1598                 EXACTTRIGGER_TOUCH(this, trigger);
1599                 delete(actor);
1600                 return;
1601         }
1602
1603         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1604                 return;
1605
1606         if(trigger.solid == SOLID_TRIGGER)
1607         {
1608                 EXACTTRIGGER_TOUCH(this, trigger);
1609         }
1610
1611         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1612         {
1613                 delete(it);
1614         });
1615
1616         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1617                 centerprint(actor, this.message);
1618 }
1619
1620 spawnfunc(target_items)
1621 {
1622         int n;
1623         string s;
1624
1625         this.use = target_items_use;
1626         if(!this.strength_finished)
1627                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1628         if(!this.invincible_finished)
1629                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1630         if(!this.superweapons_finished)
1631                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1632
1633         n = tokenize_console(this.netname);
1634         if(argv(0) == "give")
1635         {
1636                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1637         }
1638         else
1639         {
1640                 for(int j = 0; j < n; ++j)
1641                 {
1642                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1643                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1644                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1645                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1646                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1647                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1648                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1649                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1650                         else
1651                         {
1652                                 FOREACH(Buffs, it != BUFF_Null,
1653                                 {
1654                                         s = Buff_UndeprecateName(argv(j));
1655                                         if(s == it.m_name)
1656                                         {
1657                                                 this.buffs |= (it.m_itemid);
1658                                                 break;
1659                                         }
1660                                 });
1661                                 FOREACH(Weapons, it != WEP_Null, {
1662                                         s = W_UndeprecateName(argv(j));
1663                                         if(s == it.netname)
1664                                         {
1665                                                 this.weapons |= (it.m_wepset);
1666                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1667                                                         it.wr_init(it);
1668                                                 break;
1669                                         }
1670                                 });
1671                         }
1672                 }
1673
1674                 string itemprefix, valueprefix;
1675                 if(this.spawnflags == 0)
1676                 {
1677                         itemprefix = "";
1678                         valueprefix = "";
1679                 }
1680                 else if(this.spawnflags == 1)
1681                 {
1682                         itemprefix = "max ";
1683                         valueprefix = "max ";
1684                 }
1685                 else if(this.spawnflags == 2)
1686                 {
1687                         itemprefix = "min ";
1688                         valueprefix = "min ";
1689                 }
1690                 else if(this.spawnflags == 4)
1691                 {
1692                         itemprefix = "minus ";
1693                         valueprefix = "max ";
1694                 }
1695                 else
1696                 {
1697                         error("invalid spawnflags");
1698                         itemprefix = valueprefix = string_null;
1699                 }
1700
1701                 this.netname = "";
1702                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1703                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1704                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1705                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1706                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1707                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1708                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1709                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1710                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1711                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1712                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1713                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1714                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1715                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1716                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1717                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1718                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1719         }
1720         this.netname = strzone(this.netname);
1721         //print(this.netname, "\n");
1722
1723         n = tokenize_console(this.netname);
1724         for(int j = 0; j < n; ++j)
1725         {
1726                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1727             it.wr_init(it);
1728             break;
1729                 });
1730         }
1731 }
1732
1733 spawnfunc(item_fuel)
1734 {
1735         StartItem(this, ITEM_JetpackFuel);
1736 }
1737
1738 spawnfunc(item_fuel_regen)
1739 {
1740         if(start_items & ITEM_JetpackRegen.m_itemid)
1741         {
1742                 spawnfunc_item_fuel(this);
1743                 return;
1744         }
1745         StartItem(this, ITEM_JetpackRegen);
1746 }
1747
1748 spawnfunc(item_jetpack)
1749 {
1750         if(start_items & ITEM_Jetpack.m_itemid)
1751         {
1752                 spawnfunc_item_fuel(this);
1753                 return;
1754         }
1755         StartItem(this, ITEM_Jetpack);
1756 }
1757
1758 float GiveWeapon(entity e, float wpn, float op, float val)
1759 {
1760         WepSet v0, v1;
1761         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1762         v0 = (e.weapons & s);
1763         switch(op)
1764         {
1765                 case OP_SET:
1766                         if(val > 0)
1767                                 e.weapons |= s;
1768                         else
1769                                 e.weapons &= ~s;
1770                         break;
1771                 case OP_MIN:
1772                 case OP_PLUS:
1773                         if(val > 0)
1774                                 e.weapons |= s;
1775                         break;
1776                 case OP_MAX:
1777                         if(val <= 0)
1778                                 e.weapons &= ~s;
1779                         break;
1780                 case OP_MINUS:
1781                         if(val > 0)
1782                                 e.weapons &= ~s;
1783                         break;
1784         }
1785         v1 = (e.weapons & s);
1786         return (v0 != v1);
1787 }
1788
1789 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1790 {
1791         bool had_buff = (e.buffs & thebuff.m_itemid);
1792         switch(op)
1793         {
1794                 case OP_SET:
1795                         if(val > 0)
1796                                 e.buffs |= thebuff.m_itemid;
1797                         else
1798                                 e.buffs &= ~thebuff.m_itemid;
1799                         break;
1800                 case OP_MIN:
1801                 case OP_PLUS:
1802                         if(val > 0)
1803                                 e.buffs |= thebuff.m_itemid;
1804                         break;
1805                 case OP_MAX:
1806                         if(val <= 0)
1807                                 e.buffs &= ~thebuff.m_itemid;
1808                         break;
1809                 case OP_MINUS:
1810                         if(val > 0)
1811                                 e.buffs &= ~thebuff.m_itemid;
1812                         break;
1813         }
1814         bool have_buff = (e.buffs & thebuff.m_itemid);
1815         return (had_buff != have_buff);
1816 }
1817
1818 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1819 {
1820         if(v1 == v0)
1821                 return;
1822         if(v1 <= v0 - t)
1823         {
1824                 if(snd_decr != NULL)
1825                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1826         }
1827         else if(v0 >= v0 + t)
1828         {
1829                 if(snd_incr != NULL)
1830                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1831         }
1832 }
1833
1834 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1835 {
1836         if(v0 < v1)
1837                 e.(rotfield) = max(e.(rotfield), time + rottime);
1838         else if(v0 > v1)
1839                 e.(regenfield) = max(e.(regenfield), time + regentime);
1840 }
1841 float GiveItems(entity e, float beginarg, float endarg)
1842 {
1843         float got, i, val, op;
1844         string cmd;
1845
1846         val = 999;
1847         op = OP_SET;
1848
1849         got = 0;
1850
1851         int _switchweapon = 0;
1852
1853         if(CS(e).autoswitch)
1854         {
1855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1856                 {
1857                         .entity weaponentity = weaponentities[slot];
1858                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1859                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1860                                 _switchweapon |= BIT(slot);
1861                 }
1862         }
1863
1864         e.strength_finished = max(0, e.strength_finished - time);
1865         e.invincible_finished = max(0, e.invincible_finished - time);
1866         e.superweapons_finished = max(0, e.superweapons_finished - time);
1867
1868         PREGIVE(e, items);
1869         PREGIVE_WEAPONS(e);
1870         PREGIVE(e, strength_finished);
1871         PREGIVE(e, invincible_finished);
1872         PREGIVE(e, superweapons_finished);
1873         PREGIVE(e, ammo_nails);
1874         PREGIVE(e, ammo_cells);
1875         PREGIVE(e, ammo_plasma);
1876         PREGIVE(e, ammo_shells);
1877         PREGIVE(e, ammo_rockets);
1878         PREGIVE(e, ammo_fuel);
1879         PREGIVE(e, armorvalue);
1880         PREGIVE(e, health);
1881
1882         for(i = beginarg; i < endarg; ++i)
1883         {
1884                 cmd = argv(i);
1885
1886                 if(cmd == "0" || stof(cmd))
1887                 {
1888                         val = stof(cmd);
1889                         continue;
1890                 }
1891                 switch(cmd)
1892                 {
1893                         case "no":
1894                                 op = OP_MAX;
1895                                 val = 0;
1896                                 continue;
1897                         case "max":
1898                                 op = OP_MAX;
1899                                 continue;
1900                         case "min":
1901                                 op = OP_MIN;
1902                                 continue;
1903                         case "plus":
1904                                 op = OP_PLUS;
1905                                 continue;
1906                         case "minus":
1907                                 op = OP_MINUS;
1908                                 continue;
1909                         case "ALL":
1910                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1911                                 got += GiveValue(e, strength_finished, op, val);
1912                                 got += GiveValue(e, invincible_finished, op, val);
1913                                 got += GiveValue(e, superweapons_finished, op, val);
1914                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1915                         case "all":
1916                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1917                                 got += GiveValue(e, health, op, val);
1918                                 got += GiveValue(e, armorvalue, op, val);
1919                         case "allweapons":
1920                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1921                         //case "allbuffs": // all buffs makes a player god, do not want!
1922                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1923                         case "allammo":
1924                                 got += GiveValue(e, ammo_cells, op, val);
1925                                 got += GiveValue(e, ammo_plasma, op, val);
1926                                 got += GiveValue(e, ammo_shells, op, val);
1927                                 got += GiveValue(e, ammo_nails, op, val);
1928                                 got += GiveValue(e, ammo_rockets, op, val);
1929                                 got += GiveValue(e, ammo_fuel, op, val);
1930                                 break;
1931                         case "unlimited_ammo":
1932                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1933                                 break;
1934                         case "unlimited_weapon_ammo":
1935                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1936                                 break;
1937                         case "unlimited_superweapons":
1938                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1939                                 break;
1940                         case "jetpack":
1941                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1942                                 break;
1943                         case "fuel_regen":
1944                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1945                                 break;
1946                         case "strength":
1947                                 got += GiveValue(e, strength_finished, op, val);
1948                                 break;
1949                         case "invincible":
1950                                 got += GiveValue(e, invincible_finished, op, val);
1951                                 break;
1952                         case "superweapons":
1953                                 got += GiveValue(e, superweapons_finished, op, val);
1954                                 break;
1955                         case "cells":
1956                                 got += GiveValue(e, ammo_cells, op, val);
1957                                 break;
1958                         case "plasma":
1959                                 got += GiveValue(e, ammo_plasma, op, val);
1960                                 break;
1961                         case "shells":
1962                                 got += GiveValue(e, ammo_shells, op, val);
1963                                 break;
1964                         case "nails":
1965                         case "bullets":
1966                                 got += GiveValue(e, ammo_nails, op, val);
1967                                 break;
1968                         case "rockets":
1969                                 got += GiveValue(e, ammo_rockets, op, val);
1970                                 break;
1971                         case "health":
1972                                 got += GiveValue(e, health, op, val);
1973                                 break;
1974                         case "armor":
1975                                 got += GiveValue(e, armorvalue, op, val);
1976                                 break;
1977                         case "fuel":
1978                                 got += GiveValue(e, ammo_fuel, op, val);
1979                                 break;
1980                         default:
1981                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1982                                 {
1983                                         got += GiveBuff(e, it, op, val);
1984                                         break;
1985                                 });
1986                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1987                     got += GiveWeapon(e, it.m_id, op, val);
1988                     break;
1989                                 });
1990                                 break;
1991                 }
1992                 val = 999;
1993                 op = OP_SET;
1994         }
1995
1996         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1997         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1998         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1999         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
2000         FOREACH(Weapons, it != WEP_Null, {
2001                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
2002                 if(!(save_weapons & (it.m_wepset)))
2003                         if(e.weapons & (it.m_wepset))
2004                                 it.wr_init(it);
2005         });
2006         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
2007         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
2008         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
2009         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
2010         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
2011         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
2012         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
2013         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
2014         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
2015         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
2016         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
2017
2018         if(e.superweapons_finished <= 0)
2019                 if(e.weapons & WEPSET_SUPERWEAPONS)
2020                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2021
2022         if(e.strength_finished <= 0)
2023                 e.strength_finished = 0;
2024         else
2025                 e.strength_finished += time;
2026         if(e.invincible_finished <= 0)
2027                 e.invincible_finished = 0;
2028         else
2029                 e.invincible_finished += time;
2030         if(e.superweapons_finished <= 0)
2031                 e.superweapons_finished = 0;
2032         else
2033                 e.superweapons_finished += time;
2034
2035         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2036         {
2037                 .entity weaponentity = weaponentities[slot];
2038                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2039                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2040                         _switchweapon |= BIT(slot);
2041         }
2042
2043         if(_switchweapon)
2044         {
2045                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2046                 {
2047                         .entity weaponentity = weaponentities[slot];
2048                         if(_switchweapon & BIT(slot))
2049                         {
2050                                 Weapon wep = w_getbestweapon(e, weaponentity);
2051                                 if(wep != e.(weaponentity).m_switchweapon)
2052                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2053                         }
2054                 }
2055         }
2056
2057         return got;
2058 }
2059 #endif