qcsrc/common/triggers/trigger/jumppads.qc

   1 // TODO: split target_push and put it in the target folder
   2 #ifdef SVQC
   3 #include "jumppads.qh"
   4 #include "../../movetypes/movetypes.qh"
   5
   6 void trigger_push_use()
   7 {SELFPARAM();
   8         if(teamplay)
   9         {
  10                 self.team = activator.team;
  11                 self.SendFlags |= 2;
  12         }
  13 }
  14 #endif
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  17 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  18
  19 /*
  20         trigger_push_calculatevelocity
  21
  22         Arguments:
  23           org - origin of the object which is to be pushed
  24           tgt - target entity (can be either a point or a model entity; if it is
  25                 the latter, its midpoint is used)
  26           ht  - jump height, measured from the higher one of org and tgt's midpoint
  27
  28         Returns: velocity for the jump
  29         the global trigger_push_calculatevelocity_flighttime is set to the total
  30         jump time
  31  */
  32
  33 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  34 {
  35         float grav, sdist, zdist, vs, vz, jumpheight;
  36         vector sdir, torg;
  37
  38         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  39
  40         grav = PHYS_GRAVITY(other);
  41         if(PHYS_ENTGRAVITY(other))
  42                 grav *= PHYS_ENTGRAVITY(other);
  43
  44         zdist = torg.z - org.z;
  45         sdist = vlen(torg - org - zdist * '0 0 1');
  46         sdir = normalize(torg - org - zdist * '0 0 1');
  47
  48         // how high do we need to push the player?
  49         jumpheight = fabs(ht);
  50         if(zdist > 0)
  51                 jumpheight = jumpheight + zdist;
  52
  53         /*
  54                 STOP.
  55
  56                 You will not understand the following equations anyway...
  57                 But here is what I did to get them.
  58
  59                 I used the functions
  60
  61                   s(t) = t * vs
  62                   z(t) = t * vz - 1/2 grav t^2
  63
  64                 and solved for:
  65
  66                   s(ti) = sdist
  67                   z(ti) = zdist
  68                   max(z, ti) = jumpheight
  69
  70                 From these three equations, you will find the three parameters vs, vz
  71                 and ti.
  72          */
  73
  74         // push him so high...
  75         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  76
  77         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  78         if(ht < 0)
  79                 if(zdist < 0)
  80                         vz = -vz;
  81
  82         vector solution;
  83         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  84         // ALWAYS solvable because jumpheight >= zdist
  85         if(!solution.z)
  86                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  87         if(zdist == 0)
  88                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  89
  90         if(zdist < 0)
  91         {
  92                 // down-jump
  93                 if(ht < 0)
  94                 {
  95                         // almost straight line type
  96                         // jump apex is before the jump
  97                         // we must take the larger one
  98                         trigger_push_calculatevelocity_flighttime = solution.y;
  99                 }
 100                 else
 101                 {
 102                         // regular jump
 103                         // jump apex is during the jump
 104                         // we must take the larger one too
 105                         trigger_push_calculatevelocity_flighttime = solution.y;
 106                 }
 107         }
 108         else
 109         {
 110                 // up-jump
 111                 if(ht < 0)
 112                 {
 113                         // almost straight line type
 114                         // jump apex is after the jump
 115                         // we must take the smaller one
 116                         trigger_push_calculatevelocity_flighttime = solution.x;
 117                 }
 118                 else
 119                 {
 120                         // regular jump
 121                         // jump apex is during the jump
 122                         // we must take the larger one
 123                         trigger_push_calculatevelocity_flighttime = solution.y;
 124                 }
 125         }
 126         vs = sdist / trigger_push_calculatevelocity_flighttime;
 127
 128         // finally calculate the velocity
 129         return sdir * vs + '0 0 1' * vz;
 130 }
 131
 132 void trigger_push_touch()
 133 {SELFPARAM();
 134         if (this.active == ACTIVE_NOT)
 135                 return;
 136
 137 #ifdef SVQC
 138         if (!isPushable(other))
 139                 return;
 140 #endif
 141
 142         if(this.team)
 143                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, other)))
 144                         return;
 145
 146         EXACTTRIGGER_TOUCH;
 147
 148         if(this.enemy)
 149         {
 150                 other.velocity = trigger_push_calculatevelocity(other.origin, this.enemy, this.height);
 151                 other.move_velocity = other.velocity;
 152         }
 153         else if(this.target)
 154         {
 155                 entity e;
 156                 RandomSelection_Init();
 157                 for(e = world; (e = find(e, targetname, this.target)); )
 158                 {
 159                         if(e.cnt)
 160                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 161                         else
 162                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 163                 }
 164                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, this.height);
 165                 other.move_velocity = other.velocity;
 166         }
 167         else
 168         {
 169                 other.velocity = this.movedir;
 170                 other.move_velocity = other.velocity;
 171         }
 172
 173 #ifdef SVQC
 174         UNSET_ONGROUND(other);
 175 #elif defined(CSQC)
 176         other.move_flags &= ~FL_ONGROUND;
 177 #endif
 178
 179 #ifdef SVQC
 180         if (IS_PLAYER(other))
 181         {
 182                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 183                 other.oldvelocity = other.velocity;
 184
 185                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 186                 {
 187                         // flash when activated
 188                         Send_Effect(EFFECT_JUMPPAD, other.origin, other.velocity, 1);
 189                         _sound (other, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 190                         this.pushltime = time + 0.2;
 191                 }
 192                 if(IS_REAL_CLIENT(other) || IS_BOT_CLIENT(other))
 193                 {
 194                         bool found = false;
 195                         for(int i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 196                                 if(other.(jumppadsused[i]) == this)
 197                                         found = true;
 198                         if(!found)
 199                         {
 200                                 other.(jumppadsused[other.jumppadcount % NUM_JUMPPADSUSED]) = this;
 201                                 other.jumppadcount = other.jumppadcount + 1;
 202                         }
 203
 204                         if(IS_REAL_CLIENT(other))
 205                         {
 206                                 if(this.message)
 207                                         centerprint(other, this.message);
 208                         }
 209                         else
 210                                 other.lastteleporttime = time;
 211
 212                         if (other.deadflag == DEAD_NO)
 213                                 animdecide_setaction(other, ANIMACTION_JUMP, true);
 214                 }
 215                 else
 216                         other.jumppadcount = true;
 217
 218                 // reset tracking of who pushed you into a hazard (for kill credit)
 219                 other.pushltime = 0;
 220                 other.istypefrag = 0;
 221         }
 222
 223         if(this.enemy.target)
 224         {
 225                 activator = other;
 226                 WITH(entity, self, this.enemy, SUB_UseTargets());
 227         }
 228
 229         if (other.flags & FL_PROJECTILE)
 230         {
 231                 other.angles = vectoangles (other.velocity);
 232                 switch(other.movetype)
 233                 {
 234                         case MOVETYPE_FLY:
 235                                 other.movetype = MOVETYPE_TOSS;
 236                                 other.gravity = 1;
 237                                 break;
 238                         case MOVETYPE_BOUNCEMISSILE:
 239                                 other.movetype = MOVETYPE_BOUNCE;
 240                                 other.gravity = 1;
 241                                 break;
 242                 }
 243                 UpdateCSQCProjectile(other);
 244         }
 245
 246         if (this.spawnflags & PUSH_ONCE)
 247         {
 248                 this.touch = func_null;
 249                 this.think = SUB_Remove_self;
 250                 this.nextthink = time;
 251         }
 252 #endif
 253 }
 254
 255 #ifdef SVQC
 256 void trigger_push_link();
 257 void trigger_push_updatelink();
 258 #endif
 259 void trigger_push_findtarget()
 260 {SELFPARAM();
 261         entity t;
 262         vector org;
 263
 264         // first calculate a typical start point for the jump
 265         org = (self.absmin + self.absmax) * 0.5;
 266         org_z = self.absmax.z - PL_MIN.z;
 267
 268         if (self.target)
 269         {
 270                 float n = 0;
 271                 for(t = world; (t = find(t, targetname, self.target)); )
 272                 {
 273                         ++n;
 274 #ifdef SVQC
 275                         entity e = spawn();
 276                         setorigin(e, org);
 277                         setsize(e, PL_MIN, PL_MAX);
 278                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 279                         tracetoss(e, e);
 280                         if(e.movetype == MOVETYPE_NONE)
 281                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 282                         remove(e);
 283 #endif
 284                 }
 285
 286                 if(!n)
 287                 {
 288                         // no dest!
 289 #ifdef SVQC
 290                         objerror ("Jumppad with nonexistant target");
 291 #endif
 292                         return;
 293                 }
 294                 else if(n == 1)
 295                 {
 296                         // exactly one dest - bots love that
 297                         self.enemy = find(world, targetname, self.target);
 298                 }
 299                 else
 300                 {
 301                         // have to use random selection every single time
 302                         self.enemy = world;
 303                 }
 304         }
 305 #ifdef SVQC
 306         else
 307         {
 308                 entity e = spawn();
 309                 setorigin(e, org);
 310                 setsize(e, PL_MIN, PL_MAX);
 311                 e.velocity = self.movedir;
 312                 tracetoss(e, e);
 313                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 314                 remove(e);
 315         }
 316
 317         trigger_push_link();
 318         defer(self, 0.1, trigger_push_updatelink);
 319 #endif
 320 }
 321
 322 #ifdef SVQC
 323 float trigger_push_send(entity this, entity to, float sf)
 324 {
 325         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 326         WriteByte(MSG_ENTITY, sf);
 327
 328         if(sf & 1)
 329         {
 330                 WriteByte(MSG_ENTITY, self.team);
 331                 WriteInt24_t(MSG_ENTITY, self.spawnflags);
 332                 WriteByte(MSG_ENTITY, self.active);
 333                 WriteCoord(MSG_ENTITY, self.height);
 334
 335                 trigger_common_write(true);
 336         }
 337
 338         if(sf & 2)
 339         {
 340                 WriteByte(MSG_ENTITY, self.team);
 341                 WriteByte(MSG_ENTITY, self.active);
 342         }
 343
 344         return true;
 345 }
 346
 347 void trigger_push_updatelink()
 348 {SELFPARAM();
 349         self.SendFlags |= 1;
 350 }
 351
 352 void trigger_push_link()
 353 {
 354         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 355         Net_LinkEntity(self, false, 0, trigger_push_send);
 356 }
 357 #endif
 358 #ifdef SVQC
 359 /*
 360  * ENTITY PARAMETERS:
 361  *
 362  *   target:  target of jump
 363  *   height:  the absolute value is the height of the highest point of the jump
 364  *            trajectory above the higher one of the player and the target.
 365  *            the sign indicates whether the highest point is INSIDE (positive)
 366  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 367  *            positive values for targets mounted on the floor, and use negative
 368  *            values to target a point on the ceiling.
 369  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 370  */
 371 spawnfunc(trigger_push)
 372 {
 373         SetMovedir(self);
 374
 375         EXACTTRIGGER_INIT;
 376
 377         self.active = ACTIVE_ACTIVE;
 378         self.use = trigger_push_use;
 379         self.touch = trigger_push_touch;
 380
 381         // normal push setup
 382         if (!self.speed)
 383                 self.speed = 1000;
 384         self.movedir = self.movedir * self.speed * 10;
 385
 386         if (!self.noise)
 387                 self.noise = "misc/jumppad.wav";
 388         precache_sound (self.noise);
 389
 390         // this must be called to spawn the teleport waypoints for bots
 391         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 392 }
 393
 394
 395 bool target_push_send(entity this, entity to, float sf)
 396 {
 397         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 398
 399         WriteByte(MSG_ENTITY, self.cnt);
 400         WriteString(MSG_ENTITY, self.targetname);
 401         WriteCoord(MSG_ENTITY, self.origin_x);
 402         WriteCoord(MSG_ENTITY, self.origin_y);
 403         WriteCoord(MSG_ENTITY, self.origin_z);
 404
 405         WriteAngle(MSG_ENTITY, self.angles_x);
 406         WriteAngle(MSG_ENTITY, self.angles_y);
 407         WriteAngle(MSG_ENTITY, self.angles_z);
 408
 409         return true;
 410 }
 411
 412 void target_push_link()
 413 {SELFPARAM();
 414         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 415         Net_LinkEntity(self, false, 0, target_push_send);
 416         //self.SendFlags |= 1; // update
 417 }
 418
 419 spawnfunc(target_push) { target_push_link(); }
 420 spawnfunc(info_notnull) { target_push_link(); }
 421 spawnfunc(target_position) { make_pure(this); target_push_link(); }
 422
 423 #endif
 424
 425 #ifdef CSQC
 426
 427 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 428 {
 429         float sf = ReadByte();
 430
 431         if(sf & 1)
 432         {
 433                 self.classname = "jumppad";
 434                 int mytm = ReadByte(); if(mytm) { self.team = mytm - 1; }
 435                 self.spawnflags = ReadInt24_t();
 436                 self.active = ReadByte();
 437                 self.height = ReadCoord();
 438
 439                 trigger_common_read(true);
 440
 441                 self.entremove = trigger_remove_generic;
 442                 self.solid = SOLID_TRIGGER;
 443                 //self.draw = trigger_draw_generic;
 444                 self.move_touch = trigger_push_touch;
 445                 self.drawmask = MASK_NORMAL;
 446                 self.move_time = time;
 447                 defer(self, 0.25, trigger_push_findtarget);
 448         }
 449
 450         if(sf & 2)
 451         {
 452                 self.team = ReadByte();
 453                 self.active = ReadByte();
 454         }
 455         return true;
 456 }
 457
 458 void target_push_remove()
 459 {SELFPARAM();
 460         if(self.classname)
 461                 strunzone(self.classname);
 462         self.classname = string_null;
 463
 464         if(self.targetname)
 465                 strunzone(self.targetname);
 466         self.targetname = string_null;
 467 }
 468
 469 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 470 {
 471         self.classname = "push_target";
 472         self.cnt = ReadByte();
 473         self.targetname = strzone(ReadString());
 474         self.origin_x = ReadCoord();
 475         self.origin_y = ReadCoord();
 476         self.origin_z = ReadCoord();
 477
 478         self.angles_x = ReadAngle();
 479         self.angles_y = ReadAngle();
 480         self.angles_z = ReadAngle();
 481
 482         return = true;
 483
 484         setorigin(self, self.origin);
 485
 486         self.drawmask = MASK_NORMAL;
 487         self.entremove = target_push_remove;
 488 }
 489 #endif