Added GivePlayerResource.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66
67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
68 }
69
70 void ItemDraw(entity this)
71 {
72     if(this.gravity)
73     {
74         Movetype_Physics_MatchServer(this, false);
75         if(IS_ONGROUND(this))
76         { // For some reason avelocity gets set to '0 0 0' here ...
77             this.oldorigin = this.origin;
78             this.gravity = 0;
79
80             if(autocvar_cl_animate_items)
81             { // ... so reset it if animations are requested.
82                 if(this.ItemStatus & ITS_ANIMATE1)
83                     this.avelocity = '0 180 0';
84
85                 if(this.ItemStatus & ITS_ANIMATE2)
86                     this.avelocity = '0 -90 0';
87             }
88
89             // delay is for blocking item's position for a while;
90             // it's a workaround for dropped weapons that receive the position
91             // another time right after they spawn overriding animation position
92             this.onground_time = time + 0.5;
93         }
94     }
95     else if (autocvar_cl_animate_items)
96     {
97         if(this.ItemStatus & ITS_ANIMATE1)
98         {
99             this.angles += this.avelocity * frametime;
100             float fade_in = bound(0, time - this.onground_time, 1);
101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
102         }
103
104         if(this.ItemStatus & ITS_ANIMATE2)
105         {
106             this.angles += this.avelocity * frametime;
107             float fade_in = bound(0, time - this.onground_time, 1);
108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
109         }
110     }
111
112     Item_SetAlpha(this);
113 }
114
115 void ItemDrawSimple(entity this)
116 {
117     if(this.gravity)
118     {
119         Movetype_Physics_MatchServer(this, false);
120
121         if(IS_ONGROUND(this))
122             this.gravity = 0;
123     }
124
125     Item_SetAlpha(this);
126 }
127
128 void Item_PreDraw(entity this)
129 {
130         if(warpzone_warpzones_exist)
131         {
132                 setpredraw(this, func_null); // no need to keep running this
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
139         if(this.fade_start)
140         {
141                 if(vdist(org - this.origin, >, this.fade_end))
142                         alph = 0; // save on some processing
143                 else if(vdist(org - this.origin, <, this.fade_start))
144                         alph = 1; // more processing saved
145                 else
146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
147         }
148         else
149                 alph = 1;
150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
152                 this.alpha = alph;
153         if(alph <= 0)
154                 this.drawmask = 0;
155         //else
156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
157 }
158
159 void ItemRemove(entity this)
160 {
161         if(this.mdl)
162                 strunzone(this.mdl);
163 }
164
165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
166 {
167     int sf = ReadByte();
168
169     if(sf & ISF_LOCATION)
170     {
171         this.origin_x = ReadCoord();
172         this.origin_y = ReadCoord();
173         this.origin_z = ReadCoord();
174         setorigin(this, this.origin);
175         this.oldorigin = this.origin;
176     }
177
178     if(sf & ISF_ANGLES)
179     {
180         this.angles_x = ReadAngle();
181         this.angles_y = ReadAngle();
182         this.angles_z = ReadAngle();
183     }
184
185     if(sf & ISF_SIZE)
186     {
187         float use_bigsize = ReadByte();
188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
189     }
190
191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
192     {
193         this.ItemStatus = ReadByte();
194
195         Item_SetAlpha(this);
196
197         if(autocvar_cl_fullbright_items)
198             if(this.ItemStatus & ITS_ALLOWFB)
199                 this.effects |= EF_FULLBRIGHT;
200
201         if(this.ItemStatus & ITS_GLOW)
202         {
203             if(this.ItemStatus & ITS_AVAILABLE)
204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
205             else
206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
207         }
208     }
209
210     if(sf & ISF_MODEL)
211     {
212         this.drawmask  = MASK_NORMAL;
213                 set_movetype(this, MOVETYPE_TOSS);
214                 if (isnew) IL_PUSH(g_drawables, this);
215         this.draw       = ItemDraw;
216         this.solid = SOLID_TRIGGER;
217         //this.flags |= FL_ITEM;
218
219         bool use_bigsize = ReadByte();
220
221         this.fade_end = ReadShort();
222         this.fade_start = ReadShort();
223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
224                 setpredraw(this, Item_PreDraw);
225
226         if(this.mdl)
227             strunzone(this.mdl);
228
229         this.mdl = "";
230         string _fn = ReadString();
231
232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
233         {
234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
235             this.draw = ItemDrawSimple;
236
237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
245             else
246             {
247                 this.draw = ItemDraw;
248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
249             }
250         }
251
252         if(this.draw != ItemDrawSimple)
253             this.mdl = strzone(_fn);
254
255
256         if(this.mdl == "")
257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
258
259         precache_model(this.mdl);
260         _setmodel(this, this.mdl);
261
262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
263     }
264
265     if(sf & ISF_COLORMAP)
266     {
267         this.colormap = ReadShort();
268         this.item_glowmod_x = ReadByte() / 255.0;
269         this.item_glowmod_y = ReadByte() / 255.0;
270         this.item_glowmod_z = ReadByte() / 255.0;
271     }
272
273     if(sf & ISF_DROP)
274     {
275         this.gravity = 1;
276         this.pushable = true;
277         //this.angles = '0 0 0';
278         set_movetype(this, MOVETYPE_TOSS);
279         this.velocity_x = ReadCoord();
280         this.velocity_y = ReadCoord();
281         this.velocity_z = ReadCoord();
282         setorigin(this, this.oldorigin);
283
284         if(!this.move_time)
285         {
286             this.move_time = time;
287             this.spawntime = time;
288         }
289         else
290             this.move_time = max(this.move_time, time);
291     }
292
293     if(autocvar_cl_animate_items)
294     {
295         if(this.ItemStatus & ITS_ANIMATE1)
296             this.avelocity = '0 180 0';
297
298         if(this.ItemStatus & ITS_ANIMATE2)
299             this.avelocity = '0 -90 0';
300     }
301
302     this.entremove = ItemRemove;
303
304     return true;
305 }
306
307 #endif
308
309 #ifdef SVQC
310 bool ItemSend(entity this, entity to, int sf)
311 {
312         if(this.gravity)
313                 sf |= ISF_DROP;
314         else
315                 sf &= ~ISF_DROP;
316
317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
318         WriteByte(MSG_ENTITY, sf);
319
320         //WriteByte(MSG_ENTITY, this.cnt);
321         if(sf & ISF_LOCATION)
322         {
323                 WriteCoord(MSG_ENTITY, this.origin.x);
324                 WriteCoord(MSG_ENTITY, this.origin.y);
325                 WriteCoord(MSG_ENTITY, this.origin.z);
326         }
327
328         if(sf & ISF_ANGLES)
329         {
330                 WriteAngle(MSG_ENTITY, this.angles_x);
331                 WriteAngle(MSG_ENTITY, this.angles_y);
332                 WriteAngle(MSG_ENTITY, this.angles_z);
333         }
334
335         if(sf & ISF_SIZE)
336         {
337                 Pickup p = this.itemdef;
338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
339         }
340
341         if(sf & ISF_STATUS)
342                 WriteByte(MSG_ENTITY, this.ItemStatus);
343
344         if(sf & ISF_MODEL)
345         {
346                 Pickup p = this.itemdef;
347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
348                 WriteShort(MSG_ENTITY, this.fade_end);
349                 WriteShort(MSG_ENTITY, this.fade_start);
350
351                 if(this.mdl == "")
352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
353
354                 WriteString(MSG_ENTITY, this.mdl);
355         }
356
357
358         if(sf & ISF_COLORMAP)
359         {
360                 WriteShort(MSG_ENTITY, this.colormap);
361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
364         }
365
366         if(sf & ISF_DROP)
367         {
368                 WriteCoord(MSG_ENTITY, this.velocity.x);
369                 WriteCoord(MSG_ENTITY, this.velocity.y);
370                 WriteCoord(MSG_ENTITY, this.velocity.z);
371         }
372
373         return true;
374 }
375
376 void ItemUpdate(entity this)
377 {
378         this.oldorigin = this.origin;
379         this.SendFlags |= ISF_LOCATION;
380 }
381
382 void UpdateItemAfterTeleport(entity this)
383 {
384         if(getSendEntity(this) == ItemSend)
385                 ItemUpdate(this);
386 }
387
388 bool have_pickup_item(entity this)
389 {
390         if(this.itemdef.instanceOfPowerup)
391         {
392                 if(autocvar_g_powerups > 0)
393                         return true;
394                 if(autocvar_g_powerups == 0)
395                         return false;
396         }
397         else
398         {
399                 if(autocvar_g_pickup_items > 0)
400                         return true;
401                 if(autocvar_g_pickup_items == 0)
402                         return false;
403                 if(g_weaponarena)
404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
405                                 return false;
406         }
407         return true;
408 }
409
410 /*
411 float Item_Customize()
412 {
413         if(this.spawnshieldtime)
414                 return true;
415         if(this.weapons & ~other.weapons)
416         {
417                 this.colormod = '0 0 0';
418                 this.glowmod = this.colormod;
419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
420                 return true;
421         }
422         else
423         {
424                 if(g_ghost_items)
425                 {
426                         this.colormod = stov(autocvar_g_ghost_items_color);
427                         this.glowmod = this.colormod;
428                         this.alpha = g_ghost_items;
429                         return true;
430                 }
431                 else
432                         return false;
433         }
434 }
435 */
436
437 void Item_Show (entity e, float mode)
438 {
439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
440         e.ItemStatus &= ~ITS_STAYWEP;
441         entity def = e.itemdef;
442         if (mode > 0)
443         {
444                 // make the item look normal, and be touchable
445                 e.model = e.mdl;
446                 e.solid = SOLID_TRIGGER;
447                 e.spawnshieldtime = 1;
448                 e.ItemStatus |= ITS_AVAILABLE;
449         }
450         else if (mode < 0)
451         {
452                 // hide the item completely
453                 e.model = string_null;
454                 e.solid = SOLID_NOT;
455                 e.spawnshieldtime = 1;
456                 e.ItemStatus &= ~ITS_AVAILABLE;
457         }
458         else
459         {
460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
461                         || e.team // weapon stay isn't supported for teamed weapons
462                         ;
463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
464                 {
465                         // make the item translucent and not touchable
466                         e.model = e.mdl;
467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
468                         e.effects |= EF_STARDUST;
469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
471                 }
472                 else
473                 {
474                         //setmodel(e, "null");
475                         e.solid = SOLID_NOT;
476                         e.colormod = '0 0 0';
477                         //e.glowmod = e.colormod;
478                         e.spawnshieldtime = 1;
479                         e.ItemStatus &= ~ITS_AVAILABLE;
480                 }
481         }
482
483         if (def.m_glow)
484                 e.ItemStatus |= ITS_GLOW;
485
486         if (autocvar_g_nodepthtestitems)
487                 e.effects |= EF_NODEPTHTEST;
488
489
490         if (autocvar_g_fullbrightitems)
491                 e.ItemStatus |= ITS_ALLOWFB;
492
493         if (autocvar_sv_simple_items)
494                 e.ItemStatus |= ITS_ALLOWSI;
495
496         // relink entity (because solid may have changed)
497         setorigin(e, e.origin);
498         e.SendFlags |= ISF_STATUS;
499 }
500
501 void Item_Think(entity this)
502 {
503         this.nextthink = time;
504         if(this.origin != this.oldorigin)
505                 ItemUpdate(this);
506 }
507
508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
509 bool Item_ItemsTime_Allow(GameItem it);
510 float Item_ItemsTime_UpdateTime(entity e, float t);
511 void Item_ItemsTime_SetTime(entity e, float t);
512 void Item_ItemsTime_SetTimesForAllPlayers();
513
514 void Item_Respawn (entity this)
515 {
516         Item_Show(this, 1);
517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
518         setorigin(this, this.origin);
519
520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
521         {
522                 float t = Item_ItemsTime_UpdateTime(this, 0);
523                 Item_ItemsTime_SetTime(this, t);
524                 Item_ItemsTime_SetTimesForAllPlayers();
525         }
526
527         setthink(this, Item_Think);
528         this.nextthink = time;
529
530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
532 }
533
534 void Item_RespawnCountdown (entity this)
535 {
536         if(this.count >= ITEM_RESPAWN_TICKS)
537         {
538                 if(this.waypointsprite_attached)
539                         WaypointSprite_Kill(this.waypointsprite_attached);
540                 Item_Respawn(this);
541         }
542         else
543         {
544                 this.nextthink = time + 1;
545                 this.count += 1;
546                 if(this.count == 1)
547                 {
548                         do {
549                                 {
550                                         entity wi = Weapons_from(this.weapon);
551                                         if (wi != WEP_Null) {
552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
553                                                 wp.wp_extra = wi.m_id;
554                                                 break;
555                                         }
556                                 }
557                                 {
558                                         entity ii = this.itemdef;
559                                         if (ii != NULL) {
560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
561                                                 wp.wp_extra = ii.m_id;
562                                                 break;
563                                         }
564                                 }
565                         } while (0);
566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
567             if(this.waypointsprite_attached)
568             {
569                 GameItem def = this.itemdef;
570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
573             }
574                 }
575
576                 if(this.waypointsprite_attached)
577                 {
578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
580                                 {
581                                         msg_entity = it;
582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
583                                 }
584                         });
585
586                         WaypointSprite_Ping(this.waypointsprite_attached);
587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
588                 }
589         }
590 }
591
592 void Item_RespawnThink(entity this)
593 {
594         this.nextthink = time;
595         if(this.origin != this.oldorigin)
596                 ItemUpdate(this);
597
598         if(time >= this.wait)
599                 Item_Respawn(this);
600 }
601
602 void Item_ScheduleRespawnIn(entity e, float t)
603 {
604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
606         {
607                 setthink(e, Item_RespawnCountdown);
608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
610                 e.count = 0;
611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
612                 {
613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
614                         Item_ItemsTime_SetTime(e, t);
615                         Item_ItemsTime_SetTimesForAllPlayers();
616                 }
617         }
618         else
619         {
620                 setthink(e, Item_RespawnThink);
621                 e.nextthink = time;
622                 e.scheduledrespawntime = time + t;
623                 e.wait = time + t;
624
625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
626                 {
627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
628                         Item_ItemsTime_SetTime(e, t);
629                         Item_ItemsTime_SetTimesForAllPlayers();
630                 }
631         }
632 }
633
634 void Item_ScheduleRespawn(entity e)
635 {
636         if(e.respawntime > 0)
637         {
638                 Item_Show(e, 0);
639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
640         }
641         else // if respawntime is -1, this item does not respawn
642                 Item_Show(e, -1);
643 }
644
645 void Item_ScheduleInitialRespawn(entity e)
646 {
647         Item_Show(e, 0);
648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
649 }
650
651 void GivePlayerResource(entity player, .float resource_type, float amount)
652 {
653         if (amount == 0)
654         {
655                 return;
656         }
657         switch (resource_type)
658         {
659                 case health:
660                 {
661                         // Ugly hack. We do not check if health goes beyond hard limit since
662                         // currently it is done in player_regen. We need to bring back this
663                         // check when other code is ported to this function.
664                         player.health = bound(player.health, player.health + amount,
665                                 autocvar_g_balance_health_limit);
666                         // Correct code:
667                         //player.health = bound(player.health, player.health + amount,
668                         //      min(autocvar_g_balance_health_limit, ITEM_COUNT_HARD_LIMIT));
669                         player.pauserothealth_finished = max(player.pauserothealth_finished,
670                                 time + autocvar_g_balance_pause_health_rot);
671                         return;
672                 }
673                 case armorvalue:
674                 {
675                         // Ugly hack. We do not check if armor goes beyond hard limit since
676                         // currently it is done in player_regen. We need to bring back this
677                         // check when other code is ported to this function.
678                         player.armorvalue = bound(player.armorvalue, player.armorvalue +
679                                 amount, autocvar_g_balance_armor_limit);
680                         // Correct code:
681                         //player.armorvalue = bound(player.armorvalue, player.armorvalue +
682                         //      amount, min(autocvar_g_balance_armor_limit,
683                         //      ITEM_COUNT_HARD_LIMIT));
684                         player.pauserotarmor_finished = max(player.pauserotarmor_finished,
685                                 time + autocvar_g_balance_pause_armor_rot);
686                         return;
687                 }
688                 case ammo_shells:
689                 case ammo_nails:
690                 case ammo_rockets:
691                 case ammo_cells:
692                 case ammo_plasma:
693                 {
694                         GivePlayerAmmo(player, resource_type, amount);
695                         return;
696                 }
697                 case ammo_fuel:
698                 {
699                         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel +
700                                 amount, min(g_pickup_fuel_max, ITEM_COUNT_HARD_LIMIT));
701                         player.pauserotfuel_finished = max(player.pauserotfuel_finished,
702                                 time + autocvar_g_balance_pause_fuel_rot);
703                         return;
704                 }
705         }
706 }
707
708 void GivePlayerHealth(entity player, float amount)
709 {
710         GivePlayerResource(player, health, amount);
711 }
712
713 void GivePlayerArmor(entity player, float amount)
714 {
715         GivePlayerResource(player, armorvalue, amount);
716 }
717
718 void GivePlayerAmmo(entity player, .float ammotype, float amount)
719 {
720         if (amount == 0)
721         {
722                 return;
723         }
724         float maxvalue = ITEM_COUNT_HARD_LIMIT;
725         switch (ammotype)
726         {
727                 case ammo_shells:
728                 {
729                         maxvalue = g_pickup_shells_max;
730                         break;
731                 }
732                 case ammo_cells:
733                 {
734                         maxvalue = g_pickup_cells_max;
735                         break;
736                 }
737                 case ammo_rockets:
738                 {
739                         maxvalue = g_pickup_rockets_max;
740                         break;
741                 }
742                 case ammo_plasma:
743                 {
744                         maxvalue = g_pickup_plasma_max;
745                         break;
746                 }
747                 case ammo_nails:
748                 {
749                         maxvalue = g_pickup_nails_max;
750                         break;
751                 }
752         }
753         player.(ammotype) = min(player.(ammotype) + amount,
754                 min(maxvalue, ITEM_COUNT_HARD_LIMIT));
755 }
756
757 void GivePlayerFuel(entity player, float amount)
758 {
759         GivePlayerResource(player, ammo_fuel, amount);
760 }
761
762 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
763 {
764         if (!item.(ammotype))
765                 return false;
766
767         if (item.spawnshieldtime)
768         {
769                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
770                 {
771                         float amount = item.(ammotype);
772                         if ((player.(ammotype) + amount) > ammomax)
773                         {
774                                 amount = ammomax - player.(ammotype);
775                         }
776                         GivePlayerResource(player, ammotype, amount);
777                         return true;
778                 }
779         }
780         else if(g_weapon_stay == 2)
781         {
782                 float mi = min(item.(ammotype), ammomax);
783                 if (player.(ammotype) < mi)
784                 {
785                         GivePlayerResource(player, ammotype, mi - player.(ammotype));
786                 }
787                 return true;
788         }
789         return false;
790 }
791
792 float Item_GiveTo(entity item, entity player)
793 {
794         float pickedup;
795
796         // if nothing happens to player, just return without taking the item
797         pickedup = false;
798         int _switchweapon = 0;
799         // in case the player has autoswitch enabled do the following:
800         // if the player is using their best weapon before items are given, they
801         // probably want to switch to an even better weapon after items are given
802
803         if(CS(player).autoswitch)
804         {
805                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
806                 {
807                         .entity weaponentity = weaponentities[slot];
808                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
809                         {
810                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
811                                         _switchweapon |= BIT(slot);
812
813                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
814                                         _switchweapon |= BIT(slot);
815                         }
816                 }
817         }
818         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
819         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
820         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
821         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
822         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
823         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
824         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
825         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
826         if (item.itemdef.instanceOfWeaponPickup)
827         {
828                 WepSet w;
829                 w = item.weapons;
830                 w &= ~player.weapons;
831
832                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
833                 {
834                         pickedup = true;
835                         FOREACH(Weapons, it != WEP_Null, {
836                                 if(w & (it.m_wepset))
837                                 {
838                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
839                                         {
840                                                 .entity weaponentity = weaponentities[slot];
841                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
842                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
843                                         }
844                                         W_GiveWeapon(player, it.m_id);
845                                 }
846                         });
847                 }
848         }
849
850         if (item.itemdef.instanceOfPowerup)
851         {
852                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
853                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
854                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
855                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
856         }
857
858         int its;
859         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
860         {
861                 pickedup = true;
862                 player.items |= its;
863                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
864         }
865
866         if (item.strength_finished)
867         {
868                 pickedup = true;
869                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
870         }
871         if (item.invincible_finished)
872         {
873                 pickedup = true;
874                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
875         }
876         if (item.superweapons_finished)
877         {
878                 pickedup = true;
879                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
880         }
881
882 LABEL(skip)
883
884         // always eat teamed entities
885         if(item.team)
886                 pickedup = true;
887
888         if (!pickedup)
889                 return 0;
890
891         // crude hack to enforce switching weapons
892         if(g_cts && item.itemdef.instanceOfWeaponPickup)
893         {
894                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
895                 {
896                         .entity weaponentity = weaponentities[slot];
897                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
898                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
899                 }
900                 return 1;
901         }
902
903         if(_switchweapon)
904         {
905                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
906                 {
907                         .entity weaponentity = weaponentities[slot];
908                         if(_switchweapon & BIT(slot))
909                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
910                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
911                 }
912         }
913
914         return 1;
915 }
916
917 void Item_Touch(entity this, entity toucher)
918 {
919
920         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
921         if (this.classname == "droppedweapon")
922         {
923                 if (ITEM_TOUCH_NEEDKILL())
924                 {
925                         delete(this);
926                         return;
927                 }
928         }
929
930         if(!(toucher.flags & FL_PICKUPITEMS)
931         || STAT(FROZEN, toucher)
932         || IS_DEAD(toucher)
933         || (this.solid != SOLID_TRIGGER)
934         || (this.owner == toucher)
935         || (time < this.item_spawnshieldtime)
936         ) { return; }
937
938         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
939         {
940                 case MUT_ITEMTOUCH_RETURN: { return; }
941                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
942         }
943
944         toucher = M_ARGV(1, entity);
945
946         if (this.classname == "droppedweapon")
947         {
948                 this.strength_finished = max(0, this.strength_finished - time);
949                 this.invincible_finished = max(0, this.invincible_finished - time);
950                 this.superweapons_finished = max(0, this.superweapons_finished - time);
951         }
952         entity it = this.itemdef;
953         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
954         if (!gave)
955         {
956                 if (this.classname == "droppedweapon")
957                 {
958                         // undo what we did above
959                         this.strength_finished += time;
960                         this.invincible_finished += time;
961                         this.superweapons_finished += time;
962                 }
963                 return;
964         }
965
966 LABEL(pickup)
967
968         toucher.last_pickup = time;
969
970         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
971         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
972
973         if (this.classname == "droppedweapon")
974                 delete(this);
975         else if (this.spawnshieldtime)
976         {
977                 entity e;
978                 if(this.team)
979                 {
980                         RandomSelection_Init();
981                         IL_EACH(g_items, it.team == this.team,
982                         {
983                                 if(it.itemdef) // is a registered item
984                                 {
985                                         Item_Show(it, -1);
986                                         RandomSelection_AddEnt(it, it.cnt, 0);
987                                 }
988                         });
989                         e = RandomSelection_chosen_ent;
990                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
991                 }
992                 else
993                         e = this;
994                 Item_ScheduleRespawn(e);
995         }
996 }
997
998 void Item_Reset(entity this)
999 {
1000         Item_Show(this, !this.state);
1001         setorigin(this, this.origin);
1002
1003         if (this.classname != "droppedweapon")
1004         {
1005                 setthink(this, Item_Think);
1006                 this.nextthink = time;
1007
1008                 if (this.waypointsprite_attached)
1009                         WaypointSprite_Kill(this.waypointsprite_attached);
1010
1011                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1012                         Item_ScheduleInitialRespawn(this);
1013         }
1014 }
1015
1016 void Item_FindTeam(entity this)
1017 {
1018         entity e;
1019
1020         if(this.effects & EF_NODRAW)
1021         {
1022                 // marker for item team search
1023                 LOG_TRACE("Initializing item team ", ftos(this.team));
1024                 RandomSelection_Init();
1025                 IL_EACH(g_items, it.team == this.team,
1026                 {
1027                         if(it.itemdef) // is a registered item
1028                                 RandomSelection_AddEnt(it, it.cnt, 0);
1029                 });
1030
1031                 e = RandomSelection_chosen_ent;
1032                 e.state = 0;
1033                 Item_Show(e, 1);
1034
1035                 IL_EACH(g_items, it.team == this.team,
1036                 {
1037                         if(it.itemdef) // is a registered item
1038                         {
1039                                 if(it != e)
1040                                 {
1041                                         // make it non-spawned
1042                                         Item_Show(it, -1);
1043                                         it.state = 1; // state 1 = initially hidden item, apparently
1044                                 }
1045                                 it.effects &= ~EF_NODRAW;
1046                         }
1047                 });
1048
1049                 Item_Reset(this);
1050         }
1051 }
1052
1053 // Savage: used for item garbage-collection
1054 void RemoveItem(entity this)
1055 {
1056         if(wasfreed(this) || !this) { return; }
1057         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1058         delete(this);
1059 }
1060
1061 // pickup evaluation functions
1062 // these functions decide how desirable an item is to the bots
1063
1064 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1065
1066 float weapon_pickupevalfunc(entity player, entity item)
1067 {
1068         // See if I have it already
1069         if(player.weapons & item.weapons)
1070         {
1071                 // If I can pick it up
1072                 if(!item.spawnshieldtime)
1073                         return 0;
1074                 return ammo_pickupevalfunc(player, item);
1075         }
1076
1077         // reduce weapon value if bot already got a good arsenal
1078         float c = 1;
1079         int weapons_value = 0;
1080         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1081                 weapons_value += it.bot_pickupbasevalue;
1082         });
1083         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1084
1085         return item.bot_pickupbasevalue * c;
1086 }
1087
1088 float ammo_pickupevalfunc(entity player, entity item)
1089 {
1090         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1091         entity wpn = NULL;
1092         float c = 0;
1093         float rating = 0;
1094
1095         // Detect needed ammo
1096         if(item.itemdef.instanceOfWeaponPickup)
1097         {
1098                 entity ammo = NULL;
1099                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1100                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1101                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1102                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1103                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1104                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1105
1106                 if(!ammo)
1107                         return 0;
1108                 wpn = item;
1109                 rating = ammo.m_botvalue;
1110         }
1111         else
1112         {
1113                 FOREACH(Weapons, it != WEP_Null, {
1114                         if(!(player.weapons & (it.m_wepset)))
1115                                 continue;
1116
1117                         switch(it.ammo_field)
1118                         {
1119                                 case ammo_shells:  need_shells  = true; break;
1120                                 case ammo_nails:   need_nails   = true; break;
1121                                 case ammo_rockets: need_rockets = true; break;
1122                                 case ammo_cells:   need_cells   = true; break;
1123                                 case ammo_plasma:  need_plasma  = true; break;
1124                                 case ammo_fuel:    need_fuel    = true; break;
1125                         }
1126                 });
1127                 rating = item.bot_pickupbasevalue;
1128         }
1129
1130         float noammorating = 0.5;
1131
1132         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1133                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1134
1135         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1136                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1137
1138         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1139                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1140
1141         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1142                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1143
1144         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1145                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1146
1147         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1148                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1149
1150         rating *= min(c, 2);
1151         if(wpn)
1152                 rating += wpn.bot_pickupbasevalue * 0.1;
1153         return rating;
1154 }
1155
1156 .int item_group;
1157 .int item_group_count;
1158 float healtharmor_pickupevalfunc(entity player, entity item)
1159 {
1160         float c = 0;
1161         float rating = item.bot_pickupbasevalue;
1162
1163         float itemarmor = item.armorvalue;
1164         float itemhealth = item.health;
1165
1166         if(item.item_group)
1167         {
1168                 itemarmor *= min(4, item.item_group_count);
1169                 itemhealth *= min(4, item.item_group_count);
1170         }
1171
1172         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1173                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1174
1175         if (itemhealth && (player.health < item.max_health))
1176                 c = itemhealth / max(1, player.health);
1177
1178         rating *= min(2, c);
1179         return rating;
1180 }
1181
1182 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1183 {
1184         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1185                 RemoveItem(this);
1186 }
1187
1188 void item_use(entity this, entity actor, entity trigger)
1189 {
1190         // use the touch function to handle collection
1191         gettouch(this)(this, actor);
1192 }
1193
1194 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1195 {
1196         string itemname = def.m_name;
1197         Model itemmodel = def.m_model;
1198     Sound pickupsound = def.m_sound;
1199         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1200         float pickupbasevalue = def.m_botvalue;
1201         int itemflags = def.m_itemflags;
1202
1203         startitem_failed = false;
1204
1205         this.item_model_ent = itemmodel;
1206     this.item_pickupsound_ent = pickupsound;
1207
1208     if(def.m_iteminit)
1209         def.m_iteminit(this);
1210
1211         if(!this.respawntime) // both need to be set
1212         {
1213                 this.respawntime = defaultrespawntime;
1214                 this.respawntimejitter = defaultrespawntimejitter;
1215         }
1216
1217         if(!this.pickup_anyway && def.m_pickupanyway)
1218                 this.pickup_anyway = def.m_pickupanyway();
1219
1220         int itemid = def.m_itemid;
1221         this.items = itemid;
1222         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1223         this.weapon = weaponid;
1224
1225         if(!this.fade_end)
1226         {
1227                 this.fade_start = autocvar_g_items_mindist;
1228                 this.fade_end = autocvar_g_items_maxdist;
1229         }
1230
1231         if(weaponid)
1232                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1233
1234         this.flags = FL_ITEM | itemflags;
1235         IL_PUSH(g_items, this);
1236
1237         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1238         {
1239                 startitem_failed = true;
1240                 delete(this);
1241                 return;
1242         }
1243
1244         // is it a dropped weapon?
1245         if (this.classname == "droppedweapon")
1246         {
1247                 this.reset = SUB_Remove;
1248                 // it's a dropped weapon
1249                 set_movetype(this, MOVETYPE_TOSS);
1250
1251                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1252                 setthink(this, RemoveItem);
1253                 this.nextthink = time + 20;
1254
1255                 this.takedamage = DAMAGE_YES;
1256                 this.event_damage = Item_Damage;
1257
1258                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1259                 {
1260                         // if item is worthless after a timer, have it expire then
1261                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1262                 }
1263
1264                 // don't drop if in a NODROP zone (such as lava)
1265                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1266                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1267                 {
1268                         startitem_failed = true;
1269                         delete(this);
1270                         return;
1271                 }
1272         }
1273         else
1274         {
1275                 if(!have_pickup_item(this))
1276                 {
1277                         startitem_failed = true;
1278                         delete(this);
1279                         return;
1280                 }
1281
1282                 if(this.angles != '0 0 0')
1283                         this.SendFlags |= ISF_ANGLES;
1284
1285                 this.reset = Item_Reset;
1286                 // it's a level item
1287                 if(this.spawnflags & 1)
1288                         this.noalign = 1;
1289                 if (this.noalign > 0)
1290                         set_movetype(this, MOVETYPE_NONE);
1291                 else
1292                         set_movetype(this, MOVETYPE_TOSS);
1293                 // do item filtering according to game mode and other things
1294                 if (this.noalign <= 0)
1295                 {
1296                         // first nudge it off the floor a little bit to avoid math errors
1297                         setorigin(this, this.origin + '0 0 1');
1298                         // set item size before we spawn a spawnfunc_waypoint
1299                         setsize(this, def.m_mins, def.m_maxs);
1300                         this.SendFlags |= ISF_SIZE;
1301                         // note droptofloor returns false if stuck/or would fall too far
1302                         if (!this.noalign)
1303                                 droptofloor(this);
1304                         waypoint_spawnforitem(this);
1305                 }
1306
1307                 /*
1308                  * can't do it that way, as it would break maps
1309                  * TODO make a target_give like entity another way, that perhaps has
1310                  * the weapon name in a key
1311                 if(this.targetname)
1312                 {
1313                         // target_give not yet supported; maybe later
1314                         print("removed targeted ", this.classname, "\n");
1315                         startitem_failed = true;
1316                         delete(this);
1317                         return;
1318                 }
1319                 */
1320
1321                 if(this.targetname != "" && (this.spawnflags & 16))
1322                         this.use = item_use;
1323
1324                 if(autocvar_spawn_debug >= 2)
1325                 {
1326             // why not flags & fl_item?
1327                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1328                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1329                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1330                 error("Mapper sucks.");
1331             });
1332                         this.is_item = true;
1333                 }
1334
1335                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1336
1337                 precache_model(this.model);
1338                 precache_sound(this.item_pickupsound);
1339
1340                 if (   def.instanceOfPowerup
1341                         || def.instanceOfWeaponPickup
1342                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1343                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1344                         || (itemid & (IT_KEY1 | IT_KEY2))
1345                 ) this.target = "###item###"; // for finding the nearest item using find()
1346
1347                 Item_ItemsTime_SetTime(this, 0);
1348         }
1349
1350         this.bot_pickup = true;
1351         this.bot_pickupevalfunc = pickupevalfunc;
1352         this.bot_pickupbasevalue = pickupbasevalue;
1353         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1354         this.netname = itemname;
1355         settouch(this, Item_Touch);
1356         setmodel(this, MDL_Null); // precision set below
1357         //this.effects |= EF_LOWPRECISION;
1358
1359         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1360
1361         this.SendFlags |= ISF_SIZE;
1362
1363         if (!(this.spawnflags & 1024)) {
1364                 if(def.instanceOfPowerup)
1365                         this.ItemStatus |= ITS_ANIMATE1;
1366
1367                 if(this.armorvalue || this.health)
1368                         this.ItemStatus |= ITS_ANIMATE2;
1369         }
1370
1371         if(def.instanceOfWeaponPickup)
1372         {
1373                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1374                         this.colormap = 1024; // color shirt=0 pants=0 grey
1375                 else
1376                         this.gravity = 1;
1377                 if (!(this.spawnflags & 1024))
1378                         this.ItemStatus |= ITS_ANIMATE1;
1379                 this.SendFlags |= ISF_COLORMAP;
1380         }
1381
1382         this.state = 0;
1383         if(this.team) // broken, no idea why.
1384         {
1385                 if(!this.cnt)
1386                         this.cnt = 1; // item probability weight
1387
1388                 this.effects |= EF_NODRAW; // marker for item team search
1389                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1390         }
1391         else
1392                 Item_Reset(this);
1393
1394         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1395
1396         // call this hook after everything else has been done
1397         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1398         {
1399                 startitem_failed = true;
1400                 delete(this);
1401                 return;
1402         }
1403
1404         setItemGroup(this);
1405 }
1406
1407 void StartItem(entity this, GameItem def)
1408 {
1409     _StartItem(
1410         this,
1411         this.itemdef = def,
1412         def.m_respawntime(), // defaultrespawntime
1413         def.m_respawntimejitter() // defaultrespawntimejitter
1414         );
1415 }
1416
1417 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1418 int group_count = 1;
1419
1420 void setItemGroup(entity this)
1421 {
1422         if(!IS_SMALL(this.itemdef))
1423                 return;
1424
1425         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1426         {
1427                 if(!this.item_group)
1428                 {
1429                         if(!it.item_group)
1430                         {
1431                                 it.item_group = group_count;
1432                                 group_count++;
1433                         }
1434                         this.item_group = it.item_group;
1435                 }
1436                 else // spawning item is already part of a item_group X
1437                 {
1438                         if(!it.item_group)
1439                                 it.item_group = this.item_group;
1440                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1441                         {
1442                                 int grY = it.item_group;
1443                                 // move all items of item_group Y to item_group X
1444                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1445                                 {
1446                                         if(it.item_group == grY)
1447                                                 it.item_group = this.item_group;
1448                                 });
1449                         }
1450                 }
1451         });
1452 }
1453
1454 void setItemGroupCount()
1455 {
1456         for (int k = 1; k <= group_count; k++)
1457         {
1458                 int count = 0;
1459                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1460                 if (count)
1461                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1462         }
1463 }
1464
1465 spawnfunc(item_rockets)
1466 {
1467     StartItem(this, ITEM_Rockets);
1468 }
1469
1470 spawnfunc(item_bullets)
1471 {
1472         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1473            (this.classname != "droppedweapon"))
1474         {
1475                 weaponswapping = true;
1476                 spawnfunc_item_shells(this);
1477                 weaponswapping = false;
1478                 return;
1479         }
1480
1481     StartItem(this, ITEM_Bullets);
1482 }
1483
1484 spawnfunc(item_cells)
1485 {
1486         StartItem(this, ITEM_Cells);
1487 }
1488
1489 spawnfunc(item_plasma)
1490 {
1491         StartItem(this, ITEM_Plasma);
1492 }
1493
1494 spawnfunc(item_shells)
1495 {
1496         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1497            (this.classname != "droppedweapon"))
1498         {
1499                 weaponswapping = true;
1500                 spawnfunc_item_bullets(this);
1501                 weaponswapping = false;
1502                 return;
1503         }
1504
1505         StartItem(this, ITEM_Shells);
1506 }
1507
1508 spawnfunc(item_armor_small)
1509 {
1510         StartItem(this, ITEM_ArmorSmall);
1511 }
1512
1513 spawnfunc(item_armor_medium)
1514 {
1515         StartItem(this, ITEM_ArmorMedium);
1516 }
1517
1518 spawnfunc(item_armor_big)
1519 {
1520         StartItem(this, ITEM_ArmorBig);
1521 }
1522
1523 spawnfunc(item_armor_mega)
1524 {
1525         StartItem(this, ITEM_ArmorMega);
1526 }
1527
1528 spawnfunc(item_health_small)
1529 {
1530         StartItem(this, ITEM_HealthSmall);
1531 }
1532
1533 spawnfunc(item_health_medium)
1534 {
1535     StartItem(this, ITEM_HealthMedium);
1536 }
1537
1538 spawnfunc(item_health_big)
1539 {
1540         StartItem(this, ITEM_HealthBig);
1541 }
1542
1543 spawnfunc(item_health_mega)
1544 {
1545     StartItem(this, ITEM_HealthMega);
1546 }
1547
1548 // support old misnamed entities
1549 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1550 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1551 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1552 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1553 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1554 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1555 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1556
1557 spawnfunc(item_strength)
1558 {
1559         StartItem(this, ITEM_Strength);
1560 }
1561
1562 spawnfunc(item_invincible)
1563 {
1564         StartItem(this, ITEM_Shield);
1565 }
1566
1567 // compatibility:
1568 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1569
1570 void target_items_use(entity this, entity actor, entity trigger)
1571 {
1572         if(actor.classname == "droppedweapon")
1573         {
1574                 EXACTTRIGGER_TOUCH(this, trigger);
1575                 delete(actor);
1576                 return;
1577         }
1578
1579         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1580                 return;
1581
1582         if(trigger.solid == SOLID_TRIGGER)
1583         {
1584                 EXACTTRIGGER_TOUCH(this, trigger);
1585         }
1586
1587         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1588         {
1589                 delete(it);
1590         });
1591
1592         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1593                 centerprint(actor, this.message);
1594 }
1595
1596 spawnfunc(target_items)
1597 {
1598         int n;
1599         string s;
1600
1601         this.use = target_items_use;
1602         if(!this.strength_finished)
1603                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1604         if(!this.invincible_finished)
1605                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1606         if(!this.superweapons_finished)
1607                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1608
1609         n = tokenize_console(this.netname);
1610         if(argv(0) == "give")
1611         {
1612                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1613         }
1614         else
1615         {
1616                 for(int j = 0; j < n; ++j)
1617                 {
1618                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1619                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1620                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1621                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1622                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1623                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1624                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1625                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1626                         else
1627                         {
1628                                 FOREACH(Buffs, it != BUFF_Null,
1629                                 {
1630                                         s = Buff_UndeprecateName(argv(j));
1631                                         if(s == it.m_name)
1632                                         {
1633                                                 this.buffs |= (it.m_itemid);
1634                                                 break;
1635                                         }
1636                                 });
1637                                 FOREACH(Weapons, it != WEP_Null, {
1638                                         s = W_UndeprecateName(argv(j));
1639                                         if(s == it.netname)
1640                                         {
1641                                                 this.weapons |= (it.m_wepset);
1642                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1643                                                         it.wr_init(it);
1644                                                 break;
1645                                         }
1646                                 });
1647                         }
1648                 }
1649
1650                 string itemprefix, valueprefix;
1651                 if(this.spawnflags == 0)
1652                 {
1653                         itemprefix = "";
1654                         valueprefix = "";
1655                 }
1656                 else if(this.spawnflags == 1)
1657                 {
1658                         itemprefix = "max ";
1659                         valueprefix = "max ";
1660                 }
1661                 else if(this.spawnflags == 2)
1662                 {
1663                         itemprefix = "min ";
1664                         valueprefix = "min ";
1665                 }
1666                 else if(this.spawnflags == 4)
1667                 {
1668                         itemprefix = "minus ";
1669                         valueprefix = "max ";
1670                 }
1671                 else
1672                 {
1673                         error("invalid spawnflags");
1674                         itemprefix = valueprefix = string_null;
1675                 }
1676
1677                 this.netname = "";
1678                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1679                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1680                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1681                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1682                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1683                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1684                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1685                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1686                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1687                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1688                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1689                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1690                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1691                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1692                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1693                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1694                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1695         }
1696         this.netname = strzone(this.netname);
1697         //print(this.netname, "\n");
1698
1699         n = tokenize_console(this.netname);
1700         for(int j = 0; j < n; ++j)
1701         {
1702                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1703             it.wr_init(it);
1704             break;
1705                 });
1706         }
1707 }
1708
1709 spawnfunc(item_fuel)
1710 {
1711         StartItem(this, ITEM_JetpackFuel);
1712 }
1713
1714 spawnfunc(item_fuel_regen)
1715 {
1716         if(start_items & ITEM_JetpackRegen.m_itemid)
1717         {
1718                 spawnfunc_item_fuel(this);
1719                 return;
1720         }
1721         StartItem(this, ITEM_JetpackRegen);
1722 }
1723
1724 spawnfunc(item_jetpack)
1725 {
1726         if(start_items & ITEM_Jetpack.m_itemid)
1727         {
1728                 spawnfunc_item_fuel(this);
1729                 return;
1730         }
1731         StartItem(this, ITEM_Jetpack);
1732 }
1733
1734 float GiveWeapon(entity e, float wpn, float op, float val)
1735 {
1736         WepSet v0, v1;
1737         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1738         v0 = (e.weapons & s);
1739         switch(op)
1740         {
1741                 case OP_SET:
1742                         if(val > 0)
1743                                 e.weapons |= s;
1744                         else
1745                                 e.weapons &= ~s;
1746                         break;
1747                 case OP_MIN:
1748                 case OP_PLUS:
1749                         if(val > 0)
1750                                 e.weapons |= s;
1751                         break;
1752                 case OP_MAX:
1753                         if(val <= 0)
1754                                 e.weapons &= ~s;
1755                         break;
1756                 case OP_MINUS:
1757                         if(val > 0)
1758                                 e.weapons &= ~s;
1759                         break;
1760         }
1761         v1 = (e.weapons & s);
1762         return (v0 != v1);
1763 }
1764
1765 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1766 {
1767         bool had_buff = (e.buffs & thebuff.m_itemid);
1768         switch(op)
1769         {
1770                 case OP_SET:
1771                         if(val > 0)
1772                                 e.buffs |= thebuff.m_itemid;
1773                         else
1774                                 e.buffs &= ~thebuff.m_itemid;
1775                         break;
1776                 case OP_MIN:
1777                 case OP_PLUS:
1778                         if(val > 0)
1779                                 e.buffs |= thebuff.m_itemid;
1780                         break;
1781                 case OP_MAX:
1782                         if(val <= 0)
1783                                 e.buffs &= ~thebuff.m_itemid;
1784                         break;
1785                 case OP_MINUS:
1786                         if(val > 0)
1787                                 e.buffs &= ~thebuff.m_itemid;
1788                         break;
1789         }
1790         bool have_buff = (e.buffs & thebuff.m_itemid);
1791         return (had_buff != have_buff);
1792 }
1793
1794 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1795 {
1796         if(v1 == v0)
1797                 return;
1798         if(v1 <= v0 - t)
1799         {
1800                 if(snd_decr != NULL)
1801                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1802         }
1803         else if(v0 >= v0 + t)
1804         {
1805                 if(snd_incr != NULL)
1806                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1807         }
1808 }
1809
1810 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1811 {
1812         if(v0 < v1)
1813                 e.(rotfield) = max(e.(rotfield), time + rottime);
1814         else if(v0 > v1)
1815                 e.(regenfield) = max(e.(regenfield), time + regentime);
1816 }
1817 float GiveItems(entity e, float beginarg, float endarg)
1818 {
1819         float got, i, val, op;
1820         string cmd;
1821
1822         val = 999;
1823         op = OP_SET;
1824
1825         got = 0;
1826
1827         int _switchweapon = 0;
1828
1829         if(CS(e).autoswitch)
1830         {
1831                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1832                 {
1833                         .entity weaponentity = weaponentities[slot];
1834                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1835                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1836                                 _switchweapon |= BIT(slot);
1837                 }
1838         }
1839
1840         e.strength_finished = max(0, e.strength_finished - time);
1841         e.invincible_finished = max(0, e.invincible_finished - time);
1842         e.superweapons_finished = max(0, e.superweapons_finished - time);
1843
1844         PREGIVE(e, items);
1845         PREGIVE_WEAPONS(e);
1846         PREGIVE(e, strength_finished);
1847         PREGIVE(e, invincible_finished);
1848         PREGIVE(e, superweapons_finished);
1849         PREGIVE(e, ammo_nails);
1850         PREGIVE(e, ammo_cells);
1851         PREGIVE(e, ammo_plasma);
1852         PREGIVE(e, ammo_shells);
1853         PREGIVE(e, ammo_rockets);
1854         PREGIVE(e, ammo_fuel);
1855         PREGIVE(e, armorvalue);
1856         PREGIVE(e, health);
1857
1858         for(i = beginarg; i < endarg; ++i)
1859         {
1860                 cmd = argv(i);
1861
1862                 if(cmd == "0" || stof(cmd))
1863                 {
1864                         val = stof(cmd);
1865                         continue;
1866                 }
1867                 switch(cmd)
1868                 {
1869                         case "no":
1870                                 op = OP_MAX;
1871                                 val = 0;
1872                                 continue;
1873                         case "max":
1874                                 op = OP_MAX;
1875                                 continue;
1876                         case "min":
1877                                 op = OP_MIN;
1878                                 continue;
1879                         case "plus":
1880                                 op = OP_PLUS;
1881                                 continue;
1882                         case "minus":
1883                                 op = OP_MINUS;
1884                                 continue;
1885                         case "ALL":
1886                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1887                                 got += GiveValue(e, strength_finished, op, val);
1888                                 got += GiveValue(e, invincible_finished, op, val);
1889                                 got += GiveValue(e, superweapons_finished, op, val);
1890                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1891                         case "all":
1892                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1893                                 got += GiveValue(e, health, op, val);
1894                                 got += GiveValue(e, armorvalue, op, val);
1895                         case "allweapons":
1896                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1897                         //case "allbuffs": // all buffs makes a player god, do not want!
1898                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1899                         case "allammo":
1900                                 got += GiveValue(e, ammo_cells, op, val);
1901                                 got += GiveValue(e, ammo_plasma, op, val);
1902                                 got += GiveValue(e, ammo_shells, op, val);
1903                                 got += GiveValue(e, ammo_nails, op, val);
1904                                 got += GiveValue(e, ammo_rockets, op, val);
1905                                 got += GiveValue(e, ammo_fuel, op, val);
1906                                 break;
1907                         case "unlimited_ammo":
1908                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1909                                 break;
1910                         case "unlimited_weapon_ammo":
1911                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1912                                 break;
1913                         case "unlimited_superweapons":
1914                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1915                                 break;
1916                         case "jetpack":
1917                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1918                                 break;
1919                         case "fuel_regen":
1920                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1921                                 break;
1922                         case "strength":
1923                                 got += GiveValue(e, strength_finished, op, val);
1924                                 break;
1925                         case "invincible":
1926                                 got += GiveValue(e, invincible_finished, op, val);
1927                                 break;
1928                         case "superweapons":
1929                                 got += GiveValue(e, superweapons_finished, op, val);
1930                                 break;
1931                         case "cells":
1932                                 got += GiveValue(e, ammo_cells, op, val);
1933                                 break;
1934                         case "plasma":
1935                                 got += GiveValue(e, ammo_plasma, op, val);
1936                                 break;
1937                         case "shells":
1938                                 got += GiveValue(e, ammo_shells, op, val);
1939                                 break;
1940                         case "nails":
1941                         case "bullets":
1942                                 got += GiveValue(e, ammo_nails, op, val);
1943                                 break;
1944                         case "rockets":
1945                                 got += GiveValue(e, ammo_rockets, op, val);
1946                                 break;
1947                         case "health":
1948                                 got += GiveValue(e, health, op, val);
1949                                 break;
1950                         case "armor":
1951                                 got += GiveValue(e, armorvalue, op, val);
1952                                 break;
1953                         case "fuel":
1954                                 got += GiveValue(e, ammo_fuel, op, val);
1955                                 break;
1956                         default:
1957                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1958                                 {
1959                                         got += GiveBuff(e, it, op, val);
1960                                         break;
1961                                 });
1962                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1963                     got += GiveWeapon(e, it.m_id, op, val);
1964                     break;
1965                                 });
1966                                 break;
1967                 }
1968                 val = 999;
1969                 op = OP_SET;
1970         }
1971
1972         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1973         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1974         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1975         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1976         FOREACH(Weapons, it != WEP_Null, {
1977                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1978                 if(!(save_weapons & (it.m_wepset)))
1979                         if(e.weapons & (it.m_wepset))
1980                                 it.wr_init(it);
1981         });
1982         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1983         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1984         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1985         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1986         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1987         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1988         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1989         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1990         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1991         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1992         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1993
1994         if(e.superweapons_finished <= 0)
1995                 if(e.weapons & WEPSET_SUPERWEAPONS)
1996                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1997
1998         if(e.strength_finished <= 0)
1999                 e.strength_finished = 0;
2000         else
2001                 e.strength_finished += time;
2002         if(e.invincible_finished <= 0)
2003                 e.invincible_finished = 0;
2004         else
2005                 e.invincible_finished += time;
2006         if(e.superweapons_finished <= 0)
2007                 e.superweapons_finished = 0;
2008         else
2009                 e.superweapons_finished += time;
2010
2011         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2012         {
2013                 .entity weaponentity = weaponentities[slot];
2014                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2015                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2016                         _switchweapon |= BIT(slot);
2017         }
2018
2019         if(_switchweapon)
2020         {
2021                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2022                 {
2023                         .entity weaponentity = weaponentities[slot];
2024                         if(_switchweapon & BIT(slot))
2025                         {
2026                                 Weapon wep = w_getbestweapon(e, weaponentity);
2027                                 if(wep != e.(weaponentity).m_switchweapon)
2028                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2029                         }
2030                 }
2031         }
2032
2033         return got;
2034 }
2035 #endif