fa6d0f6f313510dd1bc6a8e1a6e921a425d7e1b0
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66
67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
68 }
69
70 void ItemDraw(entity this)
71 {
72     if(this.gravity)
73     {
74         Movetype_Physics_MatchServer(this, false);
75         if(IS_ONGROUND(this))
76         { // For some reason avelocity gets set to '0 0 0' here ...
77             this.oldorigin = this.origin;
78             this.gravity = 0;
79
80             if(autocvar_cl_animate_items)
81             { // ... so reset it if animations are requested.
82                 if(this.ItemStatus & ITS_ANIMATE1)
83                     this.avelocity = '0 180 0';
84
85                 if(this.ItemStatus & ITS_ANIMATE2)
86                     this.avelocity = '0 -90 0';
87             }
88
89             // delay is for blocking item's position for a while;
90             // it's a workaround for dropped weapons that receive the position
91             // another time right after they spawn overriding animation position
92             this.onground_time = time + 0.5;
93         }
94     }
95     else if (autocvar_cl_animate_items)
96     {
97         if(this.ItemStatus & ITS_ANIMATE1)
98         {
99             this.angles += this.avelocity * frametime;
100             float fade_in = bound(0, time - this.onground_time, 1);
101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
102         }
103
104         if(this.ItemStatus & ITS_ANIMATE2)
105         {
106             this.angles += this.avelocity * frametime;
107             float fade_in = bound(0, time - this.onground_time, 1);
108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
109         }
110     }
111
112     Item_SetAlpha(this);
113 }
114
115 void ItemDrawSimple(entity this)
116 {
117     if(this.gravity)
118     {
119         Movetype_Physics_MatchServer(this, false);
120
121         if(IS_ONGROUND(this))
122             this.gravity = 0;
123     }
124
125     Item_SetAlpha(this);
126 }
127
128 void Item_PreDraw(entity this)
129 {
130         if(warpzone_warpzones_exist)
131         {
132                 setpredraw(this, func_null); // no need to keep running this
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
139         if(this.fade_start)
140         {
141                 if(vdist(org - this.origin, >, this.fade_end))
142                         alph = 0; // save on some processing
143                 else if(vdist(org - this.origin, <, this.fade_start))
144                         alph = 1; // more processing saved
145                 else
146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
147         }
148         else
149                 alph = 1;
150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
152                 this.alpha = alph;
153         if(alph <= 0)
154                 this.drawmask = 0;
155         //else
156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
157 }
158
159 void ItemRemove(entity this)
160 {
161         if(this.mdl)
162                 strunzone(this.mdl);
163 }
164
165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
166 {
167     int sf = ReadByte();
168
169     if(sf & ISF_LOCATION)
170     {
171         this.origin_x = ReadCoord();
172         this.origin_y = ReadCoord();
173         this.origin_z = ReadCoord();
174         setorigin(this, this.origin);
175         this.oldorigin = this.origin;
176     }
177
178     if(sf & ISF_ANGLES)
179     {
180         this.angles_x = ReadAngle();
181         this.angles_y = ReadAngle();
182         this.angles_z = ReadAngle();
183     }
184
185     if(sf & ISF_SIZE)
186     {
187         float use_bigsize = ReadByte();
188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
189     }
190
191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
192     {
193         this.ItemStatus = ReadByte();
194
195         Item_SetAlpha(this);
196
197         if(autocvar_cl_fullbright_items)
198             if(this.ItemStatus & ITS_ALLOWFB)
199                 this.effects |= EF_FULLBRIGHT;
200
201         if(this.ItemStatus & ITS_GLOW)
202         {
203             if(this.ItemStatus & ITS_AVAILABLE)
204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
205             else
206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
207         }
208     }
209
210     if(sf & ISF_MODEL)
211     {
212         this.drawmask  = MASK_NORMAL;
213                 set_movetype(this, MOVETYPE_TOSS);
214                 if (isnew) IL_PUSH(g_drawables, this);
215         this.draw       = ItemDraw;
216         this.solid = SOLID_TRIGGER;
217         //this.flags |= FL_ITEM;
218
219         bool use_bigsize = ReadByte();
220
221         this.fade_end = ReadShort();
222         this.fade_start = ReadShort();
223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
224                 setpredraw(this, Item_PreDraw);
225
226         if(this.mdl)
227             strunzone(this.mdl);
228
229         this.mdl = "";
230         string _fn = ReadString();
231
232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
233         {
234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
235             this.draw = ItemDrawSimple;
236
237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
245             else
246             {
247                 this.draw = ItemDraw;
248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
249             }
250         }
251
252         if(this.draw != ItemDrawSimple)
253             this.mdl = strzone(_fn);
254
255
256         if(this.mdl == "")
257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
258
259         precache_model(this.mdl);
260         _setmodel(this, this.mdl);
261
262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
263     }
264
265     if(sf & ISF_COLORMAP)
266     {
267         this.colormap = ReadShort();
268         this.item_glowmod_x = ReadByte() / 255.0;
269         this.item_glowmod_y = ReadByte() / 255.0;
270         this.item_glowmod_z = ReadByte() / 255.0;
271     }
272
273     if(sf & ISF_DROP)
274     {
275         this.gravity = 1;
276         this.pushable = true;
277         //this.angles = '0 0 0';
278         set_movetype(this, MOVETYPE_TOSS);
279         this.velocity_x = ReadCoord();
280         this.velocity_y = ReadCoord();
281         this.velocity_z = ReadCoord();
282         setorigin(this, this.oldorigin);
283
284         if(!this.move_time)
285         {
286             this.move_time = time;
287             this.spawntime = time;
288         }
289         else
290             this.move_time = max(this.move_time, time);
291     }
292
293     if(autocvar_cl_animate_items)
294     {
295         if(this.ItemStatus & ITS_ANIMATE1)
296             this.avelocity = '0 180 0';
297
298         if(this.ItemStatus & ITS_ANIMATE2)
299             this.avelocity = '0 -90 0';
300     }
301
302     this.entremove = ItemRemove;
303
304     return true;
305 }
306
307 #endif
308
309 #ifdef SVQC
310 bool ItemSend(entity this, entity to, int sf)
311 {
312         if(this.gravity)
313                 sf |= ISF_DROP;
314         else
315                 sf &= ~ISF_DROP;
316
317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
318         WriteByte(MSG_ENTITY, sf);
319
320         //WriteByte(MSG_ENTITY, this.cnt);
321         if(sf & ISF_LOCATION)
322         {
323                 WriteCoord(MSG_ENTITY, this.origin.x);
324                 WriteCoord(MSG_ENTITY, this.origin.y);
325                 WriteCoord(MSG_ENTITY, this.origin.z);
326         }
327
328         if(sf & ISF_ANGLES)
329         {
330                 WriteAngle(MSG_ENTITY, this.angles_x);
331                 WriteAngle(MSG_ENTITY, this.angles_y);
332                 WriteAngle(MSG_ENTITY, this.angles_z);
333         }
334
335         if(sf & ISF_SIZE)
336         {
337                 Pickup p = this.itemdef;
338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
339         }
340
341         if(sf & ISF_STATUS)
342                 WriteByte(MSG_ENTITY, this.ItemStatus);
343
344         if(sf & ISF_MODEL)
345         {
346                 Pickup p = this.itemdef;
347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
348                 WriteShort(MSG_ENTITY, this.fade_end);
349                 WriteShort(MSG_ENTITY, this.fade_start);
350
351                 if(this.mdl == "")
352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
353
354                 WriteString(MSG_ENTITY, this.mdl);
355         }
356
357
358         if(sf & ISF_COLORMAP)
359         {
360                 WriteShort(MSG_ENTITY, this.colormap);
361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
364         }
365
366         if(sf & ISF_DROP)
367         {
368                 WriteCoord(MSG_ENTITY, this.velocity.x);
369                 WriteCoord(MSG_ENTITY, this.velocity.y);
370                 WriteCoord(MSG_ENTITY, this.velocity.z);
371         }
372
373         return true;
374 }
375
376 void ItemUpdate(entity this)
377 {
378         this.oldorigin = this.origin;
379         this.SendFlags |= ISF_LOCATION;
380 }
381
382 void UpdateItemAfterTeleport(entity this)
383 {
384         if(getSendEntity(this) == ItemSend)
385                 ItemUpdate(this);
386 }
387
388 bool have_pickup_item(entity this)
389 {
390         if(this.itemdef.instanceOfPowerup)
391         {
392                 if(autocvar_g_powerups > 0)
393                         return true;
394                 if(autocvar_g_powerups == 0)
395                         return false;
396         }
397         else
398         {
399                 if(autocvar_g_pickup_items > 0)
400                         return true;
401                 if(autocvar_g_pickup_items == 0)
402                         return false;
403                 if(g_weaponarena)
404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
405                                 return false;
406         }
407         return true;
408 }
409
410 /*
411 float Item_Customize()
412 {
413         if(this.spawnshieldtime)
414                 return true;
415         if(this.weapons & ~other.weapons)
416         {
417                 this.colormod = '0 0 0';
418                 this.glowmod = this.colormod;
419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
420                 return true;
421         }
422         else
423         {
424                 if(g_ghost_items)
425                 {
426                         this.colormod = stov(autocvar_g_ghost_items_color);
427                         this.glowmod = this.colormod;
428                         this.alpha = g_ghost_items;
429                         return true;
430                 }
431                 else
432                         return false;
433         }
434 }
435 */
436
437 void Item_Show (entity e, float mode)
438 {
439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
440         e.ItemStatus &= ~ITS_STAYWEP;
441         entity def = e.itemdef;
442         if (mode > 0)
443         {
444                 // make the item look normal, and be touchable
445                 e.model = e.mdl;
446                 e.solid = SOLID_TRIGGER;
447                 e.spawnshieldtime = 1;
448                 e.ItemStatus |= ITS_AVAILABLE;
449         }
450         else if (mode < 0)
451         {
452                 // hide the item completely
453                 e.model = string_null;
454                 e.solid = SOLID_NOT;
455                 e.spawnshieldtime = 1;
456                 e.ItemStatus &= ~ITS_AVAILABLE;
457         }
458         else
459         {
460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
461                         || e.team // weapon stay isn't supported for teamed weapons
462                         ;
463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
464                 {
465                         // make the item translucent and not touchable
466                         e.model = e.mdl;
467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
468                         e.effects |= EF_STARDUST;
469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
471                 }
472                 else
473                 {
474                         //setmodel(e, "null");
475                         e.solid = SOLID_NOT;
476                         e.colormod = '0 0 0';
477                         //e.glowmod = e.colormod;
478                         e.spawnshieldtime = 1;
479                         e.ItemStatus &= ~ITS_AVAILABLE;
480                 }
481         }
482
483         if (def.m_glow)
484                 e.ItemStatus |= ITS_GLOW;
485
486         if (autocvar_g_nodepthtestitems)
487                 e.effects |= EF_NODEPTHTEST;
488
489
490         if (autocvar_g_fullbrightitems)
491                 e.ItemStatus |= ITS_ALLOWFB;
492
493         if (autocvar_sv_simple_items)
494                 e.ItemStatus |= ITS_ALLOWSI;
495
496         // relink entity (because solid may have changed)
497         setorigin(e, e.origin);
498         e.SendFlags |= ISF_STATUS;
499 }
500
501 void Item_Think(entity this)
502 {
503         this.nextthink = time;
504         if(this.origin != this.oldorigin)
505                 ItemUpdate(this);
506 }
507
508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
509 bool Item_ItemsTime_Allow(GameItem it);
510 float Item_ItemsTime_UpdateTime(entity e, float t);
511 void Item_ItemsTime_SetTime(entity e, float t);
512 void Item_ItemsTime_SetTimesForAllPlayers();
513
514 void Item_Respawn (entity this)
515 {
516         Item_Show(this, 1);
517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
518         setorigin(this, this.origin);
519
520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
521         {
522                 float t = Item_ItemsTime_UpdateTime(this, 0);
523                 Item_ItemsTime_SetTime(this, t);
524                 Item_ItemsTime_SetTimesForAllPlayers();
525         }
526
527         setthink(this, Item_Think);
528         this.nextthink = time;
529
530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
532 }
533
534 void Item_RespawnCountdown (entity this)
535 {
536         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
537         {
538                 if(this.waypointsprite_attached)
539                         WaypointSprite_Kill(this.waypointsprite_attached);
540                 Item_Respawn(this);
541         }
542         else
543         {
544                 this.nextthink = time + 1;
545                 this.item_respawncounter += 1;
546                 if(this.item_respawncounter == 1)
547                 {
548                         do {
549                                 {
550                                         entity wi = Weapons_from(this.weapon);
551                                         if (wi != WEP_Null) {
552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
553                                                 wp.wp_extra = wi.m_id;
554                                                 break;
555                                         }
556                                 }
557                                 {
558                                         entity ii = this.itemdef;
559                                         if (ii != NULL) {
560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
561                                                 wp.wp_extra = ii.m_id;
562                                                 break;
563                                         }
564                                 }
565                         } while (0);
566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
567             if(this.waypointsprite_attached)
568             {
569                 GameItem def = this.itemdef;
570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
573             }
574                 }
575
576                 if(this.waypointsprite_attached)
577                 {
578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
580                                 {
581                                         msg_entity = it;
582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
583                                 }
584                         });
585
586                         WaypointSprite_Ping(this.waypointsprite_attached);
587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
588                 }
589         }
590 }
591
592 void Item_RespawnThink(entity this)
593 {
594         this.nextthink = time;
595         if(this.origin != this.oldorigin)
596                 ItemUpdate(this);
597
598         if(time >= this.wait)
599                 Item_Respawn(this);
600 }
601
602 void Item_ScheduleRespawnIn(entity e, float t)
603 {
604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
606         {
607                 setthink(e, Item_RespawnCountdown);
608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
610                 e.item_respawncounter = 0;
611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
612                 {
613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
614                         Item_ItemsTime_SetTime(e, t);
615                         Item_ItemsTime_SetTimesForAllPlayers();
616                 }
617         }
618         else
619         {
620                 setthink(e, Item_RespawnThink);
621                 e.nextthink = time;
622                 e.scheduledrespawntime = time + t;
623                 e.wait = time + t;
624
625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
626                 {
627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
628                         Item_ItemsTime_SetTime(e, t);
629                         Item_ItemsTime_SetTimesForAllPlayers();
630                 }
631         }
632 }
633
634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
637
638 float adjust_respawntime(float normal_respawntime) {
639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
640         float o = autocvar_g_pickup_respawntime_scaling_offset;
641         float l = autocvar_g_pickup_respawntime_scaling_linear;
642
643         if (r == 0 && l == 1) {
644                 return normal_respawntime;
645         }
646
647         CheckAllowedTeams(NULL);
648         GetTeamCounts(NULL);
649         int players = 0;
650         if (c1 != -1) players += c1;
651         if (c2 != -1) players += c2;
652         if (c3 != -1) players += c3;
653         if (c4 != -1) players += c4;
654
655         if (players >= 2) {
656                 return normal_respawntime * (r / (players + o) + l);
657         } else {
658                 return normal_respawntime;
659         }
660 }
661
662 void Item_ScheduleRespawn(entity e)
663 {
664         if(e.respawntime > 0)
665         {
666                 Item_Show(e, 0);
667
668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
670
671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
673                 Item_ScheduleRespawnIn(e, actual_time);
674         }
675         else // if respawntime is -1, this item does not respawn
676                 Item_Show(e, -1);
677 }
678
679 void Item_ScheduleInitialRespawn(entity e)
680 {
681         Item_Show(e, 0);
682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
683 }
684
685 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
686         entity ammo_entity)
687 {
688         if (num_weapons == 0)
689         {
690                 return;
691         }
692         int num_potential_weapons = tokenize_console(weapon_names);
693         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
694         {
695                 RandomSelection_Init();
696                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
697                         ++weapon_index)
698                 {
699                         string weapon = argv(weapon_index);
700                         FOREACH(Weapons, it != WEP_Null,
701                         {
702                                 // Finding a weapon which player doesn't have.
703                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
704                                 {
705                                         RandomSelection_AddEnt(it, 1, 1);
706                                         break;
707                                 }
708                         });
709                 }
710                 if (RandomSelection_chosen_ent == NULL)
711                 {
712                         return;
713                 }
714                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
715                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
716                 {
717                         continue;
718                 }
719                 if (GetResourceAmount(receiver,
720                         RandomSelection_chosen_ent.ammo_type) != 0)
721                 {
722                         continue;
723                 }
724                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
725                         GetResourceAmount(ammo_entity,
726                         RandomSelection_chosen_ent.ammo_type));
727         }
728 }
729
730 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
731 {
732         float amount = GetResourceAmount(item, resource_type);
733         if (amount == 0)
734         {
735                 return false;
736         }
737         float player_amount = GetResourceAmount(player, resource_type);
738         if (item.spawnshieldtime)
739         {
740                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
741                 {
742                         return false;
743                 }
744                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
745                 return true;
746         }
747         if (g_weapon_stay != 2)
748         {
749                 return false;
750         }
751         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
752         return true;
753 }
754
755 float Item_GiveTo(entity item, entity player)
756 {
757         float pickedup;
758
759         // if nothing happens to player, just return without taking the item
760         pickedup = false;
761         int _switchweapon = 0;
762         // in case the player has autoswitch enabled do the following:
763         // if the player is using their best weapon before items are given, they
764         // probably want to switch to an even better weapon after items are given
765
766         if(CS(player).autoswitch)
767         {
768                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
769                 {
770                         .entity weaponentity = weaponentities[slot];
771                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
772                         {
773                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
774                                         _switchweapon |= BIT(slot);
775
776                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
777                                         _switchweapon |= BIT(slot);
778                         }
779                 }
780         }
781         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
782         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
783         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
784         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
785         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
788         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
789         if (item.itemdef.instanceOfWeaponPickup)
790         {
791                 WepSet w;
792                 w = item.weapons;
793                 w &= ~player.weapons;
794
795                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
796                 {
797                         pickedup = true;
798                         FOREACH(Weapons, it != WEP_Null, {
799                                 if(w & (it.m_wepset))
800                                 {
801                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
802                                         {
803                                                 .entity weaponentity = weaponentities[slot];
804                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
805                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
806                                         }
807                                         W_GiveWeapon(player, it.m_id);
808                                 }
809                         });
810                 }
811         }
812
813         if (item.itemdef.instanceOfPowerup)
814         {
815                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
816                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
817                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
818                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
819         }
820
821         int its;
822         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
823         {
824                 pickedup = true;
825                 player.items |= its;
826                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
827         }
828
829         if (item.strength_finished)
830         {
831                 pickedup = true;
832                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
833         }
834         if (item.invincible_finished)
835         {
836                 pickedup = true;
837                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
838         }
839         if (item.superweapons_finished)
840         {
841                 pickedup = true;
842                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
843         }
844
845         // always eat teamed entities
846         if(item.team)
847                 pickedup = true;
848
849         if (!pickedup)
850                 return 0;
851
852         // crude hack to enforce switching weapons
853         if(g_cts && item.itemdef.instanceOfWeaponPickup)
854         {
855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
856                 {
857                         .entity weaponentity = weaponentities[slot];
858                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
859                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
860                 }
861                 return 1;
862         }
863
864         if(_switchweapon)
865         {
866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
867                 {
868                         .entity weaponentity = weaponentities[slot];
869                         if(_switchweapon & BIT(slot))
870                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
871                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
872                 }
873         }
874
875         return 1;
876 }
877
878 void Item_Touch(entity this, entity toucher)
879 {
880         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
881         if (Item_IsLoot(this))
882         {
883                 if (ITEM_TOUCH_NEEDKILL())
884                 {
885                         delete(this);
886                         return;
887                 }
888         }
889
890         if(!(toucher.flags & FL_PICKUPITEMS)
891         || STAT(FROZEN, toucher)
892         || IS_DEAD(toucher)
893         || (this.solid != SOLID_TRIGGER)
894         || (this.owner == toucher)
895         || (time < this.item_spawnshieldtime)
896         ) { return; }
897
898         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
899         {
900                 case MUT_ITEMTOUCH_RETURN: { return; }
901                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
902         }
903
904         toucher = M_ARGV(1, entity);
905
906         if (Item_IsExpiring(this))
907         {
908                 this.strength_finished = max(0, this.strength_finished - time);
909                 this.invincible_finished = max(0, this.invincible_finished - time);
910                 this.superweapons_finished = max(0, this.superweapons_finished - time);
911         }
912         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
913         if (!gave)
914         {
915                 if (Item_IsExpiring(this))
916                 {
917                         // undo what we did above
918                         this.strength_finished += time;
919                         this.invincible_finished += time;
920                         this.superweapons_finished += time;
921                 }
922                 return;
923         }
924
925 LABEL(pickup)
926
927         toucher.last_pickup = time;
928
929         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
930         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
931
932         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
933         if (wasfreed(this))
934         {
935                 return;
936         }
937
938         if (Item_IsLoot(this))
939         {
940                 delete(this);
941                 return;
942         }
943         if (!this.spawnshieldtime)
944         {
945                 return;
946         }
947         entity e;
948         if (this.team)
949         {
950                 RandomSelection_Init();
951                 IL_EACH(g_items, it.team == this.team,
952                 {
953                         if (it.itemdef) // is a registered item
954                         {
955                                 Item_Show(it, -1);
956                                 it.scheduledrespawntime = 0;
957                                 RandomSelection_AddEnt(it, it.cnt, 0);
958                         }
959                 });
960                 e = RandomSelection_chosen_ent;
961                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
962         }
963         else
964                 e = this;
965         Item_ScheduleRespawn(e);
966 }
967
968 void Item_Reset(entity this)
969 {
970         Item_Show(this, !this.state);
971         setorigin(this, this.origin);
972
973         if (Item_IsLoot(this))
974         {
975                 return;
976         }
977         setthink(this, Item_Think);
978         this.nextthink = time;
979         if (this.waypointsprite_attached)
980         {
981                 WaypointSprite_Kill(this.waypointsprite_attached);
982         }
983         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
984         {
985                 Item_ScheduleInitialRespawn(this);
986         }
987 }
988
989 void Item_FindTeam(entity this)
990 {
991         entity e;
992
993         if(this.effects & EF_NODRAW)
994         {
995                 // marker for item team search
996                 LOG_TRACE("Initializing item team ", ftos(this.team));
997                 RandomSelection_Init();
998                 IL_EACH(g_items, it.team == this.team,
999                 {
1000                         if(it.itemdef) // is a registered item
1001                                 RandomSelection_AddEnt(it, it.cnt, 0);
1002                 });
1003
1004                 e = RandomSelection_chosen_ent;
1005                 e.state = 0;
1006                 Item_Show(e, 1);
1007
1008                 IL_EACH(g_items, it.team == this.team,
1009                 {
1010                         if(it.itemdef) // is a registered item
1011                         {
1012                                 if(it != e)
1013                                 {
1014                                         // make it non-spawned
1015                                         Item_Show(it, -1);
1016                                         it.state = 1; // state 1 = initially hidden item, apparently
1017                                 }
1018                                 it.effects &= ~EF_NODRAW;
1019                         }
1020                 });
1021
1022                 Item_Reset(this);
1023         }
1024 }
1025
1026 // Savage: used for item garbage-collection
1027 void RemoveItem(entity this)
1028 {
1029         if(wasfreed(this) || !this) { return; }
1030         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1031         delete(this);
1032 }
1033
1034 // pickup evaluation functions
1035 // these functions decide how desirable an item is to the bots
1036
1037 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1038
1039 float weapon_pickupevalfunc(entity player, entity item)
1040 {
1041         // See if I have it already
1042         if(player.weapons & item.weapons)
1043         {
1044                 // If I can pick it up
1045                 if(!item.spawnshieldtime)
1046                         return 0;
1047                 return ammo_pickupevalfunc(player, item);
1048         }
1049
1050         // reduce weapon value if bot already got a good arsenal
1051         float c = 1;
1052         int weapons_value = 0;
1053         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1054                 weapons_value += it.bot_pickupbasevalue;
1055         });
1056         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1057
1058         return item.bot_pickupbasevalue * c;
1059 }
1060
1061 float ammo_pickupevalfunc(entity player, entity item)
1062 {
1063         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1064         entity wpn = NULL;
1065         float c = 0;
1066         float rating = 0;
1067
1068         // Detect needed ammo
1069         if(item.itemdef.instanceOfWeaponPickup)
1070         {
1071                 entity ammo = NULL;
1072                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1073                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1074                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1075                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1076                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1077                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1078
1079                 if(!ammo)
1080                         return 0;
1081                 wpn = item;
1082                 rating = ammo.m_botvalue;
1083         }
1084         else
1085         {
1086                 FOREACH(Weapons, it != WEP_Null, {
1087                         if(!(player.weapons & (it.m_wepset)))
1088                                 continue;
1089
1090                         switch(it.ammo_type)
1091                         {
1092                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1093                                 case RESOURCE_BULLETS: need_nails   = true; break;
1094                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1095                                 case RESOURCE_CELLS:   need_cells   = true; break;
1096                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1097                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1098                         }
1099                 });
1100                 rating = item.bot_pickupbasevalue;
1101         }
1102
1103         float noammorating = 0.5;
1104
1105         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1106                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1107
1108         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1109                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1110
1111         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1112                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1113
1114         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1115                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1116
1117         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1118                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1119
1120         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1121                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1122
1123         rating *= min(c, 2);
1124         if(wpn)
1125                 rating += wpn.bot_pickupbasevalue * 0.1;
1126         return rating;
1127 }
1128
1129 .int item_group;
1130 .int item_group_count;
1131 float healtharmor_pickupevalfunc(entity player, entity item)
1132 {
1133         float c = 0;
1134         float rating = item.bot_pickupbasevalue;
1135
1136         float itemarmor = item.armorvalue;
1137         float itemhealth = item.health;
1138
1139         if(item.item_group)
1140         {
1141                 itemarmor *= min(4, item.item_group_count);
1142                 itemhealth *= min(4, item.item_group_count);
1143         }
1144
1145         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1146                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1147
1148         if (itemhealth && (player.health < item.max_health))
1149                 c = itemhealth / max(1, player.health);
1150
1151         rating *= min(2, c);
1152         return rating;
1153 }
1154
1155 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1156 {
1157         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1158                 RemoveItem(this);
1159 }
1160
1161 void item_use(entity this, entity actor, entity trigger)
1162 {
1163         // use the touch function to handle collection
1164         gettouch(this)(this, actor);
1165 }
1166
1167 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1168 {
1169         string itemname = def.m_name;
1170         Model itemmodel = def.m_model;
1171     Sound pickupsound = def.m_sound;
1172         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1173         float pickupbasevalue = def.m_botvalue;
1174         int itemflags = def.m_itemflags;
1175
1176         startitem_failed = false;
1177
1178         this.item_model_ent = itemmodel;
1179     this.item_pickupsound_ent = pickupsound;
1180
1181     if(def.m_iteminit)
1182         def.m_iteminit(this);
1183
1184         if(!this.respawntime) // both need to be set
1185         {
1186                 this.respawntime = defaultrespawntime;
1187                 this.respawntimejitter = defaultrespawntimejitter;
1188         }
1189
1190         if(!this.pickup_anyway && def.m_pickupanyway)
1191                 this.pickup_anyway = def.m_pickupanyway();
1192
1193         int itemid = def.m_itemid;
1194         this.items = itemid;
1195         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1196         this.weapon = weaponid;
1197
1198         if(!this.fade_end)
1199         {
1200                 this.fade_start = autocvar_g_items_mindist;
1201                 this.fade_end = autocvar_g_items_maxdist;
1202         }
1203
1204         if(weaponid)
1205                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1206
1207         this.flags = FL_ITEM | itemflags;
1208         IL_PUSH(g_items, this);
1209
1210         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1211         {
1212                 startitem_failed = true;
1213                 delete(this);
1214                 return;
1215         }
1216
1217         if (Item_IsLoot(this))
1218         {
1219                 this.reset = SUB_Remove;
1220                 set_movetype(this, MOVETYPE_TOSS);
1221
1222                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1223                 setthink(this, RemoveItem);
1224                 this.nextthink = time + 20;
1225
1226                 this.takedamage = DAMAGE_YES;
1227                 this.event_damage = Item_Damage;
1228
1229                 if (Item_IsExpiring(this))
1230                 {
1231                         // if item is worthless after a timer, have it expire then
1232                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1233                 }
1234
1235                 // don't drop if in a NODROP zone (such as lava)
1236                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1237                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1238                 {
1239                         startitem_failed = true;
1240                         delete(this);
1241                         return;
1242                 }
1243         }
1244         else
1245         {
1246                 if(!have_pickup_item(this))
1247                 {
1248                         startitem_failed = true;
1249                         delete(this);
1250                         return;
1251                 }
1252
1253                 if(this.angles != '0 0 0')
1254                         this.SendFlags |= ISF_ANGLES;
1255
1256                 this.reset = Item_Reset;
1257                 // it's a level item
1258                 if(this.spawnflags & 1)
1259                         this.noalign = 1;
1260                 if (this.noalign > 0)
1261                         set_movetype(this, MOVETYPE_NONE);
1262                 else
1263                         set_movetype(this, MOVETYPE_TOSS);
1264                 // do item filtering according to game mode and other things
1265                 if (this.noalign <= 0)
1266                 {
1267                         // first nudge it off the floor a little bit to avoid math errors
1268                         setorigin(this, this.origin + '0 0 1');
1269                         // set item size before we spawn a spawnfunc_waypoint
1270                         setsize(this, def.m_mins, def.m_maxs);
1271                         this.SendFlags |= ISF_SIZE;
1272                         // note droptofloor returns false if stuck/or would fall too far
1273                         if (!this.noalign)
1274                                 droptofloor(this);
1275                         waypoint_spawnforitem(this);
1276                 }
1277
1278                 /*
1279                  * can't do it that way, as it would break maps
1280                  * TODO make a target_give like entity another way, that perhaps has
1281                  * the weapon name in a key
1282                 if(this.targetname)
1283                 {
1284                         // target_give not yet supported; maybe later
1285                         print("removed targeted ", this.classname, "\n");
1286                         startitem_failed = true;
1287                         delete(this);
1288                         return;
1289                 }
1290                 */
1291
1292                 if(this.targetname != "" && (this.spawnflags & 16))
1293                         this.use = item_use;
1294
1295                 if(autocvar_spawn_debug >= 2)
1296                 {
1297             // why not flags & fl_item?
1298                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1299                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1300                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1301                 error("Mapper sucks.");
1302             });
1303                         this.is_item = true;
1304                 }
1305
1306                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1307
1308                 precache_model(this.model);
1309                 precache_sound(this.item_pickupsound);
1310
1311                 if (   def.instanceOfPowerup
1312                         || def.instanceOfWeaponPickup
1313                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1314                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1315                         || (itemid & (IT_KEY1 | IT_KEY2))
1316                 ) this.target = "###item###"; // for finding the nearest item using find()
1317
1318                 Item_ItemsTime_SetTime(this, 0);
1319         }
1320
1321         this.bot_pickup = true;
1322         this.bot_pickupevalfunc = pickupevalfunc;
1323         this.bot_pickupbasevalue = pickupbasevalue;
1324         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1325         this.netname = itemname;
1326         settouch(this, Item_Touch);
1327         setmodel(this, MDL_Null); // precision set below
1328         //this.effects |= EF_LOWPRECISION;
1329
1330         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1331
1332         this.SendFlags |= ISF_SIZE;
1333
1334         if (!(this.spawnflags & 1024)) {
1335                 if(def.instanceOfPowerup)
1336                         this.ItemStatus |= ITS_ANIMATE1;
1337
1338                 if(this.armorvalue || this.health)
1339                         this.ItemStatus |= ITS_ANIMATE2;
1340         }
1341
1342         if(def.instanceOfWeaponPickup)
1343         {
1344                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1345                         this.colormap = 1024; // color shirt=0 pants=0 grey
1346                 else
1347                         this.gravity = 1;
1348                 if (!(this.spawnflags & 1024))
1349                         this.ItemStatus |= ITS_ANIMATE1;
1350                 this.SendFlags |= ISF_COLORMAP;
1351         }
1352
1353         this.state = 0;
1354         if(this.team) // broken, no idea why.
1355         {
1356                 if(!this.cnt)
1357                         this.cnt = 1; // item probability weight
1358
1359                 this.effects |= EF_NODRAW; // marker for item team search
1360                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1361         }
1362         else
1363                 Item_Reset(this);
1364
1365         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1366
1367         // call this hook after everything else has been done
1368         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1369         {
1370                 startitem_failed = true;
1371                 delete(this);
1372                 return;
1373         }
1374
1375         setItemGroup(this);
1376 }
1377
1378 void StartItem(entity this, GameItem def)
1379 {
1380     def = def.m_spawnfunc_hookreplace(def, this);
1381     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1382     {
1383         delete(this);
1384         return;
1385     }
1386     this.classname = def.m_canonical_spawnfunc;
1387     _StartItem(
1388         this,
1389         this.itemdef = def,
1390         def.m_respawntime(), // defaultrespawntime
1391         def.m_respawntimejitter() // defaultrespawntimejitter
1392         );
1393 }
1394
1395 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1396 int group_count = 1;
1397
1398 void setItemGroup(entity this)
1399 {
1400         if(!IS_SMALL(this.itemdef))
1401                 return;
1402
1403         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1404         {
1405                 if(!this.item_group)
1406                 {
1407                         if(!it.item_group)
1408                         {
1409                                 it.item_group = group_count;
1410                                 group_count++;
1411                         }
1412                         this.item_group = it.item_group;
1413                 }
1414                 else // spawning item is already part of a item_group X
1415                 {
1416                         if(!it.item_group)
1417                                 it.item_group = this.item_group;
1418                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1419                         {
1420                                 int grY = it.item_group;
1421                                 // move all items of item_group Y to item_group X
1422                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1423                                 {
1424                                         if(it.item_group == grY)
1425                                                 it.item_group = this.item_group;
1426                                 });
1427                         }
1428                 }
1429         });
1430 }
1431
1432 void setItemGroupCount()
1433 {
1434         for (int k = 1; k <= group_count; k++)
1435         {
1436                 int count = 0;
1437                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1438                 if (count)
1439                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1440         }
1441 }
1442
1443 void target_items_use(entity this, entity actor, entity trigger)
1444 {
1445         if(Item_IsLoot(actor))
1446         {
1447                 EXACTTRIGGER_TOUCH(this, trigger);
1448                 delete(actor);
1449                 return;
1450         }
1451
1452         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1453                 return;
1454
1455         if(trigger.solid == SOLID_TRIGGER)
1456         {
1457                 EXACTTRIGGER_TOUCH(this, trigger);
1458         }
1459
1460         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1461         {
1462                 delete(it);
1463         });
1464
1465         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1466                 centerprint(actor, this.message);
1467 }
1468
1469 spawnfunc(target_items)
1470 {
1471         int n;
1472         string s;
1473
1474         this.use = target_items_use;
1475         if(!this.strength_finished)
1476                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1477         if(!this.invincible_finished)
1478                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1479         if(!this.superweapons_finished)
1480                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1481
1482         n = tokenize_console(this.netname);
1483         if(argv(0) == "give")
1484         {
1485                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1486         }
1487         else
1488         {
1489                 for(int j = 0; j < n; ++j)
1490                 {
1491                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1492                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1493                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1494                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1495                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1496                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1497                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1498                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1499                         else
1500                         {
1501                                 FOREACH(Buffs, it != BUFF_Null,
1502                                 {
1503                                         s = Buff_UndeprecateName(argv(j));
1504                                         if(s == it.m_name)
1505                                         {
1506                                                 this.buffs |= (it.m_itemid);
1507                                                 break;
1508                                         }
1509                                 });
1510                                 FOREACH(Weapons, it != WEP_Null, {
1511                                         s = W_UndeprecateName(argv(j));
1512                                         if(s == it.netname)
1513                                         {
1514                                                 this.weapons |= (it.m_wepset);
1515                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1516                                                         it.wr_init(it);
1517                                                 break;
1518                                         }
1519                                 });
1520                         }
1521                 }
1522
1523                 string itemprefix, valueprefix;
1524                 if(this.spawnflags == 0)
1525                 {
1526                         itemprefix = "";
1527                         valueprefix = "";
1528                 }
1529                 else if(this.spawnflags == 1)
1530                 {
1531                         itemprefix = "max ";
1532                         valueprefix = "max ";
1533                 }
1534                 else if(this.spawnflags == 2)
1535                 {
1536                         itemprefix = "min ";
1537                         valueprefix = "min ";
1538                 }
1539                 else if(this.spawnflags == 4)
1540                 {
1541                         itemprefix = "minus ";
1542                         valueprefix = "max ";
1543                 }
1544                 else
1545                 {
1546                         error("invalid spawnflags");
1547                         itemprefix = valueprefix = string_null;
1548                 }
1549
1550                 this.netname = "";
1551                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1552                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1553                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1554                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1555                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1557                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1558                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1559                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1560                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1561                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1562                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1563                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1564                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1565                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1566                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1567                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1568         }
1569         this.netname = strzone(this.netname);
1570         //print(this.netname, "\n");
1571
1572         n = tokenize_console(this.netname);
1573         for(int j = 0; j < n; ++j)
1574         {
1575                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1576             it.wr_init(it);
1577             break;
1578                 });
1579         }
1580 }
1581
1582 float GiveWeapon(entity e, float wpn, float op, float val)
1583 {
1584         WepSet v0, v1;
1585         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1586         v0 = (e.weapons & s);
1587         switch(op)
1588         {
1589                 case OP_SET:
1590                         if(val > 0)
1591                                 e.weapons |= s;
1592                         else
1593                                 e.weapons &= ~s;
1594                         break;
1595                 case OP_MIN:
1596                 case OP_PLUS:
1597                         if(val > 0)
1598                                 e.weapons |= s;
1599                         break;
1600                 case OP_MAX:
1601                         if(val <= 0)
1602                                 e.weapons &= ~s;
1603                         break;
1604                 case OP_MINUS:
1605                         if(val > 0)
1606                                 e.weapons &= ~s;
1607                         break;
1608         }
1609         v1 = (e.weapons & s);
1610         return (v0 != v1);
1611 }
1612
1613 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1614 {
1615         bool had_buff = (e.buffs & thebuff.m_itemid);
1616         switch(op)
1617         {
1618                 case OP_SET:
1619                         if(val > 0)
1620                                 e.buffs |= thebuff.m_itemid;
1621                         else
1622                                 e.buffs &= ~thebuff.m_itemid;
1623                         break;
1624                 case OP_MIN:
1625                 case OP_PLUS:
1626                         if(val > 0)
1627                                 e.buffs |= thebuff.m_itemid;
1628                         break;
1629                 case OP_MAX:
1630                         if(val <= 0)
1631                                 e.buffs &= ~thebuff.m_itemid;
1632                         break;
1633                 case OP_MINUS:
1634                         if(val > 0)
1635                                 e.buffs &= ~thebuff.m_itemid;
1636                         break;
1637         }
1638         bool have_buff = (e.buffs & thebuff.m_itemid);
1639         return (had_buff != have_buff);
1640 }
1641
1642 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1643 {
1644         if(v1 == v0)
1645                 return;
1646         if(v1 <= v0 - t)
1647         {
1648                 if(snd_decr != NULL)
1649                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1650         }
1651         else if(v0 >= v0 + t)
1652         {
1653                 if(snd_incr != NULL)
1654                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1655         }
1656 }
1657
1658 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1659 {
1660         if(v0 < v1)
1661                 e.(rotfield) = max(e.(rotfield), time + rottime);
1662         else if(v0 > v1)
1663                 e.(regenfield) = max(e.(regenfield), time + regentime);
1664 }
1665 float GiveItems(entity e, float beginarg, float endarg)
1666 {
1667         float got, i, val, op;
1668         string cmd;
1669
1670         val = 999;
1671         op = OP_SET;
1672
1673         got = 0;
1674
1675         int _switchweapon = 0;
1676
1677         if(CS(e).autoswitch)
1678         {
1679                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1680                 {
1681                         .entity weaponentity = weaponentities[slot];
1682                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1683                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1684                                 _switchweapon |= BIT(slot);
1685                 }
1686         }
1687
1688         e.strength_finished = max(0, e.strength_finished - time);
1689         e.invincible_finished = max(0, e.invincible_finished - time);
1690         e.superweapons_finished = max(0, e.superweapons_finished - time);
1691
1692         PREGIVE(e, items);
1693         PREGIVE_WEAPONS(e);
1694         PREGIVE(e, strength_finished);
1695         PREGIVE(e, invincible_finished);
1696         PREGIVE(e, superweapons_finished);
1697         PREGIVE(e, ammo_nails);
1698         PREGIVE(e, ammo_cells);
1699         PREGIVE(e, ammo_plasma);
1700         PREGIVE(e, ammo_shells);
1701         PREGIVE(e, ammo_rockets);
1702         PREGIVE(e, ammo_fuel);
1703         PREGIVE(e, armorvalue);
1704         PREGIVE(e, health);
1705
1706         for(i = beginarg; i < endarg; ++i)
1707         {
1708                 cmd = argv(i);
1709
1710                 if(cmd == "0" || stof(cmd))
1711                 {
1712                         val = stof(cmd);
1713                         continue;
1714                 }
1715                 switch(cmd)
1716                 {
1717                         case "no":
1718                                 op = OP_MAX;
1719                                 val = 0;
1720                                 continue;
1721                         case "max":
1722                                 op = OP_MAX;
1723                                 continue;
1724                         case "min":
1725                                 op = OP_MIN;
1726                                 continue;
1727                         case "plus":
1728                                 op = OP_PLUS;
1729                                 continue;
1730                         case "minus":
1731                                 op = OP_MINUS;
1732                                 continue;
1733                         case "ALL":
1734                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1735                                 got += GiveValue(e, strength_finished, op, val);
1736                                 got += GiveValue(e, invincible_finished, op, val);
1737                                 got += GiveValue(e, superweapons_finished, op, val);
1738                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1739                         case "all":
1740                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1741                                 got += GiveValue(e, health, op, val);
1742                                 got += GiveValue(e, armorvalue, op, val);
1743                         case "allweapons":
1744                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1745                         //case "allbuffs": // all buffs makes a player god, do not want!
1746                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1747                         case "allammo":
1748                                 got += GiveValue(e, ammo_cells, op, val);
1749                                 got += GiveValue(e, ammo_plasma, op, val);
1750                                 got += GiveValue(e, ammo_shells, op, val);
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 got += GiveValue(e, ammo_rockets, op, val);
1753                                 got += GiveValue(e, ammo_fuel, op, val);
1754                                 break;
1755                         case "unlimited_ammo":
1756                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1757                                 break;
1758                         case "unlimited_weapon_ammo":
1759                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1760                                 break;
1761                         case "unlimited_superweapons":
1762                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                                 break;
1764                         case "jetpack":
1765                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1766                                 break;
1767                         case "fuel_regen":
1768                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1769                                 break;
1770                         case "strength":
1771                                 got += GiveValue(e, strength_finished, op, val);
1772                                 break;
1773                         case "invincible":
1774                                 got += GiveValue(e, invincible_finished, op, val);
1775                                 break;
1776                         case "superweapons":
1777                                 got += GiveValue(e, superweapons_finished, op, val);
1778                                 break;
1779                         case "cells":
1780                                 got += GiveValue(e, ammo_cells, op, val);
1781                                 break;
1782                         case "plasma":
1783                                 got += GiveValue(e, ammo_plasma, op, val);
1784                                 break;
1785                         case "shells":
1786                                 got += GiveValue(e, ammo_shells, op, val);
1787                                 break;
1788                         case "nails":
1789                         case "bullets":
1790                                 got += GiveValue(e, ammo_nails, op, val);
1791                                 break;
1792                         case "rockets":
1793                                 got += GiveValue(e, ammo_rockets, op, val);
1794                                 break;
1795                         case "health":
1796                                 got += GiveValue(e, health, op, val);
1797                                 break;
1798                         case "armor":
1799                                 got += GiveValue(e, armorvalue, op, val);
1800                                 break;
1801                         case "fuel":
1802                                 got += GiveValue(e, ammo_fuel, op, val);
1803                                 break;
1804                         default:
1805                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1806                                 {
1807                                         got += GiveBuff(e, it, op, val);
1808                                         break;
1809                                 });
1810                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1811                     got += GiveWeapon(e, it.m_id, op, val);
1812                     break;
1813                                 });
1814                                 break;
1815                 }
1816                 val = 999;
1817                 op = OP_SET;
1818         }
1819
1820         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1821         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1822         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1823         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1824         FOREACH(Weapons, it != WEP_Null, {
1825                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1826                 if(!(save_weapons & (it.m_wepset)))
1827                         if(e.weapons & (it.m_wepset))
1828                                 it.wr_init(it);
1829         });
1830         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1831         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1832         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1833         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1834         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1835         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1836         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1837         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1838         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1839         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1840         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1841
1842         if(e.superweapons_finished <= 0)
1843                 if(e.weapons & WEPSET_SUPERWEAPONS)
1844                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1845
1846         if(e.strength_finished <= 0)
1847                 e.strength_finished = 0;
1848         else
1849                 e.strength_finished += time;
1850         if(e.invincible_finished <= 0)
1851                 e.invincible_finished = 0;
1852         else
1853                 e.invincible_finished += time;
1854         if(e.superweapons_finished <= 0)
1855                 e.superweapons_finished = 0;
1856         else
1857                 e.superweapons_finished += time;
1858
1859         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1860         {
1861                 .entity weaponentity = weaponentities[slot];
1862                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1863                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1864                         _switchweapon |= BIT(slot);
1865         }
1866
1867         if(_switchweapon)
1868         {
1869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1870                 {
1871                         .entity weaponentity = weaponentities[slot];
1872                         if(_switchweapon & BIT(slot))
1873                         {
1874                                 Weapon wep = w_getbestweapon(e, weaponentity);
1875                                 if(wep != e.(weaponentity).m_switchweapon)
1876                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1877                         }
1878                 }
1879         }
1880
1881         return got;
1882 }
1883 #endif