qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 float adjust_respawntime(float normal_respawntime) {
 639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 640         float o = autocvar_g_pickup_respawntime_scaling_offset;
 641         float l = autocvar_g_pickup_respawntime_scaling_linear;
 642
 643         if (r == 0 && l == 1) {
 644                 return normal_respawntime;
 645         }
 646
 647         CheckAllowedTeams(NULL);
 648         GetTeamCounts(NULL);
 649         int players = 0;
 650         if (c1 != -1) players += c1;
 651         if (c2 != -1) players += c2;
 652         if (c3 != -1) players += c3;
 653         if (c4 != -1) players += c4;
 654
 655         if (players >= 2) {
 656                 return normal_respawntime * (r / (players + o) + l);
 657         } else {
 658                 return normal_respawntime;
 659         }
 660 }
 661
 662 void Item_ScheduleRespawn(entity e)
 663 {
 664         if(e.respawntime > 0)
 665         {
 666                 Item_Show(e, 0);
 667
 668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 670
 671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 673                 Item_ScheduleRespawnIn(e, actual_time);
 674         }
 675         else // if respawntime is -1, this item does not respawn
 676                 Item_Show(e, -1);
 677 }
 678
 679 void Item_ScheduleInitialRespawn(entity e)
 680 {
 681         Item_Show(e, 0);
 682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 683 }
 684
 685 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 686         entity ammo_entity)
 687 {
 688         if (num_weapons == 0)
 689         {
 690                 return;
 691         }
 692         int num_potential_weapons = tokenize_console(weapon_names);
 693         for (int i = 0; i < num_weapons; ++i)
 694         {
 695                 RandomSelection_Init();
 696                 for (int j = 0; j < num_potential_weapons; ++j)
 697                 {
 698                         string weapon = argv(j);
 699                         FOREACH(Weapons, it != WEP_Null,
 700                         {
 701                                 // Finding a weapon which player doesn't have.
 702                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 703                                 {
 704                                         RandomSelection_AddEnt(it, 1, 1);
 705                                         break;
 706                                 }
 707                         });
 708                 }
 709                 if (RandomSelection_chosen_ent == NULL)
 710                 {
 711                         return;
 712                 }
 713                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 714                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 715                 {
 716                         continue;
 717                 }
 718                 if (GetResourceAmount(receiver,
 719                         RandomSelection_chosen_ent.ammo_type) != 0)
 720                 {
 721                         continue;
 722                 }
 723                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 724                         GetResourceAmount(ammo_entity,
 725                         RandomSelection_chosen_ent.ammo_type));
 726         }
 727 }
 728
 729 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 730 {
 731         float amount = GetResourceAmount(item, resource_type);
 732         if (amount == 0)
 733         {
 734                 return false;
 735         }
 736         float player_amount = GetResourceAmount(player, resource_type);
 737         if (item.spawnshieldtime)
 738         {
 739                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 740                 {
 741                         return false;
 742                 }
 743                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 744                 return true;
 745         }
 746         if (g_weapon_stay != 2)
 747         {
 748                 return false;
 749         }
 750         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 751         return true;
 752 }
 753
 754 float Item_GiveTo(entity item, entity player)
 755 {
 756         float pickedup;
 757
 758         // if nothing happens to player, just return without taking the item
 759         pickedup = false;
 760         int _switchweapon = 0;
 761         // in case the player has autoswitch enabled do the following:
 762         // if the player is using their best weapon before items are given, they
 763         // probably want to switch to an even better weapon after items are given
 764
 765         if(CS(player).autoswitch)
 766         {
 767                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 768                 {
 769                         .entity weaponentity = weaponentities[slot];
 770                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 771                         {
 772                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 773                                         _switchweapon |= BIT(slot);
 774
 775                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 776                                         _switchweapon |= BIT(slot);
 777                         }
 778                 }
 779         }
 780         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 781         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 782         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 783         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 784         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 785         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 788         if (item.itemdef.instanceOfWeaponPickup)
 789         {
 790                 WepSet w;
 791                 w = item.weapons;
 792                 w &= ~player.weapons;
 793
 794                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 795                 {
 796                         pickedup = true;
 797                         FOREACH(Weapons, it != WEP_Null, {
 798                                 if(w & (it.m_wepset))
 799                                 {
 800                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 801                                         {
 802                                                 .entity weaponentity = weaponentities[slot];
 803                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 804                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 805                                         }
 806                                         W_GiveWeapon(player, it.m_id);
 807                                 }
 808                         });
 809                 }
 810         }
 811
 812         if (item.itemdef.instanceOfPowerup)
 813         {
 814                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 815                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 816                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 817                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 818         }
 819
 820         int its;
 821         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 822         {
 823                 pickedup = true;
 824                 player.items |= its;
 825                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 826         }
 827
 828         if (item.strength_finished)
 829         {
 830                 pickedup = true;
 831                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 832         }
 833         if (item.invincible_finished)
 834         {
 835                 pickedup = true;
 836                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 837         }
 838         if (item.superweapons_finished)
 839         {
 840                 pickedup = true;
 841                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 842         }
 843
 844 LABEL(skip)
 845
 846         // always eat teamed entities
 847         if(item.team)
 848                 pickedup = true;
 849
 850         if (!pickedup)
 851                 return 0;
 852
 853         // crude hack to enforce switching weapons
 854         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 855         {
 856                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 857                 {
 858                         .entity weaponentity = weaponentities[slot];
 859                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 860                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 861                 }
 862                 return 1;
 863         }
 864
 865         if(_switchweapon)
 866         {
 867                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 868                 {
 869                         .entity weaponentity = weaponentities[slot];
 870                         if(_switchweapon & BIT(slot))
 871                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 872                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 873                 }
 874         }
 875
 876         return 1;
 877 }
 878
 879 void Item_Touch(entity this, entity toucher)
 880 {
 881
 882         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 883         if (this.classname == "droppedweapon")
 884         {
 885                 if (ITEM_TOUCH_NEEDKILL())
 886                 {
 887                         delete(this);
 888                         return;
 889                 }
 890         }
 891
 892         if(!(toucher.flags & FL_PICKUPITEMS)
 893         || STAT(FROZEN, toucher)
 894         || IS_DEAD(toucher)
 895         || (this.solid != SOLID_TRIGGER)
 896         || (this.owner == toucher)
 897         || (time < this.item_spawnshieldtime)
 898         ) { return; }
 899
 900         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 901         {
 902                 case MUT_ITEMTOUCH_RETURN: { return; }
 903                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 904         }
 905
 906         toucher = M_ARGV(1, entity);
 907
 908         if (this.classname == "droppedweapon")
 909         {
 910                 this.strength_finished = max(0, this.strength_finished - time);
 911                 this.invincible_finished = max(0, this.invincible_finished - time);
 912                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 913         }
 914         entity it = this.itemdef;
 915         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 916         if (!gave)
 917         {
 918                 if (this.classname == "droppedweapon")
 919                 {
 920                         // undo what we did above
 921                         this.strength_finished += time;
 922                         this.invincible_finished += time;
 923                         this.superweapons_finished += time;
 924                 }
 925                 return;
 926         }
 927
 928 LABEL(pickup)
 929
 930         toucher.last_pickup = time;
 931
 932         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 933         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 934
 935         if (this.classname == "droppedweapon")
 936                 delete(this);
 937         else if (this.spawnshieldtime)
 938         {
 939                 entity e;
 940                 if(this.team)
 941                 {
 942                         RandomSelection_Init();
 943                         IL_EACH(g_items, it.team == this.team,
 944                         {
 945                                 if(it.itemdef) // is a registered item
 946                                 {
 947                                         Item_Show(it, -1);
 948                                         it.scheduledrespawntime = 0;
 949                                         RandomSelection_AddEnt(it, it.cnt, 0);
 950                                 }
 951                         });
 952                         e = RandomSelection_chosen_ent;
 953                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 954                 }
 955                 else
 956                         e = this;
 957                 Item_ScheduleRespawn(e);
 958         }
 959 }
 960
 961 void Item_Reset(entity this)
 962 {
 963         Item_Show(this, !this.state);
 964         setorigin(this, this.origin);
 965
 966         if (this.classname != "droppedweapon")
 967         {
 968                 setthink(this, Item_Think);
 969                 this.nextthink = time;
 970
 971                 if (this.waypointsprite_attached)
 972                         WaypointSprite_Kill(this.waypointsprite_attached);
 973
 974                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 975                         Item_ScheduleInitialRespawn(this);
 976         }
 977 }
 978
 979 void Item_FindTeam(entity this)
 980 {
 981         entity e;
 982
 983         if(this.effects & EF_NODRAW)
 984         {
 985                 // marker for item team search
 986                 LOG_TRACE("Initializing item team ", ftos(this.team));
 987                 RandomSelection_Init();
 988                 IL_EACH(g_items, it.team == this.team,
 989                 {
 990                         if(it.itemdef) // is a registered item
 991                                 RandomSelection_AddEnt(it, it.cnt, 0);
 992                 });
 993
 994                 e = RandomSelection_chosen_ent;
 995                 e.state = 0;
 996                 Item_Show(e, 1);
 997
 998                 IL_EACH(g_items, it.team == this.team,
 999                 {
1000                         if(it.itemdef) // is a registered item
1001                         {
1002                                 if(it != e)
1003                                 {
1004                                         // make it non-spawned
1005                                         Item_Show(it, -1);
1006                                         it.state = 1; // state 1 = initially hidden item, apparently
1007                                 }
1008                                 it.effects &= ~EF_NODRAW;
1009                         }
1010                 });
1011
1012                 Item_Reset(this);
1013         }
1014 }
1015
1016 // Savage: used for item garbage-collection
1017 void RemoveItem(entity this)
1018 {
1019         if(wasfreed(this) || !this) { return; }
1020         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1021         delete(this);
1022 }
1023
1024 // pickup evaluation functions
1025 // these functions decide how desirable an item is to the bots
1026
1027 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1028
1029 float weapon_pickupevalfunc(entity player, entity item)
1030 {
1031         // See if I have it already
1032         if(player.weapons & item.weapons)
1033         {
1034                 // If I can pick it up
1035                 if(!item.spawnshieldtime)
1036                         return 0;
1037                 return ammo_pickupevalfunc(player, item);
1038         }
1039
1040         // reduce weapon value if bot already got a good arsenal
1041         float c = 1;
1042         int weapons_value = 0;
1043         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1044                 weapons_value += it.bot_pickupbasevalue;
1045         });
1046         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1047
1048         return item.bot_pickupbasevalue * c;
1049 }
1050
1051 float ammo_pickupevalfunc(entity player, entity item)
1052 {
1053         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1054         entity wpn = NULL;
1055         float c = 0;
1056         float rating = 0;
1057
1058         // Detect needed ammo
1059         if(item.itemdef.instanceOfWeaponPickup)
1060         {
1061                 entity ammo = NULL;
1062                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1063                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1064                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1065                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1066                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1067                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1068
1069                 if(!ammo)
1070                         return 0;
1071                 wpn = item;
1072                 rating = ammo.m_botvalue;
1073         }
1074         else
1075         {
1076                 FOREACH(Weapons, it != WEP_Null, {
1077                         if(!(player.weapons & (it.m_wepset)))
1078                                 continue;
1079
1080                         switch(it.ammo_type)
1081                         {
1082                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1083                                 case RESOURCE_BULLETS: need_nails   = true; break;
1084                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1085                                 case RESOURCE_CELLS:   need_cells   = true; break;
1086                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1087                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1088                         }
1089                 });
1090                 rating = item.bot_pickupbasevalue;
1091         }
1092
1093         float noammorating = 0.5;
1094
1095         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1096                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1097
1098         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1099                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1100
1101         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1102                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1103
1104         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1105                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1106
1107         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1108                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1109
1110         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1111                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1112
1113         rating *= min(c, 2);
1114         if(wpn)
1115                 rating += wpn.bot_pickupbasevalue * 0.1;
1116         return rating;
1117 }
1118
1119 .int item_group;
1120 .int item_group_count;
1121 float healtharmor_pickupevalfunc(entity player, entity item)
1122 {
1123         float c = 0;
1124         float rating = item.bot_pickupbasevalue;
1125
1126         float itemarmor = item.armorvalue;
1127         float itemhealth = item.health;
1128
1129         if(item.item_group)
1130         {
1131                 itemarmor *= min(4, item.item_group_count);
1132                 itemhealth *= min(4, item.item_group_count);
1133         }
1134
1135         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1136                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1137
1138         if (itemhealth && (player.health < item.max_health))
1139                 c = itemhealth / max(1, player.health);
1140
1141         rating *= min(2, c);
1142         return rating;
1143 }
1144
1145 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1146 {
1147         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1148                 RemoveItem(this);
1149 }
1150
1151 void item_use(entity this, entity actor, entity trigger)
1152 {
1153         // use the touch function to handle collection
1154         gettouch(this)(this, actor);
1155 }
1156
1157 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1158 {
1159         string itemname = def.m_name;
1160         Model itemmodel = def.m_model;
1161     Sound pickupsound = def.m_sound;
1162         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1163         float pickupbasevalue = def.m_botvalue;
1164         int itemflags = def.m_itemflags;
1165
1166         startitem_failed = false;
1167
1168         this.item_model_ent = itemmodel;
1169     this.item_pickupsound_ent = pickupsound;
1170
1171     if(def.m_iteminit)
1172         def.m_iteminit(this);
1173
1174         if(!this.respawntime) // both need to be set
1175         {
1176                 this.respawntime = defaultrespawntime;
1177                 this.respawntimejitter = defaultrespawntimejitter;
1178         }
1179
1180         if(!this.pickup_anyway && def.m_pickupanyway)
1181                 this.pickup_anyway = def.m_pickupanyway();
1182
1183         int itemid = def.m_itemid;
1184         this.items = itemid;
1185         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1186         this.weapon = weaponid;
1187
1188         if(!this.fade_end)
1189         {
1190                 this.fade_start = autocvar_g_items_mindist;
1191                 this.fade_end = autocvar_g_items_maxdist;
1192         }
1193
1194         if(weaponid)
1195                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1196
1197         this.flags = FL_ITEM | itemflags;
1198         IL_PUSH(g_items, this);
1199
1200         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1201         {
1202                 startitem_failed = true;
1203                 delete(this);
1204                 return;
1205         }
1206
1207         // is it a dropped weapon?
1208         if (this.classname == "droppedweapon")
1209         {
1210                 this.reset = SUB_Remove;
1211                 // it's a dropped weapon
1212                 set_movetype(this, MOVETYPE_TOSS);
1213
1214                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1215                 setthink(this, RemoveItem);
1216                 this.nextthink = time + 20;
1217
1218                 this.takedamage = DAMAGE_YES;
1219                 this.event_damage = Item_Damage;
1220
1221                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1222                 {
1223                         // if item is worthless after a timer, have it expire then
1224                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1225                 }
1226
1227                 // don't drop if in a NODROP zone (such as lava)
1228                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1229                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1230                 {
1231                         startitem_failed = true;
1232                         delete(this);
1233                         return;
1234                 }
1235         }
1236         else
1237         {
1238                 if(!have_pickup_item(this))
1239                 {
1240                         startitem_failed = true;
1241                         delete(this);
1242                         return;
1243                 }
1244
1245                 if(this.angles != '0 0 0')
1246                         this.SendFlags |= ISF_ANGLES;
1247
1248                 this.reset = Item_Reset;
1249                 // it's a level item
1250                 if(this.spawnflags & 1)
1251                         this.noalign = 1;
1252                 if (this.noalign > 0)
1253                         set_movetype(this, MOVETYPE_NONE);
1254                 else
1255                         set_movetype(this, MOVETYPE_TOSS);
1256                 // do item filtering according to game mode and other things
1257                 if (this.noalign <= 0)
1258                 {
1259                         // first nudge it off the floor a little bit to avoid math errors
1260                         setorigin(this, this.origin + '0 0 1');
1261                         // set item size before we spawn a spawnfunc_waypoint
1262                         setsize(this, def.m_mins, def.m_maxs);
1263                         this.SendFlags |= ISF_SIZE;
1264                         // note droptofloor returns false if stuck/or would fall too far
1265                         if (!this.noalign)
1266                                 droptofloor(this);
1267                         waypoint_spawnforitem(this);
1268                 }
1269
1270                 /*
1271                  * can't do it that way, as it would break maps
1272                  * TODO make a target_give like entity another way, that perhaps has
1273                  * the weapon name in a key
1274                 if(this.targetname)
1275                 {
1276                         // target_give not yet supported; maybe later
1277                         print("removed targeted ", this.classname, "\n");
1278                         startitem_failed = true;
1279                         delete(this);
1280                         return;
1281                 }
1282                 */
1283
1284                 if(this.targetname != "" && (this.spawnflags & 16))
1285                         this.use = item_use;
1286
1287                 if(autocvar_spawn_debug >= 2)
1288                 {
1289             // why not flags & fl_item?
1290                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1291                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1292                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1293                 error("Mapper sucks.");
1294             });
1295                         this.is_item = true;
1296                 }
1297
1298                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1299
1300                 precache_model(this.model);
1301                 precache_sound(this.item_pickupsound);
1302
1303                 if (   def.instanceOfPowerup
1304                         || def.instanceOfWeaponPickup
1305                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1306                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1307                         || (itemid & (IT_KEY1 | IT_KEY2))
1308                 ) this.target = "###item###"; // for finding the nearest item using find()
1309
1310                 Item_ItemsTime_SetTime(this, 0);
1311         }
1312
1313         this.bot_pickup = true;
1314         this.bot_pickupevalfunc = pickupevalfunc;
1315         this.bot_pickupbasevalue = pickupbasevalue;
1316         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1317         this.netname = itemname;
1318         settouch(this, Item_Touch);
1319         setmodel(this, MDL_Null); // precision set below
1320         //this.effects |= EF_LOWPRECISION;
1321
1322         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1323
1324         this.SendFlags |= ISF_SIZE;
1325
1326         if (!(this.spawnflags & 1024)) {
1327                 if(def.instanceOfPowerup)
1328                         this.ItemStatus |= ITS_ANIMATE1;
1329
1330                 if(this.armorvalue || this.health)
1331                         this.ItemStatus |= ITS_ANIMATE2;
1332         }
1333
1334         if(def.instanceOfWeaponPickup)
1335         {
1336                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1337                         this.colormap = 1024; // color shirt=0 pants=0 grey
1338                 else
1339                         this.gravity = 1;
1340                 if (!(this.spawnflags & 1024))
1341                         this.ItemStatus |= ITS_ANIMATE1;
1342                 this.SendFlags |= ISF_COLORMAP;
1343         }
1344
1345         this.state = 0;
1346         if(this.team) // broken, no idea why.
1347         {
1348                 if(!this.cnt)
1349                         this.cnt = 1; // item probability weight
1350
1351                 this.effects |= EF_NODRAW; // marker for item team search
1352                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1353         }
1354         else
1355                 Item_Reset(this);
1356
1357         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1358
1359         // call this hook after everything else has been done
1360         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1361         {
1362                 startitem_failed = true;
1363                 delete(this);
1364                 return;
1365         }
1366
1367         setItemGroup(this);
1368 }
1369
1370 void StartItem(entity this, GameItem def)
1371 {
1372     _StartItem(
1373         this,
1374         this.itemdef = def,
1375         def.m_respawntime(), // defaultrespawntime
1376         def.m_respawntimejitter() // defaultrespawntimejitter
1377         );
1378 }
1379
1380 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1381 int group_count = 1;
1382
1383 void setItemGroup(entity this)
1384 {
1385         if(!IS_SMALL(this.itemdef))
1386                 return;
1387
1388         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1389         {
1390                 if(!this.item_group)
1391                 {
1392                         if(!it.item_group)
1393                         {
1394                                 it.item_group = group_count;
1395                                 group_count++;
1396                         }
1397                         this.item_group = it.item_group;
1398                 }
1399                 else // spawning item is already part of a item_group X
1400                 {
1401                         if(!it.item_group)
1402                                 it.item_group = this.item_group;
1403                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1404                         {
1405                                 int grY = it.item_group;
1406                                 // move all items of item_group Y to item_group X
1407                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1408                                 {
1409                                         if(it.item_group == grY)
1410                                                 it.item_group = this.item_group;
1411                                 });
1412                         }
1413                 }
1414         });
1415 }
1416
1417 void setItemGroupCount()
1418 {
1419         for (int k = 1; k <= group_count; k++)
1420         {
1421                 int count = 0;
1422                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1423                 if (count)
1424                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1425         }
1426 }
1427
1428 spawnfunc(item_rockets)
1429 {
1430     StartItem(this, ITEM_Rockets);
1431 }
1432
1433 spawnfunc(item_bullets)
1434 {
1435         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1436            (this.classname != "droppedweapon"))
1437         {
1438                 weaponswapping = true;
1439                 spawnfunc_item_shells(this);
1440                 weaponswapping = false;
1441                 return;
1442         }
1443
1444     StartItem(this, ITEM_Bullets);
1445 }
1446
1447 spawnfunc(item_cells)
1448 {
1449         StartItem(this, ITEM_Cells);
1450 }
1451
1452 spawnfunc(item_plasma)
1453 {
1454         StartItem(this, ITEM_Plasma);
1455 }
1456
1457 spawnfunc(item_shells)
1458 {
1459         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1460            (this.classname != "droppedweapon"))
1461         {
1462                 weaponswapping = true;
1463                 spawnfunc_item_bullets(this);
1464                 weaponswapping = false;
1465                 return;
1466         }
1467
1468         StartItem(this, ITEM_Shells);
1469 }
1470
1471 spawnfunc(item_armor_small)
1472 {
1473         StartItem(this, ITEM_ArmorSmall);
1474 }
1475
1476 spawnfunc(item_armor_medium)
1477 {
1478         StartItem(this, ITEM_ArmorMedium);
1479 }
1480
1481 spawnfunc(item_armor_big)
1482 {
1483         StartItem(this, ITEM_ArmorBig);
1484 }
1485
1486 spawnfunc(item_armor_mega)
1487 {
1488         StartItem(this, ITEM_ArmorMega);
1489 }
1490
1491 spawnfunc(item_health_small)
1492 {
1493         StartItem(this, ITEM_HealthSmall);
1494 }
1495
1496 spawnfunc(item_health_medium)
1497 {
1498     StartItem(this, ITEM_HealthMedium);
1499 }
1500
1501 spawnfunc(item_health_big)
1502 {
1503         StartItem(this, ITEM_HealthBig);
1504 }
1505
1506 spawnfunc(item_health_mega)
1507 {
1508     StartItem(this, ITEM_HealthMega);
1509 }
1510
1511 // support old misnamed entities
1512 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1513 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1514 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1515 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1516 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1517 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1518 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1519
1520 spawnfunc(item_strength)
1521 {
1522         StartItem(this, ITEM_Strength);
1523 }
1524
1525 spawnfunc(item_invincible)
1526 {
1527         StartItem(this, ITEM_Shield);
1528 }
1529
1530 // compatibility:
1531 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1532
1533 void target_items_use(entity this, entity actor, entity trigger)
1534 {
1535         if(actor.classname == "droppedweapon")
1536         {
1537                 EXACTTRIGGER_TOUCH(this, trigger);
1538                 delete(actor);
1539                 return;
1540         }
1541
1542         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1543                 return;
1544
1545         if(trigger.solid == SOLID_TRIGGER)
1546         {
1547                 EXACTTRIGGER_TOUCH(this, trigger);
1548         }
1549
1550         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1551         {
1552                 delete(it);
1553         });
1554
1555         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1556                 centerprint(actor, this.message);
1557 }
1558
1559 spawnfunc(target_items)
1560 {
1561         int n;
1562         string s;
1563
1564         this.use = target_items_use;
1565         if(!this.strength_finished)
1566                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1567         if(!this.invincible_finished)
1568                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1569         if(!this.superweapons_finished)
1570                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1571
1572         n = tokenize_console(this.netname);
1573         if(argv(0) == "give")
1574         {
1575                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1576         }
1577         else
1578         {
1579                 for(int j = 0; j < n; ++j)
1580                 {
1581                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1582                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1583                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1584                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1585                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1586                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1587                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1588                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1589                         else
1590                         {
1591                                 FOREACH(Buffs, it != BUFF_Null,
1592                                 {
1593                                         s = Buff_UndeprecateName(argv(j));
1594                                         if(s == it.m_name)
1595                                         {
1596                                                 this.buffs |= (it.m_itemid);
1597                                                 break;
1598                                         }
1599                                 });
1600                                 FOREACH(Weapons, it != WEP_Null, {
1601                                         s = W_UndeprecateName(argv(j));
1602                                         if(s == it.netname)
1603                                         {
1604                                                 this.weapons |= (it.m_wepset);
1605                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1606                                                         it.wr_init(it);
1607                                                 break;
1608                                         }
1609                                 });
1610                         }
1611                 }
1612
1613                 string itemprefix, valueprefix;
1614                 if(this.spawnflags == 0)
1615                 {
1616                         itemprefix = "";
1617                         valueprefix = "";
1618                 }
1619                 else if(this.spawnflags == 1)
1620                 {
1621                         itemprefix = "max ";
1622                         valueprefix = "max ";
1623                 }
1624                 else if(this.spawnflags == 2)
1625                 {
1626                         itemprefix = "min ";
1627                         valueprefix = "min ";
1628                 }
1629                 else if(this.spawnflags == 4)
1630                 {
1631                         itemprefix = "minus ";
1632                         valueprefix = "max ";
1633                 }
1634                 else
1635                 {
1636                         error("invalid spawnflags");
1637                         itemprefix = valueprefix = string_null;
1638                 }
1639
1640                 this.netname = "";
1641                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1642                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1643                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1644                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1645                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1646                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1647                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1648                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1649                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1650                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1651                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1652                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1653                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1654                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1655                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1656                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1657                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1658         }
1659         this.netname = strzone(this.netname);
1660         //print(this.netname, "\n");
1661
1662         n = tokenize_console(this.netname);
1663         for(int j = 0; j < n; ++j)
1664         {
1665                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1666             it.wr_init(it);
1667             break;
1668                 });
1669         }
1670 }
1671
1672 spawnfunc(item_fuel)
1673 {
1674         StartItem(this, ITEM_JetpackFuel);
1675 }
1676
1677 spawnfunc(item_fuel_regen)
1678 {
1679         if(start_items & ITEM_JetpackRegen.m_itemid)
1680         {
1681                 spawnfunc_item_fuel(this);
1682                 return;
1683         }
1684         StartItem(this, ITEM_JetpackRegen);
1685 }
1686
1687 spawnfunc(item_jetpack)
1688 {
1689         if(start_items & ITEM_Jetpack.m_itemid)
1690         {
1691                 spawnfunc_item_fuel(this);
1692                 return;
1693         }
1694         StartItem(this, ITEM_Jetpack);
1695 }
1696
1697 float GiveWeapon(entity e, float wpn, float op, float val)
1698 {
1699         WepSet v0, v1;
1700         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1701         v0 = (e.weapons & s);
1702         switch(op)
1703         {
1704                 case OP_SET:
1705                         if(val > 0)
1706                                 e.weapons |= s;
1707                         else
1708                                 e.weapons &= ~s;
1709                         break;
1710                 case OP_MIN:
1711                 case OP_PLUS:
1712                         if(val > 0)
1713                                 e.weapons |= s;
1714                         break;
1715                 case OP_MAX:
1716                         if(val <= 0)
1717                                 e.weapons &= ~s;
1718                         break;
1719                 case OP_MINUS:
1720                         if(val > 0)
1721                                 e.weapons &= ~s;
1722                         break;
1723         }
1724         v1 = (e.weapons & s);
1725         return (v0 != v1);
1726 }
1727
1728 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1729 {
1730         bool had_buff = (e.buffs & thebuff.m_itemid);
1731         switch(op)
1732         {
1733                 case OP_SET:
1734                         if(val > 0)
1735                                 e.buffs |= thebuff.m_itemid;
1736                         else
1737                                 e.buffs &= ~thebuff.m_itemid;
1738                         break;
1739                 case OP_MIN:
1740                 case OP_PLUS:
1741                         if(val > 0)
1742                                 e.buffs |= thebuff.m_itemid;
1743                         break;
1744                 case OP_MAX:
1745                         if(val <= 0)
1746                                 e.buffs &= ~thebuff.m_itemid;
1747                         break;
1748                 case OP_MINUS:
1749                         if(val > 0)
1750                                 e.buffs &= ~thebuff.m_itemid;
1751                         break;
1752         }
1753         bool have_buff = (e.buffs & thebuff.m_itemid);
1754         return (had_buff != have_buff);
1755 }
1756
1757 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1758 {
1759         if(v1 == v0)
1760                 return;
1761         if(v1 <= v0 - t)
1762         {
1763                 if(snd_decr != NULL)
1764                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1765         }
1766         else if(v0 >= v0 + t)
1767         {
1768                 if(snd_incr != NULL)
1769                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1770         }
1771 }
1772
1773 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1774 {
1775         if(v0 < v1)
1776                 e.(rotfield) = max(e.(rotfield), time + rottime);
1777         else if(v0 > v1)
1778                 e.(regenfield) = max(e.(regenfield), time + regentime);
1779 }
1780 float GiveItems(entity e, float beginarg, float endarg)
1781 {
1782         float got, i, val, op;
1783         string cmd;
1784
1785         val = 999;
1786         op = OP_SET;
1787
1788         got = 0;
1789
1790         int _switchweapon = 0;
1791
1792         if(CS(e).autoswitch)
1793         {
1794                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1795                 {
1796                         .entity weaponentity = weaponentities[slot];
1797                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1798                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1799                                 _switchweapon |= BIT(slot);
1800                 }
1801         }
1802
1803         e.strength_finished = max(0, e.strength_finished - time);
1804         e.invincible_finished = max(0, e.invincible_finished - time);
1805         e.superweapons_finished = max(0, e.superweapons_finished - time);
1806
1807         PREGIVE(e, items);
1808         PREGIVE_WEAPONS(e);
1809         PREGIVE(e, strength_finished);
1810         PREGIVE(e, invincible_finished);
1811         PREGIVE(e, superweapons_finished);
1812         PREGIVE(e, ammo_nails);
1813         PREGIVE(e, ammo_cells);
1814         PREGIVE(e, ammo_plasma);
1815         PREGIVE(e, ammo_shells);
1816         PREGIVE(e, ammo_rockets);
1817         PREGIVE(e, ammo_fuel);
1818         PREGIVE(e, armorvalue);
1819         PREGIVE(e, health);
1820
1821         for(i = beginarg; i < endarg; ++i)
1822         {
1823                 cmd = argv(i);
1824
1825                 if(cmd == "0" || stof(cmd))
1826                 {
1827                         val = stof(cmd);
1828                         continue;
1829                 }
1830                 switch(cmd)
1831                 {
1832                         case "no":
1833                                 op = OP_MAX;
1834                                 val = 0;
1835                                 continue;
1836                         case "max":
1837                                 op = OP_MAX;
1838                                 continue;
1839                         case "min":
1840                                 op = OP_MIN;
1841                                 continue;
1842                         case "plus":
1843                                 op = OP_PLUS;
1844                                 continue;
1845                         case "minus":
1846                                 op = OP_MINUS;
1847                                 continue;
1848                         case "ALL":
1849                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1850                                 got += GiveValue(e, strength_finished, op, val);
1851                                 got += GiveValue(e, invincible_finished, op, val);
1852                                 got += GiveValue(e, superweapons_finished, op, val);
1853                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1854                         case "all":
1855                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1856                                 got += GiveValue(e, health, op, val);
1857                                 got += GiveValue(e, armorvalue, op, val);
1858                         case "allweapons":
1859                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1860                         //case "allbuffs": // all buffs makes a player god, do not want!
1861                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1862                         case "allammo":
1863                                 got += GiveValue(e, ammo_cells, op, val);
1864                                 got += GiveValue(e, ammo_plasma, op, val);
1865                                 got += GiveValue(e, ammo_shells, op, val);
1866                                 got += GiveValue(e, ammo_nails, op, val);
1867                                 got += GiveValue(e, ammo_rockets, op, val);
1868                                 got += GiveValue(e, ammo_fuel, op, val);
1869                                 break;
1870                         case "unlimited_ammo":
1871                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1872                                 break;
1873                         case "unlimited_weapon_ammo":
1874                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1875                                 break;
1876                         case "unlimited_superweapons":
1877                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1878                                 break;
1879                         case "jetpack":
1880                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1881                                 break;
1882                         case "fuel_regen":
1883                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1884                                 break;
1885                         case "strength":
1886                                 got += GiveValue(e, strength_finished, op, val);
1887                                 break;
1888                         case "invincible":
1889                                 got += GiveValue(e, invincible_finished, op, val);
1890                                 break;
1891                         case "superweapons":
1892                                 got += GiveValue(e, superweapons_finished, op, val);
1893                                 break;
1894                         case "cells":
1895                                 got += GiveValue(e, ammo_cells, op, val);
1896                                 break;
1897                         case "plasma":
1898                                 got += GiveValue(e, ammo_plasma, op, val);
1899                                 break;
1900                         case "shells":
1901                                 got += GiveValue(e, ammo_shells, op, val);
1902                                 break;
1903                         case "nails":
1904                         case "bullets":
1905                                 got += GiveValue(e, ammo_nails, op, val);
1906                                 break;
1907                         case "rockets":
1908                                 got += GiveValue(e, ammo_rockets, op, val);
1909                                 break;
1910                         case "health":
1911                                 got += GiveValue(e, health, op, val);
1912                                 break;
1913                         case "armor":
1914                                 got += GiveValue(e, armorvalue, op, val);
1915                                 break;
1916                         case "fuel":
1917                                 got += GiveValue(e, ammo_fuel, op, val);
1918                                 break;
1919                         default:
1920                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1921                                 {
1922                                         got += GiveBuff(e, it, op, val);
1923                                         break;
1924                                 });
1925                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1926                     got += GiveWeapon(e, it.m_id, op, val);
1927                     break;
1928                                 });
1929                                 break;
1930                 }
1931                 val = 999;
1932                 op = OP_SET;
1933         }
1934
1935         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1936         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1937         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1938         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1939         FOREACH(Weapons, it != WEP_Null, {
1940                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1941                 if(!(save_weapons & (it.m_wepset)))
1942                         if(e.weapons & (it.m_wepset))
1943                                 it.wr_init(it);
1944         });
1945         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1946         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1947         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1948         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1949         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1950         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1951         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1952         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1953         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1954         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1955         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1956
1957         if(e.superweapons_finished <= 0)
1958                 if(e.weapons & WEPSET_SUPERWEAPONS)
1959                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1960
1961         if(e.strength_finished <= 0)
1962                 e.strength_finished = 0;
1963         else
1964                 e.strength_finished += time;
1965         if(e.invincible_finished <= 0)
1966                 e.invincible_finished = 0;
1967         else
1968                 e.invincible_finished += time;
1969         if(e.superweapons_finished <= 0)
1970                 e.superweapons_finished = 0;
1971         else
1972                 e.superweapons_finished += time;
1973
1974         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1975         {
1976                 .entity weaponentity = weaponentities[slot];
1977                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1978                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1979                         _switchweapon |= BIT(slot);
1980         }
1981
1982         if(_switchweapon)
1983         {
1984                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1985                 {
1986                         .entity weaponentity = weaponentities[slot];
1987                         if(_switchweapon & BIT(slot))
1988                         {
1989                                 Weapon wep = w_getbestweapon(e, weaponentity);
1990                                 if(wep != e.(weaponentity).m_switchweapon)
1991                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1992                         }
1993                 }
1994         }
1995
1996         return got;
1997 }
1998 #endif