qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items && !this.item_simple) // no bobbing applied to simple items, for consistency's sake (no visual difference between ammo and weapons)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 this.angles += this.avelocity * frametime;
  96             float fade_in = bound(0, time - this.onground_time, 1);
  97             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  98         }
  99
 100         if(this.ItemStatus & ITS_ANIMATE2)
 101         {
 102                 this.angles += this.avelocity * frametime;
 103             float fade_in = bound(0, time - this.onground_time, 1);
 104             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 105         }
 106     }
 107
 108     Item_SetAlpha(this);
 109 }
 110
 111 void Item_PreDraw(entity this)
 112 {
 113         if(warpzone_warpzones_exist)
 114         {
 115                 setpredraw(this, func_null); // no need to keep running this
 116                 return;
 117         }
 118         float alph;
 119         vector org = getpropertyvec(VF_ORIGIN);
 120         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 121                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 122         if(this.fade_start)
 123         {
 124                 if(vdist(org - this.origin, >, this.fade_end))
 125                         alph = 0; // save on some processing
 126                 else if(vdist(org - this.origin, <, this.fade_start))
 127                         alph = 1; // more processing saved
 128                 else
 129                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 130         }
 131         else
 132                 alph = 1;
 133         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 134         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 135                 this.alpha = alph;
 136         if(alph <= 0)
 137                 this.drawmask = 0;
 138         //else
 139                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 140 }
 141
 142 void ItemRemove(entity this)
 143 {
 144         strfree(this.mdl);
 145 }
 146
 147 HashMap ENT_CLIENT_ITEM_simple;
 148 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 149 {
 150         HM_NEW(ENT_CLIENT_ITEM_simple);
 151 }
 152 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 153 {
 154         HM_DELETE(ENT_CLIENT_ITEM_simple);
 155 }
 156
 157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 158 {
 159     int sf = ReadByte();
 160
 161     if(sf & ISF_LOCATION)
 162     {
 163         this.origin = ReadVector();
 164         setorigin(this, this.origin);
 165         this.oldorigin = this.origin;
 166     }
 167
 168     if(sf & ISF_ANGLES)
 169     {
 170         this.angles_x = ReadAngle();
 171         this.angles_y = ReadAngle();
 172         this.angles_z = ReadAngle();
 173     }
 174
 175     if(sf & ISF_SIZE)
 176     {
 177         setsize(this, '-16 -16 0', '16 16 48');
 178     }
 179
 180     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 181     {
 182         this.ItemStatus = ReadByte();
 183
 184         Item_SetAlpha(this);
 185
 186         if(this.ItemStatus & ITS_ALLOWFB)
 187            this.effects |= EF_FULLBRIGHT;
 188
 189         if(this.ItemStatus & ITS_GLOW)
 190         {
 191             if(this.ItemStatus & ITS_AVAILABLE)
 192                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 193             else
 194                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 195         }
 196     }
 197
 198     if(sf & ISF_MODEL)
 199     {
 200         this.drawmask  = MASK_NORMAL;
 201                 set_movetype(this, MOVETYPE_TOSS);
 202                 if (isnew) IL_PUSH(g_drawables, this);
 203         this.draw       = ItemDraw;
 204         this.solid = SOLID_TRIGGER;
 205         //this.flags |= FL_ITEM;
 206
 207         this.fade_end = ReadShort();
 208         this.fade_start = ReadShort();
 209         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 210                 setpredraw(this, Item_PreDraw);
 211
 212                 strfree(this.mdl);
 213
 214         string _fn = ReadString();
 215         this.item_simple = false; // reset it!
 216
 217         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 218         {
 219             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 220             this.item_simple = true;
 221
 222                         #define extensions(x) \
 223                                 x(md3) \
 224                                 x(dpm) \
 225                                 x(iqm) \
 226                                 x(mdl) \
 227                                 /**/
 228                         #define tryext(ext) { \
 229                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 230                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 231                                 if (cached == "") { \
 232                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 233                                 } \
 234                                 if (cached != "0") { \
 235                                         strcpy(this.mdl, s); \
 236                                         break; \
 237                                 } \
 238                         }
 239                         do {
 240                                 extensions(tryext);
 241                                 this.item_simple = false;
 242                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 243                         } while (0);
 244                         #undef tryext
 245                         #undef extensions
 246         }
 247
 248         if(!this.item_simple)
 249             strcpy(this.mdl, _fn);
 250
 251         if(this.mdl == "")
 252             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 253
 254         precache_model(this.mdl);
 255         _setmodel(this, this.mdl);
 256
 257         setsize(this, '-16 -16 0', '16 16 48');
 258     }
 259
 260     if(sf & ISF_COLORMAP)
 261     {
 262         this.colormap = ReadShort();
 263         this.item_glowmod_x = ReadByte() / 255.0;
 264         this.item_glowmod_y = ReadByte() / 255.0;
 265         this.item_glowmod_z = ReadByte() / 255.0;
 266     }
 267
 268     if(sf & ISF_DROP)
 269     {
 270         this.gravity = 1;
 271         this.pushable = true;
 272         //this.angles = '0 0 0';
 273         set_movetype(this, MOVETYPE_TOSS);
 274         this.velocity = ReadVector();
 275         setorigin(this, this.oldorigin);
 276
 277         if(!this.move_time)
 278         {
 279             this.move_time = time;
 280             this.spawntime = time;
 281         }
 282         else
 283             this.move_time = max(this.move_time, time);
 284     }
 285
 286     if(autocvar_cl_animate_items)
 287     {
 288         if(this.ItemStatus & ITS_ANIMATE1)
 289             this.avelocity = '0 180 0';
 290
 291         if(this.ItemStatus & ITS_ANIMATE2)
 292             this.avelocity = '0 -90 0';
 293     }
 294
 295     this.entremove = ItemRemove;
 296
 297     return true;
 298 }
 299
 300 #endif
 301
 302 #ifdef SVQC
 303 bool ItemSend(entity this, entity to, int sf)
 304 {
 305         if(this.gravity)
 306                 sf |= ISF_DROP;
 307         else
 308                 sf &= ~ISF_DROP;
 309
 310         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 311         WriteByte(MSG_ENTITY, sf);
 312
 313         //WriteByte(MSG_ENTITY, this.cnt);
 314         if(sf & ISF_LOCATION)
 315         {
 316                 WriteVector(MSG_ENTITY, this.origin);
 317         }
 318
 319         if(sf & ISF_ANGLES)
 320         {
 321                 WriteAngle(MSG_ENTITY, this.angles_x);
 322                 WriteAngle(MSG_ENTITY, this.angles_y);
 323                 WriteAngle(MSG_ENTITY, this.angles_z);
 324         }
 325
 326         // sets size on the client, unused on server
 327         //if(sf & ISF_SIZE)
 328
 329         if(sf & ISF_STATUS)
 330                 WriteByte(MSG_ENTITY, this.ItemStatus);
 331
 332         if(sf & ISF_MODEL)
 333         {
 334                 WriteShort(MSG_ENTITY, this.fade_end);
 335                 WriteShort(MSG_ENTITY, this.fade_start);
 336
 337                 if(this.mdl == "")
 338                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 339
 340                 WriteString(MSG_ENTITY, this.mdl);
 341         }
 342
 343
 344         if(sf & ISF_COLORMAP)
 345         {
 346                 WriteShort(MSG_ENTITY, this.colormap);
 347                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 348                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 349                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 350         }
 351
 352         if(sf & ISF_DROP)
 353         {
 354                 WriteVector(MSG_ENTITY, this.velocity);
 355         }
 356
 357         return true;
 358 }
 359
 360 void ItemUpdate(entity this)
 361 {
 362         this.oldorigin = this.origin;
 363         this.SendFlags |= ISF_LOCATION;
 364 }
 365
 366 void UpdateItemAfterTeleport(entity this)
 367 {
 368         if(getSendEntity(this) == ItemSend)
 369                 ItemUpdate(this);
 370 }
 371
 372 bool have_pickup_item(entity this)
 373 {
 374         if(this.itemdef.instanceOfPowerup)
 375         {
 376                 if(autocvar_g_powerups > 0)
 377                         return true;
 378                 if(autocvar_g_powerups == 0)
 379                         return false;
 380         }
 381         else
 382         {
 383                 if(autocvar_g_pickup_items > 0)
 384                         return true;
 385                 if(autocvar_g_pickup_items == 0)
 386                         return false;
 387                 if(g_weaponarena)
 388                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 389                                 return false;
 390         }
 391         return true;
 392 }
 393
 394 void Item_Show(entity e, int mode)
 395 {
 396         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 397         e.ItemStatus &= ~ITS_STAYWEP;
 398         entity def = e.itemdef;
 399         if (mode > 0)
 400         {
 401                 // make the item look normal, and be touchable
 402                 e.model = e.mdl;
 403                 e.solid = SOLID_TRIGGER;
 404                 e.spawnshieldtime = 1;
 405                 e.ItemStatus |= ITS_AVAILABLE;
 406         }
 407         else if (mode < 0)
 408         {
 409                 // hide the item completely
 410                 e.model = string_null;
 411                 e.solid = SOLID_NOT;
 412                 e.spawnshieldtime = 1;
 413                 e.ItemStatus &= ~ITS_AVAILABLE;
 414         }
 415         else
 416         {
 417                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 418                         || e.team // weapon stay isn't supported for teamed weapons
 419                         ;
 420                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 421                 {
 422                         // make the item translucent and not touchable
 423                         e.model = e.mdl;
 424                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 425                         e.effects |= EF_STARDUST;
 426                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 427                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 428                 }
 429                 else
 430                 {
 431                         //setmodel(e, "null");
 432                         e.solid = SOLID_NOT;
 433                         e.colormod = '0 0 0';
 434                         //e.glowmod = e.colormod;
 435                         e.spawnshieldtime = 1;
 436                         e.ItemStatus &= ~ITS_AVAILABLE;
 437                 }
 438         }
 439
 440         if (def.m_glow)
 441                 e.ItemStatus |= ITS_GLOW;
 442
 443         if (autocvar_g_nodepthtestitems)
 444                 e.effects |= EF_NODEPTHTEST;
 445
 446
 447         if (autocvar_g_fullbrightitems)
 448                 e.ItemStatus |= ITS_ALLOWFB;
 449
 450         if (autocvar_sv_simple_items)
 451                 e.ItemStatus |= ITS_ALLOWSI;
 452
 453         // relink entity (because solid may have changed)
 454         setorigin(e, e.origin);
 455         e.SendFlags |= ISF_STATUS;
 456 }
 457
 458 void Item_Think(entity this)
 459 {
 460         this.nextthink = time;
 461         if(this.origin != this.oldorigin)
 462                 ItemUpdate(this);
 463 }
 464
 465 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 466 bool Item_ItemsTime_Allow(GameItem it);
 467 float Item_ItemsTime_UpdateTime(entity e, float t);
 468 void Item_ItemsTime_SetTime(entity e, float t);
 469 void Item_ItemsTime_SetTimesForAllPlayers();
 470
 471 void Item_Respawn(entity this)
 472 {
 473         Item_Show(this, 1);
 474         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 475         setorigin(this, this.origin);
 476
 477         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 478         {
 479                 float t = Item_ItemsTime_UpdateTime(this, 0);
 480                 Item_ItemsTime_SetTime(this, t);
 481                 Item_ItemsTime_SetTimesForAllPlayers();
 482         }
 483
 484         setthink(this, Item_Think);
 485         this.nextthink = time;
 486
 487         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 488         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 489 }
 490
 491 void Item_RespawnCountdown(entity this)
 492 {
 493         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 494         {
 495                 if(this.waypointsprite_attached)
 496                         WaypointSprite_Kill(this.waypointsprite_attached);
 497                 Item_Respawn(this);
 498         }
 499         else
 500         {
 501                 this.nextthink = time + 1;
 502                 this.item_respawncounter += 1;
 503                 if(this.item_respawncounter == 1)
 504                 {
 505                         do {
 506                                 {
 507                                         entity wi = Weapons_from(this.weapon);
 508                                         if (wi != WEP_Null) {
 509                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 510                                                 wp.wp_extra = wi.m_id;
 511                                                 break;
 512                                         }
 513                                 }
 514                                 {
 515                                         entity ii = this.itemdef;
 516                                         if (ii != NULL) {
 517                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 518                                                 wp.wp_extra = ii.m_id;
 519                                                 break;
 520                                         }
 521                                 }
 522                         } while (0);
 523                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 524             if(this.waypointsprite_attached)
 525             {
 526                 GameItem def = this.itemdef;
 527                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 528                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 529                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 530             }
 531                 }
 532
 533                 if(this.waypointsprite_attached)
 534                 {
 535                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 536                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 537                                 {
 538                                         msg_entity = it;
 539                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 540                                 }
 541                         });
 542
 543                         WaypointSprite_Ping(this.waypointsprite_attached);
 544                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 545                 }
 546         }
 547 }
 548
 549 void Item_RespawnThink(entity this)
 550 {
 551         this.nextthink = time;
 552         if(this.origin != this.oldorigin)
 553                 ItemUpdate(this);
 554
 555         if(time >= this.wait)
 556                 Item_Respawn(this);
 557 }
 558
 559 void Item_ScheduleRespawnIn(entity e, float t)
 560 {
 561         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 562         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 563         {
 564                 setthink(e, Item_RespawnCountdown);
 565                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 566                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 567                 e.item_respawncounter = 0;
 568                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 569                 {
 570                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 571                         Item_ItemsTime_SetTime(e, t);
 572                         Item_ItemsTime_SetTimesForAllPlayers();
 573                 }
 574         }
 575         else
 576         {
 577                 setthink(e, Item_RespawnThink);
 578                 e.nextthink = time;
 579                 e.scheduledrespawntime = time + t;
 580                 e.wait = time + t;
 581
 582                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 583                 {
 584                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 585                         Item_ItemsTime_SetTime(e, t);
 586                         Item_ItemsTime_SetTimesForAllPlayers();
 587                 }
 588         }
 589 }
 590
 591 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 592 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 593 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 594
 595 /// Adjust respawn time according to the number of players.
 596 float adjust_respawntime(float normal_respawntime) {
 597         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 598         float o = autocvar_g_pickup_respawntime_scaling_offset;
 599         float l = autocvar_g_pickup_respawntime_scaling_linear;
 600
 601         if (r == 0 && l == 1) {
 602                 return normal_respawntime;
 603         }
 604
 605         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 606         TeamBalance_GetTeamCounts(balance, NULL);
 607         int players = 0;
 608         for (int i = 1; i <= NUM_TEAMS; ++i)
 609         {
 610                 if (TeamBalance_IsTeamAllowed(balance, i))
 611                 {
 612                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 613                 }
 614         }
 615         TeamBalance_Destroy(balance);
 616
 617         if (players >= 2) {
 618                 return normal_respawntime * (r / (players + o) + l);
 619         } else {
 620                 return normal_respawntime;
 621         }
 622 }
 623
 624 void Item_ScheduleRespawn(entity e)
 625 {
 626         if(e.respawntime > 0)
 627         {
 628                 Item_Show(e, 0);
 629
 630                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 631                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 632
 633                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 634                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 635                 Item_ScheduleRespawnIn(e, respawn_in);
 636         }
 637         else // if respawntime is -1, this item does not respawn
 638                 Item_Show(e, -1);
 639 }
 640
 641 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 642         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 643
 644 void Item_ScheduleInitialRespawn(entity e)
 645 {
 646         Item_Show(e, 0);
 647
 648         float spawn_in;
 649         if (autocvar_g_pickup_respawntime_initial_random == 0)
 650         {
 651                 // range: respawntime .. respawntime + respawntimejitter
 652                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 653         }
 654         else
 655         {
 656                 float rnd;
 657                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 658                 {
 659                         static float shared_random = 0;
 660                         // NOTE this code works only if items are scheduled at the same time (normal case)
 661                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 662                         if (!shared_random || floor(time) > shared_random)
 663                                 shared_random = floor(time) + random();
 664                         rnd = shared_random - floor(time);
 665                 }
 666                 else
 667                         rnd = random();
 668
 669                 // range:
 670                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 671                 // else: 0 .. ITEM_RESPAWN_TICKS
 672                 // this is to prevent powerups spawning unexpectedly without waypoints
 673                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 674         }
 675
 676         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 677 }
 678
 679 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 680         entity ammo_entity)
 681 {
 682         if (num_weapons == 0)
 683         {
 684                 return;
 685         }
 686         int num_potential_weapons = tokenize_console(weapon_names);
 687         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 688         {
 689                 RandomSelection_Init();
 690                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 691                         ++weapon_index)
 692                 {
 693                         string weapon = argv(weapon_index);
 694                         FOREACH(Weapons, it != WEP_Null,
 695                         {
 696                                 // Finding a weapon which player doesn't have.
 697                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 698                                 {
 699                                         RandomSelection_AddEnt(it, 1, 1);
 700                                         break;
 701                                 }
 702                         });
 703                 }
 704                 if (RandomSelection_chosen_ent == NULL)
 705                 {
 706                         return;
 707                 }
 708                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 709                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 710                 {
 711                         continue;
 712                 }
 713                 if (GetResource(receiver,
 714                         RandomSelection_chosen_ent.ammo_type) != 0)
 715                 {
 716                         continue;
 717                 }
 718                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 719                         GetResource(ammo_entity,
 720                         RandomSelection_chosen_ent.ammo_type));
 721         }
 722 }
 723
 724 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
 725 {
 726         float amount = GetResource(item, res_type);
 727         if (amount == 0)
 728         {
 729                 return false;
 730         }
 731         float player_amount = GetResource(player, res_type);
 732         if (item.spawnshieldtime)
 733         {
 734                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 735                         return false;
 736         }
 737         else if (g_weapon_stay == 2)
 738         {
 739                 ammomax = min(amount, ammomax);
 740                 if(player_amount >= ammomax)
 741                         return false;
 742         }
 743         else
 744                 return false;
 745         if (amount < 0)
 746                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 747         else
 748                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 749         return true;
 750 }
 751
 752 bool Item_GiveTo(entity item, entity player)
 753 {
 754         // if nothing happens to player, just return without taking the item
 755         int _switchweapon = 0;
 756         // in case the player has autoswitch enabled do the following:
 757         // if the player is using their best weapon before items are given, they
 758         // probably want to switch to an even better weapon after items are given
 759
 760         if(CS(player).autoswitch)
 761         {
 762                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 763                 {
 764                         .entity weaponentity = weaponentities[slot];
 765                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 766                         {
 767                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 768                                         _switchweapon |= BIT(slot);
 769
 770                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 771                                         _switchweapon |= BIT(slot);
 772                         }
 773                 }
 774         }
 775         bool pickedup = false;
 776         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
 777         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
 778         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
 779         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
 780         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
 781         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
 782         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
 783         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
 784         if (item.itemdef.instanceOfWeaponPickup)
 785         {
 786                 WepSet w;
 787                 w = STAT(WEAPONS, item);
 788                 w &= ~STAT(WEAPONS, player);
 789
 790                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 791                 {
 792                         pickedup = true;
 793                         FOREACH(Weapons, it != WEP_Null, {
 794                                 if(w & (it.m_wepset))
 795                                 {
 796                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 797                                         {
 798                                                 .entity weaponentity = weaponentities[slot];
 799                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 800                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 801                                         }
 802                                         W_GiveWeapon(player, it.m_id);
 803                                 }
 804                         });
 805                 }
 806         }
 807
 808         if (item.itemdef.instanceOfPowerup)
 809         {
 810                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 811                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 812                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 813                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 814         }
 815
 816         int its;
 817         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 818         {
 819                 pickedup = true;
 820                 player.items |= its;
 821                 // TODO: we probably want to show a message in the console, but not this one!
 822                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 823         }
 824
 825         if (item.strength_finished)
 826         {
 827                 pickedup = true;
 828                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 829         }
 830         if (item.invincible_finished)
 831         {
 832                 pickedup = true;
 833                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 834         }
 835         if (item.superweapons_finished)
 836         {
 837                 pickedup = true;
 838                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 839         }
 840
 841         // always eat teamed entities
 842         if(item.team)
 843                 pickedup = true;
 844
 845         if (!pickedup)
 846                 return false;
 847
 848         // crude hack to enforce switching weapons
 849         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
 850         {
 851                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 852                 {
 853                         .entity weaponentity = weaponentities[slot];
 854                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 855                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 856                 }
 857                 return true;
 858         }
 859
 860         if(_switchweapon)
 861         {
 862                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 863                 {
 864                         .entity weaponentity = weaponentities[slot];
 865                         if(_switchweapon & BIT(slot))
 866                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 867                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 868                 }
 869         }
 870
 871         return true;
 872 }
 873
 874 void Item_Touch(entity this, entity toucher)
 875 {
 876         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 877         if (Item_IsLoot(this))
 878         {
 879                 if (ITEM_TOUCH_NEEDKILL())
 880                 {
 881                         delete(this);
 882                         return;
 883                 }
 884         }
 885
 886         if(!(toucher.flags & FL_PICKUPITEMS)
 887         || STAT(FROZEN, toucher)
 888         || IS_DEAD(toucher)
 889         || (this.solid != SOLID_TRIGGER)
 890         || (this.owner == toucher)
 891         || (time < this.item_spawnshieldtime)
 892         ) { return; }
 893
 894         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 895         {
 896                 case MUT_ITEMTOUCH_RETURN: { return; }
 897                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 898         }
 899
 900         toucher = M_ARGV(1, entity);
 901
 902         if (Item_IsExpiring(this))
 903         {
 904                 this.strength_finished = max(0, this.strength_finished - time);
 905                 this.invincible_finished = max(0, this.invincible_finished - time);
 906                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 907         }
 908         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 909         if (!gave)
 910         {
 911                 if (Item_IsExpiring(this))
 912                 {
 913                         // undo what we did above
 914                         this.strength_finished += time;
 915                         this.invincible_finished += time;
 916                         this.superweapons_finished += time;
 917                 }
 918                 return;
 919         }
 920
 921 LABEL(pickup)
 922
 923         if(this.target && this.target != "" && this.target != "###item###") // defrag support
 924                 SUB_UseTargets(this, toucher, NULL);
 925
 926         STAT(LAST_PICKUP, toucher) = time;
 927
 928         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 929         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 930
 931         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 932         if (wasfreed(this))
 933         {
 934                 return;
 935         }
 936
 937         if (Item_IsLoot(this))
 938         {
 939                 delete(this);
 940                 return;
 941         }
 942         if (!this.spawnshieldtime)
 943         {
 944                 return;
 945         }
 946         entity e;
 947         if (this.team)
 948         {
 949                 RandomSelection_Init();
 950                 IL_EACH(g_items, it.team == this.team,
 951                 {
 952                         if (it.itemdef) // is a registered item
 953                         {
 954                                 Item_Show(it, -1);
 955                                 it.scheduledrespawntime = 0;
 956                                 RandomSelection_AddEnt(it, it.cnt, 0);
 957                         }
 958                 });
 959                 e = RandomSelection_chosen_ent;
 960                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 961         }
 962         else
 963                 e = this;
 964         Item_ScheduleRespawn(e);
 965 }
 966
 967 void Item_Reset(entity this)
 968 {
 969         Item_Show(this, !this.state);
 970         setorigin(this, this.origin);
 971
 972         if (Item_IsLoot(this))
 973         {
 974                 return;
 975         }
 976         setthink(this, Item_Think);
 977         this.nextthink = time;
 978         if (this.waypointsprite_attached)
 979         {
 980                 WaypointSprite_Kill(this.waypointsprite_attached);
 981         }
 982         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 983         {
 984                 Item_ScheduleInitialRespawn(this);
 985         }
 986 }
 987
 988 void Item_FindTeam(entity this)
 989 {
 990         entity e;
 991
 992         if(this.effects & EF_NODRAW)
 993         {
 994                 // marker for item team search
 995                 LOG_TRACE("Initializing item team ", ftos(this.team));
 996                 RandomSelection_Init();
 997                 IL_EACH(g_items, it.team == this.team,
 998                 {
 999                         if(it.itemdef) // is a registered item
1000                                 RandomSelection_AddEnt(it, it.cnt, 0);
1001                 });
1002
1003                 e = RandomSelection_chosen_ent;
1004                 if (!e)
1005                         return;
1006
1007                 IL_EACH(g_items, it.team == this.team,
1008                 {
1009                         if(it.itemdef) // is a registered item
1010                         {
1011                                 if(it != e)
1012                                 {
1013                                         // make it non-spawned
1014                                         Item_Show(it, -1);
1015                                         it.state = 1; // state 1 = initially hidden item, apparently
1016                                 }
1017                                 else
1018                                         Item_Reset(it);
1019                                 it.effects &= ~EF_NODRAW;
1020                         }
1021                 });
1022         }
1023 }
1024
1025 // Savage: used for item garbage-collection
1026 void RemoveItem(entity this)
1027 {
1028         if(wasfreed(this) || !this) { return; }
1029         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1030         delete(this);
1031 }
1032
1033 // pickup evaluation functions
1034 // these functions decide how desirable an item is to the bots
1035
1036 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1037
1038 float weapon_pickupevalfunc(entity player, entity item)
1039 {
1040         // See if I have it already
1041         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1042         {
1043                 // If I can pick it up
1044                 if(!item.spawnshieldtime)
1045                         return 0;
1046                 return ammo_pickupevalfunc(player, item);
1047         }
1048
1049         // reduce weapon value if bot already got a good arsenal
1050         float c = 1;
1051         int weapons_value = 0;
1052         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1053                 weapons_value += it.bot_pickupbasevalue;
1054         });
1055         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1056
1057         return item.bot_pickupbasevalue * c;
1058 }
1059
1060 float ammo_pickupevalfunc(entity player, entity item)
1061 {
1062         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1063         entity wpn = NULL;
1064         float c = 0;
1065         float rating = 0;
1066
1067         // Detect needed ammo
1068         if(item.itemdef.instanceOfWeaponPickup)
1069         {
1070                 entity ammo = NULL;
1071                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1072                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1073                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1074                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1075                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1076                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1077
1078                 if(!ammo)
1079                         return 0;
1080                 wpn = item;
1081                 rating = ammo.m_botvalue;
1082         }
1083         else
1084         {
1085                 FOREACH(Weapons, it != WEP_Null, {
1086                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1087                                 continue;
1088
1089                         switch(it.ammo_type)
1090                         {
1091                                 case RES_SHELLS:  need_shells  = true; break;
1092                                 case RES_BULLETS: need_nails   = true; break;
1093                                 case RES_ROCKETS: need_rockets = true; break;
1094                                 case RES_CELLS:   need_cells   = true; break;
1095                                 case RES_PLASMA:  need_plasma  = true; break;
1096                                 case RES_FUEL:    need_fuel    = true; break;
1097                         }
1098                 });
1099                 rating = item.bot_pickupbasevalue;
1100         }
1101
1102         float noammorating = 0.5;
1103
1104         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1105                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1106
1107         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1108                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1109
1110         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1111                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1112
1113         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1114                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1115
1116         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1117                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1118
1119         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1120                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1121
1122         rating *= min(c, 2);
1123         if(wpn)
1124                 rating += wpn.bot_pickupbasevalue * 0.1;
1125         return rating;
1126 }
1127
1128 float healtharmor_pickupevalfunc(entity player, entity item)
1129 {
1130         float c = 0;
1131         float rating = item.bot_pickupbasevalue;
1132
1133         float itemarmor = GetResource(item, RES_ARMOR);
1134         float itemhealth = GetResource(item, RES_HEALTH);
1135
1136         if(item.item_group)
1137         {
1138                 itemarmor *= min(4, item.item_group_count);
1139                 itemhealth *= min(4, item.item_group_count);
1140         }
1141
1142         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1143                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1144
1145         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1146                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1147
1148         rating *= min(2, c);
1149         return rating;
1150 }
1151
1152 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1153 {
1154         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1155                 RemoveItem(this);
1156 }
1157
1158 void item_use(entity this, entity actor, entity trigger)
1159 {
1160         // use the touch function to handle collection
1161         gettouch(this)(this, actor);
1162 }
1163
1164 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1165 {
1166         string itemname = def.m_name;
1167         Model itemmodel = def.m_model;
1168         Sound pickupsound = def.m_sound;
1169         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1170         float pickupbasevalue = def.m_botvalue;
1171         int itemflags = def.m_itemflags;
1172
1173         startitem_failed = false;
1174
1175         this.item_model_ent = itemmodel;
1176         this.item_pickupsound_ent = pickupsound;
1177
1178         if(def.m_iteminit)
1179                 def.m_iteminit(def, this);
1180
1181         if(!this.respawntime) // both need to be set
1182         {
1183                 this.respawntime = defaultrespawntime;
1184                 this.respawntimejitter = defaultrespawntimejitter;
1185         }
1186
1187         if(!this.pickup_anyway && def.m_pickupanyway)
1188                 this.pickup_anyway = def.m_pickupanyway();
1189
1190         int itemid = def.m_itemid;
1191         this.items = itemid;
1192         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1193         this.weapon = weaponid;
1194
1195         if(!this.fade_end)
1196         {
1197                 this.fade_start = autocvar_g_items_mindist;
1198                 this.fade_end = autocvar_g_items_maxdist;
1199         }
1200
1201         if(weaponid)
1202                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1203
1204         this.flags = FL_ITEM | itemflags;
1205         IL_PUSH(g_items, this);
1206
1207         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1208         {
1209                 startitem_failed = true;
1210                 delete(this);
1211                 return;
1212         }
1213
1214         precache_model(this.model);
1215         precache_sound(this.item_pickupsound);
1216
1217         if (Item_IsLoot(this))
1218         {
1219                 this.reset = SUB_Remove;
1220                 set_movetype(this, MOVETYPE_TOSS);
1221
1222                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1223                 setthink(this, RemoveItem);
1224                 this.nextthink = time + 20;
1225
1226                 this.takedamage = DAMAGE_YES;
1227                 this.event_damage = Item_Damage;
1228
1229                 if (Item_IsExpiring(this))
1230                 {
1231                         // if item is worthless after a timer, have it expire then
1232                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1233                 }
1234
1235                 // don't drop if in a NODROP zone (such as lava)
1236                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1237                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1238                 {
1239                         startitem_failed = true;
1240                         delete(this);
1241                         return;
1242                 }
1243         }
1244         else
1245         {
1246                 if(!have_pickup_item(this))
1247                 {
1248                         startitem_failed = true;
1249                         delete(this);
1250                         return;
1251                 }
1252
1253                 if(this.angles != '0 0 0')
1254                         this.SendFlags |= ISF_ANGLES;
1255
1256                 this.reset = Item_Reset;
1257                 // it's a level item
1258                 if(this.spawnflags & 1)
1259                         this.noalign = 1;
1260                 if (this.noalign > 0)
1261                         set_movetype(this, MOVETYPE_NONE);
1262                 else
1263                         set_movetype(this, MOVETYPE_TOSS);
1264                 // do item filtering according to game mode and other things
1265                 if (this.noalign <= 0)
1266                 {
1267                         // first nudge it off the floor a little bit to avoid math errors
1268                         setorigin(this, this.origin + '0 0 1');
1269                         // set item size before we spawn a spawnfunc_waypoint
1270                         setsize(this, def.m_mins, def.m_maxs);
1271                         this.SendFlags |= ISF_SIZE;
1272                         // note droptofloor returns false if stuck/or would fall too far
1273                         if (!this.noalign)
1274                                 droptofloor(this);
1275                         waypoint_spawnforitem(this);
1276                 }
1277
1278                 /*
1279                  * can't do it that way, as it would break maps
1280                  * TODO make a target_give like entity another way, that perhaps has
1281                  * the weapon name in a key
1282                 if(this.targetname)
1283                 {
1284                         // target_give not yet supported; maybe later
1285                         print("removed targeted ", this.classname, "\n");
1286                         startitem_failed = true;
1287                         delete(this);
1288                         return;
1289                 }
1290                 */
1291
1292                 if(this.targetname != "" && (this.spawnflags & 16))
1293                         this.use = item_use;
1294
1295                 if(autocvar_spawn_debug >= 2)
1296                 {
1297             // why not flags & fl_item?
1298                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1299                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1300                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1301                 error("Mapper sucks.");
1302             });
1303                         this.is_item = true;
1304                 }
1305
1306                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1307
1308                 if (   def.instanceOfPowerup
1309                         || def.instanceOfWeaponPickup
1310                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1311                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1312                         || (itemid & (IT_KEY1 | IT_KEY2))
1313                 )
1314                 {
1315                         if(!this.target || this.target == "")
1316                                 this.target = "###item###"; // for finding the nearest item using findnearest
1317                 }
1318
1319                 Item_ItemsTime_SetTime(this, 0);
1320         }
1321
1322         this.bot_pickup = true;
1323         this.bot_pickupevalfunc = pickupevalfunc;
1324         this.bot_pickupbasevalue = pickupbasevalue;
1325         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1326         this.netname = itemname;
1327         settouch(this, Item_Touch);
1328         setmodel(this, MDL_Null); // precision set below
1329         //this.effects |= EF_LOWPRECISION;
1330
1331         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1332
1333         this.SendFlags |= ISF_SIZE;
1334
1335         if (!(this.spawnflags & 1024)) {
1336                 if(def.instanceOfPowerup)
1337                         this.ItemStatus |= ITS_ANIMATE1;
1338
1339                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1340                         this.ItemStatus |= ITS_ANIMATE2;
1341         }
1342
1343         if(Item_IsLoot(this))
1344                 this.gravity = 1;
1345
1346         if(def.instanceOfWeaponPickup)
1347         {
1348                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1349                         this.colormap = 1024; // color shirt=0 pants=0 grey
1350                 if (!(this.spawnflags & 1024))
1351                         this.ItemStatus |= ITS_ANIMATE1;
1352                 this.SendFlags |= ISF_COLORMAP;
1353         }
1354
1355         this.state = 0;
1356         if(this.team)
1357         {
1358                 if(!this.cnt)
1359                         this.cnt = 1; // item probability weight
1360
1361                 this.effects |= EF_NODRAW; // marker for item team search
1362                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1363         }
1364         else
1365                 Item_Reset(this);
1366
1367         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1368
1369         // call this hook after everything else has been done
1370         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1371         {
1372                 startitem_failed = true;
1373                 delete(this);
1374                 return;
1375         }
1376
1377         setItemGroup(this);
1378 }
1379
1380 void StartItem(entity this, GameItem def)
1381 {
1382     def = def.m_spawnfunc_hookreplace(def, this);
1383     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1384     {
1385         delete(this);
1386         return;
1387     }
1388     this.classname = def.m_canonical_spawnfunc;
1389     _StartItem(
1390         this,
1391         this.itemdef = def,
1392         def.m_respawntime(), // defaultrespawntime
1393         def.m_respawntimejitter() // defaultrespawntimejitter
1394         );
1395 }
1396
1397 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1398 int group_count = 1;
1399
1400 void setItemGroup(entity this)
1401 {
1402         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1403                 return;
1404
1405         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1406         {
1407                 if(!this.item_group)
1408                 {
1409                         if(!it.item_group)
1410                         {
1411                                 it.item_group = group_count;
1412                                 group_count++;
1413                         }
1414                         this.item_group = it.item_group;
1415                 }
1416                 else // spawning item is already part of a item_group X
1417                 {
1418                         if(!it.item_group)
1419                                 it.item_group = this.item_group;
1420                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1421                         {
1422                                 int grY = it.item_group;
1423                                 // move all items of item_group Y to item_group X
1424                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1425                                 {
1426                                         if(it.item_group == grY)
1427                                                 it.item_group = this.item_group;
1428                                 });
1429                         }
1430                 }
1431         });
1432 }
1433
1434 void setItemGroupCount()
1435 {
1436         for (int k = 1; k <= group_count; k++)
1437         {
1438                 int count = 0;
1439                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1440                 if (count)
1441                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1442         }
1443 }
1444
1445 void target_items_use(entity this, entity actor, entity trigger)
1446 {
1447         if(Item_IsLoot(actor))
1448         {
1449                 EXACTTRIGGER_TOUCH(this, trigger);
1450                 delete(actor);
1451                 return;
1452         }
1453
1454         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1455                 return;
1456
1457         if(trigger.solid == SOLID_TRIGGER)
1458         {
1459                 EXACTTRIGGER_TOUCH(this, trigger);
1460         }
1461
1462         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1463         {
1464                 delete(it);
1465         });
1466
1467         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1468                 centerprint(actor, this.message);
1469 }
1470
1471 spawnfunc(target_items)
1472 {
1473         this.use = target_items_use;
1474         if(!this.strength_finished)
1475                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1476         if(!this.invincible_finished)
1477                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1478         if(!this.superweapons_finished)
1479                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1480
1481         string str;
1482         int n = tokenize_console(this.netname);
1483         if(argv(0) == "give")
1484         {
1485                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1486         }
1487         else
1488         {
1489                 for(int j = 0; j < n; ++j)
1490                 {
1491                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1492                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1493                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1494                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1495                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1496                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1497                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1498                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1499                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1500                         else
1501                         {
1502                                 FOREACH(Buffs, it != BUFF_Null,
1503                                 {
1504                                         string s = Buff_UndeprecateName(argv(j));
1505                                         if(s == it.netname)
1506                                         {
1507                                                 STAT(BUFFS, this) |= (it.m_itemid);
1508                                                 if(!STAT(BUFF_TIME, this))
1509                                                         STAT(BUFF_TIME, this) = it.m_time(it);
1510                                                 break;
1511                                         }
1512                                 });
1513                                 FOREACH(Weapons, it != WEP_Null, {
1514                                         string s = W_UndeprecateName(argv(j));
1515                                         if(s == it.netname)
1516                                         {
1517                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1518                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1519                                                         it.wr_init(it);
1520                                                 break;
1521                                         }
1522                                 });
1523                         }
1524                 }
1525
1526                 string itemprefix, valueprefix;
1527                 if(this.spawnflags == 0)
1528                 {
1529                         itemprefix = "";
1530                         valueprefix = "";
1531                 }
1532                 else if(this.spawnflags == 1)
1533                 {
1534                         itemprefix = "max ";
1535                         valueprefix = "max ";
1536                 }
1537                 else if(this.spawnflags == 2)
1538                 {
1539                         itemprefix = "min ";
1540                         valueprefix = "min ";
1541                 }
1542                 else if(this.spawnflags == 4)
1543                 {
1544                         itemprefix = "minus ";
1545                         valueprefix = "max ";
1546                 }
1547                 else
1548                 {
1549                         error("invalid spawnflags");
1550                         itemprefix = valueprefix = string_null;
1551                 }
1552
1553                 str = "";
1554                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1555                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1556                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1557                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1558                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1559                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1560                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1561                 float res;
1562                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1563                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1564                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1565                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1566                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1567                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1568                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1569                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1570                 // HACK: buffs share a single timer, so we need to include enabled buffs AFTER disabled ones to avoid loss
1571                 FOREACH(Buffs, it != BUFF_Null && !(STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1572                 FOREACH(Buffs, it != BUFF_Null && (STAT(BUFFS, this) & it.m_itemid), str = sprintf("%s %s%d %s", str, valueprefix, max(0, STAT(BUFF_TIME, this)), it.netname));
1573                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1574         }
1575         this.netname = strzone(str);
1576
1577         n = tokenize_console(this.netname);
1578         for(int j = 0; j < n; ++j)
1579         {
1580                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1581                         it.wr_init(it);
1582                         break;
1583                 });
1584         }
1585 }
1586
1587 float GiveWeapon(entity e, float wpn, float op, float val)
1588 {
1589         WepSet v0, v1;
1590         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1591         v0 = (STAT(WEAPONS, e) & s);
1592         switch(op)
1593         {
1594                 case OP_SET:
1595                         if(val > 0)
1596                                 STAT(WEAPONS, e) |= s;
1597                         else
1598                                 STAT(WEAPONS, e) &= ~s;
1599                         break;
1600                 case OP_MIN:
1601                 case OP_PLUS:
1602                         if(val > 0)
1603                                 STAT(WEAPONS, e) |= s;
1604                         break;
1605                 case OP_MAX:
1606                         if(val <= 0)
1607                                 STAT(WEAPONS, e) &= ~s;
1608                         break;
1609                 case OP_MINUS:
1610                         if(val > 0)
1611                                 STAT(WEAPONS, e) &= ~s;
1612                         break;
1613         }
1614         v1 = (STAT(WEAPONS, e) & s);
1615         return (v0 != v1);
1616 }
1617
1618 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1619 {
1620         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1621         switch (op)
1622         {
1623                 case OP_SET:
1624                         STAT(BUFF_TIME, e) = val;
1625                         break;
1626                 case OP_MIN:
1627                         STAT(BUFF_TIME, e) = max(STAT(BUFF_TIME, e), val);
1628                         break;
1629                 case OP_MAX:
1630                         STAT(BUFF_TIME, e) = min(STAT(BUFF_TIME, e), val);
1631                         break;
1632                 case OP_PLUS:
1633                         STAT(BUFF_TIME, e) += val;
1634                         break;
1635                 case OP_MINUS:
1636                         STAT(BUFF_TIME, e) -= val;
1637                         break;
1638         }
1639         if(STAT(BUFF_TIME, e) <= 0)
1640                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1641         else
1642                 STAT(BUFFS, e) = thebuff.m_itemid; // NOTE: replaces any existing buffs on the player!
1643         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1644         return (had_buff != have_buff);
1645 }
1646
1647 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1648 {
1649         if(v1 == v0)
1650                 return;
1651         if(v1 <= v0 - t)
1652         {
1653                 if(snd_decr != NULL)
1654                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1655         }
1656         else if(v0 >= v0 + t)
1657         {
1658                 if(snd_incr != NULL)
1659                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1660         }
1661 }
1662
1663 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1664 {
1665         if(v0 < v1)
1666                 e.(rotfield) = max(e.(rotfield), time + rottime);
1667         else if(v0 > v1)
1668                 e.(regenfield) = max(e.(regenfield), time + regentime);
1669 }
1670 bool GiveResourceValue(entity e, int res_type, int op, int val)
1671 {
1672         int v0 = GetResource(e, res_type);
1673         float new_val = 0;
1674         switch (op)
1675         {
1676                 // min 100 cells = at least 100 cells
1677                 case OP_SET: new_val = val; break;
1678                 case OP_MIN: new_val = max(v0, val); break;
1679                 case OP_MAX: new_val = min(v0, val); break;
1680                 case OP_PLUS: new_val = v0 + val; break;
1681                 case OP_MINUS: new_val = v0 - val; break;
1682                 default: return false;
1683         }
1684
1685         return SetResourceExplicit(e, res_type, new_val);
1686 }
1687
1688 float GiveItems(entity e, float beginarg, float endarg)
1689 {
1690         float got, i, val, op;
1691         string cmd;
1692
1693         val = 999;
1694         op = OP_SET;
1695
1696         got = 0;
1697
1698         int _switchweapon = 0;
1699
1700         if(CS(e).autoswitch)
1701         {
1702                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1703                 {
1704                         .entity weaponentity = weaponentities[slot];
1705                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1706                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1707                                 _switchweapon |= BIT(slot);
1708                 }
1709         }
1710
1711         e.strength_finished = max(0, e.strength_finished - time);
1712         e.invincible_finished = max(0, e.invincible_finished - time);
1713         e.superweapons_finished = max(0, e.superweapons_finished - time);
1714         STAT(BUFF_TIME, e) = max(0, STAT(BUFF_TIME, e) - time);
1715
1716         PREGIVE(e, items);
1717         PREGIVE_WEAPONS(e);
1718         PREGIVE(e, strength_finished);
1719         PREGIVE(e, invincible_finished);
1720         PREGIVE(e, superweapons_finished);
1721         PREGIVE_RESOURCE(e, RES_BULLETS);
1722         PREGIVE_RESOURCE(e, RES_CELLS);
1723         PREGIVE_RESOURCE(e, RES_PLASMA);
1724         PREGIVE_RESOURCE(e, RES_SHELLS);
1725         PREGIVE_RESOURCE(e, RES_ROCKETS);
1726         PREGIVE_RESOURCE(e, RES_FUEL);
1727         PREGIVE_RESOURCE(e, RES_ARMOR);
1728         PREGIVE_RESOURCE(e, RES_HEALTH);
1729
1730         for(i = beginarg; i < endarg; ++i)
1731         {
1732                 cmd = argv(i);
1733
1734                 if(cmd == "0" || stof(cmd))
1735                 {
1736                         val = stof(cmd);
1737                         continue;
1738                 }
1739                 switch(cmd)
1740                 {
1741                         case "no":
1742                                 op = OP_MAX;
1743                                 val = 0;
1744                                 continue;
1745                         case "max":
1746                                 op = OP_MAX;
1747                                 continue;
1748                         case "min":
1749                                 op = OP_MIN;
1750                                 continue;
1751                         case "plus":
1752                                 op = OP_PLUS;
1753                                 continue;
1754                         case "minus":
1755                                 op = OP_MINUS;
1756                                 continue;
1757                         case "ALL":
1758                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1759                                 got += GiveValue(e, strength_finished, op, val);
1760                                 got += GiveValue(e, invincible_finished, op, val);
1761                                 got += GiveValue(e, superweapons_finished, op, val);
1762                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                         case "all":
1764                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1765                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1766                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1767                         case "allweapons":
1768                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1769                         //case "allbuffs": // all buffs makes a player god, do not want!
1770                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1771                         case "allammo":
1772                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1773                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1774                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1775                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1776                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1777                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1778                                 break;
1779                         case "unlimited_ammo":
1780                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1781                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1782                                 break;
1783                         case "unlimited_weapon_ammo":
1784                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1785                                 break;
1786                         case "unlimited_superweapons":
1787                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1788                                 break;
1789                         case "jetpack":
1790                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1791                                 break;
1792                         case "fuel_regen":
1793                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1794                                 break;
1795                         case "strength":
1796                                 got += GiveValue(e, strength_finished, op, val);
1797                                 break;
1798                         case "invincible":
1799                                 got += GiveValue(e, invincible_finished, op, val);
1800                                 break;
1801                         case "superweapons":
1802                                 got += GiveValue(e, superweapons_finished, op, val);
1803                                 break;
1804                         case "cells":
1805                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1806                                 break;
1807                         case "plasma":
1808                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1809                                 break;
1810                         case "shells":
1811                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1812                                 break;
1813                         case "nails":
1814                         case "bullets":
1815                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1816                                 break;
1817                         case "rockets":
1818                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1819                                 break;
1820                         case "health":
1821                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1822                                 break;
1823                         case "armor":
1824                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1825                                 break;
1826                         case "fuel":
1827                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1828                                 break;
1829                         default:
1830                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.netname,
1831                                 {
1832                                         got += GiveBuff(e, it, op, val);
1833                                         break;
1834                                 });
1835                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1836                     got += GiveWeapon(e, it.m_id, op, val);
1837                     break;
1838                                 });
1839                                 break;
1840                 }
1841                 val = 999;
1842                 op = OP_SET;
1843         }
1844
1845         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1847         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1848         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1849         FOREACH(Weapons, it != WEP_Null, {
1850                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1851                 if(!(save_weapons & (it.m_wepset)))
1852                         if(STAT(WEAPONS, e) & (it.m_wepset))
1853                                 it.wr_init(it);
1854         });
1855         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1856         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1857         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1858         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1864         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1865         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1866
1867         if(e.superweapons_finished <= 0)
1868                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1869                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1870
1871         if(e.strength_finished <= 0)
1872                 e.strength_finished = 0;
1873         else
1874                 e.strength_finished += time;
1875         if(e.invincible_finished <= 0)
1876                 e.invincible_finished = 0;
1877         else
1878                 e.invincible_finished += time;
1879         if(e.superweapons_finished <= 0)
1880                 e.superweapons_finished = 0;
1881         else
1882                 e.superweapons_finished += time;
1883         if(STAT(BUFF_TIME, e) <= 0)
1884                 STAT(BUFF_TIME, e) = 0;
1885         else
1886                 STAT(BUFF_TIME, e) += time;
1887
1888         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1889         {
1890                 .entity weaponentity = weaponentities[slot];
1891                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1892                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1893                         _switchweapon |= BIT(slot);
1894         }
1895
1896         if(_switchweapon)
1897         {
1898                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1899                 {
1900                         .entity weaponentity = weaponentities[slot];
1901                         if(_switchweapon & BIT(slot))
1902                         {
1903                                 Weapon wep = w_getbestweapon(e, weaponentity);
1904                                 if(wep != e.(weaponentity).m_switchweapon)
1905                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1906                         }
1907                 }
1908         }
1909
1910         return got;
1911 }
1912 #endif