qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 void Item_ScheduleRespawn(entity e)
 635 {
 636         if(e.respawntime > 0)
 637         {
 638                 Item_Show(e, 0);
 639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 640         }
 641         else // if respawntime is -1, this item does not respawn
 642                 Item_Show(e, -1);
 643 }
 644
 645 void Item_ScheduleInitialRespawn(entity e)
 646 {
 647         Item_Show(e, 0);
 648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 649 }
 650
 651 void GivePlayerHealth(entity player, float amount)
 652 {
 653         if (amount == 0)
 654         {
 655                 return;
 656         }
 657         player.health = bound(player.health, player.health + amount,
 658                  autocvar_g_balance_health_limit);
 659         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
 660                 autocvar_g_balance_pause_health_rot);
 661 }
 662
 663 void GivePlayerArmor(entity player, float amount)
 664 {
 665         if (amount == 0)
 666         {
 667                 return;
 668         }
 669         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 670                  autocvar_g_balance_armor_limit);
 671         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
 672                 autocvar_g_balance_pause_armor_rot);
 673 }
 674
 675 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 676 {
 677         float maxvalue = 999;
 678         switch (ammotype)
 679         {
 680                 case ammo_shells:
 681                 {
 682                         maxvalue = g_pickup_shells_max;
 683                         break;
 684                 }
 685                 case ammo_cells:
 686                 {
 687                         maxvalue = g_pickup_cells_max;
 688                         break;
 689                 }
 690                 case ammo_rockets:
 691                 {
 692                         maxvalue = g_pickup_rockets_max;
 693                         break;
 694                 }
 695                 case ammo_plasma:
 696                 {
 697                         maxvalue = g_pickup_plasma_max;
 698                         break;
 699                 }
 700                 case ammo_nails:
 701                 {
 702                         maxvalue = g_pickup_nails_max;
 703                         break;
 704                 }
 705                 case ammo_fuel:
 706                 {
 707                         maxvalue = g_pickup_fuel_max;
 708                         break;
 709                 }
 710         }
 711         player.(ammotype) = min(player.(ammotype) + amount, maxvalue);
 712 }
 713
 714 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 715 {
 716         if (!item.(ammotype))
 717                 return false;
 718
 719         if (item.spawnshieldtime)
 720         {
 721                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 722                 {
 723                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 724                         goto YEAH;
 725                 }
 726         }
 727         else if(g_weapon_stay == 2)
 728         {
 729                 float mi = min(item.(ammotype), ammomax);
 730                 if (player.(ammotype) < mi)
 731                 {
 732                         player.(ammotype) = mi;
 733                         goto YEAH;
 734                 }
 735         }
 736
 737         return false;
 738
 739 LABEL(YEAH)
 740         switch(mode)
 741         {
 742                 case ITEM_MODE_FUEL:
 743                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 744                         break;
 745                 case ITEM_MODE_HEALTH:
 746                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 747                         break;
 748                 case ITEM_MODE_ARMOR:
 749                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 750                         break;
 751                 default:
 752                         break;
 753         }
 754         return true;
 755 }
 756
 757 float Item_GiveTo(entity item, entity player)
 758 {
 759         float pickedup;
 760
 761         // if nothing happens to player, just return without taking the item
 762         pickedup = false;
 763         int _switchweapon = 0;
 764         // in case the player has autoswitch enabled do the following:
 765         // if the player is using their best weapon before items are given, they
 766         // probably want to switch to an even better weapon after items are given
 767
 768         if(CS(player).autoswitch)
 769         {
 770                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771                 {
 772                         .entity weaponentity = weaponentities[slot];
 773                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 774                         {
 775                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 776                                         _switchweapon |= BIT(slot);
 777
 778                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 779                                         _switchweapon |= BIT(slot);
 780                         }
 781                 }
 782         }
 783
 784         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 785         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 786         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 787         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 788         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 789         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 790         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 791         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 792
 793         if (item.itemdef.instanceOfWeaponPickup)
 794         {
 795                 WepSet w;
 796                 w = item.weapons;
 797                 w &= ~player.weapons;
 798
 799                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 800                 {
 801                         pickedup = true;
 802                         FOREACH(Weapons, it != WEP_Null, {
 803                                 if(w & (it.m_wepset))
 804                                 {
 805                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 806                                         {
 807                                                 .entity weaponentity = weaponentities[slot];
 808                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 809                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 810                                         }
 811                                         W_GiveWeapon(player, it.m_id);
 812                                 }
 813                         });
 814                 }
 815         }
 816
 817         if (item.itemdef.instanceOfPowerup)
 818         {
 819                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 820                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 821                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 822                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 823         }
 824
 825         int its;
 826         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 827         {
 828                 pickedup = true;
 829                 player.items |= its;
 830                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 831         }
 832
 833         if (item.strength_finished)
 834         {
 835                 pickedup = true;
 836                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 837         }
 838         if (item.invincible_finished)
 839         {
 840                 pickedup = true;
 841                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 842         }
 843         if (item.superweapons_finished)
 844         {
 845                 pickedup = true;
 846                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 847         }
 848
 849 LABEL(skip)
 850
 851         // always eat teamed entities
 852         if(item.team)
 853                 pickedup = true;
 854
 855         if (!pickedup)
 856                 return 0;
 857
 858         // crude hack to enforce switching weapons
 859         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 860         {
 861                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 862                 {
 863                         .entity weaponentity = weaponentities[slot];
 864                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 865                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 866                 }
 867                 return 1;
 868         }
 869
 870         if(_switchweapon)
 871         {
 872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 873                 {
 874                         .entity weaponentity = weaponentities[slot];
 875                         if(_switchweapon & BIT(slot))
 876                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 877                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 878                 }
 879         }
 880
 881         return 1;
 882 }
 883
 884 void Item_Touch(entity this, entity toucher)
 885 {
 886
 887         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 888         if (this.classname == "droppedweapon")
 889         {
 890                 if (ITEM_TOUCH_NEEDKILL())
 891                 {
 892                         delete(this);
 893                         return;
 894                 }
 895         }
 896
 897         if(!(toucher.flags & FL_PICKUPITEMS)
 898         || STAT(FROZEN, toucher)
 899         || IS_DEAD(toucher)
 900         || (this.solid != SOLID_TRIGGER)
 901         || (this.owner == toucher)
 902         || (time < this.item_spawnshieldtime)
 903         ) { return; }
 904
 905         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 906         {
 907                 case MUT_ITEMTOUCH_RETURN: { return; }
 908                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 909         }
 910
 911         toucher = M_ARGV(1, entity);
 912
 913         if (this.classname == "droppedweapon")
 914         {
 915                 this.strength_finished = max(0, this.strength_finished - time);
 916                 this.invincible_finished = max(0, this.invincible_finished - time);
 917                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 918         }
 919         entity it = this.itemdef;
 920         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 921         if (!gave)
 922         {
 923                 if (this.classname == "droppedweapon")
 924                 {
 925                         // undo what we did above
 926                         this.strength_finished += time;
 927                         this.invincible_finished += time;
 928                         this.superweapons_finished += time;
 929                 }
 930                 return;
 931         }
 932
 933 LABEL(pickup)
 934
 935         toucher.last_pickup = time;
 936
 937         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 938         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 939
 940         if (this.classname == "droppedweapon")
 941                 delete(this);
 942         else if (this.spawnshieldtime)
 943         {
 944                 entity e;
 945                 if(this.team)
 946                 {
 947                         RandomSelection_Init();
 948                         IL_EACH(g_items, it.team == this.team,
 949                         {
 950                                 if(it.itemdef) // is a registered item
 951                                 {
 952                                         Item_Show(it, -1);
 953                                         RandomSelection_AddEnt(it, it.cnt, 0);
 954                                 }
 955                         });
 956                         e = RandomSelection_chosen_ent;
 957                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 958                 }
 959                 else
 960                         e = this;
 961                 Item_ScheduleRespawn(e);
 962         }
 963 }
 964
 965 void Item_Reset(entity this)
 966 {
 967         Item_Show(this, !this.state);
 968         setorigin(this, this.origin);
 969
 970         if (this.classname != "droppedweapon")
 971         {
 972                 setthink(this, Item_Think);
 973                 this.nextthink = time;
 974
 975                 if (this.waypointsprite_attached)
 976                         WaypointSprite_Kill(this.waypointsprite_attached);
 977
 978                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 979                         Item_ScheduleInitialRespawn(this);
 980         }
 981 }
 982
 983 void Item_FindTeam(entity this)
 984 {
 985         entity e;
 986
 987         if(this.effects & EF_NODRAW)
 988         {
 989                 // marker for item team search
 990                 LOG_TRACE("Initializing item team ", ftos(this.team));
 991                 RandomSelection_Init();
 992                 IL_EACH(g_items, it.team == this.team,
 993                 {
 994                         if(it.itemdef) // is a registered item
 995                                 RandomSelection_AddEnt(it, it.cnt, 0);
 996                 });
 997
 998                 e = RandomSelection_chosen_ent;
 999                 e.state = 0;
1000                 Item_Show(e, 1);
1001
1002                 IL_EACH(g_items, it.team == this.team,
1003                 {
1004                         if(it.itemdef) // is a registered item
1005                         {
1006                                 if(it != e)
1007                                 {
1008                                         // make it non-spawned
1009                                         Item_Show(it, -1);
1010                                         it.state = 1; // state 1 = initially hidden item, apparently
1011                                 }
1012                                 it.effects &= ~EF_NODRAW;
1013                         }
1014                 });
1015
1016                 Item_Reset(this);
1017         }
1018 }
1019
1020 // Savage: used for item garbage-collection
1021 void RemoveItem(entity this)
1022 {
1023         if(wasfreed(this) || !this) { return; }
1024         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1025         delete(this);
1026 }
1027
1028 // pickup evaluation functions
1029 // these functions decide how desirable an item is to the bots
1030
1031 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1032
1033 float weapon_pickupevalfunc(entity player, entity item)
1034 {
1035         // See if I have it already
1036         if(player.weapons & item.weapons)
1037         {
1038                 // If I can pick it up
1039                 if(!item.spawnshieldtime)
1040                         return 0;
1041                 return ammo_pickupevalfunc(player, item);
1042         }
1043
1044         // reduce weapon value if bot already got a good arsenal
1045         float c = 1;
1046         int weapons_value = 0;
1047         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1048                 weapons_value += it.bot_pickupbasevalue;
1049         });
1050         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1051
1052         return item.bot_pickupbasevalue * c;
1053 }
1054
1055 float ammo_pickupevalfunc(entity player, entity item)
1056 {
1057         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1058         entity wpn = NULL;
1059         float c = 0;
1060         float rating = 0;
1061
1062         // Detect needed ammo
1063         if(item.itemdef.instanceOfWeaponPickup)
1064         {
1065                 entity ammo = NULL;
1066                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1067                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1068                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1069                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1070                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1071                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1072
1073                 if(!ammo)
1074                         return 0;
1075                 wpn = item;
1076                 rating = ammo.m_botvalue;
1077         }
1078         else
1079         {
1080                 FOREACH(Weapons, it != WEP_Null, {
1081                         if(!(player.weapons & (it.m_wepset)))
1082                                 continue;
1083
1084                         switch(it.ammo_field)
1085                         {
1086                                 case ammo_shells:  need_shells  = true; break;
1087                                 case ammo_nails:   need_nails   = true; break;
1088                                 case ammo_rockets: need_rockets = true; break;
1089                                 case ammo_cells:   need_cells   = true; break;
1090                                 case ammo_plasma:  need_plasma  = true; break;
1091                                 case ammo_fuel:    need_fuel    = true; break;
1092                         }
1093                 });
1094                 rating = item.bot_pickupbasevalue;
1095         }
1096
1097         float noammorating = 0.5;
1098
1099         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1100                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1101
1102         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1103                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1104
1105         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1106                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1107
1108         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1109                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1110
1111         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1112                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1113
1114         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1115                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1116
1117         rating *= min(c, 2);
1118         if(wpn)
1119                 rating += wpn.bot_pickupbasevalue * 0.1;
1120         return rating;
1121 }
1122
1123 .int item_group;
1124 .int item_group_count;
1125 float healtharmor_pickupevalfunc(entity player, entity item)
1126 {
1127         float c = 0;
1128         float rating = item.bot_pickupbasevalue;
1129
1130         float itemarmor = item.armorvalue;
1131         float itemhealth = item.health;
1132
1133         if(item.item_group)
1134         {
1135                 itemarmor *= min(4, item.item_group_count);
1136                 itemhealth *= min(4, item.item_group_count);
1137         }
1138
1139         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1140                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1141
1142         if (itemhealth && (player.health < item.max_health))
1143                 c = itemhealth / max(1, player.health);
1144
1145         rating *= min(2, c);
1146         return rating;
1147 }
1148
1149 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1150 {
1151         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1152                 RemoveItem(this);
1153 }
1154
1155 void item_use(entity this, entity actor, entity trigger)
1156 {
1157         // use the touch function to handle collection
1158         gettouch(this)(this, actor);
1159 }
1160
1161 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1162 {
1163         string itemname = def.m_name;
1164         Model itemmodel = def.m_model;
1165     Sound pickupsound = def.m_sound;
1166         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1167         float pickupbasevalue = def.m_botvalue;
1168         int itemflags = def.m_itemflags;
1169
1170         startitem_failed = false;
1171
1172         this.item_model_ent = itemmodel;
1173     this.item_pickupsound_ent = pickupsound;
1174
1175     if(def.m_iteminit)
1176         def.m_iteminit(this);
1177
1178         if(!this.respawntime) // both need to be set
1179         {
1180                 this.respawntime = defaultrespawntime;
1181                 this.respawntimejitter = defaultrespawntimejitter;
1182         }
1183
1184         if(!this.pickup_anyway && def.m_pickupanyway)
1185                 this.pickup_anyway = def.m_pickupanyway();
1186
1187         int itemid = def.m_itemid;
1188         this.items = itemid;
1189         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1190         this.weapon = weaponid;
1191
1192         if(!this.fade_end)
1193         {
1194                 this.fade_start = autocvar_g_items_mindist;
1195                 this.fade_end = autocvar_g_items_maxdist;
1196         }
1197
1198         if(weaponid)
1199                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1200
1201         this.flags = FL_ITEM | itemflags;
1202         IL_PUSH(g_items, this);
1203
1204         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1205         {
1206                 startitem_failed = true;
1207                 delete(this);
1208                 return;
1209         }
1210
1211         // is it a dropped weapon?
1212         if (this.classname == "droppedweapon")
1213         {
1214                 this.reset = SUB_Remove;
1215                 // it's a dropped weapon
1216                 set_movetype(this, MOVETYPE_TOSS);
1217
1218                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1219                 setthink(this, RemoveItem);
1220                 this.nextthink = time + 20;
1221
1222                 this.takedamage = DAMAGE_YES;
1223                 this.event_damage = Item_Damage;
1224
1225                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1226                 {
1227                         // if item is worthless after a timer, have it expire then
1228                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1229                 }
1230
1231                 // don't drop if in a NODROP zone (such as lava)
1232                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1233                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1234                 {
1235                         startitem_failed = true;
1236                         delete(this);
1237                         return;
1238                 }
1239         }
1240         else
1241         {
1242                 if(!have_pickup_item(this))
1243                 {
1244                         startitem_failed = true;
1245                         delete(this);
1246                         return;
1247                 }
1248
1249                 if(this.angles != '0 0 0')
1250                         this.SendFlags |= ISF_ANGLES;
1251
1252                 this.reset = Item_Reset;
1253                 // it's a level item
1254                 if(this.spawnflags & 1)
1255                         this.noalign = 1;
1256                 if (this.noalign > 0)
1257                         set_movetype(this, MOVETYPE_NONE);
1258                 else
1259                         set_movetype(this, MOVETYPE_TOSS);
1260                 // do item filtering according to game mode and other things
1261                 if (this.noalign <= 0)
1262                 {
1263                         // first nudge it off the floor a little bit to avoid math errors
1264                         setorigin(this, this.origin + '0 0 1');
1265                         // set item size before we spawn a spawnfunc_waypoint
1266                         setsize(this, def.m_mins, def.m_maxs);
1267                         this.SendFlags |= ISF_SIZE;
1268                         // note droptofloor returns false if stuck/or would fall too far
1269                         if (!this.noalign)
1270                                 droptofloor(this);
1271                         waypoint_spawnforitem(this);
1272                 }
1273
1274                 /*
1275                  * can't do it that way, as it would break maps
1276                  * TODO make a target_give like entity another way, that perhaps has
1277                  * the weapon name in a key
1278                 if(this.targetname)
1279                 {
1280                         // target_give not yet supported; maybe later
1281                         print("removed targeted ", this.classname, "\n");
1282                         startitem_failed = true;
1283                         delete(this);
1284                         return;
1285                 }
1286                 */
1287
1288                 if(this.targetname != "" && (this.spawnflags & 16))
1289                         this.use = item_use;
1290
1291                 if(autocvar_spawn_debug >= 2)
1292                 {
1293             // why not flags & fl_item?
1294                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1295                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1296                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1297                 error("Mapper sucks.");
1298             });
1299                         this.is_item = true;
1300                 }
1301
1302                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1303
1304                 precache_model(this.model);
1305                 precache_sound(this.item_pickupsound);
1306
1307                 if (   def.instanceOfPowerup
1308                         || def.instanceOfWeaponPickup
1309                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1310                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1311                         || (itemid & (IT_KEY1 | IT_KEY2))
1312                 ) this.target = "###item###"; // for finding the nearest item using find()
1313
1314                 Item_ItemsTime_SetTime(this, 0);
1315         }
1316
1317         this.bot_pickup = true;
1318         this.bot_pickupevalfunc = pickupevalfunc;
1319         this.bot_pickupbasevalue = pickupbasevalue;
1320         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1321         this.netname = itemname;
1322         settouch(this, Item_Touch);
1323         setmodel(this, MDL_Null); // precision set below
1324         //this.effects |= EF_LOWPRECISION;
1325
1326         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1327
1328         this.SendFlags |= ISF_SIZE;
1329
1330         if (!(this.spawnflags & 1024)) {
1331                 if(def.instanceOfPowerup)
1332                         this.ItemStatus |= ITS_ANIMATE1;
1333
1334                 if(this.armorvalue || this.health)
1335                         this.ItemStatus |= ITS_ANIMATE2;
1336         }
1337
1338         if(def.instanceOfWeaponPickup)
1339         {
1340                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1341                         this.colormap = 1024; // color shirt=0 pants=0 grey
1342                 else
1343                         this.gravity = 1;
1344                 if (!(this.spawnflags & 1024))
1345                         this.ItemStatus |= ITS_ANIMATE1;
1346                 this.SendFlags |= ISF_COLORMAP;
1347         }
1348
1349         this.state = 0;
1350         if(this.team) // broken, no idea why.
1351         {
1352                 if(!this.cnt)
1353                         this.cnt = 1; // item probability weight
1354
1355                 this.effects |= EF_NODRAW; // marker for item team search
1356                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1357         }
1358         else
1359                 Item_Reset(this);
1360
1361         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1362
1363         // call this hook after everything else has been done
1364         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1365         {
1366                 startitem_failed = true;
1367                 delete(this);
1368                 return;
1369         }
1370
1371         setItemGroup(this);
1372 }
1373
1374 void StartItem(entity this, GameItem def)
1375 {
1376     _StartItem(
1377         this,
1378         this.itemdef = def,
1379         def.m_respawntime(), // defaultrespawntime
1380         def.m_respawntimejitter() // defaultrespawntimejitter
1381         );
1382 }
1383
1384 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1385 int group_count = 1;
1386
1387 void setItemGroup(entity this)
1388 {
1389         if(!IS_SMALL(this.itemdef))
1390                 return;
1391
1392         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1393         {
1394                 if(!this.item_group)
1395                 {
1396                         if(!it.item_group)
1397                         {
1398                                 it.item_group = group_count;
1399                                 group_count++;
1400                         }
1401                         this.item_group = it.item_group;
1402                 }
1403                 else // spawning item is already part of a item_group X
1404                 {
1405                         if(!it.item_group)
1406                                 it.item_group = this.item_group;
1407                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1408                         {
1409                                 int grY = it.item_group;
1410                                 // move all items of item_group Y to item_group X
1411                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1412                                 {
1413                                         if(it.item_group == grY)
1414                                                 it.item_group = this.item_group;
1415                                 });
1416                         }
1417                 }
1418         });
1419 }
1420
1421 void setItemGroupCount()
1422 {
1423         for (int k = 1; k <= group_count; k++)
1424         {
1425                 int count = 0;
1426                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1427                 if (count)
1428                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1429         }
1430 }
1431
1432 spawnfunc(item_rockets)
1433 {
1434     StartItem(this, ITEM_Rockets);
1435 }
1436
1437 spawnfunc(item_bullets)
1438 {
1439         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1440            (this.classname != "droppedweapon"))
1441         {
1442                 weaponswapping = true;
1443                 spawnfunc_item_shells(this);
1444                 weaponswapping = false;
1445                 return;
1446         }
1447
1448     StartItem(this, ITEM_Bullets);
1449 }
1450
1451 spawnfunc(item_cells)
1452 {
1453         StartItem(this, ITEM_Cells);
1454 }
1455
1456 spawnfunc(item_plasma)
1457 {
1458         StartItem(this, ITEM_Plasma);
1459 }
1460
1461 spawnfunc(item_shells)
1462 {
1463         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1464            (this.classname != "droppedweapon"))
1465         {
1466                 weaponswapping = true;
1467                 spawnfunc_item_bullets(this);
1468                 weaponswapping = false;
1469                 return;
1470         }
1471
1472         StartItem(this, ITEM_Shells);
1473 }
1474
1475 spawnfunc(item_armor_small)
1476 {
1477         StartItem(this, ITEM_ArmorSmall);
1478 }
1479
1480 spawnfunc(item_armor_medium)
1481 {
1482         StartItem(this, ITEM_ArmorMedium);
1483 }
1484
1485 spawnfunc(item_armor_big)
1486 {
1487         StartItem(this, ITEM_ArmorBig);
1488 }
1489
1490 spawnfunc(item_armor_mega)
1491 {
1492         StartItem(this, ITEM_ArmorMega);
1493 }
1494
1495 spawnfunc(item_health_small)
1496 {
1497         StartItem(this, ITEM_HealthSmall);
1498 }
1499
1500 spawnfunc(item_health_medium)
1501 {
1502     StartItem(this, ITEM_HealthMedium);
1503 }
1504
1505 spawnfunc(item_health_big)
1506 {
1507         StartItem(this, ITEM_HealthBig);
1508 }
1509
1510 spawnfunc(item_health_mega)
1511 {
1512     StartItem(this, ITEM_HealthMega);
1513 }
1514
1515 // support old misnamed entities
1516 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1517 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1518 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1519 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1520 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1521 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1522 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1523
1524 spawnfunc(item_strength)
1525 {
1526         StartItem(this, ITEM_Strength);
1527 }
1528
1529 spawnfunc(item_invincible)
1530 {
1531         StartItem(this, ITEM_Shield);
1532 }
1533
1534 // compatibility:
1535 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1536
1537 void target_items_use(entity this, entity actor, entity trigger)
1538 {
1539         if(actor.classname == "droppedweapon")
1540         {
1541                 EXACTTRIGGER_TOUCH(this, trigger);
1542                 delete(actor);
1543                 return;
1544         }
1545
1546         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1547                 return;
1548
1549         if(trigger.solid == SOLID_TRIGGER)
1550         {
1551                 EXACTTRIGGER_TOUCH(this, trigger);
1552         }
1553
1554         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1555         {
1556                 delete(it);
1557         });
1558
1559         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1560                 centerprint(actor, this.message);
1561 }
1562
1563 spawnfunc(target_items)
1564 {
1565         int n;
1566         string s;
1567
1568         this.use = target_items_use;
1569         if(!this.strength_finished)
1570                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1571         if(!this.invincible_finished)
1572                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1573         if(!this.superweapons_finished)
1574                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1575
1576         n = tokenize_console(this.netname);
1577         if(argv(0) == "give")
1578         {
1579                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1580         }
1581         else
1582         {
1583                 for(int j = 0; j < n; ++j)
1584                 {
1585                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1586                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1587                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1588                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1589                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1590                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1591                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1592                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1593                         else
1594                         {
1595                                 FOREACH(Buffs, it != BUFF_Null,
1596                                 {
1597                                         s = Buff_UndeprecateName(argv(j));
1598                                         if(s == it.m_name)
1599                                         {
1600                                                 this.buffs |= (it.m_itemid);
1601                                                 break;
1602                                         }
1603                                 });
1604                                 FOREACH(Weapons, it != WEP_Null, {
1605                                         s = W_UndeprecateName(argv(j));
1606                                         if(s == it.netname)
1607                                         {
1608                                                 this.weapons |= (it.m_wepset);
1609                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1610                                                         it.wr_init(it);
1611                                                 break;
1612                                         }
1613                                 });
1614                         }
1615                 }
1616
1617                 string itemprefix, valueprefix;
1618                 if(this.spawnflags == 0)
1619                 {
1620                         itemprefix = "";
1621                         valueprefix = "";
1622                 }
1623                 else if(this.spawnflags == 1)
1624                 {
1625                         itemprefix = "max ";
1626                         valueprefix = "max ";
1627                 }
1628                 else if(this.spawnflags == 2)
1629                 {
1630                         itemprefix = "min ";
1631                         valueprefix = "min ";
1632                 }
1633                 else if(this.spawnflags == 4)
1634                 {
1635                         itemprefix = "minus ";
1636                         valueprefix = "max ";
1637                 }
1638                 else
1639                 {
1640                         error("invalid spawnflags");
1641                         itemprefix = valueprefix = string_null;
1642                 }
1643
1644                 this.netname = "";
1645                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1646                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1647                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1648                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1649                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1650                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1651                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1652                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1653                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1654                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1655                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1656                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1657                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1658                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1659                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1660                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1661                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1662         }
1663         this.netname = strzone(this.netname);
1664         //print(this.netname, "\n");
1665
1666         n = tokenize_console(this.netname);
1667         for(int j = 0; j < n; ++j)
1668         {
1669                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1670             it.wr_init(it);
1671             break;
1672                 });
1673         }
1674 }
1675
1676 spawnfunc(item_fuel)
1677 {
1678         StartItem(this, ITEM_JetpackFuel);
1679 }
1680
1681 spawnfunc(item_fuel_regen)
1682 {
1683         if(start_items & ITEM_JetpackRegen.m_itemid)
1684         {
1685                 spawnfunc_item_fuel(this);
1686                 return;
1687         }
1688         StartItem(this, ITEM_JetpackRegen);
1689 }
1690
1691 spawnfunc(item_jetpack)
1692 {
1693         if(start_items & ITEM_Jetpack.m_itemid)
1694         {
1695                 spawnfunc_item_fuel(this);
1696                 return;
1697         }
1698         StartItem(this, ITEM_Jetpack);
1699 }
1700
1701 float GiveWeapon(entity e, float wpn, float op, float val)
1702 {
1703         WepSet v0, v1;
1704         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1705         v0 = (e.weapons & s);
1706         switch(op)
1707         {
1708                 case OP_SET:
1709                         if(val > 0)
1710                                 e.weapons |= s;
1711                         else
1712                                 e.weapons &= ~s;
1713                         break;
1714                 case OP_MIN:
1715                 case OP_PLUS:
1716                         if(val > 0)
1717                                 e.weapons |= s;
1718                         break;
1719                 case OP_MAX:
1720                         if(val <= 0)
1721                                 e.weapons &= ~s;
1722                         break;
1723                 case OP_MINUS:
1724                         if(val > 0)
1725                                 e.weapons &= ~s;
1726                         break;
1727         }
1728         v1 = (e.weapons & s);
1729         return (v0 != v1);
1730 }
1731
1732 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1733 {
1734         bool had_buff = (e.buffs & thebuff.m_itemid);
1735         switch(op)
1736         {
1737                 case OP_SET:
1738                         if(val > 0)
1739                                 e.buffs |= thebuff.m_itemid;
1740                         else
1741                                 e.buffs &= ~thebuff.m_itemid;
1742                         break;
1743                 case OP_MIN:
1744                 case OP_PLUS:
1745                         if(val > 0)
1746                                 e.buffs |= thebuff.m_itemid;
1747                         break;
1748                 case OP_MAX:
1749                         if(val <= 0)
1750                                 e.buffs &= ~thebuff.m_itemid;
1751                         break;
1752                 case OP_MINUS:
1753                         if(val > 0)
1754                                 e.buffs &= ~thebuff.m_itemid;
1755                         break;
1756         }
1757         bool have_buff = (e.buffs & thebuff.m_itemid);
1758         return (had_buff != have_buff);
1759 }
1760
1761 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1762 {
1763         if(v1 == v0)
1764                 return;
1765         if(v1 <= v0 - t)
1766         {
1767                 if(snd_decr != NULL)
1768                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1769         }
1770         else if(v0 >= v0 + t)
1771         {
1772                 if(snd_incr != NULL)
1773                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1774         }
1775 }
1776
1777 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1778 {
1779         if(v0 < v1)
1780                 e.(rotfield) = max(e.(rotfield), time + rottime);
1781         else if(v0 > v1)
1782                 e.(regenfield) = max(e.(regenfield), time + regentime);
1783 }
1784 float GiveItems(entity e, float beginarg, float endarg)
1785 {
1786         float got, i, val, op;
1787         string cmd;
1788
1789         val = 999;
1790         op = OP_SET;
1791
1792         got = 0;
1793
1794         int _switchweapon = 0;
1795
1796         if(CS(e).autoswitch)
1797         {
1798                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1799                 {
1800                         .entity weaponentity = weaponentities[slot];
1801                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1802                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1803                                 _switchweapon |= BIT(slot);
1804                 }
1805         }
1806
1807         e.strength_finished = max(0, e.strength_finished - time);
1808         e.invincible_finished = max(0, e.invincible_finished - time);
1809         e.superweapons_finished = max(0, e.superweapons_finished - time);
1810
1811         PREGIVE(e, items);
1812         PREGIVE_WEAPONS(e);
1813         PREGIVE(e, strength_finished);
1814         PREGIVE(e, invincible_finished);
1815         PREGIVE(e, superweapons_finished);
1816         PREGIVE(e, ammo_nails);
1817         PREGIVE(e, ammo_cells);
1818         PREGIVE(e, ammo_plasma);
1819         PREGIVE(e, ammo_shells);
1820         PREGIVE(e, ammo_rockets);
1821         PREGIVE(e, ammo_fuel);
1822         PREGIVE(e, armorvalue);
1823         PREGIVE(e, health);
1824
1825         for(i = beginarg; i < endarg; ++i)
1826         {
1827                 cmd = argv(i);
1828
1829                 if(cmd == "0" || stof(cmd))
1830                 {
1831                         val = stof(cmd);
1832                         continue;
1833                 }
1834                 switch(cmd)
1835                 {
1836                         case "no":
1837                                 op = OP_MAX;
1838                                 val = 0;
1839                                 continue;
1840                         case "max":
1841                                 op = OP_MAX;
1842                                 continue;
1843                         case "min":
1844                                 op = OP_MIN;
1845                                 continue;
1846                         case "plus":
1847                                 op = OP_PLUS;
1848                                 continue;
1849                         case "minus":
1850                                 op = OP_MINUS;
1851                                 continue;
1852                         case "ALL":
1853                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1854                                 got += GiveValue(e, strength_finished, op, val);
1855                                 got += GiveValue(e, invincible_finished, op, val);
1856                                 got += GiveValue(e, superweapons_finished, op, val);
1857                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1858                         case "all":
1859                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1860                                 got += GiveValue(e, health, op, val);
1861                                 got += GiveValue(e, armorvalue, op, val);
1862                         case "allweapons":
1863                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1864                         //case "allbuffs": // all buffs makes a player god, do not want!
1865                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1866                         case "allammo":
1867                                 got += GiveValue(e, ammo_cells, op, val);
1868                                 got += GiveValue(e, ammo_plasma, op, val);
1869                                 got += GiveValue(e, ammo_shells, op, val);
1870                                 got += GiveValue(e, ammo_nails, op, val);
1871                                 got += GiveValue(e, ammo_rockets, op, val);
1872                                 got += GiveValue(e, ammo_fuel, op, val);
1873                                 break;
1874                         case "unlimited_ammo":
1875                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1876                                 break;
1877                         case "unlimited_weapon_ammo":
1878                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1879                                 break;
1880                         case "unlimited_superweapons":
1881                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1882                                 break;
1883                         case "jetpack":
1884                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1885                                 break;
1886                         case "fuel_regen":
1887                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1888                                 break;
1889                         case "strength":
1890                                 got += GiveValue(e, strength_finished, op, val);
1891                                 break;
1892                         case "invincible":
1893                                 got += GiveValue(e, invincible_finished, op, val);
1894                                 break;
1895                         case "superweapons":
1896                                 got += GiveValue(e, superweapons_finished, op, val);
1897                                 break;
1898                         case "cells":
1899                                 got += GiveValue(e, ammo_cells, op, val);
1900                                 break;
1901                         case "plasma":
1902                                 got += GiveValue(e, ammo_plasma, op, val);
1903                                 break;
1904                         case "shells":
1905                                 got += GiveValue(e, ammo_shells, op, val);
1906                                 break;
1907                         case "nails":
1908                         case "bullets":
1909                                 got += GiveValue(e, ammo_nails, op, val);
1910                                 break;
1911                         case "rockets":
1912                                 got += GiveValue(e, ammo_rockets, op, val);
1913                                 break;
1914                         case "health":
1915                                 got += GiveValue(e, health, op, val);
1916                                 break;
1917                         case "armor":
1918                                 got += GiveValue(e, armorvalue, op, val);
1919                                 break;
1920                         case "fuel":
1921                                 got += GiveValue(e, ammo_fuel, op, val);
1922                                 break;
1923                         default:
1924                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1925                                 {
1926                                         got += GiveBuff(e, it, op, val);
1927                                         break;
1928                                 });
1929                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1930                     got += GiveWeapon(e, it.m_id, op, val);
1931                     break;
1932                                 });
1933                                 break;
1934                 }
1935                 val = 999;
1936                 op = OP_SET;
1937         }
1938
1939         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1940         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1941         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1942         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1943         FOREACH(Weapons, it != WEP_Null, {
1944                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1945                 if(!(save_weapons & (it.m_wepset)))
1946                         if(e.weapons & (it.m_wepset))
1947                                 it.wr_init(it);
1948         });
1949         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1950         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1951         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1952         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1953         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1954         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1955         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1956         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1957         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1958         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1959         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1960
1961         if(e.superweapons_finished <= 0)
1962                 if(e.weapons & WEPSET_SUPERWEAPONS)
1963                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1964
1965         if(e.strength_finished <= 0)
1966                 e.strength_finished = 0;
1967         else
1968                 e.strength_finished += time;
1969         if(e.invincible_finished <= 0)
1970                 e.invincible_finished = 0;
1971         else
1972                 e.invincible_finished += time;
1973         if(e.superweapons_finished <= 0)
1974                 e.superweapons_finished = 0;
1975         else
1976                 e.superweapons_finished += time;
1977
1978         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1979         {
1980                 .entity weaponentity = weaponentities[slot];
1981                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1982                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1983                         _switchweapon |= BIT(slot);
1984         }
1985
1986         if(_switchweapon)
1987         {
1988                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1989                 {
1990                         .entity weaponentity = weaponentities[slot];
1991                         if(_switchweapon & BIT(slot))
1992                         {
1993                                 Weapon wep = w_getbestweapon(e, weaponentity);
1994                                 if(wep != e.(weaponentity).m_switchweapon)
1995                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1996                         }
1997                 }
1998         }
1999
2000         return got;
2001 }
2002 #endif