qcsrc/common/triggers/func/fourier.qc

   1 #ifdef SVQC
   2 /*QUAKED spawnfunc_func_fourier (0 .5 .8) ?
   3 Brush model that moves in a pattern of added up sine waves, can be used e.g. for circular motions.
   4 netname: list of <frequencymultiplier> <phase> <x> <y> <z> quadruples, separated by spaces; note that phase 0 represents a sine wave, and phase 0.25 a cosine wave (by default, it uses 1 0 0 0 1, to match func_bobbing's defaults
   5 speed: how long one cycle of frequency multiplier 1 in seconds (default 4)
   6 height: amplitude modifier (default 32)
   7 phase: cycle timing adjustment (0-1 as a fraction of the cycle, default 0)
   8 noise: path/name of looping .wav file to play.
   9 dmg: Do this mutch dmg every .dmgtime intervall when blocked
  10 dmgtime: See above.
  11 */
  12
  13 void func_fourier_controller_think()
  14 {
  15         vector v;
  16         float n, i, t;
  17
  18         self.nextthink = time + 0.1;
  19         if(self.owner.active != ACTIVE_ACTIVE)
  20         {
  21                 self.owner.velocity = '0 0 0';
  22                 return;
  23         }
  24
  25
  26         n = floor((tokenize_console(self.owner.netname)) / 5);
  27         t = self.nextthink * self.owner.cnt + self.owner.phase * 360;
  28
  29         v = self.owner.destvec;
  30
  31         for(i = 0; i < n; ++i)
  32         {
  33                 makevectors((t * stof(argv(i*5)) + stof(argv(i*5+1)) * 360) * '0 1 0');
  34                 v = v + ('1 0 0' * stof(argv(i*5+2)) + '0 1 0' * stof(argv(i*5+3)) + '0 0 1' * stof(argv(i*5+4))) * self.owner.height * v_forward_y;
  35         }
  36
  37         if(self.owner.classname == "func_fourier") // don't brake stuff if the func_fourier was killtarget'ed
  38                 // * 10 so it will arrive in 0.1 sec
  39                 self.owner.velocity = (v - self.owner.origin) * 10;
  40 }
  41
  42 void spawnfunc_func_fourier()
  43 {
  44         entity controller;
  45         if (self.noise != "")
  46         {
  47                 precache_sound(self.noise);
  48                 soundto(MSG_INIT, self, CH_TRIGGER_SINGLE, self.noise, VOL_BASE, ATTEN_IDLE);
  49         }
  50
  51         if (!self.speed)
  52                 self.speed = 4;
  53         if (!self.height)
  54                 self.height = 32;
  55         self.destvec = self.origin;
  56         self.cnt = 360 / self.speed;
  57
  58         self.blocked = generic_plat_blocked;
  59         if(self.dmg && (self.message == ""))
  60                 self.message = " was squished";
  61     if(self.dmg && (self.message2 == ""))
  62                 self.message2 = "was squished by";
  63         if(self.dmg && (!self.dmgtime))
  64                 self.dmgtime = 0.25;
  65         self.dmgtime2 = time;
  66
  67         if(self.netname == "")
  68                 self.netname = "1 0 0 0 1";
  69
  70         if (!InitMovingBrushTrigger())
  71                 return;
  72
  73         self.active = ACTIVE_ACTIVE;
  74
  75         // wait for targets to spawn
  76         controller = spawn();
  77         controller.classname = "func_fourier_controller";
  78         controller.owner = self;
  79         controller.nextthink = time + 1;
  80         controller.think = func_fourier_controller_think;
  81         self.SUB_NEXTTHINK = self.SUB_LTIME + 999999999;
  82         self.SUB_THINK = SUB_NullThink; // for PushMove
  83
  84         // Savage: Reduce bandwith, critical on e.g. nexdm02
  85         self.effects |= EF_LOWPRECISION;
  86
  87         // TODO make a reset function for this one
  88 }
  89 #endif