Merged Lyberta/GivePlayerAmmo into Lyberta/RandomStartWeapons.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66
67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
68 }
69
70 void ItemDraw(entity this)
71 {
72     if(this.gravity)
73     {
74         Movetype_Physics_MatchServer(this, false);
75         if(IS_ONGROUND(this))
76         { // For some reason avelocity gets set to '0 0 0' here ...
77             this.oldorigin = this.origin;
78             this.gravity = 0;
79
80             if(autocvar_cl_animate_items)
81             { // ... so reset it if animations are requested.
82                 if(this.ItemStatus & ITS_ANIMATE1)
83                     this.avelocity = '0 180 0';
84
85                 if(this.ItemStatus & ITS_ANIMATE2)
86                     this.avelocity = '0 -90 0';
87             }
88
89             // delay is for blocking item's position for a while;
90             // it's a workaround for dropped weapons that receive the position
91             // another time right after they spawn overriding animation position
92             this.onground_time = time + 0.5;
93         }
94     }
95     else if (autocvar_cl_animate_items)
96     {
97         if(this.ItemStatus & ITS_ANIMATE1)
98         {
99             this.angles += this.avelocity * frametime;
100             float fade_in = bound(0, time - this.onground_time, 1);
101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
102         }
103
104         if(this.ItemStatus & ITS_ANIMATE2)
105         {
106             this.angles += this.avelocity * frametime;
107             float fade_in = bound(0, time - this.onground_time, 1);
108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
109         }
110     }
111
112     Item_SetAlpha(this);
113 }
114
115 void ItemDrawSimple(entity this)
116 {
117     if(this.gravity)
118     {
119         Movetype_Physics_MatchServer(this, false);
120
121         if(IS_ONGROUND(this))
122             this.gravity = 0;
123     }
124
125     Item_SetAlpha(this);
126 }
127
128 void Item_PreDraw(entity this)
129 {
130         if(warpzone_warpzones_exist)
131         {
132                 setpredraw(this, func_null); // no need to keep running this
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
139         if(this.fade_start)
140         {
141                 if(vdist(org - this.origin, >, this.fade_end))
142                         alph = 0; // save on some processing
143                 else if(vdist(org - this.origin, <, this.fade_start))
144                         alph = 1; // more processing saved
145                 else
146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
147         }
148         else
149                 alph = 1;
150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
152                 this.alpha = alph;
153         if(alph <= 0)
154                 this.drawmask = 0;
155         //else
156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
157 }
158
159 void ItemRemove(entity this)
160 {
161         if(this.mdl)
162                 strunzone(this.mdl);
163 }
164
165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
166 {
167     int sf = ReadByte();
168
169     if(sf & ISF_LOCATION)
170     {
171         this.origin_x = ReadCoord();
172         this.origin_y = ReadCoord();
173         this.origin_z = ReadCoord();
174         setorigin(this, this.origin);
175         this.oldorigin = this.origin;
176     }
177
178     if(sf & ISF_ANGLES)
179     {
180         this.angles_x = ReadAngle();
181         this.angles_y = ReadAngle();
182         this.angles_z = ReadAngle();
183     }
184
185     if(sf & ISF_SIZE)
186     {
187         float use_bigsize = ReadByte();
188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
189     }
190
191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
192     {
193         this.ItemStatus = ReadByte();
194
195         Item_SetAlpha(this);
196
197         if(autocvar_cl_fullbright_items)
198             if(this.ItemStatus & ITS_ALLOWFB)
199                 this.effects |= EF_FULLBRIGHT;
200
201         if(this.ItemStatus & ITS_GLOW)
202         {
203             if(this.ItemStatus & ITS_AVAILABLE)
204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
205             else
206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
207         }
208     }
209
210     if(sf & ISF_MODEL)
211     {
212         this.drawmask  = MASK_NORMAL;
213                 set_movetype(this, MOVETYPE_TOSS);
214                 if (isnew) IL_PUSH(g_drawables, this);
215         this.draw       = ItemDraw;
216         this.solid = SOLID_TRIGGER;
217         //this.flags |= FL_ITEM;
218
219         bool use_bigsize = ReadByte();
220
221         this.fade_end = ReadShort();
222         this.fade_start = ReadShort();
223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
224                 setpredraw(this, Item_PreDraw);
225
226         if(this.mdl)
227             strunzone(this.mdl);
228
229         this.mdl = "";
230         string _fn = ReadString();
231
232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
233         {
234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
235             this.draw = ItemDrawSimple;
236
237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
245             else
246             {
247                 this.draw = ItemDraw;
248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
249             }
250         }
251
252         if(this.draw != ItemDrawSimple)
253             this.mdl = strzone(_fn);
254
255
256         if(this.mdl == "")
257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
258
259         precache_model(this.mdl);
260         _setmodel(this, this.mdl);
261
262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
263     }
264
265     if(sf & ISF_COLORMAP)
266     {
267         this.colormap = ReadShort();
268         this.item_glowmod_x = ReadByte() / 255.0;
269         this.item_glowmod_y = ReadByte() / 255.0;
270         this.item_glowmod_z = ReadByte() / 255.0;
271     }
272
273     if(sf & ISF_DROP)
274     {
275         this.gravity = 1;
276         this.pushable = true;
277         //this.angles = '0 0 0';
278         set_movetype(this, MOVETYPE_TOSS);
279         this.velocity_x = ReadCoord();
280         this.velocity_y = ReadCoord();
281         this.velocity_z = ReadCoord();
282         setorigin(this, this.oldorigin);
283
284         if(!this.move_time)
285         {
286             this.move_time = time;
287             this.spawntime = time;
288         }
289         else
290             this.move_time = max(this.move_time, time);
291     }
292
293     if(autocvar_cl_animate_items)
294     {
295         if(this.ItemStatus & ITS_ANIMATE1)
296             this.avelocity = '0 180 0';
297
298         if(this.ItemStatus & ITS_ANIMATE2)
299             this.avelocity = '0 -90 0';
300     }
301
302     this.entremove = ItemRemove;
303
304     return true;
305 }
306
307 #endif
308
309 #ifdef SVQC
310 bool ItemSend(entity this, entity to, int sf)
311 {
312         if(this.gravity)
313                 sf |= ISF_DROP;
314         else
315                 sf &= ~ISF_DROP;
316
317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
318         WriteByte(MSG_ENTITY, sf);
319
320         //WriteByte(MSG_ENTITY, this.cnt);
321         if(sf & ISF_LOCATION)
322         {
323                 WriteCoord(MSG_ENTITY, this.origin.x);
324                 WriteCoord(MSG_ENTITY, this.origin.y);
325                 WriteCoord(MSG_ENTITY, this.origin.z);
326         }
327
328         if(sf & ISF_ANGLES)
329         {
330                 WriteAngle(MSG_ENTITY, this.angles_x);
331                 WriteAngle(MSG_ENTITY, this.angles_y);
332                 WriteAngle(MSG_ENTITY, this.angles_z);
333         }
334
335         if(sf & ISF_SIZE)
336         {
337                 Pickup p = this.itemdef;
338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
339         }
340
341         if(sf & ISF_STATUS)
342                 WriteByte(MSG_ENTITY, this.ItemStatus);
343
344         if(sf & ISF_MODEL)
345         {
346                 Pickup p = this.itemdef;
347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
348                 WriteShort(MSG_ENTITY, this.fade_end);
349                 WriteShort(MSG_ENTITY, this.fade_start);
350
351                 if(this.mdl == "")
352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
353
354                 WriteString(MSG_ENTITY, this.mdl);
355         }
356
357
358         if(sf & ISF_COLORMAP)
359         {
360                 WriteShort(MSG_ENTITY, this.colormap);
361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
364         }
365
366         if(sf & ISF_DROP)
367         {
368                 WriteCoord(MSG_ENTITY, this.velocity.x);
369                 WriteCoord(MSG_ENTITY, this.velocity.y);
370                 WriteCoord(MSG_ENTITY, this.velocity.z);
371         }
372
373         return true;
374 }
375
376 void ItemUpdate(entity this)
377 {
378         this.oldorigin = this.origin;
379         this.SendFlags |= ISF_LOCATION;
380 }
381
382 void UpdateItemAfterTeleport(entity this)
383 {
384         if(getSendEntity(this) == ItemSend)
385                 ItemUpdate(this);
386 }
387
388 bool have_pickup_item(entity this)
389 {
390         if(this.itemdef.instanceOfPowerup)
391         {
392                 if(autocvar_g_powerups > 0)
393                         return true;
394                 if(autocvar_g_powerups == 0)
395                         return false;
396         }
397         else
398         {
399                 if(autocvar_g_pickup_items > 0)
400                         return true;
401                 if(autocvar_g_pickup_items == 0)
402                         return false;
403                 if(g_weaponarena)
404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
405                                 return false;
406         }
407         return true;
408 }
409
410 /*
411 float Item_Customize()
412 {
413         if(this.spawnshieldtime)
414                 return true;
415         if(this.weapons & ~other.weapons)
416         {
417                 this.colormod = '0 0 0';
418                 this.glowmod = this.colormod;
419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
420                 return true;
421         }
422         else
423         {
424                 if(g_ghost_items)
425                 {
426                         this.colormod = stov(autocvar_g_ghost_items_color);
427                         this.glowmod = this.colormod;
428                         this.alpha = g_ghost_items;
429                         return true;
430                 }
431                 else
432                         return false;
433         }
434 }
435 */
436
437 void Item_Show (entity e, float mode)
438 {
439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
440         e.ItemStatus &= ~ITS_STAYWEP;
441         entity def = e.itemdef;
442         if (mode > 0)
443         {
444                 // make the item look normal, and be touchable
445                 e.model = e.mdl;
446                 e.solid = SOLID_TRIGGER;
447                 e.spawnshieldtime = 1;
448                 e.ItemStatus |= ITS_AVAILABLE;
449         }
450         else if (mode < 0)
451         {
452                 // hide the item completely
453                 e.model = string_null;
454                 e.solid = SOLID_NOT;
455                 e.spawnshieldtime = 1;
456                 e.ItemStatus &= ~ITS_AVAILABLE;
457         }
458         else
459         {
460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
461                         || e.team // weapon stay isn't supported for teamed weapons
462                         ;
463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
464                 {
465                         // make the item translucent and not touchable
466                         e.model = e.mdl;
467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
468                         e.effects |= EF_STARDUST;
469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
471                 }
472                 else
473                 {
474                         //setmodel(e, "null");
475                         e.solid = SOLID_NOT;
476                         e.colormod = '0 0 0';
477                         //e.glowmod = e.colormod;
478                         e.spawnshieldtime = 1;
479                         e.ItemStatus &= ~ITS_AVAILABLE;
480                 }
481         }
482
483         if (def.m_glow)
484                 e.ItemStatus |= ITS_GLOW;
485
486         if (autocvar_g_nodepthtestitems)
487                 e.effects |= EF_NODEPTHTEST;
488
489
490         if (autocvar_g_fullbrightitems)
491                 e.ItemStatus |= ITS_ALLOWFB;
492
493         if (autocvar_sv_simple_items)
494                 e.ItemStatus |= ITS_ALLOWSI;
495
496         // relink entity (because solid may have changed)
497         setorigin(e, e.origin);
498         e.SendFlags |= ISF_STATUS;
499 }
500
501 void Item_Think(entity this)
502 {
503         this.nextthink = time;
504         if(this.origin != this.oldorigin)
505                 ItemUpdate(this);
506 }
507
508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
509 bool Item_ItemsTime_Allow(GameItem it);
510 float Item_ItemsTime_UpdateTime(entity e, float t);
511 void Item_ItemsTime_SetTime(entity e, float t);
512 void Item_ItemsTime_SetTimesForAllPlayers();
513
514 void Item_Respawn (entity this)
515 {
516         Item_Show(this, 1);
517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
518         setorigin(this, this.origin);
519
520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
521         {
522                 float t = Item_ItemsTime_UpdateTime(this, 0);
523                 Item_ItemsTime_SetTime(this, t);
524                 Item_ItemsTime_SetTimesForAllPlayers();
525         }
526
527         setthink(this, Item_Think);
528         this.nextthink = time;
529
530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
532 }
533
534 void Item_RespawnCountdown (entity this)
535 {
536         if(this.count >= ITEM_RESPAWN_TICKS)
537         {
538                 if(this.waypointsprite_attached)
539                         WaypointSprite_Kill(this.waypointsprite_attached);
540                 Item_Respawn(this);
541         }
542         else
543         {
544                 this.nextthink = time + 1;
545                 this.count += 1;
546                 if(this.count == 1)
547                 {
548                         do {
549                                 {
550                                         entity wi = Weapons_from(this.weapon);
551                                         if (wi != WEP_Null) {
552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
553                                                 wp.wp_extra = wi.m_id;
554                                                 break;
555                                         }
556                                 }
557                                 {
558                                         entity ii = this.itemdef;
559                                         if (ii != NULL) {
560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
561                                                 wp.wp_extra = ii.m_id;
562                                                 break;
563                                         }
564                                 }
565                         } while (0);
566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
567             if(this.waypointsprite_attached)
568             {
569                 GameItem def = this.itemdef;
570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
573             }
574                 }
575
576                 if(this.waypointsprite_attached)
577                 {
578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
580                                 {
581                                         msg_entity = it;
582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
583                                 }
584                         });
585
586                         WaypointSprite_Ping(this.waypointsprite_attached);
587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
588                 }
589         }
590 }
591
592 void Item_RespawnThink(entity this)
593 {
594         this.nextthink = time;
595         if(this.origin != this.oldorigin)
596                 ItemUpdate(this);
597
598         if(time >= this.wait)
599                 Item_Respawn(this);
600 }
601
602 void Item_ScheduleRespawnIn(entity e, float t)
603 {
604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
606         {
607                 setthink(e, Item_RespawnCountdown);
608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
610                 e.count = 0;
611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
612                 {
613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
614                         Item_ItemsTime_SetTime(e, t);
615                         Item_ItemsTime_SetTimesForAllPlayers();
616                 }
617         }
618         else
619         {
620                 setthink(e, Item_RespawnThink);
621                 e.nextthink = time;
622                 e.scheduledrespawntime = time + t;
623                 e.wait = time + t;
624
625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
626                 {
627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
628                         Item_ItemsTime_SetTime(e, t);
629                         Item_ItemsTime_SetTimesForAllPlayers();
630                 }
631         }
632 }
633
634 void Item_ScheduleRespawn(entity e)
635 {
636         if(e.respawntime > 0)
637         {
638                 Item_Show(e, 0);
639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
640         }
641         else // if respawntime is -1, this item does not respawn
642                 Item_Show(e, -1);
643 }
644
645 void Item_ScheduleInitialRespawn(entity e)
646 {
647         Item_Show(e, 0);
648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
649 }
650
651 void GivePlayerResource(entity player, .float resource_type, float amount)
652 {
653         if (amount == 0)
654         {
655                 return;
656         }
657         switch (resource_type)
658         {
659                 case health:
660                 {
661                         // Ugly hack. We do not check if health goes beyond hard limit since
662                         // currently it is done in player_regen. We need to bring back this
663                         // check when other code is ported to this function.
664                         player.health = bound(player.health, player.health + amount,
665                                 autocvar_g_balance_health_limit);
666                         // Correct code:
667                         //player.health = bound(player.health, player.health + amount,
668                         //      min(autocvar_g_balance_health_limit, ITEM_COUNT_HARD_LIMIT));
669                         player.pauserothealth_finished = max(player.pauserothealth_finished,
670                                 time + autocvar_g_balance_pause_health_rot);
671                         return;
672                 }
673                 case armorvalue:
674                 {
675                         // Ugly hack. We do not check if armor goes beyond hard limit since
676                         // currently it is done in player_regen. We need to bring back this
677                         // check when other code is ported to this function.
678                         player.armorvalue = bound(player.armorvalue, player.armorvalue +
679                                 amount, autocvar_g_balance_armor_limit);
680                         // Correct code:
681                         //player.armorvalue = bound(player.armorvalue, player.armorvalue +
682                         //      amount, min(autocvar_g_balance_armor_limit,
683                         //      ITEM_COUNT_HARD_LIMIT));
684                         player.pauserotarmor_finished = max(player.pauserotarmor_finished,
685                                 time + autocvar_g_balance_pause_armor_rot);
686                         return;
687                 }
688                 case ammo_shells:
689                 case ammo_nails:
690                 case ammo_rockets:
691                 case ammo_cells:
692                 case ammo_plasma:
693                 {
694                         GivePlayerAmmo(player, resource_type, amount);
695                         return;
696                 }
697                 case ammo_fuel:
698                 {
699                         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel +
700                                 amount, min(g_pickup_fuel_max, ITEM_COUNT_HARD_LIMIT));
701                         player.pauserotfuel_finished = max(player.pauserotfuel_finished,
702                                 time + autocvar_g_balance_pause_fuel_rot);
703                         return;
704                 }
705         }
706 }
707
708 void GivePlayerHealth(entity player, float amount)
709 {
710         GivePlayerResource(player, health, amount);
711 }
712
713 void GivePlayerArmor(entity player, float amount)
714 {
715         GivePlayerResource(player, armorvalue, amount);
716 }
717
718 void GivePlayerAmmo(entity player, .float ammotype, float amount)
719 {
720         if (amount == 0)
721         {
722                 return;
723         }
724         float maxvalue = ITEM_COUNT_HARD_LIMIT;
725         switch (ammotype)
726         {
727                 case ammo_shells:
728                 {
729                         maxvalue = g_pickup_shells_max;
730                         break;
731                 }
732                 case ammo_cells:
733                 {
734                         maxvalue = g_pickup_cells_max;
735                         break;
736                 }
737                 case ammo_rockets:
738                 {
739                         maxvalue = g_pickup_rockets_max;
740                         break;
741                 }
742                 case ammo_plasma:
743                 {
744                         maxvalue = g_pickup_plasma_max;
745                         break;
746                 }
747                 case ammo_nails:
748                 {
749                         maxvalue = g_pickup_nails_max;
750                         break;
751                 }
752         }
753         player.(ammotype) = min(player.(ammotype) + amount,
754                 min(maxvalue, ITEM_COUNT_HARD_LIMIT));
755 }
756
757 void GivePlayerFuel(entity player, float amount)
758 {
759         GivePlayerResource(player, ammo_fuel, amount);
760 }
761
762 void GivePlayerRandomWeapons(entity player, int num_weapons,
763         string weapon_names, float shells, float bullets, float rockets,
764         float cells, float plasma)
765 {
766         if (num_weapons == 0)
767         {
768                 return;
769         }
770         int num_potential_weapons = tokenize_console(weapon_names);
771         for (int i = 0; i < num_weapons; ++i)
772         {
773                 RandomSelection_Init();
774                 for (int j = 0; j < num_potential_weapons; ++j)
775                 {
776                         string weapon = argv(j);
777                         FOREACH(Weapons, it != WEP_Null,
778                         {
779                                 // Finding a weapon which player doesn't have.
780                                 if (!(player.weapons & it.m_wepset) && (it.netname == weapon))
781                                 {
782                                         RandomSelection_AddEnt(it, 1, 1);
783                                         break;
784                                 }
785                         });
786                 }
787                 if (RandomSelection_chosen_ent == NULL)
788                 {
789                         return;
790                 }
791                 player.weapons |= RandomSelection_chosen_ent.m_wepset;
792                 switch (RandomSelection_chosen_ent.ammo_field)
793                 {
794                         case (ammo_shells):
795                         {
796                                 if (player.ammo_shells != 0)
797                                 {
798                                         break;
799                                 }
800                                 GivePlayerAmmo(player, ammo_shells, shells);
801                                 break;
802                         }
803                         case (ammo_nails):
804                         {
805                                 if (player.ammo_nails != 0)
806                                 {
807                                         break;
808                                 }
809                                 GivePlayerAmmo(player, ammo_nails, bullets);
810                                 break;
811                         }
812                         case (ammo_rockets):
813                         {
814                                 if (player.ammo_rockets != 0)
815                                 {
816                                         break;
817                                 }
818                                 GivePlayerAmmo(player, ammo_rockets, rockets);
819                                 break;
820                         }
821                         case (ammo_cells):
822                         {
823                                 if (player.ammo_cells != 0)
824                                 {
825                                         break;
826                                 }
827                                 GivePlayerAmmo(player, ammo_cells, cells);
828                                 break;
829                         }
830                         case (ammo_plasma):
831                         {
832                                 if (player.ammo_plasma != 0)
833                                 {
834                                         break;
835                                 }
836                                 GivePlayerAmmo(player, ammo_plasma, plasma);
837                                 break;
838                         }
839                 }
840         }
841 }
842
843 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
844 {
845         if (!item.(ammotype))
846                 return false;
847
848         if (item.spawnshieldtime)
849         {
850                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
851                 {
852                         float amount = item.(ammotype);
853                         if ((player.(ammotype) + amount) > ammomax)
854                         {
855                                 amount = ammomax - player.(ammotype);
856                         }
857                         GivePlayerResource(player, ammotype, amount);
858                         return true;
859                 }
860         }
861         else if(g_weapon_stay == 2)
862         {
863                 float mi = min(item.(ammotype), ammomax);
864                 if (player.(ammotype) < mi)
865                 {
866                         GivePlayerResource(player, ammotype, mi - player.(ammotype));
867                 }
868                 return true;
869         }
870         return false;
871 }
872
873 float Item_GiveTo(entity item, entity player)
874 {
875         float pickedup;
876
877         // if nothing happens to player, just return without taking the item
878         pickedup = false;
879         int _switchweapon = 0;
880         // in case the player has autoswitch enabled do the following:
881         // if the player is using their best weapon before items are given, they
882         // probably want to switch to an even better weapon after items are given
883
884         if(CS(player).autoswitch)
885         {
886                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
887                 {
888                         .entity weaponentity = weaponentities[slot];
889                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
890                         {
891                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
892                                         _switchweapon |= BIT(slot);
893
894                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
895                                         _switchweapon |= BIT(slot);
896                         }
897                 }
898         }
899         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
900         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
901         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
902         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
903         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
904         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
905         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
906         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
907         if (item.itemdef.instanceOfWeaponPickup)
908         {
909                 WepSet w;
910                 w = item.weapons;
911                 w &= ~player.weapons;
912
913                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
914                 {
915                         pickedup = true;
916                         FOREACH(Weapons, it != WEP_Null, {
917                                 if(w & (it.m_wepset))
918                                 {
919                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
920                                         {
921                                                 .entity weaponentity = weaponentities[slot];
922                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
923                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
924                                         }
925                                         W_GiveWeapon(player, it.m_id);
926                                 }
927                         });
928                 }
929         }
930
931         if (item.itemdef.instanceOfPowerup)
932         {
933                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
934                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
935                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
936                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
937         }
938
939         int its;
940         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
941         {
942                 pickedup = true;
943                 player.items |= its;
944                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
945         }
946
947         if (item.strength_finished)
948         {
949                 pickedup = true;
950                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
951         }
952         if (item.invincible_finished)
953         {
954                 pickedup = true;
955                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
956         }
957         if (item.superweapons_finished)
958         {
959                 pickedup = true;
960                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
961         }
962
963 LABEL(skip)
964
965         // always eat teamed entities
966         if(item.team)
967                 pickedup = true;
968
969         if (!pickedup)
970                 return 0;
971
972         // crude hack to enforce switching weapons
973         if(g_cts && item.itemdef.instanceOfWeaponPickup)
974         {
975                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
976                 {
977                         .entity weaponentity = weaponentities[slot];
978                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
979                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
980                 }
981                 return 1;
982         }
983
984         if(_switchweapon)
985         {
986                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
987                 {
988                         .entity weaponentity = weaponentities[slot];
989                         if(_switchweapon & BIT(slot))
990                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
991                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
992                 }
993         }
994
995         return 1;
996 }
997
998 void Item_Touch(entity this, entity toucher)
999 {
1000
1001         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
1002         if (this.classname == "droppedweapon")
1003         {
1004                 if (ITEM_TOUCH_NEEDKILL())
1005                 {
1006                         delete(this);
1007                         return;
1008                 }
1009         }
1010
1011         if(!(toucher.flags & FL_PICKUPITEMS)
1012         || STAT(FROZEN, toucher)
1013         || IS_DEAD(toucher)
1014         || (this.solid != SOLID_TRIGGER)
1015         || (this.owner == toucher)
1016         || (time < this.item_spawnshieldtime)
1017         ) { return; }
1018
1019         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
1020         {
1021                 case MUT_ITEMTOUCH_RETURN: { return; }
1022                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
1023         }
1024
1025         toucher = M_ARGV(1, entity);
1026
1027         if (this.classname == "droppedweapon")
1028         {
1029                 this.strength_finished = max(0, this.strength_finished - time);
1030                 this.invincible_finished = max(0, this.invincible_finished - time);
1031                 this.superweapons_finished = max(0, this.superweapons_finished - time);
1032         }
1033         entity it = this.itemdef;
1034         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
1035         if (!gave)
1036         {
1037                 if (this.classname == "droppedweapon")
1038                 {
1039                         // undo what we did above
1040                         this.strength_finished += time;
1041                         this.invincible_finished += time;
1042                         this.superweapons_finished += time;
1043                 }
1044                 return;
1045         }
1046
1047 LABEL(pickup)
1048
1049         toucher.last_pickup = time;
1050
1051         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1052         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
1053
1054         if (this.classname == "droppedweapon")
1055                 delete(this);
1056         else if (this.spawnshieldtime)
1057         {
1058                 entity e;
1059                 if(this.team)
1060                 {
1061                         RandomSelection_Init();
1062                         IL_EACH(g_items, it.team == this.team,
1063                         {
1064                                 if(it.itemdef) // is a registered item
1065                                 {
1066                                         Item_Show(it, -1);
1067                                         RandomSelection_AddEnt(it, it.cnt, 0);
1068                                 }
1069                         });
1070                         e = RandomSelection_chosen_ent;
1071                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
1072                 }
1073                 else
1074                         e = this;
1075                 Item_ScheduleRespawn(e);
1076         }
1077 }
1078
1079 void Item_Reset(entity this)
1080 {
1081         Item_Show(this, !this.state);
1082         setorigin(this, this.origin);
1083
1084         if (this.classname != "droppedweapon")
1085         {
1086                 setthink(this, Item_Think);
1087                 this.nextthink = time;
1088
1089                 if (this.waypointsprite_attached)
1090                         WaypointSprite_Kill(this.waypointsprite_attached);
1091
1092                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1093                         Item_ScheduleInitialRespawn(this);
1094         }
1095 }
1096
1097 void Item_FindTeam(entity this)
1098 {
1099         entity e;
1100
1101         if(this.effects & EF_NODRAW)
1102         {
1103                 // marker for item team search
1104                 LOG_TRACE("Initializing item team ", ftos(this.team));
1105                 RandomSelection_Init();
1106                 IL_EACH(g_items, it.team == this.team,
1107                 {
1108                         if(it.itemdef) // is a registered item
1109                                 RandomSelection_AddEnt(it, it.cnt, 0);
1110                 });
1111
1112                 e = RandomSelection_chosen_ent;
1113                 e.state = 0;
1114                 Item_Show(e, 1);
1115
1116                 IL_EACH(g_items, it.team == this.team,
1117                 {
1118                         if(it.itemdef) // is a registered item
1119                         {
1120                                 if(it != e)
1121                                 {
1122                                         // make it non-spawned
1123                                         Item_Show(it, -1);
1124                                         it.state = 1; // state 1 = initially hidden item, apparently
1125                                 }
1126                                 it.effects &= ~EF_NODRAW;
1127                         }
1128                 });
1129
1130                 Item_Reset(this);
1131         }
1132 }
1133
1134 // Savage: used for item garbage-collection
1135 void RemoveItem(entity this)
1136 {
1137         if(wasfreed(this) || !this) { return; }
1138         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1139         delete(this);
1140 }
1141
1142 // pickup evaluation functions
1143 // these functions decide how desirable an item is to the bots
1144
1145 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1146
1147 float weapon_pickupevalfunc(entity player, entity item)
1148 {
1149         // See if I have it already
1150         if(player.weapons & item.weapons)
1151         {
1152                 // If I can pick it up
1153                 if(!item.spawnshieldtime)
1154                         return 0;
1155                 return ammo_pickupevalfunc(player, item);
1156         }
1157
1158         // reduce weapon value if bot already got a good arsenal
1159         float c = 1;
1160         int weapons_value = 0;
1161         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1162                 weapons_value += it.bot_pickupbasevalue;
1163         });
1164         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1165
1166         return item.bot_pickupbasevalue * c;
1167 }
1168
1169 float ammo_pickupevalfunc(entity player, entity item)
1170 {
1171         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1172         entity wpn = NULL;
1173         float c = 0;
1174         float rating = 0;
1175
1176         // Detect needed ammo
1177         if(item.itemdef.instanceOfWeaponPickup)
1178         {
1179                 entity ammo = NULL;
1180                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1181                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1182                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1183                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1184                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1185                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1186
1187                 if(!ammo)
1188                         return 0;
1189                 wpn = item;
1190                 rating = ammo.m_botvalue;
1191         }
1192         else
1193         {
1194                 FOREACH(Weapons, it != WEP_Null, {
1195                         if(!(player.weapons & (it.m_wepset)))
1196                                 continue;
1197
1198                         switch(it.ammo_field)
1199                         {
1200                                 case ammo_shells:  need_shells  = true; break;
1201                                 case ammo_nails:   need_nails   = true; break;
1202                                 case ammo_rockets: need_rockets = true; break;
1203                                 case ammo_cells:   need_cells   = true; break;
1204                                 case ammo_plasma:  need_plasma  = true; break;
1205                                 case ammo_fuel:    need_fuel    = true; break;
1206                         }
1207                 });
1208                 rating = item.bot_pickupbasevalue;
1209         }
1210
1211         float noammorating = 0.5;
1212
1213         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1214                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1215
1216         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1217                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1218
1219         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1220                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1221
1222         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1223                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1224
1225         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1226                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1227
1228         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1229                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1230
1231         rating *= min(c, 2);
1232         if(wpn)
1233                 rating += wpn.bot_pickupbasevalue * 0.1;
1234         return rating;
1235 }
1236
1237 .int item_group;
1238 .int item_group_count;
1239 float healtharmor_pickupevalfunc(entity player, entity item)
1240 {
1241         float c = 0;
1242         float rating = item.bot_pickupbasevalue;
1243
1244         float itemarmor = item.armorvalue;
1245         float itemhealth = item.health;
1246
1247         if(item.item_group)
1248         {
1249                 itemarmor *= min(4, item.item_group_count);
1250                 itemhealth *= min(4, item.item_group_count);
1251         }
1252
1253         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1254                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1255
1256         if (itemhealth && (player.health < item.max_health))
1257                 c = itemhealth / max(1, player.health);
1258
1259         rating *= min(2, c);
1260         return rating;
1261 }
1262
1263 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1264 {
1265         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1266                 RemoveItem(this);
1267 }
1268
1269 void item_use(entity this, entity actor, entity trigger)
1270 {
1271         // use the touch function to handle collection
1272         gettouch(this)(this, actor);
1273 }
1274
1275 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1276 {
1277         string itemname = def.m_name;
1278         Model itemmodel = def.m_model;
1279     Sound pickupsound = def.m_sound;
1280         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1281         float pickupbasevalue = def.m_botvalue;
1282         int itemflags = def.m_itemflags;
1283
1284         startitem_failed = false;
1285
1286         this.item_model_ent = itemmodel;
1287     this.item_pickupsound_ent = pickupsound;
1288
1289     if(def.m_iteminit)
1290         def.m_iteminit(this);
1291
1292         if(!this.respawntime) // both need to be set
1293         {
1294                 this.respawntime = defaultrespawntime;
1295                 this.respawntimejitter = defaultrespawntimejitter;
1296         }
1297
1298         if(!this.pickup_anyway && def.m_pickupanyway)
1299                 this.pickup_anyway = def.m_pickupanyway();
1300
1301         int itemid = def.m_itemid;
1302         this.items = itemid;
1303         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1304         this.weapon = weaponid;
1305
1306         if(!this.fade_end)
1307         {
1308                 this.fade_start = autocvar_g_items_mindist;
1309                 this.fade_end = autocvar_g_items_maxdist;
1310         }
1311
1312         if(weaponid)
1313                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1314
1315         this.flags = FL_ITEM | itemflags;
1316         IL_PUSH(g_items, this);
1317
1318         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1319         {
1320                 startitem_failed = true;
1321                 delete(this);
1322                 return;
1323         }
1324
1325         // is it a dropped weapon?
1326         if (this.classname == "droppedweapon")
1327         {
1328                 this.reset = SUB_Remove;
1329                 // it's a dropped weapon
1330                 set_movetype(this, MOVETYPE_TOSS);
1331
1332                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1333                 setthink(this, RemoveItem);
1334                 this.nextthink = time + 20;
1335
1336                 this.takedamage = DAMAGE_YES;
1337                 this.event_damage = Item_Damage;
1338
1339                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1340                 {
1341                         // if item is worthless after a timer, have it expire then
1342                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1343                 }
1344
1345                 // don't drop if in a NODROP zone (such as lava)
1346                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1347                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1348                 {
1349                         startitem_failed = true;
1350                         delete(this);
1351                         return;
1352                 }
1353         }
1354         else
1355         {
1356                 if(!have_pickup_item(this))
1357                 {
1358                         startitem_failed = true;
1359                         delete(this);
1360                         return;
1361                 }
1362
1363                 if(this.angles != '0 0 0')
1364                         this.SendFlags |= ISF_ANGLES;
1365
1366                 this.reset = Item_Reset;
1367                 // it's a level item
1368                 if(this.spawnflags & 1)
1369                         this.noalign = 1;
1370                 if (this.noalign > 0)
1371                         set_movetype(this, MOVETYPE_NONE);
1372                 else
1373                         set_movetype(this, MOVETYPE_TOSS);
1374                 // do item filtering according to game mode and other things
1375                 if (this.noalign <= 0)
1376                 {
1377                         // first nudge it off the floor a little bit to avoid math errors
1378                         setorigin(this, this.origin + '0 0 1');
1379                         // set item size before we spawn a spawnfunc_waypoint
1380                         setsize(this, def.m_mins, def.m_maxs);
1381                         this.SendFlags |= ISF_SIZE;
1382                         // note droptofloor returns false if stuck/or would fall too far
1383                         if (!this.noalign)
1384                                 droptofloor(this);
1385                         waypoint_spawnforitem(this);
1386                 }
1387
1388                 /*
1389                  * can't do it that way, as it would break maps
1390                  * TODO make a target_give like entity another way, that perhaps has
1391                  * the weapon name in a key
1392                 if(this.targetname)
1393                 {
1394                         // target_give not yet supported; maybe later
1395                         print("removed targeted ", this.classname, "\n");
1396                         startitem_failed = true;
1397                         delete(this);
1398                         return;
1399                 }
1400                 */
1401
1402                 if(this.targetname != "" && (this.spawnflags & 16))
1403                         this.use = item_use;
1404
1405                 if(autocvar_spawn_debug >= 2)
1406                 {
1407             // why not flags & fl_item?
1408                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1409                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1410                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1411                 error("Mapper sucks.");
1412             });
1413                         this.is_item = true;
1414                 }
1415
1416                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1417
1418                 precache_model(this.model);
1419                 precache_sound(this.item_pickupsound);
1420
1421                 if (   def.instanceOfPowerup
1422                         || def.instanceOfWeaponPickup
1423                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1424                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1425                         || (itemid & (IT_KEY1 | IT_KEY2))
1426                 ) this.target = "###item###"; // for finding the nearest item using find()
1427
1428                 Item_ItemsTime_SetTime(this, 0);
1429         }
1430
1431         this.bot_pickup = true;
1432         this.bot_pickupevalfunc = pickupevalfunc;
1433         this.bot_pickupbasevalue = pickupbasevalue;
1434         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1435         this.netname = itemname;
1436         settouch(this, Item_Touch);
1437         setmodel(this, MDL_Null); // precision set below
1438         //this.effects |= EF_LOWPRECISION;
1439
1440         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1441
1442         this.SendFlags |= ISF_SIZE;
1443
1444         if (!(this.spawnflags & 1024)) {
1445                 if(def.instanceOfPowerup)
1446                         this.ItemStatus |= ITS_ANIMATE1;
1447
1448                 if(this.armorvalue || this.health)
1449                         this.ItemStatus |= ITS_ANIMATE2;
1450         }
1451
1452         if(def.instanceOfWeaponPickup)
1453         {
1454                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1455                         this.colormap = 1024; // color shirt=0 pants=0 grey
1456                 else
1457                         this.gravity = 1;
1458                 if (!(this.spawnflags & 1024))
1459                         this.ItemStatus |= ITS_ANIMATE1;
1460                 this.SendFlags |= ISF_COLORMAP;
1461         }
1462
1463         this.state = 0;
1464         if(this.team) // broken, no idea why.
1465         {
1466                 if(!this.cnt)
1467                         this.cnt = 1; // item probability weight
1468
1469                 this.effects |= EF_NODRAW; // marker for item team search
1470                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1471         }
1472         else
1473                 Item_Reset(this);
1474
1475         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1476
1477         // call this hook after everything else has been done
1478         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1479         {
1480                 startitem_failed = true;
1481                 delete(this);
1482                 return;
1483         }
1484
1485         setItemGroup(this);
1486 }
1487
1488 void StartItem(entity this, GameItem def)
1489 {
1490     _StartItem(
1491         this,
1492         this.itemdef = def,
1493         def.m_respawntime(), // defaultrespawntime
1494         def.m_respawntimejitter() // defaultrespawntimejitter
1495         );
1496 }
1497
1498 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1499 int group_count = 1;
1500
1501 void setItemGroup(entity this)
1502 {
1503         if(!IS_SMALL(this.itemdef))
1504                 return;
1505
1506         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1507         {
1508                 if(!this.item_group)
1509                 {
1510                         if(!it.item_group)
1511                         {
1512                                 it.item_group = group_count;
1513                                 group_count++;
1514                         }
1515                         this.item_group = it.item_group;
1516                 }
1517                 else // spawning item is already part of a item_group X
1518                 {
1519                         if(!it.item_group)
1520                                 it.item_group = this.item_group;
1521                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1522                         {
1523                                 int grY = it.item_group;
1524                                 // move all items of item_group Y to item_group X
1525                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1526                                 {
1527                                         if(it.item_group == grY)
1528                                                 it.item_group = this.item_group;
1529                                 });
1530                         }
1531                 }
1532         });
1533 }
1534
1535 void setItemGroupCount()
1536 {
1537         for (int k = 1; k <= group_count; k++)
1538         {
1539                 int count = 0;
1540                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1541                 if (count)
1542                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1543         }
1544 }
1545
1546 spawnfunc(item_rockets)
1547 {
1548     StartItem(this, ITEM_Rockets);
1549 }
1550
1551 spawnfunc(item_bullets)
1552 {
1553         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1554            (this.classname != "droppedweapon"))
1555         {
1556                 weaponswapping = true;
1557                 spawnfunc_item_shells(this);
1558                 weaponswapping = false;
1559                 return;
1560         }
1561
1562     StartItem(this, ITEM_Bullets);
1563 }
1564
1565 spawnfunc(item_cells)
1566 {
1567         StartItem(this, ITEM_Cells);
1568 }
1569
1570 spawnfunc(item_plasma)
1571 {
1572         StartItem(this, ITEM_Plasma);
1573 }
1574
1575 spawnfunc(item_shells)
1576 {
1577         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1578            (this.classname != "droppedweapon"))
1579         {
1580                 weaponswapping = true;
1581                 spawnfunc_item_bullets(this);
1582                 weaponswapping = false;
1583                 return;
1584         }
1585
1586         StartItem(this, ITEM_Shells);
1587 }
1588
1589 spawnfunc(item_armor_small)
1590 {
1591         StartItem(this, ITEM_ArmorSmall);
1592 }
1593
1594 spawnfunc(item_armor_medium)
1595 {
1596         StartItem(this, ITEM_ArmorMedium);
1597 }
1598
1599 spawnfunc(item_armor_big)
1600 {
1601         StartItem(this, ITEM_ArmorBig);
1602 }
1603
1604 spawnfunc(item_armor_mega)
1605 {
1606         StartItem(this, ITEM_ArmorMega);
1607 }
1608
1609 spawnfunc(item_health_small)
1610 {
1611         StartItem(this, ITEM_HealthSmall);
1612 }
1613
1614 spawnfunc(item_health_medium)
1615 {
1616     StartItem(this, ITEM_HealthMedium);
1617 }
1618
1619 spawnfunc(item_health_big)
1620 {
1621         StartItem(this, ITEM_HealthBig);
1622 }
1623
1624 spawnfunc(item_health_mega)
1625 {
1626     StartItem(this, ITEM_HealthMega);
1627 }
1628
1629 // support old misnamed entities
1630 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1631 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1632 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1633 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1634 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1635 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1636 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1637
1638 spawnfunc(item_strength)
1639 {
1640         StartItem(this, ITEM_Strength);
1641 }
1642
1643 spawnfunc(item_invincible)
1644 {
1645         StartItem(this, ITEM_Shield);
1646 }
1647
1648 // compatibility:
1649 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1650
1651 void target_items_use(entity this, entity actor, entity trigger)
1652 {
1653         if(actor.classname == "droppedweapon")
1654         {
1655                 EXACTTRIGGER_TOUCH(this, trigger);
1656                 delete(actor);
1657                 return;
1658         }
1659
1660         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1661                 return;
1662
1663         if(trigger.solid == SOLID_TRIGGER)
1664         {
1665                 EXACTTRIGGER_TOUCH(this, trigger);
1666         }
1667
1668         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1669         {
1670                 delete(it);
1671         });
1672
1673         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1674                 centerprint(actor, this.message);
1675 }
1676
1677 spawnfunc(target_items)
1678 {
1679         int n;
1680         string s;
1681
1682         this.use = target_items_use;
1683         if(!this.strength_finished)
1684                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1685         if(!this.invincible_finished)
1686                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1687         if(!this.superweapons_finished)
1688                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1689
1690         n = tokenize_console(this.netname);
1691         if(argv(0) == "give")
1692         {
1693                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1694         }
1695         else
1696         {
1697                 for(int j = 0; j < n; ++j)
1698                 {
1699                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1700                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1701                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1702                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1703                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1704                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1705                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1706                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1707                         else
1708                         {
1709                                 FOREACH(Buffs, it != BUFF_Null,
1710                                 {
1711                                         s = Buff_UndeprecateName(argv(j));
1712                                         if(s == it.m_name)
1713                                         {
1714                                                 this.buffs |= (it.m_itemid);
1715                                                 break;
1716                                         }
1717                                 });
1718                                 FOREACH(Weapons, it != WEP_Null, {
1719                                         s = W_UndeprecateName(argv(j));
1720                                         if(s == it.netname)
1721                                         {
1722                                                 this.weapons |= (it.m_wepset);
1723                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1724                                                         it.wr_init(it);
1725                                                 break;
1726                                         }
1727                                 });
1728                         }
1729                 }
1730
1731                 string itemprefix, valueprefix;
1732                 if(this.spawnflags == 0)
1733                 {
1734                         itemprefix = "";
1735                         valueprefix = "";
1736                 }
1737                 else if(this.spawnflags == 1)
1738                 {
1739                         itemprefix = "max ";
1740                         valueprefix = "max ";
1741                 }
1742                 else if(this.spawnflags == 2)
1743                 {
1744                         itemprefix = "min ";
1745                         valueprefix = "min ";
1746                 }
1747                 else if(this.spawnflags == 4)
1748                 {
1749                         itemprefix = "minus ";
1750                         valueprefix = "max ";
1751                 }
1752                 else
1753                 {
1754                         error("invalid spawnflags");
1755                         itemprefix = valueprefix = string_null;
1756                 }
1757
1758                 this.netname = "";
1759                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1760                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1761                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1762                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1763                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1764                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1765                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1766                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1767                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1768                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1769                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1770                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1771                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1772                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1773                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1774                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1775                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1776         }
1777         this.netname = strzone(this.netname);
1778         //print(this.netname, "\n");
1779
1780         n = tokenize_console(this.netname);
1781         for(int j = 0; j < n; ++j)
1782         {
1783                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1784             it.wr_init(it);
1785             break;
1786                 });
1787         }
1788 }
1789
1790 spawnfunc(item_fuel)
1791 {
1792         StartItem(this, ITEM_JetpackFuel);
1793 }
1794
1795 spawnfunc(item_fuel_regen)
1796 {
1797         if(start_items & ITEM_JetpackRegen.m_itemid)
1798         {
1799                 spawnfunc_item_fuel(this);
1800                 return;
1801         }
1802         StartItem(this, ITEM_JetpackRegen);
1803 }
1804
1805 spawnfunc(item_jetpack)
1806 {
1807         if(start_items & ITEM_Jetpack.m_itemid)
1808         {
1809                 spawnfunc_item_fuel(this);
1810                 return;
1811         }
1812         StartItem(this, ITEM_Jetpack);
1813 }
1814
1815 float GiveWeapon(entity e, float wpn, float op, float val)
1816 {
1817         WepSet v0, v1;
1818         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1819         v0 = (e.weapons & s);
1820         switch(op)
1821         {
1822                 case OP_SET:
1823                         if(val > 0)
1824                                 e.weapons |= s;
1825                         else
1826                                 e.weapons &= ~s;
1827                         break;
1828                 case OP_MIN:
1829                 case OP_PLUS:
1830                         if(val > 0)
1831                                 e.weapons |= s;
1832                         break;
1833                 case OP_MAX:
1834                         if(val <= 0)
1835                                 e.weapons &= ~s;
1836                         break;
1837                 case OP_MINUS:
1838                         if(val > 0)
1839                                 e.weapons &= ~s;
1840                         break;
1841         }
1842         v1 = (e.weapons & s);
1843         return (v0 != v1);
1844 }
1845
1846 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1847 {
1848         bool had_buff = (e.buffs & thebuff.m_itemid);
1849         switch(op)
1850         {
1851                 case OP_SET:
1852                         if(val > 0)
1853                                 e.buffs |= thebuff.m_itemid;
1854                         else
1855                                 e.buffs &= ~thebuff.m_itemid;
1856                         break;
1857                 case OP_MIN:
1858                 case OP_PLUS:
1859                         if(val > 0)
1860                                 e.buffs |= thebuff.m_itemid;
1861                         break;
1862                 case OP_MAX:
1863                         if(val <= 0)
1864                                 e.buffs &= ~thebuff.m_itemid;
1865                         break;
1866                 case OP_MINUS:
1867                         if(val > 0)
1868                                 e.buffs &= ~thebuff.m_itemid;
1869                         break;
1870         }
1871         bool have_buff = (e.buffs & thebuff.m_itemid);
1872         return (had_buff != have_buff);
1873 }
1874
1875 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1876 {
1877         if(v1 == v0)
1878                 return;
1879         if(v1 <= v0 - t)
1880         {
1881                 if(snd_decr != NULL)
1882                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1883         }
1884         else if(v0 >= v0 + t)
1885         {
1886                 if(snd_incr != NULL)
1887                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1888         }
1889 }
1890
1891 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1892 {
1893         if(v0 < v1)
1894                 e.(rotfield) = max(e.(rotfield), time + rottime);
1895         else if(v0 > v1)
1896                 e.(regenfield) = max(e.(regenfield), time + regentime);
1897 }
1898 float GiveItems(entity e, float beginarg, float endarg)
1899 {
1900         float got, i, val, op;
1901         string cmd;
1902
1903         val = 999;
1904         op = OP_SET;
1905
1906         got = 0;
1907
1908         int _switchweapon = 0;
1909
1910         if(CS(e).autoswitch)
1911         {
1912                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1913                 {
1914                         .entity weaponentity = weaponentities[slot];
1915                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1916                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1917                                 _switchweapon |= BIT(slot);
1918                 }
1919         }
1920
1921         e.strength_finished = max(0, e.strength_finished - time);
1922         e.invincible_finished = max(0, e.invincible_finished - time);
1923         e.superweapons_finished = max(0, e.superweapons_finished - time);
1924
1925         PREGIVE(e, items);
1926         PREGIVE_WEAPONS(e);
1927         PREGIVE(e, strength_finished);
1928         PREGIVE(e, invincible_finished);
1929         PREGIVE(e, superweapons_finished);
1930         PREGIVE(e, ammo_nails);
1931         PREGIVE(e, ammo_cells);
1932         PREGIVE(e, ammo_plasma);
1933         PREGIVE(e, ammo_shells);
1934         PREGIVE(e, ammo_rockets);
1935         PREGIVE(e, ammo_fuel);
1936         PREGIVE(e, armorvalue);
1937         PREGIVE(e, health);
1938
1939         for(i = beginarg; i < endarg; ++i)
1940         {
1941                 cmd = argv(i);
1942
1943                 if(cmd == "0" || stof(cmd))
1944                 {
1945                         val = stof(cmd);
1946                         continue;
1947                 }
1948                 switch(cmd)
1949                 {
1950                         case "no":
1951                                 op = OP_MAX;
1952                                 val = 0;
1953                                 continue;
1954                         case "max":
1955                                 op = OP_MAX;
1956                                 continue;
1957                         case "min":
1958                                 op = OP_MIN;
1959                                 continue;
1960                         case "plus":
1961                                 op = OP_PLUS;
1962                                 continue;
1963                         case "minus":
1964                                 op = OP_MINUS;
1965                                 continue;
1966                         case "ALL":
1967                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1968                                 got += GiveValue(e, strength_finished, op, val);
1969                                 got += GiveValue(e, invincible_finished, op, val);
1970                                 got += GiveValue(e, superweapons_finished, op, val);
1971                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1972                         case "all":
1973                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1974                                 got += GiveValue(e, health, op, val);
1975                                 got += GiveValue(e, armorvalue, op, val);
1976                         case "allweapons":
1977                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1978                         //case "allbuffs": // all buffs makes a player god, do not want!
1979                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1980                         case "allammo":
1981                                 got += GiveValue(e, ammo_cells, op, val);
1982                                 got += GiveValue(e, ammo_plasma, op, val);
1983                                 got += GiveValue(e, ammo_shells, op, val);
1984                                 got += GiveValue(e, ammo_nails, op, val);
1985                                 got += GiveValue(e, ammo_rockets, op, val);
1986                                 got += GiveValue(e, ammo_fuel, op, val);
1987                                 break;
1988                         case "unlimited_ammo":
1989                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1990                                 break;
1991                         case "unlimited_weapon_ammo":
1992                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1993                                 break;
1994                         case "unlimited_superweapons":
1995                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1996                                 break;
1997                         case "jetpack":
1998                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1999                                 break;
2000                         case "fuel_regen":
2001                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
2002                                 break;
2003                         case "strength":
2004                                 got += GiveValue(e, strength_finished, op, val);
2005                                 break;
2006                         case "invincible":
2007                                 got += GiveValue(e, invincible_finished, op, val);
2008                                 break;
2009                         case "superweapons":
2010                                 got += GiveValue(e, superweapons_finished, op, val);
2011                                 break;
2012                         case "cells":
2013                                 got += GiveValue(e, ammo_cells, op, val);
2014                                 break;
2015                         case "plasma":
2016                                 got += GiveValue(e, ammo_plasma, op, val);
2017                                 break;
2018                         case "shells":
2019                                 got += GiveValue(e, ammo_shells, op, val);
2020                                 break;
2021                         case "nails":
2022                         case "bullets":
2023                                 got += GiveValue(e, ammo_nails, op, val);
2024                                 break;
2025                         case "rockets":
2026                                 got += GiveValue(e, ammo_rockets, op, val);
2027                                 break;
2028                         case "health":
2029                                 got += GiveValue(e, health, op, val);
2030                                 break;
2031                         case "armor":
2032                                 got += GiveValue(e, armorvalue, op, val);
2033                                 break;
2034                         case "fuel":
2035                                 got += GiveValue(e, ammo_fuel, op, val);
2036                                 break;
2037                         default:
2038                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
2039                                 {
2040                                         got += GiveBuff(e, it, op, val);
2041                                         break;
2042                                 });
2043                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
2044                     got += GiveWeapon(e, it.m_id, op, val);
2045                     break;
2046                                 });
2047                                 break;
2048                 }
2049                 val = 999;
2050                 op = OP_SET;
2051         }
2052
2053         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
2054         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
2055         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
2056         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
2057         FOREACH(Weapons, it != WEP_Null, {
2058                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
2059                 if(!(save_weapons & (it.m_wepset)))
2060                         if(e.weapons & (it.m_wepset))
2061                                 it.wr_init(it);
2062         });
2063         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
2064         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
2065         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
2066         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
2067         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
2068         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
2069         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
2070         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
2071         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
2072         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
2073         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
2074
2075         if(e.superweapons_finished <= 0)
2076                 if(e.weapons & WEPSET_SUPERWEAPONS)
2077                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2078
2079         if(e.strength_finished <= 0)
2080                 e.strength_finished = 0;
2081         else
2082                 e.strength_finished += time;
2083         if(e.invincible_finished <= 0)
2084                 e.invincible_finished = 0;
2085         else
2086                 e.invincible_finished += time;
2087         if(e.superweapons_finished <= 0)
2088                 e.superweapons_finished = 0;
2089         else
2090                 e.superweapons_finished += time;
2091
2092         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2093         {
2094                 .entity weaponentity = weaponentities[slot];
2095                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2096                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2097                         _switchweapon |= BIT(slot);
2098         }
2099
2100         if(_switchweapon)
2101         {
2102                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2103                 {
2104                         .entity weaponentity = weaponentities[slot];
2105                         if(_switchweapon & BIT(slot))
2106                         {
2107                                 Weapon wep = w_getbestweapon(e, weaponentity);
2108                                 if(wep != e.(weaponentity).m_switchweapon)
2109                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2110                         }
2111                 }
2112         }
2113
2114         return got;
2115 }
2116 #endif