qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 if(!this.item_simple)
  96                 this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103                 if(!this.item_simple)
 104                 this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void Item_PreDraw(entity this)
 114 {
 115         if(warpzone_warpzones_exist)
 116         {
 117                 setpredraw(this, func_null); // no need to keep running this
 118                 return;
 119         }
 120         float alph;
 121         vector org = getpropertyvec(VF_ORIGIN);
 122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 124         if(this.fade_start)
 125         {
 126                 if(vdist(org - this.origin, >, this.fade_end))
 127                         alph = 0; // save on some processing
 128                 else if(vdist(org - this.origin, <, this.fade_start))
 129                         alph = 1; // more processing saved
 130                 else
 131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         }
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         //else
 141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         strfree(this.mdl);
 147 }
 148
 149 HashMap ENT_CLIENT_ITEM_simple;
 150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 151 {
 152         HM_NEW(ENT_CLIENT_ITEM_simple);
 153 }
 154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 155 {
 156         HM_DELETE(ENT_CLIENT_ITEM_simple);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin = ReadVector();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218                 strfree(this.mdl);
 219
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228                         #define extensions(x) \
 229                                 x(md3) \
 230                                 x(dpm) \
 231                                 x(iqm) \
 232                                 x(mdl) \
 233                                 /**/
 234                         #define tryext(ext) { \
 235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 237                                 if (cached == "") { \
 238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 239                                 } \
 240                                 if (cached != "0") { \
 241                                         strcpy(this.mdl, s); \
 242                                         break; \
 243                                 } \
 244                         }
 245                         do {
 246                                 extensions(tryext);
 247                                 this.item_simple = false;
 248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 249                         } while (0);
 250                         #undef tryext
 251                         #undef extensions
 252         }
 253
 254         if(!this.item_simple)
 255             strcpy(this.mdl, _fn);
 256
 257         if(this.mdl == "")
 258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 259
 260         precache_model(this.mdl);
 261         _setmodel(this, this.mdl);
 262
 263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 264     }
 265
 266     if(sf & ISF_COLORMAP)
 267     {
 268         this.colormap = ReadShort();
 269         this.item_glowmod_x = ReadByte() / 255.0;
 270         this.item_glowmod_y = ReadByte() / 255.0;
 271         this.item_glowmod_z = ReadByte() / 255.0;
 272     }
 273
 274     if(sf & ISF_DROP)
 275     {
 276         this.gravity = 1;
 277         this.pushable = true;
 278         //this.angles = '0 0 0';
 279         set_movetype(this, MOVETYPE_TOSS);
 280         this.velocity = ReadVector();
 281         setorigin(this, this.oldorigin);
 282
 283         if(!this.move_time)
 284         {
 285             this.move_time = time;
 286             this.spawntime = time;
 287         }
 288         else
 289             this.move_time = max(this.move_time, time);
 290     }
 291
 292     if(autocvar_cl_animate_items)
 293     {
 294         if(this.ItemStatus & ITS_ANIMATE1)
 295             this.avelocity = '0 180 0';
 296
 297         if(this.ItemStatus & ITS_ANIMATE2)
 298             this.avelocity = '0 -90 0';
 299     }
 300
 301     this.entremove = ItemRemove;
 302
 303     return true;
 304 }
 305
 306 #endif
 307
 308 #ifdef SVQC
 309 bool ItemSend(entity this, entity to, int sf)
 310 {
 311         if(this.gravity)
 312                 sf |= ISF_DROP;
 313         else
 314                 sf &= ~ISF_DROP;
 315
 316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 317         WriteByte(MSG_ENTITY, sf);
 318
 319         //WriteByte(MSG_ENTITY, this.cnt);
 320         if(sf & ISF_LOCATION)
 321         {
 322                 WriteVector(MSG_ENTITY, this.origin);
 323         }
 324
 325         if(sf & ISF_ANGLES)
 326         {
 327                 WriteAngle(MSG_ENTITY, this.angles_x);
 328                 WriteAngle(MSG_ENTITY, this.angles_y);
 329                 WriteAngle(MSG_ENTITY, this.angles_z);
 330         }
 331
 332         if(sf & ISF_SIZE)
 333         {
 334                 Pickup p = this.itemdef;
 335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 336         }
 337
 338         if(sf & ISF_STATUS)
 339                 WriteByte(MSG_ENTITY, this.ItemStatus);
 340
 341         if(sf & ISF_MODEL)
 342         {
 343                 Pickup p = this.itemdef;
 344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 345                 WriteShort(MSG_ENTITY, this.fade_end);
 346                 WriteShort(MSG_ENTITY, this.fade_start);
 347
 348                 if(this.mdl == "")
 349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 350
 351                 WriteString(MSG_ENTITY, this.mdl);
 352         }
 353
 354
 355         if(sf & ISF_COLORMAP)
 356         {
 357                 WriteShort(MSG_ENTITY, this.colormap);
 358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 361         }
 362
 363         if(sf & ISF_DROP)
 364         {
 365                 WriteVector(MSG_ENTITY, this.velocity);
 366         }
 367
 368         return true;
 369 }
 370
 371 void ItemUpdate(entity this)
 372 {
 373         this.oldorigin = this.origin;
 374         this.SendFlags |= ISF_LOCATION;
 375 }
 376
 377 void UpdateItemAfterTeleport(entity this)
 378 {
 379         if(getSendEntity(this) == ItemSend)
 380                 ItemUpdate(this);
 381 }
 382
 383 bool have_pickup_item(entity this)
 384 {
 385         if(this.itemdef.instanceOfPowerup)
 386         {
 387                 if(autocvar_g_powerups > 0)
 388                         return true;
 389                 if(autocvar_g_powerups == 0)
 390                         return false;
 391         }
 392         else
 393         {
 394                 if(autocvar_g_pickup_items > 0)
 395                         return true;
 396                 if(autocvar_g_pickup_items == 0)
 397                         return false;
 398                 if(g_weaponarena)
 399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 400                                 return false;
 401         }
 402         return true;
 403 }
 404
 405 void Item_Show (entity e, int mode)
 406 {
 407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 408         e.ItemStatus &= ~ITS_STAYWEP;
 409         entity def = e.itemdef;
 410         if (mode > 0)
 411         {
 412                 // make the item look normal, and be touchable
 413                 e.model = e.mdl;
 414                 e.solid = SOLID_TRIGGER;
 415                 e.spawnshieldtime = 1;
 416                 e.ItemStatus |= ITS_AVAILABLE;
 417         }
 418         else if (mode < 0)
 419         {
 420                 // hide the item completely
 421                 e.model = string_null;
 422                 e.solid = SOLID_NOT;
 423                 e.spawnshieldtime = 1;
 424                 e.ItemStatus &= ~ITS_AVAILABLE;
 425         }
 426         else
 427         {
 428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 429                         || e.team // weapon stay isn't supported for teamed weapons
 430                         ;
 431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 432                 {
 433                         // make the item translucent and not touchable
 434                         e.model = e.mdl;
 435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 436                         e.effects |= EF_STARDUST;
 437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 439                 }
 440                 else
 441                 {
 442                         //setmodel(e, "null");
 443                         e.solid = SOLID_NOT;
 444                         e.colormod = '0 0 0';
 445                         //e.glowmod = e.colormod;
 446                         e.spawnshieldtime = 1;
 447                         e.ItemStatus &= ~ITS_AVAILABLE;
 448                 }
 449         }
 450
 451         if (def.m_glow)
 452                 e.ItemStatus |= ITS_GLOW;
 453
 454         if (autocvar_g_nodepthtestitems)
 455                 e.effects |= EF_NODEPTHTEST;
 456
 457
 458         if (autocvar_g_fullbrightitems)
 459                 e.ItemStatus |= ITS_ALLOWFB;
 460
 461         if (autocvar_sv_simple_items)
 462                 e.ItemStatus |= ITS_ALLOWSI;
 463
 464         // relink entity (because solid may have changed)
 465         setorigin(e, e.origin);
 466         e.SendFlags |= ISF_STATUS;
 467 }
 468
 469 void Item_Think(entity this)
 470 {
 471         this.nextthink = time;
 472         if(this.origin != this.oldorigin)
 473                 ItemUpdate(this);
 474 }
 475
 476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 477 bool Item_ItemsTime_Allow(GameItem it);
 478 float Item_ItemsTime_UpdateTime(entity e, float t);
 479 void Item_ItemsTime_SetTime(entity e, float t);
 480 void Item_ItemsTime_SetTimesForAllPlayers();
 481
 482 void Item_Respawn (entity this)
 483 {
 484         Item_Show(this, 1);
 485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 486         setorigin(this, this.origin);
 487
 488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 489         {
 490                 float t = Item_ItemsTime_UpdateTime(this, 0);
 491                 Item_ItemsTime_SetTime(this, t);
 492                 Item_ItemsTime_SetTimesForAllPlayers();
 493         }
 494
 495         setthink(this, Item_Think);
 496         this.nextthink = time;
 497
 498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 500 }
 501
 502 void Item_RespawnCountdown (entity this)
 503 {
 504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 505         {
 506                 if(this.waypointsprite_attached)
 507                         WaypointSprite_Kill(this.waypointsprite_attached);
 508                 Item_Respawn(this);
 509         }
 510         else
 511         {
 512                 this.nextthink = time + 1;
 513                 this.item_respawncounter += 1;
 514                 if(this.item_respawncounter == 1)
 515                 {
 516                         do {
 517                                 {
 518                                         entity wi = Weapons_from(this.weapon);
 519                                         if (wi != WEP_Null) {
 520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 521                                                 wp.wp_extra = wi.m_id;
 522                                                 break;
 523                                         }
 524                                 }
 525                                 {
 526                                         entity ii = this.itemdef;
 527                                         if (ii != NULL) {
 528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 529                                                 wp.wp_extra = ii.m_id;
 530                                                 break;
 531                                         }
 532                                 }
 533                         } while (0);
 534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 535             if(this.waypointsprite_attached)
 536             {
 537                 GameItem def = this.itemdef;
 538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 541             }
 542                 }
 543
 544                 if(this.waypointsprite_attached)
 545                 {
 546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 548                                 {
 549                                         msg_entity = it;
 550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 551                                 }
 552                         });
 553
 554                         WaypointSprite_Ping(this.waypointsprite_attached);
 555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 556                 }
 557         }
 558 }
 559
 560 void Item_RespawnThink(entity this)
 561 {
 562         this.nextthink = time;
 563         if(this.origin != this.oldorigin)
 564                 ItemUpdate(this);
 565
 566         if(time >= this.wait)
 567                 Item_Respawn(this);
 568 }
 569
 570 void Item_ScheduleRespawnIn(entity e, float t)
 571 {
 572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 574         {
 575                 setthink(e, Item_RespawnCountdown);
 576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 578                 e.item_respawncounter = 0;
 579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 580                 {
 581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 582                         Item_ItemsTime_SetTime(e, t);
 583                         Item_ItemsTime_SetTimesForAllPlayers();
 584                 }
 585         }
 586         else
 587         {
 588                 setthink(e, Item_RespawnThink);
 589                 e.nextthink = time;
 590                 e.scheduledrespawntime = time + t;
 591                 e.wait = time + t;
 592
 593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 594                 {
 595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 596                         Item_ItemsTime_SetTime(e, t);
 597                         Item_ItemsTime_SetTimesForAllPlayers();
 598                 }
 599         }
 600 }
 601
 602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 605
 606 /// Adjust respawn time according to the number of players.
 607 float adjust_respawntime(float normal_respawntime) {
 608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 609         float o = autocvar_g_pickup_respawntime_scaling_offset;
 610         float l = autocvar_g_pickup_respawntime_scaling_linear;
 611
 612         if (r == 0 && l == 1) {
 613                 return normal_respawntime;
 614         }
 615
 616         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 617         TeamBalance_GetTeamCounts(balance, NULL);
 618         int players = 0;
 619         for (int i = 1; i <= NUM_TEAMS; ++i)
 620         {
 621                 if (TeamBalance_IsTeamAllowed(balance, i))
 622                 {
 623                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 624                 }
 625         }
 626         TeamBalance_Destroy(balance);
 627
 628         if (players >= 2) {
 629                 return normal_respawntime * (r / (players + o) + l);
 630         } else {
 631                 return normal_respawntime;
 632         }
 633 }
 634
 635 void Item_ScheduleRespawn(entity e)
 636 {
 637         if(e.respawntime > 0)
 638         {
 639                 Item_Show(e, 0);
 640
 641                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 642                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 643
 644                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 645                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 646                 Item_ScheduleRespawnIn(e, respawn_in);
 647         }
 648         else // if respawntime is -1, this item does not respawn
 649                 Item_Show(e, -1);
 650 }
 651
 652 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 653         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 654
 655 void Item_ScheduleInitialRespawn(entity e)
 656 {
 657         Item_Show(e, 0);
 658
 659         float spawn_in;
 660         if (autocvar_g_pickup_respawntime_initial_random == 0)
 661         {
 662                 // range: respawntime .. respawntime + respawntimejitter
 663                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 664         }
 665         else
 666         {
 667                 float rnd;
 668                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 669                 {
 670                         static float shared_random = 0;
 671                         // NOTE this code works only if items are scheduled at the same time (normal case)
 672                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 673                         if (!shared_random || floor(time) > shared_random)
 674                                 shared_random = floor(time) + random();
 675                         rnd = shared_random - floor(time);
 676                 }
 677                 else
 678                         rnd = random();
 679
 680                 // range:
 681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 682                 // else: 0 .. ITEM_RESPAWN_TICKS
 683                 // this is to prevent powerups spawning unexpectedly without waypoints
 684                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 685         }
 686
 687         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 688 }
 689
 690 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 691         entity ammo_entity)
 692 {
 693         if (num_weapons == 0)
 694         {
 695                 return;
 696         }
 697         int num_potential_weapons = tokenize_console(weapon_names);
 698         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 699         {
 700                 RandomSelection_Init();
 701                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 702                         ++weapon_index)
 703                 {
 704                         string weapon = argv(weapon_index);
 705                         FOREACH(Weapons, it != WEP_Null,
 706                         {
 707                                 // Finding a weapon which player doesn't have.
 708                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 709                                 {
 710                                         RandomSelection_AddEnt(it, 1, 1);
 711                                         break;
 712                                 }
 713                         });
 714                 }
 715                 if (RandomSelection_chosen_ent == NULL)
 716                 {
 717                         return;
 718                 }
 719                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 720                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 721                 {
 722                         continue;
 723                 }
 724                 if (GetResource(receiver,
 725                         RandomSelection_chosen_ent.ammo_type) != 0)
 726                 {
 727                         continue;
 728                 }
 729                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 730                         GetResource(ammo_entity,
 731                         RandomSelection_chosen_ent.ammo_type));
 732         }
 733 }
 734
 735 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
 736 {
 737         float amount = GetResource(item, res_type);
 738         if (amount == 0)
 739         {
 740                 return false;
 741         }
 742         float player_amount = GetResource(player, res_type);
 743         if (item.spawnshieldtime)
 744         {
 745                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 746                         return false;
 747         }
 748         else if (g_weapon_stay == 2)
 749                 ammomax = min(amount, ammomax);
 750         else
 751                 return false;
 752         if (amount < 0)
 753                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 754         else
 755                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 756         return true;
 757 }
 758
 759 bool Item_GiveTo(entity item, entity player)
 760 {
 761         // if nothing happens to player, just return without taking the item
 762         int _switchweapon = 0;
 763         // in case the player has autoswitch enabled do the following:
 764         // if the player is using their best weapon before items are given, they
 765         // probably want to switch to an even better weapon after items are given
 766
 767         if(CS(player).autoswitch)
 768         {
 769                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770                 {
 771                         .entity weaponentity = weaponentities[slot];
 772                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 773                         {
 774                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 775                                         _switchweapon |= BIT(slot);
 776
 777                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 778                                         _switchweapon |= BIT(slot);
 779                         }
 780                 }
 781         }
 782         bool pickedup = false;
 783         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health));
 784         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue));
 785         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max));
 786         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max));
 787         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max));
 788         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max));
 789         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max));
 790         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max));
 791         if (item.itemdef.instanceOfWeaponPickup)
 792         {
 793                 WepSet w;
 794                 w = STAT(WEAPONS, item);
 795                 w &= ~STAT(WEAPONS, player);
 796
 797                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 798                 {
 799                         pickedup = true;
 800                         FOREACH(Weapons, it != WEP_Null, {
 801                                 if(w & (it.m_wepset))
 802                                 {
 803                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 804                                         {
 805                                                 .entity weaponentity = weaponentities[slot];
 806                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 807                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 808                                         }
 809                                         W_GiveWeapon(player, it.m_id);
 810                                 }
 811                         });
 812                 }
 813         }
 814
 815         if (item.itemdef.instanceOfPowerup)
 816         {
 817                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 818                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 819                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 820                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 821         }
 822
 823         int its;
 824         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 825         {
 826                 pickedup = true;
 827                 player.items |= its;
 828                 // TODO: we probably want to show a message in the console, but not this one!
 829                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 830         }
 831
 832         if (item.strength_finished)
 833         {
 834                 pickedup = true;
 835                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 836         }
 837         if (item.invincible_finished)
 838         {
 839                 pickedup = true;
 840                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 841         }
 842         if (item.superweapons_finished)
 843         {
 844                 pickedup = true;
 845                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 846         }
 847
 848         // always eat teamed entities
 849         if(item.team)
 850                 pickedup = true;
 851
 852         if (!pickedup)
 853                 return false;
 854
 855         // crude hack to enforce switching weapons
 856         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
 857         {
 858                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 859                 {
 860                         .entity weaponentity = weaponentities[slot];
 861                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 862                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 863                 }
 864                 return true;
 865         }
 866
 867         if(_switchweapon)
 868         {
 869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 870                 {
 871                         .entity weaponentity = weaponentities[slot];
 872                         if(_switchweapon & BIT(slot))
 873                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 874                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 875                 }
 876         }
 877
 878         return true;
 879 }
 880
 881 void Item_Touch(entity this, entity toucher)
 882 {
 883         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 884         if (Item_IsLoot(this))
 885         {
 886                 if (ITEM_TOUCH_NEEDKILL())
 887                 {
 888                         delete(this);
 889                         return;
 890                 }
 891         }
 892
 893         if(!(toucher.flags & FL_PICKUPITEMS)
 894         || STAT(FROZEN, toucher)
 895         || IS_DEAD(toucher)
 896         || (this.solid != SOLID_TRIGGER)
 897         || (this.owner == toucher)
 898         || (time < this.item_spawnshieldtime)
 899         ) { return; }
 900
 901         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 902         {
 903                 case MUT_ITEMTOUCH_RETURN: { return; }
 904                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 905         }
 906
 907         toucher = M_ARGV(1, entity);
 908
 909         if (Item_IsExpiring(this))
 910         {
 911                 this.strength_finished = max(0, this.strength_finished - time);
 912                 this.invincible_finished = max(0, this.invincible_finished - time);
 913                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 914         }
 915         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 916         if (!gave)
 917         {
 918                 if (Item_IsExpiring(this))
 919                 {
 920                         // undo what we did above
 921                         this.strength_finished += time;
 922                         this.invincible_finished += time;
 923                         this.superweapons_finished += time;
 924                 }
 925                 return;
 926         }
 927
 928 LABEL(pickup)
 929
 930         STAT(LAST_PICKUP, toucher) = time;
 931
 932         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 933         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 934
 935         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 936         if (wasfreed(this))
 937         {
 938                 return;
 939         }
 940
 941         if (Item_IsLoot(this))
 942         {
 943                 delete(this);
 944                 return;
 945         }
 946         if (!this.spawnshieldtime)
 947         {
 948                 return;
 949         }
 950         entity e;
 951         if (this.team)
 952         {
 953                 RandomSelection_Init();
 954                 IL_EACH(g_items, it.team == this.team,
 955                 {
 956                         if (it.itemdef) // is a registered item
 957                         {
 958                                 Item_Show(it, -1);
 959                                 it.scheduledrespawntime = 0;
 960                                 RandomSelection_AddEnt(it, it.cnt, 0);
 961                         }
 962                 });
 963                 e = RandomSelection_chosen_ent;
 964                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 965         }
 966         else
 967                 e = this;
 968         Item_ScheduleRespawn(e);
 969 }
 970
 971 void Item_Reset(entity this)
 972 {
 973         Item_Show(this, !this.state);
 974         setorigin(this, this.origin);
 975
 976         if (Item_IsLoot(this))
 977         {
 978                 return;
 979         }
 980         setthink(this, Item_Think);
 981         this.nextthink = time;
 982         if (this.waypointsprite_attached)
 983         {
 984                 WaypointSprite_Kill(this.waypointsprite_attached);
 985         }
 986         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 987         {
 988                 Item_ScheduleInitialRespawn(this);
 989         }
 990 }
 991
 992 void Item_FindTeam(entity this)
 993 {
 994         entity e;
 995
 996         if(this.effects & EF_NODRAW)
 997         {
 998                 // marker for item team search
 999                 LOG_TRACE("Initializing item team ", ftos(this.team));
1000                 RandomSelection_Init();
1001                 IL_EACH(g_items, it.team == this.team,
1002                 {
1003                         if(it.itemdef) // is a registered item
1004                                 RandomSelection_AddEnt(it, it.cnt, 0);
1005                 });
1006
1007                 e = RandomSelection_chosen_ent;
1008                 e.state = 0;
1009                 Item_Show(e, 1);
1010
1011                 IL_EACH(g_items, it.team == this.team,
1012                 {
1013                         if(it.itemdef) // is a registered item
1014                         {
1015                                 if(it != e)
1016                                 {
1017                                         // make it non-spawned
1018                                         Item_Show(it, -1);
1019                                         it.state = 1; // state 1 = initially hidden item, apparently
1020                                 }
1021                                 it.effects &= ~EF_NODRAW;
1022                         }
1023                 });
1024
1025                 Item_Reset(this);
1026         }
1027 }
1028
1029 // Savage: used for item garbage-collection
1030 void RemoveItem(entity this)
1031 {
1032         if(wasfreed(this) || !this) { return; }
1033         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1034         delete(this);
1035 }
1036
1037 // pickup evaluation functions
1038 // these functions decide how desirable an item is to the bots
1039
1040 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1041
1042 float weapon_pickupevalfunc(entity player, entity item)
1043 {
1044         // See if I have it already
1045         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1046         {
1047                 // If I can pick it up
1048                 if(!item.spawnshieldtime)
1049                         return 0;
1050                 return ammo_pickupevalfunc(player, item);
1051         }
1052
1053         // reduce weapon value if bot already got a good arsenal
1054         float c = 1;
1055         int weapons_value = 0;
1056         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1057                 weapons_value += it.bot_pickupbasevalue;
1058         });
1059         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1060
1061         return item.bot_pickupbasevalue * c;
1062 }
1063
1064 float ammo_pickupevalfunc(entity player, entity item)
1065 {
1066         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1067         entity wpn = NULL;
1068         float c = 0;
1069         float rating = 0;
1070
1071         // Detect needed ammo
1072         if(item.itemdef.instanceOfWeaponPickup)
1073         {
1074                 entity ammo = NULL;
1075                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1076                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1077                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1078                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1079                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1080                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1081
1082                 if(!ammo)
1083                         return 0;
1084                 wpn = item;
1085                 rating = ammo.m_botvalue;
1086         }
1087         else
1088         {
1089                 FOREACH(Weapons, it != WEP_Null, {
1090                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1091                                 continue;
1092
1093                         switch(it.ammo_type)
1094                         {
1095                                 case RES_SHELLS:  need_shells  = true; break;
1096                                 case RES_BULLETS: need_nails   = true; break;
1097                                 case RES_ROCKETS: need_rockets = true; break;
1098                                 case RES_CELLS:   need_cells   = true; break;
1099                                 case RES_PLASMA:  need_plasma  = true; break;
1100                                 case RES_FUEL:    need_fuel    = true; break;
1101                         }
1102                 });
1103                 rating = item.bot_pickupbasevalue;
1104         }
1105
1106         float noammorating = 0.5;
1107
1108         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1109                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1110
1111         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1112                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1113
1114         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1115                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1116
1117         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1118                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1119
1120         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1121                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1122
1123         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1124                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1125
1126         rating *= min(c, 2);
1127         if(wpn)
1128                 rating += wpn.bot_pickupbasevalue * 0.1;
1129         return rating;
1130 }
1131
1132 float healtharmor_pickupevalfunc(entity player, entity item)
1133 {
1134         float c = 0;
1135         float rating = item.bot_pickupbasevalue;
1136
1137         float itemarmor = GetResource(item, RES_ARMOR);
1138         float itemhealth = GetResource(item, RES_HEALTH);
1139
1140         if(item.item_group)
1141         {
1142                 itemarmor *= min(4, item.item_group_count);
1143                 itemhealth *= min(4, item.item_group_count);
1144         }
1145
1146         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1147                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1148
1149         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1150                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1151
1152         rating *= min(2, c);
1153         return rating;
1154 }
1155
1156 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1157 {
1158         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1159                 RemoveItem(this);
1160 }
1161
1162 void item_use(entity this, entity actor, entity trigger)
1163 {
1164         // use the touch function to handle collection
1165         gettouch(this)(this, actor);
1166 }
1167
1168 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1169 {
1170         string itemname = def.m_name;
1171         Model itemmodel = def.m_model;
1172     Sound pickupsound = def.m_sound;
1173         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1174         float pickupbasevalue = def.m_botvalue;
1175         int itemflags = def.m_itemflags;
1176
1177         startitem_failed = false;
1178
1179         this.item_model_ent = itemmodel;
1180     this.item_pickupsound_ent = pickupsound;
1181
1182     if(def.m_iteminit)
1183         def.m_iteminit(def, this);
1184
1185         if(!this.respawntime) // both need to be set
1186         {
1187                 this.respawntime = defaultrespawntime;
1188                 this.respawntimejitter = defaultrespawntimejitter;
1189         }
1190
1191         if(!this.pickup_anyway && def.m_pickupanyway)
1192                 this.pickup_anyway = def.m_pickupanyway();
1193
1194         int itemid = def.m_itemid;
1195         this.items = itemid;
1196         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1197         this.weapon = weaponid;
1198
1199         if(!this.fade_end)
1200         {
1201                 this.fade_start = autocvar_g_items_mindist;
1202                 this.fade_end = autocvar_g_items_maxdist;
1203         }
1204
1205         if(weaponid)
1206                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1207
1208         this.flags = FL_ITEM | itemflags;
1209         IL_PUSH(g_items, this);
1210
1211         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1212         {
1213                 startitem_failed = true;
1214                 delete(this);
1215                 return;
1216         }
1217
1218         if (Item_IsLoot(this))
1219         {
1220                 this.reset = SUB_Remove;
1221                 set_movetype(this, MOVETYPE_TOSS);
1222
1223                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1224                 setthink(this, RemoveItem);
1225                 this.nextthink = time + 20;
1226
1227                 this.takedamage = DAMAGE_YES;
1228                 this.event_damage = Item_Damage;
1229
1230                 if (Item_IsExpiring(this))
1231                 {
1232                         // if item is worthless after a timer, have it expire then
1233                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1234                 }
1235
1236                 // don't drop if in a NODROP zone (such as lava)
1237                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1238                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1239                 {
1240                         startitem_failed = true;
1241                         delete(this);
1242                         return;
1243                 }
1244         }
1245         else
1246         {
1247                 if(!have_pickup_item(this))
1248                 {
1249                         startitem_failed = true;
1250                         delete(this);
1251                         return;
1252                 }
1253
1254                 if(this.angles != '0 0 0')
1255                         this.SendFlags |= ISF_ANGLES;
1256
1257                 this.reset = Item_Reset;
1258                 // it's a level item
1259                 if(this.spawnflags & 1)
1260                         this.noalign = 1;
1261                 if (this.noalign > 0)
1262                         set_movetype(this, MOVETYPE_NONE);
1263                 else
1264                         set_movetype(this, MOVETYPE_TOSS);
1265                 // do item filtering according to game mode and other things
1266                 if (this.noalign <= 0)
1267                 {
1268                         // first nudge it off the floor a little bit to avoid math errors
1269                         setorigin(this, this.origin + '0 0 1');
1270                         // set item size before we spawn a spawnfunc_waypoint
1271                         setsize(this, def.m_mins, def.m_maxs);
1272                         this.SendFlags |= ISF_SIZE;
1273                         // note droptofloor returns false if stuck/or would fall too far
1274                         if (!this.noalign)
1275                                 droptofloor(this);
1276                         waypoint_spawnforitem(this);
1277                 }
1278
1279                 /*
1280                  * can't do it that way, as it would break maps
1281                  * TODO make a target_give like entity another way, that perhaps has
1282                  * the weapon name in a key
1283                 if(this.targetname)
1284                 {
1285                         // target_give not yet supported; maybe later
1286                         print("removed targeted ", this.classname, "\n");
1287                         startitem_failed = true;
1288                         delete(this);
1289                         return;
1290                 }
1291                 */
1292
1293                 if(this.targetname != "" && (this.spawnflags & 16))
1294                         this.use = item_use;
1295
1296                 if(autocvar_spawn_debug >= 2)
1297                 {
1298             // why not flags & fl_item?
1299                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1300                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1301                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1302                 error("Mapper sucks.");
1303             });
1304                         this.is_item = true;
1305                 }
1306
1307                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1308
1309                 precache_model(this.model);
1310                 precache_sound(this.item_pickupsound);
1311
1312                 if (   def.instanceOfPowerup
1313                         || def.instanceOfWeaponPickup
1314                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1315                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1316                         || (itemid & (IT_KEY1 | IT_KEY2))
1317                 ) this.target = "###item###"; // for finding the nearest item using findnearest
1318
1319                 Item_ItemsTime_SetTime(this, 0);
1320         }
1321
1322         this.bot_pickup = true;
1323         this.bot_pickupevalfunc = pickupevalfunc;
1324         this.bot_pickupbasevalue = pickupbasevalue;
1325         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1326         this.netname = itemname;
1327         settouch(this, Item_Touch);
1328         setmodel(this, MDL_Null); // precision set below
1329         //this.effects |= EF_LOWPRECISION;
1330
1331         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1332
1333         this.SendFlags |= ISF_SIZE;
1334
1335         if (!(this.spawnflags & 1024)) {
1336                 if(def.instanceOfPowerup)
1337                         this.ItemStatus |= ITS_ANIMATE1;
1338
1339                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1340                         this.ItemStatus |= ITS_ANIMATE2;
1341         }
1342
1343         if(def.instanceOfWeaponPickup)
1344         {
1345                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1346                         this.colormap = 1024; // color shirt=0 pants=0 grey
1347                 else
1348                         this.gravity = 1;
1349                 if (!(this.spawnflags & 1024))
1350                         this.ItemStatus |= ITS_ANIMATE1;
1351                 this.SendFlags |= ISF_COLORMAP;
1352         }
1353
1354         this.state = 0;
1355         if(this.team) // broken, no idea why.
1356         {
1357                 if(!this.cnt)
1358                         this.cnt = 1; // item probability weight
1359
1360                 this.effects |= EF_NODRAW; // marker for item team search
1361                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1362         }
1363         else
1364                 Item_Reset(this);
1365
1366         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1367
1368         // call this hook after everything else has been done
1369         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1370         {
1371                 startitem_failed = true;
1372                 delete(this);
1373                 return;
1374         }
1375
1376         setItemGroup(this);
1377 }
1378
1379 void StartItem(entity this, GameItem def)
1380 {
1381     def = def.m_spawnfunc_hookreplace(def, this);
1382     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1383     {
1384         delete(this);
1385         return;
1386     }
1387     this.classname = def.m_canonical_spawnfunc;
1388     _StartItem(
1389         this,
1390         this.itemdef = def,
1391         def.m_respawntime(), // defaultrespawntime
1392         def.m_respawntimejitter() // defaultrespawntimejitter
1393         );
1394 }
1395
1396 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1397 int group_count = 1;
1398
1399 void setItemGroup(entity this)
1400 {
1401         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1402                 return;
1403
1404         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1405         {
1406                 if(!this.item_group)
1407                 {
1408                         if(!it.item_group)
1409                         {
1410                                 it.item_group = group_count;
1411                                 group_count++;
1412                         }
1413                         this.item_group = it.item_group;
1414                 }
1415                 else // spawning item is already part of a item_group X
1416                 {
1417                         if(!it.item_group)
1418                                 it.item_group = this.item_group;
1419                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1420                         {
1421                                 int grY = it.item_group;
1422                                 // move all items of item_group Y to item_group X
1423                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1424                                 {
1425                                         if(it.item_group == grY)
1426                                                 it.item_group = this.item_group;
1427                                 });
1428                         }
1429                 }
1430         });
1431 }
1432
1433 void setItemGroupCount()
1434 {
1435         for (int k = 1; k <= group_count; k++)
1436         {
1437                 int count = 0;
1438                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1439                 if (count)
1440                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1441         }
1442 }
1443
1444 void target_items_use(entity this, entity actor, entity trigger)
1445 {
1446         if(Item_IsLoot(actor))
1447         {
1448                 EXACTTRIGGER_TOUCH(this, trigger);
1449                 delete(actor);
1450                 return;
1451         }
1452
1453         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1454                 return;
1455
1456         if(trigger.solid == SOLID_TRIGGER)
1457         {
1458                 EXACTTRIGGER_TOUCH(this, trigger);
1459         }
1460
1461         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1462         {
1463                 delete(it);
1464         });
1465
1466         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1467                 centerprint(actor, this.message);
1468 }
1469
1470 spawnfunc(target_items)
1471 {
1472         int n;
1473         string s;
1474
1475         this.use = target_items_use;
1476         if(!this.strength_finished)
1477                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1478         if(!this.invincible_finished)
1479                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1480         if(!this.superweapons_finished)
1481                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1482
1483         n = tokenize_console(this.netname);
1484         if(argv(0) == "give")
1485         {
1486                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1487         }
1488         else
1489         {
1490                 for(int j = 0; j < n; ++j)
1491                 {
1492                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1493                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1494                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1495                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1496                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1497                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1498                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1499                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1500                         else
1501                         {
1502                                 FOREACH(Buffs, it != BUFF_Null,
1503                                 {
1504                                         s = Buff_UndeprecateName(argv(j));
1505                                         if(s == it.m_name)
1506                                         {
1507                                                 STAT(BUFFS, this) |= (it.m_itemid);
1508                                                 break;
1509                                         }
1510                                 });
1511                                 FOREACH(Weapons, it != WEP_Null, {
1512                                         s = W_UndeprecateName(argv(j));
1513                                         if(s == it.netname)
1514                                         {
1515                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1516                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1517                                                         it.wr_init(it);
1518                                                 break;
1519                                         }
1520                                 });
1521                         }
1522                 }
1523
1524                 string itemprefix, valueprefix;
1525                 if(this.spawnflags == 0)
1526                 {
1527                         itemprefix = "";
1528                         valueprefix = "";
1529                 }
1530                 else if(this.spawnflags == 1)
1531                 {
1532                         itemprefix = "max ";
1533                         valueprefix = "max ";
1534                 }
1535                 else if(this.spawnflags == 2)
1536                 {
1537                         itemprefix = "min ";
1538                         valueprefix = "min ";
1539                 }
1540                 else if(this.spawnflags == 4)
1541                 {
1542                         itemprefix = "minus ";
1543                         valueprefix = "max ";
1544                 }
1545                 else
1546                 {
1547                         error("invalid spawnflags");
1548                         itemprefix = valueprefix = string_null;
1549                 }
1550
1551                 this.netname = "";
1552                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1553                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1554                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1555                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1557                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1558                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1559                 if(GetResource(this, RES_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_SHELLS)), "shells");
1560                 if(GetResource(this, RES_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_BULLETS)), "nails");
1561                 if(GetResource(this, RES_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ROCKETS)), "rockets");
1562                 if(GetResource(this, RES_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_CELLS)), "cells");
1563                 if(GetResource(this, RES_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_PLASMA)), "plasma");
1564                 if(GetResource(this, RES_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_FUEL)), "fuel");
1565                 if(GetResource(this, RES_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_HEALTH)), "health");
1566                 if(GetResource(this, RES_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ARMOR)), "armor");
1567                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1568                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1569         }
1570         this.netname = strzone(this.netname);
1571         //print(this.netname, "\n");
1572
1573         n = tokenize_console(this.netname);
1574         for(int j = 0; j < n; ++j)
1575         {
1576                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1577             it.wr_init(it);
1578             break;
1579                 });
1580         }
1581 }
1582
1583 float GiveWeapon(entity e, float wpn, float op, float val)
1584 {
1585         WepSet v0, v1;
1586         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1587         v0 = (STAT(WEAPONS, e) & s);
1588         switch(op)
1589         {
1590                 case OP_SET:
1591                         if(val > 0)
1592                                 STAT(WEAPONS, e) |= s;
1593                         else
1594                                 STAT(WEAPONS, e) &= ~s;
1595                         break;
1596                 case OP_MIN:
1597                 case OP_PLUS:
1598                         if(val > 0)
1599                                 STAT(WEAPONS, e) |= s;
1600                         break;
1601                 case OP_MAX:
1602                         if(val <= 0)
1603                                 STAT(WEAPONS, e) &= ~s;
1604                         break;
1605                 case OP_MINUS:
1606                         if(val > 0)
1607                                 STAT(WEAPONS, e) &= ~s;
1608                         break;
1609         }
1610         v1 = (STAT(WEAPONS, e) & s);
1611         return (v0 != v1);
1612 }
1613
1614 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1615 {
1616         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1617         switch(op)
1618         {
1619                 case OP_SET:
1620                         if(val > 0)
1621                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1622                         else
1623                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1624                         break;
1625                 case OP_MIN:
1626                 case OP_PLUS:
1627                         if(val > 0)
1628                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1629                         break;
1630                 case OP_MAX:
1631                         if(val <= 0)
1632                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1633                         break;
1634                 case OP_MINUS:
1635                         if(val > 0)
1636                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1637                         break;
1638         }
1639         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1640         return (had_buff != have_buff);
1641 }
1642
1643 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1644 {
1645         if(v1 == v0)
1646                 return;
1647         if(v1 <= v0 - t)
1648         {
1649                 if(snd_decr != NULL)
1650                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1651         }
1652         else if(v0 >= v0 + t)
1653         {
1654                 if(snd_incr != NULL)
1655                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1656         }
1657 }
1658
1659 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1660 {
1661         if(v0 < v1)
1662                 e.(rotfield) = max(e.(rotfield), time + rottime);
1663         else if(v0 > v1)
1664                 e.(regenfield) = max(e.(regenfield), time + regentime);
1665 }
1666 bool GiveResourceValue(entity e, int res_type, int op, int val)
1667 {
1668         int v0 = GetResource(e, res_type);
1669         switch (op)
1670         {
1671                 // min 100 cells = at least 100 cells
1672                 case OP_SET: SetResource(e, res_type, val); break;
1673                 case OP_MIN: SetResource(e, res_type, max(v0, val)); break;
1674                 case OP_MAX: SetResource(e, res_type, min(v0, val)); break;
1675                 case OP_PLUS: SetResource(e, res_type, v0 + val); break;
1676                 case OP_MINUS: SetResource(e, res_type, v0 - val); break;
1677         }
1678         int v1 = GetResource(e, res_type);
1679         return v0 != v1;
1680 }
1681
1682 float GiveItems(entity e, float beginarg, float endarg)
1683 {
1684         float got, i, val, op;
1685         string cmd;
1686
1687         val = 999;
1688         op = OP_SET;
1689
1690         got = 0;
1691
1692         int _switchweapon = 0;
1693
1694         if(CS(e).autoswitch)
1695         {
1696                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1697                 {
1698                         .entity weaponentity = weaponentities[slot];
1699                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1700                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1701                                 _switchweapon |= BIT(slot);
1702                 }
1703         }
1704
1705         e.strength_finished = max(0, e.strength_finished - time);
1706         e.invincible_finished = max(0, e.invincible_finished - time);
1707         e.superweapons_finished = max(0, e.superweapons_finished - time);
1708
1709         PREGIVE(e, items);
1710         PREGIVE_WEAPONS(e);
1711         PREGIVE(e, strength_finished);
1712         PREGIVE(e, invincible_finished);
1713         PREGIVE(e, superweapons_finished);
1714         PREGIVE_RESOURCE(e, RES_BULLETS);
1715         PREGIVE_RESOURCE(e, RES_CELLS);
1716         PREGIVE_RESOURCE(e, RES_PLASMA);
1717         PREGIVE_RESOURCE(e, RES_SHELLS);
1718         PREGIVE_RESOURCE(e, RES_ROCKETS);
1719         PREGIVE_RESOURCE(e, RES_FUEL);
1720         PREGIVE_RESOURCE(e, RES_ARMOR);
1721         PREGIVE_RESOURCE(e, RES_HEALTH);
1722
1723         for(i = beginarg; i < endarg; ++i)
1724         {
1725                 cmd = argv(i);
1726
1727                 if(cmd == "0" || stof(cmd))
1728                 {
1729                         val = stof(cmd);
1730                         continue;
1731                 }
1732                 switch(cmd)
1733                 {
1734                         case "no":
1735                                 op = OP_MAX;
1736                                 val = 0;
1737                                 continue;
1738                         case "max":
1739                                 op = OP_MAX;
1740                                 continue;
1741                         case "min":
1742                                 op = OP_MIN;
1743                                 continue;
1744                         case "plus":
1745                                 op = OP_PLUS;
1746                                 continue;
1747                         case "minus":
1748                                 op = OP_MINUS;
1749                                 continue;
1750                         case "ALL":
1751                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1752                                 got += GiveValue(e, strength_finished, op, val);
1753                                 got += GiveValue(e, invincible_finished, op, val);
1754                                 got += GiveValue(e, superweapons_finished, op, val);
1755                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1756                         case "all":
1757                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1758                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1759                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1760                         case "allweapons":
1761                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1762                         //case "allbuffs": // all buffs makes a player god, do not want!
1763                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1764                         case "allammo":
1765                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1766                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1767                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1768                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1769                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1770                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1771                                 break;
1772                         case "unlimited_ammo":
1773                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1774                                 break;
1775                         case "unlimited_weapon_ammo":
1776                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1777                                 break;
1778                         case "unlimited_superweapons":
1779                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1780                                 break;
1781                         case "jetpack":
1782                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1783                                 break;
1784                         case "fuel_regen":
1785                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1786                                 break;
1787                         case "strength":
1788                                 got += GiveValue(e, strength_finished, op, val);
1789                                 break;
1790                         case "invincible":
1791                                 got += GiveValue(e, invincible_finished, op, val);
1792                                 break;
1793                         case "superweapons":
1794                                 got += GiveValue(e, superweapons_finished, op, val);
1795                                 break;
1796                         case "cells":
1797                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1798                                 break;
1799                         case "plasma":
1800                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1801                                 break;
1802                         case "shells":
1803                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1804                                 break;
1805                         case "nails":
1806                         case "bullets":
1807                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1808                                 break;
1809                         case "rockets":
1810                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1811                                 break;
1812                         case "health":
1813                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1814                                 break;
1815                         case "armor":
1816                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1817                                 break;
1818                         case "fuel":
1819                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1820                                 break;
1821                         default:
1822                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1823                                 {
1824                                         got += GiveBuff(e, it, op, val);
1825                                         break;
1826                                 });
1827                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1828                     got += GiveWeapon(e, it.m_id, op, val);
1829                     break;
1830                                 });
1831                                 break;
1832                 }
1833                 val = 999;
1834                 op = OP_SET;
1835         }
1836
1837         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1838         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1839         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1840         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1841         FOREACH(Weapons, it != WEP_Null, {
1842                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1843                 if(!(save_weapons & (it.m_wepset)))
1844                         if(STAT(WEAPONS, e) & (it.m_wepset))
1845                                 it.wr_init(it);
1846         });
1847         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1848         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1849         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1850         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1851         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1852         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1853         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1854         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1855         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1856         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1857         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1858
1859         if(e.superweapons_finished <= 0)
1860                 if(!g_weaponarena && STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1861                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1862
1863         if(e.strength_finished <= 0)
1864                 e.strength_finished = 0;
1865         else
1866                 e.strength_finished += time;
1867         if(e.invincible_finished <= 0)
1868                 e.invincible_finished = 0;
1869         else
1870                 e.invincible_finished += time;
1871         if(e.superweapons_finished <= 0)
1872                 e.superweapons_finished = 0;
1873         else
1874                 e.superweapons_finished += time;
1875
1876         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1877         {
1878                 .entity weaponentity = weaponentities[slot];
1879                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1880                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1881                         _switchweapon |= BIT(slot);
1882         }
1883
1884         if(_switchweapon)
1885         {
1886                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1887                 {
1888                         .entity weaponentity = weaponentities[slot];
1889                         if(_switchweapon & BIT(slot))
1890                         {
1891                                 Weapon wep = w_getbestweapon(e, weaponentity);
1892                                 if(wep != e.(weaponentity).m_switchweapon)
1893                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1894                         }
1895                 }
1896         }
1897
1898         return got;
1899 }
1900 #endif