qcsrc/common/triggers/trigger/jumppads.qc

   1 // TODO: split target_push and put it in the target folder
   2 #ifdef SVQC
   3 #include "jumppads.qh"
   4 #include "../../movetypes/movetypes.qh"
   5
   6 void trigger_push_use()
   7 {SELFPARAM();
   8         if(teamplay)
   9         {
  10                 self.team = activator.team;
  11                 self.SendFlags |= 2;
  12         }
  13 }
  14 #endif
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  17 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  18
  19 /*
  20         trigger_push_calculatevelocity
  21
  22         Arguments:
  23           org - origin of the object which is to be pushed
  24           tgt - target entity (can be either a point or a model entity; if it is
  25                 the latter, its midpoint is used)
  26           ht  - jump height, measured from the higher one of org and tgt's midpoint
  27
  28         Returns: velocity for the jump
  29         the global trigger_push_calculatevelocity_flighttime is set to the total
  30         jump time
  31  */
  32
  33 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  34 {
  35         float grav, sdist, zdist, vs, vz, jumpheight;
  36         vector sdir, torg;
  37
  38         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  39
  40         grav = PHYS_GRAVITY(other);
  41         if(PHYS_ENTGRAVITY(other))
  42                 grav *= PHYS_ENTGRAVITY(other);
  43
  44         zdist = torg.z - org.z;
  45         sdist = vlen(torg - org - zdist * '0 0 1');
  46         sdir = normalize(torg - org - zdist * '0 0 1');
  47
  48         // how high do we need to push the player?
  49         jumpheight = fabs(ht);
  50         if(zdist > 0)
  51                 jumpheight = jumpheight + zdist;
  52
  53         /*
  54                 STOP.
  55
  56                 You will not understand the following equations anyway...
  57                 But here is what I did to get them.
  58
  59                 I used the functions
  60
  61                   s(t) = t * vs
  62                   z(t) = t * vz - 1/2 grav t^2
  63
  64                 and solved for:
  65
  66                   s(ti) = sdist
  67                   z(ti) = zdist
  68                   max(z, ti) = jumpheight
  69
  70                 From these three equations, you will find the three parameters vs, vz
  71                 and ti.
  72          */
  73
  74         // push him so high...
  75         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  76
  77         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  78         if(ht < 0)
  79                 if(zdist < 0)
  80                         vz = -vz;
  81
  82         vector solution;
  83         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  84         // ALWAYS solvable because jumpheight >= zdist
  85         if(!solution.z)
  86                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  87         if(zdist == 0)
  88                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  89
  90         if(zdist < 0)
  91         {
  92                 // down-jump
  93                 if(ht < 0)
  94                 {
  95                         // almost straight line type
  96                         // jump apex is before the jump
  97                         // we must take the larger one
  98                         trigger_push_calculatevelocity_flighttime = solution.y;
  99                 }
 100                 else
 101                 {
 102                         // regular jump
 103                         // jump apex is during the jump
 104                         // we must take the larger one too
 105                         trigger_push_calculatevelocity_flighttime = solution.y;
 106                 }
 107         }
 108         else
 109         {
 110                 // up-jump
 111                 if(ht < 0)
 112                 {
 113                         // almost straight line type
 114                         // jump apex is after the jump
 115                         // we must take the smaller one
 116                         trigger_push_calculatevelocity_flighttime = solution.x;
 117                 }
 118                 else
 119                 {
 120                         // regular jump
 121                         // jump apex is during the jump
 122                         // we must take the larger one
 123                         trigger_push_calculatevelocity_flighttime = solution.y;
 124                 }
 125         }
 126         vs = sdist / trigger_push_calculatevelocity_flighttime;
 127
 128         // finally calculate the velocity
 129         return sdir * vs + '0 0 1' * vz;
 130 }
 131
 132 void trigger_push_touch()
 133 {SELFPARAM();
 134         if (this.active == ACTIVE_NOT)
 135                 return;
 136
 137 #ifdef SVQC
 138         if (!isPushable(other))
 139                 return;
 140 #endif
 141
 142         if(this.team)
 143                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, other)))
 144                         return;
 145
 146         EXACTTRIGGER_TOUCH;
 147
 148         if(this.enemy)
 149         {
 150                 other.velocity = trigger_push_calculatevelocity(other.origin, this.enemy, this.height);
 151                 other.move_velocity = other.velocity;
 152         }
 153         else if(this.target)
 154         {
 155                 entity e;
 156                 RandomSelection_Init();
 157                 for(e = world; (e = find(e, targetname, this.target)); )
 158                 {
 159                         if(e.cnt)
 160                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 161                         else
 162                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 163                 }
 164                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, this.height);
 165                 other.move_velocity = other.velocity;
 166         }
 167         else
 168         {
 169                 other.velocity = this.movedir;
 170                 other.move_velocity = other.velocity;
 171         }
 172
 173         UNSET_ONGROUND(other);
 174
 175         other.move_flags &= ~FL_ONGROUND;
 176
 177 #ifdef SVQC
 178         if (IS_PLAYER(other))
 179         {
 180                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 181                 other.oldvelocity = other.velocity;
 182
 183                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 184                 {
 185                         // flash when activated
 186                         Send_Effect(EFFECT_JUMPPAD, other.origin, other.velocity, 1);
 187                         _sound (other, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 188                         this.pushltime = time + 0.2;
 189                 }
 190                 if(IS_REAL_CLIENT(other) || IS_BOT_CLIENT(other))
 191                 {
 192                         bool found = false;
 193                         for(int i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 194                                 if(other.(jumppadsused[i]) == this)
 195                                         found = true;
 196                         if(!found)
 197                         {
 198                                 other.(jumppadsused[other.jumppadcount % NUM_JUMPPADSUSED]) = this;
 199                                 other.jumppadcount = other.jumppadcount + 1;
 200                         }
 201
 202                         if(IS_REAL_CLIENT(other))
 203                         {
 204                                 if(this.message)
 205                                         centerprint(other, this.message);
 206                         }
 207                         else
 208                                 other.lastteleporttime = time;
 209
 210                         if (other.deadflag == DEAD_NO)
 211                                 animdecide_setaction(other, ANIMACTION_JUMP, true);
 212                 }
 213                 else
 214                         other.jumppadcount = true;
 215
 216                 // reset tracking of who pushed you into a hazard (for kill credit)
 217                 other.pushltime = 0;
 218                 other.istypefrag = 0;
 219         }
 220
 221         if(this.enemy.target)
 222         {
 223                 activator = other;
 224                 WITH(entity, self, this.enemy, SUB_UseTargets());
 225         }
 226
 227         if (other.flags & FL_PROJECTILE)
 228         {
 229                 other.angles = vectoangles (other.velocity);
 230                 switch(other.movetype)
 231                 {
 232                         case MOVETYPE_FLY:
 233                                 other.movetype = MOVETYPE_TOSS;
 234                                 other.gravity = 1;
 235                                 break;
 236                         case MOVETYPE_BOUNCEMISSILE:
 237                                 other.movetype = MOVETYPE_BOUNCE;
 238                                 other.gravity = 1;
 239                                 break;
 240                 }
 241                 UpdateCSQCProjectile(other);
 242         }
 243
 244         if (this.spawnflags & PUSH_ONCE)
 245         {
 246                 this.touch = func_null;
 247                 this.think = SUB_Remove_self;
 248                 this.nextthink = time;
 249         }
 250 #endif
 251 }
 252
 253 #ifdef SVQC
 254 void trigger_push_link();
 255 void trigger_push_updatelink();
 256 #endif
 257 void trigger_push_findtarget()
 258 {SELFPARAM();
 259         entity t;
 260         vector org;
 261
 262         // first calculate a typical start point for the jump
 263         org = (self.absmin + self.absmax) * 0.5;
 264         org_z = self.absmax.z - PL_MIN.z;
 265
 266         if (self.target)
 267         {
 268                 float n = 0;
 269                 for(t = world; (t = find(t, targetname, self.target)); )
 270                 {
 271                         ++n;
 272 #ifdef SVQC
 273                         entity e = spawn();
 274                         setorigin(e, org);
 275                         setsize(e, PL_MIN, PL_MAX);
 276                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 277                         tracetoss(e, e);
 278                         if(e.movetype == MOVETYPE_NONE)
 279                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 280                         remove(e);
 281 #endif
 282                 }
 283
 284                 if(!n)
 285                 {
 286                         // no dest!
 287 #ifdef SVQC
 288                         objerror ("Jumppad with nonexistant target");
 289 #endif
 290                         return;
 291                 }
 292                 else if(n == 1)
 293                 {
 294                         // exactly one dest - bots love that
 295                         self.enemy = find(world, targetname, self.target);
 296                 }
 297                 else
 298                 {
 299                         // have to use random selection every single time
 300                         self.enemy = world;
 301                 }
 302         }
 303 #ifdef SVQC
 304         else
 305         {
 306                 entity e = spawn();
 307                 setorigin(e, org);
 308                 setsize(e, PL_MIN, PL_MAX);
 309                 e.velocity = self.movedir;
 310                 tracetoss(e, e);
 311                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 312                 remove(e);
 313         }
 314
 315         trigger_push_link();
 316         defer(self, 0.1, trigger_push_updatelink);
 317 #endif
 318 }
 319
 320 #ifdef SVQC
 321 float trigger_push_send(entity to, float sf)
 322 {SELFPARAM();
 323         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 324         WriteByte(MSG_ENTITY, sf);
 325
 326         if(sf & 1)
 327         {
 328                 WriteByte(MSG_ENTITY, self.team);
 329                 WriteInt24_t(MSG_ENTITY, self.spawnflags);
 330                 WriteByte(MSG_ENTITY, self.active);
 331                 WriteByte(MSG_ENTITY, self.height);
 332
 333                 trigger_common_write(true);
 334         }
 335
 336         if(sf & 2)
 337         {
 338                 WriteByte(MSG_ENTITY, self.team);
 339                 WriteByte(MSG_ENTITY, self.active);
 340         }
 341
 342         return true;
 343 }
 344
 345 void trigger_push_updatelink()
 346 {SELFPARAM();
 347         self.SendFlags |= 1;
 348 }
 349
 350 void trigger_push_link()
 351 {
 352         //Net_LinkEntity(self, false, 0, trigger_push_send);
 353 }
 354 #endif
 355 #ifdef SVQC
 356 /*
 357  * ENTITY PARAMETERS:
 358  *
 359  *   target:  target of jump
 360  *   height:  the absolute value is the height of the highest point of the jump
 361  *            trajectory above the higher one of the player and the target.
 362  *            the sign indicates whether the highest point is INSIDE (positive)
 363  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 364  *            positive values for targets mounted on the floor, and use negative
 365  *            values to target a point on the ceiling.
 366  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 367  */
 368 spawnfunc(trigger_push)
 369 {
 370         SetMovedir(self);
 371
 372         EXACTTRIGGER_INIT;
 373
 374         self.active = ACTIVE_ACTIVE;
 375         self.use = trigger_push_use;
 376         self.touch = trigger_push_touch;
 377
 378         // normal push setup
 379         if (!self.speed)
 380                 self.speed = 1000;
 381         self.movedir = self.movedir * self.speed * 10;
 382
 383         if (!self.noise)
 384                 self.noise = "misc/jumppad.wav";
 385         precache_sound (self.noise);
 386
 387         // this must be called to spawn the teleport waypoints for bots
 388         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 389 }
 390
 391
 392 bool target_push_send(entity this, entity to, float sf)
 393 {
 394         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 395
 396         WriteByte(MSG_ENTITY, self.cnt);
 397         WriteString(MSG_ENTITY, self.targetname);
 398         WriteCoord(MSG_ENTITY, self.origin_x);
 399         WriteCoord(MSG_ENTITY, self.origin_y);
 400         WriteCoord(MSG_ENTITY, self.origin_z);
 401
 402         return true;
 403 }
 404
 405 void target_push_link()
 406 {SELFPARAM();
 407         //Net_LinkEntity(self, false, 0, target_push_send);
 408         //self.SendFlags |= 1; // update
 409 }
 410
 411 spawnfunc(target_push) { target_push_link(); }
 412 spawnfunc(info_notnull) { target_push_link(); }
 413 spawnfunc(target_position) { make_pure(this); target_push_link(); }
 414
 415 #endif
 416
 417 #ifdef CSQC
 418
 419 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 420 {
 421         float sf = ReadByte();
 422
 423         if(sf & 1)
 424         {
 425                 self.classname = "jumppad";
 426                 int mytm = ReadByte(); if(mytm) { self.team = mytm - 1; }
 427                 self.spawnflags = ReadInt24_t();
 428                 self.active = ReadByte();
 429                 self.height = ReadByte();
 430
 431                 trigger_common_read(true);
 432
 433                 self.entremove = trigger_remove_generic;
 434                 self.solid = SOLID_TRIGGER;
 435                 self.draw = trigger_draw_generic;
 436                 self.trigger_touch = trigger_push_touch;
 437                 self.drawmask = MASK_NORMAL;
 438                 self.move_time = time;
 439                 trigger_push_findtarget();
 440         }
 441
 442         if(sf & 2)
 443         {
 444                 self.team = ReadByte();
 445                 self.active = ReadByte();
 446         }
 447         return true;
 448 }
 449
 450 void target_push_remove()
 451 {SELFPARAM();
 452         if(self.classname)
 453                 strunzone(self.classname);
 454         self.classname = string_null;
 455
 456         if(self.targetname)
 457                 strunzone(self.targetname);
 458         self.targetname = string_null;
 459 }
 460
 461 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 462 {
 463         self.classname = "push_target";
 464         self.cnt = ReadByte();
 465         self.targetname = strzone(ReadString());
 466         self.origin_x = ReadCoord();
 467         self.origin_y = ReadCoord();
 468         self.origin_z = ReadCoord();
 469
 470         return = true;
 471
 472         setorigin(self, self.origin);
 473
 474         self.drawmask = MASK_NORMAL;
 475         self.entremove = target_push_remove;
 476 }
 477 #endif