qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/bot.qh"
   8     #include "../server/bot/waypoints.qh"
   9
  10     #include <server/mutators/all.qh>
  11
  12     #include "../server/weapons/common.qh"
  13     #include "../server/weapons/selection.qh"
  14     #include "../server/weapons/weaponsystem.qh"
  15
  16     #include "constants.qh"
  17     #include <common/deathtypes/all.qh>
  18     #include <common/notifications/all.qh>
  19         #include "triggers/subs.qh"
  20     #include "util.qh"
  21
  22     #include <common/monsters/all.qh>
  23
  24     #include <common/weapons/all.qh>
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #elif defined(CSQC)
  28         #include "physics/movetypes/movetypes.qh"
  29         #include <common/weapons/all.qh>
  30         #include "../lib/csqcmodel/cl_model.qh"
  31         #include "../lib/csqcmodel/common.qh"
  32 #endif
  33
  34 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  35
  36 #ifdef CSQC
  37 bool autocvar_cl_ghost_items_vehicle = true;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = this.glowmod = '1 1 1';
  46         }
  47         else
  48         {
  49                 if (autocvar_cl_ghost_items_color)
  50                 {
  51                         this.alpha = autocvar_cl_ghost_items;
  52                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  53                 }
  54                 else
  55                         this.alpha = -1;
  56         }
  57
  58         if(!veh_hud)
  59         if(this.ItemStatus & ITS_STAYWEP)
  60         {
  61                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  62                 this.alpha = autocvar_cl_weapon_stay_alpha;
  63         }
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(this.move_flags & FL_ONGROUND)
  72         { // For some reason move_avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.move_avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.move_avelocity = '0 -90 0';
  83             }
  84         }
  85     }
  86     else if (autocvar_cl_animate_items)
  87     {
  88         if(this.ItemStatus & ITS_ANIMATE1)
  89         {
  90             this.angles += this.move_avelocity * frametime;
  91             setorigin(this, '0 0 10' + this.oldorigin + '0 0 8' * sin(time * 2));
  92         }
  93
  94         if(this.ItemStatus & ITS_ANIMATE2)
  95         {
  96             this.angles += this.move_avelocity * frametime;
  97             setorigin(this, '0 0 8' + this.oldorigin + '0 0 4' * sin(time * 3));
  98         }
  99     }
 100
 101     Item_SetAlpha(this);
 102 }
 103
 104 void ItemDrawSimple(entity this)
 105 {
 106     if(this.gravity)
 107     {
 108         Movetype_Physics_MatchServer(this, false);
 109
 110         if(this.move_flags & FL_ONGROUND)
 111             this.gravity = 0;
 112     }
 113
 114     Item_SetAlpha(this);
 115 }
 116
 117 void Item_PreDraw(entity this)
 118 {
 119         if(warpzone_warpzones_exist)
 120         {
 121                 // just incase warpzones were initialized last, reset these
 122                 //this.alpha = 1; // alpha is already set by the draw function
 123                 this.drawmask = MASK_NORMAL;
 124                 return;
 125         }
 126         float alph;
 127         vector org = getpropertyvec(VF_ORIGIN);
 128         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 129                 alph = 0;
 130         else if(this.fade_start)
 131                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         else
 133                 alph = 1;
 134         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 135         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 136                 this.alpha = alph;
 137         if(alph <= 0)
 138                 this.drawmask = 0;
 139         else
 140                 this.drawmask = MASK_NORMAL;
 141 }
 142
 143 void ItemRemove(entity this)
 144 {
 145         if(this.mdl)
 146                 strunzone(this.mdl);
 147 }
 148
 149 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 150 {
 151     int sf = ReadByte();
 152
 153     if(sf & ISF_LOCATION)
 154     {
 155         this.origin_x = ReadCoord();
 156         this.origin_y = ReadCoord();
 157         this.origin_z = ReadCoord();
 158         setorigin(this, this.origin);
 159         this.oldorigin = this.origin;
 160     }
 161
 162     if(sf & ISF_ANGLES)
 163     {
 164         this.angles_x = ReadAngle();
 165         this.angles_y = ReadAngle();
 166         this.angles_z = ReadAngle();
 167         this.move_angles = this.angles;
 168     }
 169
 170     if(sf & ISF_SIZE)
 171     {
 172         float use_bigsize = ReadByte();
 173         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 174     }
 175
 176     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 177     {
 178         this.ItemStatus = ReadByte();
 179
 180         Item_SetAlpha(this);
 181
 182         if(autocvar_cl_fullbright_items)
 183             if(this.ItemStatus & ITS_ALLOWFB)
 184                 this.effects |= EF_FULLBRIGHT;
 185
 186         if(this.ItemStatus & ITS_POWERUP)
 187         {
 188             if(this.ItemStatus & ITS_AVAILABLE)
 189                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 190             else
 191                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 192         }
 193     }
 194
 195     if(sf & ISF_MODEL)
 196     {
 197         this.drawmask  = MASK_NORMAL;
 198                 this.move_movetype = MOVETYPE_TOSS;
 199         this.draw       = ItemDraw;
 200         this.solid = SOLID_TRIGGER;
 201         //this.move_flags |= FL_ITEM;
 202
 203         bool use_bigsize = ReadByte();
 204
 205         this.fade_end = ReadShort();
 206         this.fade_start = ReadShort();
 207         if(this.fade_start && !autocvar_cl_items_nofade)
 208                 setpredraw(this, Item_PreDraw);
 209
 210         if(this.mdl)
 211             strunzone(this.mdl);
 212
 213         this.mdl = "";
 214         string _fn = ReadString();
 215
 216         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 217         {
 218             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 219             this.draw = ItemDrawSimple;
 220
 221             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 222                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 223             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 224                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 225             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 226                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 227             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 228                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 229             else
 230             {
 231                 this.draw = ItemDraw;
 232                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 233             }
 234         }
 235
 236         if(this.draw != ItemDrawSimple)
 237             this.mdl = strzone(_fn);
 238
 239
 240         if(this.mdl == "")
 241             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!\n");
 242
 243         precache_model(this.mdl);
 244         _setmodel(this, this.mdl);
 245
 246         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 247     }
 248
 249     if(sf & ISF_COLORMAP)
 250         this.colormap = ReadShort();
 251
 252     if(sf & ISF_DROP)
 253     {
 254         this.gravity = 1;
 255         this.pushable = true;
 256         //this.move_angles = '0 0 0';
 257         this.move_movetype = MOVETYPE_TOSS;
 258         this.move_velocity_x = ReadCoord();
 259         this.move_velocity_y = ReadCoord();
 260         this.move_velocity_z = ReadCoord();
 261         this.velocity = this.move_velocity;
 262         this.move_origin = this.oldorigin;
 263
 264         if(!this.move_time)
 265         {
 266             this.move_time = time;
 267             this.spawntime = time;
 268         }
 269         else
 270             this.move_time = max(this.move_time, time);
 271     }
 272
 273     if(autocvar_cl_animate_items)
 274     {
 275         if(this.ItemStatus & ITS_ANIMATE1)
 276             this.move_avelocity = '0 180 0';
 277
 278         if(this.ItemStatus & ITS_ANIMATE2)
 279             this.move_avelocity = '0 -90 0';
 280     }
 281
 282     this.entremove = ItemRemove;
 283
 284     return true;
 285 }
 286
 287 #endif
 288
 289 #ifdef SVQC
 290 bool ItemSend(entity this, entity to, int sf)
 291 {
 292         if(this.gravity)
 293                 sf |= ISF_DROP;
 294         else
 295                 sf &= ~ISF_DROP;
 296
 297         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 298         WriteByte(MSG_ENTITY, sf);
 299
 300         //WriteByte(MSG_ENTITY, this.cnt);
 301         if(sf & ISF_LOCATION)
 302         {
 303                 WriteCoord(MSG_ENTITY, this.origin.x);
 304                 WriteCoord(MSG_ENTITY, this.origin.y);
 305                 WriteCoord(MSG_ENTITY, this.origin.z);
 306         }
 307
 308         if(sf & ISF_ANGLES)
 309         {
 310                 WriteAngle(MSG_ENTITY, this.angles_x);
 311                 WriteAngle(MSG_ENTITY, this.angles_y);
 312                 WriteAngle(MSG_ENTITY, this.angles_z);
 313         }
 314
 315         if(sf & ISF_SIZE)
 316         {
 317                 Pickup p = this.itemdef;
 318                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 319         }
 320
 321         if(sf & ISF_STATUS)
 322                 WriteByte(MSG_ENTITY, this.ItemStatus);
 323
 324         if(sf & ISF_MODEL)
 325         {
 326                 Pickup p = this.itemdef;
 327                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 328                 WriteShort(MSG_ENTITY, this.fade_end);
 329                 WriteShort(MSG_ENTITY, this.fade_start);
 330
 331                 if(this.mdl == "")
 332                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "exspect a crash just aboute now\n");
 333
 334                 WriteString(MSG_ENTITY, this.mdl);
 335         }
 336
 337
 338         if(sf & ISF_COLORMAP)
 339                 WriteShort(MSG_ENTITY, this.colormap);
 340
 341         if(sf & ISF_DROP)
 342         {
 343                 WriteCoord(MSG_ENTITY, this.velocity.x);
 344                 WriteCoord(MSG_ENTITY, this.velocity.y);
 345                 WriteCoord(MSG_ENTITY, this.velocity.z);
 346         }
 347
 348         return true;
 349 }
 350
 351 void ItemUpdate(entity this)
 352 {
 353         this.oldorigin = this.origin;
 354         this.SendFlags |= ISF_LOCATION;
 355 }
 356
 357 void UpdateItemAfterTeleport(entity this)
 358 {
 359         if(getSendEntity(this) == ItemSend)
 360                 ItemUpdate(this);
 361 }
 362
 363 bool have_pickup_item(entity this)
 364 {
 365         if(this.itemdef.instanceOfPowerup)
 366         {
 367                 if(autocvar_g_powerups > 0)
 368                         return true;
 369                 if(autocvar_g_powerups == 0)
 370                         return false;
 371         }
 372         else
 373         {
 374                 if(autocvar_g_pickup_items > 0)
 375                         return true;
 376                 if(autocvar_g_pickup_items == 0)
 377                         return false;
 378                 if(g_weaponarena)
 379                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 380                                 return false;
 381         }
 382         return true;
 383 }
 384
 385 /*
 386 float Item_Customize()
 387 {
 388         if(this.spawnshieldtime)
 389                 return true;
 390         if(this.weapons & ~other.weapons)
 391         {
 392                 this.colormod = '0 0 0';
 393                 this.glowmod = this.colormod;
 394                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 395                 return true;
 396         }
 397         else
 398         {
 399                 if(g_ghost_items)
 400                 {
 401                         this.colormod = stov(autocvar_g_ghost_items_color);
 402                         this.glowmod = this.colormod;
 403                         this.alpha = g_ghost_items;
 404                         return true;
 405                 }
 406                 else
 407                         return false;
 408         }
 409 }
 410 */
 411
 412 void Item_Show (entity e, float mode)
 413 {
 414         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 415         e.ItemStatus &= ~ITS_STAYWEP;
 416         if (mode > 0)
 417         {
 418                 // make the item look normal, and be touchable
 419                 e.model = e.mdl;
 420                 e.solid = SOLID_TRIGGER;
 421                 e.spawnshieldtime = 1;
 422                 e.ItemStatus |= ITS_AVAILABLE;
 423         }
 424         else if (mode < 0)
 425         {
 426                 // hide the item completely
 427                 e.model = string_null;
 428                 e.solid = SOLID_NOT;
 429                 e.spawnshieldtime = 1;
 430                 e.ItemStatus &= ~ITS_AVAILABLE;
 431         }
 432         else {
 433         entity def = e.itemdef;
 434         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 435                 || e.team // weapon stay isn't supported for teamed weapons
 436                 ;
 437         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 438         {
 439                 // make the item translucent and not touchable
 440                 e.model = e.mdl;
 441                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 442                 e.effects |= EF_STARDUST;
 443                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 444                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 445         }
 446         else
 447         {
 448                 //setmodel(e, "null");
 449                 e.solid = SOLID_NOT;
 450                 e.colormod = '0 0 0';
 451                 e.glowmod = e.colormod;
 452                 e.spawnshieldtime = 1;
 453                 e.ItemStatus &= ~ITS_AVAILABLE;
 454         }}
 455
 456         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 457                 e.ItemStatus |= ITS_POWERUP;
 458
 459         if (autocvar_g_nodepthtestitems)
 460                 e.effects |= EF_NODEPTHTEST;
 461
 462
 463         if (autocvar_g_fullbrightitems)
 464                 e.ItemStatus |= ITS_ALLOWFB;
 465
 466         if (autocvar_sv_simple_items)
 467                 e.ItemStatus |= ITS_ALLOWSI;
 468
 469         // relink entity (because solid may have changed)
 470         setorigin(e, e.origin);
 471         e.SendFlags |= ISF_STATUS;
 472 }
 473
 474 void Item_Think(entity this)
 475 {
 476         this.nextthink = time;
 477         if(this.origin != this.oldorigin)
 478                 ItemUpdate(this);
 479 }
 480
 481 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 482 bool Item_ItemsTime_Allow(GameItem it);
 483 float Item_ItemsTime_UpdateTime(entity e, float t);
 484 void Item_ItemsTime_SetTime(entity e, float t);
 485 void Item_ItemsTime_SetTimesForAllPlayers();
 486
 487 void Item_Respawn (entity this)
 488 {
 489         Item_Show(this, 1);
 490         // this is ugly...
 491         if(this.items == ITEM_Strength.m_itemid)
 492                 sound (this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 493         else if(this.items == ITEM_Shield.m_itemid)
 494                 sound (this, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 495         else
 496                 sound (this, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 497         setorigin (this, this.origin);
 498
 499     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 500         {
 501                 float t = Item_ItemsTime_UpdateTime(this, 0);
 502                 Item_ItemsTime_SetTime(this, t);
 503                 Item_ItemsTime_SetTimesForAllPlayers();
 504         }
 505
 506         setthink(this, Item_Think);
 507         this.nextthink = time;
 508
 509         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 510         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 511 }
 512
 513 void Item_RespawnCountdown (entity this)
 514 {
 515         if(this.count >= ITEM_RESPAWN_TICKS)
 516         {
 517                 if(this.waypointsprite_attached)
 518                         WaypointSprite_Kill(this.waypointsprite_attached);
 519                 Item_Respawn(this);
 520         }
 521         else
 522         {
 523                 this.nextthink = time + 1;
 524                 this.count += 1;
 525                 if(this.count == 1)
 526                 {
 527                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 528                         do {
 529                                 {
 530                                         entity wi = Weapons_from(this.weapon);
 531                                         if (wi != WEP_Null) {
 532                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', world, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 533                                                 wp.wp_extra = wi.m_id;
 534                                                 break;
 535                                         }
 536                                 }
 537                                 {
 538                                         entity ii = this.itemdef;
 539                                         if (ii != NULL) {
 540                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', world, 0, this, waypointsprite_attached, true, RADARICON_Item);
 541                                                 wp.wp_extra = ii.m_id;
 542                                                 break;
 543                                         }
 544                                 }
 545                         } while (0);
 546             if(this.waypointsprite_attached)
 547             {
 548                 GameItem def = this.itemdef;
 549                 if (Item_ItemsTime_SpectatorOnly(def))
 550                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 551                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 552             }
 553                 }
 554
 555                 if(this.waypointsprite_attached)
 556                 {
 557                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 558                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 559                                 {
 560                                         msg_entity = it;
 561                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 562                                 }
 563                         });
 564
 565                         WaypointSprite_Ping(this.waypointsprite_attached);
 566                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 567                 }
 568         }
 569 }
 570
 571 void Item_RespawnThink(entity this)
 572 {
 573         this.nextthink = time;
 574         if(this.origin != this.oldorigin)
 575                 ItemUpdate(this);
 576
 577         if(time >= this.wait)
 578                 Item_Respawn(this);
 579 }
 580
 581 void Item_ScheduleRespawnIn(entity e, float t)
 582 {
 583         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 584         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 585         {
 586                 setthink(e, Item_RespawnCountdown);
 587                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 588                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 589                 e.count = 0;
 590                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 591                 Item_ItemsTime_SetTime(e, t);
 592                 Item_ItemsTime_SetTimesForAllPlayers();
 593         }
 594         else
 595         {
 596                 setthink(e, Item_RespawnThink);
 597                 e.nextthink = time;
 598                 e.scheduledrespawntime = time + t;
 599                 e.wait = time + t;
 600         }
 601 }
 602
 603 void Item_ScheduleRespawn(entity e)
 604 {
 605         if(e.respawntime > 0)
 606         {
 607                 Item_Show(e, 0);
 608                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 609         }
 610         else // if respawntime is -1, this item does not respawn
 611                 Item_Show(e, -1);
 612 }
 613
 614 void Item_ScheduleInitialRespawn(entity e)
 615 {
 616         Item_Show(e, 0);
 617         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 618 }
 619
 620 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 621 {
 622         if (!item.(ammotype))
 623                 return false;
 624
 625         if (item.spawnshieldtime)
 626         {
 627                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 628                 {
 629                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 630                         goto YEAH;
 631                 }
 632         }
 633         else if(g_weapon_stay == 2)
 634         {
 635                 float mi = min(item.(ammotype), ammomax);
 636                 if (player.(ammotype) < mi)
 637                 {
 638                         player.(ammotype) = mi;
 639                         goto YEAH;
 640                 }
 641         }
 642
 643         return false;
 644
 645 LABEL(YEAH)
 646         switch(mode)
 647         {
 648                 case ITEM_MODE_FUEL:
 649                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 650                         break;
 651                 case ITEM_MODE_HEALTH:
 652                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 653                         break;
 654                 case ITEM_MODE_ARMOR:
 655                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 656                         break;
 657                 default:
 658                         break;
 659         }
 660         return true;
 661 }
 662
 663 float Item_GiveTo(entity item, entity player)
 664 {
 665         float _switchweapon;
 666         float pickedup;
 667
 668         // if nothing happens to player, just return without taking the item
 669         pickedup = false;
 670         _switchweapon = false;
 671         // in case the player has autoswitch enabled do the following:
 672         // if the player is using their best weapon before items are given, they
 673         // probably want to switch to an even better weapon after items are given
 674         if (player.autoswitch)
 675         if (PS(player).m_switchweapon == w_getbestweapon(player))
 676                 _switchweapon = true;
 677
 678         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 679                 _switchweapon = true;
 680
 681         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 682         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 683         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 684         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 685         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 686         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 687         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 688         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 689
 690         if (item.itemdef.instanceOfWeaponPickup)
 691         {
 692                 WepSet w;
 693                 w = item.weapons;
 694                 w &= ~player.weapons;
 695
 696                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 697                 {
 698                         pickedup = true;
 699                         FOREACH(Weapons, it != WEP_Null, {
 700                                 if(w & (it.m_wepset))
 701                                 {
 702                                         W_DropEvent(wr_pickup, player, it.m_id, item);
 703                                         W_GiveWeapon(player, it.m_id);
 704                                 }
 705                         });
 706                 }
 707         }
 708
 709         if (item.itemdef.instanceOfPowerup)
 710         {
 711                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 712                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 713                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 714                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 715         }
 716
 717         int its;
 718         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 719         {
 720                 pickedup = true;
 721                 player.items |= its;
 722                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 723         }
 724
 725         if (item.strength_finished)
 726         {
 727                 pickedup = true;
 728                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 729         }
 730         if (item.invincible_finished)
 731         {
 732                 pickedup = true;
 733                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 734         }
 735         if (item.superweapons_finished)
 736         {
 737                 pickedup = true;
 738                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 739         }
 740
 741 LABEL(skip)
 742
 743         // always eat teamed entities
 744         if(item.team)
 745                 pickedup = true;
 746
 747         if (!pickedup)
 748                 return 0;
 749
 750         // crude hack to enforce switching weapons
 751         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 752         {
 753                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 754                 return 1;
 755         }
 756
 757         if (_switchweapon)
 758                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 759                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 760
 761         return 1;
 762 }
 763
 764 void Item_Touch(entity this)
 765 {
 766
 767         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 768         if (this.classname == "droppedweapon")
 769         {
 770                 if (ITEM_TOUCH_NEEDKILL())
 771                 {
 772                         remove(this);
 773                         return;
 774                 }
 775         }
 776
 777         if(!(other.flags & FL_PICKUPITEMS)
 778         || STAT(FROZEN, other)
 779         || IS_DEAD(other)
 780         || (this.solid != SOLID_TRIGGER)
 781         || (this.owner == other)
 782         || (time < this.item_spawnshieldtime)
 783         ) { return; }
 784
 785         switch (MUTATOR_CALLHOOK(ItemTouch, this, other))
 786         {
 787                 case MUT_ITEMTOUCH_RETURN: { return; }
 788                 case MUT_ITEMTOUCH_PICKUP: { other = M_ARGV(1, entity); goto pickup; }
 789         }
 790
 791         other = M_ARGV(1, entity);
 792
 793         if (this.classname == "droppedweapon")
 794         {
 795                 this.strength_finished = max(0, this.strength_finished - time);
 796                 this.invincible_finished = max(0, this.invincible_finished - time);
 797                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 798         }
 799         entity it = this.itemdef;
 800         bool gave = ITEM_HANDLE(Pickup, it, this, other);
 801         if (!gave)
 802         {
 803                 if (this.classname == "droppedweapon")
 804                 {
 805                         // undo what we did above
 806                         this.strength_finished += time;
 807                         this.invincible_finished += time;
 808                         this.superweapons_finished += time;
 809                 }
 810                 return;
 811         }
 812
 813 LABEL(pickup)
 814
 815         other.last_pickup = time;
 816
 817         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 818         _sound (other, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 819
 820         if (this.classname == "droppedweapon")
 821                 remove (this);
 822         else if (this.spawnshieldtime)
 823         {
 824                 entity e;
 825                 if(this.team)
 826                 {
 827                         RandomSelection_Init();
 828                         for(entity head = world; (head = findfloat(head, team, this.team)); )
 829                         {
 830                                 if(head.flags & FL_ITEM)
 831                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 832                                 {
 833                                         Item_Show(head, -1);
 834                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 835                                 }
 836                         }
 837                         e = RandomSelection_chosen_ent;
 838
 839                 }
 840                 else
 841                         e = this;
 842                 Item_ScheduleRespawn(e);
 843         }
 844 }
 845
 846 void Item_Reset(entity this)
 847 {
 848         Item_Show(this, !this.state);
 849         setorigin(this, this.origin);
 850
 851         if (this.classname != "droppedweapon")
 852         {
 853                 setthink(this, Item_Think);
 854                 this.nextthink = time;
 855
 856                 if (this.waypointsprite_attached)
 857                         WaypointSprite_Kill(this.waypointsprite_attached);
 858
 859                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 860                         Item_ScheduleInitialRespawn(this);
 861         }
 862 }
 863
 864 void Item_FindTeam(entity this)
 865 {
 866         entity e;
 867
 868         if(this.effects & EF_NODRAW)
 869         {
 870                 // marker for item team search
 871                 LOG_TRACE("Initializing item team ", ftos(this.team), "\n");
 872                 RandomSelection_Init();
 873                 FOREACH_ENTITY_FLOAT(team, this.team,
 874                 {
 875                         if(it.flags & FL_ITEM)
 876                         if(it.classname != "item_flag_team" && it.classname != "item_key_team")
 877                                 RandomSelection_Add(it, 0, string_null, it.cnt, 0);
 878                 });
 879
 880                 e = RandomSelection_chosen_ent;
 881                 e.state = 0;
 882                 Item_Show(e, 1);
 883
 884                 FOREACH_ENTITY_FLOAT(team, this.team,
 885                 {
 886                         if(it.flags & FL_ITEM)
 887                         if(it.classname != "item_flag_team" && it.classname != "item_key_team")
 888                         {
 889                                 if(it != e)
 890                                 {
 891                                         // make it non-spawned
 892                                         Item_Show(it, -1);
 893                                         it.state = 1; // state 1 = initially hidden item, apparently
 894                                 }
 895                                 it.effects &= ~EF_NODRAW;
 896                         }
 897                 });
 898
 899                 Item_Reset(this);
 900         }
 901 }
 902
 903 // Savage: used for item garbage-collection
 904 void RemoveItem(entity this)
 905 {
 906         if(wasfreed(this) || !this) { return; }
 907         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 908         remove(this);
 909 }
 910
 911 // pickup evaluation functions
 912 // these functions decide how desirable an item is to the bots
 913
 914 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 915
 916 float weapon_pickupevalfunc(entity player, entity item)
 917 {
 918         float c;
 919
 920         // See if I have it already
 921         if(item.weapons & ~player.weapons)
 922         {
 923                 // If I can pick it up
 924                 if(!item.spawnshieldtime)
 925                         c = 0;
 926                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 927                 {
 928                         // Skilled bots will grab more
 929                         c = bound(0, skill / 10, 1) * 0.5;
 930                 }
 931                 else
 932                         c = 0;
 933         }
 934         else
 935                 c = 1;
 936
 937         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 938         if( bot_custom_weapon && c )
 939         {
 940                 // Find the highest position on any range
 941                 int position = -1;
 942                 for (int j = 0; j < WEP_LAST ; ++j){
 943                         if(
 944                                         bot_weapons_far[j] == item.weapon ||
 945                                         bot_weapons_mid[j] == item.weapon ||
 946                                         bot_weapons_close[j] == item.weapon
 947                           )
 948                         {
 949                                 position = j;
 950                                 break;
 951                         }
 952                 }
 953
 954                 // Rate it
 955                 if (position >= 0 )
 956                 {
 957                         position = WEP_LAST - position;
 958                         // item.bot_pickupbasevalue is overwritten here
 959                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 960                 }
 961         }
 962
 963         return item.bot_pickupbasevalue * c;
 964 }
 965
 966 float commodity_pickupevalfunc(entity player, entity item)
 967 {
 968         float c;
 969         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 970         c = 0;
 971
 972         // Detect needed ammo
 973         FOREACH(Weapons, it != WEP_Null, {
 974                 if(!(player.weapons & (it.m_wepset)))
 975                         continue;
 976
 977                 if(it.items & ITEM_Shells.m_itemid)
 978                         need_shells = true;
 979                 else if(it.items & ITEM_Bullets.m_itemid)
 980                         need_nails = true;
 981                 else if(it.items & ITEM_Rockets.m_itemid)
 982                         need_rockets = true;
 983                 else if(it.items & ITEM_Cells.m_itemid)
 984                         need_cells = true;
 985                 else if(it.items & ITEM_Plasma.m_itemid)
 986                         need_plasma = true;
 987                 else if(it.items & ITEM_JetpackFuel.m_itemid)
 988                         need_fuel = true;
 989         });
 990
 991         // TODO: figure out if the player even has the weapon this ammo is for?
 992         // may not affect strategy much though...
 993         // find out how much more ammo/armor/health the player can hold
 994         if (need_shells)
 995         if (item.ammo_shells)
 996         if (player.ammo_shells < g_pickup_shells_max)
 997                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 998         if (need_nails)
 999         if (item.ammo_nails)
1000         if (player.ammo_nails < g_pickup_nails_max)
1001                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1002         if (need_rockets)
1003         if (item.ammo_rockets)
1004         if (player.ammo_rockets < g_pickup_rockets_max)
1005                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1006         if (need_cells)
1007         if (item.ammo_cells)
1008         if (player.ammo_cells < g_pickup_cells_max)
1009                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1010         if (need_plasma)
1011         if (item.ammo_plasma)
1012         if (player.ammo_plasma < g_pickup_plasma_max)
1013                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1014         if (need_fuel)
1015         if (item.ammo_fuel)
1016         if (player.ammo_fuel < g_pickup_fuel_max)
1017                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1018         if (item.armorvalue)
1019         if (player.armorvalue < item.max_armorvalue)
1020                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1021         if (item.health)
1022         if (player.health < item.max_health)
1023                 c = c + max(0, 1 - player.health / item.max_health);
1024
1025         return item.bot_pickupbasevalue * c;
1026 }
1027
1028 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1029 {
1030         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1031                 RemoveItem(this);
1032 }
1033
1034 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1035 {
1036         string itemname = def.m_name;
1037         Model itemmodel = def.m_model;
1038     Sound pickupsound = def.m_sound;
1039         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1040         float pickupbasevalue = def.m_botvalue;
1041         int itemflags = def.m_itemflags;
1042
1043         startitem_failed = false;
1044
1045         this.item_model_ent = itemmodel;
1046     this.item_pickupsound_ent = pickupsound;
1047
1048         if(!this.respawntime) // both need to be set
1049         {
1050                 this.respawntime = defaultrespawntime;
1051                 this.respawntimejitter = defaultrespawntimejitter;
1052         }
1053
1054         int itemid = def.m_itemid;
1055         this.items = itemid;
1056         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1057         this.weapon = weaponid;
1058
1059         if(!this.fade_end)
1060         {
1061                 this.fade_start = autocvar_g_items_mindist;
1062                 this.fade_end = autocvar_g_items_maxdist;
1063         }
1064
1065         if(weaponid)
1066                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1067
1068         this.flags = FL_ITEM | itemflags;
1069
1070         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1071         {
1072                 startitem_failed = true;
1073                 remove(this);
1074                 return;
1075         }
1076
1077         // is it a dropped weapon?
1078         if (this.classname == "droppedweapon")
1079         {
1080                 this.reset = SUB_Remove;
1081                 // it's a dropped weapon
1082                 this.movetype = MOVETYPE_TOSS;
1083
1084                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1085                 setthink(this, RemoveItem);
1086                 this.nextthink = time + 20;
1087
1088                 this.takedamage = DAMAGE_YES;
1089                 this.event_damage = Item_Damage;
1090
1091                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1092                 {
1093                         // if item is worthless after a timer, have it expire then
1094                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1095                 }
1096
1097                 // don't drop if in a NODROP zone (such as lava)
1098                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1099                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1100                 {
1101                         startitem_failed = true;
1102                         remove(this);
1103                         return;
1104                 }
1105         }
1106         else
1107         {
1108                 if(!have_pickup_item(this))
1109                 {
1110                         startitem_failed = true;
1111                         remove (this);
1112                         return;
1113                 }
1114
1115                 if(this.angles != '0 0 0')
1116                         this.SendFlags |= ISF_ANGLES;
1117
1118                 this.reset = Item_Reset;
1119                 // it's a level item
1120                 if(this.spawnflags & 1)
1121                         this.noalign = 1;
1122                 if (this.noalign > 0)
1123                         this.movetype = MOVETYPE_NONE;
1124                 else
1125                         this.movetype = MOVETYPE_TOSS;
1126                 // do item filtering according to game mode and other things
1127                 if (this.noalign <= 0)
1128                 {
1129                         // first nudge it off the floor a little bit to avoid math errors
1130                         setorigin(this, this.origin + '0 0 1');
1131                         // set item size before we spawn a spawnfunc_waypoint
1132                         setsize(this, def.m_mins, def.m_maxs);
1133                         this.SendFlags |= ISF_SIZE;
1134                         // note droptofloor returns false if stuck/or would fall too far
1135                         if (!this.noalign)
1136                                 droptofloor(this);
1137                         waypoint_spawnforitem(this);
1138                 }
1139
1140                 /*
1141                  * can't do it that way, as it would break maps
1142                  * TODO make a target_give like entity another way, that perhaps has
1143                  * the weapon name in a key
1144                 if(this.targetname)
1145                 {
1146                         // target_give not yet supported; maybe later
1147                         print("removed targeted ", this.classname, "\n");
1148                         startitem_failed = true;
1149                         remove (this);
1150                         return;
1151                 }
1152                 */
1153
1154                 if(autocvar_spawn_debug >= 2)
1155                 {
1156             // why not flags & fl_item?
1157                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1158                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1159                 LOG_TRACE(" vs ", it.netname, vtos(it.origin), "\n");
1160                 error("Mapper sucks.");
1161             });
1162                         this.is_item = true;
1163                 }
1164
1165                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1166
1167                 precache_model(this.model);
1168                 precache_sound(this.item_pickupsound);
1169
1170                 if (   def.instanceOfPowerup
1171                         || def.instanceOfWeaponPickup
1172                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1173                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1174                         || (itemid & (IT_KEY1 | IT_KEY2))
1175                 ) this.target = "###item###"; // for finding the nearest item using find()
1176
1177                 Item_ItemsTime_SetTime(this, 0);
1178         }
1179
1180         this.bot_pickup = true;
1181         this.bot_pickupevalfunc = pickupevalfunc;
1182         this.bot_pickupbasevalue = pickupbasevalue;
1183         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1184         this.netname = itemname;
1185         settouch(this, Item_Touch);
1186         setmodel(this, MDL_Null); // precision set below
1187         //this.effects |= EF_LOWPRECISION;
1188
1189         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1190
1191         this.SendFlags |= ISF_SIZE;
1192
1193         if (!(this.spawnflags & 1024)) {
1194                 if(def.instanceOfPowerup)
1195                         this.ItemStatus |= ITS_ANIMATE1;
1196
1197                 if(this.armorvalue || this.health)
1198                         this.ItemStatus |= ITS_ANIMATE2;
1199         }
1200
1201         if(def.instanceOfWeaponPickup)
1202         {
1203                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1204                         this.colormap = 1024; // color shirt=0 pants=0 grey
1205                 else
1206                         this.gravity = 1;
1207                 if (!(this.spawnflags & 1024))
1208                         this.ItemStatus |= ITS_ANIMATE1;
1209                 this.ItemStatus |= ISF_COLORMAP;
1210         }
1211
1212         this.state = 0;
1213         if(this.team) // broken, no idea why.
1214         {
1215                 if(!this.cnt)
1216                         this.cnt = 1; // item probability weight
1217
1218                 this.effects |= EF_NODRAW; // marker for item team search
1219                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1220         }
1221         else
1222                 Item_Reset(this);
1223
1224         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1225
1226         // call this hook after everything else has been done
1227         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1228         {
1229                 startitem_failed = true;
1230                 remove(this);
1231                 return;
1232         }
1233 }
1234
1235 void StartItem(entity this, GameItem def)
1236 {
1237     _StartItem(
1238         this,
1239         this.itemdef = def,
1240         def.m_respawntime(), // defaultrespawntime
1241         def.m_respawntimejitter() // defaultrespawntimejitter
1242         );
1243 }
1244
1245 spawnfunc(item_rockets)
1246 {
1247         if(!this.ammo_rockets)
1248                 this.ammo_rockets = g_pickup_rockets;
1249         if(!this.pickup_anyway)
1250                 this.pickup_anyway = g_pickup_ammo_anyway;
1251     StartItem(this, ITEM_Rockets);
1252 }
1253
1254 spawnfunc(item_bullets)
1255 {
1256         if(!weaponswapping)
1257         if(autocvar_sv_q3acompat_machineshotgunswap)
1258         if(this.classname != "droppedweapon")
1259         {
1260                 weaponswapping = true;
1261                 spawnfunc_item_shells(this);
1262                 weaponswapping = false;
1263                 return;
1264         }
1265
1266         if(!this.ammo_nails)
1267                 this.ammo_nails = g_pickup_nails;
1268         if(!this.pickup_anyway)
1269                 this.pickup_anyway = g_pickup_ammo_anyway;
1270     StartItem(this, ITEM_Bullets);
1271 }
1272
1273 spawnfunc(item_cells)
1274 {
1275         if(!this.ammo_cells)
1276                 this.ammo_cells = g_pickup_cells;
1277         if(!this.pickup_anyway)
1278                 this.pickup_anyway = g_pickup_ammo_anyway;
1279         StartItem(this, ITEM_Cells);
1280 }
1281
1282 spawnfunc(item_plasma)
1283 {
1284         if(!this.ammo_plasma)
1285                 this.ammo_plasma = g_pickup_plasma;
1286         if(!this.pickup_anyway)
1287                 this.pickup_anyway = g_pickup_ammo_anyway;
1288         StartItem(this, ITEM_Plasma);
1289 }
1290
1291 spawnfunc(item_shells)
1292 {
1293         if(!weaponswapping)
1294         if(autocvar_sv_q3acompat_machineshotgunswap)
1295         if(this.classname != "droppedweapon")
1296         {
1297                 weaponswapping = true;
1298                 spawnfunc_item_bullets(this);
1299                 weaponswapping = false;
1300                 return;
1301         }
1302
1303         if(!this.ammo_shells)
1304                 this.ammo_shells = g_pickup_shells;
1305         if(!this.pickup_anyway)
1306                 this.pickup_anyway = g_pickup_ammo_anyway;
1307         StartItem(this, ITEM_Shells);
1308 }
1309
1310 spawnfunc(item_armor_small)
1311 {
1312         if(!this.armorvalue)
1313                 this.armorvalue = g_pickup_armorsmall;
1314         if(!this.max_armorvalue)
1315                 this.max_armorvalue = g_pickup_armorsmall_max;
1316         if(!this.pickup_anyway)
1317                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1318         StartItem(this, ITEM_ArmorSmall);
1319 }
1320
1321 spawnfunc(item_armor_medium)
1322 {
1323         if(!this.armorvalue)
1324                 this.armorvalue = g_pickup_armormedium;
1325         if(!this.max_armorvalue)
1326                 this.max_armorvalue = g_pickup_armormedium_max;
1327         if(!this.pickup_anyway)
1328                 this.pickup_anyway = g_pickup_armormedium_anyway;
1329         StartItem(this, ITEM_ArmorMedium);
1330 }
1331
1332 spawnfunc(item_armor_big)
1333 {
1334         if(!this.armorvalue)
1335                 this.armorvalue = g_pickup_armorbig;
1336         if(!this.max_armorvalue)
1337                 this.max_armorvalue = g_pickup_armorbig_max;
1338         if(!this.pickup_anyway)
1339                 this.pickup_anyway = g_pickup_armorbig_anyway;
1340         StartItem(this, ITEM_ArmorLarge);
1341 }
1342
1343 spawnfunc(item_armor_large)
1344 {
1345         if(!this.armorvalue)
1346                 this.armorvalue = g_pickup_armorlarge;
1347         if(!this.max_armorvalue)
1348                 this.max_armorvalue = g_pickup_armorlarge_max;
1349         if(!this.pickup_anyway)
1350                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1351         StartItem(this, ITEM_ArmorMega);
1352 }
1353
1354 spawnfunc(item_health_small)
1355 {
1356         if(!this.max_health)
1357                 this.max_health = g_pickup_healthsmall_max;
1358         if(!this.health)
1359                 this.health = g_pickup_healthsmall;
1360         if(!this.pickup_anyway)
1361                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1362         StartItem(this, ITEM_HealthSmall);
1363 }
1364
1365 spawnfunc(item_health_medium)
1366 {
1367         if(!this.max_health)
1368                 this.max_health = g_pickup_healthmedium_max;
1369         if(!this.health)
1370                 this.health = g_pickup_healthmedium;
1371         if(!this.pickup_anyway)
1372                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1373     StartItem(this, ITEM_HealthMedium);
1374 }
1375
1376 spawnfunc(item_health_large)
1377 {
1378         if(!this.max_health)
1379                 this.max_health = g_pickup_healthlarge_max;
1380         if(!this.health)
1381                 this.health = g_pickup_healthlarge;
1382         if(!this.pickup_anyway)
1383                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1384         StartItem(this, ITEM_HealthLarge);
1385 }
1386
1387 spawnfunc(item_health_mega)
1388 {
1389     if(!this.max_health)
1390         this.max_health = g_pickup_healthmega_max;
1391     if(!this.health)
1392         this.health = g_pickup_healthmega;
1393     if(!this.pickup_anyway)
1394         this.pickup_anyway = g_pickup_healthmega_anyway;
1395     StartItem(this, ITEM_HealthMega);
1396 }
1397
1398 // support old misnamed entities
1399 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1400 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1401 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1402 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1403 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1404
1405 spawnfunc(item_strength)
1406 {
1407                 if(!this.strength_finished)
1408                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1409                 StartItem(this, ITEM_Strength);
1410 }
1411
1412 spawnfunc(item_invincible)
1413 {
1414                 if(!this.invincible_finished)
1415                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1416                 StartItem(this, ITEM_Shield);
1417 }
1418
1419 // compatibility:
1420 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1421
1422 void target_items_use(entity this, entity actor, entity trigger)
1423 {
1424         other = trigger; // TODO
1425
1426         if(actor.classname == "droppedweapon")
1427         {
1428                 EXACTTRIGGER_TOUCH;
1429                 remove(actor);
1430                 return;
1431         }
1432
1433         if (!IS_PLAYER(actor))
1434                 return;
1435         if(IS_DEAD(actor))
1436                 return;
1437         if(trigger.solid == SOLID_TRIGGER)
1438         {
1439                 EXACTTRIGGER_TOUCH;
1440         }
1441
1442         FOREACH_ENTITY_ENT(enemy, actor,
1443         {
1444                 if(it.classname == "droppedweapon")
1445                         remove(it);
1446         });
1447
1448         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1449                 centerprint(actor, this.message);
1450 }
1451
1452 spawnfunc(target_items)
1453 {
1454         float n, i;
1455         string s;
1456
1457         this.use = target_items_use;
1458         if(!this.strength_finished)
1459                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1460         if(!this.invincible_finished)
1461                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1462         if(!this.superweapons_finished)
1463                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1464
1465         n = tokenize_console(this.netname);
1466         if(argv(0) == "give")
1467         {
1468                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1469         }
1470         else
1471         {
1472                 for(i = 0; i < n; ++i)
1473                 {
1474                         if     (argv(i) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1475                         else if(argv(i) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1476                         else if(argv(i) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1477                         else if(argv(i) == "strength")               this.items |= ITEM_Strength.m_itemid;
1478                         else if(argv(i) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1479                         else if(argv(i) == "superweapons")           this.items |= IT_SUPERWEAPON;
1480                         else if(argv(i) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1481                         else if(argv(i) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1482                         else
1483                         {
1484                                 FOREACH(Weapons, it != WEP_Null, {
1485                                         s = W_UndeprecateName(argv(i));
1486                                         if(s == it.netname)
1487                                         {
1488                                                 this.weapons |= (it.m_wepset);
1489                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1490                                                         it.wr_init(it);
1491                                                 break;
1492                                         }
1493                                 });
1494                         }
1495                 }
1496
1497                 string itemprefix, valueprefix;
1498                 if(this.spawnflags == 0)
1499                 {
1500                         itemprefix = "";
1501                         valueprefix = "";
1502                 }
1503                 else if(this.spawnflags == 1)
1504                 {
1505                         itemprefix = "max ";
1506                         valueprefix = "max ";
1507                 }
1508                 else if(this.spawnflags == 2)
1509                 {
1510                         itemprefix = "min ";
1511                         valueprefix = "min ";
1512                 }
1513                 else if(this.spawnflags == 4)
1514                 {
1515                         itemprefix = "minus ";
1516                         valueprefix = "max ";
1517                 }
1518                 else
1519                 {
1520                         error("invalid spawnflags");
1521                         itemprefix = valueprefix = string_null;
1522                 }
1523
1524                 this.netname = "";
1525                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1526                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1527                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1528                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1529                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1530                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1531                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1532                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1533                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1534                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1535                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1536                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1537                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1538                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1539                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1540                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1541         }
1542         this.netname = strzone(this.netname);
1543         //print(this.netname, "\n");
1544
1545         n = tokenize_console(this.netname);
1546         for(i = 0; i < n; ++i)
1547         {
1548                 FOREACH(Weapons, it != WEP_Null && argv(i) == it.netname, {
1549             it.wr_init(it);
1550             break;
1551                 });
1552         }
1553 }
1554
1555 spawnfunc(item_fuel)
1556 {
1557         if(!this.ammo_fuel)
1558                 this.ammo_fuel = g_pickup_fuel;
1559         if(!this.pickup_anyway)
1560                 this.pickup_anyway = g_pickup_ammo_anyway;
1561         StartItem(this, ITEM_JetpackFuel);
1562 }
1563
1564 spawnfunc(item_fuel_regen)
1565 {
1566         if(start_items & ITEM_JetpackRegen.m_itemid)
1567         {
1568                 spawnfunc_item_fuel(this);
1569                 return;
1570         }
1571         StartItem(this, ITEM_JetpackRegen);
1572 }
1573
1574 spawnfunc(item_jetpack)
1575 {
1576         if(!this.ammo_fuel)
1577                 this.ammo_fuel = g_pickup_fuel_jetpack;
1578         if(start_items & ITEM_Jetpack.m_itemid)
1579         {
1580                 spawnfunc_item_fuel(this);
1581                 return;
1582         }
1583         StartItem(this, ITEM_Jetpack);
1584 }
1585
1586 float GiveWeapon(entity e, float wpn, float op, float val)
1587 {
1588         WepSet v0, v1;
1589         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1590         v0 = (e.weapons & s);
1591         switch(op)
1592         {
1593                 case OP_SET:
1594                         if(val > 0)
1595                                 e.weapons |= s;
1596                         else
1597                                 e.weapons &= ~s;
1598                         break;
1599                 case OP_MIN:
1600                 case OP_PLUS:
1601                         if(val > 0)
1602                                 e.weapons |= s;
1603                         break;
1604                 case OP_MAX:
1605                         if(val <= 0)
1606                                 e.weapons &= ~s;
1607                         break;
1608                 case OP_MINUS:
1609                         if(val > 0)
1610                                 e.weapons &= ~s;
1611                         break;
1612         }
1613         v1 = (e.weapons & s);
1614         return (v0 != v1);
1615 }
1616
1617 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1618 {
1619         if(v1 == v0)
1620                 return;
1621         if(v1 <= v0 - t)
1622         {
1623                 if(snd_decr != NULL)
1624                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1625         }
1626         else if(v0 >= v0 + t)
1627         {
1628                 if(snd_incr != NULL)
1629                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1630         }
1631 }
1632
1633 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1634 {
1635         if(v0 < v1)
1636                 e.(rotfield) = max(e.(rotfield), time + rottime);
1637         else if(v0 > v1)
1638                 e.(regenfield) = max(e.(regenfield), time + regentime);
1639 }
1640 float GiveItems(entity e, float beginarg, float endarg)
1641 {
1642         float got, i, val, op;
1643         float _switchweapon;
1644         string cmd;
1645
1646         val = 999;
1647         op = OP_SET;
1648
1649         got = 0;
1650
1651         _switchweapon = false;
1652         if (e.autoswitch)
1653                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1654                         _switchweapon = true;
1655
1656         e.strength_finished = max(0, e.strength_finished - time);
1657         e.invincible_finished = max(0, e.invincible_finished - time);
1658         e.superweapons_finished = max(0, e.superweapons_finished - time);
1659
1660         PREGIVE(e, items);
1661         PREGIVE_WEAPONS(e);
1662         PREGIVE(e, strength_finished);
1663         PREGIVE(e, invincible_finished);
1664         PREGIVE(e, superweapons_finished);
1665         PREGIVE(e, ammo_nails);
1666         PREGIVE(e, ammo_cells);
1667         PREGIVE(e, ammo_plasma);
1668         PREGIVE(e, ammo_shells);
1669         PREGIVE(e, ammo_rockets);
1670         PREGIVE(e, ammo_fuel);
1671         PREGIVE(e, armorvalue);
1672         PREGIVE(e, health);
1673
1674         for(i = beginarg; i < endarg; ++i)
1675         {
1676                 cmd = argv(i);
1677
1678                 if(cmd == "0" || stof(cmd))
1679                 {
1680                         val = stof(cmd);
1681                         continue;
1682                 }
1683                 switch(cmd)
1684                 {
1685                         case "no":
1686                                 op = OP_MAX;
1687                                 val = 0;
1688                                 continue;
1689                         case "max":
1690                                 op = OP_MAX;
1691                                 continue;
1692                         case "min":
1693                                 op = OP_MIN;
1694                                 continue;
1695                         case "plus":
1696                                 op = OP_PLUS;
1697                                 continue;
1698                         case "minus":
1699                                 op = OP_MINUS;
1700                                 continue;
1701                         case "ALL":
1702                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1703                                 got += GiveValue(e, strength_finished, op, val);
1704                                 got += GiveValue(e, invincible_finished, op, val);
1705                                 got += GiveValue(e, superweapons_finished, op, val);
1706                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1707                         case "all":
1708                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1709                                 got += GiveValue(e, health, op, val);
1710                                 got += GiveValue(e, armorvalue, op, val);
1711                         case "allweapons":
1712                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1713                         case "allammo":
1714                                 got += GiveValue(e, ammo_cells, op, val);
1715                                 got += GiveValue(e, ammo_plasma, op, val);
1716                                 got += GiveValue(e, ammo_shells, op, val);
1717                                 got += GiveValue(e, ammo_nails, op, val);
1718                                 got += GiveValue(e, ammo_rockets, op, val);
1719                                 got += GiveValue(e, ammo_fuel, op, val);
1720                                 break;
1721                         case "unlimited_ammo":
1722                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1723                                 break;
1724                         case "unlimited_weapon_ammo":
1725                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1726                                 break;
1727                         case "unlimited_superweapons":
1728                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1729                                 break;
1730                         case "jetpack":
1731                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1732                                 break;
1733                         case "fuel_regen":
1734                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1735                                 break;
1736                         case "strength":
1737                                 got += GiveValue(e, strength_finished, op, val);
1738                                 break;
1739                         case "invincible":
1740                                 got += GiveValue(e, invincible_finished, op, val);
1741                                 break;
1742                         case "superweapons":
1743                                 got += GiveValue(e, superweapons_finished, op, val);
1744                                 break;
1745                         case "cells":
1746                                 got += GiveValue(e, ammo_cells, op, val);
1747                                 break;
1748                         case "plasma":
1749                                 got += GiveValue(e, ammo_plasma, op, val);
1750                                 break;
1751                         case "shells":
1752                                 got += GiveValue(e, ammo_shells, op, val);
1753                                 break;
1754                         case "nails":
1755                         case "bullets":
1756                                 got += GiveValue(e, ammo_nails, op, val);
1757                                 break;
1758                         case "rockets":
1759                                 got += GiveValue(e, ammo_rockets, op, val);
1760                                 break;
1761                         case "health":
1762                                 got += GiveValue(e, health, op, val);
1763                                 break;
1764                         case "armor":
1765                                 got += GiveValue(e, armorvalue, op, val);
1766                                 break;
1767                         case "fuel":
1768                                 got += GiveValue(e, ammo_fuel, op, val);
1769                                 break;
1770                         default:
1771                                 FOREACH(Weapons, it != WEP_Null && cmd == it.netname, {
1772                     got += GiveWeapon(e, it.m_id, op, val);
1773                     break;
1774                                 });
1775                                 break;
1776                 }
1777                 val = 999;
1778                 op = OP_SET;
1779         }
1780
1781         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1782         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1783         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1784         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1785         FOREACH(Weapons, it != WEP_Null, {
1786                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1787                 if(!(save_weapons & (it.m_wepset)))
1788                         if(e.weapons & (it.m_wepset))
1789                                 it.wr_init(it);
1790         });
1791         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1792         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1793         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1794         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1795         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1796         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1797         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1798         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1799         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1800         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1801
1802         if(e.superweapons_finished <= 0)
1803                 if(e.weapons & WEPSET_SUPERWEAPONS)
1804                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1805
1806         if(e.strength_finished <= 0)
1807                 e.strength_finished = 0;
1808         else
1809                 e.strength_finished += time;
1810         if(e.invincible_finished <= 0)
1811                 e.invincible_finished = 0;
1812         else
1813                 e.invincible_finished += time;
1814         if(e.superweapons_finished <= 0)
1815                 e.superweapons_finished = 0;
1816         else
1817                 e.superweapons_finished += time;
1818
1819         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1820                 _switchweapon = true;
1821         if(_switchweapon)
1822                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1823
1824         return got;
1825 }
1826 #endif