qcsrc/common/triggers/target/spawn.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../../server/_all.qh"
   5     #include "../../util.qh"
   6     #include "../../../server/defs.qh"
   7 #endif
   8
   9 #ifdef SVQC
  10
  11 // spawner entity
  12 // "classname" "target_spawn"
  13 // "message" "fieldname value fieldname value ..."
  14 // "spawnflags"
  15 //   1 = call the spawn function
  16 //   2 = trigger on map load
  17
  18 float target_spawn_initialized;
  19 .void() target_spawn_spawnfunc;
  20 float target_spawn_spawnfunc_field;
  21 .entity target_spawn_activator;
  22 .float target_spawn_id;
  23 float target_spawn_count;
  24
  25 void target_spawn_helper_setmodel()
  26 {
  27         setmodel(self, self.model);
  28 }
  29
  30 void target_spawn_helper_setsize()
  31 {
  32         setsize(self, self.mins, self.maxs);
  33 }
  34
  35 void target_spawn_edit_entity(entity e, string msg, entity kt, entity t2, entity t3, entity t4, entity act)
  36 {
  37         float i, n, valuefieldpos;
  38         string key, value, valuefield, valueoffset, valueoffsetrandom;
  39         entity valueent;
  40         vector data, data2;
  41         entity oldself;
  42         entity oldactivator;
  43
  44         n = tokenize_console(msg);
  45
  46         for(i = 0; i < n-1; i += 2)
  47         {
  48                 key = argv(i);
  49                 value = argv(i+1);
  50                 if(key == "$")
  51                 {
  52                         data.x = -1;
  53                         data.y = FIELD_STRING;
  54                 }
  55                 else
  56                 {
  57                         data = stov(db_get(TemporaryDB, strcat("/target_spawn/field/", key)));
  58                         if(data.y == 0) // undefined field, i.e., invalid type
  59                         {
  60                                 LOG_INFO("target_spawn: invalid/unknown entity key ", key, " specified, ignored!\n");
  61                                 continue;
  62                         }
  63                 }
  64                 if(substring(value, 0, 1) == "$")
  65                 {
  66                         value = substring(value, 1, strlen(value) - 1);
  67                         if(substring(value, 0, 1) == "$")
  68                         {
  69                                 // deferred replacement
  70                                 // do nothing
  71                                 // useful for creating target_spawns with this!
  72                         }
  73                         else
  74                         {
  75                                 // replace me!
  76                                 valuefieldpos = strstrofs(value, "+", 0);
  77                                 valueoffset = "";
  78                                 if(valuefieldpos != -1)
  79                                 {
  80                                         valueoffset = substring(value, valuefieldpos + 1, strlen(value) - valuefieldpos - 1);
  81                                         value = substring(value, 0, valuefieldpos);
  82                                 }
  83
  84                                 valuefieldpos = strstrofs(valueoffset, "+", 0);
  85                                 valueoffsetrandom = "";
  86                                 if(valuefieldpos != -1)
  87                                 {
  88                                         valueoffsetrandom = substring(valueoffset, valuefieldpos + 1, strlen(valueoffset) - valuefieldpos - 1);
  89                                         valueoffset = substring(valueoffset, 0, valuefieldpos);
  90                                 }
  91
  92                                 valuefieldpos = strstrofs(value, ".", 0);
  93                                 valuefield = "";
  94                                 if(valuefieldpos != -1)
  95                                 {
  96                                         valuefield = substring(value, valuefieldpos + 1, strlen(value) - valuefieldpos - 1);
  97                                         value = substring(value, 0, valuefieldpos);
  98                                 }
  99
 100                                 if(value == "self")
 101                                 {
 102                                         valueent = self;
 103                                         value = "";
 104                                 }
 105                                 else if(value == "activator")
 106                                 {
 107                                         valueent = act;
 108                                         value = "";
 109                                 }
 110                                 else if(value == "other")
 111                                 {
 112                                         valueent = other;
 113                                         value = "";
 114                                 }
 115                                 else if(value == "pusher")
 116                                 {
 117                                         if(time < act.pushltime)
 118                                                 valueent = act.pusher;
 119                                         else
 120                                                 valueent = world;
 121                                         value = "";
 122                                 }
 123                                 else if(value == "target")
 124                                 {
 125                                         valueent = e;
 126                                         value = "";
 127                                 }
 128                                 else if(value == "killtarget")
 129                                 {
 130                                         valueent = kt;
 131                                         value = "";
 132                                 }
 133                                 else if(value == "target2")
 134                                 {
 135                                         valueent = t2;
 136                                         value = "";
 137                                 }
 138                                 else if(value == "target3")
 139                                 {
 140                                         valueent = t3;
 141                                         value = "";
 142                                 }
 143                                 else if(value == "target4")
 144                                 {
 145                                         valueent = t4;
 146                                         value = "";
 147                                 }
 148                                 else if(value == "time")
 149                                 {
 150                                         valueent = world;
 151                                         value = ftos(time);
 152                                 }
 153                                 else
 154                                 {
 155                                         LOG_INFO("target_spawn: invalid/unknown variable replacement ", value, " specified, ignored!\n");
 156                                         continue;
 157                                 }
 158
 159                                 if(valuefield == "")
 160                                 {
 161                                         if(value == "")
 162                                                 value = ftos(num_for_edict(valueent));
 163                                 }
 164                                 else
 165                                 {
 166                                         if(value != "")
 167                                         {
 168                                                 LOG_INFO("target_spawn: try to get a field of a non-entity, ignored!\n");
 169                                                 continue;
 170                                         }
 171                                         data2 = stov(db_get(TemporaryDB, strcat("/target_spawn/field/", valuefield)));
 172                                         if(data2_y == 0) // undefined field, i.e., invalid type
 173                                         {
 174                                                 LOG_INFO("target_spawn: invalid/unknown entity key replacement ", valuefield, " specified, ignored!\n");
 175                                                 continue;
 176                                         }
 177                                         value = getentityfieldstring(data2_x, valueent);
 178                                 }
 179
 180                                 if(valueoffset != "")
 181                                 {
 182                                         switch(data.y)
 183                                         {
 184                                                 case FIELD_STRING:
 185                                                         value = strcat(value, valueoffset);
 186                                                         break;
 187                                                 case FIELD_FLOAT:
 188                                                         value = ftos(stof(value) + stof(valueoffset));
 189                                                         break;
 190                                                 case FIELD_VECTOR:
 191                                                         value = vtos(stov(value) + stov(valueoffset));
 192                                                         break;
 193                                                 default:
 194                                                         LOG_INFO("target_spawn: only string, float and vector fields can do calculations, calculation ignored!\n");
 195                                                         break;
 196                                         }
 197                                 }
 198
 199                                 if(valueoffsetrandom != "")
 200                                 {
 201                                         switch(data.y)
 202                                         {
 203                                                 case FIELD_FLOAT:
 204                                                         value = ftos(stof(value) + random() * stof(valueoffsetrandom));
 205                                                         break;
 206                                                 case FIELD_VECTOR:
 207                                                         data2 = stov(valueoffsetrandom);
 208                                                         value = vtos(stov(value) + random() * data2_x * '1 0 0' + random() * data2_y * '0 1 0' + random() * data2_z * '0 0 1');
 209                                                         break;
 210                                                 default:
 211                                                         LOG_INFO("target_spawn: only float and vector fields can do random calculations, calculation ignored!\n");
 212                                                         break;
 213                                         }
 214                                 }
 215                         }
 216                 }
 217                 if(key == "$")
 218                 {
 219                         if(substring(value, 0, 1) == "_")
 220                                 value = strcat("target_spawn_helper", value);
 221                         putentityfieldstring(target_spawn_spawnfunc_field, e, value);
 222
 223                         oldself = self;
 224                         oldactivator = activator;
 225
 226                         self = e;
 227                         activator = act;
 228
 229                         self.target_spawn_spawnfunc();
 230
 231                         self = oldself;
 232                         activator = oldactivator;
 233
 234                         // We called an external function, so we have to re-tokenize msg.
 235                         n = tokenize_console(msg);
 236                 }
 237                 else
 238                 {
 239                         if(data.y == FIELD_VECTOR)
 240                                 value = strreplace("'", "", value); // why?!?
 241                         putentityfieldstring(data.x, e, value);
 242                 }
 243         }
 244 }
 245
 246 void target_spawn_useon(entity e)
 247 {
 248         self.target_spawn_activator = activator;
 249         target_spawn_edit_entity(
 250                 e,
 251                 self.message,
 252                 find(world, targetname, self.killtarget),
 253                 find(world, targetname, self.target2),
 254                 find(world, targetname, self.target3),
 255                 find(world, targetname, self.target4),
 256                 activator
 257         );
 258 }
 259
 260 float target_spawn_cancreate()
 261 {
 262         float c;
 263         entity e;
 264
 265         c = self.count;
 266         if(c == 0) // no limit?
 267                 return 1;
 268
 269         ++c; // increase count to not include MYSELF
 270         for(e = world; (e = findfloat(e, target_spawn_id, self.target_spawn_id)); --c)
 271                 ;
 272
 273         // if c now is 0, we have AT LEAST the given count (maybe more), so don't spawn any more
 274         if(c == 0)
 275                 return 0;
 276         return 1;
 277 }
 278
 279 void target_spawn_use()
 280 {
 281         entity e;
 282
 283         if(self.target == "")
 284         {
 285                 // spawn new entity
 286                 if(!target_spawn_cancreate())
 287                         return;
 288                 e = spawn();
 289                 target_spawn_useon(e);
 290                 e.target_spawn_id = self.target_spawn_id;
 291         }
 292         else if(self.target == "*activator")
 293         {
 294                 // edit entity
 295                 if(activator)
 296                         target_spawn_useon(activator);
 297         }
 298         else
 299         {
 300                 // edit entity
 301                 for(e = world; (e = find(e, targetname, self.target)); )
 302                         target_spawn_useon(e);
 303         }
 304 }
 305
 306 void target_spawn_spawnfirst()
 307 {
 308         activator = self.target_spawn_activator;
 309         if(self.spawnflags & 2)
 310                 target_spawn_use();
 311 }
 312
 313 void initialize_field_db()
 314 {
 315         if(!target_spawn_initialized)
 316         {
 317                 float n, i;
 318                 string fn;
 319                 vector prev, next;
 320                 float ft;
 321
 322                 n = numentityfields();
 323                 for(i = 0; i < n; ++i)
 324                 {
 325                         fn = entityfieldname(i);
 326                         ft = entityfieldtype(i);
 327                         next = i * '1 0 0' + ft * '0 1 0' + '0 0 1';
 328                         prev = stov(db_get(TemporaryDB, strcat("/target_spawn/field/", fn)));
 329                         if(prev.y == 0)
 330                         {
 331                                 db_put(TemporaryDB, strcat("/target_spawn/field/", fn), vtos(next));
 332                                 if(fn == "target_spawn_spawnfunc")
 333                                         target_spawn_spawnfunc_field = i;
 334                         }
 335                 }
 336
 337                 target_spawn_initialized = 1;
 338         }
 339 }
 340
 341 void spawnfunc_target_spawn()
 342 {
 343         initialize_field_db();
 344         self.use = target_spawn_use;
 345         self.message = strzone(strreplace("'", "\"", self.message));
 346         self.target_spawn_id = ++target_spawn_count;
 347         InitializeEntity(self, target_spawn_spawnfirst, INITPRIO_LAST);
 348 }
 349 #endif