qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         if(this.mdl)
 152                 strunzone(this.mdl);
 153 }
 154
 155 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 156 {
 157     int sf = ReadByte();
 158
 159     if(sf & ISF_LOCATION)
 160     {
 161         this.origin_x = ReadCoord();
 162         this.origin_y = ReadCoord();
 163         this.origin_z = ReadCoord();
 164         setorigin(this, this.origin);
 165         this.oldorigin = this.origin;
 166     }
 167
 168     if(sf & ISF_ANGLES)
 169     {
 170         this.angles_x = ReadAngle();
 171         this.angles_y = ReadAngle();
 172         this.angles_z = ReadAngle();
 173     }
 174
 175     if(sf & ISF_SIZE)
 176     {
 177         float use_bigsize = ReadByte();
 178         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 179     }
 180
 181     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 182     {
 183         this.ItemStatus = ReadByte();
 184
 185         Item_SetAlpha(this);
 186
 187         if(autocvar_cl_fullbright_items)
 188             if(this.ItemStatus & ITS_ALLOWFB)
 189                 this.effects |= EF_FULLBRIGHT;
 190
 191         if(this.ItemStatus & ITS_GLOW)
 192         {
 193             if(this.ItemStatus & ITS_AVAILABLE)
 194                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 195             else
 196                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 197         }
 198     }
 199
 200     if(sf & ISF_MODEL)
 201     {
 202         this.drawmask  = MASK_NORMAL;
 203                 set_movetype(this, MOVETYPE_TOSS);
 204                 if (isnew) IL_PUSH(g_drawables, this);
 205         this.draw       = ItemDraw;
 206         this.solid = SOLID_TRIGGER;
 207         //this.flags |= FL_ITEM;
 208
 209         bool use_bigsize = ReadByte();
 210
 211         this.fade_end = ReadShort();
 212         this.fade_start = ReadShort();
 213         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 214                 setpredraw(this, Item_PreDraw);
 215
 216         if(this.mdl)
 217             strunzone(this.mdl);
 218
 219         this.mdl = "";
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 229                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 230             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 231                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 232             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 233                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 234             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 235                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 236             else
 237             {
 238                 this.item_simple = false;
 239                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 240             }
 241         }
 242
 243         if(!this.item_simple)
 244             this.mdl = strzone(_fn);
 245
 246
 247         if(this.mdl == "")
 248             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 249
 250         precache_model(this.mdl);
 251         _setmodel(this, this.mdl);
 252
 253         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 254     }
 255
 256     if(sf & ISF_COLORMAP)
 257     {
 258         this.colormap = ReadShort();
 259         this.item_glowmod_x = ReadByte() / 255.0;
 260         this.item_glowmod_y = ReadByte() / 255.0;
 261         this.item_glowmod_z = ReadByte() / 255.0;
 262     }
 263
 264     if(sf & ISF_DROP)
 265     {
 266         this.gravity = 1;
 267         this.pushable = true;
 268         //this.angles = '0 0 0';
 269         set_movetype(this, MOVETYPE_TOSS);
 270         this.velocity_x = ReadCoord();
 271         this.velocity_y = ReadCoord();
 272         this.velocity_z = ReadCoord();
 273         setorigin(this, this.oldorigin);
 274
 275         if(!this.move_time)
 276         {
 277             this.move_time = time;
 278             this.spawntime = time;
 279         }
 280         else
 281             this.move_time = max(this.move_time, time);
 282     }
 283
 284     if(autocvar_cl_animate_items)
 285     {
 286         if(this.ItemStatus & ITS_ANIMATE1)
 287             this.avelocity = '0 180 0';
 288
 289         if(this.ItemStatus & ITS_ANIMATE2)
 290             this.avelocity = '0 -90 0';
 291     }
 292
 293     this.entremove = ItemRemove;
 294
 295     return true;
 296 }
 297
 298 #endif
 299
 300 #ifdef SVQC
 301 bool ItemSend(entity this, entity to, int sf)
 302 {
 303         if(this.gravity)
 304                 sf |= ISF_DROP;
 305         else
 306                 sf &= ~ISF_DROP;
 307
 308         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 309         WriteByte(MSG_ENTITY, sf);
 310
 311         //WriteByte(MSG_ENTITY, this.cnt);
 312         if(sf & ISF_LOCATION)
 313         {
 314                 WriteCoord(MSG_ENTITY, this.origin.x);
 315                 WriteCoord(MSG_ENTITY, this.origin.y);
 316                 WriteCoord(MSG_ENTITY, this.origin.z);
 317         }
 318
 319         if(sf & ISF_ANGLES)
 320         {
 321                 WriteAngle(MSG_ENTITY, this.angles_x);
 322                 WriteAngle(MSG_ENTITY, this.angles_y);
 323                 WriteAngle(MSG_ENTITY, this.angles_z);
 324         }
 325
 326         if(sf & ISF_SIZE)
 327         {
 328                 Pickup p = this.itemdef;
 329                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 330         }
 331
 332         if(sf & ISF_STATUS)
 333                 WriteByte(MSG_ENTITY, this.ItemStatus);
 334
 335         if(sf & ISF_MODEL)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339                 WriteShort(MSG_ENTITY, this.fade_end);
 340                 WriteShort(MSG_ENTITY, this.fade_start);
 341
 342                 if(this.mdl == "")
 343                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 344
 345                 WriteString(MSG_ENTITY, this.mdl);
 346         }
 347
 348
 349         if(sf & ISF_COLORMAP)
 350         {
 351                 WriteShort(MSG_ENTITY, this.colormap);
 352                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 353         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 354         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 355         }
 356
 357         if(sf & ISF_DROP)
 358         {
 359                 WriteCoord(MSG_ENTITY, this.velocity.x);
 360                 WriteCoord(MSG_ENTITY, this.velocity.y);
 361                 WriteCoord(MSG_ENTITY, this.velocity.z);
 362         }
 363
 364         return true;
 365 }
 366
 367 void ItemUpdate(entity this)
 368 {
 369         this.oldorigin = this.origin;
 370         this.SendFlags |= ISF_LOCATION;
 371 }
 372
 373 void UpdateItemAfterTeleport(entity this)
 374 {
 375         if(getSendEntity(this) == ItemSend)
 376                 ItemUpdate(this);
 377 }
 378
 379 bool have_pickup_item(entity this)
 380 {
 381         if(this.itemdef.instanceOfPowerup)
 382         {
 383                 if(autocvar_g_powerups > 0)
 384                         return true;
 385                 if(autocvar_g_powerups == 0)
 386                         return false;
 387         }
 388         else
 389         {
 390                 if(autocvar_g_pickup_items > 0)
 391                         return true;
 392                 if(autocvar_g_pickup_items == 0)
 393                         return false;
 394                 if(g_weaponarena)
 395                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 396                                 return false;
 397         }
 398         return true;
 399 }
 400
 401 /*
 402 float Item_Customize()
 403 {
 404         if(this.spawnshieldtime)
 405                 return true;
 406         if(this.weapons & ~other.weapons)
 407         {
 408                 this.colormod = '0 0 0';
 409                 this.glowmod = this.colormod;
 410                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 411                 return true;
 412         }
 413         else
 414         {
 415                 if(g_ghost_items)
 416                 {
 417                         this.colormod = stov(autocvar_g_ghost_items_color);
 418                         this.glowmod = this.colormod;
 419                         this.alpha = g_ghost_items;
 420                         return true;
 421                 }
 422                 else
 423                         return false;
 424         }
 425 }
 426 */
 427
 428 void Item_Show (entity e, float mode)
 429 {
 430         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 431         e.ItemStatus &= ~ITS_STAYWEP;
 432         entity def = e.itemdef;
 433         if (mode > 0)
 434         {
 435                 // make the item look normal, and be touchable
 436                 e.model = e.mdl;
 437                 e.solid = SOLID_TRIGGER;
 438                 e.spawnshieldtime = 1;
 439                 e.ItemStatus |= ITS_AVAILABLE;
 440         }
 441         else if (mode < 0)
 442         {
 443                 // hide the item completely
 444                 e.model = string_null;
 445                 e.solid = SOLID_NOT;
 446                 e.spawnshieldtime = 1;
 447                 e.ItemStatus &= ~ITS_AVAILABLE;
 448         }
 449         else
 450         {
 451                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 452                         || e.team // weapon stay isn't supported for teamed weapons
 453                         ;
 454                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 455                 {
 456                         // make the item translucent and not touchable
 457                         e.model = e.mdl;
 458                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 459                         e.effects |= EF_STARDUST;
 460                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 461                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 462                 }
 463                 else
 464                 {
 465                         //setmodel(e, "null");
 466                         e.solid = SOLID_NOT;
 467                         e.colormod = '0 0 0';
 468                         //e.glowmod = e.colormod;
 469                         e.spawnshieldtime = 1;
 470                         e.ItemStatus &= ~ITS_AVAILABLE;
 471                 }
 472         }
 473
 474         if (def.m_glow)
 475                 e.ItemStatus |= ITS_GLOW;
 476
 477         if (autocvar_g_nodepthtestitems)
 478                 e.effects |= EF_NODEPTHTEST;
 479
 480
 481         if (autocvar_g_fullbrightitems)
 482                 e.ItemStatus |= ITS_ALLOWFB;
 483
 484         if (autocvar_sv_simple_items)
 485                 e.ItemStatus |= ITS_ALLOWSI;
 486
 487         // relink entity (because solid may have changed)
 488         setorigin(e, e.origin);
 489         e.SendFlags |= ISF_STATUS;
 490 }
 491
 492 void Item_Think(entity this)
 493 {
 494         this.nextthink = time;
 495         if(this.origin != this.oldorigin)
 496                 ItemUpdate(this);
 497 }
 498
 499 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 500 bool Item_ItemsTime_Allow(GameItem it);
 501 float Item_ItemsTime_UpdateTime(entity e, float t);
 502 void Item_ItemsTime_SetTime(entity e, float t);
 503 void Item_ItemsTime_SetTimesForAllPlayers();
 504
 505 void Item_Respawn (entity this)
 506 {
 507         Item_Show(this, 1);
 508         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 509         setorigin(this, this.origin);
 510
 511     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 512         {
 513                 float t = Item_ItemsTime_UpdateTime(this, 0);
 514                 Item_ItemsTime_SetTime(this, t);
 515                 Item_ItemsTime_SetTimesForAllPlayers();
 516         }
 517
 518         setthink(this, Item_Think);
 519         this.nextthink = time;
 520
 521         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 522         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 523 }
 524
 525 void Item_RespawnCountdown (entity this)
 526 {
 527         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 528         {
 529                 if(this.waypointsprite_attached)
 530                         WaypointSprite_Kill(this.waypointsprite_attached);
 531                 Item_Respawn(this);
 532         }
 533         else
 534         {
 535                 this.nextthink = time + 1;
 536                 this.item_respawncounter += 1;
 537                 if(this.item_respawncounter == 1)
 538                 {
 539                         do {
 540                                 {
 541                                         entity wi = Weapons_from(this.weapon);
 542                                         if (wi != WEP_Null) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 544                                                 wp.wp_extra = wi.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                                 {
 549                                         entity ii = this.itemdef;
 550                                         if (ii != NULL) {
 551                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 552                                                 wp.wp_extra = ii.m_id;
 553                                                 break;
 554                                         }
 555                                 }
 556                         } while (0);
 557                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 558             if(this.waypointsprite_attached)
 559             {
 560                 GameItem def = this.itemdef;
 561                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 562                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 563                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 564             }
 565                 }
 566
 567                 if(this.waypointsprite_attached)
 568                 {
 569                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 570                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 571                                 {
 572                                         msg_entity = it;
 573                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 574                                 }
 575                         });
 576
 577                         WaypointSprite_Ping(this.waypointsprite_attached);
 578                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 579                 }
 580         }
 581 }
 582
 583 void Item_RespawnThink(entity this)
 584 {
 585         this.nextthink = time;
 586         if(this.origin != this.oldorigin)
 587                 ItemUpdate(this);
 588
 589         if(time >= this.wait)
 590                 Item_Respawn(this);
 591 }
 592
 593 void Item_ScheduleRespawnIn(entity e, float t)
 594 {
 595         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 596         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 597         {
 598                 setthink(e, Item_RespawnCountdown);
 599                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 600                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 601                 e.item_respawncounter = 0;
 602                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 603                 {
 604                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 605                         Item_ItemsTime_SetTime(e, t);
 606                         Item_ItemsTime_SetTimesForAllPlayers();
 607                 }
 608         }
 609         else
 610         {
 611                 setthink(e, Item_RespawnThink);
 612                 e.nextthink = time;
 613                 e.scheduledrespawntime = time + t;
 614                 e.wait = time + t;
 615
 616                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 617                 {
 618                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 619                         Item_ItemsTime_SetTime(e, t);
 620                         Item_ItemsTime_SetTimesForAllPlayers();
 621                 }
 622         }
 623 }
 624
 625 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 626 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 627 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 628
 629 float adjust_respawntime(float normal_respawntime) {
 630         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 631         float o = autocvar_g_pickup_respawntime_scaling_offset;
 632         float l = autocvar_g_pickup_respawntime_scaling_linear;
 633
 634         if (r == 0 && l == 1) {
 635                 return normal_respawntime;
 636         }
 637
 638         CheckAllowedTeams(NULL);
 639         GetTeamCounts(NULL);
 640         int players = 0;
 641         if (c1 != -1) players += c1;
 642         if (c2 != -1) players += c2;
 643         if (c3 != -1) players += c3;
 644         if (c4 != -1) players += c4;
 645
 646         if (players >= 2) {
 647                 return normal_respawntime * (r / (players + o) + l);
 648         } else {
 649                 return normal_respawntime;
 650         }
 651 }
 652
 653 void Item_ScheduleRespawn(entity e)
 654 {
 655         if(e.respawntime > 0)
 656         {
 657                 Item_Show(e, 0);
 658
 659                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 660                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 661
 662                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 663                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 664                 Item_ScheduleRespawnIn(e, actual_time);
 665         }
 666         else // if respawntime is -1, this item does not respawn
 667                 Item_Show(e, -1);
 668 }
 669
 670 void Item_ScheduleInitialRespawn(entity e)
 671 {
 672         Item_Show(e, 0);
 673         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 674 }
 675
 676 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 677         entity ammo_entity)
 678 {
 679         if (num_weapons == 0)
 680         {
 681                 return;
 682         }
 683         int num_potential_weapons = tokenize_console(weapon_names);
 684         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 685         {
 686                 RandomSelection_Init();
 687                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 688                         ++weapon_index)
 689                 {
 690                         string weapon = argv(weapon_index);
 691                         FOREACH(Weapons, it != WEP_Null,
 692                         {
 693                                 // Finding a weapon which player doesn't have.
 694                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 695                                 {
 696                                         RandomSelection_AddEnt(it, 1, 1);
 697                                         break;
 698                                 }
 699                         });
 700                 }
 701                 if (RandomSelection_chosen_ent == NULL)
 702                 {
 703                         return;
 704                 }
 705                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 706                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 707                 {
 708                         continue;
 709                 }
 710                 if (GetResourceAmount(receiver,
 711                         RandomSelection_chosen_ent.ammo_type) != 0)
 712                 {
 713                         continue;
 714                 }
 715                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 716                         GetResourceAmount(ammo_entity,
 717                         RandomSelection_chosen_ent.ammo_type));
 718         }
 719 }
 720
 721 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 722 {
 723         float amount = GetResourceAmount(item, resource_type);
 724         if (amount == 0)
 725         {
 726                 return false;
 727         }
 728         float player_amount = GetResourceAmount(player, resource_type);
 729         if (item.spawnshieldtime)
 730         {
 731                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 732                 {
 733                         return false;
 734                 }
 735                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 736                 return true;
 737         }
 738         if (g_weapon_stay != 2)
 739         {
 740                 return false;
 741         }
 742         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 743         return true;
 744 }
 745
 746 float Item_GiveTo(entity item, entity player)
 747 {
 748         float pickedup;
 749
 750         // if nothing happens to player, just return without taking the item
 751         pickedup = false;
 752         int _switchweapon = 0;
 753         // in case the player has autoswitch enabled do the following:
 754         // if the player is using their best weapon before items are given, they
 755         // probably want to switch to an even better weapon after items are given
 756
 757         if(CS(player).autoswitch)
 758         {
 759                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 760                 {
 761                         .entity weaponentity = weaponentities[slot];
 762                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 763                         {
 764                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 765                                         _switchweapon |= BIT(slot);
 766
 767                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 768                                         _switchweapon |= BIT(slot);
 769                         }
 770                 }
 771         }
 772         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 773         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 774         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 775         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 776         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 777         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 778         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 779         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 780         if (item.itemdef.instanceOfWeaponPickup)
 781         {
 782                 WepSet w;
 783                 w = item.weapons;
 784                 w &= ~player.weapons;
 785
 786                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 787                 {
 788                         pickedup = true;
 789                         FOREACH(Weapons, it != WEP_Null, {
 790                                 if(w & (it.m_wepset))
 791                                 {
 792                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 793                                         {
 794                                                 .entity weaponentity = weaponentities[slot];
 795                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 796                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 797                                         }
 798                                         W_GiveWeapon(player, it.m_id);
 799                                 }
 800                         });
 801                 }
 802         }
 803
 804         if (item.itemdef.instanceOfPowerup)
 805         {
 806                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 807                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 808                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 809                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 810         }
 811
 812         int its;
 813         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 814         {
 815                 pickedup = true;
 816                 player.items |= its;
 817                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 818         }
 819
 820         if (item.strength_finished)
 821         {
 822                 pickedup = true;
 823                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 824         }
 825         if (item.invincible_finished)
 826         {
 827                 pickedup = true;
 828                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 829         }
 830         if (item.superweapons_finished)
 831         {
 832                 pickedup = true;
 833                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 834         }
 835
 836         // always eat teamed entities
 837         if(item.team)
 838                 pickedup = true;
 839
 840         if (!pickedup)
 841                 return 0;
 842
 843         // crude hack to enforce switching weapons
 844         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 845         {
 846                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 847                 {
 848                         .entity weaponentity = weaponentities[slot];
 849                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 850                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 851                 }
 852                 return 1;
 853         }
 854
 855         if(_switchweapon)
 856         {
 857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 858                 {
 859                         .entity weaponentity = weaponentities[slot];
 860                         if(_switchweapon & BIT(slot))
 861                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 862                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 863                 }
 864         }
 865
 866         return 1;
 867 }
 868
 869 void Item_Touch(entity this, entity toucher)
 870 {
 871         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 872         if (Item_IsLoot(this))
 873         {
 874                 if (ITEM_TOUCH_NEEDKILL())
 875                 {
 876                         delete(this);
 877                         return;
 878                 }
 879         }
 880
 881         if(!(toucher.flags & FL_PICKUPITEMS)
 882         || STAT(FROZEN, toucher)
 883         || IS_DEAD(toucher)
 884         || (this.solid != SOLID_TRIGGER)
 885         || (this.owner == toucher)
 886         || (time < this.item_spawnshieldtime)
 887         ) { return; }
 888
 889         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 890         {
 891                 case MUT_ITEMTOUCH_RETURN: { return; }
 892                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 893         }
 894
 895         toucher = M_ARGV(1, entity);
 896
 897         if (Item_IsExpiring(this))
 898         {
 899                 this.strength_finished = max(0, this.strength_finished - time);
 900                 this.invincible_finished = max(0, this.invincible_finished - time);
 901                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 902         }
 903         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 904         if (!gave)
 905         {
 906                 if (Item_IsExpiring(this))
 907                 {
 908                         // undo what we did above
 909                         this.strength_finished += time;
 910                         this.invincible_finished += time;
 911                         this.superweapons_finished += time;
 912                 }
 913                 return;
 914         }
 915
 916 LABEL(pickup)
 917
 918         toucher.last_pickup = time;
 919
 920         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 921         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 922
 923         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 924         if (wasfreed(this))
 925         {
 926                 return;
 927         }
 928
 929         if (Item_IsLoot(this))
 930         {
 931                 delete(this);
 932                 return;
 933         }
 934         if (!this.spawnshieldtime)
 935         {
 936                 return;
 937         }
 938         entity e;
 939         if (this.team)
 940         {
 941                 RandomSelection_Init();
 942                 IL_EACH(g_items, it.team == this.team,
 943                 {
 944                         if (it.itemdef) // is a registered item
 945                         {
 946                                 Item_Show(it, -1);
 947                                 it.scheduledrespawntime = 0;
 948                                 RandomSelection_AddEnt(it, it.cnt, 0);
 949                         }
 950                 });
 951                 e = RandomSelection_chosen_ent;
 952                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 953         }
 954         else
 955                 e = this;
 956         Item_ScheduleRespawn(e);
 957 }
 958
 959 void Item_Reset(entity this)
 960 {
 961         Item_Show(this, !this.state);
 962         setorigin(this, this.origin);
 963
 964         if (Item_IsLoot(this))
 965         {
 966                 return;
 967         }
 968         setthink(this, Item_Think);
 969         this.nextthink = time;
 970         if (this.waypointsprite_attached)
 971         {
 972                 WaypointSprite_Kill(this.waypointsprite_attached);
 973         }
 974         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 975         {
 976                 Item_ScheduleInitialRespawn(this);
 977         }
 978 }
 979
 980 void Item_FindTeam(entity this)
 981 {
 982         entity e;
 983
 984         if(this.effects & EF_NODRAW)
 985         {
 986                 // marker for item team search
 987                 LOG_TRACE("Initializing item team ", ftos(this.team));
 988                 RandomSelection_Init();
 989                 IL_EACH(g_items, it.team == this.team,
 990                 {
 991                         if(it.itemdef) // is a registered item
 992                                 RandomSelection_AddEnt(it, it.cnt, 0);
 993                 });
 994
 995                 e = RandomSelection_chosen_ent;
 996                 e.state = 0;
 997                 Item_Show(e, 1);
 998
 999                 IL_EACH(g_items, it.team == this.team,
1000                 {
1001                         if(it.itemdef) // is a registered item
1002                         {
1003                                 if(it != e)
1004                                 {
1005                                         // make it non-spawned
1006                                         Item_Show(it, -1);
1007                                         it.state = 1; // state 1 = initially hidden item, apparently
1008                                 }
1009                                 it.effects &= ~EF_NODRAW;
1010                         }
1011                 });
1012
1013                 Item_Reset(this);
1014         }
1015 }
1016
1017 // Savage: used for item garbage-collection
1018 void RemoveItem(entity this)
1019 {
1020         if(wasfreed(this) || !this) { return; }
1021         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1022         delete(this);
1023 }
1024
1025 // pickup evaluation functions
1026 // these functions decide how desirable an item is to the bots
1027
1028 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1029
1030 float weapon_pickupevalfunc(entity player, entity item)
1031 {
1032         // See if I have it already
1033         if(player.weapons & item.weapons)
1034         {
1035                 // If I can pick it up
1036                 if(!item.spawnshieldtime)
1037                         return 0;
1038                 return ammo_pickupevalfunc(player, item);
1039         }
1040
1041         // reduce weapon value if bot already got a good arsenal
1042         float c = 1;
1043         int weapons_value = 0;
1044         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1045                 weapons_value += it.bot_pickupbasevalue;
1046         });
1047         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1048
1049         return item.bot_pickupbasevalue * c;
1050 }
1051
1052 float ammo_pickupevalfunc(entity player, entity item)
1053 {
1054         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1055         entity wpn = NULL;
1056         float c = 0;
1057         float rating = 0;
1058
1059         // Detect needed ammo
1060         if(item.itemdef.instanceOfWeaponPickup)
1061         {
1062                 entity ammo = NULL;
1063                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1064                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1065                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1066                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1067                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1068                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1069
1070                 if(!ammo)
1071                         return 0;
1072                 wpn = item;
1073                 rating = ammo.m_botvalue;
1074         }
1075         else
1076         {
1077                 FOREACH(Weapons, it != WEP_Null, {
1078                         if(!(player.weapons & (it.m_wepset)))
1079                                 continue;
1080
1081                         switch(it.ammo_type)
1082                         {
1083                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1084                                 case RESOURCE_BULLETS: need_nails   = true; break;
1085                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1086                                 case RESOURCE_CELLS:   need_cells   = true; break;
1087                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1088                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1089                         }
1090                 });
1091                 rating = item.bot_pickupbasevalue;
1092         }
1093
1094         float noammorating = 0.5;
1095
1096         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1097                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1098
1099         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1100                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1101
1102         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1103                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1104
1105         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1106                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1107
1108         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1109                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1110
1111         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1112                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1113
1114         rating *= min(c, 2);
1115         if(wpn)
1116                 rating += wpn.bot_pickupbasevalue * 0.1;
1117         return rating;
1118 }
1119
1120 float healtharmor_pickupevalfunc(entity player, entity item)
1121 {
1122         float c = 0;
1123         float rating = item.bot_pickupbasevalue;
1124
1125         float itemarmor = item.armorvalue;
1126         float itemhealth = item.health;
1127
1128         if(item.item_group)
1129         {
1130                 itemarmor *= min(4, item.item_group_count);
1131                 itemhealth *= min(4, item.item_group_count);
1132         }
1133
1134         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1135                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1136
1137         if (itemhealth && (player.health < item.max_health))
1138                 c = itemhealth / max(1, player.health);
1139
1140         rating *= min(2, c);
1141         return rating;
1142 }
1143
1144 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1145 {
1146         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1147                 RemoveItem(this);
1148 }
1149
1150 void item_use(entity this, entity actor, entity trigger)
1151 {
1152         // use the touch function to handle collection
1153         gettouch(this)(this, actor);
1154 }
1155
1156 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1157 {
1158         string itemname = def.m_name;
1159         Model itemmodel = def.m_model;
1160     Sound pickupsound = def.m_sound;
1161         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1162         float pickupbasevalue = def.m_botvalue;
1163         int itemflags = def.m_itemflags;
1164
1165         startitem_failed = false;
1166
1167         this.item_model_ent = itemmodel;
1168     this.item_pickupsound_ent = pickupsound;
1169
1170     if(def.m_iteminit)
1171         def.m_iteminit(this);
1172
1173         if(!this.respawntime) // both need to be set
1174         {
1175                 this.respawntime = defaultrespawntime;
1176                 this.respawntimejitter = defaultrespawntimejitter;
1177         }
1178
1179         if(!this.pickup_anyway && def.m_pickupanyway)
1180                 this.pickup_anyway = def.m_pickupanyway();
1181
1182         int itemid = def.m_itemid;
1183         this.items = itemid;
1184         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1185         this.weapon = weaponid;
1186
1187         if(!this.fade_end)
1188         {
1189                 this.fade_start = autocvar_g_items_mindist;
1190                 this.fade_end = autocvar_g_items_maxdist;
1191         }
1192
1193         if(weaponid)
1194                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1195
1196         this.flags = FL_ITEM | itemflags;
1197         IL_PUSH(g_items, this);
1198
1199         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1200         {
1201                 startitem_failed = true;
1202                 delete(this);
1203                 return;
1204         }
1205
1206         if (Item_IsLoot(this))
1207         {
1208                 this.reset = SUB_Remove;
1209                 set_movetype(this, MOVETYPE_TOSS);
1210
1211                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1212                 setthink(this, RemoveItem);
1213                 this.nextthink = time + 20;
1214
1215                 this.takedamage = DAMAGE_YES;
1216                 this.event_damage = Item_Damage;
1217
1218                 if (Item_IsExpiring(this))
1219                 {
1220                         // if item is worthless after a timer, have it expire then
1221                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1222                 }
1223
1224                 // don't drop if in a NODROP zone (such as lava)
1225                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1226                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1227                 {
1228                         startitem_failed = true;
1229                         delete(this);
1230                         return;
1231                 }
1232         }
1233         else
1234         {
1235                 if(!have_pickup_item(this))
1236                 {
1237                         startitem_failed = true;
1238                         delete(this);
1239                         return;
1240                 }
1241
1242                 if(this.angles != '0 0 0')
1243                         this.SendFlags |= ISF_ANGLES;
1244
1245                 this.reset = Item_Reset;
1246                 // it's a level item
1247                 if(this.spawnflags & 1)
1248                         this.noalign = 1;
1249                 if (this.noalign > 0)
1250                         set_movetype(this, MOVETYPE_NONE);
1251                 else
1252                         set_movetype(this, MOVETYPE_TOSS);
1253                 // do item filtering according to game mode and other things
1254                 if (this.noalign <= 0)
1255                 {
1256                         // first nudge it off the floor a little bit to avoid math errors
1257                         setorigin(this, this.origin + '0 0 1');
1258                         // set item size before we spawn a spawnfunc_waypoint
1259                         setsize(this, def.m_mins, def.m_maxs);
1260                         this.SendFlags |= ISF_SIZE;
1261                         // note droptofloor returns false if stuck/or would fall too far
1262                         if (!this.noalign)
1263                                 droptofloor(this);
1264                         waypoint_spawnforitem(this);
1265                 }
1266
1267                 /*
1268                  * can't do it that way, as it would break maps
1269                  * TODO make a target_give like entity another way, that perhaps has
1270                  * the weapon name in a key
1271                 if(this.targetname)
1272                 {
1273                         // target_give not yet supported; maybe later
1274                         print("removed targeted ", this.classname, "\n");
1275                         startitem_failed = true;
1276                         delete(this);
1277                         return;
1278                 }
1279                 */
1280
1281                 if(this.targetname != "" && (this.spawnflags & 16))
1282                         this.use = item_use;
1283
1284                 if(autocvar_spawn_debug >= 2)
1285                 {
1286             // why not flags & fl_item?
1287                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1288                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1289                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1290                 error("Mapper sucks.");
1291             });
1292                         this.is_item = true;
1293                 }
1294
1295                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1296
1297                 precache_model(this.model);
1298                 precache_sound(this.item_pickupsound);
1299
1300                 if (   def.instanceOfPowerup
1301                         || def.instanceOfWeaponPickup
1302                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1303                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1304                         || (itemid & (IT_KEY1 | IT_KEY2))
1305                 ) this.target = "###item###"; // for finding the nearest item using find()
1306
1307                 Item_ItemsTime_SetTime(this, 0);
1308         }
1309
1310         this.bot_pickup = true;
1311         this.bot_pickupevalfunc = pickupevalfunc;
1312         this.bot_pickupbasevalue = pickupbasevalue;
1313         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1314         this.netname = itemname;
1315         settouch(this, Item_Touch);
1316         setmodel(this, MDL_Null); // precision set below
1317         //this.effects |= EF_LOWPRECISION;
1318
1319         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1320
1321         this.SendFlags |= ISF_SIZE;
1322
1323         if (!(this.spawnflags & 1024)) {
1324                 if(def.instanceOfPowerup)
1325                         this.ItemStatus |= ITS_ANIMATE1;
1326
1327                 if(this.armorvalue || this.health)
1328                         this.ItemStatus |= ITS_ANIMATE2;
1329         }
1330
1331         if(def.instanceOfWeaponPickup)
1332         {
1333                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1334                         this.colormap = 1024; // color shirt=0 pants=0 grey
1335                 else
1336                         this.gravity = 1;
1337                 if (!(this.spawnflags & 1024))
1338                         this.ItemStatus |= ITS_ANIMATE1;
1339                 this.SendFlags |= ISF_COLORMAP;
1340         }
1341
1342         this.state = 0;
1343         if(this.team) // broken, no idea why.
1344         {
1345                 if(!this.cnt)
1346                         this.cnt = 1; // item probability weight
1347
1348                 this.effects |= EF_NODRAW; // marker for item team search
1349                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1350         }
1351         else
1352                 Item_Reset(this);
1353
1354         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1355
1356         // call this hook after everything else has been done
1357         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1358         {
1359                 startitem_failed = true;
1360                 delete(this);
1361                 return;
1362         }
1363
1364         setItemGroup(this);
1365 }
1366
1367 void StartItem(entity this, GameItem def)
1368 {
1369     def = def.m_spawnfunc_hookreplace(def, this);
1370     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1371     {
1372         delete(this);
1373         return;
1374     }
1375     this.classname = def.m_canonical_spawnfunc;
1376     _StartItem(
1377         this,
1378         this.itemdef = def,
1379         def.m_respawntime(), // defaultrespawntime
1380         def.m_respawntimejitter() // defaultrespawntimejitter
1381         );
1382 }
1383
1384 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1385 int group_count = 1;
1386
1387 void setItemGroup(entity this)
1388 {
1389         if(!IS_SMALL(this.itemdef))
1390                 return;
1391
1392         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1393         {
1394                 if(!this.item_group)
1395                 {
1396                         if(!it.item_group)
1397                         {
1398                                 it.item_group = group_count;
1399                                 group_count++;
1400                         }
1401                         this.item_group = it.item_group;
1402                 }
1403                 else // spawning item is already part of a item_group X
1404                 {
1405                         if(!it.item_group)
1406                                 it.item_group = this.item_group;
1407                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1408                         {
1409                                 int grY = it.item_group;
1410                                 // move all items of item_group Y to item_group X
1411                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1412                                 {
1413                                         if(it.item_group == grY)
1414                                                 it.item_group = this.item_group;
1415                                 });
1416                         }
1417                 }
1418         });
1419 }
1420
1421 void setItemGroupCount()
1422 {
1423         for (int k = 1; k <= group_count; k++)
1424         {
1425                 int count = 0;
1426                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1427                 if (count)
1428                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1429         }
1430 }
1431
1432 void target_items_use(entity this, entity actor, entity trigger)
1433 {
1434         if(Item_IsLoot(actor))
1435         {
1436                 EXACTTRIGGER_TOUCH(this, trigger);
1437                 delete(actor);
1438                 return;
1439         }
1440
1441         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1442                 return;
1443
1444         if(trigger.solid == SOLID_TRIGGER)
1445         {
1446                 EXACTTRIGGER_TOUCH(this, trigger);
1447         }
1448
1449         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1450         {
1451                 delete(it);
1452         });
1453
1454         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1455                 centerprint(actor, this.message);
1456 }
1457
1458 spawnfunc(target_items)
1459 {
1460         int n;
1461         string s;
1462
1463         this.use = target_items_use;
1464         if(!this.strength_finished)
1465                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1466         if(!this.invincible_finished)
1467                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1468         if(!this.superweapons_finished)
1469                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1470
1471         n = tokenize_console(this.netname);
1472         if(argv(0) == "give")
1473         {
1474                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1475         }
1476         else
1477         {
1478                 for(int j = 0; j < n; ++j)
1479                 {
1480                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1481                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1482                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1483                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1484                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1485                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1486                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1487                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1488                         else
1489                         {
1490                                 FOREACH(Buffs, it != BUFF_Null,
1491                                 {
1492                                         s = Buff_UndeprecateName(argv(j));
1493                                         if(s == it.m_name)
1494                                         {
1495                                                 this.buffs |= (it.m_itemid);
1496                                                 break;
1497                                         }
1498                                 });
1499                                 FOREACH(Weapons, it != WEP_Null, {
1500                                         s = W_UndeprecateName(argv(j));
1501                                         if(s == it.netname)
1502                                         {
1503                                                 this.weapons |= (it.m_wepset);
1504                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1505                                                         it.wr_init(it);
1506                                                 break;
1507                                         }
1508                                 });
1509                         }
1510                 }
1511
1512                 string itemprefix, valueprefix;
1513                 if(this.spawnflags == 0)
1514                 {
1515                         itemprefix = "";
1516                         valueprefix = "";
1517                 }
1518                 else if(this.spawnflags == 1)
1519                 {
1520                         itemprefix = "max ";
1521                         valueprefix = "max ";
1522                 }
1523                 else if(this.spawnflags == 2)
1524                 {
1525                         itemprefix = "min ";
1526                         valueprefix = "min ";
1527                 }
1528                 else if(this.spawnflags == 4)
1529                 {
1530                         itemprefix = "minus ";
1531                         valueprefix = "max ";
1532                 }
1533                 else
1534                 {
1535                         error("invalid spawnflags");
1536                         itemprefix = valueprefix = string_null;
1537                 }
1538
1539                 this.netname = "";
1540                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1541                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1542                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1543                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1544                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1545                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1546                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1547                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1548                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1549                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1550                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1551                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1552                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1553                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1554                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1555                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1556                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1557         }
1558         this.netname = strzone(this.netname);
1559         //print(this.netname, "\n");
1560
1561         n = tokenize_console(this.netname);
1562         for(int j = 0; j < n; ++j)
1563         {
1564                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1565             it.wr_init(it);
1566             break;
1567                 });
1568         }
1569 }
1570
1571 float GiveWeapon(entity e, float wpn, float op, float val)
1572 {
1573         WepSet v0, v1;
1574         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1575         v0 = (e.weapons & s);
1576         switch(op)
1577         {
1578                 case OP_SET:
1579                         if(val > 0)
1580                                 e.weapons |= s;
1581                         else
1582                                 e.weapons &= ~s;
1583                         break;
1584                 case OP_MIN:
1585                 case OP_PLUS:
1586                         if(val > 0)
1587                                 e.weapons |= s;
1588                         break;
1589                 case OP_MAX:
1590                         if(val <= 0)
1591                                 e.weapons &= ~s;
1592                         break;
1593                 case OP_MINUS:
1594                         if(val > 0)
1595                                 e.weapons &= ~s;
1596                         break;
1597         }
1598         v1 = (e.weapons & s);
1599         return (v0 != v1);
1600 }
1601
1602 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1603 {
1604         bool had_buff = (e.buffs & thebuff.m_itemid);
1605         switch(op)
1606         {
1607                 case OP_SET:
1608                         if(val > 0)
1609                                 e.buffs |= thebuff.m_itemid;
1610                         else
1611                                 e.buffs &= ~thebuff.m_itemid;
1612                         break;
1613                 case OP_MIN:
1614                 case OP_PLUS:
1615                         if(val > 0)
1616                                 e.buffs |= thebuff.m_itemid;
1617                         break;
1618                 case OP_MAX:
1619                         if(val <= 0)
1620                                 e.buffs &= ~thebuff.m_itemid;
1621                         break;
1622                 case OP_MINUS:
1623                         if(val > 0)
1624                                 e.buffs &= ~thebuff.m_itemid;
1625                         break;
1626         }
1627         bool have_buff = (e.buffs & thebuff.m_itemid);
1628         return (had_buff != have_buff);
1629 }
1630
1631 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1632 {
1633         if(v1 == v0)
1634                 return;
1635         if(v1 <= v0 - t)
1636         {
1637                 if(snd_decr != NULL)
1638                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1639         }
1640         else if(v0 >= v0 + t)
1641         {
1642                 if(snd_incr != NULL)
1643                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1644         }
1645 }
1646
1647 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1648 {
1649         if(v0 < v1)
1650                 e.(rotfield) = max(e.(rotfield), time + rottime);
1651         else if(v0 > v1)
1652                 e.(regenfield) = max(e.(regenfield), time + regentime);
1653 }
1654 float GiveItems(entity e, float beginarg, float endarg)
1655 {
1656         float got, i, val, op;
1657         string cmd;
1658
1659         val = 999;
1660         op = OP_SET;
1661
1662         got = 0;
1663
1664         int _switchweapon = 0;
1665
1666         if(CS(e).autoswitch)
1667         {
1668                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1669                 {
1670                         .entity weaponentity = weaponentities[slot];
1671                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1672                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1673                                 _switchweapon |= BIT(slot);
1674                 }
1675         }
1676
1677         e.strength_finished = max(0, e.strength_finished - time);
1678         e.invincible_finished = max(0, e.invincible_finished - time);
1679         e.superweapons_finished = max(0, e.superweapons_finished - time);
1680
1681         PREGIVE(e, items);
1682         PREGIVE_WEAPONS(e);
1683         PREGIVE(e, strength_finished);
1684         PREGIVE(e, invincible_finished);
1685         PREGIVE(e, superweapons_finished);
1686         PREGIVE(e, ammo_nails);
1687         PREGIVE(e, ammo_cells);
1688         PREGIVE(e, ammo_plasma);
1689         PREGIVE(e, ammo_shells);
1690         PREGIVE(e, ammo_rockets);
1691         PREGIVE(e, ammo_fuel);
1692         PREGIVE(e, armorvalue);
1693         PREGIVE(e, health);
1694
1695         for(i = beginarg; i < endarg; ++i)
1696         {
1697                 cmd = argv(i);
1698
1699                 if(cmd == "0" || stof(cmd))
1700                 {
1701                         val = stof(cmd);
1702                         continue;
1703                 }
1704                 switch(cmd)
1705                 {
1706                         case "no":
1707                                 op = OP_MAX;
1708                                 val = 0;
1709                                 continue;
1710                         case "max":
1711                                 op = OP_MAX;
1712                                 continue;
1713                         case "min":
1714                                 op = OP_MIN;
1715                                 continue;
1716                         case "plus":
1717                                 op = OP_PLUS;
1718                                 continue;
1719                         case "minus":
1720                                 op = OP_MINUS;
1721                                 continue;
1722                         case "ALL":
1723                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1724                                 got += GiveValue(e, strength_finished, op, val);
1725                                 got += GiveValue(e, invincible_finished, op, val);
1726                                 got += GiveValue(e, superweapons_finished, op, val);
1727                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1728                         case "all":
1729                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1730                                 got += GiveValue(e, health, op, val);
1731                                 got += GiveValue(e, armorvalue, op, val);
1732                         case "allweapons":
1733                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1734                         //case "allbuffs": // all buffs makes a player god, do not want!
1735                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1736                         case "allammo":
1737                                 got += GiveValue(e, ammo_cells, op, val);
1738                                 got += GiveValue(e, ammo_plasma, op, val);
1739                                 got += GiveValue(e, ammo_shells, op, val);
1740                                 got += GiveValue(e, ammo_nails, op, val);
1741                                 got += GiveValue(e, ammo_rockets, op, val);
1742                                 got += GiveValue(e, ammo_fuel, op, val);
1743                                 break;
1744                         case "unlimited_ammo":
1745                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1746                                 break;
1747                         case "unlimited_weapon_ammo":
1748                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1749                                 break;
1750                         case "unlimited_superweapons":
1751                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1752                                 break;
1753                         case "jetpack":
1754                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1755                                 break;
1756                         case "fuel_regen":
1757                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1758                                 break;
1759                         case "strength":
1760                                 got += GiveValue(e, strength_finished, op, val);
1761                                 break;
1762                         case "invincible":
1763                                 got += GiveValue(e, invincible_finished, op, val);
1764                                 break;
1765                         case "superweapons":
1766                                 got += GiveValue(e, superweapons_finished, op, val);
1767                                 break;
1768                         case "cells":
1769                                 got += GiveValue(e, ammo_cells, op, val);
1770                                 break;
1771                         case "plasma":
1772                                 got += GiveValue(e, ammo_plasma, op, val);
1773                                 break;
1774                         case "shells":
1775                                 got += GiveValue(e, ammo_shells, op, val);
1776                                 break;
1777                         case "nails":
1778                         case "bullets":
1779                                 got += GiveValue(e, ammo_nails, op, val);
1780                                 break;
1781                         case "rockets":
1782                                 got += GiveValue(e, ammo_rockets, op, val);
1783                                 break;
1784                         case "health":
1785                                 got += GiveValue(e, health, op, val);
1786                                 break;
1787                         case "armor":
1788                                 got += GiveValue(e, armorvalue, op, val);
1789                                 break;
1790                         case "fuel":
1791                                 got += GiveValue(e, ammo_fuel, op, val);
1792                                 break;
1793                         default:
1794                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1795                                 {
1796                                         got += GiveBuff(e, it, op, val);
1797                                         break;
1798                                 });
1799                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1800                     got += GiveWeapon(e, it.m_id, op, val);
1801                     break;
1802                                 });
1803                                 break;
1804                 }
1805                 val = 999;
1806                 op = OP_SET;
1807         }
1808
1809         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1810         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1811         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1812         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1813         FOREACH(Weapons, it != WEP_Null, {
1814                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1815                 if(!(save_weapons & (it.m_wepset)))
1816                         if(e.weapons & (it.m_wepset))
1817                                 it.wr_init(it);
1818         });
1819         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1820         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1821         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1822         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1823         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1824         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1825         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1826         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1827         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1828         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1829         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1830
1831         if(e.superweapons_finished <= 0)
1832                 if(e.weapons & WEPSET_SUPERWEAPONS)
1833                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1834
1835         if(e.strength_finished <= 0)
1836                 e.strength_finished = 0;
1837         else
1838                 e.strength_finished += time;
1839         if(e.invincible_finished <= 0)
1840                 e.invincible_finished = 0;
1841         else
1842                 e.invincible_finished += time;
1843         if(e.superweapons_finished <= 0)
1844                 e.superweapons_finished = 0;
1845         else
1846                 e.superweapons_finished += time;
1847
1848         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849         {
1850                 .entity weaponentity = weaponentities[slot];
1851                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1852                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1853                         _switchweapon |= BIT(slot);
1854         }
1855
1856         if(_switchweapon)
1857         {
1858                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1859                 {
1860                         .entity weaponentity = weaponentities[slot];
1861                         if(_switchweapon & BIT(slot))
1862                         {
1863                                 Weapon wep = w_getbestweapon(e, weaponentity);
1864                                 if(wep != e.(weaponentity).m_switchweapon)
1865                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1866                         }
1867                 }
1868         }
1869
1870         return got;
1871 }
1872 #endif