qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 void Item_ScheduleRespawn(entity e)
 635 {
 636         if(e.respawntime > 0)
 637         {
 638                 Item_Show(e, 0);
 639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 640         }
 641         else // if respawntime is -1, this item does not respawn
 642                 Item_Show(e, -1);
 643 }
 644
 645 void Item_ScheduleInitialRespawn(entity e)
 646 {
 647         Item_Show(e, 0);
 648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 649 }
 650
 651 void GivePlayerResource(entity player, .float resource_type, float amount)
 652 {
 653         if (amount == 0)
 654         {
 655                 return;
 656         }
 657         switch (resource_type)
 658         {
 659                 case health:
 660                 {
 661                         // Ugly hack. We do not check if health goes beyond hard limit since
 662                         // currently it is done in player_regen. We need to bring back this
 663                         // check when other code is ported to this function.
 664                         player.health = bound(player.health, player.health + amount,
 665                                 autocvar_g_balance_health_limit);
 666                         // Correct code:
 667                         //player.health = bound(player.health, player.health + amount,
 668                         //      min(autocvar_g_balance_health_limit,
 669                         //      RESOURCE_AMOUNT_HARD_LIMIT));
 670                         player.pauserothealth_finished = max(player.pauserothealth_finished,
 671                                 time + autocvar_g_balance_pause_health_rot);
 672                         return;
 673                 }
 674                 case armorvalue:
 675                 {
 676                         // Ugly hack. We do not check if armor goes beyond hard limit since
 677                         // currently it is done in player_regen. We need to bring back this
 678                         // check when other code is ported to this function.
 679                         player.armorvalue = bound(player.armorvalue, player.armorvalue +
 680                                 amount, autocvar_g_balance_armor_limit);
 681                         // Correct code:
 682                         //player.armorvalue = bound(player.armorvalue, player.armorvalue +
 683                         //      amount, min(autocvar_g_balance_armor_limit,
 684                         //      RESOURCE_AMOUNT_HARD_LIMIT));
 685                         player.pauserotarmor_finished = max(player.pauserotarmor_finished,
 686                                 time + autocvar_g_balance_pause_armor_rot);
 687                         return;
 688                 }
 689                 case ammo_shells:
 690                 case ammo_nails:
 691                 case ammo_rockets:
 692                 case ammo_cells:
 693                 case ammo_plasma:
 694                 {
 695                         GivePlayerAmmo(player, resource_type, amount);
 696                         return;
 697                 }
 698                 case ammo_fuel:
 699                 {
 700                         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel +
 701                                 amount, min(g_pickup_fuel_max, RESOURCE_AMOUNT_HARD_LIMIT));
 702                         player.pauserotfuel_finished = max(player.pauserotfuel_finished,
 703                                 time + autocvar_g_balance_pause_fuel_rot);
 704                         return;
 705                 }
 706         }
 707 }
 708
 709 void GivePlayerHealth(entity player, float amount)
 710 {
 711         GivePlayerResource(player, health, amount);
 712 }
 713
 714 void GivePlayerArmor(entity player, float amount)
 715 {
 716         GivePlayerResource(player, armorvalue, amount);
 717 }
 718
 719 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 720 {
 721         if (amount == 0)
 722         {
 723                 return;
 724         }
 725         float maxvalue = RESOURCE_AMOUNT_HARD_LIMIT;
 726         switch (ammotype)
 727         {
 728                 case ammo_shells:
 729                 {
 730                         maxvalue = g_pickup_shells_max;
 731                         break;
 732                 }
 733                 case ammo_cells:
 734                 {
 735                         maxvalue = g_pickup_cells_max;
 736                         break;
 737                 }
 738                 case ammo_rockets:
 739                 {
 740                         maxvalue = g_pickup_rockets_max;
 741                         break;
 742                 }
 743                 case ammo_plasma:
 744                 {
 745                         maxvalue = g_pickup_plasma_max;
 746                         break;
 747                 }
 748                 case ammo_nails:
 749                 {
 750                         maxvalue = g_pickup_nails_max;
 751                         break;
 752                 }
 753         }
 754         player.(ammotype) = min(player.(ammotype) + amount,
 755                 min(maxvalue, RESOURCE_AMOUNT_HARD_LIMIT));
 756 }
 757
 758 void GivePlayerFuel(entity player, float amount)
 759 {
 760         GivePlayerResource(player, ammo_fuel, amount);
 761 }
 762
 763 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
 764 {
 765         if (!item.(ammotype))
 766                 return false;
 767
 768         if (item.spawnshieldtime)
 769         {
 770                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 771                 {
 772                         float amount = item.(ammotype);
 773                         if ((player.(ammotype) + amount) > ammomax)
 774                         {
 775                                 amount = ammomax - player.(ammotype);
 776                         }
 777                         GivePlayerResource(player, ammotype, amount);
 778                         return true;
 779                 }
 780         }
 781         else if(g_weapon_stay == 2)
 782         {
 783                 float mi = min(item.(ammotype), ammomax);
 784                 if (player.(ammotype) < mi)
 785                 {
 786                         GivePlayerResource(player, ammotype, mi - player.(ammotype));
 787                 }
 788                 return true;
 789         }
 790         return false;
 791 }
 792
 793 float Item_GiveTo(entity item, entity player)
 794 {
 795         float pickedup;
 796
 797         // if nothing happens to player, just return without taking the item
 798         pickedup = false;
 799         int _switchweapon = 0;
 800         // in case the player has autoswitch enabled do the following:
 801         // if the player is using their best weapon before items are given, they
 802         // probably want to switch to an even better weapon after items are given
 803
 804         if(CS(player).autoswitch)
 805         {
 806                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 807                 {
 808                         .entity weaponentity = weaponentities[slot];
 809                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 810                         {
 811                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 812                                         _switchweapon |= BIT(slot);
 813
 814                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 815                                         _switchweapon |= BIT(slot);
 816                         }
 817                 }
 818         }
 819         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
 820         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
 821         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
 822         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
 823         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
 824         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
 825         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
 826         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 827         if (item.itemdef.instanceOfWeaponPickup)
 828         {
 829                 WepSet w;
 830                 w = item.weapons;
 831                 w &= ~player.weapons;
 832
 833                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 834                 {
 835                         pickedup = true;
 836                         FOREACH(Weapons, it != WEP_Null, {
 837                                 if(w & (it.m_wepset))
 838                                 {
 839                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 840                                         {
 841                                                 .entity weaponentity = weaponentities[slot];
 842                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 843                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 844                                         }
 845                                         W_GiveWeapon(player, it.m_id);
 846                                 }
 847                         });
 848                 }
 849         }
 850
 851         if (item.itemdef.instanceOfPowerup)
 852         {
 853                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 854                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 855                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 856                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 857         }
 858
 859         int its;
 860         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 861         {
 862                 pickedup = true;
 863                 player.items |= its;
 864                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 865         }
 866
 867         if (item.strength_finished)
 868         {
 869                 pickedup = true;
 870                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 871         }
 872         if (item.invincible_finished)
 873         {
 874                 pickedup = true;
 875                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 876         }
 877         if (item.superweapons_finished)
 878         {
 879                 pickedup = true;
 880                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 881         }
 882
 883 LABEL(skip)
 884
 885         // always eat teamed entities
 886         if(item.team)
 887                 pickedup = true;
 888
 889         if (!pickedup)
 890                 return 0;
 891
 892         // crude hack to enforce switching weapons
 893         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 894         {
 895                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 896                 {
 897                         .entity weaponentity = weaponentities[slot];
 898                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 899                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 900                 }
 901                 return 1;
 902         }
 903
 904         if(_switchweapon)
 905         {
 906                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 907                 {
 908                         .entity weaponentity = weaponentities[slot];
 909                         if(_switchweapon & BIT(slot))
 910                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 911                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 912                 }
 913         }
 914
 915         return 1;
 916 }
 917
 918 void Item_Touch(entity this, entity toucher)
 919 {
 920
 921         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 922         if (this.classname == "droppedweapon")
 923         {
 924                 if (ITEM_TOUCH_NEEDKILL())
 925                 {
 926                         delete(this);
 927                         return;
 928                 }
 929         }
 930
 931         if(!(toucher.flags & FL_PICKUPITEMS)
 932         || STAT(FROZEN, toucher)
 933         || IS_DEAD(toucher)
 934         || (this.solid != SOLID_TRIGGER)
 935         || (this.owner == toucher)
 936         || (time < this.item_spawnshieldtime)
 937         ) { return; }
 938
 939         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 940         {
 941                 case MUT_ITEMTOUCH_RETURN: { return; }
 942                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 943         }
 944
 945         toucher = M_ARGV(1, entity);
 946
 947         if (this.classname == "droppedweapon")
 948         {
 949                 this.strength_finished = max(0, this.strength_finished - time);
 950                 this.invincible_finished = max(0, this.invincible_finished - time);
 951                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 952         }
 953         entity it = this.itemdef;
 954         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 955         if (!gave)
 956         {
 957                 if (this.classname == "droppedweapon")
 958                 {
 959                         // undo what we did above
 960                         this.strength_finished += time;
 961                         this.invincible_finished += time;
 962                         this.superweapons_finished += time;
 963                 }
 964                 return;
 965         }
 966
 967 LABEL(pickup)
 968
 969         toucher.last_pickup = time;
 970
 971         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 972         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 973
 974         if (this.classname == "droppedweapon")
 975                 delete(this);
 976         else if (this.spawnshieldtime)
 977         {
 978                 entity e;
 979                 if(this.team)
 980                 {
 981                         RandomSelection_Init();
 982                         IL_EACH(g_items, it.team == this.team,
 983                         {
 984                                 if(it.itemdef) // is a registered item
 985                                 {
 986                                         Item_Show(it, -1);
 987                                         RandomSelection_AddEnt(it, it.cnt, 0);
 988                                 }
 989                         });
 990                         e = RandomSelection_chosen_ent;
 991                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 992                 }
 993                 else
 994                         e = this;
 995                 Item_ScheduleRespawn(e);
 996         }
 997 }
 998
 999 void Item_Reset(entity this)
