qcsrc/common/triggers/trigger/magicear.qc

   1 #ifdef SVQC
   2 float magicear_matched;
   3 float W_Tuba_HasPlayed(entity pl, string melody, float instrument, float ignorepitch, float mintempo, float maxtempo);
   4 string trigger_magicear_processmessage(entity ear, entity source, float teamsay, entity privatesay, string msgin)
   5 {
   6         float domatch, dotrigger, matchstart, l;
   7         string s, msg;
   8         entity oldself;
   9         string savemessage;
  10
  11         magicear_matched = false;
  12
  13         dotrigger = ((IS_PLAYER(source)) && (source.deadflag == DEAD_NO) && ((ear.radius == 0) || (vlen(source.origin - ear.origin) <= ear.radius)));
  14         domatch = ((ear.spawnflags & 32) || dotrigger);
  15
  16         if (!domatch)
  17                 return msgin;
  18
  19         if (!msgin)
  20         {
  21                 // we are in TUBA mode!
  22                 if (!(ear.spawnflags & 256))
  23                         return msgin;
  24
  25                 if(!W_Tuba_HasPlayed(source, ear.message, ear.movedir_x, !(ear.spawnflags & 512), ear.movedir_y, ear.movedir_z))
  26                         return msgin;
  27
  28                 magicear_matched = true;
  29
  30                 if(dotrigger)
  31                 {
  32                         oldself = self;
  33                         activator = source;
  34                         self = ear;
  35                         savemessage = self.message;
  36                         self.message = string_null;
  37                         SUB_UseTargets();
  38                         self.message = savemessage;
  39                         self = oldself;
  40                 }
  41
  42                 if(ear.netname != "")
  43                         return ear.netname;
  44
  45                 return msgin;
  46         }
  47
  48         if(ear.spawnflags & 256) // ENOTUBA
  49                 return msgin;
  50
  51         if(privatesay)
  52         {
  53                 if(ear.spawnflags & 4)
  54                         return msgin;
  55         }
  56         else
  57         {
  58                 if(!teamsay)
  59                         if(ear.spawnflags & 1)
  60                                 return msgin;
  61                 if(teamsay > 0)
  62                         if(ear.spawnflags & 2)
  63                                 return msgin;
  64                 if(teamsay < 0)
  65                         if(ear.spawnflags & 8)
  66                                 return msgin;
  67         }
  68
  69         matchstart = -1;
  70         l = strlen(ear.message);
  71
  72         if(ear.spawnflags & 128)
  73                 msg = msgin;
  74         else
  75                 msg = strdecolorize(msgin);
  76
  77         if(substring(ear.message, 0, 1) == "*")
  78         {
  79                 if(substring(ear.message, -1, 1) == "*")
  80                 {
  81                         // two wildcards
  82                         // as we need multi-replacement here...
  83                         s = substring(ear.message, 1, -2);
  84                         l -= 2;
  85                         if(strstrofs(msg, s, 0) >= 0)
  86                                 matchstart = -2; // we use strreplace on s
  87                 }
  88                 else
  89                 {
  90                         // match at start
  91                         s = substring(ear.message, 1, -1);
  92                         l -= 1;
  93                         if(substring(msg, -l, l) == s)
  94                                 matchstart = strlen(msg) - l;
  95                 }
  96         }
  97         else
  98         {
  99                 if(substring(ear.message, -1, 1) == "*")
 100                 {
 101                         // match at end
 102                         s = substring(ear.message, 0, -2);
 103                         l -= 1;
 104                         if(substring(msg, 0, l) == s)
 105                                 matchstart = 0;
 106                 }
 107                 else
 108                 {
 109                         // full match
 110                         s = ear.message;
 111                         if(msg == ear.message)
 112                                 matchstart = 0;
 113                 }
 114         }
 115
 116         if(matchstart == -1) // no match
 117                 return msgin;
 118
 119         magicear_matched = true;
 120
 121         if(dotrigger)
 122         {
 123                 oldself = self;
 124                 activator = source;
 125                 self = ear;
 126                 savemessage = self.message;
 127                 self.message = string_null;
 128                 SUB_UseTargets();
 129                 self.message = savemessage;
 130                 self = oldself;
 131         }
 132
 133         if(ear.spawnflags & 16)
 134         {
 135                 return ear.netname;
 136         }
 137         else if(ear.netname != "")
 138         {
 139                 if(matchstart < 0)
 140                         return strreplace(s, ear.netname, msg);
 141                 else
 142                         return strcat(
 143                                 substring(msg, 0, matchstart),
 144                                 ear.netname,
 145                                 substring(msg, matchstart + l, -1)
 146                         );
 147         }
 148         else
 149                 return msgin;
 150 }
 151
 152 entity magicears;
 153 string trigger_magicear_processmessage_forallears(entity source, float teamsay, entity privatesay, string msgin)
 154 {
 155         entity ear;
 156         string msgout;
 157         for(ear = magicears; ear; ear = ear.enemy)
 158         {
 159                 msgout = trigger_magicear_processmessage(ear, source, teamsay, privatesay, msgin);
 160                 if(!(ear.spawnflags & 64))
 161                 if(magicear_matched)
 162                         return msgout;
 163                 msgin = msgout;
 164         }
 165         return msgin;
 166 }
 167
 168 void spawnfunc_trigger_magicear()
 169 {
 170         self.enemy = magicears;
 171         magicears = self;
 172
 173         // actually handled in "say" processing
 174         // spawnflags:
 175         //    1 = ignore say
 176         //    2 = ignore teamsay
 177         //    4 = ignore tell
 178         //    8 = ignore tell to unknown player
 179         //   16 = let netname replace the whole message (otherwise, netname is a word replacement if set)
 180         //   32 = perform the replacement even if outside the radius or dead
 181         //   64 = continue replacing/triggering even if this one matched
 182         //  128 = don't decolorize message before matching
 183         //  256 = message is a tuba note sequence (pitch.duration pitch.duration ...)
 184         //  512 = tuba notes must be exact right pitch, no transposing
 185         // message: either
 186         //   *pattern*
 187         // or
 188         //   *pattern
 189         // or
 190         //   pattern*
 191         // or
 192         //   pattern
 193         // netname:
 194         //   if set, replacement for the matched text
 195         // radius:
 196         //   "hearing distance"
 197         // target:
 198         //   what to trigger
 199         // movedir:
 200         //   for spawnflags 256, defines 'instrument+1 mintempo maxtempo' (zero component doesn't matter)
 201
 202         self.movedir_x -= 1; // map to tuba instrument numbers
 203 }
 204 #endif