Improve reliability of giving buffs via triggers, fixes some odd cases involving...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "mapobjects/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26         #include <common/mutators/mutator/buffs/sv_buffs.qh>
27
28     #include "../lib/warpzone/util_server.qh"
29 #elif defined(CSQC)
30         #include "physics/movetypes/movetypes.qh"
31         #include <common/weapons/_all.qh>
32         #include "../lib/csqcmodel/cl_model.qh"
33         #include "../lib/csqcmodel/common.qh"
34 #endif
35
36 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
37
38 #ifdef CSQC
39 bool autocvar_cl_ghost_items_vehicle = true;
40 .vector item_glowmod;
41 .bool item_simple; // probably not really needed, but better safe than sorry
42 void Item_SetAlpha(entity this)
43 {
44         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
45
46         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
47         {
48                 this.alpha = 1;
49                 this.colormod = '1 1 1';
50                 this.glowmod = this.item_glowmod;
51         }
52         else
53         {
54                 this.alpha = autocvar_cl_ghost_items;
55                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56         }
57
58         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
59         {
60                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
61                 this.alpha = autocvar_cl_weapon_stay_alpha;
62         }
63
64         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
65 }
66
67 void ItemDraw(entity this)
68 {
69     if(this.gravity)
70     {
71         Movetype_Physics_MatchServer(this, false);
72         if(IS_ONGROUND(this))
73         { // For some reason avelocity gets set to '0 0 0' here ...
74             this.oldorigin = this.origin;
75             this.gravity = 0;
76
77             if(autocvar_cl_animate_items)
78             { // ... so reset it if animations are requested.
79                 if(this.ItemStatus & ITS_ANIMATE1)
80                     this.avelocity = '0 180 0';
81
82                 if(this.ItemStatus & ITS_ANIMATE2)
83                     this.avelocity = '0 -90 0';
84             }
85
86             // delay is for blocking item's position for a while;
87             // it's a workaround for dropped weapons that receive the position
88             // another time right after they spawn overriding animation position
89             this.onground_time = time + 0.5;
90         }
91     }
92     else if (autocvar_cl_animate_items && !this.item_simple) // no bobbing applied to simple items, for consistency's sake (no visual difference between ammo and weapons)
93     {
94         if(this.ItemStatus & ITS_ANIMATE1)
95         {
96                 this.angles += this.avelocity * frametime;
97             float fade_in = bound(0, time - this.onground_time, 1);
98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
99         }
100
101         if(this.ItemStatus & ITS_ANIMATE2)
102         {
103                 this.angles += this.avelocity * frametime;
104             float fade_in = bound(0, time - this.onground_time, 1);
105             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
106         }
107     }
108
109     Item_SetAlpha(this);
110 }
111
112 void Item_PreDraw(entity this)
113 {
114         if(warpzone_warpzones_exist)
115         {
116                 setpredraw(this, func_null); // no need to keep running this
117                 return;
118         }
119         float alph;
120         vector org = getpropertyvec(VF_ORIGIN);
121         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
122                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
123         if(this.fade_start)
124         {
125                 if(vdist(org - this.origin, >, this.fade_end))
126                         alph = 0; // save on some processing
127                 else if(vdist(org - this.origin, <, this.fade_start))
128                         alph = 1; // more processing saved
129                 else
130                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
131         }
132         else
133                 alph = 1;
134         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
135         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
136                 this.alpha = alph;
137         if(alph <= 0)
138                 this.drawmask = 0;
139         //else
140                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
141 }
142
143 void ItemRemove(entity this)
144 {
145         strfree(this.mdl);
146 }
147
148 HashMap ENT_CLIENT_ITEM_simple;
149 STATIC_INIT(ENT_CLIENT_ITEM_simple)
150 {
151         HM_NEW(ENT_CLIENT_ITEM_simple);
152 }
153 SHUTDOWN(ENT_CLIENT_ITEM_simple)
154 {
155         HM_DELETE(ENT_CLIENT_ITEM_simple);
156 }
157
158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
159 {
160     int sf = ReadByte();
161
162     if(sf & ISF_LOCATION)
163     {
164         this.origin = ReadVector();
165         setorigin(this, this.origin);
166         this.oldorigin = this.origin;
167     }
168
169     if(sf & ISF_ANGLES)
170     {
171         this.angles_x = ReadAngle();
172         this.angles_y = ReadAngle();
173         this.angles_z = ReadAngle();
174     }
175
176     if(sf & ISF_SIZE)
177     {
178         setsize(this, '-16 -16 0', '16 16 48');
179     }
180
181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
182     {
183         this.ItemStatus = ReadByte();
184
185         Item_SetAlpha(this);
186
187         if(this.ItemStatus & ITS_ALLOWFB)
188            this.effects |= EF_FULLBRIGHT;
189
190         if(this.ItemStatus & ITS_GLOW)
191         {
192             if(this.ItemStatus & ITS_AVAILABLE)
193                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
194             else
195                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
196         }
197     }
198
199     if(sf & ISF_MODEL)
200     {
201         this.drawmask  = MASK_NORMAL;
202                 set_movetype(this, MOVETYPE_TOSS);
203                 if (isnew) IL_PUSH(g_drawables, this);
204         this.draw       = ItemDraw;
205         this.solid = SOLID_TRIGGER;
206         //this.flags |= FL_ITEM;
207
208         this.fade_end = ReadShort();
209         this.fade_start = ReadShort();
210         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
211                 setpredraw(this, Item_PreDraw);
212
213                 strfree(this.mdl);
214
215         string _fn = ReadString();
216         this.item_simple = false; // reset it!
217
218         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
219         {
220             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
221             this.item_simple = true;
222
223                         #define extensions(x) \
224                                 x(md3) \
225                                 x(dpm) \
226                                 x(iqm) \
227                                 x(mdl) \
228                                 /**/
229                         #define tryext(ext) { \
230                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
231                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
232                                 if (cached == "") { \
233                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
234                                 } \
235                                 if (cached != "0") { \
236                                         strcpy(this.mdl, s); \
237                                         break; \
238                                 } \
239                         }
240                         do {
241                                 extensions(tryext);
242                                 this.item_simple = false;
243                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
244                         } while (0);
245                         #undef tryext
246                         #undef extensions
247         }
248
249         if(!this.item_simple)
250             strcpy(this.mdl, _fn);
251
252         if(this.mdl == "")
253             LOG_WARNF("this.mdl is unset for item %s", this.classname);
254
255         precache_model(this.mdl);
256         _setmodel(this, this.mdl);
257
258         setsize(this, '-16 -16 0', '16 16 48');
259     }
260
261     if(sf & ISF_COLORMAP)
262     {
263         this.colormap = ReadShort();
264         this.item_glowmod_x = ReadByte() / 255.0;
265         this.item_glowmod_y = ReadByte() / 255.0;
266         this.item_glowmod_z = ReadByte() / 255.0;
267     }
268
269     if(sf & ISF_DROP)
270     {
271         this.gravity = 1;
272         this.pushable = true;
273         //this.angles = '0 0 0';
274         set_movetype(this, MOVETYPE_TOSS);
275         this.velocity = ReadVector();
276         setorigin(this, this.oldorigin);
277
278         if(!this.move_time)
279         {
280             this.move_time = time;
281             this.spawntime = time;
282         }
283         else
284             this.move_time = max(this.move_time, time);
285     }
286
287     if(autocvar_cl_animate_items)
288     {
289         if(this.ItemStatus & ITS_ANIMATE1)
290             this.avelocity = '0 180 0';
291
292         if(this.ItemStatus & ITS_ANIMATE2)
293             this.avelocity = '0 -90 0';
294     }
295
296     this.entremove = ItemRemove;
297
298     return true;
299 }
300
301 #endif
302
303 #ifdef SVQC
304 bool ItemSend(entity this, entity to, int sf)
305 {
306         if(this.gravity)
307                 sf |= ISF_DROP;
308         else
309                 sf &= ~ISF_DROP;
310
311         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
312         WriteByte(MSG_ENTITY, sf);
313
314         //WriteByte(MSG_ENTITY, this.cnt);
315         if(sf & ISF_LOCATION)
316         {
317                 WriteVector(MSG_ENTITY, this.origin);
318         }
319
320         if(sf & ISF_ANGLES)
321         {
322                 WriteAngle(MSG_ENTITY, this.angles_x);
323                 WriteAngle(MSG_ENTITY, this.angles_y);
324                 WriteAngle(MSG_ENTITY, this.angles_z);
325         }
326
327         // sets size on the client, unused on server
328         //if(sf & ISF_SIZE)
329
330         if(sf & ISF_STATUS)
331                 WriteByte(MSG_ENTITY, this.ItemStatus);
332
333         if(sf & ISF_MODEL)
334         {
335                 WriteShort(MSG_ENTITY, this.fade_end);
336                 WriteShort(MSG_ENTITY, this.fade_start);
337
338                 if(this.mdl == "")
339                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
340
341                 WriteString(MSG_ENTITY, this.mdl);
342         }
343
344
345         if(sf & ISF_COLORMAP)
346         {
347                 WriteShort(MSG_ENTITY, this.colormap);
348                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
349                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
350                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
351         }
352
353         if(sf & ISF_DROP)
354         {
355                 WriteVector(MSG_ENTITY, this.velocity);
356         }
357
358         return true;
359 }
360
361 void ItemUpdate(entity this)
362 {
363         this.oldorigin = this.origin;
364         this.SendFlags |= ISF_LOCATION;
365 }
366
367 void UpdateItemAfterTeleport(entity this)
368 {
369         if(getSendEntity(this) == ItemSend)
370                 ItemUpdate(this);
371 }
372
373 bool have_pickup_item(entity this)
374 {
375         if(this.itemdef.instanceOfPowerup)
376         {
377                 if(autocvar_g_powerups > 0)
378                         return true;
379                 if(autocvar_g_powerups == 0)
380                         return false;
381         }
382         else
383         {
384                 if(autocvar_g_pickup_items > 0)
385                         return true;
386                 if(autocvar_g_pickup_items == 0)
387                         return false;
388                 if(g_weaponarena)
389                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
390                                 return false;
391         }
392         return true;
393 }
394
395 void Item_Show(entity e, int mode)
396 {
397         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
398         e.ItemStatus &= ~ITS_STAYWEP;
399         entity def = e.itemdef;
400         if (mode > 0)
401         {
402                 // make the item look normal, and be touchable
403                 e.model = e.mdl;
404                 e.solid = SOLID_TRIGGER;
405                 e.spawnshieldtime = 1;
406                 e.ItemStatus |= ITS_AVAILABLE;
407         }
408         else if (mode < 0)
409         {
410                 // hide the item completely
411                 e.model = string_null;
412                 e.solid = SOLID_NOT;
413                 e.spawnshieldtime = 1;
414                 e.ItemStatus &= ~ITS_AVAILABLE;
415         }
416         else
417         {
418                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
419                         || e.team // weapon stay isn't supported for teamed weapons
420                         ;
421                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
422                 {
423                         // make the item translucent and not touchable
424                         e.model = e.mdl;
425                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
426                         e.effects |= EF_STARDUST;
427                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
428                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
429                 }
430                 else
431                 {
432                         //setmodel(e, "null");
433                         e.solid = SOLID_NOT;
434                         e.colormod = '0 0 0';
435                         //e.glowmod = e.colormod;
436                         e.spawnshieldtime = 1;
437                         e.ItemStatus &= ~ITS_AVAILABLE;
438                 }
439         }
440
441         if (def.m_glow)
442                 e.ItemStatus |= ITS_GLOW;
443
444         if (autocvar_g_nodepthtestitems)
445                 e.effects |= EF_NODEPTHTEST;
446
447
448         if (autocvar_g_fullbrightitems)
449                 e.ItemStatus |= ITS_ALLOWFB;
450
451         if (autocvar_sv_simple_items)
452                 e.ItemStatus |= ITS_ALLOWSI;
453
454         // relink entity (because solid may have changed)
455         setorigin(e, e.origin);
456         e.SendFlags |= ISF_STATUS;
457 }
458
459 void Item_Think(entity this)
460 {
461         this.nextthink = time;
462         if(this.origin != this.oldorigin)
463                 ItemUpdate(this);
464 }
465
466 bool Item_ItemsTime_SpectatorOnly(GameItem it);
467 bool Item_ItemsTime_Allow(GameItem it);
468 float Item_ItemsTime_UpdateTime(entity e, float t);
469 void Item_ItemsTime_SetTime(entity e, float t);
470 void Item_ItemsTime_SetTimesForAllPlayers();
471
472 void Item_Respawn(entity this)
473 {
474         Item_Show(this, 1);
475         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
476         setorigin(this, this.origin);
477
478         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
479         {
480                 float t = Item_ItemsTime_UpdateTime(this, 0);
481                 Item_ItemsTime_SetTime(this, t);
482                 Item_ItemsTime_SetTimesForAllPlayers();
483         }
484
485         setthink(this, Item_Think);
486         this.nextthink = time;
487
488         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
489         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
490 }
491
492 void Item_RespawnCountdown(entity this)
493 {
494         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
495         {
496                 if(this.waypointsprite_attached)
497                         WaypointSprite_Kill(this.waypointsprite_attached);
498                 Item_Respawn(this);
499         }
500         else
501         {
502                 this.nextthink = time + 1;
503                 this.item_respawncounter += 1;
504                 if(this.item_respawncounter == 1)
505                 {
506                         do {
507                                 {
508                                         entity wi = Weapons_from(this.weapon);
509                                         if (wi != WEP_Null) {
510                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
511                                                 wp.wp_extra = wi.m_id;
512                                                 break;
513                                         }
514                                 }
515                                 {
516                                         entity ii = this.itemdef;
517                                         if (ii != NULL) {
518                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
519                                                 wp.wp_extra = ii.m_id;
520                                                 break;
521                                         }
522                                 }
523                         } while (0);
524                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
525             if(this.waypointsprite_attached)
526             {
527                 GameItem def = this.itemdef;
528                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
529                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
530                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
531             }
532                 }
533
534                 if(this.waypointsprite_attached)
535                 {
536                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
537                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
538                                 {
539                                         msg_entity = it;
540                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
541                                 }
542                         });
543
544                         WaypointSprite_Ping(this.waypointsprite_attached);
545                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
546                 }
547         }
548 }
549
550 void Item_RespawnThink(entity this)
551 {
552         this.nextthink = time;
553         if(this.origin != this.oldorigin)
554                 ItemUpdate(this);
555
556         if(time >= this.wait)
557                 Item_Respawn(this);
558 }
559
560 void Item_ScheduleRespawnIn(entity e, float t)
561 {
562         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
563         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
564         {
565                 setthink(e, Item_RespawnCountdown);
566                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
567                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
568                 e.item_respawncounter = 0;
569                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
570                 {
571                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
572                         Item_ItemsTime_SetTime(e, t);
573                         Item_ItemsTime_SetTimesForAllPlayers();
574                 }
575         }
576         else
577         {
578                 setthink(e, Item_RespawnThink);
579                 e.nextthink = time;
580                 e.scheduledrespawntime = time + t;
581                 e.wait = time + t;
582
583                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
584                 {
585                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
586                         Item_ItemsTime_SetTime(e, t);
587                         Item_ItemsTime_SetTimesForAllPlayers();
588                 }
589         }
590 }
591
592 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
593 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
594 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
595
596 /// Adjust respawn time according to the number of players.
597 float adjust_respawntime(float normal_respawntime) {
598         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
599         float o = autocvar_g_pickup_respawntime_scaling_offset;
600         float l = autocvar_g_pickup_respawntime_scaling_linear;
601
602         if (r == 0 && l == 1) {
603                 return normal_respawntime;
604         }
605
606         entity balance = TeamBalance_CheckAllowedTeams(NULL);
607         TeamBalance_GetTeamCounts(balance, NULL);
608         int players = 0;
609         for (int i = 1; i <= NUM_TEAMS; ++i)
610         {
611                 if (TeamBalance_IsTeamAllowed(balance, i))
612                 {
613                         players += TeamBalance_GetNumberOfPlayers(balance, i);
614                 }
615         }
616         TeamBalance_Destroy(balance);
617
618         if (players >= 2) {
619                 return normal_respawntime * (r / (players + o) + l);
620         } else {
621                 return normal_respawntime;
622         }
623 }
624
625 void Item_ScheduleRespawn(entity e)
626 {
627         if(e.respawntime > 0)
628         {
629                 Item_Show(e, 0);
630
631                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
632                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
633
634                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
635                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
636                 Item_ScheduleRespawnIn(e, respawn_in);
637         }
638         else // if respawntime is -1, this item does not respawn
639                 Item_Show(e, -1);
640 }
641
642 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
643         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
644
645 void Item_ScheduleInitialRespawn(entity e)
646 {
647         Item_Show(e, 0);
648
649         float spawn_in;
650         if (autocvar_g_pickup_respawntime_initial_random == 0)
651         {
652                 // range: respawntime .. respawntime + respawntimejitter
653                 spawn_in = e.respawntime + random() * e.respawntimejitter;
654         }
655         else
656         {
657                 float rnd;
658                 if (autocvar_g_pickup_respawntime_initial_random == 1)
659                 {
660                         static float shared_random = 0;
661                         // NOTE this code works only if items are scheduled at the same time (normal case)
662                         // NOTE2 random() can't return exactly 1 so this check always work as intended
663                         if (!shared_random || floor(time) > shared_random)
664                                 shared_random = floor(time) + random();
665                         rnd = shared_random - floor(time);
666                 }
667                 else
668                         rnd = random();
669
670                 // range:
671                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
672                 // else: 0 .. ITEM_RESPAWN_TICKS
673                 // this is to prevent powerups spawning unexpectedly without waypoints
674                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
675         }
676
677         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
678 }
679
680 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
681         entity ammo_entity)
682 {
683         if (num_weapons == 0)
684         {
685                 return;
686         }
687         int num_potential_weapons = tokenize_console(weapon_names);
688         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
689         {
690                 RandomSelection_Init();
691                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
692                         ++weapon_index)
693                 {
694                         string weapon = argv(weapon_index);
695                         FOREACH(Weapons, it != WEP_Null,
696                         {
697                                 // Finding a weapon which player doesn't have.
698                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
699                                 {
700                                         RandomSelection_AddEnt(it, 1, 1);
701                                         break;
702                                 }
703                         });
704                 }
705                 if (RandomSelection_chosen_ent == NULL)
706                 {
707                         return;
708                 }
709                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
710                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
711                 {
712                         continue;
713                 }
714                 if (GetResource(receiver,
715                         RandomSelection_chosen_ent.ammo_type) != 0)
716                 {
717                         continue;
718                 }
719                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
720                         GetResource(ammo_entity,
721                         RandomSelection_chosen_ent.ammo_type));
722         }
723 }
724
725 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
726 {
727         float amount = GetResource(item, res_type);
728         if (amount == 0)
729         {
730                 return false;
731         }
732         float player_amount = GetResource(player, res_type);
733         if (item.spawnshieldtime)
734         {
735                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
736                         return false;
737         }
738         else if (g_weapon_stay == 2)
739         {
740                 ammomax = min(amount, ammomax);
741                 if(player_amount >= ammomax)
742                         return false;
743         }
744         else
745                 return false;
746         if (amount < 0)
747                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
748         else
749                 GiveResourceWithLimit(player, res_type, amount, ammomax);
750         return true;
751 }
752
753 bool Item_GiveTo(entity item, entity player)
754 {
755         // if nothing happens to player, just return without taking the item
756         int _switchweapon = 0;
757         // in case the player has autoswitch enabled do the following:
758         // if the player is using their best weapon before items are given, they
759         // probably want to switch to an even better weapon after items are given
760
761         if(CS(player).autoswitch)
762         {
763                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
764                 {
765                         .entity weaponentity = weaponentities[slot];
766                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
767                         {
768                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
769                                         _switchweapon |= BIT(slot);
770
771                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
772                                         _switchweapon |= BIT(slot);
773                         }
774                 }
775         }
776         bool pickedup = false;
777         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
778         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
779         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
780         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
781         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
782         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
783         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
784         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
785         if (item.itemdef.instanceOfWeaponPickup)
786         {
787                 WepSet w;
788                 w = STAT(WEAPONS, item);
789                 w &= ~STAT(WEAPONS, player);
790
791                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
792                 {
793                         pickedup = true;
794                         FOREACH(Weapons, it != WEP_Null, {
795                                 if(w & (it.m_wepset))
796                                 {
797                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
798                                         {
799                                                 .entity weaponentity = weaponentities[slot];
800                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
801                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
802                                         }
803                                         W_GiveWeapon(player, it.m_id);
804                                 }
805                         });
806                 }
807         }
808
809         if (item.itemdef.instanceOfPowerup)
810         {
811                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
812                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
813                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
814                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
815         }
816
817         int its;
818         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
819         {
820                 pickedup = true;
821                 player.items |= its;
822                 // TODO: we probably want to show a message in the console, but not this one!
823                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
824         }
825
826         if (item.strength_finished)
827         {
828                 pickedup = true;
829                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
830         }
831         if (item.invincible_finished)
832         {
833                 pickedup = true;
834                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
835         }
836         if (item.superweapons_finished)
837         {
838                 pickedup = true;
839                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
840         }
841
842         // always eat teamed entities
843         if(item.team)
844                 pickedup = true;
845
846         if (!pickedup)
847                 return false;
848
849         // crude hack to enforce switching weapons
850         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
851         {
852                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
853                 {
854                         .entity weaponentity = weaponentities[slot];
855                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
856                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
857                 }
858                 return true;
859         }
860
861         if(_switchweapon)
862         {
863                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
864                 {
865                         .entity weaponentity = weaponentities[slot];
866                         if(_switchweapon & BIT(slot))
867                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
868                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
869                 }
870         }
871
872         return true;
873 }
874
875 void Item_Touch(entity this, entity toucher)
876 {
877         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
878         if (Item_IsLoot(this))
879         {
880                 if (ITEM_TOUCH_NEEDKILL())
881                 {
882                         delete(this);
883                         return;
884                 }
885         }
886
887         if(!(toucher.flags & FL_PICKUPITEMS)
888         || STAT(FROZEN, toucher)
889         || IS_DEAD(toucher)
890         || (this.solid != SOLID_TRIGGER)
891         || (this.owner == toucher)
892         || (time < this.item_spawnshieldtime)
893         ) { return; }
894
895         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
896         {
897                 case MUT_ITEMTOUCH_RETURN: { return; }
898                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
899         }
900
901         toucher = M_ARGV(1, entity);
902
903         if (Item_IsExpiring(this))
904         {
905                 this.strength_finished = max(0, this.strength_finished - time);
906                 this.invincible_finished = max(0, this.invincible_finished - time);
907                 this.superweapons_finished = max(0, this.superweapons_finished - time);
908         }
909         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
910         if (!gave)
911         {
912                 if (Item_IsExpiring(this))
913                 {
914                         // undo what we did above
915                         this.strength_finished += time;
916                         this.invincible_finished += time;
917                         this.superweapons_finished += time;
918                 }
919                 return;
920         }
921
922 LABEL(pickup)
923
924         if(this.target && this.target != "" && this.target != "###item###") // defrag support
925                 SUB_UseTargets(this, toucher, NULL);
926
927         STAT(LAST_PICKUP, toucher) = time;
928
929         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
930         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
931
932         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
933         if (wasfreed(this))
934         {
935                 return;
936         }
937
938         if (Item_IsLoot(this))
939         {
940                 delete(this);
941                 return;
942         }
943         if (!this.spawnshieldtime)
944         {
945                 return;
946         }
947         entity e;
948         if (this.team)
949         {
950                 RandomSelection_Init();
951                 IL_EACH(g_items, it.team == this.team,
952                 {
953                         if (it.itemdef) // is a registered item
954                         {
955                                 Item_Show(it, -1);
956                                 it.scheduledrespawntime = 0;
957                                 RandomSelection_AddEnt(it, it.cnt, 0);
958                         }
959                 });
960                 e = RandomSelection_chosen_ent;
961                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
962         }
963         else
964                 e = this;
965         Item_ScheduleRespawn(e);
966 }
967
968 void Item_Reset(entity this)
969 {
970         Item_Show(this, !this.state);
971         setorigin(this, this.origin);
972
973         if (Item_IsLoot(this))
974         {
975                 return;
976         }
977         setthink(this, Item_Think);
978         this.nextthink = time;
979         if (this.waypointsprite_attached)
980         {
981                 WaypointSprite_Kill(this.waypointsprite_attached);
982         }
983         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
984         {
985                 Item_ScheduleInitialRespawn(this);
986         }
987 }
988
989 void Item_FindTeam(entity this)
990 {
991         entity e;
992
993         if(this.effects & EF_NODRAW)
994         {
995                 // marker for item team search
996                 LOG_TRACE("Initializing item team ", ftos(this.team));
997                 RandomSelection_Init();
998                 IL_EACH(g_items, it.team == this.team,
999                 {
1000                         if(it.itemdef) // is a registered item
1001                                 RandomSelection_AddEnt(it, it.cnt, 0);
1002                 });
1003
1004                 e = RandomSelection_chosen_ent;
1005                 if (!e)
1006                         return;
1007
1008                 IL_EACH(g_items, it.team == this.team,
1009                 {
1010                         if(it.itemdef) // is a registered item
1011                         {
1012                                 if(it != e)
1013                                 {
1014                                         // make it non-spawned
1015                                         Item_Show(it, -1);
1016                                         it.state = 1; // state 1 = initially hidden item, apparently
1017                                 }
1018                                 else
1019                                         Item_Reset(it);
1020                                 it.effects &= ~EF_NODRAW;
1021                         }
1022                 });
1023         }
1024 }
1025
1026 // Savage: used for item garbage-collection
1027 void RemoveItem(entity this)
1028 {
1029         if(wasfreed(this) || !this) { return; }
1030         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1031         delete(this);
1032 }
1033
1034 // pickup evaluation functions
1035 // these functions decide how desirable an item is to the bots
1036
1037 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1038
1039 float weapon_pickupevalfunc(entity player, entity item)
1040 {
1041         // See if I have it already
1042         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1043         {
1044                 // If I can pick it up
1045                 if(!item.spawnshieldtime)
1046                         return 0;
1047                 return ammo_pickupevalfunc(player, item);
1048         }
1049
1050         // reduce weapon value if bot already got a good arsenal
1051         float c = 1;
1052         int weapons_value = 0;
1053         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1054                 weapons_value += it.bot_pickupbasevalue;
1055         });
1056         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1057
1058         return item.bot_pickupbasevalue * c;
1059 }
1060
1061 float ammo_pickupevalfunc(entity player, entity item)
1062 {
1063         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1064         entity wpn = NULL;
1065         float c = 0;
1066         float rating = 0;
1067
1068         // Detect needed ammo
1069         if(item.itemdef.instanceOfWeaponPickup)
1070         {
1071                 entity ammo = NULL;
1072                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1073                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1074                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1075                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1076                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1077                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1078
1079                 if(!ammo)
1080                         return 0;
1081                 wpn = item;
1082                 rating = ammo.m_botvalue;
1083         }
1084         else
1085         {
1086                 FOREACH(Weapons, it != WEP_Null, {
1087                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1088                                 continue;
1089
1090                         switch(it.ammo_type)
1091                         {
1092                                 case RES_SHELLS:  need_shells  = true; break;
1093                                 case RES_BULLETS: need_nails   = true; break;
1094                                 case RES_ROCKETS: need_rockets = true; break;
1095                                 case RES_CELLS:   need_cells   = true; break;
1096                                 case RES_PLASMA:  need_plasma  = true; break;
1097                                 case RES_FUEL:    need_fuel    = true; break;
1098                         }
1099                 });
1100                 rating = item.bot_pickupbasevalue;
1101         }
1102
1103         float noammorating = 0.5;
1104
1105         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1106                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1107
1108         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1109                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1110
1111         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1112                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1113
1114         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1115                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1116
1117         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1118                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1119
1120         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1121                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1122
1123         rating *= min(c, 2);
1124         if(wpn)
1125                 rating += wpn.bot_pickupbasevalue * 0.1;
1126         return rating;
1127 }
1128
1129 float healtharmor_pickupevalfunc(entity player, entity item)
1130 {
1131         float c = 0;
1132         float rating = item.bot_pickupbasevalue;
1133
1134         float itemarmor = GetResource(item, RES_ARMOR);
1135         float itemhealth = GetResource(item, RES_HEALTH);
1136
1137         if(item.item_group)
1138         {
1139                 itemarmor *= min(4, item.item_group_count);
1140                 itemhealth *= min(4, item.item_group_count);
1141         }
1142
1143         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1144                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1145
1146         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1147                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1148
1149         rating *= min(2, c);
1150         return rating;
1151 }
1152
1153 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1154 {
1155         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1156                 RemoveItem(this);
1157 }
1158
1159 void item_use(entity this, entity actor, entity trigger)
1160 {
1161         // use the touch function to handle collection
1162         gettouch(this)(this, actor);
1163 }
1164
1165 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1166 {
1167         string itemname = def.m_name;
1168         Model itemmodel = def.m_model;
1169         Sound pickupsound = def.m_sound;
1170         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1171         float pickupbasevalue = def.m_botvalue;
1172         int itemflags = def.m_itemflags;
1173
1174         startitem_failed = false;
1175
1176         this.item_model_ent = itemmodel;
1177         this.item_pickupsound_ent = pickupsound;
1178
1179         if(def.m_iteminit)
1180                 def.m_iteminit(def, this);
1181
1182         if(!this.respawntime) // both need to be set
1183         {
1184                 this.respawntime = defaultrespawntime;
1185                 this.respawntimejitter = defaultrespawntimejitter;
1186         }
1187
1188         if(!this.pickup_anyway && def.m_pickupanyway)
1189                 this.pickup_anyway = def.m_pickupanyway();
1190
1191         int itemid = def.m_itemid;
1192         this.items = itemid;
1193         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1194         this.weapon = weaponid;
1195
1196         if(!this.fade_end)
1197         {
1198                 this.fade_start = autocvar_g_items_mindist;
1199                 this.fade_end = autocvar_g_items_maxdist;
1200         }
1201
1202         if(weaponid)
1203                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1204
1205         this.flags = FL_ITEM | itemflags;
1206         IL_PUSH(g_items, this);
1207
1208         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1209         {
1210                 startitem_failed = true;
1211                 delete(this);
1212                 return;
1213         }
1214
1215         precache_model(this.model);
1216         precache_sound(this.item_pickupsound);
1217
1218         if (Item_IsLoot(this))
1219         {
1220                 this.reset = SUB_Remove;
1221                 set_movetype(this, MOVETYPE_TOSS);
1222
1223                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1224                 setthink(this, RemoveItem);
1225                 this.nextthink = time + 20;
1226
1227                 this.takedamage = DAMAGE_YES;
1228                 this.event_damage = Item_Damage;
1229
1230                 if (Item_IsExpiring(this))
1231                 {
1232                         // if item is worthless after a timer, have it expire then
1233                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1234                 }
1235
1236                 // don't drop if in a NODROP zone (such as lava)
1237                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1238                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1239                 {
1240                         startitem_failed = true;
1241                         delete(this);
1242                         return;
1243                 }
1244         }
1245         else
1246         {
1247                 if(!have_pickup_item(this))
1248                 {
1249                         startitem_failed = true;
1250                         delete(this);
1251                         return;
1252                 }
1253
1254                 if(this.angles != '0 0 0')
1255                         this.SendFlags |= ISF_ANGLES;
1256
1257                 this.reset = Item_Reset;
1258                 // it's a level item
1259                 if(this.spawnflags & 1)
1260                         this.noalign = 1;
1261                 if (this.noalign > 0)
1262                         set_movetype(this, MOVETYPE_NONE);
1263                 else
1264                         set_movetype(this, MOVETYPE_TOSS);
1265                 // do item filtering according to game mode and other things
1266                 if (this.noalign <= 0)
1267                 {
1268                         // first nudge it off the floor a little bit to avoid math errors
1269                         setorigin(this, this.origin + '0 0 1');
1270                         // set item size before we spawn a spawnfunc_waypoint
1271                         setsize(this, def.m_mins, def.m_maxs);
1272                         this.SendFlags |= ISF_SIZE;
1273                         // note droptofloor returns false if stuck/or would fall too far
1274                         if (!this.noalign)
1275                                 droptofloor(this);
1276                         waypoint_spawnforitem(this);
1277                 }
1278
1279                 /*
1280                  * can't do it that way, as it would break maps
1281                  * TODO make a target_give like entity another way, that perhaps has
1282                  * the weapon name in a key
1283                 if(this.targetname)
1284                 {
1285                         // target_give not yet supported; maybe later
1286                         print("removed targeted ", this.classname, "\n");
1287                         startitem_failed = true;
1288                         delete(this);
1289                         return;
1290                 }
1291                 */
1292
1293                 if(this.targetname != "" && (this.spawnflags & 16))
1294                         this.use = item_use;
1295
1296                 if(autocvar_spawn_debug >= 2)
1297                 {
1298             // why not flags & fl_item?
1299                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1300                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1301                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1302                 error("Mapper sucks.");
1303             });
1304                         this.is_item = true;
1305                 }
1306
1307                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1308
1309                 if (   def.instanceOfPowerup
1310                         || def.instanceOfWeaponPickup
1311                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1312                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1313                         || (itemid & (IT_KEY1 | IT_KEY2))
1314                 )
1315                 {
1316                         if(!this.target || this.target == "")
1317                                 this.target = "###item###"; // for finding the nearest item using findnearest
1318                 }
1319
1320                 Item_ItemsTime_SetTime(this, 0);
1321         }
1322
1323         this.bot_pickup = true;
1324         this.bot_pickupevalfunc = pickupevalfunc;
1325         this.bot_pickupbasevalue = pickupbasevalue;
1326         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1327         this.netname = itemname;
1328         settouch(this, Item_Touch);
1329         setmodel(this, MDL_Null); // precision set below
1330         //this.effects |= EF_LOWPRECISION;
1331
1332         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1333
1334         this.SendFlags |= ISF_SIZE;
1335
1336         if (!(this.spawnflags & 1024)) {
1337                 if(def.instanceOfPowerup)
1338                         this.ItemStatus |= ITS_ANIMATE1;
1339
1340                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1341                         this.ItemStatus |= ITS_ANIMATE2;
1342         }
1343
1344         if(Item_IsLoot(this))
1345                 this.gravity = 1;
1346
1347         if(def.instanceOfWeaponPickup)
1348         {
1349                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1350                         this.colormap = 1024; // color shirt=0 pants=0 grey
1351                 if (!(this.spawnflags & 1024))
1352                         this.ItemStatus |= ITS_ANIMATE1;
1353                 this.SendFlags |= ISF_COLORMAP;
1354         }
1355
1356         this.state = 0;
1357         if(this.team)
1358         {
1359                 if(!this.cnt)
1360                         this.cnt = 1; // item probability weight
1361
1362                 this.effects |= EF_NODRAW; // marker for item team search
1363                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1364         }
1365         else
1366                 Item_Reset(this);
1367
1368         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1369
1370         // call this hook after everything else has been done
1371         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1372         {
1373                 startitem_failed = true;
1374                 delete(this);
1375                 return;
1376         }
1377
1378         setItemGroup(this);
1379 }
1380
1381 void StartItem(entity this, GameItem def)
1382 {
1383     def = def.m_spawnfunc_hookreplace(def, this);
1384     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1385     {
1386         delete(this);
1387         return;
1388     }
1389     this.classname = def.m_canonical_spawnfunc;
1390     _StartItem(
1391         this,
1392         this.itemdef = def,
1393         def.m_respawntime(), // defaultrespawntime
1394         def.m_respawntimejitter() // defaultrespawntimejitter
1395         );
1396 }
1397
1398 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1399 int group_count = 1;
1400
1401 void setItemGroup(entity this)
1402 {
1403         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1404                 return;
1405
1406         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1407         {
1408                 if(!this.item_group)
1409                 {
1410                         if(!it.item_group)
1411                         {
1412                                 it.item_group = group_count;
1413                                 group_count++;
1414                         }
1415                         this.item_group = it.item_group;
1416                 }
1417                 else // spawning item is already part of a item_group X
1418                 {
1419                         if(!it.item_group)
1420                                 it.item_group = this.item_group;
1421                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1422                         {
1423                                 int grY = it.item_group;
1424                                 // move all items of item_group Y to item_group X
1425                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1426                                 {
1427                                         if(it.item_group == grY)
1428                                                 it.item_group = this.item_group;
1429                                 });
1430                         }
1431                 }
1432         });
1433 }
1434
1435 void setItemGroupCount()
1436 {
1437         for (int k = 1; k <= group_count; k++)
1438         {
1439                 int count = 0;
1440                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1441                 if (count)
1442                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1443         }
1444 }
1445
1446 void target_items_use(entity this, entity actor, entity trigger)
1447 {
1448         if(Item_IsLoot(actor))
1449         {
1450                 EXACTTRIGGER_TOUCH(this, trigger);
1451                 delete(actor);
1452                 return;
1453         }
1454
1455         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1456                 return;
1457
1458         if(trigger.solid == SOLID_TRIGGER)
1459         {
1460                 EXACTTRIGGER_TOUCH(this, trigger);
1461         }
1462
1463         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1464         {
1465                 delete(it);
1466         });
1467
1468         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1469                 centerprint(actor, this.message);
1470 }
1471
1472 spawnfunc(target_items)
1473 {
1474         this.use = target_items_use;
1475         if(!this.strength_finished)
1476                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1477         if(!this.invincible_finished)
1478                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1479         if(!this.superweapons_finished)
1480                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1481
1482         string str;
1483         int n = tokenize_console(this.netname);
1484         if(argv(0) == "give")
1485         {
1486                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1487         }
1488         else
1489         {
1490                 for(int j = 0; j < n; ++j)
1491                 {
1492                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1493                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1494                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1495                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1496                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1497                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1498                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1499                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1500                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1501                         else
1502                         {
1503                                 FOREACH(Buffs, it != BUFF_Null,
1504                                 {
1505                                         string s = Buff_UndeprecateName(argv(j));
1506                                         if(s == it.netname)
1507                                         {
1508                                                 STAT(BUFFS, this) |= (it.m_itemid);
1509                                                 if(!STAT(BUFF_TIME, this))
1510                                                         STAT(BUFF_TIME, this) = it.m_time(it);
1511                                                 break;
1512                                         }
1513                                 });
1514                                 FOREACH(Weapons, it != WEP_Null, {
1515                                         string s = W_UndeprecateName(argv(j));
1516                                         if(s == it.netname)
1517                                         {
1518                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1519                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1520                                                         it.wr_init(it);
1521                                                 break;
1522                                         }
1523                                 });
1524                         }
1525                 }
1526
1527                 string itemprefix, valueprefix;
1528                 if(this.spawnflags == 0)
1529                 {
1530                         itemprefix = "";
1531                         valueprefix = "";
1532                 }
1533                 else if(this.spawnflags == 1)
1534                 {
1535                         itemprefix = "max ";
1536                         valueprefix = "max ";
1537                 }
1538                 else if(this.spawnflags == 2)
1539                 {
1540                         itemprefix = "min ";
1541                         valueprefix = "min ";
1542                 }
1543                 else if(this.spawnflags == 4)
1544                 {
1545                         itemprefix = "minus ";
1546                         valueprefix = "max ";
1547                 }
1548                 else
1549                 {
1550                         error("invalid spawnflags");
1551                         itemprefix = valueprefix = string_null;
1552                 }
1553
1554                 str = "";
1555                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1556                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1557                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1558                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1559                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1560                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1561                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1562                 float res;
1563                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1564                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1565                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1566                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1567                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1568                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1569                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1570                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1571                 // HACK: buffs share a single timer, so we need to include enabled buffs AFTER disabled ones to avoid loss
1572                 FOREACH(Buffs, it != BUFF_Null && !(STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1573                 FOREACH(Buffs, it != BUFF_Null && (STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1574                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1575         }
1576         this.netname = strzone(str);
1577
1578         n = tokenize_console(this.netname);
1579         for(int j = 0; j < n; ++j)
1580         {
1581                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1582                         it.wr_init(it);
1583                         break;
1584                 });
1585         }
1586 }
1587
1588 float GiveWeapon(entity e, float wpn, float op, float val)
1589 {
1590         WepSet v0, v1;
1591         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1592         v0 = (STAT(WEAPONS, e) & s);
1593         switch(op)
1594         {
1595                 case OP_SET:
1596                         if(val > 0)
1597                                 STAT(WEAPONS, e) |= s;
1598                         else
1599                                 STAT(WEAPONS, e) &= ~s;
1600                         break;
1601                 case OP_MIN:
1602                 case OP_PLUS:
1603                         if(val > 0)
1604                                 STAT(WEAPONS, e) |= s;
1605                         break;
1606                 case OP_MAX:
1607                         if(val <= 0)
1608                                 STAT(WEAPONS, e) &= ~s;
1609                         break;
1610                 case OP_MINUS:
1611                         if(val > 0)
1612                                 STAT(WEAPONS, e) &= ~s;
1613                         break;
1614         }
1615         v1 = (STAT(WEAPONS, e) & s);
1616         return (v0 != v1);
1617 }
1618
1619 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1620 {
1621         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1622         float new_buff_time = ((had_buff) ? STAT(BUFF_TIME, e) : 0);
1623         switch (op)
1624         {
1625                 case OP_SET:
1626                         new_buff_time = val;
1627                         break;
1628                 case OP_MIN:
1629                         new_buff_time = max(new_buff_time, val);
1630                         break;
1631                 case OP_MAX:
1632                         new_buff_time = min(new_buff_time, val);
1633                         break;
1634                 case OP_PLUS:
1635                         new_buff_time += val;
1636                         break;
1637                 case OP_MINUS:
1638                         new_buff_time -= val;
1639                         break;
1640         }
1641         if(new_buff_time <= 0)
1642         {
1643                 if(had_buff)
1644                         STAT(BUFF_TIME, e) = new_buff_time;
1645                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1646         }
1647         else
1648         {
1649                 STAT(BUFF_TIME, e) = new_buff_time;
1650                 STAT(BUFFS, e) = thebuff.m_itemid; // NOTE: replaces any existing buffs on the player!
1651         }
1652         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1653         return (had_buff != have_buff);
1654 }
1655
1656 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1657 {
1658         if(v1 == v0)
1659                 return;
1660         if(v1 <= v0 - t)
1661         {
1662                 if(snd_decr != NULL)
1663                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1664         }
1665         else if(v0 >= v0 + t)
1666         {
1667                 if(snd_incr != NULL)
1668                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1669         }
1670 }
1671
1672 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1673 {
1674         if(v0 < v1)
1675                 e.(rotfield) = max(e.(rotfield), time + rottime);
1676         else if(v0 > v1)
1677                 e.(regenfield) = max(e.(regenfield), time + regentime);
1678 }
1679 bool GiveResourceValue(entity e, int res_type, int op, int val)
1680 {
1681         int v0 = GetResource(e, res_type);
1682         float new_val = 0;
1683         switch (op)
1684         {
1685                 // min 100 cells = at least 100 cells
1686                 case OP_SET: new_val = val; break;
1687                 case OP_MIN: new_val = max(v0, val); break;
1688                 case OP_MAX: new_val = min(v0, val); break;
1689                 case OP_PLUS: new_val = v0 + val; break;
1690                 case OP_MINUS: new_val = v0 - val; break;
1691                 default: return false;
1692         }
1693
1694         return SetResourceExplicit(e, res_type, new_val);
1695 }
1696
1697 float GiveItems(entity e, float beginarg, float endarg)
1698 {
1699         float got, i, val, op;
1700         string cmd;
1701
1702         val = 999;
1703         op = OP_SET;
1704
1705         got = 0;
1706
1707         int _switchweapon = 0;
1708
1709         if(CS(e).autoswitch)
1710         {
1711                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1712                 {
1713                         .entity weaponentity = weaponentities[slot];
1714                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1715                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1716                                 _switchweapon |= BIT(slot);
1717                 }
1718         }
1719
1720         e.strength_finished = max(0, e.strength_finished - time);
1721         e.invincible_finished = max(0, e.invincible_finished - time);
1722         e.superweapons_finished = max(0, e.superweapons_finished - time);
1723         STAT(BUFF_TIME, e) = max(0, STAT(BUFF_TIME, e) - time);
1724
1725         PREGIVE(e, items);
1726         PREGIVE_WEAPONS(e);
1727         PREGIVE(e, strength_finished);
1728         PREGIVE(e, invincible_finished);
1729         PREGIVE(e, superweapons_finished);
1730         PREGIVE_RESOURCE(e, RES_BULLETS);
1731         PREGIVE_RESOURCE(e, RES_CELLS);
1732         PREGIVE_RESOURCE(e, RES_PLASMA);
1733         PREGIVE_RESOURCE(e, RES_SHELLS);
1734         PREGIVE_RESOURCE(e, RES_ROCKETS);
1735         PREGIVE_RESOURCE(e, RES_FUEL);
1736         PREGIVE_RESOURCE(e, RES_ARMOR);
1737         PREGIVE_RESOURCE(e, RES_HEALTH);
1738
1739         for(i = beginarg; i < endarg; ++i)
1740         {
1741                 cmd = argv(i);
1742
1743                 if(cmd == "0" || stof(cmd))
1744                 {
1745                         val = stof(cmd);
1746                         continue;
1747                 }
1748                 switch(cmd)
1749                 {
1750                         case "no":
1751                                 op = OP_MAX;
1752                                 val = 0;
1753                                 continue;
1754                         case "max":
1755                                 op = OP_MAX;
1756                                 continue;
1757                         case "min":
1758                                 op = OP_MIN;
1759                                 continue;
1760                         case "plus":
1761                                 op = OP_PLUS;
1762                                 continue;
1763                         case "minus":
1764                                 op = OP_MINUS;
1765                                 continue;
1766                         case "ALL":
1767                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1768                                 got += GiveValue(e, strength_finished, op, val);
1769                                 got += GiveValue(e, invincible_finished, op, val);
1770                                 got += GiveValue(e, superweapons_finished, op, val);
1771                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1772                         case "all":
1773                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1774                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1775                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1776                         case "allweapons":
1777                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1778                         //case "allbuffs": // all buffs makes a player god, do not want!
1779                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1780                         case "allammo":
1781                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1782                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1783                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1784                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1785                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1786                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1787                                 break;
1788                         case "unlimited_ammo":
1789                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1790                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1791                                 break;
1792                         case "unlimited_weapon_ammo":
1793                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1794                                 break;
1795                         case "unlimited_superweapons":
1796                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1797                                 break;
1798                         case "jetpack":
1799                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1800                                 break;
1801                         case "fuel_regen":
1802                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1803                                 break;
1804                         case "strength":
1805                                 got += GiveValue(e, strength_finished, op, val);
1806                                 break;
1807                         case "invincible":
1808                                 got += GiveValue(e, invincible_finished, op, val);
1809                                 break;
1810                         case "superweapons":
1811                                 got += GiveValue(e, superweapons_finished, op, val);
1812                                 break;
1813                         case "cells":
1814                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1815                                 break;
1816                         case "plasma":
1817                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1818                                 break;
1819                         case "shells":
1820                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1821                                 break;
1822                         case "nails":
1823                         case "bullets":
1824                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1825                                 break;
1826                         case "rockets":
1827                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1828                                 break;
1829                         case "health":
1830                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1831                                 break;
1832                         case "armor":
1833                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1834                                 break;
1835                         case "fuel":
1836                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1837                                 break;
1838                         default:
1839                                 FOREACH(Buffs, it != BUFF_Null && buff_Available(it) && Buff_UndeprecateName(cmd) == it.netname,
1840                                 {
1841                                         got += GiveBuff(e, it, op, val);
1842                                         break;
1843                                 });
1844                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1845                     got += GiveWeapon(e, it.m_id, op, val);
1846                     break;
1847                                 });
1848                                 break;
1849                 }
1850                 val = 999;
1851                 op = OP_SET;
1852         }
1853
1854         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1855         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1856         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1857         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1858         FOREACH(Weapons, it != WEP_Null, {
1859                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1860                 if(!(save_weapons & (it.m_wepset)))
1861                         if(STAT(WEAPONS, e) & (it.m_wepset))
1862                                 it.wr_init(it);
1863         });
1864         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1865         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1866         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1867         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1868         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1869         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1870         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1871         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1872         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1873         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1874         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1875
1876         if(e.superweapons_finished <= 0)
1877                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1878                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1879
1880         if(e.strength_finished <= 0)
1881                 e.strength_finished = 0;
1882         else
1883                 e.strength_finished += time;
1884         if(e.invincible_finished <= 0)
1885                 e.invincible_finished = 0;
1886         else
1887                 e.invincible_finished += time;
1888         if(e.superweapons_finished <= 0)
1889                 e.superweapons_finished = 0;
1890         else
1891                 e.superweapons_finished += time;
1892         if(STAT(BUFF_TIME, e) <= 0)
1893                 STAT(BUFF_TIME, e) = 0;
1894         else
1895                 STAT(BUFF_TIME, e) += time;
1896
1897         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1898         {
1899                 .entity weaponentity = weaponentities[slot];
1900                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1901                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1902                         _switchweapon |= BIT(slot);
1903         }
1904
1905         if(_switchweapon)
1906         {
1907                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1908                 {
1909                         .entity weaponentity = weaponentities[slot];
1910                         if(_switchweapon & BIT(slot))
1911                         {
1912                                 Weapon wep = w_getbestweapon(e, weaponentity);
1913                                 if(wep != e.(weaponentity).m_switchweapon)
1914                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1915                         }
1916                 }
1917         }
1918
1919         return got;
1920 }
1921 #endif