1000 {
1001         Item_Show(this, !this.state);
1002         setorigin(this, this.origin);
1003
1004         if (this.classname != "droppedweapon")
1005         {
1006                 setthink(this, Item_Think);
1007                 this.nextthink = time;
1008
1009                 if (this.waypointsprite_attached)
1010                         WaypointSprite_Kill(this.waypointsprite_attached);
1011
1012                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1013                         Item_ScheduleInitialRespawn(this);
1014         }
1015 }
1016
1017 void Item_FindTeam(entity this)
1018 {
1019         entity e;
1020
1021         if(this.effects & EF_NODRAW)
1022         {
1023                 // marker for item team search
1024                 LOG_TRACE("Initializing item team ", ftos(this.team));
1025                 RandomSelection_Init();
1026                 IL_EACH(g_items, it.team == this.team,
1027                 {
1028                         if(it.itemdef) // is a registered item
1029                                 RandomSelection_AddEnt(it, it.cnt, 0);
1030                 });
1031
1032                 e = RandomSelection_chosen_ent;
1033                 e.state = 0;
1034                 Item_Show(e, 1);
1035
1036                 IL_EACH(g_items, it.team == this.team,
1037                 {
1038                         if(it.itemdef) // is a registered item
1039                         {
1040                                 if(it != e)
1041                                 {
1042                                         // make it non-spawned
1043                                         Item_Show(it, -1);
1044                                         it.state = 1; // state 1 = initially hidden item, apparently
1045                                 }
1046                                 it.effects &= ~EF_NODRAW;
1047                         }
1048                 });
1049
1050                 Item_Reset(this);
1051         }
1052 }
1053
1054 // Savage: used for item garbage-collection
1055 void RemoveItem(entity this)
1056 {
1057         if(wasfreed(this) || !this) { return; }
1058         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1059         delete(this);
1060 }
1061
1062 // pickup evaluation functions
1063 // these functions decide how desirable an item is to the bots
1064
1065 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1066
1067 float weapon_pickupevalfunc(entity player, entity item)
1068 {
1069         // See if I have it already
1070         if(player.weapons & item.weapons)
1071         {
1072                 // If I can pick it up
1073                 if(!item.spawnshieldtime)
1074                         return 0;
1075                 return ammo_pickupevalfunc(player, item);
1076         }
1077
1078         // reduce weapon value if bot already got a good arsenal
1079         float c = 1;
1080         int weapons_value = 0;
1081         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1082                 weapons_value += it.bot_pickupbasevalue;
1083         });
1084         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1085
1086         return item.bot_pickupbasevalue * c;
1087 }
1088
1089 float ammo_pickupevalfunc(entity player, entity item)
1090 {
1091         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1092         entity wpn = NULL;
1093         float c = 0;
1094         float rating = 0;
1095
1096         // Detect needed ammo
1097         if(item.itemdef.instanceOfWeaponPickup)
1098         {
1099                 entity ammo = NULL;
1100                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1101                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1102                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1103                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1104                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1105                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1106
1107                 if(!ammo)
1108                         return 0;
1109                 wpn = item;
1110                 rating = ammo.m_botvalue;
1111         }
1112         else
1113         {
1114                 FOREACH(Weapons, it != WEP_Null, {
1115                         if(!(player.weapons & (it.m_wepset)))
1116                                 continue;
1117
1118                         switch(it.ammo_field)
1119                         {
1120                                 case ammo_shells:  need_shells  = true; break;
1121                                 case ammo_nails:   need_nails   = true; break;
1122                                 case ammo_rockets: need_rockets = true; break;
1123                                 case ammo_cells:   need_cells   = true; break;
1124                                 case ammo_plasma:  need_plasma  = true; break;
1125                                 case ammo_fuel:    need_fuel    = true; break;
1126                         }
1127                 });
1128                 rating = item.bot_pickupbasevalue;
1129         }
1130
1131         float noammorating = 0.5;
1132
1133         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1134                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1135
1136         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1137                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1138
1139         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1140                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1141
1142         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1143                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1144
1145         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1146                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1147
1148         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1149                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1150
1151         rating *= min(c, 2);
1152         if(wpn)
1153                 rating += wpn.bot_pickupbasevalue * 0.1;
1154         return rating;
1155 }
1156
1157 .int item_group;
1158 .int item_group_count;
1159 float healtharmor_pickupevalfunc(entity player, entity item)
1160 {
1161         float c = 0;
1162         float rating = item.bot_pickupbasevalue;
1163
1164         float itemarmor = item.armorvalue;
1165         float itemhealth = item.health;
1166
1167         if(item.item_group)
1168         {
1169                 itemarmor *= min(4, item.item_group_count);
1170                 itemhealth *= min(4, item.item_group_count);
1171         }
1172
1173         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1174                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1175
1176         if (itemhealth && (player.health < item.max_health))
1177                 c = itemhealth / max(1, player.health);
1178
1179         rating *= min(2, c);
1180         return rating;
1181 }
1182
1183 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1184 {
1185         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1186                 RemoveItem(this);
1187 }
1188
1189 void item_use(entity this, entity actor, entity trigger)
1190 {
1191         // use the touch function to handle collection
1192         gettouch(this)(this, actor);
1193 }
1194
1195 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1196 {
1197         string itemname = def.m_name;
1198         Model itemmodel = def.m_model;
1199     Sound pickupsound = def.m_sound;
1200         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1201         float pickupbasevalue = def.m_botvalue;
1202         int itemflags = def.m_itemflags;
1203
1204         startitem_failed = false;
1205
1206         this.item_model_ent = itemmodel;
1207     this.item_pickupsound_ent = pickupsound;
1208
1209     if(def.m_iteminit)
1210         def.m_iteminit(this);
1211
1212         if(!this.respawntime) // both need to be set
1213         {
1214                 this.respawntime = defaultrespawntime;
1215                 this.respawntimejitter = defaultrespawntimejitter;
1216         }
1217
1218         if(!this.pickup_anyway && def.m_pickupanyway)
1219                 this.pickup_anyway = def.m_pickupanyway();
1220
1221         int itemid = def.m_itemid;
1222         this.items = itemid;
1223         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1224         this.weapon = weaponid;
1225
1226         if(!this.fade_end)
1227         {
1228                 this.fade_start = autocvar_g_items_mindist;
1229                 this.fade_end = autocvar_g_items_maxdist;
1230         }
1231
1232         if(weaponid)
1233                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1234
1235         this.flags = FL_ITEM | itemflags;
1236         IL_PUSH(g_items, this);
1237
1238         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1239         {
1240                 startitem_failed = true;
1241                 delete(this);
1242                 return;
1243         }
1244
1245         // is it a dropped weapon?
1246         if (this.classname == "droppedweapon")
1247         {
1248                 this.reset = SUB_Remove;
1249                 // it's a dropped weapon
1250                 set_movetype(this, MOVETYPE_TOSS);
1251
1252                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1253                 setthink(this, RemoveItem);
1254                 this.nextthink = time + 20;
1255
1256                 this.takedamage = DAMAGE_YES;
1257                 this.event_damage = Item_Damage;
1258
1259                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1260                 {
1261                         // if item is worthless after a timer, have it expire then
1262                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1263                 }
1264
1265                 // don't drop if in a NODROP zone (such as lava)
1266                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1267                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1268                 {
1269                         startitem_failed = true;
1270                         delete(this);
1271                         return;
1272                 }
1273         }
1274         else
1275         {
1276                 if(!have_pickup_item(this))
1277                 {
1278                         startitem_failed = true;
1279                         delete(this);
1280                         return;
1281                 }
1282
1283                 if(this.angles != '0 0 0')
1284                         this.SendFlags |= ISF_ANGLES;
1285
1286                 this.reset = Item_Reset;
1287                 // it's a level item
1288                 if(this.spawnflags & 1)
1289                         this.noalign = 1;
1290                 if (this.noalign > 0)
1291                         set_movetype(this, MOVETYPE_NONE);
1292                 else
1293                         set_movetype(this, MOVETYPE_TOSS);
1294                 // do item filtering according to game mode and other things
1295                 if (this.noalign <= 0)
1296                 {
1297                         // first nudge it off the floor a little bit to avoid math errors
1298                         setorigin(this, this.origin + '0 0 1');
1299                         // set item size before we spawn a spawnfunc_waypoint
1300                         setsize(this, def.m_mins, def.m_maxs);
1301                         this.SendFlags |= ISF_SIZE;
1302                         // note droptofloor returns false if stuck/or would fall too far
1303                         if (!this.noalign)
1304                                 droptofloor(this);
1305                         waypoint_spawnforitem(this);
1306                 }
1307
1308                 /*
1309                  * can't do it that way, as it would break maps
1310                  * TODO make a target_give like entity another way, that perhaps has
1311                  * the weapon name in a key
1312                 if(this.targetname)
1313                 {
1314                         // target_give not yet supported; maybe later
1315                         print("removed targeted ", this.classname, "\n");
1316                         startitem_failed = true;
1317                         delete(this);
1318                         return;
1319                 }
1320                 */
1321
1322                 if(this.targetname != "" && (this.spawnflags & 16))
1323                         this.use = item_use;
1324
1325                 if(autocvar_spawn_debug >= 2)
1326                 {
1327             // why not flags & fl_item?
1328                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1329                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1330                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1331                 error("Mapper sucks.");
1332             });
1333                         this.is_item = true;
1334                 }
1335
1336                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1337
1338                 precache_model(this.model);
1339                 precache_sound(this.item_pickupsound);
1340
1341                 if (   def.instanceOfPowerup
1342                         || def.instanceOfWeaponPickup
1343                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1344                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1345                         || (itemid & (IT_KEY1 | IT_KEY2))
1346                 ) this.target = "###item###"; // for finding the nearest item using find()
1347
1348                 Item_ItemsTime_SetTime(this, 0);
1349         }
1350
1351         this.bot_pickup = true;
1352         this.bot_pickupevalfunc = pickupevalfunc;
1353         this.bot_pickupbasevalue = pickupbasevalue;
1354         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1355         this.netname = itemname;
1356         settouch(this, Item_Touch);
1357         setmodel(this, MDL_Null); // precision set below
1358         //this.effects |= EF_LOWPRECISION;
1359
1360         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1361
1362         this.SendFlags |= ISF_SIZE;
1363
1364         if (!(this.spawnflags & 1024)) {
1365                 if(def.instanceOfPowerup)
1366                         this.ItemStatus |= ITS_ANIMATE1;
1367
1368                 if(this.armorvalue || this.health)
1369                         this.ItemStatus |= ITS_ANIMATE2;
1370         }
1371
1372         if(def.instanceOfWeaponPickup)
1373         {
1374                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1375                         this.colormap = 1024; // color shirt=0 pants=0 grey
1376                 else
1377                         this.gravity = 1;
1378                 if (!(this.spawnflags & 1024))
1379                         this.ItemStatus |= ITS_ANIMATE1;
1380                 this.SendFlags |= ISF_COLORMAP;
1381         }
1382
1383         this.state = 0;
1384         if(this.team) // broken, no idea why.
1385         {
1386                 if(!this.cnt)
1387                         this.cnt = 1; // item probability weight
1388
1389                 this.effects |= EF_NODRAW; // marker for item team search
1390                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1391         }
1392         else
1393                 Item_Reset(this);
1394
1395         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1396
1397         // call this hook after everything else has been done
1398         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1399         {
1400                 startitem_failed = true;
1401                 delete(this);
1402                 return;
1403         }
1404
1405         setItemGroup(this);
1406 }
1407
1408 void StartItem(entity this, GameItem def)
1409 {
1410     _StartItem(
1411         this,
1412         this.itemdef = def,
1413         def.m_respawntime(), // defaultrespawntime
1414         def.m_respawntimejitter() // defaultrespawntimejitter
1415         );
1416 }
1417
1418 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1419 int group_count = 1;
1420
1421 void setItemGroup(entity this)
1422 {
1423         if(!IS_SMALL(this.itemdef))
1424                 return;
1425
1426         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1427         {
1428                 if(!this.item_group)
1429                 {
1430                         if(!it.item_group)
1431                         {
1432                                 it.item_group = group_count;
1433                                 group_count++;
1434                         }
1435                         this.item_group = it.item_group;
1436                 }
1437                 else // spawning item is already part of a item_group X
1438                 {
1439                         if(!it.item_group)
1440                                 it.item_group = this.item_group;
1441                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1442                         {
1443                                 int grY = it.item_group;
1444                                 // move all items of item_group Y to item_group X
1445                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1446                                 {
1447                                         if(it.item_group == grY)
1448                                                 it.item_group = this.item_group;
1449                                 });
1450                         }
1451                 }
1452         });
1453 }
1454
1455 void setItemGroupCount()
1456 {
1457         for (int k = 1; k <= group_count; k++)
1458         {
1459                 int count = 0;
1460                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1461                 if (count)
1462                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1463         }
1464 }
1465
1466 spawnfunc(item_rockets)
1467 {
1468     StartItem(this, ITEM_Rockets);
1469 }
1470
1471 spawnfunc(item_bullets)
1472 {
1473         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1474            (this.classname != "droppedweapon"))
1475         {
1476                 weaponswapping = true;
1477                 spawnfunc_item_shells(this);
1478                 weaponswapping = false;
1479                 return;
1480         }
1481
1482     StartItem(this, ITEM_Bullets);
1483 }
1484
1485 spawnfunc(item_cells)
1486 {
1487         StartItem(this, ITEM_Cells);
1488 }
1489
1490 spawnfunc(item_plasma)
1491 {
1492         StartItem(this, ITEM_Plasma);
1493 }
1494
1495 spawnfunc(item_shells)
1496 {
1497         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1498            (this.classname != "droppedweapon"))
1499         {
1500                 weaponswapping = true;
1501                 spawnfunc_item_bullets(this);
1502                 weaponswapping = false;
1503                 return;
1504         }
1505
1506         StartItem(this, ITEM_Shells);
1507 }
1508
1509 spawnfunc(item_armor_small)
1510 {
1511         StartItem(this, ITEM_ArmorSmall);
1512 }
1513
1514 spawnfunc(item_armor_medium)
1515 {
1516         StartItem(this, ITEM_ArmorMedium);
1517 }
1518
1519 spawnfunc(item_armor_big)
1520 {
1521         StartItem(this, ITEM_ArmorBig);
1522 }
1523
1524 spawnfunc(item_armor_mega)
1525 {
1526         StartItem(this, ITEM_ArmorMega);
1527 }
1528
1529 spawnfunc(item_health_small)
1530 {
1531         StartItem(this, ITEM_HealthSmall);
1532 }
1533
1534 spawnfunc(item_health_medium)
1535 {
1536     StartItem(this, ITEM_HealthMedium);
1537 }
1538
1539 spawnfunc(item_health_big)
1540 {
1541         StartItem(this, ITEM_HealthBig);
1542 }
1543
1544 spawnfunc(item_health_mega)
1545 {
1546     StartItem(this, ITEM_HealthMega);
1547 }
1548
1549 // support old misnamed entities
1550 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1551 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1552 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1553 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1554 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1555 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1556 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1557
1558 spawnfunc(item_strength)
1559 {
1560         StartItem(this, ITEM_Strength);
1561 }
1562
1563 spawnfunc(item_invincible)
1564 {
1565         StartItem(this, ITEM_Shield);
1566 }
1567
1568 // compatibility:
1569 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1570
1571 void target_items_use(entity this, entity actor, entity trigger)
1572 {
1573         if(actor.classname == "droppedweapon")
1574         {
1575                 EXACTTRIGGER_TOUCH(this, trigger);
1576                 delete(actor);
1577                 return;
1578         }
1579
1580         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1581                 return;
1582
1583         if(trigger.solid == SOLID_TRIGGER)
1584         {
1585                 EXACTTRIGGER_TOUCH(this, trigger);
1586         }
1587
1588         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1589         {
1590                 delete(it);
1591         });
1592
1593         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1594                 centerprint(actor, this.message);
1595 }
1596
1597 spawnfunc(target_items)
1598 {
1599         int n;
1600         string s;
1601
1602         this.use = target_items_use;
1603         if(!this.strength_finished)
1604                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1605         if(!this.invincible_finished)
1606                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1607         if(!this.superweapons_finished)
1608                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1609
1610         n = tokenize_console(this.netname);
1611         if(argv(0) == "give")
1612         {
1613                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1614         }
1615         else
1616         {
1617                 for(int j = 0; j < n; ++j)
1618                 {
1619                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1620                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1621                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1622                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1623                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1624                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1625                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1626                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1627                         else
1628                         {
1629                                 FOREACH(Buffs, it != BUFF_Null,
1630                                 {
1631                                         s = Buff_UndeprecateName(argv(j));
1632                                         if(s == it.m_name)
1633                                         {
1634                                                 this.buffs |= (it.m_itemid);
1635                                                 break;
1636                                         }
1637                                 });
1638                                 FOREACH(Weapons, it != WEP_Null, {
1639                                         s = W_UndeprecateName(argv(j));
1640                                         if(s == it.netname)
1641                                         {
1642                                                 this.weapons |= (it.m_wepset);
1643                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1644                                                         it.wr_init(it);
1645                                                 break;
1646                                         }
1647                                 });
1648                         }
1649                 }
1650
1651                 string itemprefix, valueprefix;
1652                 if(this.spawnflags == 0)
1653                 {
1654                         itemprefix = "";
1655                         valueprefix = "";
1656                 }
1657                 else if(this.spawnflags == 1)
1658                 {
1659                         itemprefix = "max ";
1660                         valueprefix = "max ";
1661                 }
1662                 else if(this.spawnflags == 2)
1663                 {
1664                         itemprefix = "min ";
1665                         valueprefix = "min ";
1666                 }
1667                 else if(this.spawnflags == 4)
1668                 {
1669                         itemprefix = "minus ";
1670                         valueprefix = "max ";
1671                 }
1672                 else
1673                 {
1674                         error("invalid spawnflags");
1675                         itemprefix = valueprefix = string_null;
1676                 }
1677
1678                 this.netname = "";
1679                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1680                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1681                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1682                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1683                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1684                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1685                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1686                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1687                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1688                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1689                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1690                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1691                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1692                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1693                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1694                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1695                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1696         }
1697         this.netname = strzone(this.netname);
1698         //print(this.netname, "\n");
1699
1700         n = tokenize_console(this.netname);
1701         for(int j = 0; j < n; ++j)
1702         {
1703                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1704             it.wr_init(it);
1705             break;
1706                 });
1707         }
1708 }
1709
1710 spawnfunc(item_fuel)
1711 {
1712         StartItem(this, ITEM_JetpackFuel);
1713 }
1714
1715 spawnfunc(item_fuel_regen)
1716 {
1717         if(start_items & ITEM_JetpackRegen.m_itemid)
1718         {
1719                 spawnfunc_item_fuel(this);
1720                 return;
1721         }
1722         StartItem(this, ITEM_JetpackRegen);
1723 }
1724
1725 spawnfunc(item_jetpack)
1726 {
1727         if(start_items & ITEM_Jetpack.m_itemid)
1728         {
1729                 spawnfunc_item_fuel(this);
1730                 return;
1731         }
1732         StartItem(this, ITEM_Jetpack);
1733 }
1734
1735 float GiveWeapon(entity e, float wpn, float op, float val)
1736 {
1737         WepSet v0, v1;
1738         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1739         v0 = (e.weapons & s);
1740         switch(op)
1741         {
1742                 case OP_SET:
1743                         if(val > 0)
1744                                 e.weapons |= s;
1745                         else
1746                                 e.weapons &= ~s;
1747                         break;
1748                 case OP_MIN:
1749                 case OP_PLUS:
1750                         if(val > 0)
1751                                 e.weapons |= s;
1752                         break;
1753                 case OP_MAX:
1754                         if(val <= 0)
1755                                 e.weapons &= ~s;
1756                         break;
1757                 case OP_MINUS:
1758                         if(val > 0)
1759                                 e.weapons &= ~s;
1760                         break;
1761         }
1762         v1 = (e.weapons & s);
1763         return (v0 != v1);
1764 }
1765
1766 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1767 {
1768         bool had_buff = (e.buffs & thebuff.m_itemid);
1769         switch(op)
1770         {
1771                 case OP_SET:
1772                         if(val > 0)
1773                                 e.buffs |= thebuff.m_itemid;
1774                         else
1775                                 e.buffs &= ~thebuff.m_itemid;
1776                         break;
1777                 case OP_MIN:
1778                 case OP_PLUS:
1779                         if(val > 0)
1780                                 e.buffs |= thebuff.m_itemid;
1781                         break;
1782                 case OP_MAX:
1783                         if(val <= 0)
1784                                 e.buffs &= ~thebuff.m_itemid;
1785                         break;
1786                 case OP_MINUS:
1787                         if(val > 0)
1788                                 e.buffs &= ~thebuff.m_itemid;
1789                         break;
1790         }
1791         bool have_buff = (e.buffs & thebuff.m_itemid);
1792         return (had_buff != have_buff);
1793 }
1794
1795 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1796 {
1797         if(v1 == v0)
1798                 return;
1799         if(v1 <= v0 - t)
1800         {
1801                 if(snd_decr != NULL)
1802                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1803         }
1804         else if(v0 >= v0 + t)
1805         {
1806                 if(snd_incr != NULL)
1807                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1808         }
1809 }
1810
1811 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1812 {
1813         if(v0 < v1)
1814                 e.(rotfield) = max(e.(rotfield), time + rottime);
1815         else if(v0 > v1)
1816                 e.(regenfield) = max(e.(regenfield), time + regentime);
1817 }
1818 float GiveItems(entity e, float beginarg, float endarg)
1819 {
1820         float got, i, val, op;
1821         string cmd;
1822
1823         val = 999;
1824         op = OP_SET;
1825
1826         got = 0;
1827
1828         int _switchweapon = 0;
1829
1830         if(CS(e).autoswitch)
1831         {
1832                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1833                 {
1834                         .entity weaponentity = weaponentities[slot];
1835                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1836                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1837                                 _switchweapon |= BIT(slot);
1838                 }
1839         }
1840
1841         e.strength_finished = max(0, e.strength_finished - time);
1842         e.invincible_finished = max(0, e.invincible_finished - time);
1843         e.superweapons_finished = max(0, e.superweapons_finished - time);
1844
1845         PREGIVE(e, items);
1846         PREGIVE_WEAPONS(e);
1847         PREGIVE(e, strength_finished);
1848         PREGIVE(e, invincible_finished);
1849         PREGIVE(e, superweapons_finished);
1850         PREGIVE(e, ammo_nails);
1851         PREGIVE(e, ammo_cells);
1852         PREGIVE(e, ammo_plasma);
1853         PREGIVE(e, ammo_shells);
1854         PREGIVE(e, ammo_rockets);
1855         PREGIVE(e, ammo_fuel);
1856         PREGIVE(e, armorvalue);
1857         PREGIVE(e, health);
1858
1859         for(i = beginarg; i < endarg; ++i)
1860         {
1861                 cmd = argv(i);
1862
1863                 if(cmd == "0" || stof(cmd))
1864                 {
1865                         val = stof(cmd);
1866                         continue;
1867                 }
1868                 switch(cmd)
1869                 {
1870                         case "no":
1871                                 op = OP_MAX;
1872                                 val = 0;
1873                                 continue;
1874                         case "max":
1875                                 op = OP_MAX;
1876                                 continue;
1877                         case "min":
1878                                 op = OP_MIN;
1879                                 continue;
1880                         case "plus":
1881                                 op = OP_PLUS;
1882                                 continue;
1883                         case "minus":
1884                                 op = OP_MINUS;
1885                                 continue;
1886                         case "ALL":
1887                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1888                                 got += GiveValue(e, strength_finished, op, val);
1889                                 got += GiveValue(e, invincible_finished, op, val);
1890                                 got += GiveValue(e, superweapons_finished, op, val);
1891                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1892                         case "all":
1893                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1894                                 got += GiveValue(e, health, op, val);
1895                                 got += GiveValue(e, armorvalue, op, val);
1896                         case "allweapons":
1897                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1898                         //case "allbuffs": // all buffs makes a player god, do not want!
1899                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1900                         case "allammo":
1901                                 got += GiveValue(e, ammo_cells, op, val);
1902                                 got += GiveValue(e, ammo_plasma, op, val);
1903                                 got += GiveValue(e, ammo_shells, op, val);
1904                                 got += GiveValue(e, ammo_nails, op, val);
1905                                 got += GiveValue(e, ammo_rockets, op, val);
1906                                 got += GiveValue(e, ammo_fuel, op, val);
1907                                 break;
1908                         case "unlimited_ammo":
1909                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1910                                 break;
1911                         case "unlimited_weapon_ammo":
1912                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1913                                 break;
1914                         case "unlimited_superweapons":
1915                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1916                                 break;
1917                         case "jetpack":
1918                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1919                                 break;
1920                         case "fuel_regen":
1921                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1922                                 break;
1923                         case "strength":
1924                                 got += GiveValue(e, strength_finished, op, val);
1925                                 break;
1926                         case "invincible":
1927                                 got += GiveValue(e, invincible_finished, op, val);
1928                                 break;
1929                         case "superweapons":
1930                                 got += GiveValue(e, superweapons_finished, op, val);
1931                                 break;
1932                         case "cells":
1933                                 got += GiveValue(e, ammo_cells, op, val);
1934                                 break;
1935                         case "plasma":
1936                                 got += GiveValue(e, ammo_plasma, op, val);
1937                                 break;
1938                         case "shells":
1939                                 got += GiveValue(e, ammo_shells, op, val);
1940                                 break;
1941                         case "nails":
1942                         case "bullets":
1943                                 got += GiveValue(e, ammo_nails, op, val);
1944                                 break;
1945                         case "rockets":
1946                                 got += GiveValue(e, ammo_rockets, op, val);
1947                                 break;
1948                         case "health":
1949                                 got += GiveValue(e, health, op, val);
1950                                 break;
1951                         case "armor":
1952                                 got += GiveValue(e, armorvalue, op, val);
1953                                 break;
1954                         case "fuel":
1955                                 got += GiveValue(e, ammo_fuel, op, val);
1956                                 break;
1957                         default:
1958                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1959                                 {
1960                                         got += GiveBuff(e, it, op, val);
1961                                         break;
1962                                 });
1963                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1964                     got += GiveWeapon(e, it.m_id, op, val);
1965                     break;
1966                                 });
1967                                 break;
1968                 }
1969                 val = 999;
1970                 op = OP_SET;
1971         }
1972
1973         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1974         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1975         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1976         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1977         FOREACH(Weapons, it != WEP_Null, {
1978                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1979                 if(!(save_weapons & (it.m_wepset)))
1980                         if(e.weapons & (it.m_wepset))
1981                                 it.wr_init(it);
1982         });
1983         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1984         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1985         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1986         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1987         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1988         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1989         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1990         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1991         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1992         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1993         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1994
1995         if(e.superweapons_finished <= 0)
1996                 if(e.weapons & WEPSET_SUPERWEAPONS)
1997                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1998
1999         if(e.strength_finished <= 0)
2000                 e.strength_finished = 0;
2001         else
2002                 e.strength_finished += time;
2003         if(e.invincible_finished <= 0)
2004                 e.invincible_finished = 0;
2005         else
2006                 e.invincible_finished += time;
2007         if(e.superweapons_finished <= 0)
2008                 e.superweapons_finished = 0;
2009         else
2010                 e.superweapons_finished += time;
2011
2012         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2013         {
2014                 .entity weaponentity = weaponentities[slot];
2015                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2016                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2017                         _switchweapon |= BIT(slot);
2018         }
2019
2020         if(_switchweapon)
2021         {
2022                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2023                 {
2024                         .entity weaponentity = weaponentities[slot];
2025                         if(_switchweapon & BIT(slot))
2026                         {
2027                                 Weapon wep = w_getbestweapon(e, weaponentity);
2028                                 if(wep != e.(weaponentity).m_switchweapon)
2029                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2030                         }
2031                 }
2032         }
2033
2034         return got;
2035 }
2036 #endif