qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2
   3 #include "../../../server/_all.qh"
   4
   5 #include "../../../server/g_subs.qh"
   6 #include "../../../server/waypointsprites.qh"
   7 #include "../../../server/g_damage.qh"
   8 #include "../../../server/bot/bot.qh"
   9 #include "../../common/csqcmodel_settings.qh"
  10 #include "../../../csqcmodellib/sv_model.qh"
  11 #include "../../../server/weapons/common.qh"
  12
  13 .entity sprite;
  14
  15 .float dmg;
  16 .float dmg_edge;
  17 .float dmg_radius;
  18 .float dmg_force;
  19 .float debrismovetype;
  20 .float debrissolid;
  21 .vector debrisvelocity;
  22 .vector debrisvelocityjitter;
  23 .vector debrisavelocityjitter;
  24 .float debristime;
  25 .float debristimejitter;
  26 .float debrisfadetime;
  27 .float debrisdamageforcescale;
  28 .float debrisskin;
  29
  30 .string mdl_dead; // or "" to hide when broken
  31 .string debris; // space separated list of debris models
  32 // other fields:
  33 //   mdl = particle effect name
  34 //   count = particle effect multiplier
  35 //   targetname = target to trigger to unbreak the model
  36 //   target = targets to trigger when broken
  37 //   health = amount of damage it can take
  38 //   spawnflags:
  39 //     1 = start disabled (needs to be triggered to activate)
  40 //     2 = indicate damage
  41 // notes:
  42 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  43 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  44 //   want that!
  45
  46 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  47
  48 //
  49 // func_breakable
  50 // - basically func_assault_destructible for general gameplay use
  51 //
  52 void LaunchDebris (string debrisname, vector force)
  53 {
  54         entity dbr = spawn();
  55         setorigin(dbr, self.absmin
  56                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  57                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  58                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  59         setmodel (dbr, debrisname );
  60         dbr.skin = self.debrisskin;
  61         dbr.colormap = self.colormap; // inherit team colors
  62         dbr.owner = self; // do not be affected by our own explosion
  63         dbr.movetype = self.debrismovetype;
  64         dbr.solid = self.debrissolid;
  65         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  66                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  67         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  68         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  69         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  70         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  71         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  72         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  73         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  74         dbr.damageforcescale = self.debrisdamageforcescale;
  75         if(dbr.damageforcescale)
  76                 dbr.takedamage = DAMAGE_YES;
  77         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  78 }
  79
  80 void func_breakable_colormod()
  81 {
  82         float h;
  83         if (!(self.spawnflags & 2))
  84                 return;
  85         h = self.health / self.max_health;
  86         if(h < 0.25)
  87                 self.colormod = '1 0 0';
  88         else if(h <= 0.75)
  89                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  90         else
  91                 self.colormod = '1 1 1';
  92
  93         CSQCMODEL_AUTOUPDATE();
  94 }
  95
  96 void func_breakable_look_destroyed()
  97 {
  98         float floorZ;
  99
 100         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
 101                 self.dropped_origin = self.origin;
 102
 103         if(self.mdl_dead == "")
 104                 self.effects |= EF_NODRAW;
 105         else {
 106                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 107                         floorZ = self.absmin.z;
 108                         setorigin(self,((self.absmax+self.absmin)*.5));
 109                         self.origin_z = floorZ;
 110                 }
 111                 setmodel(self, self.mdl_dead);
 112                 self.effects &= ~EF_NODRAW;
 113         }
 114
 115         CSQCMODEL_AUTOUPDATE();
 116
 117         self.solid = SOLID_NOT;
 118 }
 119
 120 void func_breakable_look_restore()
 121 {
 122         setmodel(self, self.mdl);
 123         self.effects &= ~EF_NODRAW;
 124
 125         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 126                 setorigin(self, self.dropped_origin);
 127
 128         CSQCMODEL_AUTOUPDATE();
 129
 130         self.solid = SOLID_BSP;
 131 }
 132
 133 void func_breakable_behave_destroyed()
 134 {
 135         self.health = self.max_health;
 136         self.takedamage = DAMAGE_NO;
 137         self.bot_attack = false;
 138         self.event_damage = func_null;
 139         self.state = 1;
 140         func_breakable_colormod();
 141         if (self.noise1)
 142                 stopsound (self, CH_TRIGGER_SINGLE);
 143 }
 144
 145 void func_breakable_behave_restore()
 146 {
 147         self.health = self.max_health;
 148         if(self.sprite)
 149         {
 150                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 151                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 152         }
 153         self.takedamage = DAMAGE_AIM;
 154         self.bot_attack = true;
 155         self.event_damage = func_breakable_damage;
 156         self.state = 0;
 157         self.nextthink = 0; // cancel auto respawn
 158         func_breakable_colormod();
 159         if (self.noise1)
 160                 sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 161 }
 162
 163 void func_breakable_init_for_player(entity player)
 164 {
 165         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 166         {
 167                 msg_entity = player;
 168                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 169         }
 170 }
 171
 172 void func_breakable_destroyed()
 173 {
 174         func_breakable_look_destroyed();
 175         func_breakable_behave_destroyed();
 176
 177         CSQCMODEL_AUTOUPDATE();
 178 }
 179
 180 void func_breakable_restore()
 181 {
 182         func_breakable_look_restore();
 183         func_breakable_behave_restore();
 184
 185         CSQCMODEL_AUTOUPDATE();
 186 }
 187
 188 vector debrisforce; // global, set before calling this
 189 void func_breakable_destroy() {
 190         float n, i;
 191         string oldmsg;
 192
 193         activator = self.owner;
 194         self.owner = world; // set by W_PrepareExplosionByDamage
 195
 196         // now throw around the debris
 197         n = tokenize_console(self.debris);
 198         for(i = 0; i < n; ++i)
 199                 LaunchDebris(argv(i), debrisforce);
 200
 201         func_breakable_destroyed();
 202
 203         if(self.noise)
 204                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 205
 206         if(self.dmg)
 207                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 208
 209         if(self.cnt)
 210                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 211
 212         if(self.respawntime)
 213         {
 214                 self.think = func_breakable_restore;
 215                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 216         }
 217
 218         oldmsg = self.message;
 219         self.message = "";
 220         SUB_UseTargets();
 221         self.message = oldmsg;
 222 }
 223
 224 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 225 {
 226         if(self.state == 1)
 227                 return;
 228         if(self.spawnflags & DOOR_NOSPLASH)
 229                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 230                         return;
 231         if(self.team)
 232                 if(attacker.team == self.team)
 233                         return;
 234         self.health = self.health - damage;
 235         if(self.sprite)
 236         {
 237                 WaypointSprite_Ping(self.sprite);
 238                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 239         }
 240         func_breakable_colormod();
 241
 242         if(self.health <= 0)
 243         {
 244                 debrisforce = force;
 245                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 246         }
 247 }
 248
 249 void func_breakable_reset()
 250 {
 251         self.team = self.team_saved;
 252         func_breakable_look_restore();
 253         if(self.spawnflags & 1)
 254                 func_breakable_behave_destroyed();
 255         else
 256                 func_breakable_behave_restore();
 257
 258         CSQCMODEL_AUTOUPDATE();
 259 }
 260
 261 // destructible walls that can be used to trigger target_objective_decrease
 262 void spawnfunc_func_breakable()
 263 {
 264         float n, i;
 265         if(!self.health)
 266                 self.health = 100;
 267         self.max_health = self.health;
 268
 269         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 270         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 271         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 272         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 273         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 274         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 275         if(!self.debristime) self.debristime = 3.5;
 276         if(!self.debristimejitter) self.debristime = 2.5;
 277
 278         if(self.mdl != "")
 279                 self.cnt = particleeffectnum(self.mdl);
 280         if(self.count == 0)
 281                 self.count = 1;
 282
 283         if(self.message == "")
 284                 self.message = "got too close to an explosion";
 285         if(self.message2 == "")
 286                 self.message2 = "was pushed into an explosion by";
 287         if(!self.dmg_radius)
 288                 self.dmg_radius = 150;
 289         if(!self.dmg_force)
 290                 self.dmg_force = 200;
 291
 292         self.mdl = self.model;
 293         SetBrushEntityModel();
 294
 295         self.use = func_breakable_restore;
 296
 297         // precache all the models
 298         if (self.mdl_dead)
 299                 precache_model(self.mdl_dead);
 300         n = tokenize_console(self.debris);
 301         for(i = 0; i < n; ++i)
 302                 precache_model(argv(i));
 303         if(self.noise)
 304                 precache_sound(self.noise);
 305         if(self.noise1)
 306                 precache_sound(self.noise1);
 307
 308         self.team_saved = self.team;
 309         self.dropped_origin = self.origin;
 310
 311         self.reset = func_breakable_reset;
 312         func_breakable_reset();
 313
 314         self.init_for_player_needed = 1;
 315         self.init_for_player = func_breakable_init_for_player;
 316
 317         CSQCMODEL_AUTOINIT();
 318 }
 319
 320 // for use in maps with a "model" key set
 321 void spawnfunc_misc_breakablemodel() {
 322         spawnfunc_func_breakable();
 323 }
 324 #endif