qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 float adjust_respawntime(float normal_respawntime) {
 639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 640         float o = autocvar_g_pickup_respawntime_scaling_offset;
 641         float l = autocvar_g_pickup_respawntime_scaling_linear;
 642
 643         if (r == 0 && l == 1) {
 644                 return normal_respawntime;
 645         }
 646
 647         CheckAllowedTeams(NULL);
 648         GetTeamCounts(NULL);
 649         int players = 0;
 650         if (c1 != -1) players += c1;
 651         if (c2 != -1) players += c2;
 652         if (c3 != -1) players += c3;
 653         if (c4 != -1) players += c4;
 654
 655         if (players >= 2) {
 656                 return normal_respawntime * (r / (players + o) + l);
 657         } else {
 658                 return normal_respawntime;
 659         }
 660 }
 661
 662 void Item_ScheduleRespawn(entity e)
 663 {
 664         if(e.respawntime > 0)
 665         {
 666                 Item_Show(e, 0);
 667
 668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 670
 671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 673                 Item_ScheduleRespawnIn(e, actual_time);
 674         }
 675         else // if respawntime is -1, this item does not respawn
 676                 Item_Show(e, -1);
 677 }
 678
 679 void Item_ScheduleInitialRespawn(entity e)
 680 {
 681         Item_Show(e, 0);
 682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 683 }
 684
 685 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 686         float shells, float bullets, float rockets, float cells, float plasma)
 687 {
 688         if (num_weapons == 0)
 689         {
 690                 return;
 691         }
 692         int num_potential_weapons = tokenize_console(weapon_names);
 693         for (int i = 0; i < num_weapons; ++i)
 694         {
 695                 RandomSelection_Init();
 696                 for (int j = 0; j < num_potential_weapons; ++j)
 697                 {
 698                         string weapon = argv(j);
 699                         FOREACH(Weapons, it != WEP_Null,
 700                         {
 701                                 // Finding a weapon which player doesn't have.
 702                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 703                                 {
 704                                         RandomSelection_AddEnt(it, 1, 1);
 705                                         break;
 706                                 }
 707                         });
 708                 }
 709                 if (RandomSelection_chosen_ent == NULL)
 710                 {
 711                         return;
 712                 }
 713                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 714                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 715                 {
 716                         continue;
 717                 }
 718                 if (GetResourceAmount(receiver,
 719                         RandomSelection_chosen_ent.ammo_type) != 0)
 720                 {
 721                         continue;
 722                 }
 723                 switch (RandomSelection_chosen_ent.ammo_type)
 724                 {
 725                         case (RESOURCE_SHELLS):
 726                         {
 727                                 GiveResource(receiver, RESOURCE_SHELLS, shells);
 728                                 break;
 729                         }
 730                         case (RESOURCE_BULLETS):
 731                         {
 732                                 GiveResource(receiver, RESOURCE_BULLETS, bullets);
 733                                 break;
 734                         }
 735                         case (RESOURCE_ROCKETS):
 736                         {
 737                                 GiveResource(receiver, RESOURCE_ROCKETS, rockets);
 738                                 break;
 739                         }
 740                         case (RESOURCE_CELLS):
 741                         {
 742                                 GiveResource(receiver, RESOURCE_CELLS, cells);
 743                                 break;
 744                         }
 745                         case (RESOURCE_PLASMA):
 746                         {
 747                                 GiveResource(receiver, RESOURCE_PLASMA, plasma);
 748                                 break;
 749                         }
 750                 }
 751         }
 752 }
 753
 754 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 755 {
 756         float amount = GetResourceAmount(item, resource_type);
 757         if (amount == 0)
 758         {
 759                 return false;
 760         }
 761         float player_amount = GetResourceAmount(player, resource_type);
 762         if (item.spawnshieldtime)
 763         {
 764                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 765                 {
 766                         return false;
 767                 }
 768                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 769                 return true;
 770         }
 771         if (g_weapon_stay != 2)
 772         {
 773                 return false;
 774         }
 775         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 776         return true;
 777 }
 778
 779 float Item_GiveTo(entity item, entity player)
 780 {
 781         float pickedup;
 782
 783         // if nothing happens to player, just return without taking the item
 784         pickedup = false;
 785         int _switchweapon = 0;
 786         // in case the player has autoswitch enabled do the following:
 787         // if the player is using their best weapon before items are given, they
 788         // probably want to switch to an even better weapon after items are given
 789
 790         if(CS(player).autoswitch)
 791         {
 792                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 793                 {
 794                         .entity weaponentity = weaponentities[slot];
 795                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 796                         {
 797                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 798                                         _switchweapon |= BIT(slot);
 799
 800                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 801                                         _switchweapon |= BIT(slot);
 802                         }
 803                 }
 804         }
 805         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 806         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 807         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 808         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 809         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 810         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 811         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 812         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 813         if (item.itemdef.instanceOfWeaponPickup)
 814         {
 815                 WepSet w;
 816                 w = item.weapons;
 817                 w &= ~player.weapons;
 818
 819                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 820                 {
 821                         pickedup = true;
 822                         FOREACH(Weapons, it != WEP_Null, {
 823                                 if(w & (it.m_wepset))
 824                                 {
 825                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 826                                         {
 827                                                 .entity weaponentity = weaponentities[slot];
 828                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 829                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 830                                         }
 831                                         W_GiveWeapon(player, it.m_id);
 832                                 }
 833                         });
 834                 }
 835         }
 836
 837         if (item.itemdef.instanceOfPowerup)
 838         {
 839                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 840                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 841                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 842                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 843         }
 844
 845         int its;
 846         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 847         {
 848                 pickedup = true;
 849                 player.items |= its;
 850                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 851         }
 852
 853         if (item.strength_finished)
 854         {
 855                 pickedup = true;
 856                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 857         }
 858         if (item.invincible_finished)
 859         {
 860                 pickedup = true;
 861                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 862         }
 863         if (item.superweapons_finished)
 864         {
 865                 pickedup = true;
 866                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 867         }
 868
 869 LABEL(skip)
 870
 871         // always eat teamed entities
 872         if(item.team)
 873                 pickedup = true;
 874
 875         if (!pickedup)
 876                 return 0;
 877
 878         // crude hack to enforce switching weapons
 879         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 880         {
 881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 882                 {
 883                         .entity weaponentity = weaponentities[slot];
 884                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 885                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 886                 }
 887                 return 1;
 888         }
 889
 890         if(_switchweapon)
 891         {
 892                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 893                 {
 894                         .entity weaponentity = weaponentities[slot];
 895                         if(_switchweapon & BIT(slot))
 896                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 897                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 898                 }
 899         }
 900
 901         return 1;
 902 }
 903
 904 void Item_Touch(entity this, entity toucher)
 905 {
 906
 907         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 908         if (this.classname == "droppedweapon")
 909         {
 910                 if (ITEM_TOUCH_NEEDKILL())
 911                 {
 912                         delete(this);
 913                         return;
 914                 }
 915         }
 916
 917         if(!(toucher.flags & FL_PICKUPITEMS)
 918         || STAT(FROZEN, toucher)
 919         || IS_DEAD(toucher)
 920         || (this.solid != SOLID_TRIGGER)
 921         || (this.owner == toucher)
 922         || (time < this.item_spawnshieldtime)
 923         ) { return; }
 924
 925         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 926         {
 927                 case MUT_ITEMTOUCH_RETURN: { return; }
 928                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 929         }
 930
 931         toucher = M_ARGV(1, entity);
 932
 933         if (this.classname == "droppedweapon")
 934         {
 935                 this.strength_finished = max(0, this.strength_finished - time);
 936                 this.invincible_finished = max(0, this.invincible_finished - time);
 937                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 938         }
 939         entity it = this.itemdef;
 940         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 941         if (!gave)
 942         {
 943                 if (this.classname == "droppedweapon")
 944                 {
 945                         // undo what we did above
 946                         this.strength_finished += time;
 947                         this.invincible_finished += time;
 948                         this.superweapons_finished += time;
 949                 }
 950                 return;
 951         }
 952
 953 LABEL(pickup)
 954
 955         toucher.last_pickup = time;
 956
 957         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 958         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 959
 960         if (this.classname == "droppedweapon")
 961                 delete(this);
 962         else if (this.spawnshieldtime)
 963         {
 964                 entity e;
 965                 if(this.team)
 966                 {
 967                         RandomSelection_Init();
 968                         IL_EACH(g_items, it.team == this.team,
 969                         {
 970                                 if(it.itemdef) // is a registered item
 971                                 {
 972                                         Item_Show(it, -1);
 973                                         it.scheduledrespawntime = 0;
 974                                         RandomSelection_AddEnt(it, it.cnt, 0);
 975                                 }
 976                         });
 977                         e = RandomSelection_chosen_ent;
 978                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 979                 }
 980                 else
 981                         e = this;
 982                 Item_ScheduleRespawn(e);
 983         }
 984 }
 985
 986 void Item_Reset(entity this)
 987 {
 988         Item_Show(this, !this.state);
 989         setorigin(this, this.origin);
 990
 991         if (this.classname != "droppedweapon")
 992         {
 993                 setthink(this, Item_Think);
 994                 this.nextthink = time;
 995
 996                 if (this.waypointsprite_attached)
 997                         WaypointSprite_Kill(this.waypointsprite_attached);
 998
 999                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1000                         Item_ScheduleInitialRespawn(this);
1001         }
1002 }
1003
1004 void Item_FindTeam(entity this)
1005 {
1006         entity e;
1007
1008         if(this.effects & EF_NODRAW)
1009         {
1010                 // marker for item team search
1011                 LOG_TRACE("Initializing item team ", ftos(this.team));
1012                 RandomSelection_Init();
1013                 IL_EACH(g_items, it.team == this.team,
1014                 {
1015                         if(it.itemdef) // is a registered item
1016                                 RandomSelection_AddEnt(it, it.cnt, 0);
1017                 });
1018
1019                 e = RandomSelection_chosen_ent;
1020                 e.state = 0;
1021                 Item_Show(e, 1);
1022
1023                 IL_EACH(g_items, it.team == this.team,
1024                 {
1025                         if(it.itemdef) // is a registered item
1026                         {
1027                                 if(it != e)
1028                                 {
1029                                         // make it non-spawned
1030                                         Item_Show(it, -1);
1031                                         it.state = 1; // state 1 = initially hidden item, apparently
1032                                 }
1033                                 it.effects &= ~EF_NODRAW;
1034                         }
1035                 });
1036
1037                 Item_Reset(this);
1038         }
1039 }
1040
1041 // Savage: used for item garbage-collection
1042 void RemoveItem(entity this)
1043 {
1044         if(wasfreed(this) || !this) { return; }
1045         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1046         delete(this);
1047 }
1048
1049 // pickup evaluation functions
1050 // these functions decide how desirable an item is to the bots
1051
1052 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1053
1054 float weapon_pickupevalfunc(entity player, entity item)
1055 {
1056         // See if I have it already
1057         if(player.weapons & item.weapons)
1058         {
1059                 // If I can pick it up
1060                 if(!item.spawnshieldtime)
1061                         return 0;
1062                 return ammo_pickupevalfunc(player, item);
1063         }
1064
1065         // reduce weapon value if bot already got a good arsenal
1066         float c = 1;
1067         int weapons_value = 0;
1068         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1069                 weapons_value += it.bot_pickupbasevalue;
1070         });
1071         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1072
1073         return item.bot_pickupbasevalue * c;
1074 }
1075
1076 float ammo_pickupevalfunc(entity player, entity item)
1077 {
1078         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1079         entity wpn = NULL;
1080         float c = 0;
1081         float rating = 0;
1082
1083         // Detect needed ammo
1084         if(item.itemdef.instanceOfWeaponPickup)
1085         {
1086                 entity ammo = NULL;
1087                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1088                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1089                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1090                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1091                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1092                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1093
1094                 if(!ammo)
1095                         return 0;
1096                 wpn = item;
1097                 rating = ammo.m_botvalue;
1098         }
1099         else
1100         {
1101                 FOREACH(Weapons, it != WEP_Null, {
1102                         if(!(player.weapons & (it.m_wepset)))
1103                                 continue;
1104
1105                         switch(it.ammo_type)
1106                         {
1107                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1108                                 case RESOURCE_BULLETS: need_nails   = true; break;
1109                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1110                                 case RESOURCE_CELLS:   need_cells   = true; break;
1111                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1112                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1113                         }
1114                 });
1115                 rating = item.bot_pickupbasevalue;
1116         }
1117
1118         float noammorating = 0.5;
1119
1120         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1121                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1122
1123         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1124                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1125
1126         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1127                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1128
1129         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1130                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1131
1132         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1133                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1134
1135         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1136                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1137
1138         rating *= min(c, 2);
1139         if(wpn)
1140                 rating += wpn.bot_pickupbasevalue * 0.1;
1141         return rating;
1142 }
1143
1144 .int item_group;
1145 .int item_group_count;
1146 float healtharmor_pickupevalfunc(entity player, entity item)
1147 {
1148         float c = 0;
1149         float rating = item.bot_pickupbasevalue;
1150
1151         float itemarmor = item.armorvalue;
1152         float itemhealth = item.health;
1153
1154         if(item.item_group)
1155         {
1156                 itemarmor *= min(4, item.item_group_count);
1157                 itemhealth *= min(4, item.item_group_count);
1158         }
1159
1160         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1161                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1162
1163         if (itemhealth && (player.health < item.max_health))
1164                 c = itemhealth / max(1, player.health);
1165
1166         rating *= min(2, c);
1167         return rating;
1168 }
1169
1170 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1171 {
1172         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1173                 RemoveItem(this);
1174 }
1175
1176 void item_use(entity this, entity actor, entity trigger)
1177 {
1178         // use the touch function to handle collection
1179         gettouch(this)(this, actor);
1180 }
1181
1182 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1183 {
1184         string itemname = def.m_name;
1185         Model itemmodel = def.m_model;
1186     Sound pickupsound = def.m_sound;
1187         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1188         float pickupbasevalue = def.m_botvalue;
1189         int itemflags = def.m_itemflags;
1190
1191         startitem_failed = false;
1192
1193         this.item_model_ent = itemmodel;
1194     this.item_pickupsound_ent = pickupsound;
1195
1196     if(def.m_iteminit)
1197         def.m_iteminit(this);
1198
1199         if(!this.respawntime) // both need to be set
1200         {
1201                 this.respawntime = defaultrespawntime;
1202                 this.respawntimejitter = defaultrespawntimejitter;
1203         }
1204
1205         if(!this.pickup_anyway && def.m_pickupanyway)
1206                 this.pickup_anyway = def.m_pickupanyway();
1207
1208         int itemid = def.m_itemid;
1209         this.items = itemid;
1210         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1211         this.weapon = weaponid;
1212
1213         if(!this.fade_end)
1214         {
1215                 this.fade_start = autocvar_g_items_mindist;
1216                 this.fade_end = autocvar_g_items_maxdist;
1217         }
1218
1219         if(weaponid)
1220                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1221
1222         this.flags = FL_ITEM | itemflags;
1223         IL_PUSH(g_items, this);
1224
1225         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1226         {
1227                 startitem_failed = true;
1228                 delete(this);
1229                 return;
1230         }
1231
1232         // is it a dropped weapon?
1233         if (this.classname == "droppedweapon")
1234         {
1235                 this.reset = SUB_Remove;
1236                 // it's a dropped weapon
1237                 set_movetype(this, MOVETYPE_TOSS);
1238
1239                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1240                 setthink(this, RemoveItem);
1241                 this.nextthink = time + 20;
1242
1243                 this.takedamage = DAMAGE_YES;
1244                 this.event_damage = Item_Damage;
1245
1246                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1247                 {
1248                         // if item is worthless after a timer, have it expire then
1249                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1250                 }
1251
1252                 // don't drop if in a NODROP zone (such as lava)
1253                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1254                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1255                 {
1256                         startitem_failed = true;
1257                         delete(this);
1258                         return;
1259                 }
1260         }
1261         else
1262         {
1263                 if(!have_pickup_item(this))
1264                 {
1265                         startitem_failed = true;
1266                         delete(this);
1267                         return;
1268                 }
1269
1270                 if(this.angles != '0 0 0')
1271                         this.SendFlags |= ISF_ANGLES;
1272
1273                 this.reset = Item_Reset;
1274                 // it's a level item
1275                 if(this.spawnflags & 1)
1276                         this.noalign = 1;
1277                 if (this.noalign > 0)
1278                         set_movetype(this, MOVETYPE_NONE);
1279                 else
1280                         set_movetype(this, MOVETYPE_TOSS);
1281                 // do item filtering according to game mode and other things
1282                 if (this.noalign <= 0)
1283                 {
1284                         // first nudge it off the floor a little bit to avoid math errors
1285                         setorigin(this, this.origin + '0 0 1');
1286                         // set item size before we spawn a spawnfunc_waypoint
1287                         setsize(this, def.m_mins, def.m_maxs);
1288                         this.SendFlags |= ISF_SIZE;
1289                         // note droptofloor returns false if stuck/or would fall too far
1290                         if (!this.noalign)
1291                                 droptofloor(this);
1292                         waypoint_spawnforitem(this);
1293                 }
1294
1295                 /*
1296                  * can't do it that way, as it would break maps
1297                  * TODO make a target_give like entity another way, that perhaps has
1298                  * the weapon name in a key
1299                 if(this.targetname)
1300                 {
1301                         // target_give not yet supported; maybe later
1302                         print("removed targeted ", this.classname, "\n");
1303                         startitem_failed = true;
1304                         delete(this);
1305                         return;
1306                 }
1307                 */
1308
1309                 if(this.targetname != "" && (this.spawnflags & 16))
1310                         this.use = item_use;
1311
1312                 if(autocvar_spawn_debug >= 2)
1313                 {
1314             // why not flags & fl_item?
1315                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1316                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1317                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1318                 error("Mapper sucks.");
1319             });
1320                         this.is_item = true;
1321                 }
1322
1323                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1324
1325                 precache_model(this.model);
1326                 precache_sound(this.item_pickupsound);
1327
1328                 if (   def.instanceOfPowerup
1329                         || def.instanceOfWeaponPickup
1330                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1331                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1332                         || (itemid & (IT_KEY1 | IT_KEY2))
1333                 ) this.target = "###item###"; // for finding the nearest item using find()
1334
1335                 Item_ItemsTime_SetTime(this, 0);
1336         }
1337
1338         this.bot_pickup = true;
1339         this.bot_pickupevalfunc = pickupevalfunc;
1340         this.bot_pickupbasevalue = pickupbasevalue;
1341         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1342         this.netname = itemname;
1343         settouch(this, Item_Touch);
1344         setmodel(this, MDL_Null); // precision set below
1345         //this.effects |= EF_LOWPRECISION;
1346
1347         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1348
1349         this.SendFlags |= ISF_SIZE;
1350
1351         if (!(this.spawnflags & 1024)) {
1352                 if(def.instanceOfPowerup)
1353                         this.ItemStatus |= ITS_ANIMATE1;
1354
1355                 if(this.armorvalue || this.health)
1356                         this.ItemStatus |= ITS_ANIMATE2;
1357         }
1358
1359         if(def.instanceOfWeaponPickup)
1360         {
1361                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1362                         this.colormap = 1024; // color shirt=0 pants=0 grey
1363                 else
1364                         this.gravity = 1;
1365                 if (!(this.spawnflags & 1024))
1366                         this.ItemStatus |= ITS_ANIMATE1;
1367                 this.SendFlags |= ISF_COLORMAP;
1368         }
1369
1370         this.state = 0;
1371         if(this.team) // broken, no idea why.
1372         {
1373                 if(!this.cnt)
1374                         this.cnt = 1; // item probability weight
1375
1376                 this.effects |= EF_NODRAW; // marker for item team search
1377                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1378         }
1379         else
1380                 Item_Reset(this);
1381
1382         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1383
1384         // call this hook after everything else has been done
1385         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1386         {
1387                 startitem_failed = true;
1388                 delete(this);
1389                 return;
1390         }
1391
1392         setItemGroup(this);
1393 }
1394
1395 void StartItem(entity this, GameItem def)
1396 {
1397     _StartItem(
1398         this,
1399         this.itemdef = def,
1400         def.m_respawntime(), // defaultrespawntime
1401         def.m_respawntimejitter() // defaultrespawntimejitter
1402         );
1403 }
1404
1405 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1406 int group_count = 1;
1407
1408 void setItemGroup(entity this)
1409 {
1410         if(!IS_SMALL(this.itemdef))
1411                 return;
1412
1413         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1414         {
1415                 if(!this.item_group)
1416                 {
1417                         if(!it.item_group)
1418                         {
1419                                 it.item_group = group_count;
1420                                 group_count++;
1421                         }
1422                         this.item_group = it.item_group;
1423                 }
1424                 else // spawning item is already part of a item_group X
1425                 {
1426                         if(!it.item_group)
1427                                 it.item_group = this.item_group;
1428                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1429                         {
1430                                 int grY = it.item_group;
1431                                 // move all items of item_group Y to item_group X
1432                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1433                                 {
1434                                         if(it.item_group == grY)
1435                                                 it.item_group = this.item_group;
1436                                 });
1437                         }
1438                 }
1439         });
1440 }
1441
1442 void setItemGroupCount()
1443 {
1444         for (int k = 1; k <= group_count; k++)
1445         {
1446                 int count = 0;
1447                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1448                 if (count)
1449                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1450         }
1451 }
1452
1453 spawnfunc(item_rockets)
1454 {
1455     StartItem(this, ITEM_Rockets);
1456 }
1457
1458 spawnfunc(item_bullets)
1459 {
1460         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1461            (this.classname != "droppedweapon"))
1462         {
1463                 weaponswapping = true;
1464                 spawnfunc_item_shells(this);
1465                 weaponswapping = false;
1466                 return;
1467         }
1468
1469     StartItem(this, ITEM_Bullets);
1470 }
1471
1472 spawnfunc(item_cells)
1473 {
1474         StartItem(this, ITEM_Cells);
1475 }
1476
1477 spawnfunc(item_plasma)
1478 {
1479         StartItem(this, ITEM_Plasma);
1480 }
1481
1482 spawnfunc(item_shells)
1483 {
1484         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1485            (this.classname != "droppedweapon"))
1486         {
1487                 weaponswapping = true;
1488                 spawnfunc_item_bullets(this);
1489                 weaponswapping = false;
1490                 return;
1491         }
1492
1493         StartItem(this, ITEM_Shells);
1494 }
1495
1496 spawnfunc(item_armor_small)
1497 {
1498         StartItem(this, ITEM_ArmorSmall);
1499 }
1500
1501 spawnfunc(item_armor_medium)
1502 {
1503         StartItem(this, ITEM_ArmorMedium);
1504 }
1505
1506 spawnfunc(item_armor_big)
1507 {
1508         StartItem(this, ITEM_ArmorBig);
1509 }
1510
1511 spawnfunc(item_armor_mega)
1512 {
1513         StartItem(this, ITEM_ArmorMega);
1514 }
1515
1516 spawnfunc(item_health_small)
1517 {
1518         StartItem(this, ITEM_HealthSmall);
1519 }
1520
1521 spawnfunc(item_health_medium)
1522 {
1523     StartItem(this, ITEM_HealthMedium);
1524 }
1525
1526 spawnfunc(item_health_big)
1527 {
1528         StartItem(this, ITEM_HealthBig);
1529 }
1530
1531 spawnfunc(item_health_mega)
1532 {
1533     StartItem(this, ITEM_HealthMega);
1534 }
1535
1536 // support old misnamed entities
1537 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1538 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1539 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1540 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1541 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1542 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1543 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1544
1545 spawnfunc(item_strength)
1546 {
1547         StartItem(this, ITEM_Strength);
1548 }
1549
1550 spawnfunc(item_invincible)
1551 {
1552         StartItem(this, ITEM_Shield);
1553 }
1554
1555 // compatibility:
1556 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1557
1558 void target_items_use(entity this, entity actor, entity trigger)
1559 {
1560         if(actor.classname == "droppedweapon")
1561         {
1562                 EXACTTRIGGER_TOUCH(this, trigger);
1563                 delete(actor);
1564                 return;
1565         }
1566
1567         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1568                 return;
1569
1570         if(trigger.solid == SOLID_TRIGGER)
1571         {
1572                 EXACTTRIGGER_TOUCH(this, trigger);
1573         }
1574
1575         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1576         {
1577                 delete(it);
1578         });
1579
1580         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1581                 centerprint(actor, this.message);
1582 }
1583
1584 spawnfunc(target_items)
1585 {
1586         int n;
1587         string s;
1588
1589         this.use = target_items_use;
1590         if(!this.strength_finished)
1591                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1592         if(!this.invincible_finished)
1593                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1594         if(!this.superweapons_finished)
1595                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1596
1597         n = tokenize_console(this.netname);
1598         if(argv(0) == "give")
1599         {
1600                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1601         }
1602         else
1603         {
1604                 for(int j = 0; j < n; ++j)
1605                 {
1606                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1607                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1608                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1609                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1610                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1611                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1612                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1613                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1614                         else
1615                         {
1616                                 FOREACH(Buffs, it != BUFF_Null,
1617                                 {
1618                                         s = Buff_UndeprecateName(argv(j));
1619                                         if(s == it.m_name)
1620                                         {
1621                                                 this.buffs |= (it.m_itemid);
1622                                                 break;
1623                                         }
1624                                 });
1625                                 FOREACH(Weapons, it != WEP_Null, {
1626                                         s = W_UndeprecateName(argv(j));
1627                                         if(s == it.netname)
1628                                         {
1629                                                 this.weapons |= (it.m_wepset);
1630                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1631                                                         it.wr_init(it);
1632                                                 break;
1633                                         }
1634                                 });
1635                         }
1636                 }
1637
1638                 string itemprefix, valueprefix;
1639                 if(this.spawnflags == 0)
1640                 {
1641                         itemprefix = "";
1642                         valueprefix = "";
1643                 }
1644                 else if(this.spawnflags == 1)
1645                 {
1646                         itemprefix = "max ";
1647                         valueprefix = "max ";
1648                 }
1649                 else if(this.spawnflags == 2)
1650                 {
1651                         itemprefix = "min ";
1652                         valueprefix = "min ";
1653                 }
1654                 else if(this.spawnflags == 4)
1655                 {
1656                         itemprefix = "minus ";
1657                         valueprefix = "max ";
1658                 }
1659                 else
1660                 {
1661                         error("invalid spawnflags");
1662                         itemprefix = valueprefix = string_null;
1663                 }
1664
1665                 this.netname = "";
1666                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1667                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1668                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1669                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1670                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1671                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1672                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1673                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1674                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1675                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1676                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1677                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1678                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1679                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1680                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1681                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1682                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1683         }
1684         this.netname = strzone(this.netname);
1685         //print(this.netname, "\n");
1686
1687         n = tokenize_console(this.netname);
1688         for(int j = 0; j < n; ++j)
1689         {
1690                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1691             it.wr_init(it);
1692             break;
1693                 });
1694         }
1695 }
1696
1697 spawnfunc(item_fuel)
1698 {
1699         StartItem(this, ITEM_JetpackFuel);
1700 }
1701
1702 spawnfunc(item_fuel_regen)
1703 {
1704         if(start_items & ITEM_JetpackRegen.m_itemid)
1705         {
1706                 spawnfunc_item_fuel(this);
1707                 return;
1708         }
1709         StartItem(this, ITEM_JetpackRegen);
1710 }
1711
1712 spawnfunc(item_jetpack)
1713 {
1714         if(start_items & ITEM_Jetpack.m_itemid)
1715         {
1716                 spawnfunc_item_fuel(this);
1717                 return;
1718         }
1719         StartItem(this, ITEM_Jetpack);
1720 }
1721
1722 float GiveWeapon(entity e, float wpn, float op, float val)
1723 {
1724         WepSet v0, v1;
1725         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1726         v0 = (e.weapons & s);
1727         switch(op)
1728         {
1729                 case OP_SET:
1730                         if(val > 0)
1731                                 e.weapons |= s;
1732                         else
1733                                 e.weapons &= ~s;
1734                         break;
1735                 case OP_MIN:
1736                 case OP_PLUS:
1737                         if(val > 0)
1738                                 e.weapons |= s;
1739                         break;
1740                 case OP_MAX:
1741                         if(val <= 0)
1742                                 e.weapons &= ~s;
1743                         break;
1744                 case OP_MINUS:
1745                         if(val > 0)
1746                                 e.weapons &= ~s;
1747                         break;
1748         }
1749         v1 = (e.weapons & s);
1750         return (v0 != v1);
1751 }
1752
1753 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1754 {
1755         bool had_buff = (e.buffs & thebuff.m_itemid);
1756         switch(op)
1757         {
1758                 case OP_SET:
1759                         if(val > 0)
1760                                 e.buffs |= thebuff.m_itemid;
1761                         else
1762                                 e.buffs &= ~thebuff.m_itemid;
1763                         break;
1764                 case OP_MIN:
1765                 case OP_PLUS:
1766                         if(val > 0)
1767                                 e.buffs |= thebuff.m_itemid;
1768                         break;
1769                 case OP_MAX:
1770                         if(val <= 0)
1771                                 e.buffs &= ~thebuff.m_itemid;
1772                         break;
1773                 case OP_MINUS:
1774                         if(val > 0)
1775                                 e.buffs &= ~thebuff.m_itemid;
1776                         break;
1777         }
1778         bool have_buff = (e.buffs & thebuff.m_itemid);
1779         return (had_buff != have_buff);
1780 }
1781
1782 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1783 {
1784         if(v1 == v0)
1785                 return;
1786         if(v1 <= v0 - t)
1787         {
1788                 if(snd_decr != NULL)
1789                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1790         }
1791         else if(v0 >= v0 + t)
1792         {
1793                 if(snd_incr != NULL)
1794                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1795         }
1796 }
1797
1798 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1799 {
1800         if(v0 < v1)
1801                 e.(rotfield) = max(e.(rotfield), time + rottime);
1802         else if(v0 > v1)
1803                 e.(regenfield) = max(e.(regenfield), time + regentime);
1804 }
1805 float GiveItems(entity e, float beginarg, float endarg)
1806 {
1807         float got, i, val, op;
1808         string cmd;
1809
1810         val = 999;
1811         op = OP_SET;
1812
1813         got = 0;
1814
1815         int _switchweapon = 0;
1816
1817         if(CS(e).autoswitch)
1818         {
1819                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1820                 {
1821                         .entity weaponentity = weaponentities[slot];
1822                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1823                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1824                                 _switchweapon |= BIT(slot);
1825                 }
1826         }
1827
1828         e.strength_finished = max(0, e.strength_finished - time);
1829         e.invincible_finished = max(0, e.invincible_finished - time);
1830         e.superweapons_finished = max(0, e.superweapons_finished - time);
1831
1832         PREGIVE(e, items);
1833         PREGIVE_WEAPONS(e);
1834         PREGIVE(e, strength_finished);
1835         PREGIVE(e, invincible_finished);
1836         PREGIVE(e, superweapons_finished);
1837         PREGIVE(e, ammo_nails);
1838         PREGIVE(e, ammo_cells);
1839         PREGIVE(e, ammo_plasma);
1840         PREGIVE(e, ammo_shells);
1841         PREGIVE(e, ammo_rockets);
1842         PREGIVE(e, ammo_fuel);
1843         PREGIVE(e, armorvalue);
1844         PREGIVE(e, health);
1845
1846         for(i = beginarg; i < endarg; ++i)
1847         {
1848                 cmd = argv(i);
1849
1850                 if(cmd == "0" || stof(cmd))
1851                 {
1852                         val = stof(cmd);
1853                         continue;
1854                 }
1855                 switch(cmd)
1856                 {
1857                         case "no":
1858                                 op = OP_MAX;
1859                                 val = 0;
1860                                 continue;
1861                         case "max":
1862                                 op = OP_MAX;
1863                                 continue;
1864                         case "min":
1865                                 op = OP_MIN;
1866                                 continue;
1867                         case "plus":
1868                                 op = OP_PLUS;
1869                                 continue;
1870                         case "minus":
1871                                 op = OP_MINUS;
1872                                 continue;
1873                         case "ALL":
1874                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1875                                 got += GiveValue(e, strength_finished, op, val);
1876                                 got += GiveValue(e, invincible_finished, op, val);
1877                                 got += GiveValue(e, superweapons_finished, op, val);
1878                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1879                         case "all":
1880                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1881                                 got += GiveValue(e, health, op, val);
1882                                 got += GiveValue(e, armorvalue, op, val);
1883                         case "allweapons":
1884                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1885                         //case "allbuffs": // all buffs makes a player god, do not want!
1886                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1887                         case "allammo":
1888                                 got += GiveValue(e, ammo_cells, op, val);
1889                                 got += GiveValue(e, ammo_plasma, op, val);
1890                                 got += GiveValue(e, ammo_shells, op, val);
1891                                 got += GiveValue(e, ammo_nails, op, val);
1892                                 got += GiveValue(e, ammo_rockets, op, val);
1893                                 got += GiveValue(e, ammo_fuel, op, val);
1894                                 break;
1895                         case "unlimited_ammo":
1896                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1897                                 break;
1898                         case "unlimited_weapon_ammo":
1899                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1900                                 break;
1901                         case "unlimited_superweapons":
1902                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1903                                 break;
1904                         case "jetpack":
1905                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1906                                 break;
1907                         case "fuel_regen":
1908                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1909                                 break;
1910                         case "strength":
1911                                 got += GiveValue(e, strength_finished, op, val);
1912                                 break;
1913                         case "invincible":
1914                                 got += GiveValue(e, invincible_finished, op, val);
1915                                 break;
1916                         case "superweapons":
1917                                 got += GiveValue(e, superweapons_finished, op, val);
1918                                 break;
1919                         case "cells":
1920                                 got += GiveValue(e, ammo_cells, op, val);
1921                                 break;
1922                         case "plasma":
1923                                 got += GiveValue(e, ammo_plasma, op, val);
1924                                 break;
1925                         case "shells":
1926                                 got += GiveValue(e, ammo_shells, op, val);
1927                                 break;
1928                         case "nails":
1929                         case "bullets":
1930                                 got += GiveValue(e, ammo_nails, op, val);
1931                                 break;
1932                         case "rockets":
1933                                 got += GiveValue(e, ammo_rockets, op, val);
1934                                 break;
1935                         case "health":
1936                                 got += GiveValue(e, health, op, val);
1937                                 break;
1938                         case "armor":
1939                                 got += GiveValue(e, armorvalue, op, val);
1940                                 break;
1941                         case "fuel":
1942                                 got += GiveValue(e, ammo_fuel, op, val);
1943                                 break;
1944                         default:
1945                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1946                                 {
1947                                         got += GiveBuff(e, it, op, val);
1948                                         break;
1949                                 });
1950                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1951                     got += GiveWeapon(e, it.m_id, op, val);
1952                     break;
1953                                 });
1954                                 break;
1955                 }
1956                 val = 999;
1957                 op = OP_SET;
1958         }
1959
1960         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1961         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1962         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1963         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1964         FOREACH(Weapons, it != WEP_Null, {
1965                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1966                 if(!(save_weapons & (it.m_wepset)))
1967                         if(e.weapons & (it.m_wepset))
1968                                 it.wr_init(it);
1969         });
1970         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1971         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1972         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1973         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1974         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1975         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1976         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1977         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1978         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1979         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1980         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1981
1982         if(e.superweapons_finished <= 0)
1983                 if(e.weapons & WEPSET_SUPERWEAPONS)
1984                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1985
1986         if(e.strength_finished <= 0)
1987                 e.strength_finished = 0;
1988         else
1989                 e.strength_finished += time;
1990         if(e.invincible_finished <= 0)
1991                 e.invincible_finished = 0;
1992         else
1993                 e.invincible_finished += time;
1994         if(e.superweapons_finished <= 0)
1995                 e.superweapons_finished = 0;
1996         else
1997                 e.superweapons_finished += time;
1998
1999         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2000         {
2001                 .entity weaponentity = weaponentities[slot];
2002                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2003                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2004                         _switchweapon |= BIT(slot);
2005         }
2006
2007         if(_switchweapon)
2008         {
2009                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2010                 {
2011                         .entity weaponentity = weaponentities[slot];
2012                         if(_switchweapon & BIT(slot))
2013                         {
2014                                 Weapon wep = w_getbestweapon(e, weaponentity);
2015                                 if(wep != e.(weaponentity).m_switchweapon)
2016                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2017                         }
2018                 }
2019         }
2020
2021         return got;
2022 }
2023 #endif