Random start weapons: Merged URS2.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66
67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
68 }
69
70 void ItemDraw(entity this)
71 {
72     if(this.gravity)
73     {
74         Movetype_Physics_MatchServer(this, false);
75         if(IS_ONGROUND(this))
76         { // For some reason avelocity gets set to '0 0 0' here ...
77             this.oldorigin = this.origin;
78             this.gravity = 0;
79
80             if(autocvar_cl_animate_items)
81             { // ... so reset it if animations are requested.
82                 if(this.ItemStatus & ITS_ANIMATE1)
83                     this.avelocity = '0 180 0';
84
85                 if(this.ItemStatus & ITS_ANIMATE2)
86                     this.avelocity = '0 -90 0';
87             }
88
89             // delay is for blocking item's position for a while;
90             // it's a workaround for dropped weapons that receive the position
91             // another time right after they spawn overriding animation position
92             this.onground_time = time + 0.5;
93         }
94     }
95     else if (autocvar_cl_animate_items)
96     {
97         if(this.ItemStatus & ITS_ANIMATE1)
98         {
99             this.angles += this.avelocity * frametime;
100             float fade_in = bound(0, time - this.onground_time, 1);
101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
102         }
103
104         if(this.ItemStatus & ITS_ANIMATE2)
105         {
106             this.angles += this.avelocity * frametime;
107             float fade_in = bound(0, time - this.onground_time, 1);
108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
109         }
110     }
111
112     Item_SetAlpha(this);
113 }
114
115 void ItemDrawSimple(entity this)
116 {
117     if(this.gravity)
118     {
119         Movetype_Physics_MatchServer(this, false);
120
121         if(IS_ONGROUND(this))
122             this.gravity = 0;
123     }
124
125     Item_SetAlpha(this);
126 }
127
128 void Item_PreDraw(entity this)
129 {
130         if(warpzone_warpzones_exist)
131         {
132                 setpredraw(this, func_null); // no need to keep running this
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
139         if(this.fade_start)
140         {
141                 if(vdist(org - this.origin, >, this.fade_end))
142                         alph = 0; // save on some processing
143                 else if(vdist(org - this.origin, <, this.fade_start))
144                         alph = 1; // more processing saved
145                 else
146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
147         }
148         else
149                 alph = 1;
150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
152                 this.alpha = alph;
153         if(alph <= 0)
154                 this.drawmask = 0;
155         //else
156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
157 }
158
159 void ItemRemove(entity this)
160 {
161         if(this.mdl)
162                 strunzone(this.mdl);
163 }
164
165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
166 {
167     int sf = ReadByte();
168
169     if(sf & ISF_LOCATION)
170     {
171         this.origin_x = ReadCoord();
172         this.origin_y = ReadCoord();
173         this.origin_z = ReadCoord();
174         setorigin(this, this.origin);
175         this.oldorigin = this.origin;
176     }
177
178     if(sf & ISF_ANGLES)
179     {
180         this.angles_x = ReadAngle();
181         this.angles_y = ReadAngle();
182         this.angles_z = ReadAngle();
183     }
184
185     if(sf & ISF_SIZE)
186     {
187         float use_bigsize = ReadByte();
188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
189     }
190
191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
192     {
193         this.ItemStatus = ReadByte();
194
195         Item_SetAlpha(this);
196
197         if(autocvar_cl_fullbright_items)
198             if(this.ItemStatus & ITS_ALLOWFB)
199                 this.effects |= EF_FULLBRIGHT;
200
201         if(this.ItemStatus & ITS_GLOW)
202         {
203             if(this.ItemStatus & ITS_AVAILABLE)
204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
205             else
206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
207         }
208     }
209
210     if(sf & ISF_MODEL)
211     {
212         this.drawmask  = MASK_NORMAL;
213                 set_movetype(this, MOVETYPE_TOSS);
214                 if (isnew) IL_PUSH(g_drawables, this);
215         this.draw       = ItemDraw;
216         this.solid = SOLID_TRIGGER;
217         //this.flags |= FL_ITEM;
218
219         bool use_bigsize = ReadByte();
220
221         this.fade_end = ReadShort();
222         this.fade_start = ReadShort();
223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
224                 setpredraw(this, Item_PreDraw);
225
226         if(this.mdl)
227             strunzone(this.mdl);
228
229         this.mdl = "";
230         string _fn = ReadString();
231
232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
233         {
234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
235             this.draw = ItemDrawSimple;
236
237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
245             else
246             {
247                 this.draw = ItemDraw;
248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
249             }
250         }
251
252         if(this.draw != ItemDrawSimple)
253             this.mdl = strzone(_fn);
254
255
256         if(this.mdl == "")
257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
258
259         precache_model(this.mdl);
260         _setmodel(this, this.mdl);
261
262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
263     }
264
265     if(sf & ISF_COLORMAP)
266     {
267         this.colormap = ReadShort();
268         this.item_glowmod_x = ReadByte() / 255.0;
269         this.item_glowmod_y = ReadByte() / 255.0;
270         this.item_glowmod_z = ReadByte() / 255.0;
271     }
272
273     if(sf & ISF_DROP)
274     {
275         this.gravity = 1;
276         this.pushable = true;
277         //this.angles = '0 0 0';
278         set_movetype(this, MOVETYPE_TOSS);
279         this.velocity_x = ReadCoord();
280         this.velocity_y = ReadCoord();
281         this.velocity_z = ReadCoord();
282         setorigin(this, this.oldorigin);
283
284         if(!this.move_time)
285         {
286             this.move_time = time;
287             this.spawntime = time;
288         }
289         else
290             this.move_time = max(this.move_time, time);
291     }
292
293     if(autocvar_cl_animate_items)
294     {
295         if(this.ItemStatus & ITS_ANIMATE1)
296             this.avelocity = '0 180 0';
297
298         if(this.ItemStatus & ITS_ANIMATE2)
299             this.avelocity = '0 -90 0';
300     }
301
302     this.entremove = ItemRemove;
303
304     return true;
305 }
306
307 #endif
308
309 #ifdef SVQC
310 bool ItemSend(entity this, entity to, int sf)
311 {
312         if(this.gravity)
313                 sf |= ISF_DROP;
314         else
315                 sf &= ~ISF_DROP;
316
317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
318         WriteByte(MSG_ENTITY, sf);
319
320         //WriteByte(MSG_ENTITY, this.cnt);
321         if(sf & ISF_LOCATION)
322         {
323                 WriteCoord(MSG_ENTITY, this.origin.x);
324                 WriteCoord(MSG_ENTITY, this.origin.y);
325                 WriteCoord(MSG_ENTITY, this.origin.z);
326         }
327
328         if(sf & ISF_ANGLES)
329         {
330                 WriteAngle(MSG_ENTITY, this.angles_x);
331                 WriteAngle(MSG_ENTITY, this.angles_y);
332                 WriteAngle(MSG_ENTITY, this.angles_z);
333         }
334
335         if(sf & ISF_SIZE)
336         {
337                 Pickup p = this.itemdef;
338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
339         }
340
341         if(sf & ISF_STATUS)
342                 WriteByte(MSG_ENTITY, this.ItemStatus);
343
344         if(sf & ISF_MODEL)
345         {
346                 Pickup p = this.itemdef;
347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
348                 WriteShort(MSG_ENTITY, this.fade_end);
349                 WriteShort(MSG_ENTITY, this.fade_start);
350
351                 if(this.mdl == "")
352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
353
354                 WriteString(MSG_ENTITY, this.mdl);
355         }
356
357
358         if(sf & ISF_COLORMAP)
359         {
360                 WriteShort(MSG_ENTITY, this.colormap);
361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
364         }
365
366         if(sf & ISF_DROP)
367         {
368                 WriteCoord(MSG_ENTITY, this.velocity.x);
369                 WriteCoord(MSG_ENTITY, this.velocity.y);
370                 WriteCoord(MSG_ENTITY, this.velocity.z);
371         }
372
373         return true;
374 }
375
376 void ItemUpdate(entity this)
377 {
378         this.oldorigin = this.origin;
379         this.SendFlags |= ISF_LOCATION;
380 }
381
382 void UpdateItemAfterTeleport(entity this)
383 {
384         if(getSendEntity(this) == ItemSend)
385                 ItemUpdate(this);
386 }
387
388 bool have_pickup_item(entity this)
389 {
390         if(this.itemdef.instanceOfPowerup)
391         {
392                 if(autocvar_g_powerups > 0)
393                         return true;
394                 if(autocvar_g_powerups == 0)
395                         return false;
396         }
397         else
398         {
399                 if(autocvar_g_pickup_items > 0)
400                         return true;
401                 if(autocvar_g_pickup_items == 0)
402                         return false;
403                 if(g_weaponarena)
404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
405                                 return false;
406         }
407         return true;
408 }
409
410 /*
411 float Item_Customize()
412 {
413         if(this.spawnshieldtime)
414                 return true;
415         if(this.weapons & ~other.weapons)
416         {
417                 this.colormod = '0 0 0';
418                 this.glowmod = this.colormod;
419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
420                 return true;
421         }
422         else
423         {
424                 if(g_ghost_items)
425                 {
426                         this.colormod = stov(autocvar_g_ghost_items_color);
427                         this.glowmod = this.colormod;
428                         this.alpha = g_ghost_items;
429                         return true;
430                 }
431                 else
432                         return false;
433         }
434 }
435 */
436
437 void Item_Show (entity e, float mode)
438 {
439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
440         e.ItemStatus &= ~ITS_STAYWEP;
441         entity def = e.itemdef;
442         if (mode > 0)
443         {
444                 // make the item look normal, and be touchable
445                 e.model = e.mdl;
446                 e.solid = SOLID_TRIGGER;
447                 e.spawnshieldtime = 1;
448                 e.ItemStatus |= ITS_AVAILABLE;
449         }
450         else if (mode < 0)
451         {
452                 // hide the item completely
453                 e.model = string_null;
454                 e.solid = SOLID_NOT;
455                 e.spawnshieldtime = 1;
456                 e.ItemStatus &= ~ITS_AVAILABLE;
457         }
458         else
459         {
460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
461                         || e.team // weapon stay isn't supported for teamed weapons
462                         ;
463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
464                 {
465                         // make the item translucent and not touchable
466                         e.model = e.mdl;
467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
468                         e.effects |= EF_STARDUST;
469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
471                 }
472                 else
473                 {
474                         //setmodel(e, "null");
475                         e.solid = SOLID_NOT;
476                         e.colormod = '0 0 0';
477                         //e.glowmod = e.colormod;
478                         e.spawnshieldtime = 1;
479                         e.ItemStatus &= ~ITS_AVAILABLE;
480                 }
481         }
482
483         if (def.m_glow)
484                 e.ItemStatus |= ITS_GLOW;
485
486         if (autocvar_g_nodepthtestitems)
487                 e.effects |= EF_NODEPTHTEST;
488
489
490         if (autocvar_g_fullbrightitems)
491                 e.ItemStatus |= ITS_ALLOWFB;
492
493         if (autocvar_sv_simple_items)
494                 e.ItemStatus |= ITS_ALLOWSI;
495
496         // relink entity (because solid may have changed)
497         setorigin(e, e.origin);
498         e.SendFlags |= ISF_STATUS;
499 }
500
501 void Item_Think(entity this)
502 {
503         this.nextthink = time;
504         if(this.origin != this.oldorigin)
505                 ItemUpdate(this);
506 }
507
508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
509 bool Item_ItemsTime_Allow(GameItem it);
510 float Item_ItemsTime_UpdateTime(entity e, float t);
511 void Item_ItemsTime_SetTime(entity e, float t);
512 void Item_ItemsTime_SetTimesForAllPlayers();
513
514 void Item_Respawn (entity this)
515 {
516         Item_Show(this, 1);
517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
518         setorigin(this, this.origin);
519
520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
521         {
522                 float t = Item_ItemsTime_UpdateTime(this, 0);
523                 Item_ItemsTime_SetTime(this, t);
524                 Item_ItemsTime_SetTimesForAllPlayers();
525         }
526
527         setthink(this, Item_Think);
528         this.nextthink = time;
529
530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
532 }
533
534 void Item_RespawnCountdown (entity this)
535 {
536         if(this.count >= ITEM_RESPAWN_TICKS)
537         {
538                 if(this.waypointsprite_attached)
539                         WaypointSprite_Kill(this.waypointsprite_attached);
540                 Item_Respawn(this);
541         }
542         else
543         {
544                 this.nextthink = time + 1;
545                 this.count += 1;
546                 if(this.count == 1)
547                 {
548                         do {
549                                 {
550                                         entity wi = Weapons_from(this.weapon);
551                                         if (wi != WEP_Null) {
552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
553                                                 wp.wp_extra = wi.m_id;
554                                                 break;
555                                         }
556                                 }
557                                 {
558                                         entity ii = this.itemdef;
559                                         if (ii != NULL) {
560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
561                                                 wp.wp_extra = ii.m_id;
562                                                 break;
563                                         }
564                                 }
565                         } while (0);
566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
567             if(this.waypointsprite_attached)
568             {
569                 GameItem def = this.itemdef;
570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
573             }
574                 }
575
576                 if(this.waypointsprite_attached)
577                 {
578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
580                                 {
581                                         msg_entity = it;
582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
583                                 }
584                         });
585
586                         WaypointSprite_Ping(this.waypointsprite_attached);
587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
588                 }
589         }
590 }
591
592 void Item_RespawnThink(entity this)
593 {
594         this.nextthink = time;
595         if(this.origin != this.oldorigin)
596                 ItemUpdate(this);
597
598         if(time >= this.wait)
599                 Item_Respawn(this);
600 }
601
602 void Item_ScheduleRespawnIn(entity e, float t)
603 {
604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
606         {
607                 setthink(e, Item_RespawnCountdown);
608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
610                 e.count = 0;
611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
612                 {
613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
614                         Item_ItemsTime_SetTime(e, t);
615                         Item_ItemsTime_SetTimesForAllPlayers();
616                 }
617         }
618         else
619         {
620                 setthink(e, Item_RespawnThink);
621                 e.nextthink = time;
622                 e.scheduledrespawntime = time + t;
623                 e.wait = time + t;
624
625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
626                 {
627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
628                         Item_ItemsTime_SetTime(e, t);
629                         Item_ItemsTime_SetTimesForAllPlayers();
630                 }
631         }
632 }
633
634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
637
638 float adjust_respawntime(float normal_respawntime) {
639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
640         float o = autocvar_g_pickup_respawntime_scaling_offset;
641         float l = autocvar_g_pickup_respawntime_scaling_linear;
642
643         if (r == 0 && l == 1) {
644                 return normal_respawntime;
645         }
646
647         CheckAllowedTeams(NULL);
648         GetTeamCounts(NULL);
649         int players = 0;
650         if (c1 != -1) players += c1;
651         if (c2 != -1) players += c2;
652         if (c3 != -1) players += c3;
653         if (c4 != -1) players += c4;
654
655         if (players >= 2) {
656                 return normal_respawntime * (r / (players + o) + l);
657         } else {
658                 return normal_respawntime;
659         }
660 }
661
662 void Item_ScheduleRespawn(entity e)
663 {
664         if(e.respawntime > 0)
665         {
666                 Item_Show(e, 0);
667
668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
670
671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
673                 Item_ScheduleRespawnIn(e, actual_time);
674         }
675         else // if respawntime is -1, this item does not respawn
676                 Item_Show(e, -1);
677 }
678
679 void Item_ScheduleInitialRespawn(entity e)
680 {
681         Item_Show(e, 0);
682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
683 }
684
685 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
686         float shells, float bullets, float rockets, float cells, float plasma)
687 {
688         if (num_weapons == 0)
689         {
690                 return;
691         }
692         int num_potential_weapons = tokenize_console(weapon_names);
693         for (int i = 0; i < num_weapons; ++i)
694         {
695                 RandomSelection_Init();
696                 for (int j = 0; j < num_potential_weapons; ++j)
697                 {
698                         string weapon = argv(j);
699                         FOREACH(Weapons, it != WEP_Null,
700                         {
701                                 // Finding a weapon which player doesn't have.
702                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
703                                 {
704                                         RandomSelection_AddEnt(it, 1, 1);
705                                         break;
706                                 }
707                         });
708                 }
709                 if (RandomSelection_chosen_ent == NULL)
710                 {
711                         return;
712                 }
713                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
714                 switch (RandomSelection_chosen_ent.ammo_field)
715                 {
716                         case (ammo_shells):
717                         {
718                                 if (receiver.ammo_shells != 0)
719                                 {
720                                         break;
721                                 }
722                                 GiveResource(receiver, RESOURCE_SHELLS, shells);
723                                 break;
724                         }
725                         case (ammo_nails):
726                         {
727                                 if (receiver.ammo_nails != 0)
728                                 {
729                                         break;
730                                 }
731                                 GiveResource(receiver, RESOURCE_BULLETS, bullets);
732                                 break;
733                         }
734                         case (ammo_rockets):
735                         {
736                                 if (receiver.ammo_rockets != 0)
737                                 {
738                                         break;
739                                 }
740                                 GiveResource(receiver, RESOURCE_ROCKETS, rockets);
741                                 break;
742                         }
743                         case (ammo_cells):
744                         {
745                                 if (receiver.ammo_cells != 0)
746                                 {
747                                         break;
748                                 }
749                                 GiveResource(receiver, RESOURCE_CELLS, cells);
750                                 break;
751                         }
752                         case (ammo_plasma):
753                         {
754                                 if (receiver.ammo_plasma != 0)
755                                 {
756                                         break;
757                                 }
758                                 GiveResource(receiver, RESOURCE_PLASMA, plasma);
759                                 break;
760                         }
761                 }
762         }
763 }
764
765 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
766 {
767         if (!item.(ammotype))
768                 return false;
769
770         if (item.spawnshieldtime)
771         {
772                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
773                 {
774                         float amount = item.(ammotype);
775                         if ((player.(ammotype) + amount) > ammomax)
776                         {
777                                 amount = ammomax - player.(ammotype);
778                         }
779                         GiveResource(player, GetResourceType(ammotype), amount);
780                         return true;
781                 }
782         }
783         else if(g_weapon_stay == 2)
784         {
785                 float mi = min(item.(ammotype), ammomax);
786                 if (player.(ammotype) < mi)
787                 {
788                         GiveResource(player, GetResourceType(ammotype), mi -
789                                 player.(ammotype));
790                 }
791                 return true;
792         }
793         return false;
794 }
795
796 float Item_GiveTo(entity item, entity player)
797 {
798         float pickedup;
799
800         // if nothing happens to player, just return without taking the item
801         pickedup = false;
802         int _switchweapon = 0;
803         // in case the player has autoswitch enabled do the following:
804         // if the player is using their best weapon before items are given, they
805         // probably want to switch to an even better weapon after items are given
806
807         if(CS(player).autoswitch)
808         {
809                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
810                 {
811                         .entity weaponentity = weaponentities[slot];
812                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
813                         {
814                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
815                                         _switchweapon |= BIT(slot);
816
817                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
818                                         _switchweapon |= BIT(slot);
819                         }
820                 }
821         }
822         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
823         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
824         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
825         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
826         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
827         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
828         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
829         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
830         if (item.itemdef.instanceOfWeaponPickup)
831         {
832                 WepSet w;
833                 w = item.weapons;
834                 w &= ~player.weapons;
835
836                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
837                 {
838                         pickedup = true;
839                         FOREACH(Weapons, it != WEP_Null, {
840                                 if(w & (it.m_wepset))
841                                 {
842                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
843                                         {
844                                                 .entity weaponentity = weaponentities[slot];
845                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
846                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
847                                         }
848                                         W_GiveWeapon(player, it.m_id);
849                                 }
850                         });
851                 }
852         }
853
854         if (item.itemdef.instanceOfPowerup)
855         {
856                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
857                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
858                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
859                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
860         }
861
862         int its;
863         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
864         {
865                 pickedup = true;
866                 player.items |= its;
867                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
868         }
869
870         if (item.strength_finished)
871         {
872                 pickedup = true;
873                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
874         }
875         if (item.invincible_finished)
876         {
877                 pickedup = true;
878                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
879         }
880         if (item.superweapons_finished)
881         {
882                 pickedup = true;
883                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
884         }
885
886 LABEL(skip)
887
888         // always eat teamed entities
889         if(item.team)
890                 pickedup = true;
891
892         if (!pickedup)
893                 return 0;
894
895         // crude hack to enforce switching weapons
896         if(g_cts && item.itemdef.instanceOfWeaponPickup)
897         {
898                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
899                 {
900                         .entity weaponentity = weaponentities[slot];
901                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
902                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
903                 }
904                 return 1;
905         }
906
907         if(_switchweapon)
908         {
909                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
910                 {
911                         .entity weaponentity = weaponentities[slot];
912                         if(_switchweapon & BIT(slot))
913                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
914                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
915                 }
916         }
917
918         return 1;
919 }
920
921 void Item_Touch(entity this, entity toucher)
922 {
923
924         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
925         if (this.classname == "droppedweapon")
926         {
927                 if (ITEM_TOUCH_NEEDKILL())
928                 {
929                         delete(this);
930                         return;
931                 }
932         }
933
934         if(!(toucher.flags & FL_PICKUPITEMS)
935         || STAT(FROZEN, toucher)
936         || IS_DEAD(toucher)
937         || (this.solid != SOLID_TRIGGER)
938         || (this.owner == toucher)
939         || (time < this.item_spawnshieldtime)
940         ) { return; }
941
942         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
943         {
944                 case MUT_ITEMTOUCH_RETURN: { return; }
945                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
946         }
947
948         toucher = M_ARGV(1, entity);
949
950         if (this.classname == "droppedweapon")
951         {
952                 this.strength_finished = max(0, this.strength_finished - time);
953                 this.invincible_finished = max(0, this.invincible_finished - time);
954                 this.superweapons_finished = max(0, this.superweapons_finished - time);
955         }
956         entity it = this.itemdef;
957         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
958         if (!gave)
959         {
960                 if (this.classname == "droppedweapon")
961                 {
962                         // undo what we did above
963                         this.strength_finished += time;
964                         this.invincible_finished += time;
965                         this.superweapons_finished += time;
966                 }
967                 return;
968         }
969
970 LABEL(pickup)
971
972         toucher.last_pickup = time;
973
974         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
975         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
976
977         if (this.classname == "droppedweapon")
978                 delete(this);
979         else if (this.spawnshieldtime)
980         {
981                 entity e;
982                 if(this.team)
983                 {
984                         RandomSelection_Init();
985                         IL_EACH(g_items, it.team == this.team,
986                         {
987                                 if(it.itemdef) // is a registered item
988                                 {
989                                         Item_Show(it, -1);
990                                         RandomSelection_AddEnt(it, it.cnt, 0);
991                                 }
992                         });
993                         e = RandomSelection_chosen_ent;
994                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
995                 }
996                 else
997                         e = this;
998                 Item_ScheduleRespawn(e);
999         }
1000 }
1001
1002 void Item_Reset(entity this)
1003 {
1004         Item_Show(this, !this.state);
1005         setorigin(this, this.origin);
1006
1007         if (this.classname != "droppedweapon")
1008         {
1009                 setthink(this, Item_Think);
1010                 this.nextthink = time;
1011
1012                 if (this.waypointsprite_attached)
1013                         WaypointSprite_Kill(this.waypointsprite_attached);
1014
1015                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1016                         Item_ScheduleInitialRespawn(this);
1017         }
1018 }
1019
1020 void Item_FindTeam(entity this)
1021 {
1022         entity e;
1023
1024         if(this.effects & EF_NODRAW)
1025         {
1026                 // marker for item team search
1027                 LOG_TRACE("Initializing item team ", ftos(this.team));
1028                 RandomSelection_Init();
1029                 IL_EACH(g_items, it.team == this.team,
1030                 {
1031                         if(it.itemdef) // is a registered item
1032                                 RandomSelection_AddEnt(it, it.cnt, 0);
1033                 });
1034
1035                 e = RandomSelection_chosen_ent;
1036                 e.state = 0;
1037                 Item_Show(e, 1);
1038
1039                 IL_EACH(g_items, it.team == this.team,
1040                 {
1041                         if(it.itemdef) // is a registered item
1042                         {
1043                                 if(it != e)
1044                                 {
1045                                         // make it non-spawned
1046                                         Item_Show(it, -1);
1047                                         it.state = 1; // state 1 = initially hidden item, apparently
1048                                 }
1049                                 it.effects &= ~EF_NODRAW;
1050                         }
1051                 });
1052
1053                 Item_Reset(this);
1054         }
1055 }
1056
1057 // Savage: used for item garbage-collection
1058 void RemoveItem(entity this)
1059 {
1060         if(wasfreed(this) || !this) { return; }
1061         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1062         delete(this);
1063 }
1064
1065 // pickup evaluation functions
1066 // these functions decide how desirable an item is to the bots
1067
1068 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1069
1070 float weapon_pickupevalfunc(entity player, entity item)
1071 {
1072         // See if I have it already
1073         if(player.weapons & item.weapons)
1074         {
1075                 // If I can pick it up
1076                 if(!item.spawnshieldtime)
1077                         return 0;
1078                 return ammo_pickupevalfunc(player, item);
1079         }
1080
1081         // reduce weapon value if bot already got a good arsenal
1082         float c = 1;
1083         int weapons_value = 0;
1084         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1085                 weapons_value += it.bot_pickupbasevalue;
1086         });
1087         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1088
1089         return item.bot_pickupbasevalue * c;
1090 }
1091
1092 float ammo_pickupevalfunc(entity player, entity item)
1093 {
1094         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1095         entity wpn = NULL;
1096         float c = 0;
1097         float rating = 0;
1098
1099         // Detect needed ammo
1100         if(item.itemdef.instanceOfWeaponPickup)
1101         {
1102                 entity ammo = NULL;
1103                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1104                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1105                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1106                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1107                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1108                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1109
1110                 if(!ammo)
1111                         return 0;
1112                 wpn = item;
1113                 rating = ammo.m_botvalue;
1114         }
1115         else
1116         {
1117                 FOREACH(Weapons, it != WEP_Null, {
1118                         if(!(player.weapons & (it.m_wepset)))
1119                                 continue;
1120
1121                         switch(it.ammo_field)
1122                         {
1123                                 case ammo_shells:  need_shells  = true; break;
1124                                 case ammo_nails:   need_nails   = true; break;
1125                                 case ammo_rockets: need_rockets = true; break;
1126                                 case ammo_cells:   need_cells   = true; break;
1127                                 case ammo_plasma:  need_plasma  = true; break;
1128                                 case ammo_fuel:    need_fuel    = true; break;
1129                         }
1130                 });
1131                 rating = item.bot_pickupbasevalue;
1132         }
1133
1134         float noammorating = 0.5;
1135
1136         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1137                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1138
1139         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1140                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1141
1142         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1143                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1144
1145         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1146                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1147
1148         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1149                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1150
1151         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1152                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1153
1154         rating *= min(c, 2);
1155         if(wpn)
1156                 rating += wpn.bot_pickupbasevalue * 0.1;
1157         return rating;
1158 }
1159
1160 .int item_group;
1161 .int item_group_count;
1162 float healtharmor_pickupevalfunc(entity player, entity item)
1163 {
1164         float c = 0;
1165         float rating = item.bot_pickupbasevalue;
1166
1167         float itemarmor = item.armorvalue;
1168         float itemhealth = item.health;
1169
1170         if(item.item_group)
1171         {
1172                 itemarmor *= min(4, item.item_group_count);
1173                 itemhealth *= min(4, item.item_group_count);
1174         }
1175
1176         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1177                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1178
1179         if (itemhealth && (player.health < item.max_health))
1180                 c = itemhealth / max(1, player.health);
1181
1182         rating *= min(2, c);
1183         return rating;
1184 }
1185
1186 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1187 {
1188         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1189                 RemoveItem(this);
1190 }
1191
1192 void item_use(entity this, entity actor, entity trigger)
1193 {
1194         // use the touch function to handle collection
1195         gettouch(this)(this, actor);
1196 }
1197
1198 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1199 {
1200         string itemname = def.m_name;
1201         Model itemmodel = def.m_model;
1202     Sound pickupsound = def.m_sound;
1203         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1204         float pickupbasevalue = def.m_botvalue;
1205         int itemflags = def.m_itemflags;
1206
1207         startitem_failed = false;
1208
1209         this.item_model_ent = itemmodel;
1210     this.item_pickupsound_ent = pickupsound;
1211
1212     if(def.m_iteminit)
1213         def.m_iteminit(this);
1214
1215         if(!this.respawntime) // both need to be set
1216         {
1217                 this.respawntime = defaultrespawntime;
1218                 this.respawntimejitter = defaultrespawntimejitter;
1219         }
1220
1221         if(!this.pickup_anyway && def.m_pickupanyway)
1222                 this.pickup_anyway = def.m_pickupanyway();
1223
1224         int itemid = def.m_itemid;
1225         this.items = itemid;
1226         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1227         this.weapon = weaponid;
1228
1229         if(!this.fade_end)
1230         {
1231                 this.fade_start = autocvar_g_items_mindist;
1232                 this.fade_end = autocvar_g_items_maxdist;
1233         }
1234
1235         if(weaponid)
1236                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1237
1238         this.flags = FL_ITEM | itemflags;
1239         IL_PUSH(g_items, this);
1240
1241         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1242         {
1243                 startitem_failed = true;
1244                 delete(this);
1245                 return;
1246         }
1247
1248         // is it a dropped weapon?
1249         if (this.classname == "droppedweapon")
1250         {
1251                 this.reset = SUB_Remove;
1252                 // it's a dropped weapon
1253                 set_movetype(this, MOVETYPE_TOSS);
1254
1255                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1256                 setthink(this, RemoveItem);
1257                 this.nextthink = time + 20;
1258
1259                 this.takedamage = DAMAGE_YES;
1260                 this.event_damage = Item_Damage;
1261
1262                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1263                 {
1264                         // if item is worthless after a timer, have it expire then
1265                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1266                 }
1267
1268                 // don't drop if in a NODROP zone (such as lava)
1269                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1270                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1271                 {
1272                         startitem_failed = true;
1273                         delete(this);
1274                         return;
1275                 }
1276         }
1277         else
1278         {
1279                 if(!have_pickup_item(this))
1280                 {
1281                         startitem_failed = true;
1282                         delete(this);
1283                         return;
1284                 }
1285
1286                 if(this.angles != '0 0 0')
1287                         this.SendFlags |= ISF_ANGLES;
1288
1289                 this.reset = Item_Reset;
1290                 // it's a level item
1291                 if(this.spawnflags & 1)
1292                         this.noalign = 1;
1293                 if (this.noalign > 0)
1294                         set_movetype(this, MOVETYPE_NONE);
1295                 else
1296                         set_movetype(this, MOVETYPE_TOSS);
1297                 // do item filtering according to game mode and other things
1298                 if (this.noalign <= 0)
1299                 {
1300                         // first nudge it off the floor a little bit to avoid math errors
1301                         setorigin(this, this.origin + '0 0 1');
1302                         // set item size before we spawn a spawnfunc_waypoint
1303                         setsize(this, def.m_mins, def.m_maxs);
1304                         this.SendFlags |= ISF_SIZE;
1305                         // note droptofloor returns false if stuck/or would fall too far
1306                         if (!this.noalign)
1307                                 droptofloor(this);
1308                         waypoint_spawnforitem(this);
1309                 }
1310
1311                 /*
1312                  * can't do it that way, as it would break maps
1313                  * TODO make a target_give like entity another way, that perhaps has
1314                  * the weapon name in a key
1315                 if(this.targetname)
1316                 {
1317                         // target_give not yet supported; maybe later
1318                         print("removed targeted ", this.classname, "\n");
1319                         startitem_failed = true;
1320                         delete(this);
1321                         return;
1322                 }
1323                 */
1324
1325                 if(this.targetname != "" && (this.spawnflags & 16))
1326                         this.use = item_use;
1327
1328                 if(autocvar_spawn_debug >= 2)
1329                 {
1330             // why not flags & fl_item?
1331                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1332                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1333                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1334                 error("Mapper sucks.");
1335             });
1336                         this.is_item = true;
1337                 }
1338
1339                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1340
1341                 precache_model(this.model);
1342                 precache_sound(this.item_pickupsound);
1343
1344                 if (   def.instanceOfPowerup
1345                         || def.instanceOfWeaponPickup
1346                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1347                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1348                         || (itemid & (IT_KEY1 | IT_KEY2))
1349                 ) this.target = "###item###"; // for finding the nearest item using find()
1350
1351                 Item_ItemsTime_SetTime(this, 0);
1352         }
1353
1354         this.bot_pickup = true;
1355         this.bot_pickupevalfunc = pickupevalfunc;
1356         this.bot_pickupbasevalue = pickupbasevalue;
1357         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1358         this.netname = itemname;
1359         settouch(this, Item_Touch);
1360         setmodel(this, MDL_Null); // precision set below
1361         //this.effects |= EF_LOWPRECISION;
1362
1363         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1364
1365         this.SendFlags |= ISF_SIZE;
1366
1367         if (!(this.spawnflags & 1024)) {
1368                 if(def.instanceOfPowerup)
1369                         this.ItemStatus |= ITS_ANIMATE1;
1370
1371                 if(this.armorvalue || this.health)
1372                         this.ItemStatus |= ITS_ANIMATE2;
1373         }
1374
1375         if(def.instanceOfWeaponPickup)
1376         {
1377                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1378                         this.colormap = 1024; // color shirt=0 pants=0 grey
1379                 else
1380                         this.gravity = 1;
1381                 if (!(this.spawnflags & 1024))
1382                         this.ItemStatus |= ITS_ANIMATE1;
1383                 this.SendFlags |= ISF_COLORMAP;
1384         }
1385
1386         this.state = 0;
1387         if(this.team) // broken, no idea why.
1388         {
1389                 if(!this.cnt)
1390                         this.cnt = 1; // item probability weight
1391
1392                 this.effects |= EF_NODRAW; // marker for item team search
1393                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1394         }
1395         else
1396                 Item_Reset(this);
1397
1398         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1399
1400         // call this hook after everything else has been done
1401         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1402         {
1403                 startitem_failed = true;
1404                 delete(this);
1405                 return;
1406         }
1407
1408         setItemGroup(this);
1409 }
1410
1411 void StartItem(entity this, GameItem def)
1412 {
1413     _StartItem(
1414         this,
1415         this.itemdef = def,
1416         def.m_respawntime(), // defaultrespawntime
1417         def.m_respawntimejitter() // defaultrespawntimejitter
1418         );
1419 }
1420
1421 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1422 int group_count = 1;
1423
1424 void setItemGroup(entity this)
1425 {
1426         if(!IS_SMALL(this.itemdef))
1427                 return;
1428
1429         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1430         {
1431                 if(!this.item_group)
1432                 {
1433                         if(!it.item_group)
1434                         {
1435                                 it.item_group = group_count;
1436                                 group_count++;
1437                         }
1438                         this.item_group = it.item_group;
1439                 }
1440                 else // spawning item is already part of a item_group X
1441                 {
1442                         if(!it.item_group)
1443                                 it.item_group = this.item_group;
1444                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1445                         {
1446                                 int grY = it.item_group;
1447                                 // move all items of item_group Y to item_group X
1448                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1449                                 {
1450                                         if(it.item_group == grY)
1451                                                 it.item_group = this.item_group;
1452                                 });
1453                         }
1454                 }
1455         });
1456 }
1457
1458 void setItemGroupCount()
1459 {
1460         for (int k = 1; k <= group_count; k++)
1461         {
1462                 int count = 0;
1463                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1464                 if (count)
1465                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1466         }
1467 }
1468
1469 spawnfunc(item_rockets)
1470 {
1471     StartItem(this, ITEM_Rockets);
1472 }
1473
1474 spawnfunc(item_bullets)
1475 {
1476         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1477            (this.classname != "droppedweapon"))
1478         {
1479                 weaponswapping = true;
1480                 spawnfunc_item_shells(this);
1481                 weaponswapping = false;
1482                 return;
1483         }
1484
1485     StartItem(this, ITEM_Bullets);
1486 }
1487
1488 spawnfunc(item_cells)
1489 {
1490         StartItem(this, ITEM_Cells);
1491 }
1492
1493 spawnfunc(item_plasma)
1494 {
1495         StartItem(this, ITEM_Plasma);
1496 }
1497
1498 spawnfunc(item_shells)
1499 {
1500         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1501            (this.classname != "droppedweapon"))
1502         {
1503                 weaponswapping = true;
1504                 spawnfunc_item_bullets(this);
1505                 weaponswapping = false;
1506                 return;
1507         }
1508
1509         StartItem(this, ITEM_Shells);
1510 }
1511
1512 spawnfunc(item_armor_small)
1513 {
1514         StartItem(this, ITEM_ArmorSmall);
1515 }
1516
1517 spawnfunc(item_armor_medium)
1518 {
1519         StartItem(this, ITEM_ArmorMedium);
1520 }
1521
1522 spawnfunc(item_armor_big)
1523 {
1524         StartItem(this, ITEM_ArmorBig);
1525 }
1526
1527 spawnfunc(item_armor_mega)
1528 {
1529         StartItem(this, ITEM_ArmorMega);
1530 }
1531
1532 spawnfunc(item_health_small)
1533 {
1534         StartItem(this, ITEM_HealthSmall);
1535 }
1536
1537 spawnfunc(item_health_medium)
1538 {
1539     StartItem(this, ITEM_HealthMedium);
1540 }
1541
1542 spawnfunc(item_health_big)
1543 {
1544         StartItem(this, ITEM_HealthBig);
1545 }
1546
1547 spawnfunc(item_health_mega)
1548 {
1549     StartItem(this, ITEM_HealthMega);
1550 }
1551
1552 // support old misnamed entities
1553 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1554 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1555 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1556 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1557 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1558 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1559 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1560
1561 spawnfunc(item_strength)
1562 {
1563         StartItem(this, ITEM_Strength);
1564 }
1565
1566 spawnfunc(item_invincible)
1567 {
1568         StartItem(this, ITEM_Shield);
1569 }
1570
1571 // compatibility:
1572 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1573
1574 void target_items_use(entity this, entity actor, entity trigger)
1575 {
1576         if(actor.classname == "droppedweapon")
1577         {
1578                 EXACTTRIGGER_TOUCH(this, trigger);
1579                 delete(actor);
1580                 return;
1581         }
1582
1583         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1584                 return;
1585
1586         if(trigger.solid == SOLID_TRIGGER)
1587         {
1588                 EXACTTRIGGER_TOUCH(this, trigger);
1589         }
1590
1591         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1592         {
1593                 delete(it);
1594         });
1595
1596         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1597                 centerprint(actor, this.message);
1598 }
1599
1600 spawnfunc(target_items)
1601 {
1602         int n;
1603         string s;
1604
1605         this.use = target_items_use;
1606         if(!this.strength_finished)
1607                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1608         if(!this.invincible_finished)
1609                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1610         if(!this.superweapons_finished)
1611                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1612
1613         n = tokenize_console(this.netname);
1614         if(argv(0) == "give")
1615         {
1616                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1617         }
1618         else
1619         {
1620                 for(int j = 0; j < n; ++j)
1621                 {
1622                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1623                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1624                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1625                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1626                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1627                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1628                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1629                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1630                         else
1631                         {
1632                                 FOREACH(Buffs, it != BUFF_Null,
1633                                 {
1634                                         s = Buff_UndeprecateName(argv(j));
1635                                         if(s == it.m_name)
1636                                         {
1637                                                 this.buffs |= (it.m_itemid);
1638                                                 break;
1639                                         }
1640                                 });
1641                                 FOREACH(Weapons, it != WEP_Null, {
1642                                         s = W_UndeprecateName(argv(j));
1643                                         if(s == it.netname)
1644                                         {
1645                                                 this.weapons |= (it.m_wepset);
1646                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1647                                                         it.wr_init(it);
1648                                                 break;
1649                                         }
1650                                 });
1651                         }
1652                 }
1653
1654                 string itemprefix, valueprefix;
1655                 if(this.spawnflags == 0)
1656                 {
1657                         itemprefix = "";
1658                         valueprefix = "";
1659                 }
1660                 else if(this.spawnflags == 1)
1661                 {
1662                         itemprefix = "max ";
1663                         valueprefix = "max ";
1664                 }
1665                 else if(this.spawnflags == 2)
1666                 {
1667                         itemprefix = "min ";
1668                         valueprefix = "min ";
1669                 }
1670                 else if(this.spawnflags == 4)
1671                 {
1672                         itemprefix = "minus ";
1673                         valueprefix = "max ";
1674                 }
1675                 else
1676                 {
1677                         error("invalid spawnflags");
1678                         itemprefix = valueprefix = string_null;
1679                 }
1680
1681                 this.netname = "";
1682                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1683                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1684                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1685                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1686                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1687                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1688                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1689                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1690                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1691                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1692                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1693                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1694                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1695                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1696                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1697                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1698                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1699         }
1700         this.netname = strzone(this.netname);
1701         //print(this.netname, "\n");
1702
1703         n = tokenize_console(this.netname);
1704         for(int j = 0; j < n; ++j)
1705         {
1706                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1707             it.wr_init(it);
1708             break;
1709                 });
1710         }
1711 }
1712
1713 spawnfunc(item_fuel)
1714 {
1715         StartItem(this, ITEM_JetpackFuel);
1716 }
1717
1718 spawnfunc(item_fuel_regen)
1719 {
1720         if(start_items & ITEM_JetpackRegen.m_itemid)
1721         {
1722                 spawnfunc_item_fuel(this);
1723                 return;
1724         }
1725         StartItem(this, ITEM_JetpackRegen);
1726 }
1727
1728 spawnfunc(item_jetpack)
1729 {
1730         if(start_items & ITEM_Jetpack.m_itemid)
1731         {
1732                 spawnfunc_item_fuel(this);
1733                 return;
1734         }
1735         StartItem(this, ITEM_Jetpack);
1736 }
1737
1738 float GiveWeapon(entity e, float wpn, float op, float val)
1739 {
1740         WepSet v0, v1;
1741         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1742         v0 = (e.weapons & s);
1743         switch(op)
1744         {
1745                 case OP_SET:
1746                         if(val > 0)
1747                                 e.weapons |= s;
1748                         else
1749                                 e.weapons &= ~s;
1750                         break;
1751                 case OP_MIN:
1752                 case OP_PLUS:
1753                         if(val > 0)
1754                                 e.weapons |= s;
1755                         break;
1756                 case OP_MAX:
1757                         if(val <= 0)
1758                                 e.weapons &= ~s;
1759                         break;
1760                 case OP_MINUS:
1761                         if(val > 0)
1762                                 e.weapons &= ~s;
1763                         break;
1764         }
1765         v1 = (e.weapons & s);
1766         return (v0 != v1);
1767 }
1768
1769 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1770 {
1771         bool had_buff = (e.buffs & thebuff.m_itemid);
1772         switch(op)
1773         {
1774                 case OP_SET:
1775                         if(val > 0)
1776                                 e.buffs |= thebuff.m_itemid;
1777                         else
1778                                 e.buffs &= ~thebuff.m_itemid;
1779                         break;
1780                 case OP_MIN:
1781                 case OP_PLUS:
1782                         if(val > 0)
1783                                 e.buffs |= thebuff.m_itemid;
1784                         break;
1785                 case OP_MAX:
1786                         if(val <= 0)
1787                                 e.buffs &= ~thebuff.m_itemid;
1788                         break;
1789                 case OP_MINUS:
1790                         if(val > 0)
1791                                 e.buffs &= ~thebuff.m_itemid;
1792                         break;
1793         }
1794         bool have_buff = (e.buffs & thebuff.m_itemid);
1795         return (had_buff != have_buff);
1796 }
1797
1798 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1799 {
1800         if(v1 == v0)
1801                 return;
1802         if(v1 <= v0 - t)
1803         {
1804                 if(snd_decr != NULL)
1805                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1806         }
1807         else if(v0 >= v0 + t)
1808         {
1809                 if(snd_incr != NULL)
1810                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1811         }
1812 }
1813
1814 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1815 {
1816         if(v0 < v1)
1817                 e.(rotfield) = max(e.(rotfield), time + rottime);
1818         else if(v0 > v1)
1819                 e.(regenfield) = max(e.(regenfield), time + regentime);
1820 }
1821 float GiveItems(entity e, float beginarg, float endarg)
1822 {
1823         float got, i, val, op;
1824         string cmd;
1825
1826         val = 999;
1827         op = OP_SET;
1828
1829         got = 0;
1830
1831         int _switchweapon = 0;
1832
1833         if(CS(e).autoswitch)
1834         {
1835                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1836                 {
1837                         .entity weaponentity = weaponentities[slot];
1838                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1839                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1840                                 _switchweapon |= BIT(slot);
1841                 }
1842         }
1843
1844         e.strength_finished = max(0, e.strength_finished - time);
1845         e.invincible_finished = max(0, e.invincible_finished - time);
1846         e.superweapons_finished = max(0, e.superweapons_finished - time);
1847
1848         PREGIVE(e, items);
1849         PREGIVE_WEAPONS(e);
1850         PREGIVE(e, strength_finished);
1851         PREGIVE(e, invincible_finished);
1852         PREGIVE(e, superweapons_finished);
1853         PREGIVE(e, ammo_nails);
1854         PREGIVE(e, ammo_cells);
1855         PREGIVE(e, ammo_plasma);
1856         PREGIVE(e, ammo_shells);
1857         PREGIVE(e, ammo_rockets);
1858         PREGIVE(e, ammo_fuel);
1859         PREGIVE(e, armorvalue);
1860         PREGIVE(e, health);
1861
1862         for(i = beginarg; i < endarg; ++i)
1863         {
1864                 cmd = argv(i);
1865
1866                 if(cmd == "0" || stof(cmd))
1867                 {
1868                         val = stof(cmd);
1869                         continue;
1870                 }
1871                 switch(cmd)
1872                 {
1873                         case "no":
1874                                 op = OP_MAX;
1875                                 val = 0;
1876                                 continue;
1877                         case "max":
1878                                 op = OP_MAX;
1879                                 continue;
1880                         case "min":
1881                                 op = OP_MIN;
1882                                 continue;
1883                         case "plus":
1884                                 op = OP_PLUS;
1885                                 continue;
1886                         case "minus":
1887                                 op = OP_MINUS;
1888                                 continue;
1889                         case "ALL":
1890                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1891                                 got += GiveValue(e, strength_finished, op, val);
1892                                 got += GiveValue(e, invincible_finished, op, val);
1893                                 got += GiveValue(e, superweapons_finished, op, val);
1894                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1895                         case "all":
1896                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1897                                 got += GiveValue(e, health, op, val);
1898                                 got += GiveValue(e, armorvalue, op, val);
1899                         case "allweapons":
1900                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1901                         //case "allbuffs": // all buffs makes a player god, do not want!
1902                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1903                         case "allammo":
1904                                 got += GiveValue(e, ammo_cells, op, val);
1905                                 got += GiveValue(e, ammo_plasma, op, val);
1906                                 got += GiveValue(e, ammo_shells, op, val);
1907                                 got += GiveValue(e, ammo_nails, op, val);
1908                                 got += GiveValue(e, ammo_rockets, op, val);
1909                                 got += GiveValue(e, ammo_fuel, op, val);
1910                                 break;
1911                         case "unlimited_ammo":
1912                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1913                                 break;
1914                         case "unlimited_weapon_ammo":
1915                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1916                                 break;
1917                         case "unlimited_superweapons":
1918                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1919                                 break;
1920                         case "jetpack":
1921                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1922                                 break;
1923                         case "fuel_regen":
1924                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1925                                 break;
1926                         case "strength":
1927                                 got += GiveValue(e, strength_finished, op, val);
1928                                 break;
1929                         case "invincible":
1930                                 got += GiveValue(e, invincible_finished, op, val);
1931                                 break;
1932                         case "superweapons":
1933                                 got += GiveValue(e, superweapons_finished, op, val);
1934                                 break;
1935                         case "cells":
1936                                 got += GiveValue(e, ammo_cells, op, val);
1937                                 break;
1938                         case "plasma":
1939                                 got += GiveValue(e, ammo_plasma, op, val);
1940                                 break;
1941                         case "shells":
1942                                 got += GiveValue(e, ammo_shells, op, val);
1943                                 break;
1944                         case "nails":
1945                         case "bullets":
1946                                 got += GiveValue(e, ammo_nails, op, val);
1947                                 break;
1948                         case "rockets":
1949                                 got += GiveValue(e, ammo_rockets, op, val);
1950                                 break;
1951                         case "health":
1952                                 got += GiveValue(e, health, op, val);
1953                                 break;
1954                         case "armor":
1955                                 got += GiveValue(e, armorvalue, op, val);
1956                                 break;
1957                         case "fuel":
1958                                 got += GiveValue(e, ammo_fuel, op, val);
1959                                 break;
1960                         default:
1961                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1962                                 {
1963                                         got += GiveBuff(e, it, op, val);
1964                                         break;
1965                                 });
1966                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1967                     got += GiveWeapon(e, it.m_id, op, val);
1968                     break;
1969                                 });
1970                                 break;
1971                 }
1972                 val = 999;
1973                 op = OP_SET;
1974         }
1975
1976         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1977         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1978         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1979         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1980         FOREACH(Weapons, it != WEP_Null, {
1981                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1982                 if(!(save_weapons & (it.m_wepset)))
1983                         if(e.weapons & (it.m_wepset))
1984                                 it.wr_init(it);
1985         });
1986         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1987         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1988         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1989         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1990         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1991         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1992         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1993         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1994         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1995         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1996         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1997
1998         if(e.superweapons_finished <= 0)
1999                 if(e.weapons & WEPSET_SUPERWEAPONS)
2000                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2001
2002         if(e.strength_finished <= 0)
2003                 e.strength_finished = 0;
2004         else
2005                 e.strength_finished += time;
2006         if(e.invincible_finished <= 0)
2007                 e.invincible_finished = 0;
2008         else
2009                 e.invincible_finished += time;
2010         if(e.superweapons_finished <= 0)
2011                 e.superweapons_finished = 0;
2012         else
2013                 e.superweapons_finished += time;
2014
2015         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2016         {
2017                 .entity weaponentity = weaponentities[slot];
2018                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2019                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2020                         _switchweapon |= BIT(slot);
2021         }
2022
2023         if(_switchweapon)
2024         {
2025                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2026                 {
2027                         .entity weaponentity = weaponentities[slot];
2028                         if(_switchweapon & BIT(slot))
2029                         {
2030                                 Weapon wep = w_getbestweapon(e, weaponentity);
2031                                 if(wep != e.(weaponentity).m_switchweapon)
2032                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2033                         }
2034                 }
2035         }
2036
2037         return got;
2038 }
2039 #endif