qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2
   3 #include "../../../server/_all.qh"
   4
   5 #include "../../../server/g_subs.qh"
   6 #include "../../../server/g_damage.qh"
   7 #include "../../../server/bot/bot.qh"
   8 #include "../../common/csqcmodel_settings.qh"
   9 #include "../../../csqcmodellib/sv_model.qh"
  10 #include "../../../server/weapons/common.qh"
  11
  12 .entity sprite;
  13
  14 .float dmg;
  15 .float dmg_edge;
  16 .float dmg_radius;
  17 .float dmg_force;
  18 .float debrismovetype;
  19 .float debrissolid;
  20 .vector debrisvelocity;
  21 .vector debrisvelocityjitter;
  22 .vector debrisavelocityjitter;
  23 .float debristime;
  24 .float debristimejitter;
  25 .float debrisfadetime;
  26 .float debrisdamageforcescale;
  27 .float debrisskin;
  28
  29 .string mdl_dead; // or "" to hide when broken
  30 .string debris; // space separated list of debris models
  31 // other fields:
  32 //   mdl = particle effect name
  33 //   count = particle effect multiplier
  34 //   targetname = target to trigger to unbreak the model
  35 //   target = targets to trigger when broken
  36 //   health = amount of damage it can take
  37 //   spawnflags:
  38 //     1 = start disabled (needs to be triggered to activate)
  39 //     2 = indicate damage
  40 //     4 = don't take direct damage (needs to be triggered to 'explode', then triggered again to restore)
  41 // notes:
  42 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  43 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  44 //   want that!
  45
  46 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  47
  48 //
  49 // func_breakable
  50 // - basically func_assault_destructible for general gameplay use
  51 //
  52 void LaunchDebris (string debrisname, vector force)
  53 {
  54         entity dbr = spawn();
  55         setorigin(dbr, self.absmin
  56                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  57                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  58                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  59         setmodel (dbr, debrisname );
  60         dbr.skin = self.debrisskin;
  61         dbr.colormap = self.colormap; // inherit team colors
  62         dbr.owner = self; // do not be affected by our own explosion
  63         dbr.movetype = self.debrismovetype;
  64         dbr.solid = self.debrissolid;
  65         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  66                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  67         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  68         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  69         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  70         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  71         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  72         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  73         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  74         dbr.damageforcescale = self.debrisdamageforcescale;
  75         if(dbr.damageforcescale)
  76                 dbr.takedamage = DAMAGE_YES;
  77         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  78 }
  79
  80 void func_breakable_colormod()
  81 {
  82         float h;
  83         if (!(self.spawnflags & 2))
  84                 return;
  85         h = self.health / self.max_health;
  86         if(h < 0.25)
  87                 self.colormod = '1 0 0';
  88         else if(h <= 0.75)
  89                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  90         else
  91                 self.colormod = '1 1 1';
  92
  93         CSQCMODEL_AUTOUPDATE();
  94 }
  95
  96 void func_breakable_look_destroyed()
  97 {
  98         float floorZ;
  99
 100         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
 101                 self.dropped_origin = self.origin;
 102
 103         if(self.mdl_dead == "")
 104                 self.effects |= EF_NODRAW;
 105         else {
 106                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 107                         floorZ = self.absmin.z;
 108                         setorigin(self,((self.absmax+self.absmin)*.5));
 109                         self.origin_z = floorZ;
 110                 }
 111                 setmodel(self, self.mdl_dead);
 112                 self.effects &= ~EF_NODRAW;
 113         }
 114
 115         CSQCMODEL_AUTOUPDATE();
 116
 117         self.solid = SOLID_NOT;
 118 }
 119
 120 void func_breakable_look_restore()
 121 {
 122         setmodel(self, self.mdl);
 123         self.effects &= ~EF_NODRAW;
 124
 125         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 126                 setorigin(self, self.dropped_origin);
 127
 128         CSQCMODEL_AUTOUPDATE();
 129
 130         self.solid = SOLID_BSP;
 131 }
 132
 133 void func_breakable_behave_destroyed()
 134 {
 135         self.health = self.max_health;
 136         self.takedamage = DAMAGE_NO;
 137         self.bot_attack = false;
 138         self.event_damage = func_null;
 139         self.state = 1;
 140         if(self.spawnflags & 4)
 141                 self.use = func_null;
 142         func_breakable_colormod();
 143         if (self.noise1)
 144                 stopsound (self, CH_TRIGGER_SINGLE);
 145 }
 146
 147 void func_breakable_behave_restore()
 148 {
 149         self.health = self.max_health;
 150         if(self.sprite)
 151         {
 152                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 153                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 154         }
 155         if(!(self.spawnflags & 4))
 156         {
 157                 self.takedamage = DAMAGE_AIM;
 158                 self.bot_attack = true;
 159                 self.event_damage = func_breakable_damage;
 160         }
 161         self.state = 0;
 162         self.nextthink = 0; // cancel auto respawn
 163         func_breakable_colormod();
 164         if (self.noise1)
 165                 sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 166 }
 167
 168 void func_breakable_init_for_player(entity player)
 169 {
 170         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 171         {
 172                 msg_entity = player;
 173                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 174         }
 175 }
 176
 177 void func_breakable_destroyed()
 178 {
 179         func_breakable_look_destroyed();
 180         func_breakable_behave_destroyed();
 181
 182         CSQCMODEL_AUTOUPDATE();
 183 }
 184
 185 void func_breakable_restore()
 186 {
 187         func_breakable_look_restore();
 188         func_breakable_behave_restore();
 189
 190         CSQCMODEL_AUTOUPDATE();
 191 }
 192
 193 vector debrisforce; // global, set before calling this
 194 void func_breakable_destroy() {
 195         float n, i;
 196         string oldmsg;
 197
 198         activator = self.owner;
 199         self.owner = world; // set by W_PrepareExplosionByDamage
 200
 201         // now throw around the debris
 202         n = tokenize_console(self.debris);
 203         for(i = 0; i < n; ++i)
 204                 LaunchDebris(argv(i), debrisforce);
 205
 206         func_breakable_destroyed();
 207
 208         if(self.noise)
 209                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 210
 211         if(self.dmg)
 212                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 213
 214         if(self.cnt) // TODO
 215                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 216
 217         if(self.respawntime)
 218         {
 219                 self.think = func_breakable_restore;
 220                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 221         }
 222
 223         oldmsg = self.message;
 224         self.message = "";
 225         SUB_UseTargets();
 226         self.message = oldmsg;
 227 }
 228
 229 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 230 {
 231         if(self.state == 1)
 232                 return;
 233         if(self.spawnflags & DOOR_NOSPLASH)
 234                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 235                         return;
 236         if(self.team)
 237                 if(attacker.team == self.team)
 238                         return;
 239         self.pain_finished = time;
 240         self.health = self.health - damage;
 241         if(self.sprite)
 242         {
 243                 WaypointSprite_Ping(self.sprite);
 244                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 245         }
 246         func_breakable_colormod();
 247
 248         if(self.health <= 0)
 249         {
 250                 debrisforce = force;
 251                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 252         }
 253 }
 254
 255 void func_breakable_reset()
 256 {
 257         self.team = self.team_saved;
 258         func_breakable_look_restore();
 259         if(self.spawnflags & 1)
 260                 func_breakable_behave_destroyed();
 261         else
 262                 func_breakable_behave_restore();
 263
 264         CSQCMODEL_AUTOUPDATE();
 265 }
 266
 267 // destructible walls that can be used to trigger target_objective_decrease
 268 void spawnfunc_func_breakable()
 269 {
 270         float n, i;
 271         if(!self.health)
 272                 self.health = 100;
 273         self.max_health = self.health;
 274
 275         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 276         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 277         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 278         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 279         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 280         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 281         if(!self.debristime) self.debristime = 3.5;
 282         if(!self.debristimejitter) self.debristime = 2.5;
 283
 284         if(self.mdl != "")
 285                 self.cnt = particleeffectnum(self.mdl);
 286         if(self.count == 0)
 287                 self.count = 1;
 288
 289         if(self.message == "")
 290                 self.message = "got too close to an explosion";
 291         if(self.message2 == "")
 292                 self.message2 = "was pushed into an explosion by";
 293         if(!self.dmg_radius)
 294                 self.dmg_radius = 150;
 295         if(!self.dmg_force)
 296                 self.dmg_force = 200;
 297
 298         self.mdl = self.model;
 299         SetBrushEntityModel();
 300
 301         if(self.spawnflags & 4)
 302                 self.use = func_breakable_destroy;
 303         else
 304                 self.use = func_breakable_restore;
 305
 306         if(self.spawnflags & 4)
 307         {
 308                 self.takedamage = DAMAGE_NO;
 309                 self.event_damage = func_null;
 310                 self.bot_attack = false;
 311         }
 312
 313         // precache all the models
 314         if (self.mdl_dead)
 315                 precache_model(self.mdl_dead);
 316         n = tokenize_console(self.debris);
 317         for(i = 0; i < n; ++i)
 318                 precache_model(argv(i));
 319         if(self.noise)
 320                 precache_sound(self.noise);
 321         if(self.noise1)
 322                 precache_sound(self.noise1);
 323
 324         self.team_saved = self.team;
 325         self.dropped_origin = self.origin;
 326
 327         self.reset = func_breakable_reset;
 328         func_breakable_reset();
 329
 330         self.init_for_player_needed = 1;
 331         self.init_for_player = func_breakable_init_for_player;
 332
 333         CSQCMODEL_AUTOINIT();
 334 }
 335
 336 // for use in maps with a "model" key set
 337 void spawnfunc_misc_breakablemodel() {
 338         spawnfunc_func_breakable();
 339 }
 340 #endif