qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 if(!this.item_simple)
  96                 this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103                 if(!this.item_simple)
 104                 this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void Item_PreDraw(entity this)
 114 {
 115         if(warpzone_warpzones_exist)
 116         {
 117                 setpredraw(this, func_null); // no need to keep running this
 118                 return;
 119         }
 120         float alph;
 121         vector org = getpropertyvec(VF_ORIGIN);
 122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 124         if(this.fade_start)
 125         {
 126                 if(vdist(org - this.origin, >, this.fade_end))
 127                         alph = 0; // save on some processing
 128                 else if(vdist(org - this.origin, <, this.fade_start))
 129                         alph = 1; // more processing saved
 130                 else
 131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         }
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         //else
 141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         strfree(this.mdl);
 147 }
 148
 149 HashMap ENT_CLIENT_ITEM_simple;
 150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 151 {
 152         HM_NEW(ENT_CLIENT_ITEM_simple);
 153 }
 154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 155 {
 156         HM_DELETE(ENT_CLIENT_ITEM_simple);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin = ReadVector();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218                 strfree(this.mdl);
 219
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228                         #define extensions(x) \
 229                                 x(md3) \
 230                                 x(dpm) \
 231                                 x(iqm) \
 232                                 x(mdl) \
 233                                 /**/
 234                         #define tryext(ext) { \
 235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 237                                 if (cached == "") { \
 238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 239                                 } \
 240                                 if (cached != "0") { \
 241                                         strcpy(this.mdl, s); \
 242                                         break; \
 243                                 } \
 244                         }
 245                         do {
 246                                 extensions(tryext);
 247                                 this.item_simple = false;
 248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 249                         } while (0);
 250                         #undef tryext
 251                         #undef extensions
 252         }
 253
 254         if(!this.item_simple)
 255             strcpy(this.mdl, _fn);
 256
 257         if(this.mdl == "")
 258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 259
 260         precache_model(this.mdl);
 261         _setmodel(this, this.mdl);
 262
 263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 264     }
 265
 266     if(sf & ISF_COLORMAP)
 267     {
 268         this.colormap = ReadShort();
 269         this.item_glowmod_x = ReadByte() / 255.0;
 270         this.item_glowmod_y = ReadByte() / 255.0;
 271         this.item_glowmod_z = ReadByte() / 255.0;
 272     }
 273
 274     if(sf & ISF_DROP)
 275     {
 276         this.gravity = 1;
 277         this.pushable = true;
 278         //this.angles = '0 0 0';
 279         set_movetype(this, MOVETYPE_TOSS);
 280         this.velocity = ReadVector();
 281         setorigin(this, this.oldorigin);
 282
 283         if(!this.move_time)
 284         {
 285             this.move_time = time;
 286             this.spawntime = time;
 287         }
 288         else
 289             this.move_time = max(this.move_time, time);
 290     }
 291
 292     if(autocvar_cl_animate_items)
 293     {
 294         if(this.ItemStatus & ITS_ANIMATE1)
 295             this.avelocity = '0 180 0';
 296
 297         if(this.ItemStatus & ITS_ANIMATE2)
 298             this.avelocity = '0 -90 0';
 299     }
 300
 301     this.entremove = ItemRemove;
 302
 303     return true;
 304 }
 305
 306 #endif
 307
 308 #ifdef SVQC
 309 bool ItemSend(entity this, entity to, int sf)
 310 {
 311         if(this.gravity)
 312                 sf |= ISF_DROP;
 313         else
 314                 sf &= ~ISF_DROP;
 315
 316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 317         WriteByte(MSG_ENTITY, sf);
 318
 319         //WriteByte(MSG_ENTITY, this.cnt);
 320         if(sf & ISF_LOCATION)
 321         {
 322                 WriteVector(MSG_ENTITY, this.origin);
 323         }
 324
 325         if(sf & ISF_ANGLES)
 326         {
 327                 WriteAngle(MSG_ENTITY, this.angles_x);
 328                 WriteAngle(MSG_ENTITY, this.angles_y);
 329                 WriteAngle(MSG_ENTITY, this.angles_z);
 330         }
 331
 332         if(sf & ISF_SIZE)
 333         {
 334                 Pickup p = this.itemdef;
 335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 336         }
 337
 338         if(sf & ISF_STATUS)
 339                 WriteByte(MSG_ENTITY, this.ItemStatus);
 340
 341         if(sf & ISF_MODEL)
 342         {
 343                 Pickup p = this.itemdef;
 344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 345                 WriteShort(MSG_ENTITY, this.fade_end);
 346                 WriteShort(MSG_ENTITY, this.fade_start);
 347
 348                 if(this.mdl == "")
 349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 350
 351                 WriteString(MSG_ENTITY, this.mdl);
 352         }
 353
 354
 355         if(sf & ISF_COLORMAP)
 356         {
 357                 WriteShort(MSG_ENTITY, this.colormap);
 358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 361         }
 362
 363         if(sf & ISF_DROP)
 364         {
 365                 WriteVector(MSG_ENTITY, this.velocity);
 366         }
 367
 368         return true;
 369 }
 370
 371 void ItemUpdate(entity this)
 372 {
 373         this.oldorigin = this.origin;
 374         this.SendFlags |= ISF_LOCATION;
 375 }
 376
 377 void UpdateItemAfterTeleport(entity this)
 378 {
 379         if(getSendEntity(this) == ItemSend)
 380                 ItemUpdate(this);
 381 }
 382
 383 bool have_pickup_item(entity this)
 384 {
 385         if(this.itemdef.instanceOfPowerup)
 386         {
 387                 if(autocvar_g_powerups > 0)
 388                         return true;
 389                 if(autocvar_g_powerups == 0)
 390                         return false;
 391         }
 392         else
 393         {
 394                 if(autocvar_g_pickup_items > 0)
 395                         return true;
 396                 if(autocvar_g_pickup_items == 0)
 397                         return false;
 398                 if(g_weaponarena)
 399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 400                                 return false;
 401         }
 402         return true;
 403 }
 404
 405 void Item_Show (entity e, float mode)
 406 {
 407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 408         e.ItemStatus &= ~ITS_STAYWEP;
 409         entity def = e.itemdef;
 410         if (mode > 0)
 411         {
 412                 // make the item look normal, and be touchable
 413                 e.model = e.mdl;
 414                 e.solid = SOLID_TRIGGER;
 415                 e.spawnshieldtime = 1;
 416                 e.ItemStatus |= ITS_AVAILABLE;
 417         }
 418         else if (mode < 0)
 419         {
 420                 // hide the item completely
 421                 e.model = string_null;
 422                 e.solid = SOLID_NOT;
 423                 e.spawnshieldtime = 1;
 424                 e.ItemStatus &= ~ITS_AVAILABLE;
 425         }
 426         else
 427         {
 428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 429                         || e.team // weapon stay isn't supported for teamed weapons
 430                         ;
 431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 432                 {
 433                         // make the item translucent and not touchable
 434                         e.model = e.mdl;
 435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 436                         e.effects |= EF_STARDUST;
 437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 439                 }
 440                 else
 441                 {
 442                         //setmodel(e, "null");
 443                         e.solid = SOLID_NOT;
 444                         e.colormod = '0 0 0';
 445                         //e.glowmod = e.colormod;
 446                         e.spawnshieldtime = 1;
 447                         e.ItemStatus &= ~ITS_AVAILABLE;
 448                 }
 449         }
 450
 451         if (def.m_glow)
 452                 e.ItemStatus |= ITS_GLOW;
 453
 454         if (autocvar_g_nodepthtestitems)
 455                 e.effects |= EF_NODEPTHTEST;
 456
 457
 458         if (autocvar_g_fullbrightitems)
 459                 e.ItemStatus |= ITS_ALLOWFB;
 460
 461         if (autocvar_sv_simple_items)
 462                 e.ItemStatus |= ITS_ALLOWSI;
 463
 464         // relink entity (because solid may have changed)
 465         setorigin(e, e.origin);
 466         e.SendFlags |= ISF_STATUS;
 467 }
 468
 469 void Item_Think(entity this)
 470 {
 471         this.nextthink = time;
 472         if(this.origin != this.oldorigin)
 473                 ItemUpdate(this);
 474 }
 475
 476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 477 bool Item_ItemsTime_Allow(GameItem it);
 478 float Item_ItemsTime_UpdateTime(entity e, float t);
 479 void Item_ItemsTime_SetTime(entity e, float t);
 480 void Item_ItemsTime_SetTimesForAllPlayers();
 481
 482 void Item_Respawn (entity this)
 483 {
 484         Item_Show(this, 1);
 485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 486         setorigin(this, this.origin);
 487
 488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 489         {
 490                 float t = Item_ItemsTime_UpdateTime(this, 0);
 491                 Item_ItemsTime_SetTime(this, t);
 492                 Item_ItemsTime_SetTimesForAllPlayers();
 493         }
 494
 495         setthink(this, Item_Think);
 496         this.nextthink = time;
 497
 498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 500 }
 501
 502 void Item_RespawnCountdown (entity this)
 503 {
 504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 505         {
 506                 if(this.waypointsprite_attached)
 507                         WaypointSprite_Kill(this.waypointsprite_attached);
 508                 Item_Respawn(this);
 509         }
 510         else
 511         {
 512                 this.nextthink = time + 1;
 513                 this.item_respawncounter += 1;
 514                 if(this.item_respawncounter == 1)
 515                 {
 516                         do {
 517                                 {
 518                                         entity wi = Weapons_from(this.weapon);
 519                                         if (wi != WEP_Null) {
 520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 521                                                 wp.wp_extra = wi.m_id;
 522                                                 break;
 523                                         }
 524                                 }
 525                                 {
 526                                         entity ii = this.itemdef;
 527                                         if (ii != NULL) {
 528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 529                                                 wp.wp_extra = ii.m_id;
 530                                                 break;
 531                                         }
 532                                 }
 533                         } while (0);
 534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 535             if(this.waypointsprite_attached)
 536             {
 537                 GameItem def = this.itemdef;
 538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 541             }
 542                 }
 543
 544                 if(this.waypointsprite_attached)
 545                 {
 546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 548                                 {
 549                                         msg_entity = it;
 550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 551                                 }
 552                         });
 553
 554                         WaypointSprite_Ping(this.waypointsprite_attached);
 555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 556                 }
 557         }
 558 }
 559
 560 void Item_RespawnThink(entity this)
 561 {
 562         this.nextthink = time;
 563         if(this.origin != this.oldorigin)
 564                 ItemUpdate(this);
 565
 566         if(time >= this.wait)
 567                 Item_Respawn(this);
 568 }
 569
 570 void Item_ScheduleRespawnIn(entity e, float t)
 571 {
 572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 574         {
 575                 setthink(e, Item_RespawnCountdown);
 576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 578                 e.item_respawncounter = 0;
 579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 580                 {
 581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 582                         Item_ItemsTime_SetTime(e, t);
 583                         Item_ItemsTime_SetTimesForAllPlayers();
 584                 }
 585         }
 586         else
 587         {
 588                 setthink(e, Item_RespawnThink);
 589                 e.nextthink = time;
 590                 e.scheduledrespawntime = time + t;
 591                 e.wait = time + t;
 592
 593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 594                 {
 595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 596                         Item_ItemsTime_SetTime(e, t);
 597                         Item_ItemsTime_SetTimesForAllPlayers();
 598                 }
 599         }
 600 }
 601
 602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 605
 606 /// Adjust respawn time according to the number of players.
 607 float adjust_respawntime(float normal_respawntime) {
 608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 609         float o = autocvar_g_pickup_respawntime_scaling_offset;
 610         float l = autocvar_g_pickup_respawntime_scaling_linear;
 611
 612         if (r == 0 && l == 1) {
 613                 return normal_respawntime;
 614         }
 615
 616         CheckAllowedTeams(NULL);
 617         GetTeamCounts(NULL);
 618         int players = 0;
 619         if (c1 != -1) players += c1;
 620         if (c2 != -1) players += c2;
 621         if (c3 != -1) players += c3;
 622         if (c4 != -1) players += c4;
 623
 624         if (players >= 2) {
 625                 return normal_respawntime * (r / (players + o) + l);
 626         } else {
 627                 return normal_respawntime;
 628         }
 629 }
 630
 631 void Item_ScheduleRespawn(entity e)
 632 {
 633         if(e.respawntime > 0)
 634         {
 635                 Item_Show(e, 0);
 636
 637                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 638                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 639
 640                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 641                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 642                 Item_ScheduleRespawnIn(e, respawn_in);
 643         }
 644         else // if respawntime is -1, this item does not respawn
 645                 Item_Show(e, -1);
 646 }
 647
 648 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 649         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 650
 651 void Item_ScheduleInitialRespawn(entity e)
 652 {
 653         Item_Show(e, 0);
 654
 655         float spawn_in;
 656         if (autocvar_g_pickup_respawntime_initial_random == 0)
 657         {
 658                 // range: respawntime .. respawntime + respawntimejitter
 659                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 660         }
 661         else
 662         {
 663                 float rnd;
 664                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 665                 {
 666                         static float shared_random = 0;
 667                         // NOTE this code works only if items are scheduled at the same time (normal case)
 668                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 669                         if (!shared_random || floor(time) > shared_random)
 670                                 shared_random = floor(time) + random();
 671                         rnd = shared_random - floor(time);
 672                 }
 673                 else
 674                         rnd = random();
 675
 676                 // range:
 677                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 678                 // else: 0 .. ITEM_RESPAWN_TICKS
 679                 // this is to prevent powerups spawning unexpectedly without waypoints
 680                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 681         }
 682
 683         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 684 }
 685
 686 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 687         entity ammo_entity)
 688 {
 689         if (num_weapons == 0)
 690         {
 691                 return;
 692         }
 693         int num_potential_weapons = tokenize_console(weapon_names);
 694         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 695         {
 696                 RandomSelection_Init();
 697                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 698                         ++weapon_index)
 699                 {
 700                         string weapon = argv(weapon_index);
 701                         FOREACH(Weapons, it != WEP_Null,
 702                         {
 703                                 // Finding a weapon which player doesn't have.
 704                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 705                                 {
 706                                         RandomSelection_AddEnt(it, 1, 1);
 707                                         break;
 708                                 }
 709                         });
 710                 }
 711                 if (RandomSelection_chosen_ent == NULL)
 712                 {
 713                         return;
 714                 }
 715                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 716                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 717                 {
 718                         continue;
 719                 }
 720                 if (GetResourceAmount(receiver,
 721                         RandomSelection_chosen_ent.ammo_type) != 0)
 722                 {
 723                         continue;
 724                 }
 725                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 726                         GetResourceAmount(ammo_entity,
 727                         RandomSelection_chosen_ent.ammo_type));
 728         }
 729 }
 730
 731 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 732 {
 733         float amount = GetResourceAmount(item, resource_type);
 734         if (amount == 0)
 735         {
 736                 return false;
 737         }
 738         float player_amount = GetResourceAmount(player, resource_type);
 739         if (item.spawnshieldtime)
 740         {
 741                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 742                 {
 743                         return false;
 744                 }
 745                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 746                 return true;
 747         }
 748         if (g_weapon_stay != 2)
 749         {
 750                 return false;
 751         }
 752         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 753         return true;
 754 }
 755
 756 float Item_GiveTo(entity item, entity player)
 757 {
 758         float pickedup;
 759
 760         // if nothing happens to player, just return without taking the item
 761         pickedup = false;
 762         int _switchweapon = 0;
 763         // in case the player has autoswitch enabled do the following:
 764         // if the player is using their best weapon before items are given, they
 765         // probably want to switch to an even better weapon after items are given
 766
 767         if(CS(player).autoswitch)
 768         {
 769                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770                 {
 771                         .entity weaponentity = weaponentities[slot];
 772                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 773                         {
 774                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 775                                         _switchweapon |= BIT(slot);
 776
 777                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 778                                         _switchweapon |= BIT(slot);
 779                         }
 780                 }
 781         }
 782         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 783         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 784         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 785         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 788         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 789         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 790         if (item.itemdef.instanceOfWeaponPickup)
 791         {
 792                 WepSet w;
 793                 w = STAT(WEAPONS, item);
 794                 w &= ~STAT(WEAPONS, player);
 795
 796                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 797                 {
 798                         pickedup = true;
 799                         FOREACH(Weapons, it != WEP_Null, {
 800                                 if(w & (it.m_wepset))
 801                                 {
 802                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803                                         {
 804                                                 .entity weaponentity = weaponentities[slot];
 805                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 806                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 807                                         }
 808                                         W_GiveWeapon(player, it.m_id);
 809                                 }
 810                         });
 811                 }
 812         }
 813
 814         if (item.itemdef.instanceOfPowerup)
 815         {
 816                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 817                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 818                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 819                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 820         }
 821
 822         int its;
 823         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 824         {
 825                 pickedup = true;
 826                 player.items |= its;
 827                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 828         }
 829
 830         if (item.strength_finished)
 831         {
 832                 pickedup = true;
 833                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 834         }
 835         if (item.invincible_finished)
 836         {
 837                 pickedup = true;
 838                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 839         }
 840         if (item.superweapons_finished)
 841         {
 842                 pickedup = true;
 843                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 844         }
 845
 846         // always eat teamed entities
 847         if(item.team)
 848                 pickedup = true;
 849
 850         if (!pickedup)
 851                 return 0;
 852
 853         // crude hack to enforce switching weapons
 854         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 855         {
 856                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 857                 {
 858                         .entity weaponentity = weaponentities[slot];
 859                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 860                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 861                 }
 862                 return 1;
 863         }
 864
 865         if(_switchweapon)
 866         {
 867                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 868                 {
 869                         .entity weaponentity = weaponentities[slot];
 870                         if(_switchweapon & BIT(slot))
 871                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 872                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 873                 }
 874         }
 875
 876         return 1;
 877 }
 878
 879 void Item_Touch(entity this, entity toucher)
 880 {
 881         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 882         if (Item_IsLoot(this))
 883         {
 884                 if (ITEM_TOUCH_NEEDKILL())
 885                 {
 886                         delete(this);
 887                         return;
 888                 }
 889         }
 890
 891         if(!(toucher.flags & FL_PICKUPITEMS)
 892         || STAT(FROZEN, toucher)
 893         || IS_DEAD(toucher)
 894         || (this.solid != SOLID_TRIGGER)
 895         || (this.owner == toucher)
 896         || (time < this.item_spawnshieldtime)
 897         ) { return; }
 898
 899         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 900         {
 901                 case MUT_ITEMTOUCH_RETURN: { return; }
 902                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 903         }
 904
 905         toucher = M_ARGV(1, entity);
 906
 907         if (Item_IsExpiring(this))
 908         {
 909                 this.strength_finished = max(0, this.strength_finished - time);
 910                 this.invincible_finished = max(0, this.invincible_finished - time);
 911                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 912         }
 913         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 914         if (!gave)
 915         {
 916                 if (Item_IsExpiring(this))
 917                 {
 918                         // undo what we did above
 919                         this.strength_finished += time;
 920                         this.invincible_finished += time;
 921                         this.superweapons_finished += time;
 922                 }
 923                 return;
 924         }
 925
 926 LABEL(pickup)
 927
 928         STAT(LAST_PICKUP, toucher) = time;
 929
 930         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 931         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 932
 933         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 934         if (wasfreed(this))
 935         {
 936                 return;
 937         }
 938
 939         if (Item_IsLoot(this))
 940         {
 941                 delete(this);
 942                 return;
 943         }
 944         if (!this.spawnshieldtime)
 945         {
 946                 return;
 947         }
 948         entity e;
 949         if (this.team)
 950         {
 951                 RandomSelection_Init();
 952                 IL_EACH(g_items, it.team == this.team,
 953                 {
 954                         if (it.itemdef) // is a registered item
 955                         {
 956                                 Item_Show(it, -1);
 957                                 it.scheduledrespawntime = 0;
 958                                 RandomSelection_AddEnt(it, it.cnt, 0);
 959                         }
 960                 });
 961                 e = RandomSelection_chosen_ent;
 962                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 963         }
 964         else
 965                 e = this;
 966         Item_ScheduleRespawn(e);
 967 }
 968
 969 void Item_Reset(entity this)
 970 {
 971         Item_Show(this, !this.state);
 972         setorigin(this, this.origin);
 973
 974         if (Item_IsLoot(this))
 975         {
 976                 return;
 977         }
 978         setthink(this, Item_Think);
 979         this.nextthink = time;
 980         if (this.waypointsprite_attached)
 981         {
 982                 WaypointSprite_Kill(this.waypointsprite_attached);
 983         }
 984         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 985         {
 986                 Item_ScheduleInitialRespawn(this);
 987         }
 988 }
 989
 990 void Item_FindTeam(entity this)
 991 {
 992         entity e;
 993
 994         if(this.effects & EF_NODRAW)
 995         {
 996                 // marker for item team search
 997                 LOG_TRACE("Initializing item team ", ftos(this.team));
 998                 RandomSelection_Init();
 999                 IL_EACH(g_items, it.team == this.team,
1000                 {
1001                         if(it.itemdef) // is a registered item
1002                                 RandomSelection_AddEnt(it, it.cnt, 0);
1003                 });
1004
1005                 e = RandomSelection_chosen_ent;
1006                 e.state = 0;
1007                 Item_Show(e, 1);
1008
1009                 IL_EACH(g_items, it.team == this.team,
1010                 {
1011                         if(it.itemdef) // is a registered item
1012                         {
1013                                 if(it != e)
1014                                 {
1015                                         // make it non-spawned
1016                                         Item_Show(it, -1);
1017                                         it.state = 1; // state 1 = initially hidden item, apparently
1018                                 }
1019                                 it.effects &= ~EF_NODRAW;
1020                         }
1021                 });
1022
1023                 Item_Reset(this);
1024         }
1025 }
1026
1027 // Savage: used for item garbage-collection
1028 void RemoveItem(entity this)
1029 {
1030         if(wasfreed(this) || !this) { return; }
1031         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1032         delete(this);
1033 }
1034
1035 // pickup evaluation functions
1036 // these functions decide how desirable an item is to the bots
1037
1038 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1039
1040 float weapon_pickupevalfunc(entity player, entity item)
1041 {
1042         // See if I have it already
1043         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1044         {
1045                 // If I can pick it up
1046                 if(!item.spawnshieldtime)
1047                         return 0;
1048                 return ammo_pickupevalfunc(player, item);
1049         }
1050
1051         // reduce weapon value if bot already got a good arsenal
1052         float c = 1;
1053         int weapons_value = 0;
1054         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1055                 weapons_value += it.bot_pickupbasevalue;
1056         });
1057         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1058
1059         return item.bot_pickupbasevalue * c;
1060 }
1061
1062 float ammo_pickupevalfunc(entity player, entity item)
1063 {
1064         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1065         entity wpn = NULL;
1066         float c = 0;
1067         float rating = 0;
1068
1069         // Detect needed ammo
1070         if(item.itemdef.instanceOfWeaponPickup)
1071         {
1072                 entity ammo = NULL;
1073                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1074                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1075                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1076                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1077                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1078                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1079
1080                 if(!ammo)
1081                         return 0;
1082                 wpn = item;
1083                 rating = ammo.m_botvalue;
1084         }
1085         else
1086         {
1087                 FOREACH(Weapons, it != WEP_Null, {
1088                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1089                                 continue;
1090
1091                         switch(it.ammo_type)
1092                         {
1093                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1094                                 case RESOURCE_BULLETS: need_nails   = true; break;
1095                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1096                                 case RESOURCE_CELLS:   need_cells   = true; break;
1097                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1098                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1099                         }
1100                 });
1101                 rating = item.bot_pickupbasevalue;
1102         }
1103
1104         float noammorating = 0.5;
1105
1106         if ((need_shells) && (item.ammo_shells) && (GetResourceAmount(player, RESOURCE_SHELLS) < g_pickup_shells_max))
1107                 c = item.ammo_shells / max(noammorating, GetResourceAmount(player, RESOURCE_SHELLS));
1108
1109         if ((need_nails) && (item.ammo_nails) && (GetResourceAmount(player, RESOURCE_BULLETS) < g_pickup_nails_max))
1110                 c = item.ammo_nails / max(noammorating, GetResourceAmount(player, RESOURCE_BULLETS));
1111
1112         if ((need_rockets) && (item.ammo_rockets) && (GetResourceAmount(player, RESOURCE_ROCKETS) < g_pickup_rockets_max))
1113                 c = item.ammo_rockets / max(noammorating, GetResourceAmount(player, RESOURCE_ROCKETS));
1114
1115         if ((need_cells) && (item.ammo_cells) && (GetResourceAmount(player, RESOURCE_CELLS) < g_pickup_cells_max))
1116                 c = item.ammo_cells / max(noammorating, GetResourceAmount(player, RESOURCE_CELLS));
1117
1118         if ((need_plasma) && (item.ammo_plasma) && (GetResourceAmount(player, RESOURCE_PLASMA) < g_pickup_plasma_max))
1119                 c = item.ammo_plasma / max(noammorating, GetResourceAmount(player, RESOURCE_PLASMA));
1120
1121         if ((need_fuel) && (item.ammo_fuel) && (GetResourceAmount(player, RESOURCE_FUEL) < g_pickup_fuel_max))
1122                 c = item.ammo_fuel / max(noammorating, GetResourceAmount(player, RESOURCE_FUEL));
1123
1124         rating *= min(c, 2);
1125         if(wpn)
1126                 rating += wpn.bot_pickupbasevalue * 0.1;
1127         return rating;
1128 }
1129
1130 float healtharmor_pickupevalfunc(entity player, entity item)
1131 {
1132         float c = 0;
1133         float rating = item.bot_pickupbasevalue;
1134
1135         float itemarmor = item.armorvalue;
1136         float itemhealth = item.health;
1137
1138         if(item.item_group)
1139         {
1140                 itemarmor *= min(4, item.item_group_count);
1141                 itemhealth *= min(4, item.item_group_count);
1142         }
1143
1144         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1145                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1146
1147         if (itemhealth && (player.health < item.max_health))
1148                 c = itemhealth / max(1, player.health);
1149
1150         rating *= min(2, c);
1151         return rating;
1152 }
1153
1154 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1155 {
1156         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1157                 RemoveItem(this);
1158 }
1159
1160 void item_use(entity this, entity actor, entity trigger)
1161 {
1162         // use the touch function to handle collection
1163         gettouch(this)(this, actor);
1164 }
1165
1166 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1167 {
1168         string itemname = def.m_name;
1169         Model itemmodel = def.m_model;
1170     Sound pickupsound = def.m_sound;
1171         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1172         float pickupbasevalue = def.m_botvalue;
1173         int itemflags = def.m_itemflags;
1174
1175         startitem_failed = false;
1176
1177         this.item_model_ent = itemmodel;
1178     this.item_pickupsound_ent = pickupsound;
1179
1180     if(def.m_iteminit)
1181         def.m_iteminit(this);
1182
1183         if(!this.respawntime) // both need to be set
1184         {
1185                 this.respawntime = defaultrespawntime;
1186                 this.respawntimejitter = defaultrespawntimejitter;
1187         }
1188
1189         if(!this.pickup_anyway && def.m_pickupanyway)
1190                 this.pickup_anyway = def.m_pickupanyway();
1191
1192         int itemid = def.m_itemid;
1193         this.items = itemid;
1194         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1195         this.weapon = weaponid;
1196
1197         if(!this.fade_end)
1198         {
1199                 this.fade_start = autocvar_g_items_mindist;
1200                 this.fade_end = autocvar_g_items_maxdist;
1201         }
1202
1203         if(weaponid)
1204                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1205
1206         this.flags = FL_ITEM | itemflags;
1207         IL_PUSH(g_items, this);
1208
1209         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1210         {
1211                 startitem_failed = true;
1212                 delete(this);
1213                 return;
1214         }
1215
1216         if (Item_IsLoot(this))
1217         {
1218                 this.reset = SUB_Remove;
1219                 set_movetype(this, MOVETYPE_TOSS);
1220
1221                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1222                 setthink(this, RemoveItem);
1223                 this.nextthink = time + 20;
1224
1225                 this.takedamage = DAMAGE_YES;
1226                 this.event_damage = Item_Damage;
1227
1228                 if (Item_IsExpiring(this))
1229                 {
1230                         // if item is worthless after a timer, have it expire then
1231                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1232                 }
1233
1234                 // don't drop if in a NODROP zone (such as lava)
1235                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1236                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1237                 {
1238                         startitem_failed = true;
1239                         delete(this);
1240                         return;
1241                 }
1242         }
1243         else
1244         {
1245                 if(!have_pickup_item(this))
1246                 {
1247                         startitem_failed = true;
1248                         delete(this);
1249                         return;
1250                 }
1251
1252                 if(this.angles != '0 0 0')
1253                         this.SendFlags |= ISF_ANGLES;
1254
1255                 this.reset = Item_Reset;
1256                 // it's a level item
1257                 if(this.spawnflags & 1)
1258                         this.noalign = 1;
1259                 if (this.noalign > 0)
1260                         set_movetype(this, MOVETYPE_NONE);
1261                 else
1262                         set_movetype(this, MOVETYPE_TOSS);
1263                 // do item filtering according to game mode and other things
1264                 if (this.noalign <= 0)
1265                 {
1266                         // first nudge it off the floor a little bit to avoid math errors
1267                         setorigin(this, this.origin + '0 0 1');
1268                         // set item size before we spawn a spawnfunc_waypoint
1269                         setsize(this, def.m_mins, def.m_maxs);
1270                         this.SendFlags |= ISF_SIZE;
1271                         // note droptofloor returns false if stuck/or would fall too far
1272                         if (!this.noalign)
1273                                 droptofloor(this);
1274                         waypoint_spawnforitem(this);
1275                 }
1276
1277                 /*
1278                  * can't do it that way, as it would break maps
1279                  * TODO make a target_give like entity another way, that perhaps has
1280                  * the weapon name in a key
1281                 if(this.targetname)
1282                 {
1283                         // target_give not yet supported; maybe later
1284                         print("removed targeted ", this.classname, "\n");
1285                         startitem_failed = true;
1286                         delete(this);
1287                         return;
1288                 }
1289                 */
1290
1291                 if(this.targetname != "" && (this.spawnflags & 16))
1292                         this.use = item_use;
1293
1294                 if(autocvar_spawn_debug >= 2)
1295                 {
1296             // why not flags & fl_item?
1297                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1298                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1299                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1300                 error("Mapper sucks.");
1301             });
1302                         this.is_item = true;
1303                 }
1304
1305                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1306
1307                 precache_model(this.model);
1308                 precache_sound(this.item_pickupsound);
1309
1310                 if (   def.instanceOfPowerup
1311                         || def.instanceOfWeaponPickup
1312                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1313                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1314                         || (itemid & (IT_KEY1 | IT_KEY2))
1315                 ) this.target = "###item###"; // for finding the nearest item using find()
1316
1317                 Item_ItemsTime_SetTime(this, 0);
1318         }
1319
1320         this.bot_pickup = true;
1321         this.bot_pickupevalfunc = pickupevalfunc;
1322         this.bot_pickupbasevalue = pickupbasevalue;
1323         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1324         this.netname = itemname;
1325         settouch(this, Item_Touch);
1326         setmodel(this, MDL_Null); // precision set below
1327         //this.effects |= EF_LOWPRECISION;
1328
1329         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1330
1331         this.SendFlags |= ISF_SIZE;
1332
1333         if (!(this.spawnflags & 1024)) {
1334                 if(def.instanceOfPowerup)
1335                         this.ItemStatus |= ITS_ANIMATE1;
1336
1337                 if(this.armorvalue || this.health)
1338                         this.ItemStatus |= ITS_ANIMATE2;
1339         }
1340
1341         if(def.instanceOfWeaponPickup)
1342         {
1343                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1344                         this.colormap = 1024; // color shirt=0 pants=0 grey
1345                 else
1346                         this.gravity = 1;
1347                 if (!(this.spawnflags & 1024))
1348                         this.ItemStatus |= ITS_ANIMATE1;
1349                 this.SendFlags |= ISF_COLORMAP;
1350         }
1351
1352         this.state = 0;
1353         if(this.team) // broken, no idea why.
1354         {
1355                 if(!this.cnt)
1356                         this.cnt = 1; // item probability weight
1357
1358                 this.effects |= EF_NODRAW; // marker for item team search
1359                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1360         }
1361         else
1362                 Item_Reset(this);
1363
1364         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1365
1366         // call this hook after everything else has been done
1367         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1368         {
1369                 startitem_failed = true;
1370                 delete(this);
1371                 return;
1372         }
1373
1374         setItemGroup(this);
1375 }
1376
1377 void StartItem(entity this, GameItem def)
1378 {
1379     def = def.m_spawnfunc_hookreplace(def, this);
1380     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1381     {
1382         delete(this);
1383         return;
1384     }
1385     this.classname = def.m_canonical_spawnfunc;
1386     _StartItem(
1387         this,
1388         this.itemdef = def,
1389         def.m_respawntime(), // defaultrespawntime
1390         def.m_respawntimejitter() // defaultrespawntimejitter
1391         );
1392 }
1393
1394 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1395 int group_count = 1;
1396
1397 void setItemGroup(entity this)
1398 {
1399         if(!IS_SMALL(this.itemdef))
1400                 return;
1401
1402         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1403         {
1404                 if(!this.item_group)
1405                 {
1406                         if(!it.item_group)
1407                         {
1408                                 it.item_group = group_count;
1409                                 group_count++;
1410                         }
1411                         this.item_group = it.item_group;
1412                 }
1413                 else // spawning item is already part of a item_group X
1414                 {
1415                         if(!it.item_group)
1416                                 it.item_group = this.item_group;
1417                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1418                         {
1419                                 int grY = it.item_group;
1420                                 // move all items of item_group Y to item_group X
1421                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1422                                 {
1423                                         if(it.item_group == grY)
1424                                                 it.item_group = this.item_group;
1425                                 });
1426                         }
1427                 }
1428         });
1429 }
1430
1431 void setItemGroupCount()
1432 {
1433         for (int k = 1; k <= group_count; k++)
1434         {
1435                 int count = 0;
1436                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1437                 if (count)
1438                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1439         }
1440 }
1441
1442 void target_items_use(entity this, entity actor, entity trigger)
1443 {
1444         if(Item_IsLoot(actor))
1445         {
1446                 EXACTTRIGGER_TOUCH(this, trigger);
1447                 delete(actor);
1448                 return;
1449         }
1450
1451         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1452                 return;
1453
1454         if(trigger.solid == SOLID_TRIGGER)
1455         {
1456                 EXACTTRIGGER_TOUCH(this, trigger);
1457         }
1458
1459         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1460         {
1461                 delete(it);
1462         });
1463
1464         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1465                 centerprint(actor, this.message);
1466 }
1467
1468 spawnfunc(target_items)
1469 {
1470         int n;
1471         string s;
1472
1473         this.use = target_items_use;
1474         if(!this.strength_finished)
1475                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1476         if(!this.invincible_finished)
1477                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1478         if(!this.superweapons_finished)
1479                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1480
1481         n = tokenize_console(this.netname);
1482         if(argv(0) == "give")
1483         {
1484                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1485         }
1486         else
1487         {
1488                 for(int j = 0; j < n; ++j)
1489                 {
1490                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1491                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1492                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1493                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1494                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1495                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1496                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1497                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1498                         else
1499                         {
1500                                 FOREACH(Buffs, it != BUFF_Null,
1501                                 {
1502                                         s = Buff_UndeprecateName(argv(j));
1503                                         if(s == it.m_name)
1504                                         {
1505                                                 STAT(BUFFS, this) |= (it.m_itemid);
1506                                                 break;
1507                                         }
1508                                 });
1509                                 FOREACH(Weapons, it != WEP_Null, {
1510                                         s = W_UndeprecateName(argv(j));
1511                                         if(s == it.netname)
1512                                         {
1513                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1514                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1515                                                         it.wr_init(it);
1516                                                 break;
1517                                         }
1518                                 });
1519                         }
1520                 }
1521
1522                 string itemprefix, valueprefix;
1523                 if(this.spawnflags == 0)
1524                 {
1525                         itemprefix = "";
1526                         valueprefix = "";
1527                 }
1528                 else if(this.spawnflags == 1)
1529                 {
1530                         itemprefix = "max ";
1531                         valueprefix = "max ";
1532                 }
1533                 else if(this.spawnflags == 2)
1534                 {
1535                         itemprefix = "min ";
1536                         valueprefix = "min ";
1537                 }
1538                 else if(this.spawnflags == 4)
1539                 {
1540                         itemprefix = "minus ";
1541                         valueprefix = "max ";
1542                 }
1543                 else
1544                 {
1545                         error("invalid spawnflags");
1546                         itemprefix = valueprefix = string_null;
1547                 }
1548
1549                 this.netname = "";
1550                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1551                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1552                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1553                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1554                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1555                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1557                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1558                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1559                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1560                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1561                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1562                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1563                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1564                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1565                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1566                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1567         }
1568         this.netname = strzone(this.netname);
1569         //print(this.netname, "\n");
1570
1571         n = tokenize_console(this.netname);
1572         for(int j = 0; j < n; ++j)
1573         {
1574                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1575             it.wr_init(it);
1576             break;
1577                 });
1578         }
1579 }
1580
1581 float GiveWeapon(entity e, float wpn, float op, float val)
1582 {
1583         WepSet v0, v1;
1584         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1585         v0 = (STAT(WEAPONS, e) & s);
1586         switch(op)
1587         {
1588                 case OP_SET:
1589                         if(val > 0)
1590                                 STAT(WEAPONS, e) |= s;
1591                         else
1592                                 STAT(WEAPONS, e) &= ~s;
1593                         break;
1594                 case OP_MIN:
1595                 case OP_PLUS:
1596                         if(val > 0)
1597                                 STAT(WEAPONS, e) |= s;
1598                         break;
1599                 case OP_MAX:
1600                         if(val <= 0)
1601                                 STAT(WEAPONS, e) &= ~s;
1602                         break;
1603                 case OP_MINUS:
1604                         if(val > 0)
1605                                 STAT(WEAPONS, e) &= ~s;
1606                         break;
1607         }
1608         v1 = (STAT(WEAPONS, e) & s);
1609         return (v0 != v1);
1610 }
1611
1612 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1613 {
1614         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1615         switch(op)
1616         {
1617                 case OP_SET:
1618                         if(val > 0)
1619                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1620                         else
1621                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1622                         break;
1623                 case OP_MIN:
1624                 case OP_PLUS:
1625                         if(val > 0)
1626                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1627                         break;
1628                 case OP_MAX:
1629                         if(val <= 0)
1630                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1631                         break;
1632                 case OP_MINUS:
1633                         if(val > 0)
1634                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1635                         break;
1636         }
1637         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1638         return (had_buff != have_buff);
1639 }
1640
1641 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1642 {
1643         if(v1 == v0)
1644                 return;
1645         if(v1 <= v0 - t)
1646         {
1647                 if(snd_decr != NULL)
1648                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1649         }
1650         else if(v0 >= v0 + t)
1651         {
1652                 if(snd_incr != NULL)
1653                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1654         }
1655 }
1656
1657 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1658 {
1659         if(v0 < v1)
1660                 e.(rotfield) = max(e.(rotfield), time + rottime);
1661         else if(v0 > v1)
1662                 e.(regenfield) = max(e.(regenfield), time + regentime);
1663 }
1664 float GiveItems(entity e, float beginarg, float endarg)
1665 {
1666         float got, i, val, op;
1667         string cmd;
1668
1669         val = 999;
1670         op = OP_SET;
1671
1672         got = 0;
1673
1674         int _switchweapon = 0;
1675
1676         if(CS(e).autoswitch)
1677         {
1678                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1679                 {
1680                         .entity weaponentity = weaponentities[slot];
1681                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1682                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1683                                 _switchweapon |= BIT(slot);
1684                 }
1685         }
1686
1687         e.strength_finished = max(0, e.strength_finished - time);
1688         e.invincible_finished = max(0, e.invincible_finished - time);
1689         e.superweapons_finished = max(0, e.superweapons_finished - time);
1690
1691         PREGIVE(e, items);
1692         PREGIVE_WEAPONS(e);
1693         PREGIVE(e, strength_finished);
1694         PREGIVE(e, invincible_finished);
1695         PREGIVE(e, superweapons_finished);
1696         PREGIVE(e, ammo_nails);
1697         PREGIVE(e, ammo_cells);
1698         PREGIVE(e, ammo_plasma);
1699         PREGIVE(e, ammo_shells);
1700         PREGIVE(e, ammo_rockets);
1701         PREGIVE(e, ammo_fuel);
1702         PREGIVE(e, armorvalue);
1703         PREGIVE(e, health);
1704
1705         for(i = beginarg; i < endarg; ++i)
1706         {
1707                 cmd = argv(i);
1708
1709                 if(cmd == "0" || stof(cmd))
1710                 {
1711                         val = stof(cmd);
1712                         continue;
1713                 }
1714                 switch(cmd)
1715                 {
1716                         case "no":
1717                                 op = OP_MAX;
1718                                 val = 0;
1719                                 continue;
1720                         case "max":
1721                                 op = OP_MAX;
1722                                 continue;
1723                         case "min":
1724                                 op = OP_MIN;
1725                                 continue;
1726                         case "plus":
1727                                 op = OP_PLUS;
1728                                 continue;
1729                         case "minus":
1730                                 op = OP_MINUS;
1731                                 continue;
1732                         case "ALL":
1733                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1734                                 got += GiveValue(e, strength_finished, op, val);
1735                                 got += GiveValue(e, invincible_finished, op, val);
1736                                 got += GiveValue(e, superweapons_finished, op, val);
1737                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1738                         case "all":
1739                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1740                                 got += GiveValue(e, health, op, val);
1741                                 got += GiveValue(e, armorvalue, op, val);
1742                         case "allweapons":
1743                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1744                         //case "allbuffs": // all buffs makes a player god, do not want!
1745                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1746                         case "allammo":
1747                                 got += GiveValue(e, ammo_cells, op, val);
1748                                 got += GiveValue(e, ammo_plasma, op, val);
1749                                 got += GiveValue(e, ammo_shells, op, val);
1750                                 got += GiveValue(e, ammo_nails, op, val);
1751                                 got += GiveValue(e, ammo_rockets, op, val);
1752                                 got += GiveValue(e, ammo_fuel, op, val);
1753                                 break;
1754                         case "unlimited_ammo":
1755                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1756                                 break;
1757                         case "unlimited_weapon_ammo":
1758                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1759                                 break;
1760                         case "unlimited_superweapons":
1761                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1762                                 break;
1763                         case "jetpack":
1764                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1765                                 break;
1766                         case "fuel_regen":
1767                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1768                                 break;
1769                         case "strength":
1770                                 got += GiveValue(e, strength_finished, op, val);
1771                                 break;
1772                         case "invincible":
1773                                 got += GiveValue(e, invincible_finished, op, val);
1774                                 break;
1775                         case "superweapons":
1776                                 got += GiveValue(e, superweapons_finished, op, val);
1777                                 break;
1778                         case "cells":
1779                                 got += GiveValue(e, ammo_cells, op, val);
1780                                 break;
1781                         case "plasma":
1782                                 got += GiveValue(e, ammo_plasma, op, val);
1783                                 break;
1784                         case "shells":
1785                                 got += GiveValue(e, ammo_shells, op, val);
1786                                 break;
1787                         case "nails":
1788                         case "bullets":
1789                                 got += GiveValue(e, ammo_nails, op, val);
1790                                 break;
1791                         case "rockets":
1792                                 got += GiveValue(e, ammo_rockets, op, val);
1793                                 break;
1794                         case "health":
1795                                 got += GiveValue(e, health, op, val);
1796                                 break;
1797                         case "armor":
1798                                 got += GiveValue(e, armorvalue, op, val);
1799                                 break;
1800                         case "fuel":
1801                                 got += GiveValue(e, ammo_fuel, op, val);
1802                                 break;
1803                         default:
1804                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1805                                 {
1806                                         got += GiveBuff(e, it, op, val);
1807                                         break;
1808                                 });
1809                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1810                     got += GiveWeapon(e, it.m_id, op, val);
1811                     break;
1812                                 });
1813                                 break;
1814                 }
1815                 val = 999;
1816                 op = OP_SET;
1817         }
1818
1819         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1820         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1821         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1822         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1823         FOREACH(Weapons, it != WEP_Null, {
1824                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1825                 if(!(save_weapons & (it.m_wepset)))
1826                         if(STAT(WEAPONS, e) & (it.m_wepset))
1827                                 it.wr_init(it);
1828         });
1829         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1830         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1831         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1832         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1833         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1834         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1835         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1836         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1837         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1838         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1839         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1840
1841         if(e.superweapons_finished <= 0)
1842                 if(STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1843                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1844
1845         if(e.strength_finished <= 0)
1846                 e.strength_finished = 0;
1847         else
1848                 e.strength_finished += time;
1849         if(e.invincible_finished <= 0)
1850                 e.invincible_finished = 0;
1851         else
1852                 e.invincible_finished += time;
1853         if(e.superweapons_finished <= 0)
1854                 e.superweapons_finished = 0;
1855         else
1856                 e.superweapons_finished += time;
1857
1858         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1859         {
1860                 .entity weaponentity = weaponentities[slot];
1861                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1862                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1863                         _switchweapon |= BIT(slot);
1864         }
1865
1866         if(_switchweapon)
1867         {
1868                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1869                 {
1870                         .entity weaponentity = weaponentities[slot];
1871                         if(_switchweapon & BIT(slot))
1872                         {
1873                                 Weapon wep = w_getbestweapon(e, weaponentity);
1874                                 if(wep != e.(weaponentity).m_switchweapon)
1875                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1876                         }
1877                 }
1878         }
1879
1880         return got;
1881 }
1882 #endif