Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / triggers / trigger / jumppads.qc
1 // TODO: split target_push and put it in the target folder
2 #ifdef SVQC
3 #include "jumppads.qh"
4 #include <common/physics/movetypes/movetypes.qh>
5
6 void trigger_push_use()
7 {SELFPARAM();
8         if(teamplay)
9         {
10                 self.team = activator.team;
11                 self.SendFlags |= 2;
12         }
13 }
14 #endif
15
16 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
17 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
18
19 /*
20         trigger_push_calculatevelocity
21
22         Arguments:
23           org - origin of the object which is to be pushed
24           tgt - target entity (can be either a point or a model entity; if it is
25                 the latter, its midpoint is used)
26           ht  - jump height, measured from the higher one of org and tgt's midpoint
27
28         Returns: velocity for the jump
29         the global trigger_push_calculatevelocity_flighttime is set to the total
30         jump time
31  */
32
33 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
34 {
35         float grav, sdist, zdist, vs, vz, jumpheight;
36         vector sdir, torg;
37
38         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
39
40         grav = PHYS_GRAVITY(other);
41         if(PHYS_ENTGRAVITY(other))
42                 grav *= PHYS_ENTGRAVITY(other);
43
44         zdist = torg.z - org.z;
45         sdist = vlen(torg - org - zdist * '0 0 1');
46         sdir = normalize(torg - org - zdist * '0 0 1');
47
48         // how high do we need to push the player?
49         jumpheight = fabs(ht);
50         if(zdist > 0)
51                 jumpheight = jumpheight + zdist;
52
53         /*
54                 STOP.
55
56                 You will not understand the following equations anyway...
57                 But here is what I did to get them.
58
59                 I used the functions
60
61                   s(t) = t * vs
62                   z(t) = t * vz - 1/2 grav t^2
63
64                 and solved for:
65
66                   s(ti) = sdist
67                   z(ti) = zdist
68                   max(z, ti) = jumpheight
69
70                 From these three equations, you will find the three parameters vs, vz
71                 and ti.
72          */
73
74         // push him so high...
75         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
76
77         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
78         if(ht < 0)
79                 if(zdist < 0)
80                         vz = -vz;
81
82         vector solution;
83         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
84         // ALWAYS solvable because jumpheight >= zdist
85         if(!solution.z)
86                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
87         if(zdist == 0)
88                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
89
90         if(zdist < 0)
91         {
92                 // down-jump
93                 if(ht < 0)
94                 {
95                         // almost straight line type
96                         // jump apex is before the jump
97                         // we must take the larger one
98                         trigger_push_calculatevelocity_flighttime = solution.y;
99                 }
100                 else
101                 {
102                         // regular jump
103                         // jump apex is during the jump
104                         // we must take the larger one too
105                         trigger_push_calculatevelocity_flighttime = solution.y;
106                 }
107         }
108         else
109         {
110                 // up-jump
111                 if(ht < 0)
112                 {
113                         // almost straight line type
114                         // jump apex is after the jump
115                         // we must take the smaller one
116                         trigger_push_calculatevelocity_flighttime = solution.x;
117                 }
118                 else
119                 {
120                         // regular jump
121                         // jump apex is during the jump
122                         // we must take the larger one
123                         trigger_push_calculatevelocity_flighttime = solution.y;
124                 }
125         }
126         vs = sdist / trigger_push_calculatevelocity_flighttime;
127
128         // finally calculate the velocity
129         return sdir * vs + '0 0 1' * vz;
130 }
131
132 void trigger_push_touch()
133 {SELFPARAM();
134         if (this.active == ACTIVE_NOT)
135                 return;
136
137         if (!isPushable(other))
138                 return;
139
140         if(this.team)
141                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, other)))
142                         return;
143
144         EXACTTRIGGER_TOUCH;
145
146         if(this.enemy)
147         {
148                 other.velocity = trigger_push_calculatevelocity(other.origin, this.enemy, this.height);
149                 other.move_velocity = other.velocity;
150         }
151         else if(this.target)
152         {
153                 entity e;
154                 RandomSelection_Init();
155                 for(e = world; (e = find(e, targetname, this.target)); )
156                 {
157                         if(e.cnt)
158                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
159                         else
160                                 RandomSelection_Add(e, 0, string_null, 1, 1);
161                 }
162                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, this.height);
163                 other.move_velocity = other.velocity;
164         }
165         else
166         {
167                 other.velocity = this.movedir;
168                 other.move_velocity = other.velocity;
169         }
170
171 #ifdef SVQC
172         UNSET_ONGROUND(other);
173 #elif defined(CSQC)
174         other.move_flags &= ~FL_ONGROUND;
175
176         if (other.flags & FL_PROJECTILE)
177         {
178                 other.move_angles = vectoangles (other.move_velocity);
179                 switch(other.move_movetype)
180                 {
181                         case MOVETYPE_FLY:
182                                 other.move_movetype = MOVETYPE_TOSS;
183                                 other.gravity = 1;
184                                 break;
185                         case MOVETYPE_BOUNCEMISSILE:
186                                 other.move_movetype = MOVETYPE_BOUNCE;
187                                 other.gravity = 1;
188                                 break;
189                 }
190         }
191 #endif
192
193 #ifdef SVQC
194         if (IS_PLAYER(other))
195         {
196                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
197                 other.oldvelocity = other.velocity;
198
199                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
200                 {
201                         // flash when activated
202                         Send_Effect(EFFECT_JUMPPAD, other.origin, other.velocity, 1);
203                         _sound (other, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
204                         this.pushltime = time + 0.2;
205                 }
206                 if(IS_REAL_CLIENT(other) || IS_BOT_CLIENT(other))
207                 {
208                         bool found = false;
209                         for(int i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
210                                 if(other.(jumppadsused[i]) == this)
211                                         found = true;
212                         if(!found)
213                         {
214                                 other.(jumppadsused[other.jumppadcount % NUM_JUMPPADSUSED]) = this;
215                                 other.jumppadcount = other.jumppadcount + 1;
216                         }
217
218                         if(IS_REAL_CLIENT(other))
219                         {
220                                 if(this.message)
221                                         centerprint(other, this.message);
222                         }
223                         else
224                                 other.lastteleporttime = time;
225
226                         if (other.deadflag == DEAD_NO)
227                                 animdecide_setaction(other, ANIMACTION_JUMP, true);
228                 }
229                 else
230                         other.jumppadcount = true;
231
232                 // reset tracking of who pushed you into a hazard (for kill credit)
233                 other.pushltime = 0;
234                 other.istypefrag = 0;
235         }
236
237         if(this.enemy.target)
238         {
239                 activator = other;
240                 WITH(entity, self, this.enemy, SUB_UseTargets());
241         }
242
243         if (other.flags & FL_PROJECTILE)
244         {
245                 other.angles = vectoangles (other.velocity);
246                 switch(other.movetype)
247                 {
248                         case MOVETYPE_FLY:
249                                 other.movetype = MOVETYPE_TOSS;
250                                 other.gravity = 1;
251                                 break;
252                         case MOVETYPE_BOUNCEMISSILE:
253                                 other.movetype = MOVETYPE_BOUNCE;
254                                 other.gravity = 1;
255                                 break;
256                 }
257                 UpdateCSQCProjectile(other);
258         }
259
260         /*if (other.flags & FL_ITEM)
261         {
262                 ItemUpdate(other);
263                 other.SendFlags |= ISF_DROP;
264         }*/
265
266         if (this.spawnflags & PUSH_ONCE)
267         {
268                 this.touch = func_null;
269                 this.think = SUB_Remove_self;
270                 this.nextthink = time;
271         }
272 #endif
273 }
274
275 #ifdef SVQC
276 void trigger_push_link();
277 void trigger_push_updatelink();
278 #endif
279 void trigger_push_findtarget()
280 {SELFPARAM();
281         entity t;
282         vector org;
283
284         // first calculate a typical start point for the jump
285         org = (self.absmin + self.absmax) * 0.5;
286         org_z = self.absmax.z - STAT(PL_MIN, NULL).z;
287
288         if (self.target)
289         {
290                 float n = 0;
291                 for(t = world; (t = find(t, targetname, self.target)); )
292                 {
293                         ++n;
294 #ifdef SVQC
295                         entity e = spawn();
296                         setorigin(e, org);
297                         setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
298                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
299                         tracetoss(e, e);
300                         if(e.movetype == MOVETYPE_NONE)
301                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
302                         remove(e);
303 #endif
304                 }
305
306                 if(!n)
307                 {
308                         // no dest!
309 #ifdef SVQC
310                         objerror ("Jumppad with nonexistant target");
311 #endif
312                         return;
313                 }
314                 else if(n == 1)
315                 {
316                         // exactly one dest - bots love that
317                         self.enemy = find(world, targetname, self.target);
318                 }
319                 else
320                 {
321                         // have to use random selection every single time
322                         self.enemy = world;
323                 }
324         }
325 #ifdef SVQC
326         else
327         {
328                 entity e = spawn();
329                 setorigin(e, org);
330                 setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
331                 e.velocity = self.movedir;
332                 tracetoss(e, e);
333                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
334                 remove(e);
335         }
336
337         trigger_push_link();
338         defer(self, 0.1, trigger_push_updatelink);
339 #endif
340 }
341
342 #ifdef SVQC
343 float trigger_push_send(entity this, entity to, float sf)
344 {
345         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
346
347         WriteByte(MSG_ENTITY, self.team);
348         WriteInt24_t(MSG_ENTITY, self.spawnflags);
349         WriteByte(MSG_ENTITY, self.active);
350         WriteCoord(MSG_ENTITY, self.height);
351
352         trigger_common_write(self, true);
353
354         return true;
355 }
356
357 void trigger_push_updatelink()
358 {SELFPARAM();
359         self.SendFlags |= 1;
360 }
361
362 void trigger_push_link()
363 {
364         trigger_link(self, trigger_push_send);
365 }
366
367 /*
368  * ENTITY PARAMETERS:
369  *
370  *   target:  target of jump
371  *   height:  the absolute value is the height of the highest point of the jump
372  *            trajectory above the higher one of the player and the target.
373  *            the sign indicates whether the highest point is INSIDE (positive)
374  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
375  *            positive values for targets mounted on the floor, and use negative
376  *            values to target a point on the ceiling.
377  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
378  */
379 spawnfunc(trigger_push)
380 {
381         SetMovedir(self);
382
383         trigger_init(self);
384
385         self.active = ACTIVE_ACTIVE;
386         self.use = trigger_push_use;
387         self.touch = trigger_push_touch;
388
389         // normal push setup
390         if (!self.speed)
391                 self.speed = 1000;
392         self.movedir = self.movedir * self.speed * 10;
393
394         if (!self.noise)
395                 self.noise = "misc/jumppad.wav";
396         precache_sound (self.noise);
397
398         // this must be called to spawn the teleport waypoints for bots
399         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
400 }
401
402
403 bool target_push_send(entity this, entity to, float sf)
404 {
405         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
406
407         WriteByte(MSG_ENTITY, self.cnt);
408         WriteString(MSG_ENTITY, self.targetname);
409         WriteCoord(MSG_ENTITY, self.origin_x);
410         WriteCoord(MSG_ENTITY, self.origin_y);
411         WriteCoord(MSG_ENTITY, self.origin_z);
412
413         WriteAngle(MSG_ENTITY, self.angles_x);
414         WriteAngle(MSG_ENTITY, self.angles_y);
415         WriteAngle(MSG_ENTITY, self.angles_z);
416
417         return true;
418 }
419
420 void target_push_link()
421 {SELFPARAM();
422         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
423         Net_LinkEntity(self, false, 0, target_push_send);
424         //self.SendFlags |= 1; // update
425 }
426
427 spawnfunc(target_push) { target_push_link(); }
428 spawnfunc(info_notnull) { target_push_link(); }
429 spawnfunc(target_position) { make_pure(this); target_push_link(); }
430
431 #elif defined(CSQC)
432
433 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
434 {
435         make_pure(this);
436
437         self.classname = "jumppad";
438         int mytm = ReadByte(); if(mytm) { self.team = mytm - 1; }
439         self.spawnflags = ReadInt24_t();
440         self.active = ReadByte();
441         self.height = ReadCoord();
442
443         trigger_common_read(true);
444
445         self.entremove = trigger_remove_generic;
446         self.solid = SOLID_TRIGGER;
447         //self.draw = trigger_draw_generic;
448         self.move_touch = trigger_push_touch;
449         self.drawmask = MASK_NORMAL;
450         self.move_time = time;
451         defer(self, 0.25, trigger_push_findtarget);
452
453         return true;
454 }
455
456 void target_push_remove()
457 {SELFPARAM();
458         if(self.classname)
459                 strunzone(self.classname);
460         self.classname = string_null;
461
462         if(self.targetname)
463                 strunzone(self.targetname);
464         self.targetname = string_null;
465 }
466
467 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
468 {
469         make_pure(this);
470         self.classname = "push_target";
471         self.cnt = ReadByte();
472         self.targetname = strzone(ReadString());
473         self.origin_x = ReadCoord();
474         self.origin_y = ReadCoord();
475         self.origin_z = ReadCoord();
476
477         self.angles_x = ReadAngle();
478         self.angles_y = ReadAngle();
479         self.angles_z = ReadAngle();
480
481         return = true;
482
483         setorigin(self, self.origin);
484
485         self.drawmask = MASK_NORMAL;
486         self.entremove = target_push_remove;
487 }
488 #endif