qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include "../lib/warpzone/util_server.qh"
  26 #elif defined(CSQC)
  27         #include "physics/movetypes/movetypes.qh"
  28         #include <common/weapons/_all.qh>
  29         #include "../lib/csqcmodel/cl_model.qh"
  30         #include "../lib/csqcmodel/common.qh"
  31 #endif
  32
  33 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  34
  35 #ifdef CSQC
  36 bool autocvar_cl_ghost_items_vehicle = true;
  37 .vector item_glowmod;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = '1 1 1';
  46                 this.glowmod = this.item_glowmod;
  47         }
  48         else
  49         {
  50                 if (autocvar_cl_ghost_items_color)
  51                 {
  52                         this.alpha = autocvar_cl_ghost_items;
  53                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  54                 }
  55                 else
  56                         this.alpha = -1;
  57         }
  58
  59         if(!veh_hud)
  60         if(this.ItemStatus & ITS_STAYWEP)
  61         {
  62                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  63                 this.alpha = autocvar_cl_weapon_stay_alpha;
  64         }
  65 }
  66
  67 void ItemDraw(entity this)
  68 {
  69     if(this.gravity)
  70     {
  71         Movetype_Physics_MatchServer(this, false);
  72         if(IS_ONGROUND(this))
  73         { // For some reason avelocity gets set to '0 0 0' here ...
  74             this.oldorigin = this.origin;
  75             this.gravity = 0;
  76
  77             if(autocvar_cl_animate_items)
  78             { // ... so reset it if animations are requested.
  79                 if(this.ItemStatus & ITS_ANIMATE1)
  80                     this.avelocity = '0 180 0';
  81
  82                 if(this.ItemStatus & ITS_ANIMATE2)
  83                     this.avelocity = '0 -90 0';
  84             }
  85
  86             // delay is for blocking item's position for a while;
  87             // it's a workaround for dropped weapons that receive the position
  88             // another time right after they spawn overriding animation position
  89             this.onground_time = time + 0.5;
  90         }
  91     }
  92     else if (autocvar_cl_animate_items)
  93     {
  94         if(this.ItemStatus & ITS_ANIMATE1)
  95         {
  96             this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103             this.angles += this.avelocity * frametime;
 104             float fade_in = bound(0, time - this.onground_time, 1);
 105             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 106         }
 107     }
 108
 109     Item_SetAlpha(this);
 110 }
 111
 112 void ItemDrawSimple(entity this)
 113 {
 114     if(this.gravity)
 115     {
 116         Movetype_Physics_MatchServer(this, false);
 117
 118         if(IS_ONGROUND(this))
 119             this.gravity = 0;
 120     }
 121
 122     Item_SetAlpha(this);
 123 }
 124
 125 void Item_PreDraw(entity this)
 126 {
 127         if(warpzone_warpzones_exist)
 128         {
 129                 // just incase warpzones were initialized last, reset these
 130                 //this.alpha = 1; // alpha is already set by the draw function
 131                 this.drawmask = MASK_NORMAL;
 132                 return;
 133         }
 134         float alph;
 135         vector org = getpropertyvec(VF_ORIGIN);
 136         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 137                 alph = 0;
 138         else if(this.fade_start)
 139                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 140         else
 141                 alph = 1;
 142         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 143         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 144                 this.alpha = alph;
 145         if(alph <= 0)
 146                 this.drawmask = 0;
 147         else
 148                 this.drawmask = MASK_NORMAL;
 149 }
 150
 151 void ItemRemove(entity this)
 152 {
 153         if(this.mdl)
 154                 strunzone(this.mdl);
 155 }
 156
 157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 158 {
 159     int sf = ReadByte();
 160
 161     if(sf & ISF_LOCATION)
 162     {
 163         this.origin_x = ReadCoord();
 164         this.origin_y = ReadCoord();
 165         this.origin_z = ReadCoord();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218         if(this.mdl)
 219             strunzone(this.mdl);
 220
 221         this.mdl = "";
 222         string _fn = ReadString();
 223
 224         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 225         {
 226             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 227             this.draw = ItemDrawSimple;
 228
 229             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 230                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 231             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 237             else
 238             {
 239                 this.draw = ItemDraw;
 240                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 241             }
 242         }
 243
 244         if(this.draw != ItemDrawSimple)
 245             this.mdl = strzone(_fn);
 246
 247
 248         if(this.mdl == "")
 249             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 250
 251         precache_model(this.mdl);
 252         _setmodel(this, this.mdl);
 253
 254         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 255     }
 256
 257     if(sf & ISF_COLORMAP)
 258     {
 259         this.colormap = ReadShort();
 260         this.item_glowmod_x = ReadByte() / 255.0;
 261         this.item_glowmod_y = ReadByte() / 255.0;
 262         this.item_glowmod_z = ReadByte() / 255.0;
 263     }
 264
 265     if(sf & ISF_DROP)
 266     {
 267         this.gravity = 1;
 268         this.pushable = true;
 269         //this.angles = '0 0 0';
 270         set_movetype(this, MOVETYPE_TOSS);
 271         this.velocity_x = ReadCoord();
 272         this.velocity_y = ReadCoord();
 273         this.velocity_z = ReadCoord();
 274         setorigin(this, this.oldorigin);
 275
 276         if(!this.move_time)
 277         {
 278             this.move_time = time;
 279             this.spawntime = time;
 280         }
 281         else
 282             this.move_time = max(this.move_time, time);
 283     }
 284
 285     if(autocvar_cl_animate_items)
 286     {
 287         if(this.ItemStatus & ITS_ANIMATE1)
 288             this.avelocity = '0 180 0';
 289
 290         if(this.ItemStatus & ITS_ANIMATE2)
 291             this.avelocity = '0 -90 0';
 292     }
 293
 294     this.entremove = ItemRemove;
 295
 296     return true;
 297 }
 298
 299 #endif
 300
 301 #ifdef SVQC
 302 bool ItemSend(entity this, entity to, int sf)
 303 {
 304         if(this.gravity)
 305                 sf |= ISF_DROP;
 306         else
 307                 sf &= ~ISF_DROP;
 308
 309         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 310         WriteByte(MSG_ENTITY, sf);
 311
 312         //WriteByte(MSG_ENTITY, this.cnt);
 313         if(sf & ISF_LOCATION)
 314         {
 315                 WriteCoord(MSG_ENTITY, this.origin.x);
 316                 WriteCoord(MSG_ENTITY, this.origin.y);
 317                 WriteCoord(MSG_ENTITY, this.origin.z);
 318         }
 319
 320         if(sf & ISF_ANGLES)
 321         {
 322                 WriteAngle(MSG_ENTITY, this.angles_x);
 323                 WriteAngle(MSG_ENTITY, this.angles_y);
 324                 WriteAngle(MSG_ENTITY, this.angles_z);
 325         }
 326
 327         if(sf & ISF_SIZE)
 328         {
 329                 Pickup p = this.itemdef;
 330                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 331         }
 332
 333         if(sf & ISF_STATUS)
 334                 WriteByte(MSG_ENTITY, this.ItemStatus);
 335
 336         if(sf & ISF_MODEL)
 337         {
 338                 Pickup p = this.itemdef;
 339                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 340                 WriteShort(MSG_ENTITY, this.fade_end);
 341                 WriteShort(MSG_ENTITY, this.fade_start);
 342
 343                 if(this.mdl == "")
 344                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 345
 346                 WriteString(MSG_ENTITY, this.mdl);
 347         }
 348
 349
 350         if(sf & ISF_COLORMAP)
 351         {
 352                 WriteShort(MSG_ENTITY, this.colormap);
 353                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 354         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 356         }
 357
 358         if(sf & ISF_DROP)
 359         {
 360                 WriteCoord(MSG_ENTITY, this.velocity.x);
 361                 WriteCoord(MSG_ENTITY, this.velocity.y);
 362                 WriteCoord(MSG_ENTITY, this.velocity.z);
 363         }
 364
 365         return true;
 366 }
 367
 368 void ItemUpdate(entity this)
 369 {
 370         this.oldorigin = this.origin;
 371         this.SendFlags |= ISF_LOCATION;
 372 }
 373
 374 void UpdateItemAfterTeleport(entity this)
 375 {
 376         if(getSendEntity(this) == ItemSend)
 377                 ItemUpdate(this);
 378 }
 379
 380 bool have_pickup_item(entity this)
 381 {
 382         if(this.itemdef.instanceOfPowerup)
 383         {
 384                 if(autocvar_g_powerups > 0)
 385                         return true;
 386                 if(autocvar_g_powerups == 0)
 387                         return false;
 388         }
 389         else
 390         {
 391                 if(autocvar_g_pickup_items > 0)
 392                         return true;
 393                 if(autocvar_g_pickup_items == 0)
 394                         return false;
 395                 if(g_weaponarena)
 396                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 397                                 return false;
 398         }
 399         return true;
 400 }
 401
 402 /*
 403 float Item_Customize()
 404 {
 405         if(this.spawnshieldtime)
 406                 return true;
 407         if(this.weapons & ~other.weapons)
 408         {
 409                 this.colormod = '0 0 0';
 410                 this.glowmod = this.colormod;
 411                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 412                 return true;
 413         }
 414         else
 415         {
 416                 if(g_ghost_items)
 417                 {
 418                         this.colormod = stov(autocvar_g_ghost_items_color);
 419                         this.glowmod = this.colormod;
 420                         this.alpha = g_ghost_items;
 421                         return true;
 422                 }
 423                 else
 424                         return false;
 425         }
 426 }
 427 */
 428
 429 void Item_Show (entity e, float mode)
 430 {
 431         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 432         e.ItemStatus &= ~ITS_STAYWEP;
 433         entity def = e.itemdef;
 434         if (mode > 0)
 435         {
 436                 // make the item look normal, and be touchable
 437                 e.model = e.mdl;
 438                 e.solid = SOLID_TRIGGER;
 439                 e.spawnshieldtime = 1;
 440                 e.ItemStatus |= ITS_AVAILABLE;
 441         }
 442         else if (mode < 0)
 443         {
 444                 // hide the item completely
 445                 e.model = string_null;
 446                 e.solid = SOLID_NOT;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus &= ~ITS_AVAILABLE;
 449         }
 450         else {
 451         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 452                 || e.team // weapon stay isn't supported for teamed weapons
 453                 ;
 454         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 455         {
 456                 // make the item translucent and not touchable
 457                 e.model = e.mdl;
 458                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 459                 e.effects |= EF_STARDUST;
 460                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 461                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 462         }
 463         else
 464         {
 465                 //setmodel(e, "null");
 466                 e.solid = SOLID_NOT;
 467                 e.colormod = '0 0 0';
 468                 //e.glowmod = e.colormod;
 469                 e.spawnshieldtime = 1;
 470                 e.ItemStatus &= ~ITS_AVAILABLE;
 471         }}
 472
 473         if (def.m_glow)
 474                 e.ItemStatus |= ITS_GLOW;
 475
 476         if (autocvar_g_nodepthtestitems)
 477                 e.effects |= EF_NODEPTHTEST;
 478
 479
 480         if (autocvar_g_fullbrightitems)
 481                 e.ItemStatus |= ITS_ALLOWFB;
 482
 483         if (autocvar_sv_simple_items)
 484                 e.ItemStatus |= ITS_ALLOWSI;
 485
 486         // relink entity (because solid may have changed)
 487         setorigin(e, e.origin);
 488         e.SendFlags |= ISF_STATUS;
 489 }
 490
 491 void Item_Think(entity this)
 492 {
 493         this.nextthink = time;
 494         if(this.origin != this.oldorigin)
 495                 ItemUpdate(this);
 496 }
 497
 498 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 499 bool Item_ItemsTime_Allow(GameItem it);
 500 float Item_ItemsTime_UpdateTime(entity e, float t);
 501 void Item_ItemsTime_SetTime(entity e, float t);
 502 void Item_ItemsTime_SetTimesForAllPlayers();
 503
 504 void Item_Respawn (entity this)
 505 {
 506         Item_Show(this, 1);
 507         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 508         setorigin(this, this.origin);
 509
 510     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 511         {
 512                 float t = Item_ItemsTime_UpdateTime(this, 0);
 513                 Item_ItemsTime_SetTime(this, t);
 514                 Item_ItemsTime_SetTimesForAllPlayers();
 515         }
 516
 517         setthink(this, Item_Think);
 518         this.nextthink = time;
 519
 520         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 521         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 522 }
 523
 524 void Item_RespawnCountdown (entity this)
 525 {
 526         if(this.count >= ITEM_RESPAWN_TICKS)
 527         {
 528                 if(this.waypointsprite_attached)
 529                         WaypointSprite_Kill(this.waypointsprite_attached);
 530                 Item_Respawn(this);
 531         }
 532         else
 533         {
 534                 this.nextthink = time + 1;
 535                 this.count += 1;
 536                 if(this.count == 1)
 537                 {
 538                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 539                         do {
 540                                 {
 541                                         entity wi = Weapons_from(this.weapon);
 542                                         if (wi != WEP_Null) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 544                                                 wp.wp_extra = wi.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                                 {
 549                                         entity ii = this.itemdef;
 550                                         if (ii != NULL) {
 551                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 552                                                 wp.wp_extra = ii.m_id;
 553                                                 break;
 554                                         }
 555                                 }
 556                         } while (0);
 557             if(this.waypointsprite_attached)
 558             {
 559                 GameItem def = this.itemdef;
 560                 if (Item_ItemsTime_SpectatorOnly(def))
 561                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 562                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 563             }
 564                 }
 565
 566                 if(this.waypointsprite_attached)
 567                 {
 568                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 569                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 570                                 {
 571                                         msg_entity = it;
 572                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 573                                 }
 574                         });
 575
 576                         WaypointSprite_Ping(this.waypointsprite_attached);
 577                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 578                 }
 579         }
 580 }
 581
 582 void Item_RespawnThink(entity this)
 583 {
 584         this.nextthink = time;
 585         if(this.origin != this.oldorigin)
 586                 ItemUpdate(this);
 587
 588         if(time >= this.wait)
 589                 Item_Respawn(this);
 590 }
 591
 592 void Item_ScheduleRespawnIn(entity e, float t)
 593 {
 594         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 595         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 596         {
 597                 setthink(e, Item_RespawnCountdown);
 598                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 599                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 600                 e.count = 0;
 601                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 602                 Item_ItemsTime_SetTime(e, t);
 603                 Item_ItemsTime_SetTimesForAllPlayers();
 604         }
 605         else
 606         {
 607                 setthink(e, Item_RespawnThink);
 608                 e.nextthink = time;
 609                 e.scheduledrespawntime = time + t;
 610                 e.wait = time + t;
 611         }
 612 }
 613
 614 void Item_ScheduleRespawn(entity e)
 615 {
 616         if(e.respawntime > 0)
 617         {
 618                 Item_Show(e, 0);
 619                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 620         }
 621         else // if respawntime is -1, this item does not respawn
 622                 Item_Show(e, -1);
 623 }
 624
 625 void Item_ScheduleInitialRespawn(entity e)
 626 {
 627         Item_Show(e, 0);
 628         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 629 }
 630
 631 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 632 {
 633         if (!item.(ammotype))
 634                 return false;
 635
 636         if (item.spawnshieldtime)
 637         {
 638                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 639                 {
 640                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 641                         goto YEAH;
 642                 }
 643         }
 644         else if(g_weapon_stay == 2)
 645         {
 646                 float mi = min(item.(ammotype), ammomax);
 647                 if (player.(ammotype) < mi)
 648                 {
 649                         player.(ammotype) = mi;
 650                         goto YEAH;
 651                 }
 652         }
 653
 654         return false;
 655
 656 LABEL(YEAH)
 657         switch(mode)
 658         {
 659                 case ITEM_MODE_FUEL:
 660                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 661                         break;
 662                 case ITEM_MODE_HEALTH:
 663                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 664                         break;
 665                 case ITEM_MODE_ARMOR:
 666                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 667                         break;
 668                 default:
 669                         break;
 670         }
 671         return true;
 672 }
 673
 674 float Item_GiveTo(entity item, entity player)
 675 {
 676         float _switchweapon;
 677         float pickedup;
 678
 679         // if nothing happens to player, just return without taking the item
 680         pickedup = false;
 681         _switchweapon = false;
 682         // in case the player has autoswitch enabled do the following:
 683         // if the player is using their best weapon before items are given, they
 684         // probably want to switch to an even better weapon after items are given
 685         if (player.autoswitch)
 686         if (PS(player).m_switchweapon == w_getbestweapon(player))
 687                 _switchweapon = true;
 688
 689         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 690                 _switchweapon = true;
 691
 692         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 693         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 694         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 695         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 696         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 697         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 698         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 699         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 700
 701         if (item.itemdef.instanceOfWeaponPickup)
 702         {
 703                 WepSet w;
 704                 w = item.weapons;
 705                 w &= ~player.weapons;
 706
 707                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 708                 {
 709                         pickedup = true;
 710                         FOREACH(Weapons, it != WEP_Null, {
 711                                 if(w & (it.m_wepset))
 712                                 {
 713                                         W_DropEvent(wr_pickup, player, it.m_id, item);
 714                                         W_GiveWeapon(player, it.m_id);
 715                                 }
 716                         });
 717                 }
 718         }
 719
 720         if (item.itemdef.instanceOfPowerup)
 721         {
 722                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 723                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 724                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 725                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 726         }
 727
 728         int its;
 729         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 730         {
 731                 pickedup = true;
 732                 player.items |= its;
 733                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 734         }
 735
 736         if (item.strength_finished)
 737         {
 738                 pickedup = true;
 739                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 740         }
 741         if (item.invincible_finished)
 742         {
 743                 pickedup = true;
 744                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 745         }
 746         if (item.superweapons_finished)
 747         {
 748                 pickedup = true;
 749                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 750         }
 751
 752 LABEL(skip)
 753
 754         // always eat teamed entities
 755         if(item.team)
 756                 pickedup = true;
 757
 758         if (!pickedup)
 759                 return 0;
 760
 761         // crude hack to enforce switching weapons
 762         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 763         {
 764                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 765                 return 1;
 766         }
 767
 768         if (_switchweapon)
 769                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 770                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 771
 772         return 1;
 773 }
 774
 775 void Item_Touch(entity this, entity toucher)
 776 {
 777
 778         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 779         if (this.classname == "droppedweapon")
 780         {
 781                 if (ITEM_TOUCH_NEEDKILL())
 782                 {
 783                         delete(this);
 784                         return;
 785                 }
 786         }
 787
 788         if(!(toucher.flags & FL_PICKUPITEMS)
 789         || STAT(FROZEN, toucher)
 790         || IS_DEAD(toucher)
 791         || (this.solid != SOLID_TRIGGER)
 792         || (this.owner == toucher)
 793         || (time < this.item_spawnshieldtime)
 794         ) { return; }
 795
 796         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 797         {
 798                 case MUT_ITEMTOUCH_RETURN: { return; }
 799                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 800         }
 801
 802         toucher = M_ARGV(1, entity);
 803
 804         if (this.classname == "droppedweapon")
 805         {
 806                 this.strength_finished = max(0, this.strength_finished - time);
 807                 this.invincible_finished = max(0, this.invincible_finished - time);
 808                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 809         }
 810         entity it = this.itemdef;
 811         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 812         if (!gave)
 813         {
 814                 if (this.classname == "droppedweapon")
 815                 {
 816                         // undo what we did above
 817                         this.strength_finished += time;
 818                         this.invincible_finished += time;
 819                         this.superweapons_finished += time;
 820                 }
 821                 return;
 822         }
 823
 824 LABEL(pickup)
 825
 826         toucher.last_pickup = time;
 827
 828         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 829         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 830
 831         if (this.classname == "droppedweapon")
 832                 delete (this);
 833         else if (this.spawnshieldtime)
 834         {
 835                 entity e;
 836                 if(this.team)
 837                 {
 838                         RandomSelection_Init();
 839                         IL_EACH(g_items, it.team == this.team,
 840                         {
 841                                 if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 842                                 {
 843                                         Item_Show(it, -1);
 844                                         RandomSelection_AddEnt(it, it.cnt, 0);
 845                                 }
 846                         });
 847                         e = RandomSelection_chosen_ent;
 848
 849                 }
 850                 else
 851                         e = this;
 852                 Item_ScheduleRespawn(e);
 853         }
 854 }
 855
 856 void Item_Reset(entity this)
 857 {
 858         Item_Show(this, !this.state);
 859         setorigin(this, this.origin);
 860
 861         if (this.classname != "droppedweapon")
 862         {
 863                 setthink(this, Item_Think);
 864                 this.nextthink = time;
 865
 866                 if (this.waypointsprite_attached)
 867                         WaypointSprite_Kill(this.waypointsprite_attached);
 868
 869                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 870                         Item_ScheduleInitialRespawn(this);
 871         }
 872 }
 873
 874 void Item_FindTeam(entity this)
 875 {
 876         entity e;
 877
 878         if(this.effects & EF_NODRAW)
 879         {
 880                 // marker for item team search
 881                 LOG_TRACE("Initializing item team ", ftos(this.team));
 882                 RandomSelection_Init();
 883                 IL_EACH(g_items, it.team == this.team,
 884                 {
 885                         if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 886                                 RandomSelection_AddEnt(it, it.cnt, 0);
 887                 });
 888
 889                 e = RandomSelection_chosen_ent;
 890                 e.state = 0;
 891                 Item_Show(e, 1);
 892
 893                 IL_EACH(g_items, it.team == this.team,
 894                 {
 895                         if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 896                         {
 897                                 if(it != e)
 898                                 {
 899                                         // make it non-spawned
 900                                         Item_Show(it, -1);
 901                                         it.state = 1; // state 1 = initially hidden item, apparently
 902                                 }
 903                                 it.effects &= ~EF_NODRAW;
 904                         }
 905                 });
 906
 907                 Item_Reset(this);
 908         }
 909 }
 910
 911 // Savage: used for item garbage-collection
 912 void RemoveItem(entity this)
 913 {
 914         if(wasfreed(this) || !this) { return; }
 915         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 916         delete(this);
 917 }
 918
 919 // pickup evaluation functions
 920 // these functions decide how desirable an item is to the bots
 921
 922 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 923
 924 float weapon_pickupevalfunc(entity player, entity item)
 925 {
 926         float c;
 927
 928         // See if I have it already
 929         if(item.weapons & ~player.weapons)
 930         {
 931                 // If I can pick it up
 932                 if(!item.spawnshieldtime)
 933                         c = 0;
 934                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 935                 {
 936                         // Skilled bots will grab more
 937                         c = bound(0, skill / 10, 1) * 0.5;
 938                 }
 939                 else
 940                         c = 0;
 941         }
 942         else
 943                 c = 1;
 944
 945         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 946         if( bot_custom_weapon && c )
 947         {
 948                 // Find the highest position on any range
 949                 int position = -1;
 950                 for (int j = 0; j < WEP_LAST ; ++j){
 951                         if(
 952                                         bot_weapons_far[j] == item.weapon ||
 953                                         bot_weapons_mid[j] == item.weapon ||
 954                                         bot_weapons_close[j] == item.weapon
 955                           )
 956                         {
 957                                 position = j;
 958                                 break;
 959                         }
 960                 }
 961
 962                 // Rate it
 963                 if (position >= 0 )
 964                 {
 965                         position = WEP_LAST - position;
 966                         // item.bot_pickupbasevalue is overwritten here
 967                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 968                 }
 969         }
 970
 971         return item.bot_pickupbasevalue * c;
 972 }
 973
 974 float commodity_pickupevalfunc(entity player, entity item)
 975 {
 976         float c;
 977         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 978         c = 0;
 979
 980         // Detect needed ammo
 981         FOREACH(Weapons, it != WEP_Null, {
 982                 if(!(player.weapons & (it.m_wepset)))
 983                         continue;
 984
 985                 if(it.items & ITEM_Shells.m_itemid)
 986                         need_shells = true;
 987                 else if(it.items & ITEM_Bullets.m_itemid)
 988                         need_nails = true;
 989                 else if(it.items & ITEM_Rockets.m_itemid)
 990                         need_rockets = true;
 991                 else if(it.items & ITEM_Cells.m_itemid)
 992                         need_cells = true;
 993                 else if(it.items & ITEM_Plasma.m_itemid)
 994                         need_plasma = true;
 995                 else if(it.items & ITEM_JetpackFuel.m_itemid)
 996                         need_fuel = true;
 997         });
 998
 999         // TODO: figure out if the player even has the weapon this ammo is for?
1000         // may not affect strategy much though...
1001         // find out how much more ammo/armor/health the player can hold
1002         if (need_shells)
1003         if (item.ammo_shells)
1004         if (player.ammo_shells < g_pickup_shells_max)
1005                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1006         if (need_nails)
1007         if (item.ammo_nails)
1008         if (player.ammo_nails < g_pickup_nails_max)
1009                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1010         if (need_rockets)
1011         if (item.ammo_rockets)
1012         if (player.ammo_rockets < g_pickup_rockets_max)
1013                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1014         if (need_cells)
1015         if (item.ammo_cells)
1016         if (player.ammo_cells < g_pickup_cells_max)
1017                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1018         if (need_plasma)
1019         if (item.ammo_plasma)
1020         if (player.ammo_plasma < g_pickup_plasma_max)
1021                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1022         if (need_fuel)
1023         if (item.ammo_fuel)
1024         if (player.ammo_fuel < g_pickup_fuel_max)
1025                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1026         if (item.armorvalue)
1027         if (player.armorvalue < item.max_armorvalue)
1028                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1029         if (item.health)
1030         if (player.health < item.max_health)
1031                 c = c + max(0, 1 - player.health / item.max_health);
1032
1033         return item.bot_pickupbasevalue * c;
1034 }
1035
1036 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1037 {
1038         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1039                 RemoveItem(this);
1040 }
1041
1042 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1043 {
1044         string itemname = def.m_name;
1045         Model itemmodel = def.m_model;
1046     Sound pickupsound = def.m_sound;
1047         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1048         float pickupbasevalue = def.m_botvalue;
1049         int itemflags = def.m_itemflags;
1050
1051         startitem_failed = false;
1052
1053         this.item_model_ent = itemmodel;
1054     this.item_pickupsound_ent = pickupsound;
1055
1056         if(!this.respawntime) // both need to be set
1057         {
1058                 this.respawntime = defaultrespawntime;
1059                 this.respawntimejitter = defaultrespawntimejitter;
1060         }
1061
1062         int itemid = def.m_itemid;
1063         this.items = itemid;
1064         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1065         this.weapon = weaponid;
1066
1067         if(!this.fade_end)
1068         {
1069                 this.fade_start = autocvar_g_items_mindist;
1070                 this.fade_end = autocvar_g_items_maxdist;
1071         }
1072
1073         if(weaponid)
1074                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1075
1076         this.flags = FL_ITEM | itemflags;
1077         IL_PUSH(g_items, this);
1078
1079         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1080         {
1081                 startitem_failed = true;
1082                 delete(this);
1083                 return;
1084         }
1085
1086         // is it a dropped weapon?
1087         if (this.classname == "droppedweapon")
1088         {
1089                 this.reset = SUB_Remove;
1090                 // it's a dropped weapon
1091                 set_movetype(this, MOVETYPE_TOSS);
1092
1093                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1094                 setthink(this, RemoveItem);
1095                 this.nextthink = time + 20;
1096
1097                 this.takedamage = DAMAGE_YES;
1098                 this.event_damage = Item_Damage;
1099
1100                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1101                 {
1102                         // if item is worthless after a timer, have it expire then
1103                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1104                 }
1105
1106                 // don't drop if in a NODROP zone (such as lava)
1107                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1108                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1109                 {
1110                         startitem_failed = true;
1111                         delete(this);
1112                         return;
1113                 }
1114         }
1115         else
1116         {
1117                 if(!have_pickup_item(this))
1118                 {
1119                         startitem_failed = true;
1120                         delete (this);
1121                         return;
1122                 }
1123
1124                 if(this.angles != '0 0 0')
1125                         this.SendFlags |= ISF_ANGLES;
1126
1127                 this.reset = Item_Reset;
1128                 // it's a level item
1129                 if(this.spawnflags & 1)
1130                         this.noalign = 1;
1131                 if (this.noalign > 0)
1132                         set_movetype(this, MOVETYPE_NONE);
1133                 else
1134                         set_movetype(this, MOVETYPE_TOSS);
1135                 // do item filtering according to game mode and other things
1136                 if (this.noalign <= 0)
1137                 {
1138                         // first nudge it off the floor a little bit to avoid math errors
1139                         setorigin(this, this.origin + '0 0 1');
1140                         // set item size before we spawn a spawnfunc_waypoint
1141                         setsize(this, def.m_mins, def.m_maxs);
1142                         this.SendFlags |= ISF_SIZE;
1143                         // note droptofloor returns false if stuck/or would fall too far
1144                         if (!this.noalign)
1145                                 droptofloor(this);
1146                         waypoint_spawnforitem(this);
1147                 }
1148
1149                 /*
1150                  * can't do it that way, as it would break maps
1151                  * TODO make a target_give like entity another way, that perhaps has
1152                  * the weapon name in a key
1153                 if(this.targetname)
1154                 {
1155                         // target_give not yet supported; maybe later
1156                         print("removed targeted ", this.classname, "\n");
1157                         startitem_failed = true;
1158                         remove (this);
1159                         return;
1160                 }
1161                 */
1162
1163                 if(autocvar_spawn_debug >= 2)
1164                 {
1165             // why not flags & fl_item?
1166                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1167                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1168                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1169                 error("Mapper sucks.");
1170             });
1171                         this.is_item = true;
1172                 }
1173
1174                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1175
1176                 precache_model(this.model);
1177                 precache_sound(this.item_pickupsound);
1178
1179                 if (   def.instanceOfPowerup
1180                         || def.instanceOfWeaponPickup
1181                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1182                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1183                         || (itemid & (IT_KEY1 | IT_KEY2))
1184                 ) this.target = "###item###"; // for finding the nearest item using find()
1185
1186                 Item_ItemsTime_SetTime(this, 0);
1187         }
1188
1189         this.bot_pickup = true;
1190         this.bot_pickupevalfunc = pickupevalfunc;
1191         this.bot_pickupbasevalue = pickupbasevalue;
1192         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1193         this.netname = itemname;
1194         settouch(this, Item_Touch);
1195         setmodel(this, MDL_Null); // precision set below
1196         //this.effects |= EF_LOWPRECISION;
1197
1198         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1199
1200         this.SendFlags |= ISF_SIZE;
1201
1202         if (!(this.spawnflags & 1024)) {
1203                 if(def.instanceOfPowerup)
1204                         this.ItemStatus |= ITS_ANIMATE1;
1205
1206                 if(this.armorvalue || this.health)
1207                         this.ItemStatus |= ITS_ANIMATE2;
1208         }
1209
1210         if(def.instanceOfWeaponPickup)
1211         {
1212                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1213                         this.colormap = 1024; // color shirt=0 pants=0 grey
1214                 else
1215                         this.gravity = 1;
1216                 if (!(this.spawnflags & 1024))
1217                         this.ItemStatus |= ITS_ANIMATE1;
1218                 this.SendFlags |= ISF_COLORMAP;
1219         }
1220
1221         this.state = 0;
1222         if(this.team) // broken, no idea why.
1223         {
1224                 if(!this.cnt)
1225                         this.cnt = 1; // item probability weight
1226
1227                 this.effects |= EF_NODRAW; // marker for item team search
1228                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1229         }
1230         else
1231                 Item_Reset(this);
1232
1233         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1234
1235         // call this hook after everything else has been done
1236         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1237         {
1238                 startitem_failed = true;
1239                 delete(this);
1240                 return;
1241         }
1242 }
1243
1244 void StartItem(entity this, GameItem def)
1245 {
1246     _StartItem(
1247         this,
1248         this.itemdef = def,
1249         def.m_respawntime(), // defaultrespawntime
1250         def.m_respawntimejitter() // defaultrespawntimejitter
1251         );
1252 }
1253
1254 spawnfunc(item_rockets)
1255 {
1256         if(!this.ammo_rockets)
1257                 this.ammo_rockets = g_pickup_rockets;
1258         if(!this.pickup_anyway)
1259                 this.pickup_anyway = g_pickup_ammo_anyway;
1260     StartItem(this, ITEM_Rockets);
1261 }
1262
1263 spawnfunc(item_bullets)
1264 {
1265         if(!weaponswapping)
1266         if(autocvar_sv_q3acompat_machineshotgunswap)
1267         if(this.classname != "droppedweapon")
1268         {
1269                 weaponswapping = true;
1270                 spawnfunc_item_shells(this);
1271                 weaponswapping = false;
1272                 return;
1273         }
1274
1275         if(!this.ammo_nails)
1276                 this.ammo_nails = g_pickup_nails;
1277         if(!this.pickup_anyway)
1278                 this.pickup_anyway = g_pickup_ammo_anyway;
1279     StartItem(this, ITEM_Bullets);
1280 }
1281
1282 spawnfunc(item_cells)
1283 {
1284         if(!this.ammo_cells)
1285                 this.ammo_cells = g_pickup_cells;
1286         if(!this.pickup_anyway)
1287                 this.pickup_anyway = g_pickup_ammo_anyway;
1288         StartItem(this, ITEM_Cells);
1289 }
1290
1291 spawnfunc(item_plasma)
1292 {
1293         if(!this.ammo_plasma)
1294                 this.ammo_plasma = g_pickup_plasma;
1295         if(!this.pickup_anyway)
1296                 this.pickup_anyway = g_pickup_ammo_anyway;
1297         StartItem(this, ITEM_Plasma);
1298 }
1299
1300 spawnfunc(item_shells)
1301 {
1302         if(!weaponswapping)
1303         if(autocvar_sv_q3acompat_machineshotgunswap)
1304         if(this.classname != "droppedweapon")
1305         {
1306                 weaponswapping = true;
1307                 spawnfunc_item_bullets(this);
1308                 weaponswapping = false;
1309                 return;
1310         }
1311
1312         if(!this.ammo_shells)
1313                 this.ammo_shells = g_pickup_shells;
1314         if(!this.pickup_anyway)
1315                 this.pickup_anyway = g_pickup_ammo_anyway;
1316         StartItem(this, ITEM_Shells);
1317 }
1318
1319 spawnfunc(item_armor_small)
1320 {
1321         if(!this.armorvalue)
1322                 this.armorvalue = g_pickup_armorsmall;
1323         if(!this.max_armorvalue)
1324                 this.max_armorvalue = g_pickup_armorsmall_max;
1325         if(!this.pickup_anyway)
1326                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1327         StartItem(this, ITEM_ArmorSmall);
1328 }
1329
1330 spawnfunc(item_armor_medium)
1331 {
1332         if(!this.armorvalue)
1333                 this.armorvalue = g_pickup_armormedium;
1334         if(!this.max_armorvalue)
1335                 this.max_armorvalue = g_pickup_armormedium_max;
1336         if(!this.pickup_anyway)
1337                 this.pickup_anyway = g_pickup_armormedium_anyway;
1338         StartItem(this, ITEM_ArmorMedium);
1339 }
1340
1341 spawnfunc(item_armor_big)
1342 {
1343         if(!this.armorvalue)
1344                 this.armorvalue = g_pickup_armorbig;
1345         if(!this.max_armorvalue)
1346                 this.max_armorvalue = g_pickup_armorbig_max;
1347         if(!this.pickup_anyway)
1348                 this.pickup_anyway = g_pickup_armorbig_anyway;
1349         StartItem(this, ITEM_ArmorLarge);
1350 }
1351
1352 spawnfunc(item_armor_large)
1353 {
1354         if(!this.armorvalue)
1355                 this.armorvalue = g_pickup_armorlarge;
1356         if(!this.max_armorvalue)
1357                 this.max_armorvalue = g_pickup_armorlarge_max;
1358         if(!this.pickup_anyway)
1359                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1360         StartItem(this, ITEM_ArmorMega);
1361 }
1362
1363 spawnfunc(item_health_small)
1364 {
1365         if(!this.max_health)
1366                 this.max_health = g_pickup_healthsmall_max;
1367         if(!this.health)
1368                 this.health = g_pickup_healthsmall;
1369         if(!this.pickup_anyway)
1370                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1371         StartItem(this, ITEM_HealthSmall);
1372 }
1373
1374 spawnfunc(item_health_medium)
1375 {
1376         if(!this.max_health)
1377                 this.max_health = g_pickup_healthmedium_max;
1378         if(!this.health)
1379                 this.health = g_pickup_healthmedium;
1380         if(!this.pickup_anyway)
1381                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1382     StartItem(this, ITEM_HealthMedium);
1383 }
1384
1385 spawnfunc(item_health_large)
1386 {
1387         if(!this.max_health)
1388                 this.max_health = g_pickup_healthlarge_max;
1389         if(!this.health)
1390                 this.health = g_pickup_healthlarge;
1391         if(!this.pickup_anyway)
1392                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1393         StartItem(this, ITEM_HealthLarge);
1394 }
1395
1396 spawnfunc(item_health_mega)
1397 {
1398     if(!this.max_health)
1399         this.max_health = g_pickup_healthmega_max;
1400     if(!this.health)
1401         this.health = g_pickup_healthmega;
1402     if(!this.pickup_anyway)
1403         this.pickup_anyway = g_pickup_healthmega_anyway;
1404     StartItem(this, ITEM_HealthMega);
1405 }
1406
1407 // support old misnamed entities
1408 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1409 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1410 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1411 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1412 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1413
1414 spawnfunc(item_strength)
1415 {
1416                 if(!this.strength_finished)
1417                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1418                 StartItem(this, ITEM_Strength);
1419 }
1420
1421 spawnfunc(item_invincible)
1422 {
1423                 if(!this.invincible_finished)
1424                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1425                 StartItem(this, ITEM_Shield);
1426 }
1427
1428 // compatibility:
1429 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1430
1431 void target_items_use(entity this, entity actor, entity trigger)
1432 {
1433         if(actor.classname == "droppedweapon")
1434         {
1435                 EXACTTRIGGER_TOUCH(this, trigger);
1436                 delete(actor);
1437                 return;
1438         }
1439
1440         if (!IS_PLAYER(actor))
1441                 return;
1442         if(IS_DEAD(actor))
1443                 return;
1444         if(trigger.solid == SOLID_TRIGGER)
1445         {
1446                 EXACTTRIGGER_TOUCH(this, trigger);
1447         }
1448
1449         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1450         {
1451                 delete(it);
1452         });
1453
1454         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1455                 centerprint(actor, this.message);
1456 }
1457
1458 spawnfunc(target_items)
1459 {
1460         int n, j;
1461         string s;
1462
1463         this.use = target_items_use;
1464         if(!this.strength_finished)
1465                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1466         if(!this.invincible_finished)
1467                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1468         if(!this.superweapons_finished)
1469                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1470
1471         n = tokenize_console(this.netname);
1472         if(argv(0) == "give")
1473         {
1474                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1475         }
1476         else
1477         {
1478                 for(j = 0; j < n; ++j)
1479                 {
1480                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1481                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1482                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1483                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1484                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1485                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1486                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1487                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1488                         else
1489                         {
1490                                 FOREACH(Weapons, it != WEP_Null, {
1491                                         s = W_UndeprecateName(argv(j));
1492                                         if(s == it.netname)
1493                                         {
1494                                                 this.weapons |= (it.m_wepset);
1495                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1496                                                         it.wr_init(it);
1497                                                 break;
1498                                         }
1499                                 });
1500                         }
1501                 }
1502
1503                 string itemprefix, valueprefix;
1504                 if(this.spawnflags == 0)
1505                 {
1506                         itemprefix = "";
1507                         valueprefix = "";
1508                 }
1509                 else if(this.spawnflags == 1)
1510                 {
1511                         itemprefix = "max ";
1512                         valueprefix = "max ";
1513                 }
1514                 else if(this.spawnflags == 2)
1515                 {
1516                         itemprefix = "min ";
1517                         valueprefix = "min ";
1518                 }
1519                 else if(this.spawnflags == 4)
1520                 {
1521                         itemprefix = "minus ";
1522                         valueprefix = "max ";
1523                 }
1524                 else
1525                 {
1526                         error("invalid spawnflags");
1527                         itemprefix = valueprefix = string_null;
1528                 }
1529
1530                 this.netname = "";
1531                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1532                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1533                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1534                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1535                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1536                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1537                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1538                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1539                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1540                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1541                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1542                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1543                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1544                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1545                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1546                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1547         }
1548         this.netname = strzone(this.netname);
1549         //print(this.netname, "\n");
1550
1551         n = tokenize_console(this.netname);
1552         for(j = 0; j < n; ++j)
1553         {
1554                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1555             it.wr_init(it);
1556             break;
1557                 });
1558         }
1559 }
1560
1561 spawnfunc(item_fuel)
1562 {
1563         if(!this.ammo_fuel)
1564                 this.ammo_fuel = g_pickup_fuel;
1565         if(!this.pickup_anyway)
1566                 this.pickup_anyway = g_pickup_ammo_anyway;
1567         StartItem(this, ITEM_JetpackFuel);
1568 }
1569
1570 spawnfunc(item_fuel_regen)
1571 {
1572         if(start_items & ITEM_JetpackRegen.m_itemid)
1573         {
1574                 spawnfunc_item_fuel(this);
1575                 return;
1576         }
1577         StartItem(this, ITEM_JetpackRegen);
1578 }
1579
1580 spawnfunc(item_jetpack)
1581 {
1582         if(!this.ammo_fuel)
1583                 this.ammo_fuel = g_pickup_fuel_jetpack;
1584         if(start_items & ITEM_Jetpack.m_itemid)
1585         {
1586                 spawnfunc_item_fuel(this);
1587                 return;
1588         }
1589         StartItem(this, ITEM_Jetpack);
1590 }
1591
1592 float GiveWeapon(entity e, float wpn, float op, float val)
1593 {
1594         WepSet v0, v1;
1595         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1596         v0 = (e.weapons & s);
1597         switch(op)
1598         {
1599                 case OP_SET:
1600                         if(val > 0)
1601                                 e.weapons |= s;
1602                         else
1603                                 e.weapons &= ~s;
1604                         break;
1605                 case OP_MIN:
1606                 case OP_PLUS:
1607                         if(val > 0)
1608                                 e.weapons |= s;
1609                         break;
1610                 case OP_MAX:
1611                         if(val <= 0)
1612                                 e.weapons &= ~s;
1613                         break;
1614                 case OP_MINUS:
1615                         if(val > 0)
1616                                 e.weapons &= ~s;
1617                         break;
1618         }
1619         v1 = (e.weapons & s);
1620         return (v0 != v1);
1621 }
1622
1623 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1624 {
1625         if(v1 == v0)
1626                 return;
1627         if(v1 <= v0 - t)
1628         {
1629                 if(snd_decr != NULL)
1630                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1631         }
1632         else if(v0 >= v0 + t)
1633         {
1634                 if(snd_incr != NULL)
1635                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1636         }
1637 }
1638
1639 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1640 {
1641         if(v0 < v1)
1642                 e.(rotfield) = max(e.(rotfield), time + rottime);
1643         else if(v0 > v1)
1644                 e.(regenfield) = max(e.(regenfield), time + regentime);
1645 }
1646 float GiveItems(entity e, float beginarg, float endarg)
1647 {
1648         float got, i, val, op;
1649         float _switchweapon;
1650         string cmd;
1651
1652         val = 999;
1653         op = OP_SET;
1654
1655         got = 0;
1656
1657         _switchweapon = false;
1658         if (e.autoswitch)
1659                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1660                         _switchweapon = true;
1661
1662         e.strength_finished = max(0, e.strength_finished - time);
1663         e.invincible_finished = max(0, e.invincible_finished - time);
1664         e.superweapons_finished = max(0, e.superweapons_finished - time);
1665
1666         PREGIVE(e, items);
1667         PREGIVE_WEAPONS(e);
1668         PREGIVE(e, strength_finished);
1669         PREGIVE(e, invincible_finished);
1670         PREGIVE(e, superweapons_finished);
1671         PREGIVE(e, ammo_nails);
1672         PREGIVE(e, ammo_cells);
1673         PREGIVE(e, ammo_plasma);
1674         PREGIVE(e, ammo_shells);
1675         PREGIVE(e, ammo_rockets);
1676         PREGIVE(e, ammo_fuel);
1677         PREGIVE(e, armorvalue);
1678         PREGIVE(e, health);
1679
1680         for(i = beginarg; i < endarg; ++i)
1681         {
1682                 cmd = argv(i);
1683
1684                 if(cmd == "0" || stof(cmd))
1685                 {
1686                         val = stof(cmd);
1687                         continue;
1688                 }
1689                 switch(cmd)
1690                 {
1691                         case "no":
1692                                 op = OP_MAX;
1693                                 val = 0;
1694                                 continue;
1695                         case "max":
1696                                 op = OP_MAX;
1697                                 continue;
1698                         case "min":
1699                                 op = OP_MIN;
1700                                 continue;
1701                         case "plus":
1702                                 op = OP_PLUS;
1703                                 continue;
1704                         case "minus":
1705                                 op = OP_MINUS;
1706                                 continue;
1707                         case "ALL":
1708                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1709                                 got += GiveValue(e, strength_finished, op, val);
1710                                 got += GiveValue(e, invincible_finished, op, val);
1711                                 got += GiveValue(e, superweapons_finished, op, val);
1712                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1713                         case "all":
1714                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1715                                 got += GiveValue(e, health, op, val);
1716                                 got += GiveValue(e, armorvalue, op, val);
1717                         case "allweapons":
1718                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1719                         case "allammo":
1720                                 got += GiveValue(e, ammo_cells, op, val);
1721                                 got += GiveValue(e, ammo_plasma, op, val);
1722                                 got += GiveValue(e, ammo_shells, op, val);
1723                                 got += GiveValue(e, ammo_nails, op, val);
1724                                 got += GiveValue(e, ammo_rockets, op, val);
1725                                 got += GiveValue(e, ammo_fuel, op, val);
1726                                 break;
1727                         case "unlimited_ammo":
1728                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1729                                 break;
1730                         case "unlimited_weapon_ammo":
1731                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1732                                 break;
1733                         case "unlimited_superweapons":
1734                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1735                                 break;
1736                         case "jetpack":
1737                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1738                                 break;
1739                         case "fuel_regen":
1740                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1741                                 break;
1742                         case "strength":
1743                                 got += GiveValue(e, strength_finished, op, val);
1744                                 break;
1745                         case "invincible":
1746                                 got += GiveValue(e, invincible_finished, op, val);
1747                                 break;
1748                         case "superweapons":
1749                                 got += GiveValue(e, superweapons_finished, op, val);
1750                                 break;
1751                         case "cells":
1752                                 got += GiveValue(e, ammo_cells, op, val);
1753                                 break;
1754                         case "plasma":
1755                                 got += GiveValue(e, ammo_plasma, op, val);
1756                                 break;
1757                         case "shells":
1758                                 got += GiveValue(e, ammo_shells, op, val);
1759                                 break;
1760                         case "nails":
1761                         case "bullets":
1762                                 got += GiveValue(e, ammo_nails, op, val);
1763                                 break;
1764                         case "rockets":
1765                                 got += GiveValue(e, ammo_rockets, op, val);
1766                                 break;
1767                         case "health":
1768                                 got += GiveValue(e, health, op, val);
1769                                 break;
1770                         case "armor":
1771                                 got += GiveValue(e, armorvalue, op, val);
1772                                 break;
1773                         case "fuel":
1774                                 got += GiveValue(e, ammo_fuel, op, val);
1775                                 break;
1776                         default:
1777                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1778                     got += GiveWeapon(e, it.m_id, op, val);
1779                     break;
1780                                 });
1781                                 break;
1782                 }
1783                 val = 999;
1784                 op = OP_SET;
1785         }
1786
1787         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1788         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1789         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1790         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1791         FOREACH(Weapons, it != WEP_Null, {
1792                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1793                 if(!(save_weapons & (it.m_wepset)))
1794                         if(e.weapons & (it.m_wepset))
1795                                 it.wr_init(it);
1796         });
1797         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1798         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1799         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1800         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1801         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1802         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1803         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1804         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1805         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1806         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1807
1808         if(e.superweapons_finished <= 0)
1809                 if(e.weapons & WEPSET_SUPERWEAPONS)
1810                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1811
1812         if(e.strength_finished <= 0)
1813                 e.strength_finished = 0;
1814         else
1815                 e.strength_finished += time;
1816         if(e.invincible_finished <= 0)
1817                 e.invincible_finished = 0;
1818         else
1819                 e.invincible_finished += time;
1820         if(e.superweapons_finished <= 0)
1821                 e.superweapons_finished = 0;
1822         else
1823                 e.superweapons_finished += time;
1824
1825         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1826                 _switchweapon = true;
1827         if(_switchweapon)
1828                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1829
1830         return got;
1831 }
1832 #endif