qcsrc/common/triggers/func/conveyor.qc

   1 #include "conveyor.qh"
   2 REGISTER_NET_LINKED(ENT_CLIENT_CONVEYOR)
   3
   4 void conveyor_think(entity this)
   5 {
   6 #ifdef CSQC
   7         // TODO: check if this is what is causing the glitchiness when switching between them
   8         float dt = time - this.move_time;
   9         this.move_time = time;
  10         if(dt <= 0) { return; }
  11 #endif
  12
  13         // set myself as current conveyor where possible
  14         IL_EACH(g_conveyed, it.conveyor == this,
  15         {
  16                 it.conveyor = NULL;
  17                 IL_REMOVE(g_conveyed, it);
  18         });
  19
  20         if(this.state)
  21         {
  22                 FOREACH_ENTITY_RADIUS((this.absmin + this.absmax) * 0.5, vlen(this.absmax - this.absmin) * 0.5 + 1, !it.conveyor.state && isPushable(it),
  23                 {
  24                         vector emin = it.absmin;
  25                         vector emax = it.absmax;
  26                         if(this.solid == SOLID_BSP)
  27                         {
  28                                 emin -= '1 1 1';
  29                                 emax += '1 1 1';
  30                         }
  31                         if(boxesoverlap(emin, emax, this.absmin, this.absmax)) // quick
  32                                 if(WarpZoneLib_BoxTouchesBrush(emin, emax, this, it)) // accurate
  33                                 {
  34                                         if(!it.conveyor)
  35                                                 IL_PUSH(g_conveyed, it);
  36                                         it.conveyor = this;
  37                                 }
  38                 });
  39
  40                 IL_EACH(g_conveyed, it.conveyor == this,
  41                 {
  42                         if(IS_CLIENT(it)) // doing it via velocity has quite some advantages
  43                                 continue; // done in SV_PlayerPhysics   continue;
  44
  45                         setorigin(it, it.origin + this.movedir * PHYS_INPUT_FRAMETIME);
  46                         move_out_of_solid(it);
  47 #ifdef SVQC
  48                         UpdateCSQCProjectile(it);
  49 #endif
  50                         /*
  51                         // stupid conveyor code
  52                         tracebox(it.origin, it.mins, it.maxs, it.origin + this.movedir * sys_frametime, MOVE_NORMAL, it);
  53                         if(trace_fraction > 0)
  54                                 setorigin(it, trace_endpos);
  55                         */
  56                 });
  57         }
  58
  59 #ifdef SVQC
  60         this.nextthink = time;
  61 #endif
  62 }
  63
  64 #ifdef SVQC
  65
  66 void conveyor_use(entity this, entity actor, entity trigger)
  67 {
  68         this.state = !this.state;
  69
  70         this.SendFlags |= 2;
  71 }
  72
  73 void conveyor_reset(entity this)
  74 {
  75         this.state = (this.spawnflags & 1);
  76
  77         this.SendFlags |= 2;
  78 }
  79
  80 bool conveyor_send(entity this, entity to, int sf)
  81 {
  82         WriteHeader(MSG_ENTITY, ENT_CLIENT_CONVEYOR);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 1)
  86         {
  87                 WriteByte(MSG_ENTITY, this.warpzone_isboxy);
  88                 WriteVector(MSG_ENTITY, this.origin);
  89
  90                 WriteVector(MSG_ENTITY, this.mins);
  91                 WriteVector(MSG_ENTITY, this.maxs);
  92
  93                 WriteVector(MSG_ENTITY, this.movedir);
  94
  95                 WriteByte(MSG_ENTITY, this.speed);
  96                 WriteByte(MSG_ENTITY, this.state);
  97
  98                 WriteString(MSG_ENTITY, this.targetname);
  99                 WriteString(MSG_ENTITY, this.target);
 100         }
 101
 102         if(sf & 2)
 103                 WriteByte(MSG_ENTITY, this.state);
 104
 105         return true;
 106 }
 107
 108 void conveyor_init(entity this)
 109 {
 110         if (!this.speed) this.speed = 200;
 111         this.movedir *= this.speed;
 112         setthink(this, conveyor_think);
 113         this.nextthink = time;
 114         IFTARGETED
 115         {
 116                 this.use = conveyor_use;
 117                 this.reset = conveyor_reset;
 118                 this.reset(this);
 119         }
 120         else
 121                 this.state = 1;
 122
 123         FixSize(this);
 124
 125         Net_LinkEntity(this, 0, false, conveyor_send);
 126
 127         this.SendFlags |= 1;
 128 }
 129
 130 spawnfunc(trigger_conveyor)
 131 {
 132         SetMovedir(this);
 133         EXACTTRIGGER_INIT;
 134         conveyor_init(this);
 135 }
 136
 137 spawnfunc(func_conveyor)
 138 {
 139         SetMovedir(this);
 140         InitMovingBrushTrigger(this);
 141         set_movetype(this, MOVETYPE_NONE);
 142         conveyor_init(this);
 143 }
 144
 145 #elif defined(CSQC)
 146
 147 void conveyor_draw(entity this) { conveyor_think(this); }
 148
 149 void conveyor_init(entity this, bool isnew)
 150 {
 151         if(isnew)
 152                 IL_PUSH(g_drawables, this);
 153         this.draw = conveyor_draw;
 154         this.drawmask = MASK_NORMAL;
 155
 156         set_movetype(this, MOVETYPE_NONE);
 157         this.model = "";
 158         this.solid = SOLID_TRIGGER;
 159         this.move_time = time;
 160 }
 161
 162 NET_HANDLE(ENT_CLIENT_CONVEYOR, bool isnew)
 163 {
 164         int sf = ReadByte();
 165
 166         if(sf & 1)
 167         {
 168                 this.warpzone_isboxy = ReadByte();
 169                 this.origin = ReadVector();
 170                 setorigin(this, this.origin);
 171
 172                 this.mins = ReadVector();
 173                 this.maxs = ReadVector();
 174                 setsize(this, this.mins, this.maxs);
 175
 176                 this.movedir = ReadVector();
 177
 178                 this.speed = ReadByte();
 179                 this.state = ReadByte();
 180
 181                 this.targetname = strzone(ReadString());
 182                 this.target = strzone(ReadString());
 183
 184                 conveyor_init(this, isnew);
 185         }
 186
 187         if(sf & 2)
 188                 this.state = ReadByte();
 189
 190         return true;
 191 }
 192 #endif