Added GivePlayerFuel.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 /// \brief Unconditional maximum amount of items the player can have.
38 const int ITEM_COUNT_HARD_LIMIT = 999; 
39
40 #ifdef CSQC
41 bool autocvar_cl_ghost_items_vehicle = true;
42 .vector item_glowmod;
43 void Item_SetAlpha(entity this)
44 {
45         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
46
47         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
48         {
49                 this.alpha = 1;
50                 this.colormod = '1 1 1';
51                 this.glowmod = this.item_glowmod;
52         }
53         else
54         {
55                 if (autocvar_cl_ghost_items_color)
56                 {
57                         this.alpha = autocvar_cl_ghost_items;
58                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
59                 }
60                 else
61                         this.alpha = -1;
62         }
63
64         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
65         {
66                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
67                 this.alpha = autocvar_cl_weapon_stay_alpha;
68         }
69
70         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
71 }
72
73 void ItemDraw(entity this)
74 {
75     if(this.gravity)
76     {
77         Movetype_Physics_MatchServer(this, false);
78         if(IS_ONGROUND(this))
79         { // For some reason avelocity gets set to '0 0 0' here ...
80             this.oldorigin = this.origin;
81             this.gravity = 0;
82
83             if(autocvar_cl_animate_items)
84             { // ... so reset it if animations are requested.
85                 if(this.ItemStatus & ITS_ANIMATE1)
86                     this.avelocity = '0 180 0';
87
88                 if(this.ItemStatus & ITS_ANIMATE2)
89                     this.avelocity = '0 -90 0';
90             }
91
92             // delay is for blocking item's position for a while;
93             // it's a workaround for dropped weapons that receive the position
94             // another time right after they spawn overriding animation position
95             this.onground_time = time + 0.5;
96         }
97     }
98     else if (autocvar_cl_animate_items)
99     {
100         if(this.ItemStatus & ITS_ANIMATE1)
101         {
102             this.angles += this.avelocity * frametime;
103             float fade_in = bound(0, time - this.onground_time, 1);
104             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
105         }
106
107         if(this.ItemStatus & ITS_ANIMATE2)
108         {
109             this.angles += this.avelocity * frametime;
110             float fade_in = bound(0, time - this.onground_time, 1);
111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
112         }
113     }
114
115     Item_SetAlpha(this);
116 }
117
118 void ItemDrawSimple(entity this)
119 {
120     if(this.gravity)
121     {
122         Movetype_Physics_MatchServer(this, false);
123
124         if(IS_ONGROUND(this))
125             this.gravity = 0;
126     }
127
128     Item_SetAlpha(this);
129 }
130
131 void Item_PreDraw(entity this)
132 {
133         if(warpzone_warpzones_exist)
134         {
135                 setpredraw(this, func_null); // no need to keep running this
136                 return;
137         }
138         float alph;
139         vector org = getpropertyvec(VF_ORIGIN);
140         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
141                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
142         if(this.fade_start)
143         {
144                 if(vdist(org - this.origin, >, this.fade_end))
145                         alph = 0; // save on some processing
146                 else if(vdist(org - this.origin, <, this.fade_start))
147                         alph = 1; // more processing saved
148                 else
149                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
150         }
151         else
152                 alph = 1;
153         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
154         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
155                 this.alpha = alph;
156         if(alph <= 0)
157                 this.drawmask = 0;
158         //else
159                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
160 }
161
162 void ItemRemove(entity this)
163 {
164         if(this.mdl)
165                 strunzone(this.mdl);
166 }
167
168 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
169 {
170     int sf = ReadByte();
171
172     if(sf & ISF_LOCATION)
173     {
174         this.origin_x = ReadCoord();
175         this.origin_y = ReadCoord();
176         this.origin_z = ReadCoord();
177         setorigin(this, this.origin);
178         this.oldorigin = this.origin;
179     }
180
181     if(sf & ISF_ANGLES)
182     {
183         this.angles_x = ReadAngle();
184         this.angles_y = ReadAngle();
185         this.angles_z = ReadAngle();
186     }
187
188     if(sf & ISF_SIZE)
189     {
190         float use_bigsize = ReadByte();
191         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
192     }
193
194     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
195     {
196         this.ItemStatus = ReadByte();
197
198         Item_SetAlpha(this);
199
200         if(autocvar_cl_fullbright_items)
201             if(this.ItemStatus & ITS_ALLOWFB)
202                 this.effects |= EF_FULLBRIGHT;
203
204         if(this.ItemStatus & ITS_GLOW)
205         {
206             if(this.ItemStatus & ITS_AVAILABLE)
207                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
208             else
209                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
210         }
211     }
212
213     if(sf & ISF_MODEL)
214     {
215         this.drawmask  = MASK_NORMAL;
216                 set_movetype(this, MOVETYPE_TOSS);
217                 if (isnew) IL_PUSH(g_drawables, this);
218         this.draw       = ItemDraw;
219         this.solid = SOLID_TRIGGER;
220         //this.flags |= FL_ITEM;
221
222         bool use_bigsize = ReadByte();
223
224         this.fade_end = ReadShort();
225         this.fade_start = ReadShort();
226         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
227                 setpredraw(this, Item_PreDraw);
228
229         if(this.mdl)
230             strunzone(this.mdl);
231
232         this.mdl = "";
233         string _fn = ReadString();
234
235         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
236         {
237             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
238             this.draw = ItemDrawSimple;
239
240             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
241                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
242             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
243                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
244             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
245                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
246             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
247                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
248             else
249             {
250                 this.draw = ItemDraw;
251                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
252             }
253         }
254
255         if(this.draw != ItemDrawSimple)
256             this.mdl = strzone(_fn);
257
258
259         if(this.mdl == "")
260             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
261
262         precache_model(this.mdl);
263         _setmodel(this, this.mdl);
264
265         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
266     }
267
268     if(sf & ISF_COLORMAP)
269     {
270         this.colormap = ReadShort();
271         this.item_glowmod_x = ReadByte() / 255.0;
272         this.item_glowmod_y = ReadByte() / 255.0;
273         this.item_glowmod_z = ReadByte() / 255.0;
274     }
275
276     if(sf & ISF_DROP)
277     {
278         this.gravity = 1;
279         this.pushable = true;
280         //this.angles = '0 0 0';
281         set_movetype(this, MOVETYPE_TOSS);
282         this.velocity_x = ReadCoord();
283         this.velocity_y = ReadCoord();
284         this.velocity_z = ReadCoord();
285         setorigin(this, this.oldorigin);
286
287         if(!this.move_time)
288         {
289             this.move_time = time;
290             this.spawntime = time;
291         }
292         else
293             this.move_time = max(this.move_time, time);
294     }
295
296     if(autocvar_cl_animate_items)
297     {
298         if(this.ItemStatus & ITS_ANIMATE1)
299             this.avelocity = '0 180 0';
300
301         if(this.ItemStatus & ITS_ANIMATE2)
302             this.avelocity = '0 -90 0';
303     }
304
305     this.entremove = ItemRemove;
306
307     return true;
308 }
309
310 #endif
311
312 #ifdef SVQC
313 bool ItemSend(entity this, entity to, int sf)
314 {
315         if(this.gravity)
316                 sf |= ISF_DROP;
317         else
318                 sf &= ~ISF_DROP;
319
320         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
321         WriteByte(MSG_ENTITY, sf);
322
323         //WriteByte(MSG_ENTITY, this.cnt);
324         if(sf & ISF_LOCATION)
325         {
326                 WriteCoord(MSG_ENTITY, this.origin.x);
327                 WriteCoord(MSG_ENTITY, this.origin.y);
328                 WriteCoord(MSG_ENTITY, this.origin.z);
329         }
330
331         if(sf & ISF_ANGLES)
332         {
333                 WriteAngle(MSG_ENTITY, this.angles_x);
334                 WriteAngle(MSG_ENTITY, this.angles_y);
335                 WriteAngle(MSG_ENTITY, this.angles_z);
336         }
337
338         if(sf & ISF_SIZE)
339         {
340                 Pickup p = this.itemdef;
341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
342         }
343
344         if(sf & ISF_STATUS)
345                 WriteByte(MSG_ENTITY, this.ItemStatus);
346
347         if(sf & ISF_MODEL)
348         {
349                 Pickup p = this.itemdef;
350                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
351                 WriteShort(MSG_ENTITY, this.fade_end);
352                 WriteShort(MSG_ENTITY, this.fade_start);
353
354                 if(this.mdl == "")
355                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
356
357                 WriteString(MSG_ENTITY, this.mdl);
358         }
359
360
361         if(sf & ISF_COLORMAP)
362         {
363                 WriteShort(MSG_ENTITY, this.colormap);
364                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
365         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
366         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
367         }
368
369         if(sf & ISF_DROP)
370         {
371                 WriteCoord(MSG_ENTITY, this.velocity.x);
372                 WriteCoord(MSG_ENTITY, this.velocity.y);
373                 WriteCoord(MSG_ENTITY, this.velocity.z);
374         }
375
376         return true;
377 }
378
379 void ItemUpdate(entity this)
380 {
381         this.oldorigin = this.origin;
382         this.SendFlags |= ISF_LOCATION;
383 }
384
385 void UpdateItemAfterTeleport(entity this)
386 {
387         if(getSendEntity(this) == ItemSend)
388                 ItemUpdate(this);
389 }
390
391 bool have_pickup_item(entity this)
392 {
393         if(this.itemdef.instanceOfPowerup)
394         {
395                 if(autocvar_g_powerups > 0)
396                         return true;
397                 if(autocvar_g_powerups == 0)
398                         return false;
399         }
400         else
401         {
402                 if(autocvar_g_pickup_items > 0)
403                         return true;
404                 if(autocvar_g_pickup_items == 0)
405                         return false;
406                 if(g_weaponarena)
407                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
408                                 return false;
409         }
410         return true;
411 }
412
413 /*
414 float Item_Customize()
415 {
416         if(this.spawnshieldtime)
417                 return true;
418         if(this.weapons & ~other.weapons)
419         {
420                 this.colormod = '0 0 0';
421                 this.glowmod = this.colormod;
422                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
423                 return true;
424         }
425         else
426         {
427                 if(g_ghost_items)
428                 {
429                         this.colormod = stov(autocvar_g_ghost_items_color);
430                         this.glowmod = this.colormod;
431                         this.alpha = g_ghost_items;
432                         return true;
433                 }
434                 else
435                         return false;
436         }
437 }
438 */
439
440 void Item_Show (entity e, float mode)
441 {
442         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
443         e.ItemStatus &= ~ITS_STAYWEP;
444         entity def = e.itemdef;
445         if (mode > 0)
446         {
447                 // make the item look normal, and be touchable
448                 e.model = e.mdl;
449                 e.solid = SOLID_TRIGGER;
450                 e.spawnshieldtime = 1;
451                 e.ItemStatus |= ITS_AVAILABLE;
452         }
453         else if (mode < 0)
454         {
455                 // hide the item completely
456                 e.model = string_null;
457                 e.solid = SOLID_NOT;
458                 e.spawnshieldtime = 1;
459                 e.ItemStatus &= ~ITS_AVAILABLE;
460         }
461         else
462         {
463                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
464                         || e.team // weapon stay isn't supported for teamed weapons
465                         ;
466                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
467                 {
468                         // make the item translucent and not touchable
469                         e.model = e.mdl;
470                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
471                         e.effects |= EF_STARDUST;
472                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
473                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
474                 }
475                 else
476                 {
477                         //setmodel(e, "null");
478                         e.solid = SOLID_NOT;
479                         e.colormod = '0 0 0';
480                         //e.glowmod = e.colormod;
481                         e.spawnshieldtime = 1;
482                         e.ItemStatus &= ~ITS_AVAILABLE;
483                 }
484         }
485
486         if (def.m_glow)
487                 e.ItemStatus |= ITS_GLOW;
488
489         if (autocvar_g_nodepthtestitems)
490                 e.effects |= EF_NODEPTHTEST;
491
492
493         if (autocvar_g_fullbrightitems)
494                 e.ItemStatus |= ITS_ALLOWFB;
495
496         if (autocvar_sv_simple_items)
497                 e.ItemStatus |= ITS_ALLOWSI;
498
499         // relink entity (because solid may have changed)
500         setorigin(e, e.origin);
501         e.SendFlags |= ISF_STATUS;
502 }
503
504 void Item_Think(entity this)
505 {
506         this.nextthink = time;
507         if(this.origin != this.oldorigin)
508                 ItemUpdate(this);
509 }
510
511 bool Item_ItemsTime_SpectatorOnly(GameItem it);
512 bool Item_ItemsTime_Allow(GameItem it);
513 float Item_ItemsTime_UpdateTime(entity e, float t);
514 void Item_ItemsTime_SetTime(entity e, float t);
515 void Item_ItemsTime_SetTimesForAllPlayers();
516
517 void Item_Respawn (entity this)
518 {
519         Item_Show(this, 1);
520         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
521         setorigin(this, this.origin);
522
523     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
524         {
525                 float t = Item_ItemsTime_UpdateTime(this, 0);
526                 Item_ItemsTime_SetTime(this, t);
527                 Item_ItemsTime_SetTimesForAllPlayers();
528         }
529
530         setthink(this, Item_Think);
531         this.nextthink = time;
532
533         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
534         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
535 }
536
537 void Item_RespawnCountdown (entity this)
538 {
539         if(this.count >= ITEM_RESPAWN_TICKS)
540         {
541                 if(this.waypointsprite_attached)
542                         WaypointSprite_Kill(this.waypointsprite_attached);
543                 Item_Respawn(this);
544         }
545         else
546         {
547                 this.nextthink = time + 1;
548                 this.count += 1;
549                 if(this.count == 1)
550                 {
551                         do {
552                                 {
553                                         entity wi = Weapons_from(this.weapon);
554                                         if (wi != WEP_Null) {
555                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
556                                                 wp.wp_extra = wi.m_id;
557                                                 break;
558                                         }
559                                 }
560                                 {
561                                         entity ii = this.itemdef;
562                                         if (ii != NULL) {
563                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
564                                                 wp.wp_extra = ii.m_id;
565                                                 break;
566                                         }
567                                 }
568                         } while (0);
569                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
570             if(this.waypointsprite_attached)
571             {
572                 GameItem def = this.itemdef;
573                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
574                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
575                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
576             }
577                 }
578
579                 if(this.waypointsprite_attached)
580                 {
581                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
582                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
583                                 {
584                                         msg_entity = it;
585                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
586                                 }
587                         });
588
589                         WaypointSprite_Ping(this.waypointsprite_attached);
590                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
591                 }
592         }
593 }
594
595 void Item_RespawnThink(entity this)
596 {
597         this.nextthink = time;
598         if(this.origin != this.oldorigin)
599                 ItemUpdate(this);
600
601         if(time >= this.wait)
602                 Item_Respawn(this);
603 }
604
605 void Item_ScheduleRespawnIn(entity e, float t)
606 {
607         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
608         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
609         {
610                 setthink(e, Item_RespawnCountdown);
611                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
612                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
613                 e.count = 0;
614                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
615                 {
616                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
617                         Item_ItemsTime_SetTime(e, t);
618                         Item_ItemsTime_SetTimesForAllPlayers();
619                 }
620         }
621         else
622         {
623                 setthink(e, Item_RespawnThink);
624                 e.nextthink = time;
625                 e.scheduledrespawntime = time + t;
626                 e.wait = time + t;
627
628                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
629                 {
630                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
631                         Item_ItemsTime_SetTime(e, t);
632                         Item_ItemsTime_SetTimesForAllPlayers();
633                 }
634         }
635 }
636
637 void Item_ScheduleRespawn(entity e)
638 {
639         if(e.respawntime > 0)
640         {
641                 Item_Show(e, 0);
642                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
643         }
644         else // if respawntime is -1, this item does not respawn
645                 Item_Show(e, -1);
646 }
647
648 void Item_ScheduleInitialRespawn(entity e)
649 {
650         Item_Show(e, 0);
651         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
652 }
653
654 void GivePlayerHealth(entity player, float amount)
655 {
656         if (amount == 0)
657         {
658                 return;
659         }
660         player.health = bound(player.health, player.health + amount,
661                  min(autocvar_g_balance_health_limit, ITEM_COUNT_HARD_LIMIT));
662         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
663                 autocvar_g_balance_pause_health_rot);
664 }
665
666 void GivePlayerArmor(entity player, float amount)
667 {
668         if (amount == 0)
669         {
670                 return;
671         }
672         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
673                  min(autocvar_g_balance_armor_limit, ITEM_COUNT_HARD_LIMIT));
674         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
675                 autocvar_g_balance_pause_armor_rot);
676 }
677
678 void GivePlayerAmmo(entity player, .float ammotype, float amount)
679 {
680         float maxvalue = 999;
681         switch (ammotype)
682         {
683                 case ammo_shells:
684                 {
685                         maxvalue = g_pickup_shells_max;
686                         break;
687                 }
688                 case ammo_cells:
689                 {
690                         maxvalue = g_pickup_cells_max;
691                         break;
692                 }
693                 case ammo_rockets:
694                 {
695                         maxvalue = g_pickup_rockets_max;
696                         break;
697                 }
698                 case ammo_plasma:
699                 {
700                         maxvalue = g_pickup_plasma_max;
701                         break;
702                 }
703                 case ammo_nails:
704                 {
705                         maxvalue = g_pickup_nails_max;
706                         break;
707                 }
708                 case ammo_fuel:
709                 {
710                         maxvalue = g_pickup_fuel_max;
711                         break;
712                 }
713         }
714         player.(ammotype) = min(player.(ammotype) + amount,
715                 min(maxvalue, ITEM_COUNT_HARD_LIMIT));
716 }
717
718 void GivePlayerFuel(entity player, float amount)
719 {
720         if (amount == 0)
721         {
722                 return;
723         }
724         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel + amount,
725                  min(g_pickup_fuel_max, ITEM_COUNT_HARD_LIMIT));
726         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time +
727                 autocvar_g_balance_pause_fuel_rot);
728 }
729
730 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
731 {
732         if (!item.(ammotype))
733                 return false;
734
735         if (item.spawnshieldtime)
736         {
737                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
738                 {
739                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
740                         goto YEAH;
741                 }
742         }
743         else if(g_weapon_stay == 2)
744         {
745                 float mi = min(item.(ammotype), ammomax);
746                 if (player.(ammotype) < mi)
747                 {
748                         player.(ammotype) = mi;
749                         goto YEAH;
750                 }
751         }
752
753         return false;
754
755 LABEL(YEAH)
756         switch(mode)
757         {
758                 case ITEM_MODE_FUEL:
759                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
760                         break;
761                 case ITEM_MODE_HEALTH:
762                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
763                         break;
764                 case ITEM_MODE_ARMOR:
765                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
766                         break;
767                 default:
768                         break;
769         }
770         return true;
771 }
772
773 float Item_GiveTo(entity item, entity player)
774 {
775         float pickedup;
776
777         // if nothing happens to player, just return without taking the item
778         pickedup = false;
779         int _switchweapon = 0;
780         // in case the player has autoswitch enabled do the following:
781         // if the player is using their best weapon before items are given, they
782         // probably want to switch to an even better weapon after items are given
783
784         if(CS(player).autoswitch)
785         {
786                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
787                 {
788                         .entity weaponentity = weaponentities[slot];
789                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
790                         {
791                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
792                                         _switchweapon |= BIT(slot);
793
794                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
795                                         _switchweapon |= BIT(slot);
796                         }
797                 }
798         }
799
800         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
801         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
802         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
803         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
804         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
805         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
806         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
807         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
808
809         if (item.itemdef.instanceOfWeaponPickup)
810         {
811                 WepSet w;
812                 w = item.weapons;
813                 w &= ~player.weapons;
814
815                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
816                 {
817                         pickedup = true;
818                         FOREACH(Weapons, it != WEP_Null, {
819                                 if(w & (it.m_wepset))
820                                 {
821                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
822                                         {
823                                                 .entity weaponentity = weaponentities[slot];
824                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
825                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
826                                         }
827                                         W_GiveWeapon(player, it.m_id);
828                                 }
829                         });
830                 }
831         }
832
833         if (item.itemdef.instanceOfPowerup)
834         {
835                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
836                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
837                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
838                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
839         }
840
841         int its;
842         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
843         {
844                 pickedup = true;
845                 player.items |= its;
846                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
847         }
848
849         if (item.strength_finished)
850         {
851                 pickedup = true;
852                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
853         }
854         if (item.invincible_finished)
855         {
856                 pickedup = true;
857                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
858         }
859         if (item.superweapons_finished)
860         {
861                 pickedup = true;
862                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
863         }
864
865 LABEL(skip)
866
867         // always eat teamed entities
868         if(item.team)
869                 pickedup = true;
870
871         if (!pickedup)
872                 return 0;
873
874         // crude hack to enforce switching weapons
875         if(g_cts && item.itemdef.instanceOfWeaponPickup)
876         {
877                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
878                 {
879                         .entity weaponentity = weaponentities[slot];
880                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
881                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
882                 }
883                 return 1;
884         }
885
886         if(_switchweapon)
887         {
888                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
889                 {
890                         .entity weaponentity = weaponentities[slot];
891                         if(_switchweapon & BIT(slot))
892                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
893                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
894                 }
895         }
896
897         return 1;
898 }
899
900 void Item_Touch(entity this, entity toucher)
901 {
902
903         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
904         if (this.classname == "droppedweapon")
905         {
906                 if (ITEM_TOUCH_NEEDKILL())
907                 {
908                         delete(this);
909                         return;
910                 }
911         }
912
913         if(!(toucher.flags & FL_PICKUPITEMS)
914         || STAT(FROZEN, toucher)
915         || IS_DEAD(toucher)
916         || (this.solid != SOLID_TRIGGER)
917         || (this.owner == toucher)
918         || (time < this.item_spawnshieldtime)
919         ) { return; }
920
921         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
922         {
923                 case MUT_ITEMTOUCH_RETURN: { return; }
924                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
925         }
926
927         toucher = M_ARGV(1, entity);
928
929         if (this.classname == "droppedweapon")
930         {
931                 this.strength_finished = max(0, this.strength_finished - time);
932                 this.invincible_finished = max(0, this.invincible_finished - time);
933                 this.superweapons_finished = max(0, this.superweapons_finished - time);
934         }
935         entity it = this.itemdef;
936         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
937         if (!gave)
938         {
939                 if (this.classname == "droppedweapon")
940                 {
941                         // undo what we did above
942                         this.strength_finished += time;
943                         this.invincible_finished += time;
944                         this.superweapons_finished += time;
945                 }
946                 return;
947         }
948
949 LABEL(pickup)
950
951         toucher.last_pickup = time;
952
953         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
954         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
955
956         if (this.classname == "droppedweapon")
957                 delete(this);
958         else if (this.spawnshieldtime)
959         {
960                 entity e;
961                 if(this.team)
962                 {
963                         RandomSelection_Init();
964                         IL_EACH(g_items, it.team == this.team,
965                         {
966                                 if(it.itemdef) // is a registered item
967                                 {
968                                         Item_Show(it, -1);
969                                         RandomSelection_AddEnt(it, it.cnt, 0);
970                                 }
971                         });
972                         e = RandomSelection_chosen_ent;
973                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
974                 }
975                 else
976                         e = this;
977                 Item_ScheduleRespawn(e);
978         }
979 }
980
981 void Item_Reset(entity this)
982 {
983         Item_Show(this, !this.state);
984         setorigin(this, this.origin);
985
986         if (this.classname != "droppedweapon")
987         {
988                 setthink(this, Item_Think);
989                 this.nextthink = time;
990
991                 if (this.waypointsprite_attached)
992                         WaypointSprite_Kill(this.waypointsprite_attached);
993
994                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
995                         Item_ScheduleInitialRespawn(this);
996         }
997 }
998
999 void Item_FindTeam(entity this)
1000 {
1001         entity e;
1002
1003         if(this.effects & EF_NODRAW)
1004         {
1005                 // marker for item team search
1006                 LOG_TRACE("Initializing item team ", ftos(this.team));
1007                 RandomSelection_Init();
1008                 IL_EACH(g_items, it.team == this.team,
1009                 {
1010                         if(it.itemdef) // is a registered item
1011                                 RandomSelection_AddEnt(it, it.cnt, 0);
1012                 });
1013
1014                 e = RandomSelection_chosen_ent;
1015                 e.state = 0;
1016                 Item_Show(e, 1);
1017
1018                 IL_EACH(g_items, it.team == this.team,
1019                 {
1020                         if(it.itemdef) // is a registered item
1021                         {
1022                                 if(it != e)
1023                                 {
1024                                         // make it non-spawned
1025                                         Item_Show(it, -1);
1026                                         it.state = 1; // state 1 = initially hidden item, apparently
1027                                 }
1028                                 it.effects &= ~EF_NODRAW;
1029                         }
1030                 });
1031
1032                 Item_Reset(this);
1033         }
1034 }
1035
1036 // Savage: used for item garbage-collection
1037 void RemoveItem(entity this)
1038 {
1039         if(wasfreed(this) || !this) { return; }
1040         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1041         delete(this);
1042 }
1043
1044 // pickup evaluation functions
1045 // these functions decide how desirable an item is to the bots
1046
1047 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1048
1049 float weapon_pickupevalfunc(entity player, entity item)
1050 {
1051         // See if I have it already
1052         if(player.weapons & item.weapons)
1053         {
1054                 // If I can pick it up
1055                 if(!item.spawnshieldtime)
1056                         return 0;
1057                 return ammo_pickupevalfunc(player, item);
1058         }
1059
1060         // reduce weapon value if bot already got a good arsenal
1061         float c = 1;
1062         int weapons_value = 0;
1063         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1064                 weapons_value += it.bot_pickupbasevalue;
1065         });
1066         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1067
1068         return item.bot_pickupbasevalue * c;
1069 }
1070
1071 float ammo_pickupevalfunc(entity player, entity item)
1072 {
1073         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1074         entity wpn = NULL;
1075         float c = 0;
1076         float rating = 0;
1077
1078         // Detect needed ammo
1079         if(item.itemdef.instanceOfWeaponPickup)
1080         {
1081                 entity ammo = NULL;
1082                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1083                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1084                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1085                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1086                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1087                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1088
1089                 if(!ammo)
1090                         return 0;
1091                 wpn = item;
1092                 rating = ammo.m_botvalue;
1093         }
1094         else
1095         {
1096                 FOREACH(Weapons, it != WEP_Null, {
1097                         if(!(player.weapons & (it.m_wepset)))
1098                                 continue;
1099
1100                         switch(it.ammo_field)
1101                         {
1102                                 case ammo_shells:  need_shells  = true; break;
1103                                 case ammo_nails:   need_nails   = true; break;
1104                                 case ammo_rockets: need_rockets = true; break;
1105                                 case ammo_cells:   need_cells   = true; break;
1106                                 case ammo_plasma:  need_plasma  = true; break;
1107                                 case ammo_fuel:    need_fuel    = true; break;
1108                         }
1109                 });
1110                 rating = item.bot_pickupbasevalue;
1111         }
1112
1113         float noammorating = 0.5;
1114
1115         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1116                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1117
1118         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1119                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1120
1121         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1122                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1123
1124         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1125                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1126
1127         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1128                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1129
1130         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1131                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1132
1133         rating *= min(c, 2);
1134         if(wpn)
1135                 rating += wpn.bot_pickupbasevalue * 0.1;
1136         return rating;
1137 }
1138
1139 .int item_group;
1140 .int item_group_count;
1141 float healtharmor_pickupevalfunc(entity player, entity item)
1142 {
1143         float c = 0;
1144         float rating = item.bot_pickupbasevalue;
1145
1146         float itemarmor = item.armorvalue;
1147         float itemhealth = item.health;
1148
1149         if(item.item_group)
1150         {
1151                 itemarmor *= min(4, item.item_group_count);
1152                 itemhealth *= min(4, item.item_group_count);
1153         }
1154
1155         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1156                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1157
1158         if (itemhealth && (player.health < item.max_health))
1159                 c = itemhealth / max(1, player.health);
1160
1161         rating *= min(2, c);
1162         return rating;
1163 }
1164
1165 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1166 {
1167         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1168                 RemoveItem(this);
1169 }
1170
1171 void item_use(entity this, entity actor, entity trigger)
1172 {
1173         // use the touch function to handle collection
1174         gettouch(this)(this, actor);
1175 }
1176
1177 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1178 {
1179         string itemname = def.m_name;
1180         Model itemmodel = def.m_model;
1181     Sound pickupsound = def.m_sound;
1182         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1183         float pickupbasevalue = def.m_botvalue;
1184         int itemflags = def.m_itemflags;
1185
1186         startitem_failed = false;
1187
1188         this.item_model_ent = itemmodel;
1189     this.item_pickupsound_ent = pickupsound;
1190
1191     if(def.m_iteminit)
1192         def.m_iteminit(this);
1193
1194         if(!this.respawntime) // both need to be set
1195         {
1196                 this.respawntime = defaultrespawntime;
1197                 this.respawntimejitter = defaultrespawntimejitter;
1198         }
1199
1200         if(!this.pickup_anyway && def.m_pickupanyway)
1201                 this.pickup_anyway = def.m_pickupanyway();
1202
1203         int itemid = def.m_itemid;
1204         this.items = itemid;
1205         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1206         this.weapon = weaponid;
1207
1208         if(!this.fade_end)
1209         {
1210                 this.fade_start = autocvar_g_items_mindist;
1211                 this.fade_end = autocvar_g_items_maxdist;
1212         }
1213
1214         if(weaponid)
1215                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1216
1217         this.flags = FL_ITEM | itemflags;
1218         IL_PUSH(g_items, this);
1219
1220         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1221         {
1222                 startitem_failed = true;
1223                 delete(this);
1224                 return;
1225         }
1226
1227         // is it a dropped weapon?
1228         if (this.classname == "droppedweapon")
1229         {
1230                 this.reset = SUB_Remove;
1231                 // it's a dropped weapon
1232                 set_movetype(this, MOVETYPE_TOSS);
1233
1234                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1235                 setthink(this, RemoveItem);
1236                 this.nextthink = time + 20;
1237
1238                 this.takedamage = DAMAGE_YES;
1239                 this.event_damage = Item_Damage;
1240
1241                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1242                 {
1243                         // if item is worthless after a timer, have it expire then
1244                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1245                 }
1246
1247                 // don't drop if in a NODROP zone (such as lava)
1248                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1249                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1250                 {
1251                         startitem_failed = true;
1252                         delete(this);
1253                         return;
1254                 }
1255         }
1256         else
1257         {
1258                 if(!have_pickup_item(this))
1259                 {
1260                         startitem_failed = true;
1261                         delete(this);
1262                         return;
1263                 }
1264
1265                 if(this.angles != '0 0 0')
1266                         this.SendFlags |= ISF_ANGLES;
1267
1268                 this.reset = Item_Reset;
1269                 // it's a level item
1270                 if(this.spawnflags & 1)
1271                         this.noalign = 1;
1272                 if (this.noalign > 0)
1273                         set_movetype(this, MOVETYPE_NONE);
1274                 else
1275                         set_movetype(this, MOVETYPE_TOSS);
1276                 // do item filtering according to game mode and other things
1277                 if (this.noalign <= 0)
1278                 {
1279                         // first nudge it off the floor a little bit to avoid math errors
1280                         setorigin(this, this.origin + '0 0 1');
1281                         // set item size before we spawn a spawnfunc_waypoint
1282                         setsize(this, def.m_mins, def.m_maxs);
1283                         this.SendFlags |= ISF_SIZE;
1284                         // note droptofloor returns false if stuck/or would fall too far
1285                         if (!this.noalign)
1286                                 droptofloor(this);
1287                         waypoint_spawnforitem(this);
1288                 }
1289
1290                 /*
1291                  * can't do it that way, as it would break maps
1292                  * TODO make a target_give like entity another way, that perhaps has
1293                  * the weapon name in a key
1294                 if(this.targetname)
1295                 {
1296                         // target_give not yet supported; maybe later
1297                         print("removed targeted ", this.classname, "\n");
1298                         startitem_failed = true;
1299                         delete(this);
1300                         return;
1301                 }
1302                 */
1303
1304                 if(this.targetname != "" && (this.spawnflags & 16))
1305                         this.use = item_use;
1306
1307                 if(autocvar_spawn_debug >= 2)
1308                 {
1309             // why not flags & fl_item?
1310                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1311                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1312                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1313                 error("Mapper sucks.");
1314             });
1315                         this.is_item = true;
1316                 }
1317
1318                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1319
1320                 precache_model(this.model);
1321                 precache_sound(this.item_pickupsound);
1322
1323                 if (   def.instanceOfPowerup
1324                         || def.instanceOfWeaponPickup
1325                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1326                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1327                         || (itemid & (IT_KEY1 | IT_KEY2))
1328                 ) this.target = "###item###"; // for finding the nearest item using find()
1329
1330                 Item_ItemsTime_SetTime(this, 0);
1331         }
1332
1333         this.bot_pickup = true;
1334         this.bot_pickupevalfunc = pickupevalfunc;
1335         this.bot_pickupbasevalue = pickupbasevalue;
1336         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1337         this.netname = itemname;
1338         settouch(this, Item_Touch);
1339         setmodel(this, MDL_Null); // precision set below
1340         //this.effects |= EF_LOWPRECISION;
1341
1342         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1343
1344         this.SendFlags |= ISF_SIZE;
1345
1346         if (!(this.spawnflags & 1024)) {
1347                 if(def.instanceOfPowerup)
1348                         this.ItemStatus |= ITS_ANIMATE1;
1349
1350                 if(this.armorvalue || this.health)
1351                         this.ItemStatus |= ITS_ANIMATE2;
1352         }
1353
1354         if(def.instanceOfWeaponPickup)
1355         {
1356                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1357                         this.colormap = 1024; // color shirt=0 pants=0 grey
1358                 else
1359                         this.gravity = 1;
1360                 if (!(this.spawnflags & 1024))
1361                         this.ItemStatus |= ITS_ANIMATE1;
1362                 this.SendFlags |= ISF_COLORMAP;
1363         }
1364
1365         this.state = 0;
1366         if(this.team) // broken, no idea why.
1367         {
1368                 if(!this.cnt)
1369                         this.cnt = 1; // item probability weight
1370
1371                 this.effects |= EF_NODRAW; // marker for item team search
1372                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1373         }
1374         else
1375                 Item_Reset(this);
1376
1377         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1378
1379         // call this hook after everything else has been done
1380         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1381         {
1382                 startitem_failed = true;
1383                 delete(this);
1384                 return;
1385         }
1386
1387         setItemGroup(this);
1388 }
1389
1390 void StartItem(entity this, GameItem def)
1391 {
1392     _StartItem(
1393         this,
1394         this.itemdef = def,
1395         def.m_respawntime(), // defaultrespawntime
1396         def.m_respawntimejitter() // defaultrespawntimejitter
1397         );
1398 }
1399
1400 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1401 int group_count = 1;
1402
1403 void setItemGroup(entity this)
1404 {
1405         if(!IS_SMALL(this.itemdef))
1406                 return;
1407
1408         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1409         {
1410                 if(!this.item_group)
1411                 {
1412                         if(!it.item_group)
1413                         {
1414                                 it.item_group = group_count;
1415                                 group_count++;
1416                         }
1417                         this.item_group = it.item_group;
1418                 }
1419                 else // spawning item is already part of a item_group X
1420                 {
1421                         if(!it.item_group)
1422                                 it.item_group = this.item_group;
1423                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1424                         {
1425                                 int grY = it.item_group;
1426                                 // move all items of item_group Y to item_group X
1427                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1428                                 {
1429                                         if(it.item_group == grY)
1430                                                 it.item_group = this.item_group;
1431                                 });
1432                         }
1433                 }
1434         });
1435 }
1436
1437 void setItemGroupCount()
1438 {
1439         for (int k = 1; k <= group_count; k++)
1440         {
1441                 int count = 0;
1442                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1443                 if (count)
1444                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1445         }
1446 }
1447
1448 spawnfunc(item_rockets)
1449 {
1450     StartItem(this, ITEM_Rockets);
1451 }
1452
1453 spawnfunc(item_bullets)
1454 {
1455         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1456            (this.classname != "droppedweapon"))
1457         {
1458                 weaponswapping = true;
1459                 spawnfunc_item_shells(this);
1460                 weaponswapping = false;
1461                 return;
1462         }
1463
1464     StartItem(this, ITEM_Bullets);
1465 }
1466
1467 spawnfunc(item_cells)
1468 {
1469         StartItem(this, ITEM_Cells);
1470 }
1471
1472 spawnfunc(item_plasma)
1473 {
1474         StartItem(this, ITEM_Plasma);
1475 }
1476
1477 spawnfunc(item_shells)
1478 {
1479         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1480            (this.classname != "droppedweapon"))
1481         {
1482                 weaponswapping = true;
1483                 spawnfunc_item_bullets(this);
1484                 weaponswapping = false;
1485                 return;
1486         }
1487
1488         StartItem(this, ITEM_Shells);
1489 }
1490
1491 spawnfunc(item_armor_small)
1492 {
1493         StartItem(this, ITEM_ArmorSmall);
1494 }
1495
1496 spawnfunc(item_armor_medium)
1497 {
1498         StartItem(this, ITEM_ArmorMedium);
1499 }
1500
1501 spawnfunc(item_armor_big)
1502 {
1503         StartItem(this, ITEM_ArmorBig);
1504 }
1505
1506 spawnfunc(item_armor_mega)
1507 {
1508         StartItem(this, ITEM_ArmorMega);
1509 }
1510
1511 spawnfunc(item_health_small)
1512 {
1513         StartItem(this, ITEM_HealthSmall);
1514 }
1515
1516 spawnfunc(item_health_medium)
1517 {
1518     StartItem(this, ITEM_HealthMedium);
1519 }
1520
1521 spawnfunc(item_health_big)
1522 {
1523         StartItem(this, ITEM_HealthBig);
1524 }
1525
1526 spawnfunc(item_health_mega)
1527 {
1528     StartItem(this, ITEM_HealthMega);
1529 }
1530
1531 // support old misnamed entities
1532 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1533 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1534 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1535 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1536 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1537 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1538 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1539
1540 spawnfunc(item_strength)
1541 {
1542         StartItem(this, ITEM_Strength);
1543 }
1544
1545 spawnfunc(item_invincible)
1546 {
1547         StartItem(this, ITEM_Shield);
1548 }
1549
1550 // compatibility:
1551 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1552
1553 void target_items_use(entity this, entity actor, entity trigger)
1554 {
1555         if(actor.classname == "droppedweapon")
1556         {
1557                 EXACTTRIGGER_TOUCH(this, trigger);
1558                 delete(actor);
1559                 return;
1560         }
1561
1562         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1563                 return;
1564
1565         if(trigger.solid == SOLID_TRIGGER)
1566         {
1567                 EXACTTRIGGER_TOUCH(this, trigger);
1568         }
1569
1570         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1571         {
1572                 delete(it);
1573         });
1574
1575         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1576                 centerprint(actor, this.message);
1577 }
1578
1579 spawnfunc(target_items)
1580 {
1581         int n;
1582         string s;
1583
1584         this.use = target_items_use;
1585         if(!this.strength_finished)
1586                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1587         if(!this.invincible_finished)
1588                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1589         if(!this.superweapons_finished)
1590                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1591
1592         n = tokenize_console(this.netname);
1593         if(argv(0) == "give")
1594         {
1595                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1596         }
1597         else
1598         {
1599                 for(int j = 0; j < n; ++j)
1600                 {
1601                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1602                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1603                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1604                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1605                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1606                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1607                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1608                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1609                         else
1610                         {
1611                                 FOREACH(Buffs, it != BUFF_Null,
1612                                 {
1613                                         s = Buff_UndeprecateName(argv(j));
1614                                         if(s == it.m_name)
1615                                         {
1616                                                 this.buffs |= (it.m_itemid);
1617                                                 break;
1618                                         }
1619                                 });
1620                                 FOREACH(Weapons, it != WEP_Null, {
1621                                         s = W_UndeprecateName(argv(j));
1622                                         if(s == it.netname)
1623                                         {
1624                                                 this.weapons |= (it.m_wepset);
1625                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1626                                                         it.wr_init(it);
1627                                                 break;
1628                                         }
1629                                 });
1630                         }
1631                 }
1632
1633                 string itemprefix, valueprefix;
1634                 if(this.spawnflags == 0)
1635                 {
1636                         itemprefix = "";
1637                         valueprefix = "";
1638                 }
1639                 else if(this.spawnflags == 1)
1640                 {
1641                         itemprefix = "max ";
1642                         valueprefix = "max ";
1643                 }
1644                 else if(this.spawnflags == 2)
1645                 {
1646                         itemprefix = "min ";
1647                         valueprefix = "min ";
1648                 }
1649                 else if(this.spawnflags == 4)
1650                 {
1651                         itemprefix = "minus ";
1652                         valueprefix = "max ";
1653                 }
1654                 else
1655                 {
1656                         error("invalid spawnflags");
1657                         itemprefix = valueprefix = string_null;
1658                 }
1659
1660                 this.netname = "";
1661                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1662                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1663                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1664                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1665                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1666                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1667                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1668                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1669                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1670                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1671                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1672                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1673                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1674                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1675                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1676                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1677                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1678         }
1679         this.netname = strzone(this.netname);
1680         //print(this.netname, "\n");
1681
1682         n = tokenize_console(this.netname);
1683         for(int j = 0; j < n; ++j)
1684         {
1685                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1686             it.wr_init(it);
1687             break;
1688                 });
1689         }
1690 }
1691
1692 spawnfunc(item_fuel)
1693 {
1694         StartItem(this, ITEM_JetpackFuel);
1695 }
1696
1697 spawnfunc(item_fuel_regen)
1698 {
1699         if(start_items & ITEM_JetpackRegen.m_itemid)
1700         {
1701                 spawnfunc_item_fuel(this);
1702                 return;
1703         }
1704         StartItem(this, ITEM_JetpackRegen);
1705 }
1706
1707 spawnfunc(item_jetpack)
1708 {
1709         if(start_items & ITEM_Jetpack.m_itemid)
1710         {
1711                 spawnfunc_item_fuel(this);
1712                 return;
1713         }
1714         StartItem(this, ITEM_Jetpack);
1715 }
1716
1717 float GiveWeapon(entity e, float wpn, float op, float val)
1718 {
1719         WepSet v0, v1;
1720         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1721         v0 = (e.weapons & s);
1722         switch(op)
1723         {
1724                 case OP_SET:
1725                         if(val > 0)
1726                                 e.weapons |= s;
1727                         else
1728                                 e.weapons &= ~s;
1729                         break;
1730                 case OP_MIN:
1731                 case OP_PLUS:
1732                         if(val > 0)
1733                                 e.weapons |= s;
1734                         break;
1735                 case OP_MAX:
1736                         if(val <= 0)
1737                                 e.weapons &= ~s;
1738                         break;
1739                 case OP_MINUS:
1740                         if(val > 0)
1741                                 e.weapons &= ~s;
1742                         break;
1743         }
1744         v1 = (e.weapons & s);
1745         return (v0 != v1);
1746 }
1747
1748 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1749 {
1750         bool had_buff = (e.buffs & thebuff.m_itemid);
1751         switch(op)
1752         {
1753                 case OP_SET:
1754                         if(val > 0)
1755                                 e.buffs |= thebuff.m_itemid;
1756                         else
1757                                 e.buffs &= ~thebuff.m_itemid;
1758                         break;
1759                 case OP_MIN:
1760                 case OP_PLUS:
1761                         if(val > 0)
1762                                 e.buffs |= thebuff.m_itemid;
1763                         break;
1764                 case OP_MAX:
1765                         if(val <= 0)
1766                                 e.buffs &= ~thebuff.m_itemid;
1767                         break;
1768                 case OP_MINUS:
1769                         if(val > 0)
1770                                 e.buffs &= ~thebuff.m_itemid;
1771                         break;
1772         }
1773         bool have_buff = (e.buffs & thebuff.m_itemid);
1774         return (had_buff != have_buff);
1775 }
1776
1777 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1778 {
1779         if(v1 == v0)
1780                 return;
1781         if(v1 <= v0 - t)
1782         {
1783                 if(snd_decr != NULL)
1784                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1785         }
1786         else if(v0 >= v0 + t)
1787         {
1788                 if(snd_incr != NULL)
1789                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1790         }
1791 }
1792
1793 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1794 {
1795         if(v0 < v1)
1796                 e.(rotfield) = max(e.(rotfield), time + rottime);
1797         else if(v0 > v1)
1798                 e.(regenfield) = max(e.(regenfield), time + regentime);
1799 }
1800 float GiveItems(entity e, float beginarg, float endarg)
1801 {
1802         float got, i, val, op;
1803         string cmd;
1804
1805         val = 999;
1806         op = OP_SET;
1807
1808         got = 0;
1809
1810         int _switchweapon = 0;
1811
1812         if(CS(e).autoswitch)
1813         {
1814                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1815                 {
1816                         .entity weaponentity = weaponentities[slot];
1817                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1818                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1819                                 _switchweapon |= BIT(slot);
1820                 }
1821         }
1822
1823         e.strength_finished = max(0, e.strength_finished - time);
1824         e.invincible_finished = max(0, e.invincible_finished - time);
1825         e.superweapons_finished = max(0, e.superweapons_finished - time);
1826
1827         PREGIVE(e, items);
1828         PREGIVE_WEAPONS(e);
1829         PREGIVE(e, strength_finished);
1830         PREGIVE(e, invincible_finished);
1831         PREGIVE(e, superweapons_finished);
1832         PREGIVE(e, ammo_nails);
1833         PREGIVE(e, ammo_cells);
1834         PREGIVE(e, ammo_plasma);
1835         PREGIVE(e, ammo_shells);
1836         PREGIVE(e, ammo_rockets);
1837         PREGIVE(e, ammo_fuel);
1838         PREGIVE(e, armorvalue);
1839         PREGIVE(e, health);
1840
1841         for(i = beginarg; i < endarg; ++i)
1842         {
1843                 cmd = argv(i);
1844
1845                 if(cmd == "0" || stof(cmd))
1846                 {
1847                         val = stof(cmd);
1848                         continue;
1849                 }
1850                 switch(cmd)
1851                 {
1852                         case "no":
1853                                 op = OP_MAX;
1854                                 val = 0;
1855                                 continue;
1856                         case "max":
1857                                 op = OP_MAX;
1858                                 continue;
1859                         case "min":
1860                                 op = OP_MIN;
1861                                 continue;
1862                         case "plus":
1863                                 op = OP_PLUS;
1864                                 continue;
1865                         case "minus":
1866                                 op = OP_MINUS;
1867                                 continue;
1868                         case "ALL":
1869                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1870                                 got += GiveValue(e, strength_finished, op, val);
1871                                 got += GiveValue(e, invincible_finished, op, val);
1872                                 got += GiveValue(e, superweapons_finished, op, val);
1873                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1874                         case "all":
1875                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1876                                 got += GiveValue(e, health, op, val);
1877                                 got += GiveValue(e, armorvalue, op, val);
1878                         case "allweapons":
1879                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1880                         //case "allbuffs": // all buffs makes a player god, do not want!
1881                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1882                         case "allammo":
1883                                 got += GiveValue(e, ammo_cells, op, val);
1884                                 got += GiveValue(e, ammo_plasma, op, val);
1885                                 got += GiveValue(e, ammo_shells, op, val);
1886                                 got += GiveValue(e, ammo_nails, op, val);
1887                                 got += GiveValue(e, ammo_rockets, op, val);
1888                                 got += GiveValue(e, ammo_fuel, op, val);
1889                                 break;
1890                         case "unlimited_ammo":
1891                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1892                                 break;
1893                         case "unlimited_weapon_ammo":
1894                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1895                                 break;
1896                         case "unlimited_superweapons":
1897                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1898                                 break;
1899                         case "jetpack":
1900                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1901                                 break;
1902                         case "fuel_regen":
1903                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1904                                 break;
1905                         case "strength":
1906                                 got += GiveValue(e, strength_finished, op, val);
1907                                 break;
1908                         case "invincible":
1909                                 got += GiveValue(e, invincible_finished, op, val);
1910                                 break;
1911                         case "superweapons":
1912                                 got += GiveValue(e, superweapons_finished, op, val);
1913                                 break;
1914                         case "cells":
1915                                 got += GiveValue(e, ammo_cells, op, val);
1916                                 break;
1917                         case "plasma":
1918                                 got += GiveValue(e, ammo_plasma, op, val);
1919                                 break;
1920                         case "shells":
1921                                 got += GiveValue(e, ammo_shells, op, val);
1922                                 break;
1923                         case "nails":
1924                         case "bullets":
1925                                 got += GiveValue(e, ammo_nails, op, val);
1926                                 break;
1927                         case "rockets":
1928                                 got += GiveValue(e, ammo_rockets, op, val);
1929                                 break;
1930                         case "health":
1931                                 got += GiveValue(e, health, op, val);
1932                                 break;
1933                         case "armor":
1934                                 got += GiveValue(e, armorvalue, op, val);
1935                                 break;
1936                         case "fuel":
1937                                 got += GiveValue(e, ammo_fuel, op, val);
1938                                 break;
1939                         default:
1940                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1941                                 {
1942                                         got += GiveBuff(e, it, op, val);
1943                                         break;
1944                                 });
1945                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1946                     got += GiveWeapon(e, it.m_id, op, val);
1947                     break;
1948                                 });
1949                                 break;
1950                 }
1951                 val = 999;
1952                 op = OP_SET;
1953         }
1954
1955         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1956         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1957         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1958         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1959         FOREACH(Weapons, it != WEP_Null, {
1960                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1961                 if(!(save_weapons & (it.m_wepset)))
1962                         if(e.weapons & (it.m_wepset))
1963                                 it.wr_init(it);
1964         });
1965         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1966         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1967         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1968         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1969         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1970         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1971         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1972         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1973         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1974         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1975         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1976
1977         if(e.superweapons_finished <= 0)
1978                 if(e.weapons & WEPSET_SUPERWEAPONS)
1979                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1980
1981         if(e.strength_finished <= 0)
1982                 e.strength_finished = 0;
1983         else
1984                 e.strength_finished += time;
1985         if(e.invincible_finished <= 0)
1986                 e.invincible_finished = 0;
1987         else
1988                 e.invincible_finished += time;
1989         if(e.superweapons_finished <= 0)
1990                 e.superweapons_finished = 0;
1991         else
1992                 e.superweapons_finished += time;
1993
1994         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1995         {
1996                 .entity weaponentity = weaponentities[slot];
1997                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1998                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1999                         _switchweapon |= BIT(slot);
2000         }
2001
2002         if(_switchweapon)
2003         {
2004                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2005                 {
2006                         .entity weaponentity = weaponentities[slot];
2007                         if(_switchweapon & BIT(slot))
2008                         {
2009                                 Weapon wep = w_getbestweapon(e, weaponentity);
2010                                 if(wep != e.(weaponentity).m_switchweapon)
2011                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2012                         }
2013                 }
2014         }
2015
2016         return got;
2017 }
2018 #endif