qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2 #include "../../../server/weapons/common.qh"
   3
   4 .entity sprite;
   5
   6 .float dmg;
   7 .float dmg_edge;
   8 .float dmg_radius;
   9 .float dmg_force;
  10 .float debrismovetype;
  11 .float debrissolid;
  12 .vector debrisvelocity;
  13 .vector debrisvelocityjitter;
  14 .vector debrisavelocityjitter;
  15 .float debristime;
  16 .float debristimejitter;
  17 .float debrisfadetime;
  18 .float debrisdamageforcescale;
  19 .float debrisskin;
  20
  21 .string mdl_dead; // or "" to hide when broken
  22 .string debris; // space separated list of debris models
  23 // other fields:
  24 //   mdl = particle effect name
  25 //   count = particle effect multiplier
  26 //   targetname = target to trigger to unbreak the model
  27 //   target = targets to trigger when broken
  28 //   health = amount of damage it can take
  29 //   spawnflags:
  30 //     1 = start disabled (needs to be triggered to activate)
  31 //     2 = indicate damage
  32 // notes:
  33 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  34 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  35 //   want that!
  36
  37 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  38
  39 //
  40 // func_breakable
  41 // - basically func_assault_destructible for general gameplay use
  42 //
  43 void LaunchDebris (string debrisname, vector force)
  44 {
  45         entity dbr = spawn();
  46         setorigin(dbr, self.absmin
  47                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  48                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  49                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  50         setmodel (dbr, debrisname );
  51         dbr.skin = self.debrisskin;
  52         dbr.colormap = self.colormap; // inherit team colors
  53         dbr.owner = self; // do not be affected by our own explosion
  54         dbr.movetype = self.debrismovetype;
  55         dbr.solid = self.debrissolid;
  56         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  57                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  58         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  59         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  60         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  61         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  62         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  63         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  64         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  65         dbr.damageforcescale = self.debrisdamageforcescale;
  66         if(dbr.damageforcescale)
  67                 dbr.takedamage = DAMAGE_YES;
  68         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  69 }
  70
  71 void func_breakable_colormod()
  72 {
  73         float h;
  74         if (!(self.spawnflags & 2))
  75                 return;
  76         h = self.health / self.max_health;
  77         if(h < 0.25)
  78                 self.colormod = '1 0 0';
  79         else if(h <= 0.75)
  80                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  81         else
  82                 self.colormod = '1 1 1';
  83
  84         CSQCMODEL_AUTOUPDATE();
  85 }
  86
  87 void func_breakable_look_destroyed()
  88 {
  89         float floorZ;
  90
  91         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  92                 self.dropped_origin = self.origin;
  93
  94         if(self.mdl_dead == "")
  95                 self.effects |= EF_NODRAW;
  96         else {
  97                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  98                         floorZ = self.absmin.z;
  99                         setorigin(self,((self.absmax+self.absmin)*.5));
 100                         self.origin_z = floorZ;
 101                 }
 102                 setmodel(self, self.mdl_dead);
 103                 self.effects &= ~EF_NODRAW;
 104         }
 105
 106         CSQCMODEL_AUTOUPDATE();
 107
 108         self.solid = SOLID_NOT;
 109 }
 110
 111 void func_breakable_look_restore()
 112 {
 113         setmodel(self, self.mdl);
 114         self.effects &= ~EF_NODRAW;
 115
 116         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 117                 setorigin(self, self.dropped_origin);
 118
 119         CSQCMODEL_AUTOUPDATE();
 120
 121         self.solid = SOLID_BSP;
 122 }
 123
 124 void func_breakable_behave_destroyed()
 125 {
 126         self.health = self.max_health;
 127         self.takedamage = DAMAGE_NO;
 128         self.bot_attack = false;
 129         self.event_damage = func_null;
 130         self.state = 1;
 131         func_breakable_colormod();
 132         if (self.noise1)
 133                 stopsound (self, CH_TRIGGER_SINGLE);
 134 }
 135
 136 void func_breakable_behave_restore()
 137 {
 138         self.health = self.max_health;
 139         if(self.sprite)
 140         {
 141                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 142                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 143         }
 144         self.takedamage = DAMAGE_AIM;
 145         self.bot_attack = true;
 146         self.event_damage = func_breakable_damage;
 147         self.state = 0;
 148         self.nextthink = 0; // cancel auto respawn
 149         func_breakable_colormod();
 150         if (self.noise1)
 151                 sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 152 }
 153
 154 void func_breakable_init_for_player(entity player)
 155 {
 156         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 157         {
 158                 msg_entity = player;
 159                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 160         }
 161 }
 162
 163 void func_breakable_destroyed()
 164 {
 165         func_breakable_look_destroyed();
 166         func_breakable_behave_destroyed();
 167
 168         CSQCMODEL_AUTOUPDATE();
 169 }
 170
 171 void func_breakable_restore()
 172 {
 173         func_breakable_look_restore();
 174         func_breakable_behave_restore();
 175
 176         CSQCMODEL_AUTOUPDATE();
 177 }
 178
 179 vector debrisforce; // global, set before calling this
 180 void func_breakable_destroy() {
 181         float n, i;
 182         string oldmsg;
 183
 184         activator = self.owner;
 185         self.owner = world; // set by W_PrepareExplosionByDamage
 186
 187         // now throw around the debris
 188         n = tokenize_console(self.debris);
 189         for(i = 0; i < n; ++i)
 190                 LaunchDebris(argv(i), debrisforce);
 191
 192         func_breakable_destroyed();
 193
 194         if(self.noise)
 195                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 196
 197         if(self.dmg)
 198                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 199
 200         if(self.cnt)
 201                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 202
 203         if(self.respawntime)
 204         {
 205                 self.think = func_breakable_restore;
 206                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 207         }
 208
 209         oldmsg = self.message;
 210         self.message = "";
 211         SUB_UseTargets();
 212         self.message = oldmsg;
 213 }
 214
 215 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 216 {
 217         if(self.state == 1)
 218                 return;
 219         if(self.spawnflags & DOOR_NOSPLASH)
 220                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 221                         return;
 222         if(self.team)
 223                 if(attacker.team == self.team)
 224                         return;
 225         self.health = self.health - damage;
 226         if(self.sprite)
 227         {
 228                 WaypointSprite_Ping(self.sprite);
 229                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 230         }
 231         func_breakable_colormod();
 232
 233         if(self.health <= 0)
 234         {
 235                 debrisforce = force;
 236                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 237         }
 238 }
 239
 240 void func_breakable_reset()
 241 {
 242         self.team = self.team_saved;
 243         func_breakable_look_restore();
 244         if(self.spawnflags & 1)
 245                 func_breakable_behave_destroyed();
 246         else
 247                 func_breakable_behave_restore();
 248
 249         CSQCMODEL_AUTOUPDATE();
 250 }
 251
 252 // destructible walls that can be used to trigger target_objective_decrease
 253 void spawnfunc_func_breakable()
 254 {
 255         float n, i;
 256         if(!self.health)
 257                 self.health = 100;
 258         self.max_health = self.health;
 259
 260         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 261         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 262         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 263         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 264         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 265         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 266         if(!self.debristime) self.debristime = 3.5;
 267         if(!self.debristimejitter) self.debristime = 2.5;
 268
 269         if(self.mdl != "")
 270                 self.cnt = particleeffectnum(self.mdl);
 271         if(self.count == 0)
 272                 self.count = 1;
 273
 274         if(self.message == "")
 275                 self.message = "got too close to an explosion";
 276         if(self.message2 == "")
 277                 self.message2 = "was pushed into an explosion by";
 278         if(!self.dmg_radius)
 279                 self.dmg_radius = 150;
 280         if(!self.dmg_force)
 281                 self.dmg_force = 200;
 282
 283         self.mdl = self.model;
 284         SetBrushEntityModel();
 285
 286         self.use = func_breakable_restore;
 287
 288         // precache all the models
 289         if (self.mdl_dead)
 290                 precache_model(self.mdl_dead);
 291         n = tokenize_console(self.debris);
 292         for(i = 0; i < n; ++i)
 293                 precache_model(argv(i));
 294         if(self.noise)
 295                 precache_sound(self.noise);
 296         if(self.noise1)
 297                 precache_sound(self.noise1);
 298
 299         self.team_saved = self.team;
 300         self.dropped_origin = self.origin;
 301
 302         self.reset = func_breakable_reset;
 303         func_breakable_reset();
 304
 305         self.init_for_player_needed = 1;
 306         self.init_for_player = func_breakable_init_for_player;
 307
 308         CSQCMODEL_AUTOINIT();
 309 }
 310
 311 // for use in maps with a "model" key set
 312 void spawnfunc_misc_breakablemodel() {
 313         spawnfunc_func_breakable();
 314 }
 315 #endif