qcsrc/common/triggers/trigger/jumppads.qc

   1 // TODO: split target_push and put it in the target folder
   2 #ifdef SVQC
   3 #include "jumppads.qh"
   4 #include <common/physics/movetypes/movetypes.qh>
   5
   6 void trigger_push_use(entity this, entity actor, entity trigger)
   7 {
   8         if(teamplay)
   9         {
  10                 this.team = actor.team;
  11                 this.SendFlags |= 2;
  12         }
  13 }
  14 #endif
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  17 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  18
  19 /*
  20         trigger_push_calculatevelocity
  21
  22         Arguments:
  23           org - origin of the object which is to be pushed
  24           tgt - target entity (can be either a point or a model entity; if it is
  25                 the latter, its midpoint is used)
  26           ht  - jump height, measured from the higher one of org and tgt's midpoint
  27
  28         Returns: velocity for the jump
  29         the global trigger_push_calculatevelocity_flighttime is set to the total
  30         jump time
  31  */
  32
  33 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  34 {
  35         float grav, sdist, zdist, vs, vz, jumpheight;
  36         vector sdir, torg;
  37
  38         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  39
  40         grav = PHYS_GRAVITY(other);
  41         if(PHYS_ENTGRAVITY(other))
  42                 grav *= PHYS_ENTGRAVITY(other);
  43
  44         zdist = torg.z - org.z;
  45         sdist = vlen(torg - org - zdist * '0 0 1');
  46         sdir = normalize(torg - org - zdist * '0 0 1');
  47
  48         // how high do we need to push the player?
  49         jumpheight = fabs(ht);
  50         if(zdist > 0)
  51                 jumpheight = jumpheight + zdist;
  52
  53         /*
  54                 STOP.
  55
  56                 You will not understand the following equations anyway...
  57                 But here is what I did to get them.
  58
  59                 I used the functions
  60
  61                   s(t) = t * vs
  62                   z(t) = t * vz - 1/2 grav t^2
  63
  64                 and solved for:
  65
  66                   s(ti) = sdist
  67                   z(ti) = zdist
  68                   max(z, ti) = jumpheight
  69
  70                 From these three equations, you will find the three parameters vs, vz
  71                 and ti.
  72          */
  73
  74         // push him so high...
  75         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  76
  77         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  78         if(ht < 0)
  79                 if(zdist < 0)
  80                         vz = -vz;
  81
  82         vector solution;
  83         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  84         // ALWAYS solvable because jumpheight >= zdist
  85         if(!solution.z)
  86                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  87         if(zdist == 0)
  88                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  89
  90         if(zdist < 0)
  91         {
  92                 // down-jump
  93                 if(ht < 0)
  94                 {
  95                         // almost straight line type
  96                         // jump apex is before the jump
  97                         // we must take the larger one
  98                         trigger_push_calculatevelocity_flighttime = solution.y;
  99                 }
 100                 else
 101                 {
 102                         // regular jump
 103                         // jump apex is during the jump
 104                         // we must take the larger one too
 105                         trigger_push_calculatevelocity_flighttime = solution.y;
 106                 }
 107         }
 108         else
 109         {
 110                 // up-jump
 111                 if(ht < 0)
 112                 {
 113                         // almost straight line type
 114                         // jump apex is after the jump
 115                         // we must take the smaller one
 116                         trigger_push_calculatevelocity_flighttime = solution.x;
 117                 }
 118                 else
 119                 {
 120                         // regular jump
 121                         // jump apex is during the jump
 122                         // we must take the larger one
 123                         trigger_push_calculatevelocity_flighttime = solution.y;
 124                 }
 125         }
 126         vs = sdist / trigger_push_calculatevelocity_flighttime;
 127
 128         // finally calculate the velocity
 129         return sdir * vs + '0 0 1' * vz;
 130 }
 131
 132 void trigger_push_touch(entity this, entity toucher)
 133 {
 134         if (this.active == ACTIVE_NOT)
 135                 return;
 136
 137         if (!isPushable(toucher))
 138                 return;
 139
 140         if(this.team)
 141                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, toucher)))
 142                         return;
 143
 144         EXACTTRIGGER_TOUCH(this, toucher);
 145
 146         if(this.enemy)
 147         {
 148                 toucher.velocity = trigger_push_calculatevelocity(toucher.origin, this.enemy, this.height);
 149         }
 150         else if(this.target && this.target != "")
 151         {
 152                 entity e;
 153                 RandomSelection_Init();
 154                 for(e = NULL; (e = find(e, targetname, this.target)); )
 155                 {
 156                         if(e.cnt)
 157                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 158                         else
 159                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 160                 }
 161                 toucher.velocity = trigger_push_calculatevelocity(toucher.origin, RandomSelection_chosen_ent, this.height);
 162         }
 163         else
 164         {
 165                 toucher.velocity = this.movedir;
 166         }
 167
 168         UNSET_ONGROUND(toucher);
 169
 170 #ifdef CSQC
 171         if (toucher.flags & FL_PROJECTILE)
 172         {
 173                 toucher.angles = vectoangles (toucher.velocity);
 174                 switch(toucher.move_movetype)
 175                 {
 176                         case MOVETYPE_FLY:
 177                                 toucher.move_movetype = MOVETYPE_TOSS;
 178                                 toucher.gravity = 1;
 179                                 break;
 180                         case MOVETYPE_BOUNCEMISSILE:
 181                                 toucher.move_movetype = MOVETYPE_BOUNCE;
 182                                 toucher.gravity = 1;
 183                                 break;
 184                 }
 185         }
 186 #endif
 187
 188 #ifdef SVQC
 189         if (IS_PLAYER(toucher))
 190         {
 191                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 192                 toucher.oldvelocity = toucher.velocity;
 193
 194                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 195                 {
 196                         // flash when activated
 197                         Send_Effect(EFFECT_JUMPPAD, toucher.origin, toucher.velocity, 1);
 198                         _sound (toucher, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 199                         this.pushltime = time + 0.2;
 200                 }
 201                 if(IS_REAL_CLIENT(toucher) || IS_BOT_CLIENT(toucher))
 202                 {
 203                         bool found = false;
 204                         for(int i = 0; i < toucher.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 205                                 if(toucher.(jumppadsused[i]) == this)
 206                                         found = true;
 207                         if(!found)
 208                         {
 209                                 toucher.(jumppadsused[toucher.jumppadcount % NUM_JUMPPADSUSED]) = this;
 210                                 toucher.jumppadcount = toucher.jumppadcount + 1;
 211                         }
 212
 213                         if(IS_REAL_CLIENT(toucher))
 214                         {
 215                                 if(this.message)
 216                                         centerprint(toucher, this.message);
 217                         }
 218                         else
 219                                 toucher.lastteleporttime = time;
 220
 221                         if (!IS_DEAD(toucher))
 222                                 animdecide_setaction(toucher, ANIMACTION_JUMP, true);
 223                 }
 224                 else
 225                         toucher.jumppadcount = true;
 226
 227                 // reset tracking of who pushed you into a hazard (for kill credit)
 228                 toucher.pushltime = 0;
 229                 toucher.istypefrag = 0;
 230         }
 231
 232         if(this.enemy.target)
 233                 SUB_UseTargets(this.enemy, toucher, toucher); // TODO: do we need toucher as trigger too?
 234
 235         if (toucher.flags & FL_PROJECTILE)
 236         {
 237                 toucher.angles = vectoangles (toucher.velocity);
 238                 switch(toucher.movetype)
 239                 {
 240                         case MOVETYPE_FLY:
 241                                 toucher.movetype = MOVETYPE_TOSS;
 242                                 toucher.gravity = 1;
 243                                 break;
 244                         case MOVETYPE_BOUNCEMISSILE:
 245                                 toucher.movetype = MOVETYPE_BOUNCE;
 246                                 toucher.gravity = 1;
 247                                 break;
 248                 }
 249                 UpdateCSQCProjectile(toucher);
 250         }
 251
 252         /*if (toucher.flags & FL_ITEM)
 253         {
 254                 ItemUpdate(toucher);
 255                 toucher.SendFlags |= ISF_DROP;
 256         }*/
 257
 258         if (this.spawnflags & PUSH_ONCE)
 259         {
 260                 settouch(this, func_null);
 261                 setthink(this, SUB_Remove);
 262                 this.nextthink = time;
 263         }
 264 #endif
 265 }
 266
 267 #ifdef SVQC
 268 void trigger_push_link(entity this);
 269 void trigger_push_updatelink(entity this);
 270 #endif
 271 void trigger_push_findtarget(entity this)
 272 {
 273         entity t;
 274         vector org;
 275
 276         // first calculate a typical start point for the jump
 277         org = (this.absmin + this.absmax) * 0.5;
 278         org_z = this.absmax.z - STAT(PL_MIN, NULL).z;
 279
 280         if (this.target)
 281         {
 282                 float n = 0;
 283                 for(t = NULL; (t = find(t, targetname, this.target)); )
 284                 {
 285                         ++n;
 286 #ifdef SVQC
 287                         entity e = spawn();
 288                         setorigin(e, org);
 289                         setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 290                         e.velocity = trigger_push_calculatevelocity(org, t, this.height);
 291                         tracetoss(e, e);
 292                         if(e.movetype == MOVETYPE_NONE)
 293                                 waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 294                         remove(e);
 295 #endif
 296                 }
 297
 298                 if(!n)
 299                 {
 300                         // no dest!
 301 #ifdef SVQC
 302                         objerror (this, "Jumppad with nonexistant target");
 303 #endif
 304                         return;
 305                 }
 306                 else if(n == 1)
 307                 {
 308                         // exactly one dest - bots love that
 309                         this.enemy = find(NULL, targetname, this.target);
 310                 }
 311                 else
 312                 {
 313                         // have to use random selection every single time
 314                         this.enemy = NULL;
 315                 }
 316         }
 317 #ifdef SVQC
 318         else
 319         {
 320                 entity e = spawn();
 321                 setorigin(e, org);
 322                 setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 323                 e.velocity = this.movedir;
 324                 tracetoss(e, e);
 325                 waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 326                 remove(e);
 327         }
 328
 329         trigger_push_link(this);
 330         defer(this, 0.1, trigger_push_updatelink);
 331 #endif
 332 }
 333
 334 #ifdef SVQC
 335 float trigger_push_send(entity this, entity to, float sf)
 336 {
 337         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 338
 339         WriteByte(MSG_ENTITY, this.team);
 340         WriteInt24_t(MSG_ENTITY, this.spawnflags);
 341         WriteByte(MSG_ENTITY, this.active);
 342         WriteCoord(MSG_ENTITY, this.height);
 343
 344         WriteCoord(MSG_ENTITY, this.movedir_x);
 345         WriteCoord(MSG_ENTITY, this.movedir_y);
 346         WriteCoord(MSG_ENTITY, this.movedir_z);
 347
 348         trigger_common_write(this, true);
 349
 350         return true;
 351 }
 352
 353 void trigger_push_updatelink(entity this)
 354 {
 355         this.SendFlags |= 1;
 356 }
 357
 358 void trigger_push_link(entity this)
 359 {
 360         trigger_link(this, trigger_push_send);
 361 }
 362
 363 /*
 364  * ENTITY PARAMETERS:
 365  *
 366  *   target:  target of jump
 367  *   height:  the absolute value is the height of the highest point of the jump
 368  *            trajectory above the higher one of the player and the target.
 369  *            the sign indicates whether the highest point is INSIDE (positive)
 370  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 371  *            positive values for targets mounted on the floor, and use negative
 372  *            values to target a point on the ceiling.
 373  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 374  */
 375 spawnfunc(trigger_push)
 376 {
 377         SetMovedir(this);
 378
 379         trigger_init(this);
 380
 381         this.active = ACTIVE_ACTIVE;
 382         this.use = trigger_push_use;
 383         settouch(this, trigger_push_touch);
 384
 385         // normal push setup
 386         if (!this.speed)
 387                 this.speed = 1000;
 388         this.movedir = this.movedir * this.speed * 10;
 389
 390         if (!this.noise)
 391                 this.noise = "misc/jumppad.wav";
 392         precache_sound (this.noise);
 393
 394         // this must be called to spawn the teleport waypoints for bots
 395         InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 396 }
 397
 398
 399 bool target_push_send(entity this, entity to, float sf)
 400 {
 401         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 402
 403         WriteByte(MSG_ENTITY, this.cnt);
 404         WriteString(MSG_ENTITY, this.targetname);
 405         WriteCoord(MSG_ENTITY, this.origin_x);
 406         WriteCoord(MSG_ENTITY, this.origin_y);
 407         WriteCoord(MSG_ENTITY, this.origin_z);
 408
 409         WriteAngle(MSG_ENTITY, this.angles_x);
 410         WriteAngle(MSG_ENTITY, this.angles_y);
 411         WriteAngle(MSG_ENTITY, this.angles_z);
 412
 413         return true;
 414 }
 415
 416 void target_push_link(entity this)
 417 {
 418         BITSET_ASSIGN(this.effects, EF_NODEPTHTEST);
 419         Net_LinkEntity(this, false, 0, target_push_send);
 420         //this.SendFlags |= 1; // update
 421 }
 422
 423 void target_push_init(entity this)
 424 {
 425         this.mangle = this.angles;
 426         setorigin(this, this.origin);
 427         target_push_link(this);
 428 }
 429
 430 spawnfunc(target_push) { target_push_init(this); }
 431 spawnfunc(info_notnull) { target_push_init(this); }
 432 spawnfunc(target_position) { target_push_init(this); }
 433
 434 #elif defined(CSQC)
 435
 436 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 437 {
 438         this.classname = "jumppad";
 439         int mytm = ReadByte(); if(mytm) { this.team = mytm - 1; }
 440         this.spawnflags = ReadInt24_t();
 441         this.active = ReadByte();
 442         this.height = ReadCoord();
 443
 444         this.movedir_x = ReadCoord();
 445         this.movedir_y = ReadCoord();
 446         this.movedir_z = ReadCoord();
 447
 448         trigger_common_read(this, true);
 449
 450         this.entremove = trigger_remove_generic;
 451         this.solid = SOLID_TRIGGER;
 452         settouch(this, trigger_push_touch);
 453         this.move_time = time;
 454         defer(this, 0.25, trigger_push_findtarget);
 455
 456         return true;
 457 }
 458
 459 void target_push_remove(entity this)
 460 {
 461         if(this.classname)
 462                 strunzone(this.classname);
 463         this.classname = string_null;
 464
 465         if(this.targetname)
 466                 strunzone(this.targetname);
 467         this.targetname = string_null;
 468 }
 469
 470 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 471 {
 472         this.classname = "push_target";
 473         this.cnt = ReadByte();
 474         this.targetname = strzone(ReadString());
 475         this.origin_x = ReadCoord();
 476         this.origin_y = ReadCoord();
 477         this.origin_z = ReadCoord();
 478
 479         this.angles_x = ReadAngle();
 480         this.angles_y = ReadAngle();
 481         this.angles_z = ReadAngle();
 482
 483         return = true;
 484
 485         setorigin(this, this.origin);
 486
 487         this.drawmask = MASK_NORMAL;
 488         this.entremove = target_push_remove;
 489 }
 490 #endif