Add a hack to fix the use of self in .predraw functions
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/all.qc"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/bot.qh"
8     #include "../server/bot/waypoints.qh"
9
10     #include <server/mutators/all.qh>
11
12     #include "../server/weapons/common.qh"
13     #include "../server/weapons/selection.qh"
14     #include "../server/weapons/weaponsystem.qh"
15
16     #include "constants.qh"
17     #include <common/deathtypes/all.qh>
18     #include <common/notifications.qh>
19         #include "triggers/subs.qh"
20     #include "util.qh"
21
22     #include <common/monsters/all.qh>
23
24     #include <common/weapons/all.qh>
25
26     #include "../lib/warpzone/util_server.qh"
27 #elif defined(CSQC)
28         #include "physics/movetypes/movetypes.qh"
29         #include <common/weapons/all.qh>
30         #include "../lib/csqcmodel/cl_model.qh"
31         #include "../lib/csqcmodel/common.qh"
32 #endif
33
34 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
35
36 #ifdef CSQC
37 bool autocvar_cl_ghost_items_vehicle = true;
38 void Item_SetAlpha(entity this)
39 {
40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
41
42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
43         {
44                 this.alpha = 1;
45                 this.colormod = this.glowmod = '1 1 1';
46         }
47         else
48         {
49                 if (autocvar_cl_ghost_items_color)
50                 {
51                         this.alpha = autocvar_cl_ghost_items;
52                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
53                 }
54                 else
55                         this.alpha = -1;
56         }
57
58         if(!veh_hud)
59         if(this.ItemStatus & ITS_STAYWEP)
60         {
61                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
62                 this.alpha = autocvar_cl_weapon_stay_alpha;
63         }
64 }
65
66 void ItemDraw(entity this)
67 {
68     if(this.gravity)
69     {
70         Movetype_Physics_MatchServer(this, false);
71         if(this.move_flags & FL_ONGROUND)
72         { // For some reason move_avelocity gets set to '0 0 0' here ...
73             this.oldorigin = this.origin;
74             this.gravity = 0;
75
76             if(autocvar_cl_animate_items)
77             { // ... so reset it if animations are requested.
78                 if(this.ItemStatus & ITS_ANIMATE1)
79                     this.move_avelocity = '0 180 0';
80
81                 if(this.ItemStatus & ITS_ANIMATE2)
82                     this.move_avelocity = '0 -90 0';
83             }
84         }
85     }
86     else if (autocvar_cl_animate_items)
87     {
88         if(this.ItemStatus & ITS_ANIMATE1)
89         {
90             this.angles += this.move_avelocity * frametime;
91             setorigin(this, '0 0 10' + this.oldorigin + '0 0 8' * sin(time * 2));
92         }
93
94         if(this.ItemStatus & ITS_ANIMATE2)
95         {
96             this.angles += this.move_avelocity * frametime;
97             setorigin(this, '0 0 8' + this.oldorigin + '0 0 4' * sin(time * 3));
98         }
99     }
100
101     Item_SetAlpha(this);
102 }
103
104 void ItemDrawSimple(entity this)
105 {
106     if(this.gravity)
107     {
108         Movetype_Physics_MatchServer(this, false);
109
110         if(this.move_flags & FL_ONGROUND)
111             this.gravity = 0;
112     }
113
114     Item_SetAlpha(this);
115 }
116
117 void Item_PreDraw(entity this)
118 {
119         if(warpzone_warpzones_exist)
120         {
121                 // just incase warpzones were initialized last, reset these
122                 //this.alpha = 1; // alpha is already set by the draw function
123                 this.drawmask = MASK_NORMAL;
124                 return;
125         }
126         float alph;
127         vector org = getpropertyvec(VF_ORIGIN);
128         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
129                 alph = 0;
130         else if(this.fade_start)
131                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
132         else
133                 alph = 1;
134         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
135         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
136                 this.alpha = alph;
137         if(alph <= 0)
138                 this.drawmask = 0;
139         else
140                 this.drawmask = MASK_NORMAL;
141 }
142
143 void ItemRemove(entity this)
144 {
145         if(this.mdl)
146                 strunzone(this.mdl);
147 }
148
149 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
150 {
151     int sf = ReadByte();
152
153     if(sf & ISF_LOCATION)
154     {
155         self.origin_x = ReadCoord();
156         self.origin_y = ReadCoord();
157         self.origin_z = ReadCoord();
158         setorigin(self, self.origin);
159         self.oldorigin = self.origin;
160     }
161
162     if(sf & ISF_ANGLES)
163     {
164         self.angles_x = ReadAngle();
165         self.angles_y = ReadAngle();
166         self.angles_z = ReadAngle();
167         self.move_angles = self.angles;
168     }
169
170     if(sf & ISF_SIZE)
171     {
172         float use_bigsize = ReadByte();
173         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
174     }
175
176     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
177     {
178         self.ItemStatus = ReadByte();
179
180         Item_SetAlpha(self);
181
182         if(autocvar_cl_fullbright_items)
183             if(self.ItemStatus & ITS_ALLOWFB)
184                 self.effects |= EF_FULLBRIGHT;
185
186         if(self.ItemStatus & ITS_POWERUP)
187         {
188             if(self.ItemStatus & ITS_AVAILABLE)
189                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
190             else
191                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
192         }
193     }
194
195     if(sf & ISF_MODEL)
196     {
197         self.drawmask  = MASK_NORMAL;
198                 self.move_movetype = MOVETYPE_TOSS;
199         self.draw       = ItemDraw;
200         self.solid = SOLID_TRIGGER;
201         //self.move_flags |= FL_ITEM;
202
203         bool use_bigsize = ReadByte();
204
205         self.fade_end = ReadShort();
206         self.fade_start = ReadShort();
207         if(self.fade_start && !autocvar_cl_items_nofade)
208                 setpredraw(self, Item_PreDraw);
209
210         if(self.mdl)
211             strunzone(self.mdl);
212
213         self.mdl = "";
214         string _fn = ReadString();
215
216         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
217         {
218             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
219             self.draw = ItemDrawSimple;
220
221             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
222                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
223             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
224                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
225             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
226                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
227             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
228                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
229             else
230             {
231                 self.draw = ItemDraw;
232                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
233             }
234         }
235
236         if(self.draw != ItemDrawSimple)
237             self.mdl = strzone(_fn);
238
239
240         if(self.mdl == "")
241             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, ", tell tZork about this!\n");
242
243         precache_model(self.mdl);
244         _setmodel(self, self.mdl);
245
246         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
247     }
248
249     if(sf & ISF_COLORMAP)
250         self.colormap = ReadShort();
251
252     if(sf & ISF_DROP)
253     {
254         self.gravity = 1;
255         self.pushable = true;
256         //self.move_angles = '0 0 0';
257         self.move_movetype = MOVETYPE_TOSS;
258         self.move_velocity_x = ReadCoord();
259         self.move_velocity_y = ReadCoord();
260         self.move_velocity_z = ReadCoord();
261         self.velocity = self.move_velocity;
262         self.move_origin = self.oldorigin;
263
264         if(!self.move_time)
265         {
266             self.move_time = time;
267             self.spawntime = time;
268         }
269         else
270             self.move_time = max(self.move_time, time);
271     }
272
273     if(autocvar_cl_animate_items)
274     {
275         if(self.ItemStatus & ITS_ANIMATE1)
276             self.move_avelocity = '0 180 0';
277
278         if(self.ItemStatus & ITS_ANIMATE2)
279             self.move_avelocity = '0 -90 0';
280     }
281
282     self.entremove = ItemRemove;
283
284     return true;
285 }
286
287 #endif
288
289 #ifdef SVQC
290 bool ItemSend(entity this, entity to, int sf)
291 {
292         if(self.gravity)
293                 sf |= ISF_DROP;
294         else
295                 sf &= ~ISF_DROP;
296
297         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
298         WriteByte(MSG_ENTITY, sf);
299
300         //WriteByte(MSG_ENTITY, self.cnt);
301         if(sf & ISF_LOCATION)
302         {
303                 WriteCoord(MSG_ENTITY, self.origin.x);
304                 WriteCoord(MSG_ENTITY, self.origin.y);
305                 WriteCoord(MSG_ENTITY, self.origin.z);
306         }
307
308         if(sf & ISF_ANGLES)
309         {
310                 WriteAngle(MSG_ENTITY, self.angles_x);
311                 WriteAngle(MSG_ENTITY, self.angles_y);
312                 WriteAngle(MSG_ENTITY, self.angles_z);
313         }
314
315         if(sf & ISF_SIZE)
316         {
317                 Pickup p = this.itemdef;
318                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
319         }
320
321         if(sf & ISF_STATUS)
322                 WriteByte(MSG_ENTITY, self.ItemStatus);
323
324         if(sf & ISF_MODEL)
325         {
326                 Pickup p = this.itemdef;
327                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
328                 WriteShort(MSG_ENTITY, self.fade_end);
329                 WriteShort(MSG_ENTITY, self.fade_start);
330
331                 if(self.mdl == "")
332                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
333
334                 WriteString(MSG_ENTITY, self.mdl);
335         }
336
337
338         if(sf & ISF_COLORMAP)
339                 WriteShort(MSG_ENTITY, self.colormap);
340
341         if(sf & ISF_DROP)
342         {
343                 WriteCoord(MSG_ENTITY, self.velocity.x);
344                 WriteCoord(MSG_ENTITY, self.velocity.y);
345                 WriteCoord(MSG_ENTITY, self.velocity.z);
346         }
347
348         return true;
349 }
350
351 void ItemUpdate(entity this)
352 {
353         this.oldorigin = this.origin;
354         this.SendFlags |= ISF_LOCATION;
355 }
356
357 void UpdateItemAfterTeleport(entity this)
358 {
359         if(this.SendEntity3 == ItemSend)
360                 ItemUpdate(this);
361 }
362
363 bool have_pickup_item(entity this)
364 {
365         if(this.itemdef.instanceOfPowerup)
366         {
367                 if(autocvar_g_powerups > 0)
368                         return true;
369                 if(autocvar_g_powerups == 0)
370                         return false;
371         }
372         else
373         {
374                 if(autocvar_g_pickup_items > 0)
375                         return true;
376                 if(autocvar_g_pickup_items == 0)
377                         return false;
378                 if(g_weaponarena)
379                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
380                                 return false;
381         }
382         return true;
383 }
384
385 /*
386 float Item_Customize()
387 {
388         if(self.spawnshieldtime)
389                 return true;
390         if(self.weapons & ~other.weapons)
391         {
392                 self.colormod = '0 0 0';
393                 self.glowmod = self.colormod;
394                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
395                 return true;
396         }
397         else
398         {
399                 if(g_ghost_items)
400                 {
401                         self.colormod = stov(autocvar_g_ghost_items_color);
402                         self.glowmod = self.colormod;
403                         self.alpha = g_ghost_items;
404                         return true;
405                 }
406                 else
407                         return false;
408         }
409 }
410 */
411
412 void Item_Show (entity e, float mode)
413 {
414         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
415         e.ItemStatus &= ~ITS_STAYWEP;
416         if (mode > 0)
417         {
418                 // make the item look normal, and be touchable
419                 e.model = e.mdl;
420                 e.solid = SOLID_TRIGGER;
421                 e.spawnshieldtime = 1;
422                 e.ItemStatus |= ITS_AVAILABLE;
423         }
424         else if (mode < 0)
425         {
426                 // hide the item completely
427                 e.model = string_null;
428                 e.solid = SOLID_NOT;
429                 e.spawnshieldtime = 1;
430                 e.ItemStatus &= ~ITS_AVAILABLE;
431         }
432         else {
433         entity def = e.itemdef;
434         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
435                 || e.team // weapon stay isn't supported for teamed weapons
436                 ;
437         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
438         {
439                 // make the item translucent and not touchable
440                 e.model = e.mdl;
441                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
442                 e.effects |= EF_STARDUST;
443                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
444                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
445         }
446         else
447         {
448                 //setmodel(e, "null");
449                 e.solid = SOLID_NOT;
450                 e.colormod = '0 0 0';
451                 e.glowmod = e.colormod;
452                 e.spawnshieldtime = 1;
453                 e.ItemStatus &= ~ITS_AVAILABLE;
454         }}
455
456         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
457                 e.ItemStatus |= ITS_POWERUP;
458
459         if (autocvar_g_nodepthtestitems)
460                 e.effects |= EF_NODEPTHTEST;
461
462
463         if (autocvar_g_fullbrightitems)
464                 e.ItemStatus |= ITS_ALLOWFB;
465
466         if (autocvar_sv_simple_items)
467                 e.ItemStatus |= ITS_ALLOWSI;
468
469         // relink entity (because solid may have changed)
470         setorigin(e, e.origin);
471         e.SendFlags |= ISF_STATUS;
472 }
473
474 void Item_Think()
475 {SELFPARAM();
476         self.nextthink = time;
477         if(self.origin != self.oldorigin)
478                 ItemUpdate(self);
479 }
480
481 bool Item_ItemsTime_SpectatorOnly(GameItem it);
482 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
483 float Item_ItemsTime_UpdateTime(entity e, float t);
484 void Item_ItemsTime_SetTime(entity e, float t);
485 void Item_ItemsTime_SetTimesForAllPlayers();
486
487 void Item_Respawn ()
488 {SELFPARAM();
489         Item_Show(self, 1);
490         // this is ugly...
491         if(self.items == ITEM_Strength.m_itemid)
492                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
493         else if(self.items == ITEM_Shield.m_itemid)
494                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
495         else
496                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
497         setorigin (self, self.origin);
498
499     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
500         {
501                 float t = Item_ItemsTime_UpdateTime(self, 0);
502                 Item_ItemsTime_SetTime(self, t);
503                 Item_ItemsTime_SetTimesForAllPlayers();
504         }
505
506         self.think = Item_Think;
507         self.nextthink = time;
508
509         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
510         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
511 }
512
513 void Item_RespawnCountdown ()
514 {SELFPARAM();
515         if(self.count >= ITEM_RESPAWN_TICKS)
516         {
517                 if(self.waypointsprite_attached)
518                         WaypointSprite_Kill(self.waypointsprite_attached);
519                 Item_Respawn();
520         }
521         else
522         {
523                 self.nextthink = time + 1;
524                 self.count += 1;
525                 if(self.count == 1)
526                 {
527                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
528                         do {
529                                 {
530                                         entity wi = Weapons_from(self.weapon);
531                                         if (wi != WEP_Null) {
532                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
533                                                 wp.wp_extra = wi.m_id;
534                                                 break;
535                                         }
536                                 }
537                                 {
538                                         entity ii = self.itemdef;
539                                         if (ii != NULL) {
540                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
541                                                 wp.wp_extra = ii.m_id;
542                                                 break;
543                                         }
544                                 }
545                         } while (0);
546             if(self.waypointsprite_attached)
547             {
548                 GameItem def = self.itemdef;
549                 if (Item_ItemsTime_SpectatorOnly(def))
550                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
551                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
552             }
553                 }
554
555                 if(self.waypointsprite_attached)
556                 {
557                         setself(self.waypointsprite_attached);
558                         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
559                                 if(self.waypointsprite_visible_for_player(it))
560                                 {
561                                         msg_entity = it;
562                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
563                                 }
564                         ));
565                         setself(this);
566
567                         WaypointSprite_Ping(self.waypointsprite_attached);
568                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
569                 }
570         }
571 }
572
573 void Item_RespawnThink()
574 {SELFPARAM();
575         self.nextthink = time;
576         if(self.origin != self.oldorigin)
577                 ItemUpdate(self);
578
579         if(time >= self.wait)
580                 Item_Respawn();
581 }
582
583 void Item_ScheduleRespawnIn(entity e, float t)
584 {
585         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
586         {
587                 e.think = Item_RespawnCountdown;
588                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
589                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
590                 e.count = 0;
591                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
592                 Item_ItemsTime_SetTime(e, t);
593                 Item_ItemsTime_SetTimesForAllPlayers();
594         }
595         else
596         {
597                 e.think = Item_RespawnThink;
598                 e.nextthink = time;
599                 e.scheduledrespawntime = time + t;
600                 e.wait = time + t;
601         }
602 }
603
604 void Item_ScheduleRespawn(entity e)
605 {
606         if(e.respawntime > 0)
607         {
608                 Item_Show(e, 0);
609                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
610         }
611         else // if respawntime is -1, this item does not respawn
612                 Item_Show(e, -1);
613 }
614
615 void Item_ScheduleInitialRespawn(entity e)
616 {
617         Item_Show(e, 0);
618         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
619 }
620
621 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
622 {
623         if (!item.(ammotype))
624                 return false;
625
626         if (item.spawnshieldtime)
627         {
628                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
629                 {
630                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
631                         goto YEAH;
632                 }
633         }
634         else if(g_weapon_stay == 2)
635         {
636                 float mi = min(item.(ammotype), ammomax);
637                 if (player.(ammotype) < mi)
638                 {
639                         player.(ammotype) = mi;
640                         goto YEAH;
641                 }
642         }
643
644         return false;
645
646 :YEAH
647         switch(mode)
648         {
649                 case ITEM_MODE_FUEL:
650                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
651                         break;
652                 case ITEM_MODE_HEALTH:
653                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
654                         break;
655                 case ITEM_MODE_ARMOR:
656                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
657                         break;
658                 default:
659                         break;
660         }
661         return true;
662 }
663
664 float Item_GiveTo(entity item, entity player)
665 {
666         float _switchweapon;
667         float pickedup;
668
669         // if nothing happens to player, just return without taking the item
670         pickedup = false;
671         _switchweapon = false;
672         // in case the player has autoswitch enabled do the following:
673         // if the player is using their best weapon before items are given, they
674         // probably want to switch to an even better weapon after items are given
675         if (player.autoswitch)
676         if (PS(player).m_switchweapon == w_getbestweapon(player))
677                 _switchweapon = true;
678
679         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
680                 _switchweapon = true;
681
682         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
683         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
684         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
685         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
686         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
687         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
688         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
689         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
690
691         if (item.itemdef.instanceOfWeaponPickup)
692         {
693                 WepSet w;
694                 w = item.weapons;
695                 w &= ~player.weapons;
696
697                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
698                 {
699                         pickedup = true;
700                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
701                                 if(w & (it.m_wepset))
702                                 {
703                                         W_DropEvent(wr_pickup, player, it.m_id, item);
704                                         W_GiveWeapon(player, it.m_id);
705                                 }
706                         ));
707                 }
708         }
709
710         int its;
711         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
712         {
713                 pickedup = true;
714                 player.items |= its;
715                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
716         }
717
718         if (item.strength_finished)
719         {
720                 pickedup = true;
721                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
722         }
723         if (item.invincible_finished)
724         {
725                 pickedup = true;
726                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
727         }
728         if (item.superweapons_finished)
729         {
730                 pickedup = true;
731                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
732         }
733
734 :skip
735
736         // always eat teamed entities
737         if(item.team)
738                 pickedup = true;
739
740         if (!pickedup)
741                 return 0;
742
743         // crude hack to enforce switching weapons
744         if(g_cts && item.itemdef.instanceOfWeaponPickup)
745         {
746                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
747                 return 1;
748         }
749
750         if (_switchweapon)
751                 if (PS(player).m_switchweapon != w_getbestweapon(player))
752                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
753
754         return 1;
755 }
756
757 void Item_Touch()
758 {
759         SELFPARAM();
760
761         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
762         if (this.classname == "droppedweapon")
763         {
764                 if (ITEM_TOUCH_NEEDKILL())
765                 {
766                         remove(this);
767                         return;
768                 }
769         }
770
771         if(!(other.flags & FL_PICKUPITEMS)
772         || STAT(FROZEN, other)
773         || IS_DEAD(other)
774         || (this.solid != SOLID_TRIGGER)
775         || (this.owner == other)
776         || (time < this.item_spawnshieldtime)
777         ) { return; }
778
779         switch (MUTATOR_CALLHOOK(ItemTouch, this, other))
780         {
781                 case MUT_ITEMTOUCH_RETURN: { return; }
782                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
783         }
784
785         if (this.classname == "droppedweapon")
786         {
787                 this.strength_finished = max(0, this.strength_finished - time);
788                 this.invincible_finished = max(0, this.invincible_finished - time);
789                 this.superweapons_finished = max(0, this.superweapons_finished - time);
790         }
791         entity it = this.itemdef;
792         bool gave = ITEM_HANDLE(Pickup, it, this, other);
793         if (!gave)
794         {
795                 if (this.classname == "droppedweapon")
796                 {
797                         // undo what we did above
798                         this.strength_finished += time;
799                         this.invincible_finished += time;
800                         this.superweapons_finished += time;
801                 }
802                 return;
803         }
804
805         :pickup
806
807         other.last_pickup = time;
808
809         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
810         _sound (other, CH_TRIGGER, (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
811
812         if (this.classname == "droppedweapon")
813                 remove (this);
814         else if (this.spawnshieldtime)
815         {
816                 entity e;
817                 if(this.team)
818                 {
819                         RandomSelection_Init();
820                         for(entity head = world; (head = findfloat(head, team, this.team)); )
821                         {
822                                 if(head.flags & FL_ITEM)
823                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
824                                 {
825                                         Item_Show(head, -1);
826                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
827                                 }
828                         }
829                         e = RandomSelection_chosen_ent;
830
831                 }
832                 else
833                         e = this;
834                 Item_ScheduleRespawn(e);
835         }
836 }
837
838 void Item_Reset(entity this)
839 {
840         Item_Show(this, !this.state);
841         setorigin(this, this.origin);
842
843         if (this.classname != "droppedweapon")
844         {
845                 this.think = Item_Think;
846                 this.nextthink = time;
847
848                 if (this.waypointsprite_attached)
849                         WaypointSprite_Kill(this.waypointsprite_attached);
850
851                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
852                         Item_ScheduleInitialRespawn(this);
853         }
854 }
855 void Item_Reset_self() { SELFPARAM(); Item_Reset(this); }
856
857 void Item_FindTeam()
858 {SELFPARAM();
859         entity head, e;
860
861         if(self.effects & EF_NODRAW)
862         {
863                 // marker for item team search
864                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
865                 RandomSelection_Init();
866                 for(head = world; (head = findfloat(head, team, self.team)); )
867                 if(head.flags & FL_ITEM)
868                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
869                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
870                 e = RandomSelection_chosen_ent;
871                 e.state = 0;
872                 Item_Show(e, 1);
873
874                 for(head = world; (head = findfloat(head, team, self.team)); )
875                 if(head.flags & FL_ITEM)
876                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
877                 {
878                         if(head != e)
879                         {
880                                 // make it a non-spawned item
881                                 Item_Show(head, -1);
882                                 head.state = 1; // state 1 = initially hidden item
883                         }
884                         head.effects &= ~EF_NODRAW;
885                 }
886
887                 Item_Reset(self);
888         }
889 }
890
891 // Savage: used for item garbage-collection
892 // TODO: perhaps nice special effect?
893 void RemoveItem()
894 {SELFPARAM();
895         if(wasfreed(self) || !self) { return; }
896         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
897         remove(self);
898 }
899
900 // pickup evaluation functions
901 // these functions decide how desirable an item is to the bots
902
903 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
904
905 float weapon_pickupevalfunc(entity player, entity item)
906 {
907         float c;
908
909         // See if I have it already
910         if(item.weapons & ~player.weapons)
911         {
912                 // If I can pick it up
913                 if(!item.spawnshieldtime)
914                         c = 0;
915                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
916                 {
917                         // Skilled bots will grab more
918                         c = bound(0, skill / 10, 1) * 0.5;
919                 }
920                 else
921                         c = 0;
922         }
923         else
924                 c = 1;
925
926         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
927         if( bot_custom_weapon && c )
928         {
929                 // Find the highest position on any range
930                 int position = -1;
931                 for (int j = 0; j < WEP_LAST ; ++j){
932                         if(
933                                         bot_weapons_far[j] == item.weapon ||
934                                         bot_weapons_mid[j] == item.weapon ||
935                                         bot_weapons_close[j] == item.weapon
936                           )
937                         {
938                                 position = j;
939                                 break;
940                         }
941                 }
942
943                 // Rate it
944                 if (position >= 0 )
945                 {
946                         position = WEP_LAST - position;
947                         // item.bot_pickupbasevalue is overwritten here
948                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
949                 }
950         }
951
952         return item.bot_pickupbasevalue * c;
953 }
954
955 float commodity_pickupevalfunc(entity player, entity item)
956 {
957         float c;
958         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
959         c = 0;
960
961         // Detect needed ammo
962         FOREACH(Weapons, it != WEP_Null, LAMBDA(
963                 if(!(player.weapons & (it.m_wepset)))
964                         continue;
965
966                 if(it.items & ITEM_Shells.m_itemid)
967                         need_shells = true;
968                 else if(it.items & ITEM_Bullets.m_itemid)
969                         need_nails = true;
970                 else if(it.items & ITEM_Rockets.m_itemid)
971                         need_rockets = true;
972                 else if(it.items & ITEM_Cells.m_itemid)
973                         need_cells = true;
974                 else if(it.items & ITEM_Plasma.m_itemid)
975                         need_plasma = true;
976                 else if(it.items & ITEM_JetpackFuel.m_itemid)
977                         need_fuel = true;
978         ));
979
980         // TODO: figure out if the player even has the weapon this ammo is for?
981         // may not affect strategy much though...
982         // find out how much more ammo/armor/health the player can hold
983         if (need_shells)
984         if (item.ammo_shells)
985         if (player.ammo_shells < g_pickup_shells_max)
986                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
987         if (need_nails)
988         if (item.ammo_nails)
989         if (player.ammo_nails < g_pickup_nails_max)
990                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
991         if (need_rockets)
992         if (item.ammo_rockets)
993         if (player.ammo_rockets < g_pickup_rockets_max)
994                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
995         if (need_cells)
996         if (item.ammo_cells)
997         if (player.ammo_cells < g_pickup_cells_max)
998                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
999         if (need_plasma)
1000         if (item.ammo_plasma)
1001         if (player.ammo_plasma < g_pickup_plasma_max)
1002                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1003         if (need_fuel)
1004         if (item.ammo_fuel)
1005         if (player.ammo_fuel < g_pickup_fuel_max)
1006                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1007         if (item.armorvalue)
1008         if (player.armorvalue < item.max_armorvalue)
1009                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1010         if (item.health)
1011         if (player.health < item.max_health)
1012                 c = c + max(0, 1 - player.health / item.max_health);
1013
1014         return item.bot_pickupbasevalue * c;
1015 }
1016
1017 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1018 {
1019         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1020                 WITH(entity, self, this, RemoveItem());
1021 }
1022
1023 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1024 {
1025         string itemname = def.m_name;
1026         Model itemmodel = def.m_model;
1027     Sound pickupsound = def.m_sound;
1028         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1029         float pickupbasevalue = def.m_botvalue;
1030         int itemflags = def.m_itemflags;
1031
1032         startitem_failed = false;
1033
1034         this.item_model_ent = itemmodel;
1035     this.item_pickupsound_ent = pickupsound;
1036
1037         if(!this.respawntime) // both need to be set
1038         {
1039                 this.respawntime = defaultrespawntime;
1040                 this.respawntimejitter = defaultrespawntimejitter;
1041         }
1042
1043         int itemid = def.m_itemid;
1044         this.items = itemid;
1045         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1046         this.weapon = weaponid;
1047
1048         if(!this.fade_end)
1049         {
1050                 this.fade_start = autocvar_g_items_mindist;
1051                 this.fade_end = autocvar_g_items_maxdist;
1052         }
1053
1054         if(weaponid)
1055                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1056
1057         this.flags = FL_ITEM | itemflags;
1058
1059         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1060         {
1061                 startitem_failed = true;
1062                 remove(this);
1063                 return;
1064         }
1065
1066         // is it a dropped weapon?
1067         if (this.classname == "droppedweapon")
1068         {
1069                 this.reset = SUB_Remove;
1070                 // it's a dropped weapon
1071                 this.movetype = MOVETYPE_TOSS;
1072
1073                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1074                 this.think = RemoveItem;
1075                 this.nextthink = time + 20;
1076
1077                 this.takedamage = DAMAGE_YES;
1078                 this.event_damage = Item_Damage;
1079
1080                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1081                 {
1082                         // if item is worthless after a timer, have it expire then
1083                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1084                 }
1085
1086                 // don't drop if in a NODROP zone (such as lava)
1087                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1088                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1089                 {
1090                         startitem_failed = true;
1091                         remove(this);
1092                         return;
1093                 }
1094         }
1095         else
1096         {
1097                 if(!have_pickup_item(this))
1098                 {
1099                         startitem_failed = true;
1100                         remove (this);
1101                         return;
1102                 }
1103
1104                 if(this.angles != '0 0 0')
1105                         this.SendFlags |= ISF_ANGLES;
1106
1107                 this.reset = Item_Reset;
1108                 // it's a level item
1109                 if(this.spawnflags & 1)
1110                         this.noalign = 1;
1111                 if (this.noalign > 0)
1112                         this.movetype = MOVETYPE_NONE;
1113                 else
1114                         this.movetype = MOVETYPE_TOSS;
1115                 // do item filtering according to game mode and other things
1116                 if (this.noalign <= 0)
1117                 {
1118                         // first nudge it off the floor a little bit to avoid math errors
1119                         setorigin(this, this.origin + '0 0 1');
1120                         // set item size before we spawn a spawnfunc_waypoint
1121                         setsize(this, def.m_mins, def.m_maxs);
1122                         this.SendFlags |= ISF_SIZE;
1123                         // note droptofloor returns false if stuck/or would fall too far
1124                         if (!this.noalign)
1125                                 WITH(entity, self, this, droptofloor());
1126                         waypoint_spawnforitem(this);
1127                 }
1128
1129                 /*
1130                  * can't do it that way, as it would break maps
1131                  * TODO make a target_give like entity another way, that perhaps has
1132                  * the weapon name in a key
1133                 if(this.targetname)
1134                 {
1135                         // target_give not yet supported; maybe later
1136                         print("removed targeted ", this.classname, "\n");
1137                         startitem_failed = true;
1138                         remove (this);
1139                         return;
1140                 }
1141                 */
1142
1143                 if(autocvar_spawn_debug >= 2)
1144                 {
1145                         for(entity otheritem = findradius(this.origin, 3); otheritem; otheritem = otheritem.chain)
1146                         {
1147                             // why not flags & fl_item?
1148                                 if(otheritem.is_item)
1149                                 {
1150                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1151                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1152                                         error("Mapper sucks.");
1153                                 }
1154                         }
1155                         this.is_item = true;
1156                 }
1157
1158                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1159
1160                 precache_model(this.model);
1161                 precache_sound(this.item_pickupsound);
1162
1163                 if (   def.instanceOfPowerup
1164                         || def.instanceOfWeaponPickup
1165                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1166                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1167                         || (itemid & (IT_KEY1 | IT_KEY2))
1168                 ) this.target = "###item###"; // for finding the nearest item using find()
1169
1170                 Item_ItemsTime_SetTime(this, 0);
1171         }
1172
1173         this.bot_pickup = true;
1174         this.bot_pickupevalfunc = pickupevalfunc;
1175         this.bot_pickupbasevalue = pickupbasevalue;
1176         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1177         this.netname = itemname;
1178         this.touch = Item_Touch;
1179         setmodel(this, MDL_Null); // precision set below
1180         //this.effects |= EF_LOWPRECISION;
1181
1182         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1183
1184         this.SendFlags |= ISF_SIZE;
1185
1186         if (!(this.spawnflags & 1024)) {
1187                 if(def.instanceOfPowerup)
1188                         this.ItemStatus |= ITS_ANIMATE1;
1189
1190                 if(this.armorvalue || this.health)
1191                         this.ItemStatus |= ITS_ANIMATE2;
1192         }
1193
1194         if(def.instanceOfWeaponPickup)
1195         {
1196                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1197                         this.colormap = 1024; // color shirt=0 pants=0 grey
1198                 else
1199                         this.gravity = 1;
1200                 if (!(this.spawnflags & 1024))
1201                         this.ItemStatus |= ITS_ANIMATE1;
1202                 this.ItemStatus |= ISF_COLORMAP;
1203         }
1204
1205         this.state = 0;
1206         if(this.team) // broken, no idea why.
1207         {
1208                 if(!this.cnt)
1209                         this.cnt = 1; // item probability weight
1210
1211                 this.effects |= EF_NODRAW; // marker for item team search
1212                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1213         }
1214         else
1215                 Item_Reset(this);
1216
1217         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1218
1219         // call this hook after everything else has been done
1220         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1221         {
1222                 startitem_failed = true;
1223                 remove(this);
1224                 return;
1225         }
1226 }
1227
1228 void StartItem(entity this, GameItem def)
1229 {
1230     _StartItem(
1231         this,
1232         this.itemdef = def,
1233         def.m_respawntime(), // defaultrespawntime
1234         def.m_respawntimejitter() // defaultrespawntimejitter
1235         );
1236 }
1237
1238 spawnfunc(item_rockets)
1239 {
1240         if(!this.ammo_rockets)
1241                 this.ammo_rockets = g_pickup_rockets;
1242         if(!this.pickup_anyway)
1243                 this.pickup_anyway = g_pickup_ammo_anyway;
1244     StartItem(this, ITEM_Rockets);
1245 }
1246
1247 spawnfunc(item_bullets)
1248 {
1249         if(!weaponswapping)
1250         if(autocvar_sv_q3acompat_machineshotgunswap)
1251         if(this.classname != "droppedweapon")
1252         {
1253                 weaponswapping = true;
1254                 spawnfunc_item_shells(this);
1255                 weaponswapping = false;
1256                 return;
1257         }
1258
1259         if(!this.ammo_nails)
1260                 this.ammo_nails = g_pickup_nails;
1261         if(!this.pickup_anyway)
1262                 this.pickup_anyway = g_pickup_ammo_anyway;
1263     StartItem(this, ITEM_Bullets);
1264 }
1265
1266 spawnfunc(item_cells)
1267 {
1268         if(!this.ammo_cells)
1269                 this.ammo_cells = g_pickup_cells;
1270         if(!this.pickup_anyway)
1271                 this.pickup_anyway = g_pickup_ammo_anyway;
1272         StartItem(this, ITEM_Cells);
1273 }
1274
1275 spawnfunc(item_plasma)
1276 {
1277         if(!this.ammo_plasma)
1278                 this.ammo_plasma = g_pickup_plasma;
1279         if(!this.pickup_anyway)
1280                 this.pickup_anyway = g_pickup_ammo_anyway;
1281         StartItem(this, ITEM_Plasma);
1282 }
1283
1284 spawnfunc(item_shells)
1285 {
1286         if(!weaponswapping)
1287         if(autocvar_sv_q3acompat_machineshotgunswap)
1288         if(this.classname != "droppedweapon")
1289         {
1290                 weaponswapping = true;
1291                 spawnfunc_item_bullets(this);
1292                 weaponswapping = false;
1293                 return;
1294         }
1295
1296         if(!this.ammo_shells)
1297                 this.ammo_shells = g_pickup_shells;
1298         if(!this.pickup_anyway)
1299                 this.pickup_anyway = g_pickup_ammo_anyway;
1300         StartItem(this, ITEM_Shells);
1301 }
1302
1303 spawnfunc(item_armor_small)
1304 {
1305         if(!this.armorvalue)
1306                 this.armorvalue = g_pickup_armorsmall;
1307         if(!this.max_armorvalue)
1308                 this.max_armorvalue = g_pickup_armorsmall_max;
1309         if(!this.pickup_anyway)
1310                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1311         StartItem(this, ITEM_ArmorSmall);
1312 }
1313
1314 spawnfunc(item_armor_medium)
1315 {
1316         if(!this.armorvalue)
1317                 this.armorvalue = g_pickup_armormedium;
1318         if(!this.max_armorvalue)
1319                 this.max_armorvalue = g_pickup_armormedium_max;
1320         if(!this.pickup_anyway)
1321                 this.pickup_anyway = g_pickup_armormedium_anyway;
1322         StartItem(this, ITEM_ArmorMedium);
1323 }
1324
1325 spawnfunc(item_armor_big)
1326 {
1327         if(!this.armorvalue)
1328                 this.armorvalue = g_pickup_armorbig;
1329         if(!this.max_armorvalue)
1330                 this.max_armorvalue = g_pickup_armorbig_max;
1331         if(!this.pickup_anyway)
1332                 this.pickup_anyway = g_pickup_armorbig_anyway;
1333         StartItem(this, ITEM_ArmorLarge);
1334 }
1335
1336 spawnfunc(item_armor_large)
1337 {
1338         if(!this.armorvalue)
1339                 this.armorvalue = g_pickup_armorlarge;
1340         if(!this.max_armorvalue)
1341                 this.max_armorvalue = g_pickup_armorlarge_max;
1342         if(!this.pickup_anyway)
1343                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1344         StartItem(this, ITEM_ArmorMega);
1345 }
1346
1347 spawnfunc(item_health_small)
1348 {
1349         if(!this.max_health)
1350                 this.max_health = g_pickup_healthsmall_max;
1351         if(!this.health)
1352                 this.health = g_pickup_healthsmall;
1353         if(!this.pickup_anyway)
1354                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1355         StartItem(this, ITEM_HealthSmall);
1356 }
1357
1358 spawnfunc(item_health_medium)
1359 {
1360         if(!this.max_health)
1361                 this.max_health = g_pickup_healthmedium_max;
1362         if(!this.health)
1363                 this.health = g_pickup_healthmedium;
1364         if(!this.pickup_anyway)
1365                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1366     StartItem(this, ITEM_HealthMedium);
1367 }
1368
1369 spawnfunc(item_health_large)
1370 {
1371         if(!this.max_health)
1372                 this.max_health = g_pickup_healthlarge_max;
1373         if(!this.health)
1374                 this.health = g_pickup_healthlarge;
1375         if(!this.pickup_anyway)
1376                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1377         StartItem(this, ITEM_HealthLarge);
1378 }
1379
1380 spawnfunc(item_health_mega)
1381 {
1382     if(!this.max_health)
1383         this.max_health = g_pickup_healthmega_max;
1384     if(!this.health)
1385         this.health = g_pickup_healthmega;
1386     if(!this.pickup_anyway)
1387         this.pickup_anyway = g_pickup_healthmega_anyway;
1388     StartItem(this, ITEM_HealthMega);
1389 }
1390
1391 // support old misnamed entities
1392 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1393 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1394 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1395 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1396 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1397
1398 spawnfunc(item_strength)
1399 {
1400                 if(!this.strength_finished)
1401                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1402                 StartItem(this, ITEM_Strength);
1403 }
1404
1405 spawnfunc(item_invincible)
1406 {
1407                 if(!this.invincible_finished)
1408                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1409                 StartItem(this, ITEM_Shield);
1410 }
1411
1412 // compatibility:
1413 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1414
1415 void target_items_use()
1416 {SELFPARAM();
1417         if(activator.classname == "droppedweapon")
1418         {
1419                 EXACTTRIGGER_TOUCH;
1420                 remove(activator);
1421                 return;
1422         }
1423
1424         if (!IS_PLAYER(activator))
1425                 return;
1426         if(IS_DEAD(activator))
1427                 return;
1428         EXACTTRIGGER_TOUCH;
1429
1430         FOREACH_ENTITY_ENT(enemy, activator,
1431         {
1432                 if(it.classname == "droppedweapon")
1433                         remove(it);
1434         });
1435
1436         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1437                 centerprint(activator, self.message);
1438 }
1439
1440 spawnfunc(target_items)
1441 {
1442         float n, i;
1443         string s;
1444
1445         self.use = target_items_use;
1446         if(!self.strength_finished)
1447                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1448         if(!self.invincible_finished)
1449                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1450         if(!self.superweapons_finished)
1451                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1452
1453         n = tokenize_console(self.netname);
1454         if(argv(0) == "give")
1455         {
1456                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1457         }
1458         else
1459         {
1460                 for(i = 0; i < n; ++i)
1461                 {
1462                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1463                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1464                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1465                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1466                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1467                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1468                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1469                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1470                         else
1471                         {
1472                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1473                                         s = W_UndeprecateName(argv(i));
1474                                         if(s == it.netname)
1475                                         {
1476                                                 self.weapons |= (it.m_wepset);
1477                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1478                                                         it.wr_init(it);
1479                                                 break;
1480                                         }
1481                                 ));
1482                         }
1483                 }
1484
1485                 string itemprefix, valueprefix;
1486                 if(self.spawnflags == 0)
1487                 {
1488                         itemprefix = "";
1489                         valueprefix = "";
1490                 }
1491                 else if(self.spawnflags == 1)
1492                 {
1493                         itemprefix = "max ";
1494                         valueprefix = "max ";
1495                 }
1496                 else if(self.spawnflags == 2)
1497                 {
1498                         itemprefix = "min ";
1499                         valueprefix = "min ";
1500                 }
1501                 else if(self.spawnflags == 4)
1502                 {
1503                         itemprefix = "minus ";
1504                         valueprefix = "max ";
1505                 }
1506                 else
1507                 {
1508                         error("invalid spawnflags");
1509                         itemprefix = valueprefix = string_null;
1510                 }
1511
1512                 self.netname = "";
1513                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1514                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1515                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * boolean(self.items & ITEM_Strength.m_itemid), "strength");
1516                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * boolean(self.items & ITEM_Shield.m_itemid), "invincible");
1517                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * boolean(self.items & IT_SUPERWEAPON), "superweapons");
1518                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1519                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1520                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1521                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1522                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1523                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1524                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1525                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1526                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1527                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1528                 FOREACH(Weapons, it != WEP_Null, LAMBDA(self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & (it.m_wepset)), it.netname)));
1529         }
1530         self.netname = strzone(self.netname);
1531         //print(self.netname, "\n");
1532
1533         n = tokenize_console(self.netname);
1534         for(i = 0; i < n; ++i)
1535         {
1536                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1537                         if(argv(i) == it.netname)
1538                         {
1539                                 it.wr_init(it);
1540                                 break;
1541                         }
1542                 ));
1543         }
1544 }
1545
1546 spawnfunc(item_fuel)
1547 {
1548         if(!this.ammo_fuel)
1549                 this.ammo_fuel = g_pickup_fuel;
1550         if(!this.pickup_anyway)
1551                 this.pickup_anyway = g_pickup_ammo_anyway;
1552         StartItem(this, ITEM_JetpackFuel);
1553 }
1554
1555 spawnfunc(item_fuel_regen)
1556 {
1557         if(start_items & ITEM_JetpackRegen.m_itemid)
1558         {
1559                 spawnfunc_item_fuel(this);
1560                 return;
1561         }
1562         StartItem(this, ITEM_JetpackRegen);
1563 }
1564
1565 spawnfunc(item_jetpack)
1566 {
1567         if(!this.ammo_fuel)
1568                 this.ammo_fuel = g_pickup_fuel_jetpack;
1569         if(start_items & ITEM_Jetpack.m_itemid)
1570         {
1571                 spawnfunc_item_fuel(this);
1572                 return;
1573         }
1574         StartItem(this, ITEM_Jetpack);
1575 }
1576
1577 float GiveWeapon(entity e, float wpn, float op, float val)
1578 {
1579         WepSet v0, v1;
1580         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1581         v0 = (e.weapons & s);
1582         switch(op)
1583         {
1584                 case OP_SET:
1585                         if(val > 0)
1586                                 e.weapons |= s;
1587                         else
1588                                 e.weapons &= ~s;
1589                         break;
1590                 case OP_MIN:
1591                 case OP_PLUS:
1592                         if(val > 0)
1593                                 e.weapons |= s;
1594                         break;
1595                 case OP_MAX:
1596                         if(val <= 0)
1597                                 e.weapons &= ~s;
1598                         break;
1599                 case OP_MINUS:
1600                         if(val > 0)
1601                                 e.weapons &= ~s;
1602                         break;
1603         }
1604         v1 = (e.weapons & s);
1605         return (v0 != v1);
1606 }
1607
1608 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1609 {
1610         if(v1 == v0)
1611                 return;
1612         if(v1 <= v0 - t)
1613         {
1614                 if(snd_decr != "")
1615                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1616         }
1617         else if(v0 >= v0 + t)
1618         {
1619                 if(snd_incr != "")
1620                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1621         }
1622 }
1623
1624 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1625 {
1626         if(v0 < v1)
1627                 e.(rotfield) = max(e.(rotfield), time + rottime);
1628         else if(v0 > v1)
1629                 e.(regenfield) = max(e.(regenfield), time + regentime);
1630 }
1631 float GiveItems(entity e, float beginarg, float endarg)
1632 {SELFPARAM();
1633         float got, i, val, op;
1634         float _switchweapon;
1635         string cmd;
1636
1637         val = 999;
1638         op = OP_SET;
1639
1640         got = 0;
1641
1642         _switchweapon = false;
1643         if (e.autoswitch)
1644                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1645                         _switchweapon = true;
1646
1647         e.strength_finished = max(0, e.strength_finished - time);
1648         e.invincible_finished = max(0, e.invincible_finished - time);
1649         e.superweapons_finished = max(0, e.superweapons_finished - time);
1650
1651         PREGIVE(e, items);
1652         PREGIVE_WEAPONS(e);
1653         PREGIVE(e, strength_finished);
1654         PREGIVE(e, invincible_finished);
1655         PREGIVE(e, superweapons_finished);
1656         PREGIVE(e, ammo_nails);
1657         PREGIVE(e, ammo_cells);
1658         PREGIVE(e, ammo_plasma);
1659         PREGIVE(e, ammo_shells);
1660         PREGIVE(e, ammo_rockets);
1661         PREGIVE(e, ammo_fuel);
1662         PREGIVE(e, armorvalue);
1663         PREGIVE(e, health);
1664
1665         for(i = beginarg; i < endarg; ++i)
1666         {
1667                 cmd = argv(i);
1668
1669                 if(cmd == "0" || stof(cmd))
1670                 {
1671                         val = stof(cmd);
1672                         continue;
1673                 }
1674                 switch(cmd)
1675                 {
1676                         case "no":
1677                                 op = OP_MAX;
1678                                 val = 0;
1679                                 continue;
1680                         case "max":
1681                                 op = OP_MAX;
1682                                 continue;
1683                         case "min":
1684                                 op = OP_MIN;
1685                                 continue;
1686                         case "plus":
1687                                 op = OP_PLUS;
1688                                 continue;
1689                         case "minus":
1690                                 op = OP_MINUS;
1691                                 continue;
1692                         case "ALL":
1693                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1694                                 got += GiveValue(e, strength_finished, op, val);
1695                                 got += GiveValue(e, invincible_finished, op, val);
1696                                 got += GiveValue(e, superweapons_finished, op, val);
1697                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1698                         case "all":
1699                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1700                                 got += GiveValue(e, health, op, val);
1701                                 got += GiveValue(e, armorvalue, op, val);
1702                         case "allweapons":
1703                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1704                                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1705                                                 got += GiveWeapon(e, it.m_id, op, val);
1706                                 ));
1707                         case "allammo":
1708                                 got += GiveValue(e, ammo_cells, op, val);
1709                                 got += GiveValue(e, ammo_plasma, op, val);
1710                                 got += GiveValue(e, ammo_shells, op, val);
1711                                 got += GiveValue(e, ammo_nails, op, val);
1712                                 got += GiveValue(e, ammo_rockets, op, val);
1713                                 got += GiveValue(e, ammo_fuel, op, val);
1714                                 break;
1715                         case "unlimited_ammo":
1716                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1717                                 break;
1718                         case "unlimited_weapon_ammo":
1719                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1720                                 break;
1721                         case "unlimited_superweapons":
1722                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1723                                 break;
1724                         case "jetpack":
1725                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1726                                 break;
1727                         case "fuel_regen":
1728                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1729                                 break;
1730                         case "strength":
1731                                 got += GiveValue(e, strength_finished, op, val);
1732                                 break;
1733                         case "invincible":
1734                                 got += GiveValue(e, invincible_finished, op, val);
1735                                 break;
1736                         case "superweapons":
1737                                 got += GiveValue(e, superweapons_finished, op, val);
1738                                 break;
1739                         case "cells":
1740                                 got += GiveValue(e, ammo_cells, op, val);
1741                                 break;
1742                         case "plasma":
1743                                 got += GiveValue(e, ammo_plasma, op, val);
1744                                 break;
1745                         case "shells":
1746                                 got += GiveValue(e, ammo_shells, op, val);
1747                                 break;
1748                         case "nails":
1749                         case "bullets":
1750                                 got += GiveValue(e, ammo_nails, op, val);
1751                                 break;
1752                         case "rockets":
1753                                 got += GiveValue(e, ammo_rockets, op, val);
1754                                 break;
1755                         case "health":
1756                                 got += GiveValue(e, health, op, val);
1757                                 break;
1758                         case "armor":
1759                                 got += GiveValue(e, armorvalue, op, val);
1760                                 break;
1761                         case "fuel":
1762                                 got += GiveValue(e, ammo_fuel, op, val);
1763                                 break;
1764                         default:
1765                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1766                                         if(cmd == it.netname)
1767                                         {
1768                                                 got += GiveWeapon(e, it.m_id, op, val);
1769                                                 break;
1770                                         }
1771                                 ));
1772                                 break;
1773                 }
1774                 val = 999;
1775                 op = OP_SET;
1776         }
1777
1778         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1779         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1780         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1781         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1782         FOREACH(Weapons, it != WEP_Null, LAMBDA(
1783                 POSTGIVE_WEAPON(e, it, SND(WEAPONPICKUP), string_null);
1784                 if(!(save_weapons & (it.m_wepset)))
1785                         if(e.weapons & (it.m_wepset))
1786                                 it.wr_init(it);
1787         ));
1788         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1789         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1790         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1791         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1792         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1793         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1794         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1795         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1796         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1797         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1798
1799         if(e.superweapons_finished <= 0)
1800                 if(self.weapons & WEPSET_SUPERWEAPONS)
1801                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1802
1803         if(e.strength_finished <= 0)
1804                 e.strength_finished = 0;
1805         else
1806                 e.strength_finished += time;
1807         if(e.invincible_finished <= 0)
1808                 e.invincible_finished = 0;
1809         else
1810                 e.invincible_finished += time;
1811         if(e.superweapons_finished <= 0)
1812                 e.superweapons_finished = 0;
1813         else
1814                 e.superweapons_finished += time;
1815
1816         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1817                 _switchweapon = true;
1818         if(_switchweapon)
1819                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1820
1821         return got;
1822 }
1823 #endif