qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 float adjust_respawntime(float normal_respawntime) {
 639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 640         float o = autocvar_g_pickup_respawntime_scaling_offset;
 641         float l = autocvar_g_pickup_respawntime_scaling_linear;
 642
 643         if (r == 0 && l == 1) {
 644                 return normal_respawntime;
 645         }
 646
 647         CheckAllowedTeams(NULL);
 648         GetTeamCounts(NULL);
 649         int players = 0;
 650         if (c1 != -1) players += c1;
 651         if (c2 != -1) players += c2;
 652         if (c3 != -1) players += c3;
 653         if (c4 != -1) players += c4;
 654
 655         if (players >= 2) {
 656                 return normal_respawntime * (r / (players + o) + l);
 657         } else {
 658                 return normal_respawntime;
 659         }
 660 }
 661
 662 void Item_ScheduleRespawn(entity e)
 663 {
 664         if(e.respawntime > 0)
 665         {
 666                 Item_Show(e, 0);
 667
 668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 670
 671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 673                 Item_ScheduleRespawnIn(e, actual_time);
 674         }
 675         else // if respawntime is -1, this item does not respawn
 676                 Item_Show(e, -1);
 677 }
 678
 679 void Item_ScheduleInitialRespawn(entity e)
 680 {
 681         Item_Show(e, 0);
 682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 683 }
 684
 685 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 686         float shells, float bullets, float rockets, float cells, float plasma)
 687 {
 688         if (num_weapons == 0)
 689         {
 690                 return;
 691         }
 692         int num_potential_weapons = tokenize_console(weapon_names);
 693         for (int i = 0; i < num_weapons; ++i)
 694         {
 695                 RandomSelection_Init();
 696                 for (int j = 0; j < num_potential_weapons; ++j)
 697                 {
 698                         string weapon = argv(j);
 699                         FOREACH(Weapons, it != WEP_Null,
 700                         {
 701                                 // Finding a weapon which player doesn't have.
 702                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 703                                 {
 704                                         RandomSelection_AddEnt(it, 1, 1);
 705                                         break;
 706                                 }
 707                         });
 708                 }
 709                 if (RandomSelection_chosen_ent == NULL)
 710                 {
 711                         return;
 712                 }
 713                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 714                 switch (RandomSelection_chosen_ent.ammo_field)
 715                 {
 716                         case (ammo_shells):
 717                         {
 718                                 if (GetResourceAmount(receiver, RESOURCE_SHELLS) != 0)
 719                                 {
 720                                         break;
 721                                 }
 722                                 GiveResource(receiver, RESOURCE_SHELLS, shells);
 723                                 break;
 724                         }
 725                         case (ammo_nails):
 726                         {
 727                                 if (GetResourceAmount(receiver, RESOURCE_BULLETS) != 0)
 728                                 {
 729                                         break;
 730                                 }
 731                                 GiveResource(receiver, RESOURCE_BULLETS, bullets);
 732                                 break;
 733                         }
 734                         case (ammo_rockets):
 735                         {
 736                                 if (GetResourceAmount(receiver, RESOURCE_ROCKETS) != 0)
 737                                 {
 738                                         break;
 739                                 }
 740                                 GiveResource(receiver, RESOURCE_ROCKETS, rockets);
 741                                 break;
 742                         }
 743                         case (ammo_cells):
 744                         {
 745                                 if (GetResourceAmount(receiver, RESOURCE_CELLS) != 0)
 746                                 {
 747                                         break;
 748                                 }
 749                                 GiveResource(receiver, RESOURCE_CELLS, cells);
 750                                 break;
 751                         }
 752                         case (ammo_plasma):
 753                         {
 754                                 if (GetResourceAmount(receiver, RESOURCE_PLASMA) != 0)
 755                                 {
 756                                         break;
 757                                 }
 758                                 GiveResource(receiver, RESOURCE_PLASMA, plasma);
 759                                 break;
 760                         }
 761                 }
 762         }
 763 }
 764
 765 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 766 {
 767         float amount = GetResourceAmount(item, resource_type);
 768         if (amount == 0)
 769         {
 770                 return false;
 771         }
 772         float player_amount = GetResourceAmount(player, resource_type);
 773         if (item.spawnshieldtime)
 774         {
 775                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 776                 {
 777                         return false;
 778                 }
 779                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 780                 return true;
 781         }
 782         if (g_weapon_stay != 2)
 783         {
 784                 return false;
 785         }
 786         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 787         return true;
 788 }
 789
 790 float Item_GiveTo(entity item, entity player)
 791 {
 792         float pickedup;
 793
 794         // if nothing happens to player, just return without taking the item
 795         pickedup = false;
 796         int _switchweapon = 0;
 797         // in case the player has autoswitch enabled do the following:
 798         // if the player is using their best weapon before items are given, they
 799         // probably want to switch to an even better weapon after items are given
 800
 801         if(CS(player).autoswitch)
 802         {
 803                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 804                 {
 805                         .entity weaponentity = weaponentities[slot];
 806                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 807                         {
 808                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 809                                         _switchweapon |= BIT(slot);
 810
 811                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 812                                         _switchweapon |= BIT(slot);
 813                         }
 814                 }
 815         }
 816         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 817         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 818         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 819         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 820         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 821         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 822         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 823         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 824         if (item.itemdef.instanceOfWeaponPickup)
 825         {
 826                 WepSet w;
 827                 w = item.weapons;
 828                 w &= ~player.weapons;
 829
 830                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 831                 {
 832                         pickedup = true;
 833                         FOREACH(Weapons, it != WEP_Null, {
 834                                 if(w & (it.m_wepset))
 835                                 {
 836                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 837                                         {
 838                                                 .entity weaponentity = weaponentities[slot];
 839                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 840                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 841                                         }
 842                                         W_GiveWeapon(player, it.m_id);
 843                                 }
 844                         });
 845                 }
 846         }
 847
 848         if (item.itemdef.instanceOfPowerup)
 849         {
 850                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 851                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 852                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 853                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 854         }
 855
 856         int its;
 857         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 858         {
 859                 pickedup = true;
 860                 player.items |= its;
 861                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 862         }
 863
 864         if (item.strength_finished)
 865         {
 866                 pickedup = true;
 867                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 868         }
 869         if (item.invincible_finished)
 870         {
 871                 pickedup = true;
 872                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 873         }
 874         if (item.superweapons_finished)
 875         {
 876                 pickedup = true;
 877                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 878         }
 879
 880 LABEL(skip)
 881
 882         // always eat teamed entities
 883         if(item.team)
 884                 pickedup = true;
 885
 886         if (!pickedup)
 887                 return 0;
 888
 889         // crude hack to enforce switching weapons
 890         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 891         {
 892                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 893                 {
 894                         .entity weaponentity = weaponentities[slot];
 895                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 896                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 897                 }
 898                 return 1;
 899         }
 900
 901         if(_switchweapon)
 902         {
 903                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 904                 {
 905                         .entity weaponentity = weaponentities[slot];
 906                         if(_switchweapon & BIT(slot))
 907                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 908                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 909                 }
 910         }
 911
 912         return 1;
 913 }
 914
 915 void Item_Touch(entity this, entity toucher)
 916 {
 917
 918         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 919         if (this.classname == "droppedweapon")
 920         {
 921                 if (ITEM_TOUCH_NEEDKILL())
 922                 {
 923                         delete(this);
 924                         return;
 925                 }
 926         }
 927
 928         if(!(toucher.flags & FL_PICKUPITEMS)
 929         || STAT(FROZEN, toucher)
 930         || IS_DEAD(toucher)
 931         || (this.solid != SOLID_TRIGGER)
 932         || (this.owner == toucher)
 933         || (time < this.item_spawnshieldtime)
 934         ) { return; }
 935
 936         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 937         {
 938                 case MUT_ITEMTOUCH_RETURN: { return; }
 939                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 940         }
 941
 942         toucher = M_ARGV(1, entity);
 943
 944         if (this.classname == "droppedweapon")
 945         {
 946                 this.strength_finished = max(0, this.strength_finished - time);
 947                 this.invincible_finished = max(0, this.invincible_finished - time);
 948                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 949         }
 950         entity it = this.itemdef;
 951         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 952         if (!gave)
 953         {
 954                 if (this.classname == "droppedweapon")
 955                 {
 956                         // undo what we did above
 957                         this.strength_finished += time;
 958                         this.invincible_finished += time;
 959                         this.superweapons_finished += time;
 960                 }
 961                 return;
 962         }
 963
 964 LABEL(pickup)
 965
 966         toucher.last_pickup = time;
 967
 968         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 969         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 970
 971         if (this.classname == "droppedweapon")
 972                 delete(this);
 973         else if (this.spawnshieldtime)
 974         {
 975                 entity e;
 976                 if(this.team)
 977                 {
 978                         RandomSelection_Init();
 979                         IL_EACH(g_items, it.team == this.team,
 980                         {
 981                                 if(it.itemdef) // is a registered item
 982                                 {
 983                                         Item_Show(it, -1);
 984                                         RandomSelection_AddEnt(it, it.cnt, 0);
 985                                 }
 986                         });
 987                         e = RandomSelection_chosen_ent;
 988                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 989                 }
 990                 else
 991                         e = this;
 992                 Item_ScheduleRespawn(e);
 993         }
 994 }
 995
 996 void Item_Reset(entity this)
 997 {
 998         Item_Show(this, !this.state);
 999         setorigin(this, this.origin);
1000
1001         if (this.classname != "droppedweapon")
1002         {
1003                 setthink(this, Item_Think);
1004                 this.nextthink = time;
1005
1006                 if (this.waypointsprite_attached)
1007                         WaypointSprite_Kill(this.waypointsprite_attached);
1008
1009                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1010                         Item_ScheduleInitialRespawn(this);
1011         }
1012 }
1013
1014 void Item_FindTeam(entity this)
1015 {
1016         entity e;
1017
1018         if(this.effects & EF_NODRAW)
1019         {
1020                 // marker for item team search
1021                 LOG_TRACE("Initializing item team ", ftos(this.team));
1022                 RandomSelection_Init();
1023                 IL_EACH(g_items, it.team == this.team,
1024                 {
1025                         if(it.itemdef) // is a registered item
1026                                 RandomSelection_AddEnt(it, it.cnt, 0);
1027                 });
1028
1029                 e = RandomSelection_chosen_ent;
1030                 e.state = 0;
1031                 Item_Show(e, 1);
1032
1033                 IL_EACH(g_items, it.team == this.team,
1034                 {
1035                         if(it.itemdef) // is a registered item
1036                         {
1037                                 if(it != e)
1038                                 {
1039                                         // make it non-spawned
1040                                         Item_Show(it, -1);
1041                                         it.state = 1; // state 1 = initially hidden item, apparently
1042                                 }
1043                                 it.effects &= ~EF_NODRAW;
1044                         }
1045                 });
1046
1047                 Item_Reset(this);
1048         }
1049 }
1050
1051 // Savage: used for item garbage-collection
1052 void RemoveItem(entity this)
1053 {
1054         if(wasfreed(this) || !this) { return; }
1055         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1056         delete(this);
1057 }
1058
1059 // pickup evaluation functions
1060 // these functions decide how desirable an item is to the bots
1061
1062 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1063
1064 float weapon_pickupevalfunc(entity player, entity item)
1065 {
1066         // See if I have it already
1067         if(player.weapons & item.weapons)
1068         {
1069                 // If I can pick it up
1070                 if(!item.spawnshieldtime)
1071                         return 0;
1072                 return ammo_pickupevalfunc(player, item);
1073         }
1074
1075         // reduce weapon value if bot already got a good arsenal
1076         float c = 1;
1077         int weapons_value = 0;
1078         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1079                 weapons_value += it.bot_pickupbasevalue;
1080         });
1081         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1082
1083         return item.bot_pickupbasevalue * c;
1084 }
1085
1086 float ammo_pickupevalfunc(entity player, entity item)
1087 {
1088         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1089         entity wpn = NULL;
1090         float c = 0;
1091         float rating = 0;
1092
1093         // Detect needed ammo
1094         if(item.itemdef.instanceOfWeaponPickup)
1095         {
1096                 entity ammo = NULL;
1097                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1098                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1099                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1100                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1101                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1102                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1103
1104                 if(!ammo)
1105                         return 0;
1106                 wpn = item;
1107                 rating = ammo.m_botvalue;
1108         }
1109         else
1110         {
1111                 FOREACH(Weapons, it != WEP_Null, {
1112                         if(!(player.weapons & (it.m_wepset)))
1113                                 continue;
1114
1115                         switch(it.ammo_field)
1116                         {
1117                                 case ammo_shells:  need_shells  = true; break;
1118                                 case ammo_nails:   need_nails   = true; break;
1119                                 case ammo_rockets: need_rockets = true; break;
1120                                 case ammo_cells:   need_cells   = true; break;
1121                                 case ammo_plasma:  need_plasma  = true; break;
1122                                 case ammo_fuel:    need_fuel    = true; break;
1123                         }
1124                 });
1125                 rating = item.bot_pickupbasevalue;
1126         }
1127
1128         float noammorating = 0.5;
1129
1130         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1131                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1132
1133         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1134                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1135
1136         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1137                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1138
1139         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1140                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1141
1142         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1143                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1144
1145         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1146                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1147
1148         rating *= min(c, 2);
1149         if(wpn)
1150                 rating += wpn.bot_pickupbasevalue * 0.1;
1151         return rating;
1152 }
1153
1154 .int item_group;
1155 .int item_group_count;
1156 float healtharmor_pickupevalfunc(entity player, entity item)
1157 {
1158         float c = 0;
1159         float rating = item.bot_pickupbasevalue;
1160
1161         float itemarmor = item.armorvalue;
1162         float itemhealth = item.health;
1163
1164         if(item.item_group)
1165         {
1166                 itemarmor *= min(4, item.item_group_count);
1167                 itemhealth *= min(4, item.item_group_count);
1168         }
1169
1170         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1171                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1172
1173         if (itemhealth && (player.health < item.max_health))
1174                 c = itemhealth / max(1, player.health);
1175
1176         rating *= min(2, c);
1177         return rating;
1178 }
1179
1180 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1181 {
1182         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1183                 RemoveItem(this);
1184 }
1185
1186 void item_use(entity this, entity actor, entity trigger)
1187 {
1188         // use the touch function to handle collection
1189         gettouch(this)(this, actor);
1190 }
1191
1192 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1193 {
1194         string itemname = def.m_name;
1195         Model itemmodel = def.m_model;
1196     Sound pickupsound = def.m_sound;
1197         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1198         float pickupbasevalue = def.m_botvalue;
1199         int itemflags = def.m_itemflags;
1200
1201         startitem_failed = false;
1202
1203         this.item_model_ent = itemmodel;
1204     this.item_pickupsound_ent = pickupsound;
1205
1206     if(def.m_iteminit)
1207         def.m_iteminit(this);
1208
1209         if(!this.respawntime) // both need to be set
1210         {
1211                 this.respawntime = defaultrespawntime;
1212                 this.respawntimejitter = defaultrespawntimejitter;
1213         }
1214
1215         if(!this.pickup_anyway && def.m_pickupanyway)
1216                 this.pickup_anyway = def.m_pickupanyway();
1217
1218         int itemid = def.m_itemid;
1219         this.items = itemid;
1220         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1221         this.weapon = weaponid;
1222
1223         if(!this.fade_end)
1224         {
1225                 this.fade_start = autocvar_g_items_mindist;
1226                 this.fade_end = autocvar_g_items_maxdist;
1227         }
1228
1229         if(weaponid)
1230                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1231
1232         this.flags = FL_ITEM | itemflags;
1233         IL_PUSH(g_items, this);
1234
1235         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1236         {
1237                 startitem_failed = true;
1238                 delete(this);
1239                 return;
1240         }
1241
1242         // is it a dropped weapon?
1243         if (this.classname == "droppedweapon")
1244         {
1245                 this.reset = SUB_Remove;
1246                 // it's a dropped weapon
1247                 set_movetype(this, MOVETYPE_TOSS);
1248
1249                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1250                 setthink(this, RemoveItem);
1251                 this.nextthink = time + 20;
1252
1253                 this.takedamage = DAMAGE_YES;
1254                 this.event_damage = Item_Damage;
1255
1256                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1257                 {
1258                         // if item is worthless after a timer, have it expire then
1259                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1260                 }
1261
1262                 // don't drop if in a NODROP zone (such as lava)
1263                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1264                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1265                 {
1266                         startitem_failed = true;
1267                         delete(this);
1268                         return;
1269                 }
1270         }
1271         else
1272         {
1273                 if(!have_pickup_item(this))
1274                 {
1275                         startitem_failed = true;
1276                         delete(this);
1277                         return;
1278                 }
1279
1280                 if(this.angles != '0 0 0')
1281                         this.SendFlags |= ISF_ANGLES;
1282
1283                 this.reset = Item_Reset;
1284                 // it's a level item
1285                 if(this.spawnflags & 1)
1286                         this.noalign = 1;
1287                 if (this.noalign > 0)
1288                         set_movetype(this, MOVETYPE_NONE);
1289                 else
1290                         set_movetype(this, MOVETYPE_TOSS);
1291                 // do item filtering according to game mode and other things
1292                 if (this.noalign <= 0)
1293                 {
1294                         // first nudge it off the floor a little bit to avoid math errors
1295                         setorigin(this, this.origin + '0 0 1');
1296                         // set item size before we spawn a spawnfunc_waypoint
1297                         setsize(this, def.m_mins, def.m_maxs);
1298                         this.SendFlags |= ISF_SIZE;
1299                         // note droptofloor returns false if stuck/or would fall too far
1300                         if (!this.noalign)
1301                                 droptofloor(this);
1302                         waypoint_spawnforitem(this);
1303                 }
1304
1305                 /*
1306                  * can't do it that way, as it would break maps
1307                  * TODO make a target_give like entity another way, that perhaps has
1308                  * the weapon name in a key
1309                 if(this.targetname)
1310                 {
1311                         // target_give not yet supported; maybe later
1312                         print("removed targeted ", this.classname, "\n");
1313                         startitem_failed = true;
1314                         delete(this);
1315                         return;
1316                 }
1317                 */
1318
1319                 if(this.targetname != "" && (this.spawnflags & 16))
1320                         this.use = item_use;
1321
1322                 if(autocvar_spawn_debug >= 2)
1323                 {
1324             // why not flags & fl_item?
1325                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1326                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1327                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1328                 error("Mapper sucks.");
1329             });
1330                         this.is_item = true;
1331                 }
1332
1333                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1334
1335                 precache_model(this.model);
1336                 precache_sound(this.item_pickupsound);
1337
1338                 if (   def.instanceOfPowerup
1339                         || def.instanceOfWeaponPickup
1340                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1341                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1342                         || (itemid & (IT_KEY1 | IT_KEY2))
1343                 ) this.target = "###item###"; // for finding the nearest item using find()
1344
1345                 Item_ItemsTime_SetTime(this, 0);
1346         }
1347
1348         this.bot_pickup = true;
1349         this.bot_pickupevalfunc = pickupevalfunc;
1350         this.bot_pickupbasevalue = pickupbasevalue;
1351         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1352         this.netname = itemname;
1353         settouch(this, Item_Touch);
1354         setmodel(this, MDL_Null); // precision set below
1355         //this.effects |= EF_LOWPRECISION;
1356
1357         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1358
1359         this.SendFlags |= ISF_SIZE;
1360
1361         if (!(this.spawnflags & 1024)) {
1362                 if(def.instanceOfPowerup)
1363                         this.ItemStatus |= ITS_ANIMATE1;
1364
1365                 if(this.armorvalue || this.health)
1366                         this.ItemStatus |= ITS_ANIMATE2;
1367         }
1368
1369         if(def.instanceOfWeaponPickup)
1370         {
1371                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1372                         this.colormap = 1024; // color shirt=0 pants=0 grey
1373                 else
1374                         this.gravity = 1;
1375                 if (!(this.spawnflags & 1024))
1376                         this.ItemStatus |= ITS_ANIMATE1;
1377                 this.SendFlags |= ISF_COLORMAP;
1378         }
1379
1380         this.state = 0;
1381         if(this.team) // broken, no idea why.
1382         {
1383                 if(!this.cnt)
1384                         this.cnt = 1; // item probability weight
1385
1386                 this.effects |= EF_NODRAW; // marker for item team search
1387                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1388         }
1389         else
1390                 Item_Reset(this);
1391
1392         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1393
1394         // call this hook after everything else has been done
1395         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1396         {
1397                 startitem_failed = true;
1398                 delete(this);
1399                 return;
1400         }
1401
1402         setItemGroup(this);
1403 }
1404
1405 void StartItem(entity this, GameItem def)
1406 {
1407     _StartItem(
1408         this,
1409         this.itemdef = def,
1410         def.m_respawntime(), // defaultrespawntime
1411         def.m_respawntimejitter() // defaultrespawntimejitter
1412         );
1413 }
1414
1415 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1416 int group_count = 1;
1417
1418 void setItemGroup(entity this)
1419 {
1420         if(!IS_SMALL(this.itemdef))
1421                 return;
1422
1423         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1424         {
1425                 if(!this.item_group)
1426                 {
1427                         if(!it.item_group)
1428                         {
1429                                 it.item_group = group_count;
1430                                 group_count++;
1431                         }
1432                         this.item_group = it.item_group;
1433                 }
1434                 else // spawning item is already part of a item_group X
1435                 {
1436                         if(!it.item_group)
1437                                 it.item_group = this.item_group;
1438                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1439                         {
1440                                 int grY = it.item_group;
1441                                 // move all items of item_group Y to item_group X
1442                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1443                                 {
1444                                         if(it.item_group == grY)
1445                                                 it.item_group = this.item_group;
1446                                 });
1447                         }
1448                 }
1449         });
1450 }
1451
1452 void setItemGroupCount()
1453 {
1454         for (int k = 1; k <= group_count; k++)
1455         {
1456                 int count = 0;
1457                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1458                 if (count)
1459                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1460         }
1461 }
1462
1463 spawnfunc(item_rockets)
1464 {
1465     StartItem(this, ITEM_Rockets);
1466 }
1467
1468 spawnfunc(item_bullets)
1469 {
1470         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1471            (this.classname != "droppedweapon"))
1472         {
1473                 weaponswapping = true;
1474                 spawnfunc_item_shells(this);
1475                 weaponswapping = false;
1476                 return;
1477         }
1478
1479     StartItem(this, ITEM_Bullets);
1480 }
1481
1482 spawnfunc(item_cells)
1483 {
1484         StartItem(this, ITEM_Cells);
1485 }
1486
1487 spawnfunc(item_plasma)
1488 {
1489         StartItem(this, ITEM_Plasma);
1490 }
1491
1492 spawnfunc(item_shells)
1493 {
1494         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1495            (this.classname != "droppedweapon"))
1496         {
1497                 weaponswapping = true;
1498                 spawnfunc_item_bullets(this);
1499                 weaponswapping = false;
1500                 return;
1501         }
1502
1503         StartItem(this, ITEM_Shells);
1504 }
1505
1506 spawnfunc(item_armor_small)
1507 {
1508         StartItem(this, ITEM_ArmorSmall);
1509 }
1510
1511 spawnfunc(item_armor_medium)
1512 {
1513         StartItem(this, ITEM_ArmorMedium);
1514 }
1515
1516 spawnfunc(item_armor_big)
1517 {
1518         StartItem(this, ITEM_ArmorBig);
1519 }
1520
1521 spawnfunc(item_armor_mega)
1522 {
1523         StartItem(this, ITEM_ArmorMega);
1524 }
1525
1526 spawnfunc(item_health_small)
1527 {
1528         StartItem(this, ITEM_HealthSmall);
1529 }
1530
1531 spawnfunc(item_health_medium)
1532 {
1533     StartItem(this, ITEM_HealthMedium);
1534 }
1535
1536 spawnfunc(item_health_big)
1537 {
1538         StartItem(this, ITEM_HealthBig);
1539 }
1540
1541 spawnfunc(item_health_mega)
1542 {
1543     StartItem(this, ITEM_HealthMega);
1544 }
1545
1546 // support old misnamed entities
1547 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1548 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1549 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1550 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1551 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1552 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1553 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1554
1555 spawnfunc(item_strength)
1556 {
1557         StartItem(this, ITEM_Strength);
1558 }
1559
1560 spawnfunc(item_invincible)
1561 {
1562         StartItem(this, ITEM_Shield);
1563 }
1564
1565 // compatibility:
1566 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1567
1568 void target_items_use(entity this, entity actor, entity trigger)
1569 {
1570         if(actor.classname == "droppedweapon")
1571         {
1572                 EXACTTRIGGER_TOUCH(this, trigger);
1573                 delete(actor);
1574                 return;
1575         }
1576
1577         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1578                 return;
1579
1580         if(trigger.solid == SOLID_TRIGGER)
1581         {
1582                 EXACTTRIGGER_TOUCH(this, trigger);
1583         }
1584
1585         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1586         {
1587                 delete(it);
1588         });
1589
1590         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1591                 centerprint(actor, this.message);
1592 }
1593
1594 spawnfunc(target_items)
1595 {
1596         int n;
1597         string s;
1598
1599         this.use = target_items_use;
1600         if(!this.strength_finished)
1601                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1602         if(!this.invincible_finished)
1603                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1604         if(!this.superweapons_finished)
1605                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1606
1607         n = tokenize_console(this.netname);
1608         if(argv(0) == "give")
1609         {
1610                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1611         }
1612         else
1613         {
1614                 for(int j = 0; j < n; ++j)
1615                 {
1616                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1617                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1618                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1619                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1620                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1621                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1622                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1623                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1624                         else
1625                         {
1626                                 FOREACH(Buffs, it != BUFF_Null,
1627                                 {
1628                                         s = Buff_UndeprecateName(argv(j));
1629                                         if(s == it.m_name)
1630                                         {
1631                                                 this.buffs |= (it.m_itemid);
1632                                                 break;
1633                                         }
1634                                 });
1635                                 FOREACH(Weapons, it != WEP_Null, {
1636                                         s = W_UndeprecateName(argv(j));
1637                                         if(s == it.netname)
1638                                         {
1639                                                 this.weapons |= (it.m_wepset);
1640                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1641                                                         it.wr_init(it);
1642                                                 break;
1643                                         }
1644                                 });
1645                         }
1646                 }
1647
1648                 string itemprefix, valueprefix;
1649                 if(this.spawnflags == 0)
1650                 {
1651                         itemprefix = "";
1652                         valueprefix = "";
1653                 }
1654                 else if(this.spawnflags == 1)
1655                 {
1656                         itemprefix = "max ";
1657                         valueprefix = "max ";
1658                 }
1659                 else if(this.spawnflags == 2)
1660                 {
1661                         itemprefix = "min ";
1662                         valueprefix = "min ";
1663                 }
1664                 else if(this.spawnflags == 4)
1665                 {
1666                         itemprefix = "minus ";
1667                         valueprefix = "max ";
1668                 }
1669                 else
1670                 {
1671                         error("invalid spawnflags");
1672                         itemprefix = valueprefix = string_null;
1673                 }
1674
1675                 this.netname = "";
1676                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1677                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1678                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1679                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1680                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1681                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1682                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1683                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1684                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1685                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1686                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1687                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1688                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1689                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1690                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1691                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1692                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1693         }
1694         this.netname = strzone(this.netname);
1695         //print(this.netname, "\n");
1696
1697         n = tokenize_console(this.netname);
1698         for(int j = 0; j < n; ++j)
1699         {
1700                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1701             it.wr_init(it);
1702             break;
1703                 });
1704         }
1705 }
1706
1707 spawnfunc(item_fuel)
1708 {
1709         StartItem(this, ITEM_JetpackFuel);
1710 }
1711
1712 spawnfunc(item_fuel_regen)
1713 {
1714         if(start_items & ITEM_JetpackRegen.m_itemid)
1715         {
1716                 spawnfunc_item_fuel(this);
1717                 return;
1718         }
1719         StartItem(this, ITEM_JetpackRegen);
1720 }
1721
1722 spawnfunc(item_jetpack)
1723 {
1724         if(start_items & ITEM_Jetpack.m_itemid)
1725         {
1726                 spawnfunc_item_fuel(this);
1727                 return;
1728         }
1729         StartItem(this, ITEM_Jetpack);
1730 }
1731
1732 float GiveWeapon(entity e, float wpn, float op, float val)
1733 {
1734         WepSet v0, v1;
1735         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1736         v0 = (e.weapons & s);
1737         switch(op)
1738         {
1739                 case OP_SET:
1740                         if(val > 0)
1741                                 e.weapons |= s;
1742                         else
1743                                 e.weapons &= ~s;
1744                         break;
1745                 case OP_MIN:
1746                 case OP_PLUS:
1747                         if(val > 0)
1748                                 e.weapons |= s;
1749                         break;
1750                 case OP_MAX:
1751                         if(val <= 0)
1752                                 e.weapons &= ~s;
1753                         break;
1754                 case OP_MINUS:
1755                         if(val > 0)
1756                                 e.weapons &= ~s;
1757                         break;
1758         }
1759         v1 = (e.weapons & s);
1760         return (v0 != v1);
1761 }
1762
1763 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1764 {
1765         bool had_buff = (e.buffs & thebuff.m_itemid);
1766         switch(op)
1767         {
1768                 case OP_SET:
1769                         if(val > 0)
1770                                 e.buffs |= thebuff.m_itemid;
1771                         else
1772                                 e.buffs &= ~thebuff.m_itemid;
1773                         break;
1774                 case OP_MIN:
1775                 case OP_PLUS:
1776                         if(val > 0)
1777                                 e.buffs |= thebuff.m_itemid;
1778                         break;
1779                 case OP_MAX:
1780                         if(val <= 0)
1781                                 e.buffs &= ~thebuff.m_itemid;
1782                         break;
1783                 case OP_MINUS:
1784                         if(val > 0)
1785                                 e.buffs &= ~thebuff.m_itemid;
1786                         break;
1787         }
1788         bool have_buff = (e.buffs & thebuff.m_itemid);
1789         return (had_buff != have_buff);
1790 }
1791
1792 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1793 {
1794         if(v1 == v0)
1795                 return;
1796         if(v1 <= v0 - t)
1797         {
1798                 if(snd_decr != NULL)
1799                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1800         }
1801         else if(v0 >= v0 + t)
1802         {
1803                 if(snd_incr != NULL)
1804                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1805         }
1806 }
1807
1808 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1809 {
1810         if(v0 < v1)
1811                 e.(rotfield) = max(e.(rotfield), time + rottime);
1812         else if(v0 > v1)
1813                 e.(regenfield) = max(e.(regenfield), time + regentime);
1814 }
1815 float GiveItems(entity e, float beginarg, float endarg)
1816 {
1817         float got, i, val, op;
1818         string cmd;
1819
1820         val = 999;
1821         op = OP_SET;
1822
1823         got = 0;
1824
1825         int _switchweapon = 0;
1826
1827         if(CS(e).autoswitch)
1828         {
1829                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1830                 {
1831                         .entity weaponentity = weaponentities[slot];
1832                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1833                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1834                                 _switchweapon |= BIT(slot);
1835                 }
1836         }
1837
1838         e.strength_finished = max(0, e.strength_finished - time);
1839         e.invincible_finished = max(0, e.invincible_finished - time);
1840         e.superweapons_finished = max(0, e.superweapons_finished - time);
1841
1842         PREGIVE(e, items);
1843         PREGIVE_WEAPONS(e);
1844         PREGIVE(e, strength_finished);
1845         PREGIVE(e, invincible_finished);
1846         PREGIVE(e, superweapons_finished);
1847         PREGIVE(e, ammo_nails);
1848         PREGIVE(e, ammo_cells);
1849         PREGIVE(e, ammo_plasma);
1850         PREGIVE(e, ammo_shells);
1851         PREGIVE(e, ammo_rockets);
1852         PREGIVE(e, ammo_fuel);
1853         PREGIVE(e, armorvalue);
1854         PREGIVE(e, health);
1855
1856         for(i = beginarg; i < endarg; ++i)
1857         {
1858                 cmd = argv(i);
1859
1860                 if(cmd == "0" || stof(cmd))
1861                 {
1862                         val = stof(cmd);
1863                         continue;
1864                 }
1865                 switch(cmd)
1866                 {
1867                         case "no":
1868                                 op = OP_MAX;
1869                                 val = 0;
1870                                 continue;
1871                         case "max":
1872                                 op = OP_MAX;
1873                                 continue;
1874                         case "min":
1875                                 op = OP_MIN;
1876                                 continue;
1877                         case "plus":
1878                                 op = OP_PLUS;
1879                                 continue;
1880                         case "minus":
1881                                 op = OP_MINUS;
1882                                 continue;
1883                         case "ALL":
1884                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1885                                 got += GiveValue(e, strength_finished, op, val);
1886                                 got += GiveValue(e, invincible_finished, op, val);
1887                                 got += GiveValue(e, superweapons_finished, op, val);
1888                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1889                         case "all":
1890                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1891                                 got += GiveValue(e, health, op, val);
1892                                 got += GiveValue(e, armorvalue, op, val);
1893                         case "allweapons":
1894                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1895                         //case "allbuffs": // all buffs makes a player god, do not want!
1896                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1897                         case "allammo":
1898                                 got += GiveValue(e, ammo_cells, op, val);
1899                                 got += GiveValue(e, ammo_plasma, op, val);
1900                                 got += GiveValue(e, ammo_shells, op, val);
1901                                 got += GiveValue(e, ammo_nails, op, val);
1902                                 got += GiveValue(e, ammo_rockets, op, val);
1903                                 got += GiveValue(e, ammo_fuel, op, val);
1904                                 break;
1905                         case "unlimited_ammo":
1906                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1907                                 break;
1908                         case "unlimited_weapon_ammo":
1909                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1910                                 break;
1911                         case "unlimited_superweapons":
1912                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1913                                 break;
1914                         case "jetpack":
1915                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1916                                 break;
1917                         case "fuel_regen":
1918                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1919                                 break;
1920                         case "strength":
1921                                 got += GiveValue(e, strength_finished, op, val);
1922                                 break;
1923                         case "invincible":
1924                                 got += GiveValue(e, invincible_finished, op, val);
1925                                 break;
1926                         case "superweapons":
1927                                 got += GiveValue(e, superweapons_finished, op, val);
1928                                 break;
1929                         case "cells":
1930                                 got += GiveValue(e, ammo_cells, op, val);
1931                                 break;
1932                         case "plasma":
1933                                 got += GiveValue(e, ammo_plasma, op, val);
1934                                 break;
1935                         case "shells":
1936                                 got += GiveValue(e, ammo_shells, op, val);
1937                                 break;
1938                         case "nails":
1939                         case "bullets":
1940                                 got += GiveValue(e, ammo_nails, op, val);
1941                                 break;
1942                         case "rockets":
1943                                 got += GiveValue(e, ammo_rockets, op, val);
1944                                 break;
1945                         case "health":
1946                                 got += GiveValue(e, health, op, val);
1947                                 break;
1948                         case "armor":
1949                                 got += GiveValue(e, armorvalue, op, val);
1950                                 break;
1951                         case "fuel":
1952                                 got += GiveValue(e, ammo_fuel, op, val);
1953                                 break;
1954                         default:
1955                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1956                                 {
1957                                         got += GiveBuff(e, it, op, val);
1958                                         break;
1959                                 });
1960                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1961                     got += GiveWeapon(e, it.m_id, op, val);
1962                     break;
1963                                 });
1964                                 break;
1965                 }
1966                 val = 999;
1967                 op = OP_SET;
1968         }
1969
1970         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1971         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1972         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1973         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1974         FOREACH(Weapons, it != WEP_Null, {
1975                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1976                 if(!(save_weapons & (it.m_wepset)))
1977                         if(e.weapons & (it.m_wepset))
1978                                 it.wr_init(it);
1979         });
1980         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1981         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1982         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1983         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1984         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1985         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1986         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1987         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1988         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1989         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1990         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1991
1992         if(e.superweapons_finished <= 0)
1993                 if(e.weapons & WEPSET_SUPERWEAPONS)
1994                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1995
1996         if(e.strength_finished <= 0)
1997                 e.strength_finished = 0;
1998         else
1999                 e.strength_finished += time;
2000         if(e.invincible_finished <= 0)
2001                 e.invincible_finished = 0;
2002         else
2003                 e.invincible_finished += time;
2004         if(e.superweapons_finished <= 0)
2005                 e.superweapons_finished = 0;
2006         else
2007                 e.superweapons_finished += time;
2008
2009         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2010         {
2011                 .entity weaponentity = weaponentities[slot];
2012                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2013                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2014                         _switchweapon |= BIT(slot);
2015         }
2016
2017         if(_switchweapon)
2018         {
2019                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2020                 {
2021                         .entity weaponentity = weaponentities[slot];
2022                         if(_switchweapon & BIT(slot))
2023                         {
2024                                 Weapon wep = w_getbestweapon(e, weaponentity);
2025                                 if(wep != e.(weaponentity).m_switchweapon)
2026                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2027                         }
2028                 }
2029         }
2030
2031         return got;
2032 }
2033 #endif