Merge branch 'martin-t/spec' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if(!veh_hud)
62         if(this.ItemStatus & ITS_STAYWEP)
63         {
64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
65                 this.alpha = autocvar_cl_weapon_stay_alpha;
66         }
67 }
68
69 void ItemDraw(entity this)
70 {
71     if(this.gravity)
72     {
73         Movetype_Physics_MatchServer(this, false);
74         if(IS_ONGROUND(this))
75         { // For some reason avelocity gets set to '0 0 0' here ...
76             this.oldorigin = this.origin;
77             this.gravity = 0;
78
79             if(autocvar_cl_animate_items)
80             { // ... so reset it if animations are requested.
81                 if(this.ItemStatus & ITS_ANIMATE1)
82                     this.avelocity = '0 180 0';
83
84                 if(this.ItemStatus & ITS_ANIMATE2)
85                     this.avelocity = '0 -90 0';
86             }
87
88             // delay is for blocking item's position for a while;
89             // it's a workaround for dropped weapons that receive the position
90             // another time right after they spawn overriding animation position
91             this.onground_time = time + 0.5;
92         }
93     }
94     else if (autocvar_cl_animate_items)
95     {
96         if(this.ItemStatus & ITS_ANIMATE1)
97         {
98             this.angles += this.avelocity * frametime;
99             float fade_in = bound(0, time - this.onground_time, 1);
100             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
101         }
102
103         if(this.ItemStatus & ITS_ANIMATE2)
104         {
105             this.angles += this.avelocity * frametime;
106             float fade_in = bound(0, time - this.onground_time, 1);
107             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
108         }
109     }
110
111     Item_SetAlpha(this);
112 }
113
114 void ItemDrawSimple(entity this)
115 {
116     if(this.gravity)
117     {
118         Movetype_Physics_MatchServer(this, false);
119
120         if(IS_ONGROUND(this))
121             this.gravity = 0;
122     }
123
124     Item_SetAlpha(this);
125 }
126
127 void Item_PreDraw(entity this)
128 {
129         if(warpzone_warpzones_exist)
130         {
131                 // just incase warpzones were initialized last, reset these
132                 //this.alpha = 1; // alpha is already set by the draw function
133                 this.drawmask = MASK_NORMAL;
134                 return;
135         }
136         float alph;
137         vector org = getpropertyvec(VF_ORIGIN);
138         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
139                 alph = 0;
140         else if(this.fade_start)
141                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
142         else
143                 alph = 1;
144         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
145         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
146                 this.alpha = alph;
147         if(alph <= 0)
148                 this.drawmask = 0;
149         else
150                 this.drawmask = MASK_NORMAL;
151 }
152
153 void ItemRemove(entity this)
154 {
155         if(this.mdl)
156                 strunzone(this.mdl);
157 }
158
159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
160 {
161     int sf = ReadByte();
162
163     if(sf & ISF_LOCATION)
164     {
165         this.origin_x = ReadCoord();
166         this.origin_y = ReadCoord();
167         this.origin_z = ReadCoord();
168         setorigin(this, this.origin);
169         this.oldorigin = this.origin;
170     }
171
172     if(sf & ISF_ANGLES)
173     {
174         this.angles_x = ReadAngle();
175         this.angles_y = ReadAngle();
176         this.angles_z = ReadAngle();
177     }
178
179     if(sf & ISF_SIZE)
180     {
181         float use_bigsize = ReadByte();
182         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
183     }
184
185     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
186     {
187         this.ItemStatus = ReadByte();
188
189         Item_SetAlpha(this);
190
191         if(autocvar_cl_fullbright_items)
192             if(this.ItemStatus & ITS_ALLOWFB)
193                 this.effects |= EF_FULLBRIGHT;
194
195         if(this.ItemStatus & ITS_GLOW)
196         {
197             if(this.ItemStatus & ITS_AVAILABLE)
198                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
199             else
200                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
201         }
202     }
203
204     if(sf & ISF_MODEL)
205     {
206         this.drawmask  = MASK_NORMAL;
207                 set_movetype(this, MOVETYPE_TOSS);
208                 if (isnew) IL_PUSH(g_drawables, this);
209         this.draw       = ItemDraw;
210         this.solid = SOLID_TRIGGER;
211         //this.flags |= FL_ITEM;
212
213         bool use_bigsize = ReadByte();
214
215         this.fade_end = ReadShort();
216         this.fade_start = ReadShort();
217         if(this.fade_start && !autocvar_cl_items_nofade)
218                 setpredraw(this, Item_PreDraw);
219
220         if(this.mdl)
221             strunzone(this.mdl);
222
223         this.mdl = "";
224         string _fn = ReadString();
225
226         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
227         {
228             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
229             this.draw = ItemDrawSimple;
230
231             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
232                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
233             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
234                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
235             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
236                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
237             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
238                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
239             else
240             {
241                 this.draw = ItemDraw;
242                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
243             }
244         }
245
246         if(this.draw != ItemDrawSimple)
247             this.mdl = strzone(_fn);
248
249
250         if(this.mdl == "")
251             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
252
253         precache_model(this.mdl);
254         _setmodel(this, this.mdl);
255
256         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
257     }
258
259     if(sf & ISF_COLORMAP)
260     {
261         this.colormap = ReadShort();
262         this.item_glowmod_x = ReadByte() / 255.0;
263         this.item_glowmod_y = ReadByte() / 255.0;
264         this.item_glowmod_z = ReadByte() / 255.0;
265     }
266
267     if(sf & ISF_DROP)
268     {
269         this.gravity = 1;
270         this.pushable = true;
271         //this.angles = '0 0 0';
272         set_movetype(this, MOVETYPE_TOSS);
273         this.velocity_x = ReadCoord();
274         this.velocity_y = ReadCoord();
275         this.velocity_z = ReadCoord();
276         setorigin(this, this.oldorigin);
277
278         if(!this.move_time)
279         {
280             this.move_time = time;
281             this.spawntime = time;
282         }
283         else
284             this.move_time = max(this.move_time, time);
285     }
286
287     if(autocvar_cl_animate_items)
288     {
289         if(this.ItemStatus & ITS_ANIMATE1)
290             this.avelocity = '0 180 0';
291
292         if(this.ItemStatus & ITS_ANIMATE2)
293             this.avelocity = '0 -90 0';
294     }
295
296     this.entremove = ItemRemove;
297
298     return true;
299 }
300
301 #endif
302
303 #ifdef SVQC
304 bool ItemSend(entity this, entity to, int sf)
305 {
306         if(this.gravity)
307                 sf |= ISF_DROP;
308         else
309                 sf &= ~ISF_DROP;
310
311         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
312         WriteByte(MSG_ENTITY, sf);
313
314         //WriteByte(MSG_ENTITY, this.cnt);
315         if(sf & ISF_LOCATION)
316         {
317                 WriteCoord(MSG_ENTITY, this.origin.x);
318                 WriteCoord(MSG_ENTITY, this.origin.y);
319                 WriteCoord(MSG_ENTITY, this.origin.z);
320         }
321
322         if(sf & ISF_ANGLES)
323         {
324                 WriteAngle(MSG_ENTITY, this.angles_x);
325                 WriteAngle(MSG_ENTITY, this.angles_y);
326                 WriteAngle(MSG_ENTITY, this.angles_z);
327         }
328
329         if(sf & ISF_SIZE)
330         {
331                 Pickup p = this.itemdef;
332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
333         }
334
335         if(sf & ISF_STATUS)
336                 WriteByte(MSG_ENTITY, this.ItemStatus);
337
338         if(sf & ISF_MODEL)
339         {
340                 Pickup p = this.itemdef;
341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
342                 WriteShort(MSG_ENTITY, this.fade_end);
343                 WriteShort(MSG_ENTITY, this.fade_start);
344
345                 if(this.mdl == "")
346                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
347
348                 WriteString(MSG_ENTITY, this.mdl);
349         }
350
351
352         if(sf & ISF_COLORMAP)
353         {
354                 WriteShort(MSG_ENTITY, this.colormap);
355                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
356         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
357         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
358         }
359
360         if(sf & ISF_DROP)
361         {
362                 WriteCoord(MSG_ENTITY, this.velocity.x);
363                 WriteCoord(MSG_ENTITY, this.velocity.y);
364                 WriteCoord(MSG_ENTITY, this.velocity.z);
365         }
366
367         return true;
368 }
369
370 void ItemUpdate(entity this)
371 {
372         this.oldorigin = this.origin;
373         this.SendFlags |= ISF_LOCATION;
374 }
375
376 void UpdateItemAfterTeleport(entity this)
377 {
378         if(getSendEntity(this) == ItemSend)
379                 ItemUpdate(this);
380 }
381
382 bool have_pickup_item(entity this)
383 {
384         if(this.itemdef.instanceOfPowerup)
385         {
386                 if(autocvar_g_powerups > 0)
387                         return true;
388                 if(autocvar_g_powerups == 0)
389                         return false;
390         }
391         else
392         {
393                 if(autocvar_g_pickup_items > 0)
394                         return true;
395                 if(autocvar_g_pickup_items == 0)
396                         return false;
397                 if(g_weaponarena)
398                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
399                                 return false;
400         }
401         return true;
402 }
403
404 /*
405 float Item_Customize()
406 {
407         if(this.spawnshieldtime)
408                 return true;
409         if(this.weapons & ~other.weapons)
410         {
411                 this.colormod = '0 0 0';
412                 this.glowmod = this.colormod;
413                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
414                 return true;
415         }
416         else
417         {
418                 if(g_ghost_items)
419                 {
420                         this.colormod = stov(autocvar_g_ghost_items_color);
421                         this.glowmod = this.colormod;
422                         this.alpha = g_ghost_items;
423                         return true;
424                 }
425                 else
426                         return false;
427         }
428 }
429 */
430
431 void Item_Show (entity e, float mode)
432 {
433         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
434         e.ItemStatus &= ~ITS_STAYWEP;
435         entity def = e.itemdef;
436         if (mode > 0)
437         {
438                 // make the item look normal, and be touchable
439                 e.model = e.mdl;
440                 e.solid = SOLID_TRIGGER;
441                 e.spawnshieldtime = 1;
442                 e.ItemStatus |= ITS_AVAILABLE;
443         }
444         else if (mode < 0)
445         {
446                 // hide the item completely
447                 e.model = string_null;
448                 e.solid = SOLID_NOT;
449                 e.spawnshieldtime = 1;
450                 e.ItemStatus &= ~ITS_AVAILABLE;
451         }
452         else {
453         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
454                 || e.team // weapon stay isn't supported for teamed weapons
455                 ;
456         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
457         {
458                 // make the item translucent and not touchable
459                 e.model = e.mdl;
460                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
461                 e.effects |= EF_STARDUST;
462                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
463                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
464         }
465         else
466         {
467                 //setmodel(e, "null");
468                 e.solid = SOLID_NOT;
469                 e.colormod = '0 0 0';
470                 //e.glowmod = e.colormod;
471                 e.spawnshieldtime = 1;
472                 e.ItemStatus &= ~ITS_AVAILABLE;
473         }}
474
475         if (def.m_glow)
476                 e.ItemStatus |= ITS_GLOW;
477
478         if (autocvar_g_nodepthtestitems)
479                 e.effects |= EF_NODEPTHTEST;
480
481
482         if (autocvar_g_fullbrightitems)
483                 e.ItemStatus |= ITS_ALLOWFB;
484
485         if (autocvar_sv_simple_items)
486                 e.ItemStatus |= ITS_ALLOWSI;
487
488         // relink entity (because solid may have changed)
489         setorigin(e, e.origin);
490         e.SendFlags |= ISF_STATUS;
491 }
492
493 void Item_Think(entity this)
494 {
495         this.nextthink = time;
496         if(this.origin != this.oldorigin)
497                 ItemUpdate(this);
498 }
499
500 bool Item_ItemsTime_SpectatorOnly(GameItem it);
501 bool Item_ItemsTime_Allow(GameItem it);
502 float Item_ItemsTime_UpdateTime(entity e, float t);
503 void Item_ItemsTime_SetTime(entity e, float t);
504 void Item_ItemsTime_SetTimesForAllPlayers();
505
506 void Item_Respawn (entity this)
507 {
508         Item_Show(this, 1);
509         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
510         setorigin(this, this.origin);
511
512     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
513         {
514                 float t = Item_ItemsTime_UpdateTime(this, 0);
515                 Item_ItemsTime_SetTime(this, t);
516                 Item_ItemsTime_SetTimesForAllPlayers();
517         }
518
519         setthink(this, Item_Think);
520         this.nextthink = time;
521
522         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
523         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
524 }
525
526 void Item_RespawnCountdown (entity this)
527 {
528         if(this.count >= ITEM_RESPAWN_TICKS)
529         {
530                 if(this.waypointsprite_attached)
531                         WaypointSprite_Kill(this.waypointsprite_attached);
532                 Item_Respawn(this);
533         }
534         else
535         {
536                 this.nextthink = time + 1;
537                 this.count += 1;
538                 if(this.count == 1)
539                 {
540                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
541                         do {
542                                 {
543                                         entity wi = Weapons_from(this.weapon);
544                                         if (wi != WEP_Null) {
545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
546                                                 wp.wp_extra = wi.m_id;
547                                                 break;
548                                         }
549                                 }
550                                 {
551                                         entity ii = this.itemdef;
552                                         if (ii != NULL) {
553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
554                                                 wp.wp_extra = ii.m_id;
555                                                 break;
556                                         }
557                                 }
558                         } while (0);
559             if(this.waypointsprite_attached)
560             {
561                 GameItem def = this.itemdef;
562                 if (Item_ItemsTime_SpectatorOnly(def))
563                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
564                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
565             }
566                 }
567
568                 if(this.waypointsprite_attached)
569                 {
570                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
571                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
572                                 {
573                                         msg_entity = it;
574                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
575                                 }
576                         });
577
578                         WaypointSprite_Ping(this.waypointsprite_attached);
579                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
580                 }
581         }
582 }
583
584 void Item_RespawnThink(entity this)
585 {
586         this.nextthink = time;
587         if(this.origin != this.oldorigin)
588                 ItemUpdate(this);
589
590         if(time >= this.wait)
591                 Item_Respawn(this);
592 }
593
594 void Item_ScheduleRespawnIn(entity e, float t)
595 {
596         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
597         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS)) && (t - ITEM_RESPAWN_TICKS) > 0)
598         {
599                 setthink(e, Item_RespawnCountdown);
600                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
601                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
602                 e.count = 0;
603                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
604                 Item_ItemsTime_SetTime(e, t);
605                 Item_ItemsTime_SetTimesForAllPlayers();
606         }
607         else
608         {
609                 setthink(e, Item_RespawnThink);
610                 e.nextthink = time;
611                 e.scheduledrespawntime = time + t;
612                 e.wait = time + t;
613
614                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
615                 {
616                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
617                         Item_ItemsTime_SetTime(e, t);
618                         Item_ItemsTime_SetTimesForAllPlayers();
619                 }
620         }
621 }
622
623 void Item_ScheduleRespawn(entity e)
624 {
625         if(e.respawntime > 0)
626         {
627                 Item_Show(e, 0);
628                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
629         }
630         else // if respawntime is -1, this item does not respawn
631                 Item_Show(e, -1);
632 }
633
634 void Item_ScheduleInitialRespawn(entity e)
635 {
636         Item_Show(e, 0);
637         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
638 }
639
640 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
641 {
642         if (!item.(ammotype))
643                 return false;
644
645         if (item.spawnshieldtime)
646         {
647                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
648                 {
649                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
650                         goto YEAH;
651                 }
652         }
653         else if(g_weapon_stay == 2)
654         {
655                 float mi = min(item.(ammotype), ammomax);
656                 if (player.(ammotype) < mi)
657                 {
658                         player.(ammotype) = mi;
659                         goto YEAH;
660                 }
661         }
662
663         return false;
664
665 LABEL(YEAH)
666         switch(mode)
667         {
668                 case ITEM_MODE_FUEL:
669                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
670                         break;
671                 case ITEM_MODE_HEALTH:
672                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
673                         break;
674                 case ITEM_MODE_ARMOR:
675                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
676                         break;
677                 default:
678                         break;
679         }
680         return true;
681 }
682
683 float Item_GiveTo(entity item, entity player)
684 {
685         float pickedup;
686
687         // if nothing happens to player, just return without taking the item
688         pickedup = false;
689         int _switchweapon = 0;
690         // in case the player has autoswitch enabled do the following:
691         // if the player is using their best weapon before items are given, they
692         // probably want to switch to an even better weapon after items are given
693
694         if(player.autoswitch)
695         {
696                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
697                 {
698                         .entity weaponentity = weaponentities[slot];
699                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
700                         {
701                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
702                                         _switchweapon |= BIT(slot);
703
704                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
705                                         _switchweapon |= BIT(slot);
706                         }
707                 }
708         }
709
710         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
711         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
712         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
713         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
714         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
715         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
716         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
717         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
718
719         if (item.itemdef.instanceOfWeaponPickup)
720         {
721                 WepSet w;
722                 w = item.weapons;
723                 w &= ~player.weapons;
724
725                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
726                 {
727                         pickedup = true;
728                         FOREACH(Weapons, it != WEP_Null, {
729                                 if(w & (it.m_wepset))
730                                 {
731                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
732                                         {
733                                                 .entity weaponentity = weaponentities[slot];
734                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
735                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
736                                         }
737                                         W_GiveWeapon(player, it.m_id);
738                                 }
739                         });
740                 }
741         }
742
743         if (item.itemdef.instanceOfPowerup)
744         {
745                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
746                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
747                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
748                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
749         }
750
751         int its;
752         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
753         {
754                 pickedup = true;
755                 player.items |= its;
756                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
757         }
758
759         if (item.strength_finished)
760         {
761                 pickedup = true;
762                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
763         }
764         if (item.invincible_finished)
765         {
766                 pickedup = true;
767                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
768         }
769         if (item.superweapons_finished)
770         {
771                 pickedup = true;
772                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
773         }
774
775 LABEL(skip)
776
777         // always eat teamed entities
778         if(item.team)
779                 pickedup = true;
780
781         if (!pickedup)
782                 return 0;
783
784         // crude hack to enforce switching weapons
785         if(g_cts && item.itemdef.instanceOfWeaponPickup)
786         {
787                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
788                 {
789                         .entity weaponentity = weaponentities[slot];
790                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
791                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
792                 }
793                 return 1;
794         }
795
796         if(_switchweapon)
797         {
798                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
799                 {
800                         .entity weaponentity = weaponentities[slot];
801                         if(_switchweapon & BIT(slot))
802                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
803                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
804                 }
805         }
806
807         return 1;
808 }
809
810 void Item_Touch(entity this, entity toucher)
811 {
812
813         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
814         if (this.classname == "droppedweapon")
815         {
816                 if (ITEM_TOUCH_NEEDKILL())
817                 {
818                         delete(this);
819                         return;
820                 }
821         }
822
823         if(!(toucher.flags & FL_PICKUPITEMS)
824         || STAT(FROZEN, toucher)
825         || IS_DEAD(toucher)
826         || (this.solid != SOLID_TRIGGER)
827         || (this.owner == toucher)
828         || (time < this.item_spawnshieldtime)
829         ) { return; }
830
831         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
832         {
833                 case MUT_ITEMTOUCH_RETURN: { return; }
834                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
835         }
836
837         toucher = M_ARGV(1, entity);
838
839         if (this.classname == "droppedweapon")
840         {
841                 this.strength_finished = max(0, this.strength_finished - time);
842                 this.invincible_finished = max(0, this.invincible_finished - time);
843                 this.superweapons_finished = max(0, this.superweapons_finished - time);
844         }
845         entity it = this.itemdef;
846         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
847         if (!gave)
848         {
849                 if (this.classname == "droppedweapon")
850                 {
851                         // undo what we did above
852                         this.strength_finished += time;
853                         this.invincible_finished += time;
854                         this.superweapons_finished += time;
855                 }
856                 return;
857         }
858
859 LABEL(pickup)
860
861         toucher.last_pickup = time;
862
863         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
864         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
865
866         if (this.classname == "droppedweapon")
867                 delete (this);
868         else if (this.spawnshieldtime)
869         {
870                 entity e;
871                 if(this.team)
872                 {
873                         RandomSelection_Init();
874                         IL_EACH(g_items, it.team == this.team,
875                         {
876                                 if(it.itemdef) // is a registered item
877                                 {
878                                         Item_Show(it, -1);
879                                         RandomSelection_AddEnt(it, it.cnt, 0);
880                                 }
881                         });
882                         e = RandomSelection_chosen_ent;
883                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
884                 }
885                 else
886                         e = this;
887                 Item_ScheduleRespawn(e);
888         }
889 }
890
891 void Item_Reset(entity this)
892 {
893         Item_Show(this, !this.state);
894         setorigin(this, this.origin);
895
896         if (this.classname != "droppedweapon")
897         {
898                 setthink(this, Item_Think);
899                 this.nextthink = time;
900
901                 if (this.waypointsprite_attached)
902                         WaypointSprite_Kill(this.waypointsprite_attached);
903
904                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
905                         Item_ScheduleInitialRespawn(this);
906         }
907 }
908
909 void Item_FindTeam(entity this)
910 {
911         entity e;
912
913         if(this.effects & EF_NODRAW)
914         {
915                 // marker for item team search
916                 LOG_TRACE("Initializing item team ", ftos(this.team));
917                 RandomSelection_Init();
918                 IL_EACH(g_items, it.team == this.team,
919                 {
920                         if(it.itemdef) // is a registered item
921                                 RandomSelection_AddEnt(it, it.cnt, 0);
922                 });
923
924                 e = RandomSelection_chosen_ent;
925                 e.state = 0;
926                 Item_Show(e, 1);
927
928                 IL_EACH(g_items, it.team == this.team,
929                 {
930                         if(it.itemdef) // is a registered item
931                         {
932                                 if(it != e)
933                                 {
934                                         // make it non-spawned
935                                         Item_Show(it, -1);
936                                         it.state = 1; // state 1 = initially hidden item, apparently
937                                 }
938                                 it.effects &= ~EF_NODRAW;
939                         }
940                 });
941
942                 Item_Reset(this);
943         }
944 }
945
946 // Savage: used for item garbage-collection
947 void RemoveItem(entity this)
948 {
949         if(wasfreed(this) || !this) { return; }
950         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
951         delete(this);
952 }
953
954 // pickup evaluation functions
955 // these functions decide how desirable an item is to the bots
956
957 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
958
959 float weapon_pickupevalfunc(entity player, entity item)
960 {
961         // See if I have it already
962         if(player.weapons & item.weapons)
963         {
964                 // If I can pick it up
965                 if(!item.spawnshieldtime)
966                         return 0;
967                 return ammo_pickupevalfunc(player, item);
968         }
969
970         // reduce weapon value if bot already got a good arsenal
971         float c = 1;
972         int weapons_value = 0;
973         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
974                 weapons_value += it.bot_pickupbasevalue;
975         });
976         c -= bound(0, weapons_value / 20000, 1) * 0.5;
977
978         return item.bot_pickupbasevalue * c;
979 }
980
981 float ammo_pickupevalfunc(entity player, entity item)
982 {
983         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
984         entity wpn = NULL;
985         float c = 0;
986         float rating = 0;
987
988         // Detect needed ammo
989         if(item.itemdef.instanceOfWeaponPickup)
990         {
991                 entity ammo = NULL;
992                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
993                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
994                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
995                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
996                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
997                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
998
999                 if(!ammo)
1000                         return 0;
1001                 wpn = item;
1002                 rating = ammo.m_botvalue;
1003         }
1004         else
1005         {
1006                 FOREACH(Weapons, it != WEP_Null, {
1007                         if(!(player.weapons & (it.m_wepset)))
1008                                 continue;
1009
1010                         switch(it.ammo_field)
1011                         {
1012                                 case ammo_shells:  need_shells  = true; break;
1013                                 case ammo_shells:  need_shells  = true; break;
1014                                 case ammo_nails:   need_nails   = true; break;
1015                                 case ammo_rockets: need_rockets = true; break;
1016                                 case ammo_cells:   need_cells   = true; break;
1017                                 case ammo_plasma:  need_plasma  = true; break;
1018                                 case ammo_fuel:    need_fuel    = true; break;
1019                         }
1020                 });
1021                 rating = item.bot_pickupbasevalue;
1022         }
1023
1024         if (need_shells)
1025         if (item.ammo_shells)
1026         if (player.ammo_shells < g_pickup_shells_max)
1027                 c = item.ammo_shells / player.ammo_shells;
1028         if (need_nails)
1029         if (item.ammo_nails)
1030         if (player.ammo_nails < g_pickup_nails_max)
1031                 c = item.ammo_nails / player.ammo_nails;
1032         if (need_rockets)
1033         if (item.ammo_rockets)
1034         if (player.ammo_rockets < g_pickup_rockets_max)
1035                 c = item.ammo_rockets / player.ammo_rockets;
1036         if (need_cells)
1037         if (item.ammo_cells)
1038         if (player.ammo_cells < g_pickup_cells_max)
1039                 c = item.ammo_cells / player.ammo_cells;
1040         if (need_plasma)
1041         if (item.ammo_plasma)
1042         if (player.ammo_plasma < g_pickup_plasma_max)
1043                 c = item.ammo_plasma / player.ammo_plasma;
1044         if (need_fuel)
1045         if (item.ammo_fuel)
1046         if (player.ammo_fuel < g_pickup_fuel_max)
1047                 c = item.ammo_fuel / player.ammo_fuel;
1048
1049         rating *= min(2, c);
1050         if(wpn)
1051                 rating += wpn.bot_pickupbasevalue * 0.1;
1052         return rating;
1053 }
1054
1055 .int item_group;
1056 .int item_group_count;
1057 float healtharmor_pickupevalfunc(entity player, entity item)
1058 {
1059         float c = 0;
1060         float rating = item.bot_pickupbasevalue;
1061
1062         float itemarmor = item.armorvalue;
1063         float itemhealth = item.health;
1064         if(item.item_group)
1065         {
1066                 itemarmor *= min(4, item.item_group_count);
1067                 itemhealth *= min(4, item.item_group_count);
1068         }
1069         if (itemarmor)
1070         if (player.armorvalue < item.max_armorvalue)
1071                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1072         if (itemhealth)
1073         if (player.health < item.max_health)
1074                 c = itemhealth / max(1, player.health);
1075
1076         rating *= min(2, c);
1077         return rating;
1078 }
1079
1080 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1081 {
1082         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1083                 RemoveItem(this);
1084 }
1085
1086 void item_use(entity this, entity actor, entity trigger)
1087 {
1088         // use the touch function to handle collection
1089         gettouch(this)(this, actor);
1090 }
1091
1092 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1093 {
1094         string itemname = def.m_name;
1095         Model itemmodel = def.m_model;
1096     Sound pickupsound = def.m_sound;
1097         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1098         float pickupbasevalue = def.m_botvalue;
1099         int itemflags = def.m_itemflags;
1100
1101         startitem_failed = false;
1102
1103         this.item_model_ent = itemmodel;
1104     this.item_pickupsound_ent = pickupsound;
1105
1106     if(def.m_iteminit)
1107         def.m_iteminit(this);
1108
1109         if(!this.respawntime) // both need to be set
1110         {
1111                 this.respawntime = defaultrespawntime;
1112                 this.respawntimejitter = defaultrespawntimejitter;
1113         }
1114
1115         if(!this.pickup_anyway && def.m_pickupanyway)
1116                 this.pickup_anyway = def.m_pickupanyway();
1117
1118         int itemid = def.m_itemid;
1119         this.items = itemid;
1120         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1121         this.weapon = weaponid;
1122
1123         if(!this.fade_end)
1124         {
1125                 this.fade_start = autocvar_g_items_mindist;
1126                 this.fade_end = autocvar_g_items_maxdist;
1127         }
1128
1129         if(weaponid)
1130                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1131
1132         this.flags = FL_ITEM | itemflags;
1133         IL_PUSH(g_items, this);
1134
1135         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1136         {
1137                 startitem_failed = true;
1138                 delete(this);
1139                 return;
1140         }
1141
1142         // is it a dropped weapon?
1143         if (this.classname == "droppedweapon")
1144         {
1145                 this.reset = SUB_Remove;
1146                 // it's a dropped weapon
1147                 set_movetype(this, MOVETYPE_TOSS);
1148
1149                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1150                 setthink(this, RemoveItem);
1151                 this.nextthink = time + 20;
1152
1153                 this.takedamage = DAMAGE_YES;
1154                 this.event_damage = Item_Damage;
1155
1156                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1157                 {
1158                         // if item is worthless after a timer, have it expire then
1159                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1160                 }
1161
1162                 // don't drop if in a NODROP zone (such as lava)
1163                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1164                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1165                 {
1166                         startitem_failed = true;
1167                         delete(this);
1168                         return;
1169                 }
1170         }
1171         else
1172         {
1173                 if(!have_pickup_item(this))
1174                 {
1175                         startitem_failed = true;
1176                         delete (this);
1177                         return;
1178                 }
1179
1180                 if(this.angles != '0 0 0')
1181                         this.SendFlags |= ISF_ANGLES;
1182
1183                 this.reset = Item_Reset;
1184                 // it's a level item
1185                 if(this.spawnflags & 1)
1186                         this.noalign = 1;
1187                 if (this.noalign > 0)
1188                         set_movetype(this, MOVETYPE_NONE);
1189                 else
1190                         set_movetype(this, MOVETYPE_TOSS);
1191                 // do item filtering according to game mode and other things
1192                 if (this.noalign <= 0)
1193                 {
1194                         // first nudge it off the floor a little bit to avoid math errors
1195                         setorigin(this, this.origin + '0 0 1');
1196                         // set item size before we spawn a spawnfunc_waypoint
1197                         setsize(this, def.m_mins, def.m_maxs);
1198                         this.SendFlags |= ISF_SIZE;
1199                         // note droptofloor returns false if stuck/or would fall too far
1200                         if (!this.noalign)
1201                                 droptofloor(this);
1202                         waypoint_spawnforitem(this);
1203                 }
1204
1205                 /*
1206                  * can't do it that way, as it would break maps
1207                  * TODO make a target_give like entity another way, that perhaps has
1208                  * the weapon name in a key
1209                 if(this.targetname)
1210                 {
1211                         // target_give not yet supported; maybe later
1212                         print("removed targeted ", this.classname, "\n");
1213                         startitem_failed = true;
1214                         remove (this);
1215                         return;
1216                 }
1217                 */
1218
1219                 if(this.targetname != "" && (this.spawnflags & 16))
1220                         this.use = item_use;
1221
1222                 if(autocvar_spawn_debug >= 2)
1223                 {
1224             // why not flags & fl_item?
1225                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1226                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1227                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1228                 error("Mapper sucks.");
1229             });
1230                         this.is_item = true;
1231                 }
1232
1233                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1234
1235                 precache_model(this.model);
1236                 precache_sound(this.item_pickupsound);
1237
1238                 if (   def.instanceOfPowerup
1239                         || def.instanceOfWeaponPickup
1240                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1241                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1242                         || (itemid & (IT_KEY1 | IT_KEY2))
1243                 ) this.target = "###item###"; // for finding the nearest item using find()
1244
1245                 Item_ItemsTime_SetTime(this, 0);
1246         }
1247
1248         this.bot_pickup = true;
1249         this.bot_pickupevalfunc = pickupevalfunc;
1250         this.bot_pickupbasevalue = pickupbasevalue;
1251         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1252         this.netname = itemname;
1253         settouch(this, Item_Touch);
1254         setmodel(this, MDL_Null); // precision set below
1255         //this.effects |= EF_LOWPRECISION;
1256
1257         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1258
1259         this.SendFlags |= ISF_SIZE;
1260
1261         if (!(this.spawnflags & 1024)) {
1262                 if(def.instanceOfPowerup)
1263                         this.ItemStatus |= ITS_ANIMATE1;
1264
1265                 if(this.armorvalue || this.health)
1266                         this.ItemStatus |= ITS_ANIMATE2;
1267         }
1268
1269         if(def.instanceOfWeaponPickup)
1270         {
1271                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1272                         this.colormap = 1024; // color shirt=0 pants=0 grey
1273                 else
1274                         this.gravity = 1;
1275                 if (!(this.spawnflags & 1024))
1276                         this.ItemStatus |= ITS_ANIMATE1;
1277                 this.SendFlags |= ISF_COLORMAP;
1278         }
1279
1280         this.state = 0;
1281         if(this.team) // broken, no idea why.
1282         {
1283                 if(!this.cnt)
1284                         this.cnt = 1; // item probability weight
1285
1286                 this.effects |= EF_NODRAW; // marker for item team search
1287                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1288         }
1289         else
1290                 Item_Reset(this);
1291
1292         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1293
1294         // call this hook after everything else has been done
1295         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1296         {
1297                 startitem_failed = true;
1298                 delete(this);
1299                 return;
1300         }
1301
1302         setItemGroup(this);
1303 }
1304
1305 void StartItem(entity this, GameItem def)
1306 {
1307     _StartItem(
1308         this,
1309         this.itemdef = def,
1310         def.m_respawntime(), // defaultrespawntime
1311         def.m_respawntimejitter() // defaultrespawntimejitter
1312         );
1313 }
1314
1315 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1316 int group_count = 1;
1317
1318 void setItemGroup(entity this)
1319 {
1320         if(!IS_SMALL(this.itemdef))
1321                 return;
1322
1323         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1324         {
1325                 if(!this.item_group)
1326                 {
1327                         if(!it.item_group)
1328                         {
1329                                 it.item_group = group_count;
1330                                 group_count++;
1331                         }
1332                         this.item_group = it.item_group;
1333                 }
1334                 else // spawning item is already part of a item_group X
1335                 {
1336                         if(!it.item_group)
1337                                 it.item_group = this.item_group;
1338                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1339                         {
1340                                 int grY = it.item_group;
1341                                 // move all items of item_group Y to item_group X
1342                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1343                                 {
1344                                         if(it.item_group == grY)
1345                                                 it.item_group = this.item_group;
1346                                 });
1347                         }
1348                 }
1349         });
1350 }
1351
1352 void setItemGroupCount()
1353 {
1354         for (int k = 1; k <= group_count; k++)
1355         {
1356                 int count = 0;
1357                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1358                 if (count)
1359                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1360         }
1361 }
1362
1363 spawnfunc(item_rockets)
1364 {
1365     StartItem(this, ITEM_Rockets);
1366 }
1367
1368 spawnfunc(item_bullets)
1369 {
1370         if(!weaponswapping)
1371         if(autocvar_sv_q3acompat_machineshotgunswap)
1372         if(this.classname != "droppedweapon")
1373         {
1374                 weaponswapping = true;
1375                 spawnfunc_item_shells(this);
1376                 weaponswapping = false;
1377                 return;
1378         }
1379
1380     StartItem(this, ITEM_Bullets);
1381 }
1382
1383 spawnfunc(item_cells)
1384 {
1385         StartItem(this, ITEM_Cells);
1386 }
1387
1388 spawnfunc(item_plasma)
1389 {
1390         StartItem(this, ITEM_Plasma);
1391 }
1392
1393 spawnfunc(item_shells)
1394 {
1395         if(!weaponswapping)
1396         if(autocvar_sv_q3acompat_machineshotgunswap)
1397         if(this.classname != "droppedweapon")
1398         {
1399                 weaponswapping = true;
1400                 spawnfunc_item_bullets(this);
1401                 weaponswapping = false;
1402                 return;
1403         }
1404
1405         StartItem(this, ITEM_Shells);
1406 }
1407
1408 spawnfunc(item_armor_small)
1409 {
1410         StartItem(this, ITEM_ArmorSmall);
1411 }
1412
1413 spawnfunc(item_armor_medium)
1414 {
1415         StartItem(this, ITEM_ArmorMedium);
1416 }
1417
1418 spawnfunc(item_armor_big)
1419 {
1420         StartItem(this, ITEM_ArmorBig);
1421 }
1422
1423 spawnfunc(item_armor_mega)
1424 {
1425         StartItem(this, ITEM_ArmorMega);
1426 }
1427
1428 spawnfunc(item_health_small)
1429 {
1430         StartItem(this, ITEM_HealthSmall);
1431 }
1432
1433 spawnfunc(item_health_medium)
1434 {
1435     StartItem(this, ITEM_HealthMedium);
1436 }
1437
1438 spawnfunc(item_health_big)
1439 {
1440         StartItem(this, ITEM_HealthBig);
1441 }
1442
1443 spawnfunc(item_health_mega)
1444 {
1445     StartItem(this, ITEM_HealthMega);
1446 }
1447
1448 // support old misnamed entities
1449 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1450 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1451 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1452 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1453 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1454 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1455 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1456
1457 spawnfunc(item_strength)
1458 {
1459         StartItem(this, ITEM_Strength);
1460 }
1461
1462 spawnfunc(item_invincible)
1463 {
1464         StartItem(this, ITEM_Shield);
1465 }
1466
1467 // compatibility:
1468 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1469
1470 void target_items_use(entity this, entity actor, entity trigger)
1471 {
1472         if(actor.classname == "droppedweapon")
1473         {
1474                 EXACTTRIGGER_TOUCH(this, trigger);
1475                 delete(actor);
1476                 return;
1477         }
1478
1479         if (!IS_PLAYER(actor))
1480                 return;
1481         if(IS_DEAD(actor))
1482                 return;
1483         if(trigger.solid == SOLID_TRIGGER)
1484         {
1485                 EXACTTRIGGER_TOUCH(this, trigger);
1486         }
1487
1488         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1489         {
1490                 delete(it);
1491         });
1492
1493         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1494                 centerprint(actor, this.message);
1495 }
1496
1497 spawnfunc(target_items)
1498 {
1499         int n, j;
1500         string s;
1501
1502         this.use = target_items_use;
1503         if(!this.strength_finished)
1504                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1505         if(!this.invincible_finished)
1506                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1507         if(!this.superweapons_finished)
1508                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1509
1510         n = tokenize_console(this.netname);
1511         if(argv(0) == "give")
1512         {
1513                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1514         }
1515         else
1516         {
1517                 for(j = 0; j < n; ++j)
1518                 {
1519                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1520                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1521                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1522                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1523                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1524                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1525                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1526                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1527                         else
1528                         {
1529                                 FOREACH(Buffs, it != BUFF_Null,
1530                                 {
1531                                         s = Buff_UndeprecateName(argv(j));
1532                                         if(s == it.m_name)
1533                                         {
1534                                                 this.buffs |= (it.m_itemid);
1535                                                 break;
1536                                         }
1537                                 });
1538                                 FOREACH(Weapons, it != WEP_Null, {
1539                                         s = W_UndeprecateName(argv(j));
1540                                         if(s == it.netname)
1541                                         {
1542                                                 this.weapons |= (it.m_wepset);
1543                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1544                                                         it.wr_init(it);
1545                                                 break;
1546                                         }
1547                                 });
1548                         }
1549                 }
1550
1551                 string itemprefix, valueprefix;
1552                 if(this.spawnflags == 0)
1553                 {
1554                         itemprefix = "";
1555                         valueprefix = "";
1556                 }
1557                 else if(this.spawnflags == 1)
1558                 {
1559                         itemprefix = "max ";
1560                         valueprefix = "max ";
1561                 }
1562                 else if(this.spawnflags == 2)
1563                 {
1564                         itemprefix = "min ";
1565                         valueprefix = "min ";
1566                 }
1567                 else if(this.spawnflags == 4)
1568                 {
1569                         itemprefix = "minus ";
1570                         valueprefix = "max ";
1571                 }
1572                 else
1573                 {
1574                         error("invalid spawnflags");
1575                         itemprefix = valueprefix = string_null;
1576                 }
1577
1578                 this.netname = "";
1579                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1580                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1581                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1582                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1583                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1584                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1585                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1586                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1587                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1588                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1589                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1590                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1591                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1592                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1593                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1594                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1595                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1596         }
1597         this.netname = strzone(this.netname);
1598         //print(this.netname, "\n");
1599
1600         n = tokenize_console(this.netname);
1601         for(j = 0; j < n; ++j)
1602         {
1603                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1604             it.wr_init(it);
1605             break;
1606                 });
1607         }
1608 }
1609
1610 spawnfunc(item_fuel)
1611 {
1612         StartItem(this, ITEM_JetpackFuel);
1613 }
1614
1615 spawnfunc(item_fuel_regen)
1616 {
1617         if(start_items & ITEM_JetpackRegen.m_itemid)
1618         {
1619                 spawnfunc_item_fuel(this);
1620                 return;
1621         }
1622         StartItem(this, ITEM_JetpackRegen);
1623 }
1624
1625 spawnfunc(item_jetpack)
1626 {
1627         if(start_items & ITEM_Jetpack.m_itemid)
1628         {
1629                 spawnfunc_item_fuel(this);
1630                 return;
1631         }
1632         StartItem(this, ITEM_Jetpack);
1633 }
1634
1635 float GiveWeapon(entity e, float wpn, float op, float val)
1636 {
1637         WepSet v0, v1;
1638         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1639         v0 = (e.weapons & s);
1640         switch(op)
1641         {
1642                 case OP_SET:
1643                         if(val > 0)
1644                                 e.weapons |= s;
1645                         else
1646                                 e.weapons &= ~s;
1647                         break;
1648                 case OP_MIN:
1649                 case OP_PLUS:
1650                         if(val > 0)
1651                                 e.weapons |= s;
1652                         break;
1653                 case OP_MAX:
1654                         if(val <= 0)
1655                                 e.weapons &= ~s;
1656                         break;
1657                 case OP_MINUS:
1658                         if(val > 0)
1659                                 e.weapons &= ~s;
1660                         break;
1661         }
1662         v1 = (e.weapons & s);
1663         return (v0 != v1);
1664 }
1665
1666 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1667 {
1668         bool had_buff = (e.buffs & thebuff.m_itemid);
1669         switch(op)
1670         {
1671                 case OP_SET:
1672                         if(val > 0)
1673                                 e.buffs |= thebuff.m_itemid;
1674                         else
1675                                 e.buffs &= ~thebuff.m_itemid;
1676                         break;
1677                 case OP_MIN:
1678                 case OP_PLUS:
1679                         if(val > 0)
1680                                 e.buffs |= thebuff.m_itemid;
1681                         break;
1682                 case OP_MAX:
1683                         if(val <= 0)
1684                                 e.buffs &= ~thebuff.m_itemid;
1685                         break;
1686                 case OP_MINUS:
1687                         if(val > 0)
1688                                 e.buffs &= ~thebuff.m_itemid;
1689                         break;
1690         }
1691         bool have_buff = (e.buffs & thebuff.m_itemid);
1692         return (had_buff != have_buff);
1693 }
1694
1695 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1696 {
1697         if(v1 == v0)
1698                 return;
1699         if(v1 <= v0 - t)
1700         {
1701                 if(snd_decr != NULL)
1702                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1703         }
1704         else if(v0 >= v0 + t)
1705         {
1706                 if(snd_incr != NULL)
1707                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1708         }
1709 }
1710
1711 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1712 {
1713         if(v0 < v1)
1714                 e.(rotfield) = max(e.(rotfield), time + rottime);
1715         else if(v0 > v1)
1716                 e.(regenfield) = max(e.(regenfield), time + regentime);
1717 }
1718 float GiveItems(entity e, float beginarg, float endarg)
1719 {
1720         float got, i, val, op;
1721         string cmd;
1722
1723         val = 999;
1724         op = OP_SET;
1725
1726         got = 0;
1727
1728         int _switchweapon = 0;
1729
1730         if(e.autoswitch)
1731         {
1732                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1733                 {
1734                         .entity weaponentity = weaponentities[slot];
1735                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1736                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1737                                 _switchweapon |= BIT(slot);
1738                 }
1739         }
1740
1741         e.strength_finished = max(0, e.strength_finished - time);
1742         e.invincible_finished = max(0, e.invincible_finished - time);
1743         e.superweapons_finished = max(0, e.superweapons_finished - time);
1744
1745         PREGIVE(e, items);
1746         PREGIVE_WEAPONS(e);
1747         PREGIVE(e, strength_finished);
1748         PREGIVE(e, invincible_finished);
1749         PREGIVE(e, superweapons_finished);
1750         PREGIVE(e, ammo_nails);
1751         PREGIVE(e, ammo_cells);
1752         PREGIVE(e, ammo_plasma);
1753         PREGIVE(e, ammo_shells);
1754         PREGIVE(e, ammo_rockets);
1755         PREGIVE(e, ammo_fuel);
1756         PREGIVE(e, armorvalue);
1757         PREGIVE(e, health);
1758
1759         for(i = beginarg; i < endarg; ++i)
1760         {
1761                 cmd = argv(i);
1762
1763                 if(cmd == "0" || stof(cmd))
1764                 {
1765                         val = stof(cmd);
1766                         continue;
1767                 }
1768                 switch(cmd)
1769                 {
1770                         case "no":
1771                                 op = OP_MAX;
1772                                 val = 0;
1773                                 continue;
1774                         case "max":
1775                                 op = OP_MAX;
1776                                 continue;
1777                         case "min":
1778                                 op = OP_MIN;
1779                                 continue;
1780                         case "plus":
1781                                 op = OP_PLUS;
1782                                 continue;
1783                         case "minus":
1784                                 op = OP_MINUS;
1785                                 continue;
1786                         case "ALL":
1787                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1788                                 got += GiveValue(e, strength_finished, op, val);
1789                                 got += GiveValue(e, invincible_finished, op, val);
1790                                 got += GiveValue(e, superweapons_finished, op, val);
1791                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1792                         case "all":
1793                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1794                                 got += GiveValue(e, health, op, val);
1795                                 got += GiveValue(e, armorvalue, op, val);
1796                         case "allweapons":
1797                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1798                         //case "allbuffs": // all buffs makes a player god, do not want!
1799                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1800                         case "allammo":
1801                                 got += GiveValue(e, ammo_cells, op, val);
1802                                 got += GiveValue(e, ammo_plasma, op, val);
1803                                 got += GiveValue(e, ammo_shells, op, val);
1804                                 got += GiveValue(e, ammo_nails, op, val);
1805                                 got += GiveValue(e, ammo_rockets, op, val);
1806                                 got += GiveValue(e, ammo_fuel, op, val);
1807                                 break;
1808                         case "unlimited_ammo":
1809                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1810                                 break;
1811                         case "unlimited_weapon_ammo":
1812                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1813                                 break;
1814                         case "unlimited_superweapons":
1815                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1816                                 break;
1817                         case "jetpack":
1818                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1819                                 break;
1820                         case "fuel_regen":
1821                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1822                                 break;
1823                         case "strength":
1824                                 got += GiveValue(e, strength_finished, op, val);
1825                                 break;
1826                         case "invincible":
1827                                 got += GiveValue(e, invincible_finished, op, val);
1828                                 break;
1829                         case "superweapons":
1830                                 got += GiveValue(e, superweapons_finished, op, val);
1831                                 break;
1832                         case "cells":
1833                                 got += GiveValue(e, ammo_cells, op, val);
1834                                 break;
1835                         case "plasma":
1836                                 got += GiveValue(e, ammo_plasma, op, val);
1837                                 break;
1838                         case "shells":
1839                                 got += GiveValue(e, ammo_shells, op, val);
1840                                 break;
1841                         case "nails":
1842                         case "bullets":
1843                                 got += GiveValue(e, ammo_nails, op, val);
1844                                 break;
1845                         case "rockets":
1846                                 got += GiveValue(e, ammo_rockets, op, val);
1847                                 break;
1848                         case "health":
1849                                 got += GiveValue(e, health, op, val);
1850                                 break;
1851                         case "armor":
1852                                 got += GiveValue(e, armorvalue, op, val);
1853                                 break;
1854                         case "fuel":
1855                                 got += GiveValue(e, ammo_fuel, op, val);
1856                                 break;
1857                         default:
1858                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1859                                 {
1860                                         got += GiveBuff(e, it, op, val);
1861                                         break;
1862                                 });
1863                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1864                     got += GiveWeapon(e, it.m_id, op, val);
1865                     break;
1866                                 });
1867                                 break;
1868                 }
1869                 val = 999;
1870                 op = OP_SET;
1871         }
1872
1873         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1874         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1875         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1876         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1877         FOREACH(Weapons, it != WEP_Null, {
1878                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1879                 if(!(save_weapons & (it.m_wepset)))
1880                         if(e.weapons & (it.m_wepset))
1881                                 it.wr_init(it);
1882         });
1883         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1884         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1885         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1886         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1887         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1888         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1889         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1890         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1891         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1892         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1893         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1894
1895         if(e.superweapons_finished <= 0)
1896                 if(e.weapons & WEPSET_SUPERWEAPONS)
1897                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1898
1899         if(e.strength_finished <= 0)
1900                 e.strength_finished = 0;
1901         else
1902                 e.strength_finished += time;
1903         if(e.invincible_finished <= 0)
1904                 e.invincible_finished = 0;
1905         else
1906                 e.invincible_finished += time;
1907         if(e.superweapons_finished <= 0)
1908                 e.superweapons_finished = 0;
1909         else
1910                 e.superweapons_finished += time;
1911
1912         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1913         {
1914                 .entity weaponentity = weaponentities[slot];
1915                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1916                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1917                         _switchweapon |= BIT(slot);
1918         }
1919
1920         if(_switchweapon)
1921         {
1922                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1923                 {
1924                         .entity weaponentity = weaponentities[slot];
1925                         if(_switchweapon & BIT(slot))
1926                         {
1927                                 Weapon wep = w_getbestweapon(e, weaponentity);
1928                                 if(wep != e.(weaponentity).m_switchweapon)
1929                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1930                         }
1931                 }
1932         }
1933
1934         return got;
1935 }
1936 #endif