qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 float adjust_respawntime(float normal_respawntime) {
 639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 640         float o = autocvar_g_pickup_respawntime_scaling_offset;
 641         float l = autocvar_g_pickup_respawntime_scaling_linear;
 642
 643         if (r == 0 && l == 1) {
 644                 return normal_respawntime;
 645         }
 646
 647         CheckAllowedTeams(NULL);
 648         GetTeamCounts(NULL);
 649         int players = 0;
 650         if (c1 != -1) players += c1;
 651         if (c2 != -1) players += c2;
 652         if (c3 != -1) players += c3;
 653         if (c4 != -1) players += c4;
 654
 655         if (players >= 2) {
 656                 return normal_respawntime * (r / (players + o) + l);
 657         } else {
 658                 return normal_respawntime;
 659         }
 660 }
 661
 662 void Item_ScheduleRespawn(entity e)
 663 {
 664         if(e.respawntime > 0)
 665         {
 666                 Item_Show(e, 0);
 667
 668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 670
 671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 673                 Item_ScheduleRespawnIn(e, actual_time);
 674         }
 675         else // if respawntime is -1, this item does not respawn
 676                 Item_Show(e, -1);
 677 }
 678
 679 void Item_ScheduleInitialRespawn(entity e)
 680 {
 681         Item_Show(e, 0);
 682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 683 }
 684
 685 int GetResourceType(.float resource_property)
 686 {
 687         switch (resource_property)
 688         {
 689                 case health: { return RESOURCE_HEALTH; }
 690                 case armorvalue: { return RESOURCE_ARMOR; }
 691                 case ammo_shells: { return RESOURCE_SHELLS; }
 692                 case ammo_nails: { return RESOURCE_BULLETS; }
 693                 case ammo_rockets: { return RESOURCE_ROCKETS; }
 694                 case ammo_cells: { return RESOURCE_CELLS; }
 695                 case ammo_plasma: { return RESOURCE_PLASMA; }
 696                 case ammo_fuel: { return RESOURCE_FUEL; }
 697         }
 698         error("GetResourceType: Invalid property.");
 699         return 0;
 700 }
 701
 702 .float GetResourceProperty(int resource_type)
 703 {
 704         switch (resource_type)
 705         {
 706                 case RESOURCE_HEALTH: { return health; }
 707                 case RESOURCE_ARMOR: { return armorvalue; }
 708                 case RESOURCE_SHELLS: { return ammo_shells; }
 709                 case RESOURCE_BULLETS: { return ammo_nails; }
 710                 case RESOURCE_ROCKETS: { return ammo_rockets; }
 711                 case RESOURCE_CELLS: { return ammo_cells; }
 712                 case RESOURCE_PLASMA: { return ammo_plasma; }
 713                 case RESOURCE_FUEL: { return ammo_fuel; }
 714         }
 715         error("GetResourceProperty: Invalid resource type.");
 716         return health;
 717 }
 718
 719 float GetResourceLimit(int resource_type)
 720 {
 721         float limit;
 722         switch (resource_type)
 723         {
 724                 case RESOURCE_HEALTH:
 725                 {
 726                         limit = autocvar_g_balance_health_limit;
 727                         break;
 728                 }
 729                 case RESOURCE_ARMOR:
 730                 {
 731                         limit = autocvar_g_balance_armor_limit;
 732                         break;
 733                 }
 734                 case RESOURCE_SHELLS:
 735                 {
 736                         limit = g_pickup_shells_max;
 737                         break;
 738                 }
 739                 case RESOURCE_BULLETS:
 740                 {
 741                         limit = g_pickup_nails_max;
 742                         break;
 743                 }
 744                 case RESOURCE_ROCKETS:
 745                 {
 746                         limit = g_pickup_rockets_max;
 747                         break;
 748                 }
 749                 case RESOURCE_CELLS:
 750                 {
 751                         limit = g_pickup_cells_max;
 752                         break;
 753                 }
 754                 case RESOURCE_PLASMA:
 755                 {
 756                         limit = g_pickup_plasma_max;
 757                         break;
 758                 }
 759                 case RESOURCE_FUEL:
 760                 {
 761                         limit = g_pickup_fuel_max;
 762                         break;
 763                 }
 764                 default:
 765                 {
 766                         error("GetResourceLimit: Invalid resource type.");
 767                         return 0;
 768                 }
 769         }
 770         MUTATOR_CALLHOOK(GetResourceLimit, resource_type, limit);
 771         limit = M_ARGV(1, float);
 772         if (limit > RESOURCE_AMOUNT_HARD_LIMIT)
 773         {
 774                 limit = RESOURCE_AMOUNT_HARD_LIMIT
 775         }
 776         return limit;
 777 }
 778
 779 void GivePlayerResource(entity player, int resource_type, float amount)
 780 {
 781         if (amount == 0)
 782         {
 783                 return;
 784         }
 785         bool forbid = MUTATOR_CALLHOOK(GivePlayerResource, player, resource_type,
 786                 amount);
 787         if (forbid)
 788         {
 789                 return;
 790         }
 791         resource_type = M_ARGV(1, int);
 792         amount = M_ARGV(2, float);
 793         .float resource_property = GetResourceProperty(resource_type);
 794         float max_amount = GetResourceLimit(resource_type);
 795         player.(resource_property) = bound(player.(resource_property),
 796                 player.(resource_property) + amount, max_amount);
 797         switch (resource_type)
 798         {
 799                 case RESOURCE_HEALTH:
 800                 {
 801                         player.pauserothealth_finished = max(player.pauserothealth_finished,
 802                                 time + autocvar_g_balance_pause_health_rot);
 803                         return;
 804                 }
 805                 case RESOURCE_ARMOR:
 806                 {
 807                         player.pauserotarmor_finished = max(player.pauserotarmor_finished,
 808                                 time + autocvar_g_balance_pause_armor_rot);
 809                         return;
 810                 }
 811                 case RESOURCE_FUEL:
 812                 {
 813                         player.pauserotfuel_finished = max(player.pauserotfuel_finished,
 814                                 time + autocvar_g_balance_pause_fuel_rot);
 815                         return;
 816                 }
 817         }
 818 }
 819
 820 void GivePlayerResourceViaProperty(entity player, .float resource_property,
 821         float amount)
 822 {
 823         GivePlayerResource(player, GetResourceType(resource_property), amount);
 824 }
 825
 826 void GivePlayerHealth(entity player, float amount)
 827 {
 828         GivePlayerResource(player, RESOURCE_HEALTH, amount);
 829 }
 830
 831 void GivePlayerArmor(entity player, float amount)
 832 {
 833         GivePlayerResource(player, RESOURCE_ARMOR, amount);
 834 }
 835
 836 void GivePlayerFuel(entity player, float amount)
 837 {
 838         GivePlayerResource(player, RESOURCE_FUEL, amount);
 839 }
 840
 841 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
 842 {
 843         if (!item.(ammotype))
 844                 return false;
 845
 846         if (item.spawnshieldtime)
 847         {
 848                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 849                 {
 850                         float amount = item.(ammotype);
 851                         if ((player.(ammotype) + amount) > ammomax)
 852                         {
 853                                 amount = ammomax - player.(ammotype);
 854                         }
 855                         GivePlayerResourceViaProperty(player, ammotype, amount);
 856                         return true;
 857                 }
 858         }
 859         else if(g_weapon_stay == 2)
 860         {
 861                 float mi = min(item.(ammotype), ammomax);
 862                 if (player.(ammotype) < mi)
 863                 {
 864                         GivePlayerResourceViaProperty(player, ammotype, mi -
 865                                 player.(ammotype));
 866                 }
 867                 return true;
 868         }
 869         return false;
 870 }
 871
 872 float Item_GiveTo(entity item, entity player)
 873 {
 874         float pickedup;
 875
 876         // if nothing happens to player, just return without taking the item
 877         pickedup = false;
 878         int _switchweapon = 0;
 879         // in case the player has autoswitch enabled do the following:
 880         // if the player is using their best weapon before items are given, they
 881         // probably want to switch to an even better weapon after items are given
 882
 883         if(CS(player).autoswitch)
 884         {
 885                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 886                 {
 887                         .entity weaponentity = weaponentities[slot];
 888                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 889                         {
 890                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 891                                         _switchweapon |= BIT(slot);
 892
 893                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 894                                         _switchweapon |= BIT(slot);
 895                         }
 896                 }
 897         }
 898         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
 899         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
 900         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
 901         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
 902         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
 903         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
 904         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
 905         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 906         if (item.itemdef.instanceOfWeaponPickup)
 907         {
 908                 WepSet w;
 909                 w = item.weapons;
 910                 w &= ~player.weapons;
 911
 912                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 913                 {
 914                         pickedup = true;
 915                         FOREACH(Weapons, it != WEP_Null, {
 916                                 if(w & (it.m_wepset))
 917                                 {
 918                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 919                                         {
 920                                                 .entity weaponentity = weaponentities[slot];
 921                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 922                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 923                                         }
 924                                         W_GiveWeapon(player, it.m_id);
 925                                 }
 926                         });
 927                 }
 928         }
 929
 930         if (item.itemdef.instanceOfPowerup)
 931         {
 932                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 933                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 934                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 935                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 936         }
 937
 938         int its;
 939         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 940         {
 941                 pickedup = true;
 942                 player.items |= its;
 943                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 944         }
 945
 946         if (item.strength_finished)
 947         {
 948                 pickedup = true;
 949                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 950         }
 951         if (item.invincible_finished)
 952         {
 953                 pickedup = true;
 954                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 955         }
 956         if (item.superweapons_finished)
 957         {
 958                 pickedup = true;
 959                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 960         }
 961
 962 LABEL(skip)
 963
 964         // always eat teamed entities
 965         if(item.team)
 966                 pickedup = true;
 967
 968         if (!pickedup)
 969                 return 0;
 970
 971         // crude hack to enforce switching weapons
 972         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 973         {
 974                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 975                 {
 976                         .entity weaponentity = weaponentities[slot];
 977                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 978                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 979                 }
 980                 return 1;
 981         }
 982
 983         if(_switchweapon)
 984         {
 985                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 986                 {
 987                         .entity weaponentity = weaponentities[slot];
 988                         if(_switchweapon & BIT(slot))
 989                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 990                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 991                 }
 992         }
 993
 994         return 1;
 995 }
 996
 997 void Item_Touch(entity this, entity toucher)
 998 {
 999
1000         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
1001         if (this.classname == "droppedweapon")
1002         {
1003                 if (ITEM_TOUCH_NEEDKILL())
1004                 {
1005                         delete(this);
1006                         return;
1007                 }
1008         }
1009
1010         if(!(toucher.flags & FL_PICKUPITEMS)
1011         || STAT(FROZEN, toucher)
1012         || IS_DEAD(toucher)
1013         || (this.solid != SOLID_TRIGGER)
1014         || (this.owner == toucher)
1015         || (time < this.item_spawnshieldtime)
1016         ) { return; }
1017
1018         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
1019         {
1020                 case MUT_ITEMTOUCH_RETURN: { return; }
1021                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
1022         }
1023
1024         toucher = M_ARGV(1, entity);
1025
1026         if (this.classname == "droppedweapon")
1027         {
1028                 this.strength_finished = max(0, this.strength_finished - time);
1029                 this.invincible_finished = max(0, this.invincible_finished - time);
1030                 this.superweapons_finished = max(0, this.superweapons_finished - time);
1031         }
1032         entity it = this.itemdef;
1033         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
1034         if (!gave)
1035         {
1036                 if (this.classname == "droppedweapon")
1037                 {
1038                         // undo what we did above
1039                         this.strength_finished += time;
1040                         this.invincible_finished += time;
1041                         this.superweapons_finished += time;
1042                 }
1043                 return;
1044         }
1045
1046 LABEL(pickup)
1047
1048         toucher.last_pickup = time;
1049
1050         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1051         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
1052
1053         if (this.classname == "droppedweapon")
1054                 delete(this);
1055         else if (this.spawnshieldtime)
1056         {
1057                 entity e;
1058                 if(this.team)
1059                 {
1060                         RandomSelection_Init();
1061                         IL_EACH(g_items, it.team == this.team,
1062                         {
1063                                 if(it.itemdef) // is a registered item
1064                                 {
1065                                         Item_Show(it, -1);
1066                                         RandomSelection_AddEnt(it, it.cnt, 0);
1067                                 }
1068                         });
1069                         e = RandomSelection_chosen_ent;
1070                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
1071                 }
1072                 else
1073                         e = this;
1074                 Item_ScheduleRespawn(e);
1075         }
1076 }
1077
1078 void Item_Reset(entity this)
1079 {
1080         Item_Show(this, !this.state);
1081         setorigin(this, this.origin);
1082
1083         if (this.classname != "droppedweapon")
1084         {
1085                 setthink(this, Item_Think);
1086                 this.nextthink = time;
1087
1088                 if (this.waypointsprite_attached)
1089                         WaypointSprite_Kill(this.waypointsprite_attached);
1090
1091                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1092                         Item_ScheduleInitialRespawn(this);
1093         }
1094 }
1095
1096 void Item_FindTeam(entity this)
1097 {
1098         entity e;
1099
1100         if(this.effects & EF_NODRAW)
1101         {
1102                 // marker for item team search
1103                 LOG_TRACE("Initializing item team ", ftos(this.team));
1104                 RandomSelection_Init();
1105                 IL_EACH(g_items, it.team == this.team,
1106                 {
1107                         if(it.itemdef) // is a registered item
1108                                 RandomSelection_AddEnt(it, it.cnt, 0);
1109                 });
1110
1111                 e = RandomSelection_chosen_ent;
1112                 e.state = 0;
1113                 Item_Show(e, 1);
1114
1115                 IL_EACH(g_items, it.team == this.team,
1116                 {
1117                         if(it.itemdef) // is a registered item
1118                         {
1119                                 if(it != e)
1120                                 {
1121                                         // make it non-spawned
1122                                         Item_Show(it, -1);
1123                                         it.state = 1; // state 1 = initially hidden item, apparently
1124                                 }
1125                                 it.effects &= ~EF_NODRAW;
1126                         }
1127                 });
1128
1129                 Item_Reset(this);
1130         }
1131 }
1132
1133 // Savage: used for item garbage-collection
1134 void RemoveItem(entity this)
1135 {
1136         if(wasfreed(this) || !this) { return; }
1137         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1138         delete(this);
1139 }
1140
1141 // pickup evaluation functions
1142 // these functions decide how desirable an item is to the bots
1143
1144 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1145
1146 float weapon_pickupevalfunc(entity player, entity item)
1147 {
1148         // See if I have it already
1149         if(player.weapons & item.weapons)
1150         {
1151                 // If I can pick it up
1152                 if(!item.spawnshieldtime)
1153                         return 0;
1154                 return ammo_pickupevalfunc(player, item);
1155         }
1156
1157         // reduce weapon value if bot already got a good arsenal
1158         float c = 1;
1159         int weapons_value = 0;
1160         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1161                 weapons_value += it.bot_pickupbasevalue;
1162         });
1163         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1164
1165         return item.bot_pickupbasevalue * c;
1166 }
1167
1168 float ammo_pickupevalfunc(entity player, entity item)
1169 {
1170         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1171         entity wpn = NULL;
1172         float c = 0;
1173         float rating = 0;
1174
1175         // Detect needed ammo
1176         if(item.itemdef.instanceOfWeaponPickup)
1177         {
1178                 entity ammo = NULL;
1179                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1180                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1181                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1182                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1183                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1184                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1185
1186                 if(!ammo)
1187                         return 0;
1188                 wpn = item;
1189                 rating = ammo.m_botvalue;
1190         }
1191         else
1192         {
1193                 FOREACH(Weapons, it != WEP_Null, {
1194                         if(!(player.weapons & (it.m_wepset)))
1195                                 continue;
1196
1197                         switch(it.ammo_field)
1198                         {
1199                                 case ammo_shells:  need_shells  = true; break;
1200                                 case ammo_nails:   need_nails   = true; break;
1201                                 case ammo_rockets: need_rockets = true; break;
1202                                 case ammo_cells:   need_cells   = true; break;
1203                                 case ammo_plasma:  need_plasma  = true; break;
1204                                 case ammo_fuel:    need_fuel    = true; break;
1205                         }
1206                 });
1207                 rating = item.bot_pickupbasevalue;
1208         }
1209
1210         float noammorating = 0.5;
1211
1212         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1213                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1214
1215         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1216                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1217
1218         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1219                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1220
1221         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1222                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1223
1224         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1225                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1226
1227         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1228                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1229
1230         rating *= min(c, 2);
1231         if(wpn)
1232                 rating += wpn.bot_pickupbasevalue * 0.1;
1233         return rating;
1234 }
1235
1236 .int item_group;
1237 .int item_group_count;
1238 float healtharmor_pickupevalfunc(entity player, entity item)
1239 {
1240         float c = 0;
1241         float rating = item.bot_pickupbasevalue;
1242
1243         float itemarmor = item.armorvalue;
1244         float itemhealth = item.health;
1245
1246         if(item.item_group)
1247         {
1248                 itemarmor *= min(4, item.item_group_count);
1249                 itemhealth *= min(4, item.item_group_count);
1250         }
1251
1252         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1253                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1254
1255         if (itemhealth && (player.health < item.max_health))
1256                 c = itemhealth / max(1, player.health);
1257
1258         rating *= min(2, c);
1259         return rating;
1260 }
1261
1262 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1263 {
1264         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1265                 RemoveItem(this);
1266 }
1267
1268 void item_use(entity this, entity actor, entity trigger)
1269 {
1270         // use the touch function to handle collection
1271         gettouch(this)(this, actor);
1272 }
1273
1274 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1275 {
1276         string itemname = def.m_name;
1277         Model itemmodel = def.m_model;
1278     Sound pickupsound = def.m_sound;
1279         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1280         float pickupbasevalue = def.m_botvalue;
1281         int itemflags = def.m_itemflags;
1282
1283         startitem_failed = false;
1284
1285         this.item_model_ent = itemmodel;
1286     this.item_pickupsound_ent = pickupsound;
1287
1288     if(def.m_iteminit)
1289         def.m_iteminit(this);
1290
1291         if(!this.respawntime) // both need to be set
1292         {
1293                 this.respawntime = defaultrespawntime;
1294                 this.respawntimejitter = defaultrespawntimejitter;
1295         }
1296
1297         if(!this.pickup_anyway && def.m_pickupanyway)
1298                 this.pickup_anyway = def.m_pickupanyway();
1299
1300         int itemid = def.m_itemid;
1301         this.items = itemid;
1302         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1303         this.weapon = weaponid;
1304
1305         if(!this.fade_end)
1306         {
1307                 this.fade_start = autocvar_g_items_mindist;
1308                 this.fade_end = autocvar_g_items_maxdist;
1309         }
1310
1311         if(weaponid)
1312                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1313
1314         this.flags = FL_ITEM | itemflags;
1315         IL_PUSH(g_items, this);
1316
1317         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1318         {
1319                 startitem_failed = true;
1320                 delete(this);
1321                 return;
1322         }
1323
1324         // is it a dropped weapon?
1325         if (this.classname == "droppedweapon")
1326         {
1327                 this.reset = SUB_Remove;
1328                 // it's a dropped weapon
1329                 set_movetype(this, MOVETYPE_TOSS);
1330
1331                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1332                 setthink(this, RemoveItem);
1333                 this.nextthink = time + 20;
1334
1335                 this.takedamage = DAMAGE_YES;
1336                 this.event_damage = Item_Damage;
1337
1338                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1339                 {
1340                         // if item is worthless after a timer, have it expire then
1341                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1342                 }
1343
1344                 // don't drop if in a NODROP zone (such as lava)
1345                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1346                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1347                 {
1348                         startitem_failed = true;
1349                         delete(this);
1350                         return;
1351                 }
1352         }
1353         else
1354         {
1355                 if(!have_pickup_item(this))
1356                 {
1357                         startitem_failed = true;
1358                         delete(this);
1359                         return;
1360                 }
1361
1362                 if(this.angles != '0 0 0')
1363                         this.SendFlags |= ISF_ANGLES;
1364
1365                 this.reset = Item_Reset;
1366                 // it's a level item
1367                 if(this.spawnflags & 1)
1368                         this.noalign = 1;
1369                 if (this.noalign > 0)
1370                         set_movetype(this, MOVETYPE_NONE);
1371                 else
1372                         set_movetype(this, MOVETYPE_TOSS);
1373                 // do item filtering according to game mode and other things
1374                 if (this.noalign <= 0)
1375                 {
1376                         // first nudge it off the floor a little bit to avoid math errors
1377                         setorigin(this, this.origin + '0 0 1');
1378                         // set item size before we spawn a spawnfunc_waypoint
1379                         setsize(this, def.m_mins, def.m_maxs);
1380                         this.SendFlags |= ISF_SIZE;
1381                         // note droptofloor returns false if stuck/or would fall too far
1382                         if (!this.noalign)
1383                                 droptofloor(this);
1384                         waypoint_spawnforitem(this);
1385                 }
1386
1387                 /*
1388                  * can't do it that way, as it would break maps
1389                  * TODO make a target_give like entity another way, that perhaps has
1390                  * the weapon name in a key
1391                 if(this.targetname)
1392                 {
1393                         // target_give not yet supported; maybe later
1394                         print("removed targeted ", this.classname, "\n");
1395                         startitem_failed = true;
1396                         delete(this);
1397                         return;
1398                 }
1399                 */
1400
1401                 if(this.targetname != "" && (this.spawnflags & 16))
1402                         this.use = item_use;
1403
1404                 if(autocvar_spawn_debug >= 2)
1405                 {
1406             // why not flags & fl_item?
1407                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1408                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1409                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1410                 error("Mapper sucks.");
1411             });
1412                         this.is_item = true;
1413                 }
1414
1415                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1416
1417                 precache_model(this.model);
1418                 precache_sound(this.item_pickupsound);
1419
1420                 if (   def.instanceOfPowerup
1421                         || def.instanceOfWeaponPickup
1422                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1423                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1424                         || (itemid & (IT_KEY1 | IT_KEY2))
1425                 ) this.target = "###item###"; // for finding the nearest item using find()
1426
1427                 Item_ItemsTime_SetTime(this, 0);
1428         }
1429
1430         this.bot_pickup = true;
1431         this.bot_pickupevalfunc = pickupevalfunc;
1432         this.bot_pickupbasevalue = pickupbasevalue;
1433         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1434         this.netname = itemname;
1435         settouch(this, Item_Touch);
1436         setmodel(this, MDL_Null); // precision set below
1437         //this.effects |= EF_LOWPRECISION;
1438
1439         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1440
1441         this.SendFlags |= ISF_SIZE;
1442
1443         if (!(this.spawnflags & 1024)) {
1444                 if(def.instanceOfPowerup)
1445                         this.ItemStatus |= ITS_ANIMATE1;
1446
1447                 if(this.armorvalue || this.health)
1448                         this.ItemStatus |= ITS_ANIMATE2;
1449         }
1450
1451         if(def.instanceOfWeaponPickup)
1452         {
1453                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1454                         this.colormap = 1024; // color shirt=0 pants=0 grey
1455                 else
1456                         this.gravity = 1;
1457                 if (!(this.spawnflags & 1024))
1458                         this.ItemStatus |= ITS_ANIMATE1;
1459                 this.SendFlags |= ISF_COLORMAP;
1460         }
1461
1462         this.state = 0;
1463         if(this.team) // broken, no idea why.
1464         {
1465                 if(!this.cnt)
1466                         this.cnt = 1; // item probability weight
1467
1468                 this.effects |= EF_NODRAW; // marker for item team search
1469                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1470         }
1471         else
1472                 Item_Reset(this);
1473
1474         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1475
1476         // call this hook after everything else has been done
1477         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1478         {
1479                 startitem_failed = true;
1480                 delete(this);
1481                 return;
1482         }
1483
1484         setItemGroup(this);
1485 }
1486
1487 void StartItem(entity this, GameItem def)
1488 {
1489     _StartItem(
1490         this,
1491         this.itemdef = def,
1492         def.m_respawntime(), // defaultrespawntime
1493         def.m_respawntimejitter() // defaultrespawntimejitter
1494         );
1495 }
1496
1497 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1498 int group_count = 1;
1499
1500 void setItemGroup(entity this)
1501 {
1502         if(!IS_SMALL(this.itemdef))
1503                 return;
1504
1505         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1506         {
1507                 if(!this.item_group)
1508                 {
1509                         if(!it.item_group)
1510                         {
1511                                 it.item_group = group_count;
1512                                 group_count++;
1513                         }
1514                         this.item_group = it.item_group;
1515                 }
1516                 else // spawning item is already part of a item_group X
1517                 {
1518                         if(!it.item_group)
1519                                 it.item_group = this.item_group;
1520                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1521                         {
1522                                 int grY = it.item_group;
1523                                 // move all items of item_group Y to item_group X
1524                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1525                                 {
1526                                         if(it.item_group == grY)
1527                                                 it.item_group = this.item_group;
1528                                 });
1529                         }
1530                 }
1531         });
1532 }
1533
1534 void setItemGroupCount()
1535 {
1536         for (int k = 1; k <= group_count; k++)
1537         {
1538                 int count = 0;
1539                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1540                 if (count)
1541                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1542         }
1543 }
1544
1545 spawnfunc(item_rockets)
1546 {
1547     StartItem(this, ITEM_Rockets);
1548 }
1549
1550 spawnfunc(item_bullets)
1551 {
1552         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1553            (this.classname != "droppedweapon"))
1554         {
1555                 weaponswapping = true;
1556                 spawnfunc_item_shells(this);
1557                 weaponswapping = false;
1558                 return;
1559         }
1560
1561     StartItem(this, ITEM_Bullets);
1562 }
1563
1564 spawnfunc(item_cells)
1565 {
1566         StartItem(this, ITEM_Cells);
1567 }
1568
1569 spawnfunc(item_plasma)
1570 {
1571         StartItem(this, ITEM_Plasma);
1572 }
1573
1574 spawnfunc(item_shells)
1575 {
1576         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1577            (this.classname != "droppedweapon"))
1578         {
1579                 weaponswapping = true;
1580                 spawnfunc_item_bullets(this);
1581                 weaponswapping = false;
1582                 return;
1583         }
1584
1585         StartItem(this, ITEM_Shells);
1586 }
1587
1588 spawnfunc(item_armor_small)
1589 {
1590         StartItem(this, ITEM_ArmorSmall);
1591 }
1592
1593 spawnfunc(item_armor_medium)
1594 {
1595         StartItem(this, ITEM_ArmorMedium);
1596 }
1597
1598 spawnfunc(item_armor_big)
1599 {
1600         StartItem(this, ITEM_ArmorBig);
1601 }
1602
1603 spawnfunc(item_armor_mega)
1604 {
1605         StartItem(this, ITEM_ArmorMega);
1606 }
1607
1608 spawnfunc(item_health_small)
1609 {
1610         StartItem(this, ITEM_HealthSmall);
1611 }
1612
1613 spawnfunc(item_health_medium)
1614 {
1615     StartItem(this, ITEM_HealthMedium);
1616 }
1617
1618 spawnfunc(item_health_big)
1619 {
1620         StartItem(this, ITEM_HealthBig);
1621 }
1622
1623 spawnfunc(item_health_mega)
1624 {
1625     StartItem(this, ITEM_HealthMega);
1626 }
1627
1628 // support old misnamed entities
1629 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1630 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1631 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1632 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1633 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1634 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1635 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1636
1637 spawnfunc(item_strength)
1638 {
1639         StartItem(this, ITEM_Strength);
1640 }
1641
1642 spawnfunc(item_invincible)
1643 {
1644         StartItem(this, ITEM_Shield);
1645 }
1646
1647 // compatibility:
1648 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1649
1650 void target_items_use(entity this, entity actor, entity trigger)
1651 {
1652         if(actor.classname == "droppedweapon")
1653         {
1654                 EXACTTRIGGER_TOUCH(this, trigger);
1655                 delete(actor);
1656                 return;
1657         }
1658
1659         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1660                 return;
1661
1662         if(trigger.solid == SOLID_TRIGGER)
1663         {
1664                 EXACTTRIGGER_TOUCH(this, trigger);
1665         }
1666
1667         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1668         {
1669                 delete(it);
1670         });
1671
1672         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1673                 centerprint(actor, this.message);
1674 }
1675
1676 spawnfunc(target_items)
1677 {
1678         int n;
1679         string s;
1680
1681         this.use = target_items_use;
1682         if(!this.strength_finished)
1683                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1684         if(!this.invincible_finished)
1685                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1686         if(!this.superweapons_finished)
1687                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1688
1689         n = tokenize_console(this.netname);
1690         if(argv(0) == "give")
1691         {
1692                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1693         }
1694         else
1695         {
1696                 for(int j = 0; j < n; ++j)
1697                 {
1698                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1699                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1700                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1701                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1702                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1703                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1704                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1705                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1706                         else
1707                         {
1708                                 FOREACH(Buffs, it != BUFF_Null,
1709                                 {
1710                                         s = Buff_UndeprecateName(argv(j));
1711                                         if(s == it.m_name)
1712                                         {
1713                                                 this.buffs |= (it.m_itemid);
1714                                                 break;
1715                                         }
1716                                 });
1717                                 FOREACH(Weapons, it != WEP_Null, {
1718                                         s = W_UndeprecateName(argv(j));
1719                                         if(s == it.netname)
1720                                         {
1721                                                 this.weapons |= (it.m_wepset);
1722                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1723                                                         it.wr_init(it);
1724                                                 break;
1725                                         }
1726                                 });
1727                         }
1728                 }
1729
1730                 string itemprefix, valueprefix;
1731                 if(this.spawnflags == 0)
1732                 {
1733                         itemprefix = "";
1734                         valueprefix = "";
1735                 }
1736                 else if(this.spawnflags == 1)
1737                 {
1738                         itemprefix = "max ";
1739                         valueprefix = "max ";
1740                 }
1741                 else if(this.spawnflags == 2)
1742                 {
1743                         itemprefix = "min ";
1744                         valueprefix = "min ";
1745                 }
1746                 else if(this.spawnflags == 4)
1747                 {
1748                         itemprefix = "minus ";
1749                         valueprefix = "max ";
1750                 }
1751                 else
1752                 {
1753                         error("invalid spawnflags");
1754                         itemprefix = valueprefix = string_null;
1755                 }
1756
1757                 this.netname = "";
1758                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1759                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1760                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1761                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1762                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1763                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1764                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1765                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1766                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1767                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1768                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1769                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1770                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1771                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1772                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1773                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1774                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1775         }
1776         this.netname = strzone(this.netname);
1777         //print(this.netname, "\n");
1778
1779         n = tokenize_console(this.netname);
1780         for(int j = 0; j < n; ++j)
1781         {
1782                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1783             it.wr_init(it);
1784             break;
1785                 });
1786         }
1787 }
1788
1789 spawnfunc(item_fuel)
1790 {
1791         StartItem(this, ITEM_JetpackFuel);
1792 }
1793
1794 spawnfunc(item_fuel_regen)
1795 {
1796         if(start_items & ITEM_JetpackRegen.m_itemid)
1797         {
1798                 spawnfunc_item_fuel(this);
1799                 return;
1800         }
1801         StartItem(this, ITEM_JetpackRegen);
1802 }
1803
1804 spawnfunc(item_jetpack)
1805 {
1806         if(start_items & ITEM_Jetpack.m_itemid)
1807         {
1808                 spawnfunc_item_fuel(this);
1809                 return;
1810         }
1811         StartItem(this, ITEM_Jetpack);
1812 }
1813
1814 float GiveWeapon(entity e, float wpn, float op, float val)
1815 {
1816         WepSet v0, v1;
1817         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1818         v0 = (e.weapons & s);
1819         switch(op)
1820         {
1821                 case OP_SET:
1822                         if(val > 0)
1823                                 e.weapons |= s;
1824                         else
1825                                 e.weapons &= ~s;
1826                         break;
1827                 case OP_MIN:
1828                 case OP_PLUS:
1829                         if(val > 0)
1830                                 e.weapons |= s;
1831                         break;
1832                 case OP_MAX:
1833                         if(val <= 0)
1834                                 e.weapons &= ~s;
1835                         break;
1836                 case OP_MINUS:
1837                         if(val > 0)
1838                                 e.weapons &= ~s;
1839                         break;
1840         }
1841         v1 = (e.weapons & s);
1842         return (v0 != v1);
1843 }
1844
1845 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1846 {
1847         bool had_buff = (e.buffs & thebuff.m_itemid);
1848         switch(op)
1849         {
1850                 case OP_SET:
1851                         if(val > 0)
1852                                 e.buffs |= thebuff.m_itemid;
1853                         else
1854                                 e.buffs &= ~thebuff.m_itemid;
1855                         break;
1856                 case OP_MIN:
1857                 case OP_PLUS:
1858                         if(val > 0)
1859                                 e.buffs |= thebuff.m_itemid;
1860                         break;
1861                 case OP_MAX:
1862                         if(val <= 0)
1863                                 e.buffs &= ~thebuff.m_itemid;
1864                         break;
1865                 case OP_MINUS:
1866                         if(val > 0)
1867                                 e.buffs &= ~thebuff.m_itemid;
1868                         break;
1869         }
1870         bool have_buff = (e.buffs & thebuff.m_itemid);
1871         return (had_buff != have_buff);
1872 }
1873
1874 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1875 {
1876         if(v1 == v0)
1877                 return;
1878         if(v1 <= v0 - t)
1879         {
1880                 if(snd_decr != NULL)
1881                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1882         }
1883         else if(v0 >= v0 + t)
1884         {
1885                 if(snd_incr != NULL)
1886                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1887         }
1888 }
1889
1890 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1891 {
1892         if(v0 < v1)
1893                 e.(rotfield) = max(e.(rotfield), time + rottime);
1894         else if(v0 > v1)
1895                 e.(regenfield) = max(e.(regenfield), time + regentime);
1896 }
1897 float GiveItems(entity e, float beginarg, float endarg)
1898 {
1899         float got, i, val, op;
1900         string cmd;
1901
1902         val = 999;
1903         op = OP_SET;
1904
1905         got = 0;
1906
1907         int _switchweapon = 0;
1908
1909         if(CS(e).autoswitch)
1910         {
1911                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1912                 {
1913                         .entity weaponentity = weaponentities[slot];
1914                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1915                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1916                                 _switchweapon |= BIT(slot);
1917                 }
1918         }
1919
1920         e.strength_finished = max(0, e.strength_finished - time);
1921         e.invincible_finished = max(0, e.invincible_finished - time);
1922         e.superweapons_finished = max(0, e.superweapons_finished - time);
1923
1924         PREGIVE(e, items);
1925         PREGIVE_WEAPONS(e);
1926         PREGIVE(e, strength_finished);
1927         PREGIVE(e, invincible_finished);
1928         PREGIVE(e, superweapons_finished);
1929         PREGIVE(e, ammo_nails);
1930         PREGIVE(e, ammo_cells);
1931         PREGIVE(e, ammo_plasma);
1932         PREGIVE(e, ammo_shells);
1933         PREGIVE(e, ammo_rockets);
1934         PREGIVE(e, ammo_fuel);
1935         PREGIVE(e, armorvalue);
1936         PREGIVE(e, health);
1937
1938         for(i = beginarg; i < endarg; ++i)
1939         {
1940                 cmd = argv(i);
1941
1942                 if(cmd == "0" || stof(cmd))
1943                 {
1944                         val = stof(cmd);
1945                         continue;
1946                 }
1947                 switch(cmd)
1948                 {
1949                         case "no":
1950                                 op = OP_MAX;
1951                                 val = 0;
1952                                 continue;
1953                         case "max":
1954                                 op = OP_MAX;
1955                                 continue;
1956                         case "min":
1957                                 op = OP_MIN;
1958                                 continue;
1959                         case "plus":
1960                                 op = OP_PLUS;
1961                                 continue;
1962                         case "minus":
1963                                 op = OP_MINUS;
1964                                 continue;
1965                         case "ALL":
1966                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1967                                 got += GiveValue(e, strength_finished, op, val);
1968                                 got += GiveValue(e, invincible_finished, op, val);
1969                                 got += GiveValue(e, superweapons_finished, op, val);
1970                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1971                         case "all":
1972                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1973                                 got += GiveValue(e, health, op, val);
1974                                 got += GiveValue(e, armorvalue, op, val);
1975                         case "allweapons":
1976                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1977                         //case "allbuffs": // all buffs makes a player god, do not want!
1978                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1979                         case "allammo":
1980                                 got += GiveValue(e, ammo_cells, op, val);
1981                                 got += GiveValue(e, ammo_plasma, op, val);
1982                                 got += GiveValue(e, ammo_shells, op, val);
1983                                 got += GiveValue(e, ammo_nails, op, val);
1984                                 got += GiveValue(e, ammo_rockets, op, val);
1985                                 got += GiveValue(e, ammo_fuel, op, val);
1986                                 break;
1987                         case "unlimited_ammo":
1988                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1989                                 break;
1990                         case "unlimited_weapon_ammo":
1991                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1992                                 break;
1993                         case "unlimited_superweapons":
1994                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1995                                 break;
1996                         case "jetpack":
1997                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1998                                 break;
1999                         case "fuel_regen":
2000                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
2001                                 break;
2002                         case "strength":
2003                                 got += GiveValue(e, strength_finished, op, val);
2004                                 break;
2005                         case "invincible":
2006                                 got += GiveValue(e, invincible_finished, op, val);
2007                                 break;
2008                         case "superweapons":
2009                                 got += GiveValue(e, superweapons_finished, op, val);
2010                                 break;
2011                         case "cells":
2012                                 got += GiveValue(e, ammo_cells, op, val);
2013                                 break;
2014                         case "plasma":
2015                                 got += GiveValue(e, ammo_plasma, op, val);
2016                                 break;
2017                         case "shells":
2018                                 got += GiveValue(e, ammo_shells, op, val);
2019                                 break;
2020                         case "nails":
2021                         case "bullets":
2022                                 got += GiveValue(e, ammo_nails, op, val);
2023                                 break;
2024                         case "rockets":
2025                                 got += GiveValue(e, ammo_rockets, op, val);
2026                                 break;
2027                         case "health":
2028                                 got += GiveValue(e, health, op, val);
2029                                 break;
2030                         case "armor":
2031                                 got += GiveValue(e, armorvalue, op, val);
2032                                 break;
2033                         case "fuel":
2034                                 got += GiveValue(e, ammo_fuel, op, val);
2035                                 break;
2036                         default:
2037                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
2038                                 {
2039                                         got += GiveBuff(e, it, op, val);
2040                                         break;
2041                                 });
2042                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
2043                     got += GiveWeapon(e, it.m_id, op, val);
2044                     break;
2045                                 });
2046                                 break;
2047                 }
2048                 val = 999;
2049                 op = OP_SET;
2050         }
2051
2052         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
2053         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
2054         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
2055         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
2056         FOREACH(Weapons, it != WEP_Null, {
2057                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
2058                 if(!(save_weapons & (it.m_wepset)))
2059                         if(e.weapons & (it.m_wepset))
2060                                 it.wr_init(it);
2061         });
2062         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
2063         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
2064         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
2065         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
2066         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
2067         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
2068         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
2069         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
2070         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
2071         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
2072         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
2073
2074         if(e.superweapons_finished <= 0)
2075                 if(e.weapons & WEPSET_SUPERWEAPONS)
2076                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2077
2078         if(e.strength_finished <= 0)
2079                 e.strength_finished = 0;
2080         else
2081                 e.strength_finished += time;
2082         if(e.invincible_finished <= 0)
2083                 e.invincible_finished = 0;
2084         else
2085                 e.invincible_finished += time;
2086         if(e.superweapons_finished <= 0)
2087                 e.superweapons_finished = 0;
2088         else
2089                 e.superweapons_finished += time;
2090
2091         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2092         {
2093                 .entity weaponentity = weaponentities[slot];
2094                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2095                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2096                         _switchweapon |= BIT(slot);
2097         }
2098
2099         if(_switchweapon)
2100         {
2101                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2102                 {
2103                         .entity weaponentity = weaponentities[slot];
2104                         if(_switchweapon & BIT(slot))
2105                         {
2106                                 Weapon wep = w_getbestweapon(e, weaponentity);
2107                                 if(wep != e.(weaponentity).m_switchweapon)
2108                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2109                         }
2110                 }
2111         }
2112
2113         return got;
2114 }
2115 #endif